lily/parser.yy

   1 /* -*- mode: c++; c-file-style: "linux"; indent-tabs-mode: t -*- */
   2 /*
   3   This file is part of LilyPond, the GNU music typesetter.
   4
   5   Copyright (C) 1997--2012 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6                  Jan Nieuwenhuizen <janneke@gnu.org>
   7
   8   LilyPond is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   LilyPond is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  20 */
  21
  22 /* Mode and indentation are at best a rough approximation based on TAB
  23  * formatting (reasonable for compatibility with unspecific editor
  24  * modes as Bison modes are hard to find) and need manual correction
  25  * frequently.  Without a reasonably dependable way of formatting a
  26  * Bison file sensibly, there is little point in trying to fix the
  27  * inconsistent state of indentation.
  28  */
  29
  30 %{
  31
  32 #define yyerror Lily_parser::parser_error
  33
  34 /* We use custom location type: Input objects */
  35 #define YYLTYPE Input
  36 #define YYSTYPE SCM
  37 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  38         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  39
  40 #define YYPRINT(file, type, value)                                      \
  41         do {                                                            \
  42                 if (scm_is_eq (value, SCM_UNSPECIFIED))                 \
  43                         break;                                          \
  44                 char *p = scm_to_locale_string                          \
  45                         (scm_simple_format (SCM_BOOL_F,                 \
  46                                             scm_from_locale_string ("~S"), \
  47                                             scm_list_1 (value)));       \
  48                 fputs (p, file);                                        \
  49                 free (p);                                               \
  50         } while (0)
  51
  52 %}
  53
  54 %parse-param {Lily_parser *parser}
  55 %parse-param {SCM *retval}
  56 %lex-param {Lily_parser *parser}
  57 %error-verbose
  58 %debug
  59
  60 /* We use SCMs to do strings, because it saves us the trouble of
  61 deleting them.  Let's hope that a stack overflow doesn't trigger a move
  62 of the parse stack onto the heap. */
  63
  64 %left PREC_BOT
  65 %nonassoc REPEAT
  66 %nonassoc ALTERNATIVE
  67
  68 /* The above precedences tackle the shift/reduce problem
  69
  70 1.  \repeat
  71         \repeat .. \alternative
  72
  73     \repeat { \repeat .. \alternative }
  74
  75 or
  76
  77     \repeat { \repeat } \alternative
  78 */
  79
  80 %nonassoc COMPOSITE
  81 %left ADDLYRICS
  82
  83  /* ADDLYRICS needs to have lower precedence than argument scanning,
  84   * or we won't be able to tell music apart from closed_music without
  85   * lookahead in the context of function calls.
  86   */
  87
  88 %nonassoc DEFAULT
  89
  90  /* \default is only applied after exhausting function arguments */
  91
  92 %nonassoc FUNCTION_ARGLIST
  93
  94  /* expressions with units are permitted into argument lists */
  95
  96 %right PITCH_IDENTIFIER NOTENAME_PITCH TONICNAME_PITCH
  97       UNSIGNED REAL DURATION_IDENTIFIER ':'
  98
  99  /* The above are the symbols that can start optional function arguments
 100     that are recognized in the grammar rather than by predicate
 101  */
 102
 103 %nonassoc NUMBER_IDENTIFIER '/'
 104
 105  /* Number-unit expressions, where permitted, are concatenated into
 106   * function arguments, just like fractions and tremoli.  Tremoli must
 107   * not have higher precedence than UNSIGNED, or Lilypond will not
 108   * join ':' with a following optional number.
 109   */
 110
 111 %left PREC_TOP
 112
 113
 114
 115
 116 %pure-parser
 117 %locations
 118
 119
 120
 121 %{ // -*-Fundamental-*-
 122
 123 /*
 124 FIXME:
 125
 126    * The rules for who is protecting what are very shady.  Uniformise
 127      this.
 128
 129    * There are too many lexical modes?
 130 */
 131
 132 #include "config.hh"
 133
 134 #include <cctype>
 135 #include <cstdlib>
 136 #include <cstdio>
 137 using namespace std;
 138
 139 #include "book.hh"
 140 #include "context-def.hh"
 141 #include "context-mod.hh"
 142 #include "dimensions.hh"
 143 #include "file-path.hh"
 144 #include "input.hh"
 145 #include "international.hh"
 146 #include "lily-guile.hh"
 147 #include "lily-lexer.hh"
 148 #include "lily-parser.hh"
 149 #include "main.hh"
 150 #include "misc.hh"
 151 #include "music.hh"
 152 #include "output-def.hh"
 153 #include "paper-book.hh"
 154 #include "scm-hash.hh"
 155 #include "score.hh"
 156 #include "text-interface.hh"
 157 #include "warn.hh"
 158
 159 void
 160 Lily_parser::parser_error (Input const *i, Lily_parser *parser, SCM *, const string &s)
 161 {
 162         parser->parser_error (*i, s);
 163 }
 164
 165 #define MYBACKUP(Token, Value, Location)                                \
 166 do                                                                      \
 167         if (yychar == YYEMPTY)                                          \
 168         {                                                               \
 169                 if (Token)                                              \
 170                         parser->lexer_->push_extra_token (Token, Value); \
 171                 parser->lexer_->push_extra_token (BACKUP);              \
 172         } else {                                                        \
 173                 parser->parser_error                                    \
 174                         (Location, _("Too much lookahead"));            \
 175         }                                                               \
 176 while (0)
 177
 178
 179 #define MYREPARSE(Location, Pred, Token, Value)                         \
 180 do                                                                      \
 181         if (yychar == YYEMPTY)                                          \
 182         {                                                               \
 183                 parser->lexer_->push_extra_token (Token, Value);        \
 184                 parser->lexer_->push_extra_token (REPARSE,              \
 185                                                   Pred);                \
 186         } else {                                                        \
 187                 parser->parser_error                                    \
 188                         (Location, _("Too much lookahead"));            \
 189         }                                                               \
 190 while (0)
 191
 192 %}
 193
 194
 195 %{
 196
 197 #define MY_MAKE_MUSIC(x, spot) \
 198         make_music_with_input (ly_symbol2scm (x), \
 199                                parser->lexer_->override_input (spot))
 200
 201 /* ES TODO:
 202 - Don't use lily module, create a new module instead.
 203 - delay application of the function
 204 */
 205 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 206   scm_apply_0 (proc, args)
 207 /* Syntactic Sugar. */
 208 #define MAKE_SYNTAX(name, location, ...)                                \
 209         LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (parser->self_scm (), make_input (parser->lexer_->override_input (location)), ##__VA_ARGS__, SCM_UNDEFINED))
 210 #define START_MAKE_SYNTAX(name, ...)                                    \
 211         scm_list_n (ly_lily_module_constant (name) , ##__VA_ARGS__, SCM_UNDEFINED)
 212 #define FINISH_MAKE_SYNTAX(start, location, ...)                        \
 213         LOWLEVEL_MAKE_SYNTAX (scm_car (start), scm_cons2 (parser->self_scm (), make_input (parser->lexer_->override_input (location)), scm_append_x (scm_list_2 (scm_cdr (start), scm_list_n (__VA_ARGS__, SCM_UNDEFINED)))))
 214
 215 SCM get_next_unique_context_id ();
 216 SCM get_next_unique_lyrics_context_id ();
 217
 218 #undef _
 219 #if !HAVE_GETTEXT
 220 #define _(x) x
 221 #else
 222 #include <libintl.h>
 223 #define _(x) gettext (x)
 224 #endif
 225
 226
 227 static Music *make_music_with_input (SCM name, Input where);
 228 SCM check_scheme_arg (Lily_parser *parser, Input loc,
 229                       SCM arg, SCM args, SCM pred, SCM disp = SCM_UNDEFINED);
 230 SCM make_music_from_simple (Lily_parser *parser, Input loc, SCM pitch);
 231 SCM loc_on_music (Input loc, SCM arg);
 232 SCM make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list);
 233 SCM make_chord_step (SCM step, Rational alter);
 234 SCM make_simple_markup (SCM a);
 235 bool is_duration (int t);
 236 bool is_regular_identifier (SCM id, bool multiple=false);
 237 SCM try_string_variants (SCM pred, SCM str);
 238 int yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser);
 239
 240 %}
 241
 242 /* The third option is an alias that will be used to display the
 243    syntax error.  Bison CVS now correctly handles backslash escapes.
 244
 245    FIXME: Bison needs to translate some of these, eg, STRING.
 246
 247 */
 248
 249 /* Keyword tokens with plain escaped name.  */
 250 %token END_OF_FILE 0 "end of input"
 251 %token ACCEPTS "\\accepts"
 252 %token ADDLYRICS "\\addlyrics"
 253 %token ALIAS "\\alias"
 254 %token ALTERNATIVE "\\alternative"
 255 %token BOOK "\\book"
 256 %token BOOKPART "\\bookpart"
 257 %token CHANGE "\\change"
 258 %token CHORDMODE "\\chordmode"
 259 %token CHORDS "\\chords"
 260 %token CONSISTS "\\consists"
 261 %token CONTEXT "\\context"
 262 %token DEFAULT "\\default"
 263 %token DEFAULTCHILD "\\defaultchild"
 264 %token DENIES "\\denies"
 265 %token DESCRIPTION "\\description"
 266 %token DRUMMODE "\\drummode"
 267 %token DRUMS "\\drums"
 268 %token FIGUREMODE "\\figuremode"
 269 %token FIGURES "\\figures"
 270 %token HEADER "\\header"
 271 %token INVALID "\\version-error"
 272 %token LAYOUT "\\layout"
 273 %token LYRICMODE "\\lyricmode"
 274 %token LYRICS "\\lyrics"
 275 %token LYRICSTO "\\lyricsto"
 276 %token MARKUP "\\markup"
 277 %token MARKUPLIST "\\markuplist"
 278 %token MIDI "\\midi"
 279 %token NAME "\\name"
 280 %token NOTEMODE "\\notemode"
 281 %token OVERRIDE "\\override"
 282 %token PAPER "\\paper"
 283 %token REMOVE "\\remove"
 284 %token REPEAT "\\repeat"
 285 %token REST "\\rest"
 286 %token REVERT "\\revert"
 287 %token SCORE "\\score"
 288 %token SEQUENTIAL "\\sequential"
 289 %token SET "\\set"
 290 %token SIMULTANEOUS "\\simultaneous"
 291 %token TEMPO "\\tempo"
 292 %token TYPE "\\type"
 293 %token UNSET "\\unset"
 294 %token WITH "\\with"
 295
 296 /* Keyword token exceptions.  */
 297 %token NEWCONTEXT "\\new"
 298
 299
 300 /* Other string tokens.  */
 301
 302 %token CHORD_BASS "/+"
 303 %token CHORD_CARET "^"
 304 %token CHORD_COLON ":"
 305 %token CHORD_MINUS "-"
 306 %token CHORD_SLASH "/"
 307 %token ANGLE_OPEN "<"
 308 %token ANGLE_CLOSE ">"
 309 %token DOUBLE_ANGLE_OPEN "<<"
 310 %token DOUBLE_ANGLE_CLOSE ">>"
 311 %token E_BACKSLASH "\\"
 312 %token E_EXCLAMATION "\\!"
 313 %token E_PLUS "\\+"
 314 %token EXTENDER "__"
 315
 316 /*
 317 If we give names, Bison complains.
 318 */
 319 %token FIGURE_CLOSE /* "\\>" */
 320 %token FIGURE_OPEN /* "\\<" */
 321 %token FIGURE_SPACE "_"
 322 %token HYPHEN "--"
 323
 324 %token CHORDMODIFIERS
 325 %token MULTI_MEASURE_REST
 326
 327
 328 %token E_UNSIGNED
 329 %token UNSIGNED
 330
 331 /* Artificial tokens, for more generic function syntax */
 332 %token EXPECT_MARKUP "markup?"
 333 %token EXPECT_PITCH "ly:pitch?"
 334 %token EXPECT_DURATION "ly:duration?"
 335 %token EXPECT_SCM "scheme?"
 336 %token BACKUP "(backed-up?)"
 337 %token REPARSE "(reparsed?)"
 338 %token EXPECT_MARKUP_LIST "markup-list?"
 339 %token EXPECT_OPTIONAL "optional?"
 340 /* After the last argument. */
 341 %token EXPECT_NO_MORE_ARGS;
 342
 343 /* An artificial token for parsing embedded Lilypond */
 344 %token EMBEDDED_LILY "#{"
 345
 346 %token BOOK_IDENTIFIER
 347 %token CHORDMODIFIER_PITCH
 348 %token CHORD_MODIFIER
 349 %token CHORD_REPETITION
 350 %token CONTEXT_DEF_IDENTIFIER
 351 %token CONTEXT_MOD_IDENTIFIER
 352 %token DRUM_PITCH
 353 %token PITCH_IDENTIFIER
 354 %token DURATION_IDENTIFIER
 355 %token EVENT_IDENTIFIER
 356 %token EVENT_FUNCTION
 357 %token FRACTION
 358 %token LYRIC_ELEMENT
 359 %token MARKUP_FUNCTION
 360 %token MARKUP_LIST_FUNCTION
 361 %token MARKUP_IDENTIFIER
 362 %token MARKUPLIST_IDENTIFIER
 363 %token MUSIC_FUNCTION
 364 %token MUSIC_IDENTIFIER
 365 %token NOTENAME_PITCH
 366 %token NUMBER_IDENTIFIER
 367 %token OUTPUT_DEF_IDENTIFIER
 368 %token REAL
 369 %token RESTNAME
 370 %token SCM_ARG
 371 %token SCM_FUNCTION
 372 %token SCM_IDENTIFIER
 373 %token SCM_TOKEN
 374 %token STRING
 375 %token SYMBOL_LIST
 376 %token TONICNAME_PITCH
 377
 378 %left '-' '+'
 379
 380 /* We don't assign precedence to / and *, because we might need varied
 381 prec levels in different prods */
 382
 383 %left UNARY_MINUS
 384
 385 %%
 386
 387 start_symbol:
 388         lilypond
 389         | EMBEDDED_LILY {
 390                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 391                 parser->lexer_->push_note_state (nn);
 392         } embedded_lilypond {
 393                 parser->lexer_->pop_state ();
 394                 *retval = $3;
 395         }
 396         ;
 397
 398 lilypond:       /* empty */ { $$ = SCM_UNSPECIFIED; }
 399         | lilypond toplevel_expression {
 400         }
 401         | lilypond assignment {
 402         }
 403         | lilypond error {
 404                 parser->error_level_ = 1;
 405         }
 406         | lilypond INVALID      {
 407                 parser->error_level_ = 1;
 408         }
 409         ;
 410
 411
 412 toplevel_expression:
 413         {
 414                 parser->lexer_->add_scope (get_header (parser));
 415         } lilypond_header {
 416                 parser->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $2);
 417         }
 418         | book_block {
 419                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-book-handler");
 420                 scm_call_2 (proc, parser->self_scm (), $1);
 421         }
 422         | bookpart_block {
 423                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 424                 scm_call_2 (proc, parser->self_scm (), $1);
 425         }
 426         | score_block {
 427                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-score-handler");
 428                 scm_call_2 (proc, parser->self_scm (), $1);
 429         }
 430         | composite_music {
 431                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-music-handler");
 432                 scm_call_2 (proc, parser->self_scm (), $1);
 433         }
 434         | full_markup {
 435                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 436                 scm_call_2 (proc, parser->self_scm (), scm_list_1 ($1));
 437         }
 438         | full_markup_list {
 439                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 440                 scm_call_2 (proc, parser->self_scm (), $1);
 441         }
 442         | SCM_TOKEN {
 443                 // Evaluate and ignore #xxx, as opposed to \xxx
 444                 parser->lexer_->eval_scm_token ($1);
 445         }
 446         | embedded_scm_active
 447         {
 448                 SCM out = SCM_UNDEFINED;
 449                 if (Text_interface::is_markup ($1))
 450                         out = scm_list_1 ($1);
 451                 else if (Text_interface::is_markup_list ($1))
 452                         out = $1;
 453                 if (scm_is_pair (out))
 454                 {
 455                         SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 456                         scm_call_2 (proc, parser->self_scm (), out);
 457                 } else if (!scm_is_eq ($1, SCM_UNSPECIFIED))
 458                         parser->parser_error (@1, _("bad expression type"));
 459         }
 460         | output_def {
 461                 SCM id = SCM_EOL;
 462                 Output_def * od = unsmob_output_def ($1);
 463
 464                 if (od->c_variable ("is-paper") == SCM_BOOL_T)
 465                         id = ly_symbol2scm ("$defaultpaper");
 466                 else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 467                         id = ly_symbol2scm ("$defaultmidi");
 468                 else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 469                         id = ly_symbol2scm ("$defaultlayout");
 470
 471                 parser->lexer_->set_identifier (id, $1);
 472         }
 473         ;
 474
 475 embedded_scm_bare:
 476         SCM_TOKEN
 477         {
 478                 $$ = parser->lexer_->eval_scm_token ($1);
 479         }
 480         | SCM_IDENTIFIER
 481         ;
 482
 483 embedded_scm_active:
 484         SCM_IDENTIFIER
 485         | scm_function_call
 486         ;
 487
 488 embedded_scm_bare_arg:
 489         SCM_ARG
 490         | SCM_TOKEN
 491         {
 492                 $$ = parser->lexer_->eval_scm_token ($1);
 493         }
 494         | full_markup_list
 495         | context_modification
 496         | score_block
 497         | context_def_spec_block
 498         | book_block
 499         | bookpart_block
 500         | output_def
 501         ;
 502
 503 /* The generic version may end in music, or not */
 504
 505 embedded_scm:
 506         embedded_scm_bare
 507         | scm_function_call
 508         ;
 509
 510 embedded_scm_arg:
 511         embedded_scm_bare_arg
 512         | scm_function_call
 513         | music_arg
 514         ;
 515
 516 scm_function_call:
 517         SCM_FUNCTION function_arglist {
 518                 $$ = MAKE_SYNTAX ("music-function", @$,
 519                                          $1, $2);
 520         }
 521         ;
 522
 523 embedded_lilypond:
 524         /* empty */
 525         {
 526                 $$ = MAKE_SYNTAX ("void-music", @$);
 527         }
 528         | identifier_init
 529         | music_embedded music_embedded music_list {
 530                 $3 = scm_reverse_x ($3, SCM_EOL);
 531                 if (unsmob_music ($2))
 532                         $3 = scm_cons ($2, $3);
 533                 if (unsmob_music ($1))
 534                         $3 = scm_cons ($1, $3);
 535                 $$ = MAKE_SYNTAX ("sequential-music", @$, $3);
 536         }
 537         | error {
 538                 parser->error_level_ = 1;
 539                 $$ = SCM_UNSPECIFIED;
 540         }
 541         | INVALID embedded_lilypond {
 542                 parser->error_level_ = 1;
 543                 $$ = $2;
 544         }
 545         ;
 546
 547
 548 lilypond_header_body:
 549         /* empty */ { $$ = SCM_UNSPECIFIED; }
 550         | lilypond_header_body assignment  {
 551
 552         }
 553         | lilypond_header_body embedded_scm  {
 554
 555         }
 556         ;
 557
 558 lilypond_header:
 559         HEADER '{' lilypond_header_body '}'     {
 560                 $$ = parser->lexer_->remove_scope ();
 561         }
 562         ;
 563
 564 /*
 565         DECLARATIONS
 566 */
 567 assignment_id:
 568         STRING          { $$ = $1; }
 569         ;
 570
 571 assignment:
 572         assignment_id '=' identifier_init  {
 573                 parser->lexer_->set_identifier ($1, $3);
 574                 $$ = SCM_UNSPECIFIED;
 575         }
 576         | assignment_id property_path '=' identifier_init {
 577                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 578                 parser->lexer_->set_identifier (path, $4);
 579                 $$ = SCM_UNSPECIFIED;
 580         }
 581         ;
 582
 583
 584 identifier_init:
 585         score_block
 586         | book_block
 587         | bookpart_block
 588         | output_def
 589         | context_def_spec_block
 590         | music_assign
 591         | post_event_nofinger post_events
 592         {
 593                 $$ = scm_reverse_x ($2, SCM_EOL);
 594                 if (Music *m = unsmob_music ($1))
 595                 {
 596                         if (m->is_mus_type ("post-event-wrapper"))
 597                                 $$ = scm_append
 598                                         (scm_list_2 (m->get_property ("elements"),
 599                                                      $$));
 600                         else
 601                                 $$ = scm_cons ($1, $$);
 602                 }
 603                 if (scm_is_pair ($$)
 604                     && scm_is_null (scm_cdr ($$)))
 605                         $$ = scm_car ($$);
 606                 else
 607                 {
 608                         Music * m = MY_MAKE_MUSIC ("PostEvents", @$);
 609                         m->set_property ("elements", $$);
 610                         $$ = m->unprotect ();
 611                 }
 612         }
 613         | number_expression
 614         | FRACTION
 615         | string
 616         | embedded_scm
 617         | full_markup_list
 618         | context_modification
 619         ;
 620
 621 context_def_spec_block:
 622         CONTEXT '{' context_def_spec_body '}'
 623                 {
 624                 $$ = $3;
 625         }
 626         ;
 627
 628 context_mod_arg:
 629         embedded_scm
 630         |
 631         {
 632                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 633                 parser->lexer_->push_note_state (nn);
 634         }
 635         composite_music
 636         {
 637                 parser->lexer_->pop_state ();
 638                 $$ = $2;
 639         }
 640         ;
 641
 642 context_mod_embedded:
 643         context_mod_arg
 644         {
 645                 if (unsmob_music ($1)) {
 646                         SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
 647                         $1 = scm_call_2 (proc, parser->self_scm (), $1);
 648                 }
 649                 if (unsmob_context_mod ($1))
 650                         $$ = $1;
 651                 else {
 652                         parser->parser_error (@1, _ ("not a context mod"));
 653                 }
 654         }
 655         ;
 656
 657
 658 context_def_spec_body:
 659         /**/ {
 660                 $$ = Context_def::make_scm ();
 661                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 662         }
 663         | CONTEXT_DEF_IDENTIFIER {
 664                 $$ = $1;
 665                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 666         }
 667         | context_def_spec_body context_mod {
 668                 if (!SCM_UNBNDP ($2))
 669                         unsmob_context_def ($$)->add_context_mod ($2);
 670         }
 671         | context_def_spec_body context_modification {
 672                 Context_def *td = unsmob_context_def ($$);
 673                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 674                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 675                     td->add_context_mod (scm_car (m));
 676                 }
 677         }
 678         | context_def_spec_body context_mod_embedded {
 679                 Context_def *td = unsmob_context_def ($$);
 680                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 681                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 682                     td->add_context_mod (scm_car (m));
 683                 }
 684         }
 685         ;
 686
 687
 688
 689 book_block:
 690         BOOK '{' book_body '}'  {
 691                 $$ = $3;
 692                 pop_paper (parser);
 693                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 694         }
 695         ;
 696
 697 /* FIXME:
 698    * Use 'handlers' like for toplevel-* stuff?
 699    * grok \layout and \midi?  */
 700 book_body:
 701         {
 702                 Book *book = new Book;
 703                 init_papers (parser);
 704                 book->origin ()->set_spot (@$);
 705                 book->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (parser->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 706                 book->paper_->unprotect ();
 707                 push_paper (parser, book->paper_);
 708                 book->header_ = get_header (parser);
 709                 $$ = book->unprotect ();
 710                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$);
 711         }
 712         | BOOK_IDENTIFIER {
 713                 unsmob_book ($1)->origin ()->set_spot (@$);
 714                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 715         }
 716         | book_body paper_block {
 717                 unsmob_book ($1)->paper_ = unsmob_output_def ($2);
 718                 set_paper (parser, unsmob_output_def ($2));
 719         }
 720         | book_body bookpart_block {
 721                 SCM proc = parser->lexer_->lookup_identifier ("book-bookpart-handler");
 722                 scm_call_2 (proc, $1, $2);
 723         }
 724         | book_body score_block {
 725                 SCM proc = parser->lexer_->lookup_identifier ("book-score-handler");
 726                 scm_call_2 (proc, $1, $2);
 727         }
 728         | book_body composite_music {
 729                 SCM proc = parser->lexer_->lookup_identifier ("book-music-handler");
 730                 scm_call_3 (proc, parser->self_scm (), $1, $2);
 731         }
 732         | book_body full_markup {
 733                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 734                 scm_call_2 (proc, $1, scm_list_1 ($2));
 735         }
 736         | book_body full_markup_list {
 737                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 738                 scm_call_2 (proc, $1, $2);
 739         }
 740         | book_body SCM_TOKEN {
 741                 // Evaluate and ignore #xxx, as opposed to \xxx
 742                 parser->lexer_->eval_scm_token ($2);
 743         }
 744         | book_body embedded_scm_active
 745         {
 746                 SCM out = SCM_UNDEFINED;
 747                 if (Text_interface::is_markup ($2))
 748                         out = scm_list_1 ($2);
 749                 else if (Text_interface::is_markup_list ($2))
 750                         out = $2;
 751                 if (scm_is_pair (out))
 752                 {
 753                         SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 754                         scm_call_2 (proc, $1, out);
 755                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
 756                         parser->parser_error (@2, _("bad expression type"));
 757         }
 758         | book_body
 759         {
 760                 parser->lexer_->add_scope (unsmob_book ($1)->header_);
 761         } lilypond_header
 762         | book_body error {
 763                 Book *book = unsmob_book ($1);
 764                 book->paper_ = 0;
 765                 book->scores_ = SCM_EOL;
 766                 book->bookparts_ = SCM_EOL;
 767         }
 768         ;
 769
 770 bookpart_block:
 771         BOOKPART '{' bookpart_body '}' {
 772                 $$ = $3;
 773                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 774         }
 775         ;
 776
 777 bookpart_body:
 778         {
 779                 Book *book = new Book;
 780                 book->origin ()->set_spot (@$);
 781                 $$ = book->unprotect ();
 782                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$);
 783         }
 784         | BOOK_IDENTIFIER {
 785                 unsmob_book ($1)->origin ()->set_spot (@$);
 786                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 787         }
 788         | bookpart_body paper_block {
 789                 unsmob_book ($$)->paper_ = unsmob_output_def ($2);
 790         }
 791         | bookpart_body score_block {
 792                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-score-handler");
 793                 scm_call_2 (proc, $1, $2);
 794         }
 795         | bookpart_body composite_music {
 796                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-music-handler");
 797                 scm_call_3 (proc, parser->self_scm (), $1, $2);
 798         }
 799         | bookpart_body full_markup {
 800                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 801                 scm_call_2 (proc, $1, scm_list_1 ($2));
 802         }
 803         | bookpart_body full_markup_list {
 804                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 805                 scm_call_2 (proc, $1, $2);
 806         }
 807         | bookpart_body SCM_TOKEN {
 808                 // Evaluate and ignore #xxx, as opposed to \xxx
 809                 parser->lexer_->eval_scm_token ($2);
 810         }
 811         | bookpart_body embedded_scm_active
 812         {
 813                 SCM out = SCM_UNDEFINED;
 814                 if (Text_interface::is_markup ($2))
 815                         out = scm_list_1 ($2);
 816                 else if (Text_interface::is_markup_list ($2))
 817                         out = $2;
 818                 if (scm_is_pair (out))
 819                 {
 820                         SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 821                         scm_call_2 (proc, $1, out);
 822                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
 823                         parser->parser_error (@2, _("bad expression type"));
 824         }
 825         | bookpart_body
 826         {
 827                 Book *book = unsmob_book ($1);
 828                 if (!ly_is_module (book->header_))
 829                         book->header_ = ly_make_module (false);
 830                 parser->lexer_->add_scope (book->header_);
 831         } lilypond_header
 832         | bookpart_body error {
 833                 Book *book = unsmob_book ($1);
 834                 book->paper_ = 0;
 835                 book->scores_ = SCM_EOL;
 836         }
 837         ;
 838
 839 score_block:
 840         SCORE '{' score_body '}'        {
 841                 $$ = $3;
 842         }
 843         ;
 844
 845 score_body:
 846         music {
 847                 SCM scorify = ly_lily_module_constant ("scorify-music");
 848                 $$ = scm_call_2 (scorify, $1, parser->self_scm ());
 849
 850                 unsmob_score ($$)->origin ()->set_spot (@$);
 851         }
 852         | embedded_scm_active {
 853                 Score *score;
 854                 if (unsmob_score ($1))
 855                         score = new Score (*unsmob_score ($1));
 856                 else {
 857                         score = new Score;
 858                         parser->parser_error (@1, _("score expected"));
 859                 }
 860                 unsmob_score ($$)->origin ()->set_spot (@$);
 861                 $$ = score->unprotect ();
 862         }
 863         | score_body
 864         {
 865                 Score *score = unsmob_score ($1);
 866                 if (!ly_is_module (score->get_header ()))
 867                         score->set_header (ly_make_module (false));
 868                 parser->lexer_->add_scope (score->get_header ());
 869         } lilypond_header
 870         | score_body output_def {
 871                 Output_def *od = unsmob_output_def ($2);
 872                 if (od->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 873                 {
 874                         parser->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 875
 876                 }
 877                 else
 878                 {
 879                         unsmob_score ($1)->add_output_def (od);
 880                 }
 881         }
 882         | score_body error {
 883                 unsmob_score ($$)->error_found_ = true;
 884         }
 885         ;
 886
 887
 888 /*
 889         OUTPUT DEF
 890 */
 891
 892 paper_block:
 893         output_def {
 894                 Output_def *od = unsmob_output_def ($1);
 895
 896                 if (od->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 897                 {
 898                         parser->parser_error (@1, _ ("need \\paper for paper block"));
 899                         $$ = get_paper (parser)->unprotect ();
 900                 }
 901         }
 902         ;
 903
 904
 905 output_def:
 906         output_def_body '}' {
 907                 $$ = $1;
 908
 909                 parser->lexer_->remove_scope ();
 910                 parser->lexer_->pop_state ();
 911         }
 912         ;
 913
 914 output_def_head:
 915         PAPER {
 916                 Output_def *p = get_paper (parser);
 917                 p->input_origin_ = @$;
 918                 parser->lexer_->add_scope (p->scope_);
 919                 $$ = p->unprotect ();
 920         }
 921         | MIDI    {
 922                 Output_def *p = get_midi (parser);
 923                 $$ = p->unprotect ();
 924                 parser->lexer_->add_scope (p->scope_);
 925         }
 926         | LAYOUT        {
 927                 Output_def *p = get_layout (parser);
 928
 929                 parser->lexer_->add_scope (p->scope_);
 930                 $$ = p->unprotect ();
 931         }
 932         ;
 933
 934 output_def_head_with_mode_switch:
 935         output_def_head {
 936                 parser->lexer_->push_initial_state ();
 937                 $$ = $1;
 938         }
 939         ;
 940
 941 // We need this weird nonterminal because both music as well as a
 942 // context definition can start with \context and the difference is
 943 // only apparent after looking at the next token.  If it is '{', there
 944 // is still time to escape from notes mode.
 945
 946 music_or_context_def:
 947         music_arg
 948         {
 949                 parser->lexer_->pop_state ();
 950         }
 951         | CONTEXT
 952         {
 953                 parser->lexer_->pop_state ();
 954         } '{' context_def_spec_body '}'
 955         {
 956                 $$ = $4;
 957         }
 958         ;
 959
 960 output_def_body:
 961         output_def_head_with_mode_switch '{' {
 962                 $$ = $1;
 963                 unsmob_output_def ($$)->input_origin_.set_spot (@$);
 964         }
 965         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 966                 Output_def *o = unsmob_output_def ($3);
 967                 o->input_origin_.set_spot (@$);
 968                 $$ = o->self_scm ();
 969                 parser->lexer_->remove_scope ();
 970                 parser->lexer_->add_scope (o->scope_);
 971         }
 972         | output_def_body assignment  {
 973
 974         }
 975         | output_def_body embedded_scm  {
 976
 977         }
 978         | output_def_body
 979         {
 980                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 981                 parser->lexer_->push_note_state (nn);
 982         } music_or_context_def
 983         {
 984                 if (unsmob_context_def ($3))
 985                         assign_context_def (unsmob_output_def ($1), $3);
 986                 else {
 987
 988                         SCM proc = parser->lexer_->lookup_identifier
 989                                      ("output-def-music-handler");
 990                         scm_call_3 (proc, parser->self_scm (),
 991                                     $1, $3);
 992                 }
 993         }
 994         | output_def_body error {
 995
 996         }
 997         ;
 998
 999 tempo_event:
1000         TEMPO steno_duration '=' tempo_range    {
1001                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_EOL, $2, $4);
1002         }
1003         | TEMPO scalar_closed steno_duration '=' tempo_range    {
1004                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
1005         }
1006         | TEMPO scalar {
1007                 $$ = MAKE_SYNTAX ("tempo", @$, $2);
1008         }
1009         ;
1010
1011 /*
1012 The representation of a  list is reversed to have efficient append.  */
1013
1014 music_list:
1015         /* empty */ {
1016                 $$ = SCM_EOL;
1017         }
1018         | music_list music_embedded {
1019                 if (unsmob_music ($2))
1020                         $$ = scm_cons ($2, $1);
1021         }
1022         | music_list error {
1023                 Music *m = MY_MAKE_MUSIC("Music", @$);
1024                 // ugh. code dup
1025                 m->set_property ("error-found", SCM_BOOL_T);
1026                 $$ = scm_cons (m->self_scm (), $1);
1027                 m->unprotect (); /* UGH */
1028         }
1029         ;
1030
1031 braced_music_list:
1032         '{' music_list '}'
1033         {
1034                 $$ = scm_reverse_x ($2, SCM_EOL);
1035         }
1036         ;
1037
1038 music:  music_arg
1039         | lyric_element_music
1040         ;
1041
1042 music_embedded:
1043         music
1044         {
1045                 if (unsmob_music ($1)->is_mus_type ("post-event")) {
1046                         parser->parser_error (@1, _ ("unexpected post-event"));
1047                         $$ = SCM_UNSPECIFIED;
1048                 }
1049         }
1050         | music_embedded_backup
1051         {
1052                 $$ = $1;
1053         }
1054         | music_embedded_backup BACKUP lyric_element_music
1055         {
1056                 $$ = $3;
1057         }
1058         ;
1059
1060 music_embedded_backup:
1061         embedded_scm
1062         {
1063                 if (scm_is_eq ($1, SCM_UNSPECIFIED))
1064                         $$ = $1;
1065                 else if (Music *m = unsmob_music ($1)) {
1066                         if (m->is_mus_type ("post-event")) {
1067                                 parser->parser_error
1068                                         (@1, _ ("unexpected post-event"));
1069                                 $$ = SCM_UNSPECIFIED;
1070                         } else
1071                                 $$ = $1;
1072                 } else if (parser->lexer_->is_lyric_state ()
1073                            && Text_interface::is_markup ($1))
1074                         MYBACKUP (LYRIC_ELEMENT, $1, @1);
1075                 else {
1076                         @$.warning (_ ("Ignoring non-music expression"));
1077                         $$ = $1;
1078                 }
1079         }
1080         ;
1081
1082 music_arg:
1083         simple_music
1084         {
1085                 $$ = make_music_from_simple (parser, @1, $1);
1086                 if (!unsmob_music ($$))
1087                         parser->parser_error (@1, _ ("music expected"));
1088         }
1089         | composite_music %prec COMPOSITE
1090         ;
1091
1092 music_assign:
1093         simple_music
1094         | composite_music %prec COMPOSITE
1095         ;
1096
1097 repeated_music:
1098         REPEAT simple_string unsigned_number music
1099         {
1100                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, SCM_EOL);
1101         }
1102         | REPEAT simple_string unsigned_number music ALTERNATIVE braced_music_list
1103         {
1104                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $6);
1105         }
1106         ;
1107
1108 sequential_music:
1109         SEQUENTIAL braced_music_list {
1110                 $$ = MAKE_SYNTAX ("sequential-music", @$, $2);
1111         }
1112         | braced_music_list {
1113                 $$ = MAKE_SYNTAX ("sequential-music", @$, $1);
1114         }
1115         ;
1116
1117 simultaneous_music:
1118         SIMULTANEOUS braced_music_list {
1119                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, $2);
1120         }
1121         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1122                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($2, SCM_EOL));
1123         }
1124         ;
1125
1126 simple_music:
1127         event_chord
1128         | music_property_def
1129         | context_change
1130         ;
1131
1132 context_modification:
1133         WITH { parser->lexer_->push_initial_state (); } '{' context_mod_list '}'
1134         {
1135                 parser->lexer_->pop_state ();
1136                 $$ = $4;
1137         }
1138         | WITH CONTEXT_MOD_IDENTIFIER
1139         {
1140                 $$ = $2;
1141         }
1142         | CONTEXT_MOD_IDENTIFIER
1143         {
1144                 $$ = $1;
1145         }
1146         | WITH embedded_scm_closed
1147         {
1148                 if (unsmob_context_mod ($2))
1149                         $$ = $2;
1150                 else {
1151                         parser->parser_error (@2, _ ("not a context mod"));
1152                         $$ = Context_mod ().smobbed_copy ();
1153                 }
1154         }
1155         ;
1156
1157 optional_context_mod:
1158         /**/ {
1159             $$ = SCM_EOL;
1160         }
1161         | context_modification
1162         {
1163               $$ = $1;
1164         }
1165         ;
1166
1167 context_mod_list:
1168         /**/ {
1169             $$ = Context_mod ().smobbed_copy ();
1170         }
1171         | context_mod_list context_mod  {
1172                 if (!SCM_UNBNDP ($2))
1173                         unsmob_context_mod ($1)->add_context_mod ($2);
1174         }
1175         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1176                  Context_mod *md = unsmob_context_mod ($2);
1177                  if (md)
1178                      unsmob_context_mod ($1)->add_context_mods (md->get_mods ());
1179         }
1180         | context_mod_list context_mod_embedded {
1181                 unsmob_context_mod ($1)->add_context_mods
1182                         (unsmob_context_mod ($2)->get_mods ());
1183         }
1184         ;
1185
1186 composite_music:
1187         complex_music
1188         | music_bare
1189         ;
1190
1191 /* Music that can be parsed without lookahead */
1192 closed_music:
1193         music_bare
1194         | complex_music_prefix closed_music
1195         {
1196                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1197         }
1198         | music_function_call_closed
1199         ;
1200
1201 music_bare:
1202         mode_changed_music
1203         | MUSIC_IDENTIFIER
1204         | grouped_music_list
1205         ;
1206
1207 grouped_music_list:
1208         simultaneous_music              { $$ = $1; }
1209         | sequential_music              { $$ = $1; }
1210         ;
1211
1212 /* An argument list. If a function \foo expects scm scm pitch, then the lexer expands \foo into the token sequence:
1213  MUSIC_FUNCTION EXPECT_PITCH EXPECT_SCM EXPECT_SCM EXPECT_NO_MORE_ARGS
1214 and this rule returns the reversed list of arguments. */
1215
1216 /* Function argument lists come in a number of flavors.  Whenever
1217  * LilyPond has to pick between different flavors, the decision is
1218  * either made because of tokens it has already seen, or it is
1219  * postponed until tokens suitable for making the decision come up.
1220  * For postponing decisions, it may be necessary that the competing
1221  * rules are written in a way making them compatible until a decision
1222  * can be made.  Sometimes this is done by putting common traits into
1223  * a separate "common" rule set.
1224  *
1225  * function_arglist: a full argument list.  Optional arguments at the
1226  * end of the list can only be skipped by writing \default in their
1227  * place.
1228  *
1229  * function_arglist_backup: an argument list ending in an optional
1230  * argument that may be skipped depending on its predicate.
1231  *
1232  * function_arglist_skip: an argument list _not_ ending in an optional
1233  * argument that is actually taken.
1234  *
1235  * function_arglist_nonbackup: an argument list ending in an optional
1236  * argument that may not be skipped because it is in end position and
1237  * has not been shortcircuited with \default.
1238  *
1239  * function_arglist* / function_arglist_closed*: The closed variants
1240  * don't end in simple music expressions that might still accept
1241  * things like a duration or a postevent.
1242  */
1243
1244 function_arglist_skip:
1245         function_arglist_common
1246         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_skip
1247         {
1248                 $$ = scm_cons ($1, $3);
1249         } %prec FUNCTION_ARGLIST
1250         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_skip
1251         {
1252                 $$ = scm_cons ($1, $3);
1253         } %prec FUNCTION_ARGLIST
1254         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip
1255         {
1256                 $$ = scm_cons ($1, $3);
1257         } %prec FUNCTION_ARGLIST
1258         ;
1259
1260
1261 function_arglist_nonbackup_common:
1262         EXPECT_OPTIONAL EXPECT_PITCH function_arglist pitch_also_in_chords {
1263                 $$ = scm_cons ($4, $3);
1264         }
1265         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed duration_length {
1266                 $$ = scm_cons ($4, $3);
1267         }
1268         | EXPECT_OPTIONAL EXPECT_SCM function_arglist FRACTION
1269         {
1270                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1271         }
1272         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed post_event_nofinger
1273         {
1274                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1275         }
1276         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed '-' UNSIGNED
1277         {
1278                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1279                 if (scm_is_true (scm_call_1 ($2, n)))
1280                         $$ = scm_cons (n, $3);
1281                 else {
1282                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1283                         t->set_property ("digit", $5);
1284                         $$ = check_scheme_arg (parser, @4, t->unprotect (),
1285                                                $3, $2, n);
1286                 }
1287
1288         }
1289         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed '-' REAL
1290         {
1291                 $$ = check_scheme_arg (parser, @4,
1292                                        scm_difference ($5, SCM_UNDEFINED),
1293                                        $3, $2);
1294         }
1295         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed '-' NUMBER_IDENTIFIER
1296         {
1297                 $$ = check_scheme_arg (parser, @4,
1298                                        scm_difference ($5, SCM_UNDEFINED),
1299                                        $3, $2);
1300         }
1301         ;
1302
1303 function_arglist_closed_nonbackup:
1304         function_arglist_nonbackup_common
1305         | EXPECT_OPTIONAL EXPECT_SCM function_arglist embedded_scm_arg_closed
1306         {
1307                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1308         }
1309         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed bare_number_closed
1310         {
1311                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1312         }
1313         | EXPECT_OPTIONAL EXPECT_SCM function_arglist SCM_IDENTIFIER
1314         {
1315                 $$ = check_scheme_arg (parser, @4,
1316                                        try_string_variants ($2, $4),
1317                                        $3, $2, $4);
1318         }
1319         | EXPECT_OPTIONAL EXPECT_SCM function_arglist STRING
1320         {
1321                 $$ = check_scheme_arg (parser, @4,
1322                                        try_string_variants ($2, $4),
1323                                        $3, $2, $4);
1324         }
1325         | EXPECT_OPTIONAL EXPECT_SCM function_arglist full_markup
1326         {
1327                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1328         }
1329         ;
1330
1331 symbol_list_arg:
1332         SYMBOL_LIST
1333         | SYMBOL_LIST '.' symbol_list_rev
1334         {
1335                 $$ = scm_append (scm_list_2 ($1, scm_reverse_x ($3, SCM_EOL)));
1336         }
1337         ;
1338
1339 symbol_list_rev:
1340         symbol_list_part
1341         | symbol_list_rev '.' symbol_list_part
1342         {
1343                 $$ = scm_append_x (scm_list_2 ($3, $1));
1344         }
1345         ;
1346
1347 // symbol_list_part delivers elements in reverse copy.
1348
1349 symbol_list_part:
1350         symbol_list_element
1351         {
1352                 SCM sym_l_p = ly_lily_module_constant ("symbol-list?");
1353                 $$ = try_string_variants (sym_l_p, $1);
1354                 if (SCM_UNBNDP ($$)) {
1355                         parser->parser_error (@1, _("not a symbol"));
1356                         $$ = SCM_EOL;
1357                 } else
1358                         $$ = scm_reverse ($$);
1359         }
1360         ;
1361
1362
1363 symbol_list_element:
1364         STRING
1365         | embedded_scm_bare
1366         ;
1367
1368
1369 function_arglist_nonbackup:
1370         function_arglist_nonbackup_common
1371         | EXPECT_OPTIONAL EXPECT_SCM function_arglist embedded_scm_arg
1372         {
1373                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1374         }
1375         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed bare_number
1376         {
1377                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1378         }
1379         | function_arglist_nonbackup_reparse REPARSE SCM_ARG
1380         {
1381                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1382         }
1383         | function_arglist_nonbackup_reparse REPARSE lyric_element_music
1384         {
1385                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1386         }
1387         | function_arglist_nonbackup_reparse REPARSE symbol_list_arg
1388         {
1389                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1390         }
1391         ;
1392
1393 function_arglist_nonbackup_reparse:
1394         EXPECT_OPTIONAL EXPECT_SCM function_arglist SCM_IDENTIFIER
1395         {
1396                 $$ = $3;
1397                 SCM res = try_string_variants ($2, $4);
1398                 if (!SCM_UNBNDP (res))
1399                         if (scm_is_pair (res))
1400                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1401                         else
1402                                 MYREPARSE (@4, $2, SCM_ARG, res);
1403                 else if (scm_is_true
1404                          (scm_call_1
1405                           ($2, make_music_from_simple
1406                            (parser, @4, $4))))
1407                         MYREPARSE (@4, $2, STRING, $4);
1408                 else
1409                         MYREPARSE (@4, $2, SCM_ARG, $4);
1410         }
1411         | EXPECT_OPTIONAL EXPECT_SCM function_arglist STRING
1412         {
1413                 $$ = $3;
1414                 SCM res = try_string_variants ($2, $4);
1415                 if (!SCM_UNBNDP (res))
1416                         if (scm_is_pair (res))
1417                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1418                         else
1419                                 MYREPARSE (@4, $2, SCM_ARG, res);
1420                 else if (scm_is_true
1421                          (scm_call_1
1422                           ($2, make_music_from_simple
1423                            (parser, @4, $4))))
1424                         MYREPARSE (@4, $2, STRING, $4);
1425                 else
1426                         MYREPARSE (@4, $2, SCM_ARG, $4);
1427         }
1428         | EXPECT_OPTIONAL EXPECT_SCM function_arglist full_markup
1429         {
1430                 $$ = $3;
1431                 if (scm_is_true (scm_call_1 ($2, $4)))
1432                         MYREPARSE (@4, $2, SCM_ARG, $4);
1433                 else if (scm_is_true
1434                          (scm_call_1
1435                           ($2, make_music_from_simple
1436                            (parser, @4, $4))))
1437                         MYREPARSE (@4, $2, STRING, $4);
1438                 else
1439                         MYREPARSE (@4, $2, SCM_ARG, $4);
1440         }
1441         ;
1442
1443 function_arglist_keep:
1444         function_arglist_common
1445         | function_arglist_backup
1446         ;
1447
1448 function_arglist_closed_keep:
1449         function_arglist_closed_common
1450         | function_arglist_backup
1451         ;
1452
1453 function_arglist_backup:
1454         EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep embedded_scm_arg_closed
1455         {
1456                 if (scm_is_true (scm_call_1 ($2, $4)))
1457                 {
1458                         $$ = scm_cons ($4, $3);
1459                 } else {
1460                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1461                         MYBACKUP (SCM_ARG, $4, @4);
1462                 }
1463         }
1464         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep post_event_nofinger
1465         {
1466                 if (scm_is_true (scm_call_1 ($2, $4)))
1467                 {
1468                         $$ = scm_cons ($4, $3);
1469                 } else {
1470                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1471                         MYBACKUP (EVENT_IDENTIFIER, $4, @4);
1472                 }
1473         }
1474         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep full_markup
1475         {
1476                 if (scm_is_true (scm_call_1 ($2, $4)))
1477                         $$ = scm_cons ($4, $3);
1478                 else {
1479                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1480                         MYBACKUP (LYRIC_ELEMENT, $4, @4);
1481                 }
1482         }
1483         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep UNSIGNED
1484         {
1485                 if (scm_is_true (scm_call_1 ($2, $4)))
1486                 {
1487                         $$ = $3;
1488                         MYREPARSE (@4, $2, UNSIGNED, $4);
1489                 } else {
1490                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1491                         MYBACKUP (UNSIGNED, $4, @4);
1492                 }
1493         }
1494         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep REAL
1495         {
1496                 if (scm_is_true (scm_call_1 ($2, $4)))
1497                 {
1498                         $$ = $3;
1499                         MYREPARSE (@4, $2, REAL, $4);
1500                 } else {
1501                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1502                         MYBACKUP (REAL, $4, @4);
1503                 }
1504         }
1505         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep NUMBER_IDENTIFIER
1506         {
1507                 if (scm_is_true (scm_call_1 ($2, $4)))
1508                 {
1509                         $$ = scm_cons ($4, $3);
1510                 } else {
1511                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1512                         MYBACKUP (NUMBER_IDENTIFIER, $4, @4);
1513                 }
1514         }
1515         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep FRACTION
1516         {
1517                 if (scm_is_true (scm_call_1 ($2, $4)))
1518                 {
1519                         $$ = scm_cons ($4, $3);
1520                 } else {
1521                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1522                         MYBACKUP (FRACTION, $4, @4);
1523                 }
1524         }
1525         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep '-' UNSIGNED
1526         {
1527                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1528                 if (scm_is_true (scm_call_1 ($2, n))) {
1529                         $$ = $3;
1530                         MYREPARSE (@5, $2, REAL, n);
1531                 } else {
1532                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1533                         t->set_property ("digit", $5);
1534                         $$ = t->unprotect ();
1535                         if (scm_is_true (scm_call_1 ($2, $$)))
1536                                 $$ = scm_cons ($$, $3);
1537                         else {
1538                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1539                                 MYBACKUP (UNSIGNED, $5, @5);
1540                                 parser->lexer_->push_extra_token ('-');
1541                         }
1542                 }
1543
1544         }
1545         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep '-' REAL
1546         {
1547                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1548                 if (scm_is_true (scm_call_1 ($2, n))) {
1549                         MYREPARSE (@5, $2, REAL, n);
1550                         $$ = $3;
1551                 } else {
1552                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1553                         MYBACKUP (REAL, n, @5);
1554                 }
1555         }
1556         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep '-' NUMBER_IDENTIFIER
1557         {
1558                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1559                 if (scm_is_true (scm_call_1 ($2, n))) {
1560                         $$ = scm_cons (n, $3);
1561                 } else {
1562                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1563                         MYBACKUP (NUMBER_IDENTIFIER, n, @5);
1564                 }
1565         }
1566         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_keep pitch_also_in_chords
1567         {
1568                 $$ = scm_cons ($4, $3);
1569         }
1570         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_keep duration_length
1571         {
1572                 $$ = scm_cons ($4, $3);
1573         }
1574         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep SCM_IDENTIFIER
1575         {
1576                 SCM res = try_string_variants ($2, $4);
1577                 if (!SCM_UNBNDP (res))
1578                         if (scm_is_pair (res)) {
1579                                 $$ = $3;
1580                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1581                         }
1582                         else
1583                                 $$ = scm_cons (res, $3);
1584                 else {
1585                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1586                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
1587                 }
1588         }
1589         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep STRING
1590         {
1591                 SCM res = try_string_variants ($2, $4);
1592                 if (!SCM_UNBNDP (res))
1593                         if (scm_is_pair (res)) {
1594                                 $$ = $3;
1595                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1596                         }
1597                         else
1598                                 $$ = scm_cons (res, $3);
1599                 else {
1600                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1601                         MYBACKUP (STRING, $4, @4);
1602                 }
1603         }
1604         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup BACKUP
1605         {
1606                 $$ = scm_cons ($1, $3);
1607                 MYBACKUP(0, SCM_UNDEFINED, @3);
1608         }
1609         | function_arglist_backup REPARSE bare_number
1610         {
1611                 $$ = check_scheme_arg (parser, @3,
1612                                        $3, $1, $2);
1613         }
1614         | function_arglist_backup REPARSE symbol_list_arg
1615         {
1616                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1617         }
1618         ;
1619
1620 function_arglist:
1621         function_arglist_common
1622         | function_arglist_nonbackup
1623         ;
1624
1625 function_arglist_common:
1626         function_arglist_bare
1627         | EXPECT_SCM function_arglist_optional embedded_scm_arg
1628         {
1629                 $$ = check_scheme_arg (parser, @3,
1630                                        $3, $2, $1);
1631         }
1632         | EXPECT_SCM function_arglist_closed_optional bare_number
1633         {
1634                 $$ = check_scheme_arg (parser, @3,
1635                                        $3, $2, $1);
1636         }
1637         | EXPECT_SCM function_arglist_optional FRACTION
1638         {
1639                 $$ = check_scheme_arg (parser, @3,
1640                                        $3, $2, $1);
1641         }
1642         | EXPECT_SCM function_arglist_closed_optional post_event_nofinger
1643         {
1644                 $$ = check_scheme_arg (parser, @3,
1645                                        $3, $2, $1);
1646         }
1647         | EXPECT_SCM function_arglist_closed_optional '-' NUMBER_IDENTIFIER
1648         {
1649                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1650                 $$ = check_scheme_arg (parser, @4, n, $2, $1);
1651         }
1652         | function_arglist_common_reparse REPARSE SCM_ARG
1653         {
1654                 $$ = check_scheme_arg (parser, @3,
1655                                        $3, $1, $2);
1656         }
1657         | function_arglist_common_reparse REPARSE lyric_element_music
1658         {
1659                 $$ = check_scheme_arg (parser, @3,
1660                                        $3, $1, $2);
1661         }
1662         | function_arglist_common_reparse REPARSE bare_number
1663         {
1664                 $$ = check_scheme_arg (parser, @3,
1665                                        $3, $1, $2);
1666         }
1667         | function_arglist_common_reparse REPARSE symbol_list_arg
1668         {
1669                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1670         }
1671         ;
1672
1673 function_arglist_common_reparse:
1674         EXPECT_SCM function_arglist_optional SCM_IDENTIFIER
1675         {
1676                 $$ = $2;
1677                 SCM res = try_string_variants ($1, $3);
1678                 if (!SCM_UNBNDP (res))
1679                         if (scm_is_pair (res))
1680                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
1681                         else
1682                                 MYREPARSE (@3, $1, SCM_ARG, res);
1683                 else if (scm_is_true
1684                          (scm_call_1
1685                           ($1, make_music_from_simple (parser, @3, $3))))
1686                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
1687                 else
1688                         // This is going to flag a syntax error, we
1689                         // know the predicate to be false.
1690                         MYREPARSE (@3, $1, SCM_ARG, $3);
1691         }
1692         | EXPECT_SCM function_arglist_optional STRING
1693         {
1694                 $$ = $2;
1695                 SCM res = try_string_variants ($1, $3);
1696                 if (!SCM_UNBNDP (res))
1697                         if (scm_is_pair (res))
1698                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
1699                         else
1700                                 MYREPARSE (@3, $1, SCM_ARG, res);
1701                 else if (scm_is_true
1702                          (scm_call_1
1703                           ($1, make_music_from_simple (parser, @3, $3))))
1704                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
1705                 else
1706                         // This is going to flag a syntax error, we
1707                         // know the predicate to be false.
1708                         MYREPARSE (@3, $1, SCM_ARG, $3);
1709         }
1710         | EXPECT_SCM function_arglist_optional full_markup
1711         {
1712                 $$ = $2;
1713                 if (scm_is_true (scm_call_1 ($1, $3)))
1714                         MYREPARSE (@3, $1, SCM_ARG, $3);
1715                 else if (scm_is_true
1716                          (scm_call_1
1717                           ($1, make_music_from_simple (parser, @3, $3))))
1718                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
1719                 else
1720                         // This is going to flag a syntax error, we
1721                         // know the predicate to be false.
1722                         MYREPARSE (@3, $1, SCM_ARG, $3);
1723         }
1724         | EXPECT_SCM function_arglist_closed_optional '-' UNSIGNED
1725         {
1726                 $$ = $2;
1727                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1728                 if (scm_is_true (scm_call_1 ($1, n)))
1729                         MYREPARSE (@4, $1, REAL, n);
1730                 else {
1731                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @4);
1732                         t->set_property ("digit", $4);
1733                         SCM m = t->unprotect ();
1734                         if (scm_is_true (scm_call_1 ($1, m)))
1735                                 MYREPARSE (@4, $1, SCM_ARG, m);
1736                         else
1737                                 MYREPARSE (@4, $1, SCM_ARG, $4);
1738                 }
1739
1740         }
1741         | EXPECT_SCM function_arglist_closed_optional '-' REAL
1742         {
1743                 $$ = $2;
1744                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1745                 MYREPARSE (@4, $1, REAL, n);
1746         }
1747         ;
1748
1749 function_arglist_closed:
1750         function_arglist_closed_common
1751         | function_arglist_closed_nonbackup
1752         ;
1753
1754 function_arglist_closed_common:
1755         function_arglist_bare
1756         | EXPECT_SCM function_arglist_optional embedded_scm_arg_closed
1757         {
1758                 $$ = check_scheme_arg (parser, @3,
1759                                        $3, $2, $1);
1760         }
1761         | EXPECT_SCM function_arglist_closed_optional bare_number
1762         {
1763                 $$ = check_scheme_arg (parser, @3,
1764                                        $3, $2, $1);
1765         }
1766         | EXPECT_SCM function_arglist_closed_optional '-' NUMBER_IDENTIFIER
1767         {
1768                 $$ = check_scheme_arg (parser, @3,
1769                                        scm_difference ($4, SCM_UNDEFINED),
1770                                        $2, $1);
1771         }
1772         | EXPECT_SCM function_arglist_closed_optional post_event_nofinger
1773         {
1774                 $$ = check_scheme_arg (parser, @3,
1775                                        $3, $2, $1);
1776         }
1777         | EXPECT_SCM function_arglist_optional FRACTION
1778         {
1779                 $$ = check_scheme_arg (parser, @3,
1780                                        $3, $2, $1);
1781         }
1782         | function_arglist_common_reparse REPARSE SCM_ARG
1783         {
1784                 $$ = check_scheme_arg (parser, @3,
1785                                        $3, $1, $2);
1786         }
1787         | function_arglist_common_reparse REPARSE bare_number
1788         {
1789                 $$ = check_scheme_arg (parser, @3,
1790                                        $3, $1, $2);
1791         }
1792         | function_arglist_common_reparse REPARSE symbol_list_arg
1793         {
1794                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1795         }
1796         ;
1797
1798 function_arglist_optional:
1799         function_arglist_keep %prec FUNCTION_ARGLIST
1800         | function_arglist_backup BACKUP
1801         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_optional
1802         {
1803                 $$ = scm_cons ($1, $3);
1804         }
1805         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_optional
1806         {
1807                 $$ = scm_cons ($1, $3);
1808         }
1809         ;
1810
1811 function_arglist_closed_optional:
1812         function_arglist_closed_keep %prec FUNCTION_ARGLIST
1813         | function_arglist_backup BACKUP
1814         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_closed_optional
1815         {
1816                 $$ = scm_cons ($1, $3);
1817         }
1818         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_optional
1819         {
1820                 $$ = scm_cons ($1, $3);
1821         }
1822         ;
1823
1824 embedded_scm_closed:
1825         embedded_scm_bare
1826         | scm_function_call_closed
1827         ;
1828
1829 embedded_scm_arg_closed:
1830         embedded_scm_bare_arg
1831         | scm_function_call_closed
1832         | closed_music
1833         ;
1834
1835 scm_function_call_closed:
1836         SCM_FUNCTION function_arglist_closed {
1837                 $$ = MAKE_SYNTAX ("music-function", @$,
1838                                          $1, $2);
1839         } %prec FUNCTION_ARGLIST
1840         ;
1841
1842 function_arglist_bare:
1843         EXPECT_NO_MORE_ARGS {
1844                 $$ = SCM_EOL;
1845         }
1846         | EXPECT_PITCH function_arglist_optional pitch_also_in_chords {
1847                 $$ = scm_cons ($3, $2);
1848         }
1849         | EXPECT_DURATION function_arglist_closed_optional duration_length {
1850                 $$ = scm_cons ($3, $2);
1851         }
1852         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_skip DEFAULT {
1853                 $$ = scm_cons ($1, $3);
1854         }
1855         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_skip DEFAULT {
1856                 $$ = scm_cons ($1, $3);
1857         }
1858         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip DEFAULT {
1859                 $$ = scm_cons ($1, $3);
1860         }
1861         ;
1862
1863 music_function_call:
1864         MUSIC_FUNCTION function_arglist {
1865                 $$ = MAKE_SYNTAX ("music-function", @$,
1866                                          $1, $2);
1867         }
1868         ;
1869
1870
1871 optional_id:
1872         /**/ { $$ = SCM_EOL; }
1873         | '=' simple_string {
1874                 $$ = $2;
1875         }
1876         ;
1877
1878 complex_music:
1879         music_function_call
1880         | repeated_music                { $$ = $1; }
1881         | re_rhythmed_music     { $$ = $1; }
1882         | complex_music_prefix music
1883         {
1884                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1885         }
1886         ;
1887
1888 complex_music_prefix:
1889         CONTEXT symbol optional_id optional_context_mod {
1890                 Context_mod *ctxmod = unsmob_context_mod ($4);
1891                 SCM mods = SCM_EOL;
1892                 if (ctxmod)
1893                         mods = ctxmod->get_mods ();
1894                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_F);
1895         }
1896         | NEWCONTEXT symbol optional_id optional_context_mod {
1897                 Context_mod *ctxmod = unsmob_context_mod ($4);
1898                 SCM mods = SCM_EOL;
1899                 if (ctxmod)
1900                         mods = ctxmod->get_mods ();
1901                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_T);
1902         }
1903         ;
1904
1905 mode_changed_music:
1906         mode_changing_head grouped_music_list {
1907                 if ($1 == ly_symbol2scm ("chords"))
1908                 {
1909                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1910                 }
1911                 else
1912                 {
1913                   $$ = $2;
1914                 }
1915                 parser->lexer_->pop_state ();
1916         }
1917         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1918                 Context_mod *ctxmod = unsmob_context_mod ($2);
1919                 SCM mods = SCM_EOL;
1920                 if (ctxmod)
1921                         mods = ctxmod->get_mods ();
1922                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, mods, SCM_BOOL_T, $3);
1923                 if ($1 == ly_symbol2scm ("ChordNames"))
1924                 {
1925                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1926                 }
1927                 parser->lexer_->pop_state ();
1928         }
1929         ;
1930
1931 mode_changing_head:
1932         NOTEMODE {
1933                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
1934                 parser->lexer_->push_note_state (nn);
1935
1936                 $$ = ly_symbol2scm ("notes");
1937         }
1938         | DRUMMODE
1939                 {
1940                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
1941                 parser->lexer_->push_note_state (nn);
1942
1943                 $$ = ly_symbol2scm ("drums");
1944         }
1945         | FIGUREMODE {
1946                 parser->lexer_->push_figuredbass_state ();
1947
1948                 $$ = ly_symbol2scm ("figures");
1949         }
1950         | CHORDMODE {
1951                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
1952                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1953                 nn = parser->lexer_->lookup_identifier ("pitchnames");
1954                 parser->lexer_->push_chord_state (nn);
1955                 $$ = ly_symbol2scm ("chords");
1956
1957         }
1958         | LYRICMODE
1959                 { parser->lexer_->push_lyric_state ();
1960                 $$ = ly_symbol2scm ("lyrics");
1961         }
1962         ;
1963
1964 mode_changing_head_with_context:
1965         DRUMS {
1966                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
1967                 parser->lexer_->push_note_state (nn);
1968
1969                 $$ = ly_symbol2scm ("DrumStaff");
1970         }
1971         | FIGURES {
1972                 parser->lexer_->push_figuredbass_state ();
1973
1974                 $$ = ly_symbol2scm ("FiguredBass");
1975         }
1976         | CHORDS {
1977                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
1978                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1979                 nn = parser->lexer_->lookup_identifier ("pitchnames");
1980                 parser->lexer_->push_chord_state (nn);
1981                 $$ = ly_symbol2scm ("ChordNames");
1982         }
1983         | LYRICS
1984                 { parser->lexer_->push_lyric_state ();
1985                 $$ = ly_symbol2scm ("Lyrics");
1986         }
1987         ;
1988
1989 new_lyrics:
1990         ADDLYRICS { parser->lexer_->push_lyric_state (); }
1991         /*cont */
1992         composite_music {
1993         /* Can also use music at the expensive of two S/Rs similar to
1994            \repeat \alternative */
1995                 parser->lexer_->pop_state ();
1996
1997                 $$ = scm_cons ($3, SCM_EOL);
1998         }
1999         | new_lyrics ADDLYRICS {
2000                 parser->lexer_->push_lyric_state ();
2001         } composite_music {
2002                 parser->lexer_->pop_state ();
2003                 $$ = scm_cons ($4, $1);
2004         }
2005         ;
2006
2007 re_rhythmed_music:
2008         composite_music new_lyrics {
2009                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
2010         } %prec COMPOSITE
2011         | LYRICSTO simple_string {
2012                 parser->lexer_->push_lyric_state ();
2013         } music {
2014                 parser->lexer_->pop_state ();
2015                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
2016         }
2017         ;
2018
2019 context_change:
2020         CHANGE STRING '=' STRING  {
2021                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
2022         }
2023         ;
2024
2025
2026 property_path:
2027         symbol_list_rev  {
2028                 $$ = scm_reverse_x ($1, SCM_EOL);
2029         }
2030         | symbol_list_rev property_path {
2031                 $$ = scm_reverse_x ($1, $2);
2032         }
2033         ;
2034
2035 property_operation:
2036         symbol '=' scalar {
2037                 $$ = scm_list_3 (ly_symbol2scm ("assign"), $1, $3);
2038         }
2039         | UNSET symbol {
2040                 $$ = scm_list_2 (ly_symbol2scm ("unset"), $2);
2041         }
2042         | OVERRIDE property_path '=' scalar {
2043                 if (scm_ilength ($2) < 2) {
2044                         parser->parser_error (@2, _("bad grob property path"));
2045                         $$ = SCM_UNDEFINED;
2046                 } else {
2047                         $$ = scm_cons (ly_symbol2scm ("push"),
2048                                        scm_cons2 (scm_car ($2),
2049                                                   $4,
2050                                                   scm_cdr ($2)));
2051                 }
2052         }
2053         | REVERT revert_arg {
2054                 $$ = scm_cons (ly_symbol2scm ("pop"), $2);
2055         }
2056         ;
2057
2058 // This is all quite awkward for the sake of substantial backward
2059 // compatibility while at the same time allowing a more "natural" form
2060 // of specification not separating grob specification from grob
2061 // property path.  The purpose of this definition of revert_arg is to
2062 // allow the symbol list which specifies grob and property to revert
2063 // to be optionally be split into two parts after the grob (which in
2064 // this case is just the first element of the list).  symbol_list_part
2065 // is only one path component, but it can be parsed without lookahead,
2066 // so we can follow it with a synthetic BACKUP token when needed.  If
2067 // the first symbol_list_part already contains multiple elements (only
2068 // possible if a Scheme expression provides them), we just parse for
2069 // additional elements introduced by '.', which is what the
2070 // SYMBOL_LIST backup in connection with the immediately following
2071 // rule using symbol_list_arg does.
2072 //
2073 // As long as we don't have our coffers filled with both grob and at
2074 // least one grob property specification, the rest of the required
2075 // symbol list chain may be provided either with or without a leading
2076 // dot.  This is for both allowing the traditional
2077 // \revert Accidental #'color
2078 // as well as well as the "naive" form
2079 // \revert Accidental.color
2080
2081 revert_arg:
2082         revert_arg_backup BACKUP symbol_list_arg
2083         {
2084                 $$ = $3;
2085         }
2086         ;
2087
2088 revert_arg_backup:
2089         revert_arg_part
2090         {
2091                 if (scm_is_null ($1)
2092                     || scm_is_null (scm_cdr ($1)))
2093                         MYBACKUP (SCM_ARG, $1, @1);
2094                 else
2095                         MYBACKUP (SYMBOL_LIST, scm_reverse_x ($1, SCM_EOL), @1);
2096         }
2097         ;
2098
2099 // revert_arg_part delivers results in reverse
2100 revert_arg_part:
2101         symbol_list_part
2102         | revert_arg_backup BACKUP SCM_ARG '.' symbol_list_part
2103         {
2104                 $$ = scm_append_x (scm_list_2 ($5, $3));
2105         }
2106         | revert_arg_backup BACKUP SCM_ARG symbol_list_part
2107         {
2108                 $$ = scm_append_x (scm_list_2 ($4, $3));
2109         }
2110         ;
2111
2112 context_def_mod:
2113         CONSISTS { $$ = ly_symbol2scm ("consists"); }
2114         | REMOVE { $$ = ly_symbol2scm ("remove"); }
2115
2116         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
2117         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
2118         | DENIES { $$ = ly_symbol2scm ("denies"); }
2119
2120         | ALIAS { $$ = ly_symbol2scm ("alias"); }
2121         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
2122         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
2123         | NAME { $$ = ly_symbol2scm ("context-name"); }
2124         ;
2125
2126 context_mod:
2127         property_operation { $$ = $1; }
2128         | context_def_mod STRING {
2129                 $$ = scm_list_2 ($1, $2);
2130         }
2131         | context_def_mod embedded_scm
2132         {
2133                 if (!scm_is_string ($2)
2134                     && ly_symbol2scm ("consists") != $1
2135                     && ly_symbol2scm ("remove") != $1)
2136                 {
2137                         $$ = SCM_EOL;
2138                         parser->parser_error (@1, _ ("only \\consists and \\remove take non-string argument."));
2139                 }
2140                 else
2141                 {
2142                         $$ = scm_list_2 ($1, $2);
2143                 }
2144         }
2145         ;
2146
2147 // If defined, at least two members.
2148 grob_prop_spec:
2149         symbol_list_rev
2150         {
2151                 SCM l = scm_reverse_x ($1, SCM_EOL);
2152                 if (scm_is_pair (l)
2153                     && to_boolean
2154                     (scm_object_property (scm_car (l),
2155                                           ly_symbol2scm ("is-grob?"))))
2156                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2157                 if (scm_is_null (l) || scm_is_null (scm_cdr (l))) {
2158                         parser->parser_error (@1, _ ("bad grob property path"));
2159                         l = SCM_UNDEFINED;
2160                 }
2161                 $$ = l;
2162         }
2163         ;
2164
2165 // If defined, at least three members
2166 grob_prop_path:
2167         grob_prop_spec
2168         {
2169                 if (!SCM_UNBNDP ($1) && scm_is_null (scm_cddr ($1)))
2170                 {
2171                         parser->parser_error (@1, _ ("bad grob property path"));
2172                         $$ = SCM_UNDEFINED;
2173                 }
2174         }
2175         | grob_prop_spec property_path
2176         {
2177                 if (!SCM_UNBNDP ($1)) {
2178                         $$ = scm_append_x (scm_list_2 ($1, $2));
2179                         if (scm_is_null (scm_cddr ($$))) {
2180                                 parser->parser_error (@$, _ ("bad grob property path"));
2181                                 $$ = SCM_UNDEFINED;
2182                         }
2183                 }
2184
2185         }
2186         ;
2187
2188 // Exactly two elements or undefined
2189 context_prop_spec:
2190         symbol_list_rev
2191         {
2192                 SCM l = scm_reverse_x ($1, SCM_EOL);
2193                 switch (scm_ilength (l)) {
2194                 case 1:
2195                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2196                 case 2:
2197                         break;
2198                 default:
2199                         parser->parser_error (@1, _ ("bad context property path"));
2200                         l = SCM_UNDEFINED;
2201                 }
2202                 $$ = l;
2203         }
2204         ;
2205
2206 simple_music_property_def:
2207         OVERRIDE grob_prop_path '=' scalar {
2208                 if (SCM_UNBNDP ($2))
2209                         $$ = SCM_UNDEFINED;
2210                 else {
2211                         $$ = scm_list_5 (scm_car ($2),
2212                                          ly_symbol2scm ("OverrideProperty"),
2213                                          scm_cadr ($2),
2214                                          $4,
2215                                          scm_cddr ($2));
2216                 }
2217         }
2218         | REVERT simple_revert_context revert_arg {
2219                 $$ = scm_list_4 ($2,
2220                                  ly_symbol2scm ("RevertProperty"),
2221                                  scm_car ($3),
2222                                  scm_cdr ($3));
2223         }
2224         | SET context_prop_spec '=' scalar {
2225                 if (SCM_UNBNDP ($2))
2226                         $$ = SCM_UNDEFINED;
2227                 else
2228                         $$ = scm_list_4 (scm_car ($2),
2229                                          ly_symbol2scm ("PropertySet"),
2230                                          scm_cadr ($2),
2231                                          $4);
2232         }
2233         | UNSET context_prop_spec {
2234                 if (SCM_UNBNDP ($2))
2235                         $$ = SCM_UNDEFINED;
2236                 else
2237                         $$ = scm_list_3 (scm_car ($2),
2238                                          ly_symbol2scm ("PropertyUnset"),
2239                                          scm_cadr ($2));
2240         }
2241         ;
2242
2243
2244 // This is all quite awkward for the sake of substantial backward
2245 // compatibility while at the same time allowing a more "natural" form
2246 // of specification not separating grob specification from grob
2247 // property path.  The purpose of this definition of
2248 // simple_revert_context is to allow the symbol list which specifies
2249 // grob and property to revert to be optionally be split into two
2250 // parts after the grob (which may be preceded by a context
2251 // specification, a case which we distinguish by checking whether the
2252 // first symbol is a valid grob symbol instead).
2253 //
2254 // See revert_arg above for the main work horse of this arrangement.
2255 // simple_revert_context just caters for the context and delegates the
2256 // rest of the job to revert_arg.
2257
2258 simple_revert_context:
2259         symbol_list_part
2260         {
2261                 $1 = scm_reverse_x ($1, SCM_EOL);
2262                 if (scm_is_null ($1)
2263                     || to_boolean
2264                     (scm_object_property (scm_car ($1),
2265                                           ly_symbol2scm ("is-grob?")))) {
2266                         $$ = ly_symbol2scm ("Bottom");
2267                         parser->lexer_->push_extra_token (SCM_IDENTIFIER, $1);
2268                 } else {
2269                         $$ = scm_car ($1);
2270                         parser->lexer_->push_extra_token (SCM_IDENTIFIER,
2271                                                           scm_cdr ($1));
2272                 }
2273         }
2274         ;
2275
2276 music_property_def:
2277         simple_music_property_def {
2278                 if (SCM_UNBNDP ($1))
2279                         $$ = MAKE_SYNTAX ("void-music", @1);
2280                 else
2281                         $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons2 (parser->self_scm (), make_input (@$), $1));
2282         }
2283         ;
2284
2285 string:
2286         STRING {
2287                 $$ = $1;
2288         }
2289         | full_markup
2290         ;
2291
2292 simple_string: STRING {
2293                 $$ = $1;
2294         }
2295         | embedded_scm_bare
2296         {
2297                 if (scm_is_string ($1)) {
2298                         $$ = $1;
2299                 } else {
2300                         parser->parser_error (@1, (_ ("simple string expected")));
2301                         $$ = scm_string (SCM_EOL);
2302                 }
2303         }
2304         ;
2305
2306 symbol:
2307         STRING {
2308                 $$ = scm_string_to_symbol ($1);
2309         }
2310         | embedded_scm_bare
2311         {
2312                 // This is a bit of overkill but makes the same
2313                 // routine responsible for all symbol interpretations.
2314                 $$ = try_string_variants (ly_lily_module_constant ("symbol?"),
2315                                           $1);
2316                 if (SCM_UNBNDP ($$))
2317                 {
2318                         parser->parser_error (@1, (_ ("symbol expected")));
2319                         // Generate a unique symbol in case it is used
2320                         // for an assignment or similar
2321                         $$ = scm_make_symbol (ly_string2scm ("undefined"));
2322                 }
2323         }
2324         ;
2325
2326 scalar:
2327         embedded_scm_arg
2328         | SCM_IDENTIFIER
2329         | bare_number
2330         // The following is a rather defensive variant of admitting
2331         // negative numbers: the grammar would permit number_factor or
2332         // even number_expression.  However, function arguments allow
2333         // only this simple kind of negative number, so to have things
2334         // like \tweak and \override behave reasonably similar, it
2335         // makes sense to rule out things like -- which are rather an
2336         // accent in function argument contexts.
2337         | '-' bare_number
2338         {
2339                 $$ = scm_difference ($2, SCM_UNDEFINED);
2340         }
2341         | FRACTION
2342         | STRING
2343         | full_markup
2344         ;
2345
2346 scalar_closed:
2347         embedded_scm_arg_closed
2348         | SCM_IDENTIFIER
2349         // for scalar_closed to be an actually closed (no lookahead)
2350         // expression, we'd need to use bare_number_closed here.  It
2351         // turns out that the only use of scalar_closed in TEMPO is
2352         // not of the kind requiring the full closedness criterion.
2353         | bare_number
2354         | '-' bare_number
2355         {
2356                 $$ = scm_difference ($2, SCM_UNDEFINED);
2357         }
2358         | FRACTION
2359         | STRING
2360         | full_markup
2361         ;
2362
2363
2364 event_chord:
2365         simple_element post_events {
2366                 // Let the rhythmic music iterator sort this mess out.
2367                 if (scm_is_pair ($2)) {
2368                         $$ = make_music_from_simple (parser, @1, $1);
2369                         if (unsmob_music ($$))
2370                                 unsmob_music ($$)->set_property ("articulations",
2371                                                                  scm_reverse_x ($2, SCM_EOL));
2372                         else
2373                                 parser->parser_error (@1, _("music expected"));
2374                 }
2375         }
2376         | simple_chord_elements post_events     {
2377                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
2378
2379                 Input i;
2380                 /* why is this giving wrong start location? -ns
2381                  * i = @$; */
2382                 i.set_location (@1, @2);
2383                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
2384         }
2385         | CHORD_REPETITION optional_notemode_duration post_events {
2386                 Input i;
2387                 i.set_location (@1, @3);
2388                 $$ = MAKE_SYNTAX ("repetition-chord", i,
2389                                   $2, scm_reverse_x ($3, SCM_EOL));
2390         }
2391         | MULTI_MEASURE_REST optional_notemode_duration post_events {
2392                 Input i;
2393                 i.set_location (@1, @3);
2394                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
2395                                   scm_reverse_x ($3, SCM_EOL));
2396         }
2397         | command_element
2398         | note_chord_element
2399         ;
2400
2401
2402 note_chord_element:
2403         chord_body optional_notemode_duration post_events
2404         {
2405                 Music *m = unsmob_music ($1);
2406                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
2407                 SCM es = m->get_property ("elements");
2408                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
2409
2410                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
2411                   unsmob_music (scm_car (s))->set_property ("duration", dur);
2412                 es = ly_append2 (es, postevs);
2413
2414                 m-> set_property ("elements", es);
2415                 m->set_spot (@$);
2416                 $$ = m->self_scm ();
2417         }
2418         ;
2419
2420 chord_body:
2421         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
2422         {
2423                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
2424         }
2425         ;
2426
2427 chord_body_elements:
2428         /* empty */             { $$ = SCM_EOL; }
2429         | chord_body_elements chord_body_element {
2430                 if (!SCM_UNBNDP ($2))
2431                         $$ = scm_cons ($2, $1);
2432         }
2433         ;
2434
2435 chord_body_element:
2436         pitch exclamations questions octave_check post_events
2437         {
2438                 bool q = to_boolean ($3);
2439                 bool ex = to_boolean ($2);
2440                 SCM check = $4;
2441                 SCM post = $5;
2442
2443                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2444                 n->set_property ("pitch", $1);
2445                 if (q)
2446                         n->set_property ("cautionary", SCM_BOOL_T);
2447                 if (ex || q)
2448                         n->set_property ("force-accidental", SCM_BOOL_T);
2449
2450                 if (scm_is_pair (post)) {
2451                         SCM arts = scm_reverse_x (post, SCM_EOL);
2452                         n->set_property ("articulations", arts);
2453                 }
2454                 if (scm_is_number (check))
2455                 {
2456                         int q = scm_to_int (check);
2457                         n->set_property ("absolute-octave", scm_from_int (q-1));
2458                 }
2459
2460                 $$ = n->unprotect ();
2461         }
2462         | DRUM_PITCH post_events {
2463                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2464                 n->set_property ("drum-type", $1);
2465
2466                 if (scm_is_pair ($2)) {
2467                         SCM arts = scm_reverse_x ($2, SCM_EOL);
2468                         n->set_property ("articulations", arts);
2469                 }
2470                 $$ = n->unprotect ();
2471         }
2472         | music_function_chord_body
2473         {
2474                 Music *m = unsmob_music ($1);
2475
2476                 while (m && m->is_mus_type ("music-wrapper-music")) {
2477                         $$ = m->get_property ("element");
2478                         m = unsmob_music ($$);
2479                 }
2480
2481                 if (!(m && m->is_mus_type ("rhythmic-event"))) {
2482                         parser->parser_error (@$, _ ("not a rhythmic event"));
2483                         $$ = SCM_UNDEFINED;
2484                 }
2485         }
2486         ;
2487
2488 music_function_chord_body:
2489         music_function_call
2490         | MUSIC_IDENTIFIER
2491         ;
2492
2493 // Event functions may only take closed arglists, otherwise it would
2494 // not be clear whether a following postevent should be associated
2495 // with the last argument of the event function or with the expression
2496 // for which the function call acts itself as event.
2497
2498 music_function_call_closed:
2499         MUSIC_FUNCTION function_arglist_closed {
2500                 $$ = MAKE_SYNTAX ("music-function", @$,
2501                                          $1, $2);
2502         }
2503         ;
2504
2505 event_function_event:
2506         EVENT_FUNCTION function_arglist_closed {
2507                 $$ = MAKE_SYNTAX ("music-function", @$,
2508                                          $1, $2);
2509         }
2510         ;
2511
2512 command_element:
2513         command_event {
2514                 $$ = $1;
2515         }
2516         ;
2517
2518 command_event:
2519         tempo_event {
2520                 $$ = $1;
2521         }
2522         ;
2523
2524
2525 post_events:
2526         /* empty */ {
2527                 $$ = SCM_EOL;
2528         }
2529         | post_events post_event {
2530                 $$ = $1;
2531                 if (Music *m = unsmob_music ($2))
2532                 {
2533                         if (m->is_mus_type ("post-event-wrapper"))
2534                         {
2535                                 for (SCM p = m->get_property ("elements");
2536                                      scm_is_pair (p);
2537                                      p = scm_cdr (p))
2538                                 {
2539                                         $$ = scm_cons (scm_car (p), $$);
2540                                 }
2541                         } else {
2542                                 m->set_spot (@2);
2543                                 $$ = scm_cons ($2, $$);
2544                         }
2545                 }
2546         }
2547         ;
2548
2549 post_event_nofinger:
2550         direction_less_event {
2551                 $$ = $1;
2552         }
2553         | script_dir music_function_call_closed {
2554                 $$ = $2;
2555                 if (!unsmob_music ($2)->is_mus_type ("post-event")) {
2556                         parser->parser_error (@2, _ ("post-event expected"));
2557                         $$ = SCM_UNSPECIFIED;
2558                 } else if (!SCM_UNBNDP ($1))
2559                 {
2560                         unsmob_music ($$)->set_property ("direction", $1);
2561                 }
2562         }
2563         | HYPHEN {
2564                 if (!parser->lexer_->is_lyric_state ())
2565                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2566                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
2567         }
2568         | EXTENDER {
2569                 if (!parser->lexer_->is_lyric_state ())
2570                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2571                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
2572         }
2573         | script_dir direction_reqd_event {
2574                 if (!SCM_UNBNDP ($1))
2575                 {
2576                         Music *m = unsmob_music ($2);
2577                         m->set_property ("direction", $1);
2578                 }
2579                 $$ = $2;
2580         }
2581         | script_dir direction_less_event {
2582                 if (!SCM_UNBNDP ($1))
2583                 {
2584                         Music *m = unsmob_music ($2);
2585                         m->set_property ("direction", $1);
2586                 }
2587                 $$ = $2;
2588         }
2589         | '^' fingering
2590         {
2591                 $$ = $2;
2592                 unsmob_music ($$)->set_property ("direction", scm_from_int (UP));
2593         }
2594         | '_' fingering
2595         {
2596                 $$ = $2;
2597                 unsmob_music ($$)->set_property ("direction", scm_from_int (DOWN));
2598         }
2599         ;
2600
2601 post_event:
2602         post_event_nofinger
2603         | '-' fingering {
2604                 $$ = $2;
2605         }
2606         ;
2607
2608 string_number_event:
2609         E_UNSIGNED {
2610                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
2611                 s->set_property ("string-number", $1);
2612                 $$ = s->unprotect ();
2613         }
2614         ;
2615
2616 direction_less_event:
2617         string_number_event
2618         | EVENT_IDENTIFIER      {
2619                 $$ = $1;
2620         }
2621         | tremolo_type  {
2622                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
2623                a->set_property ("tremolo-type", $1);
2624                $$ = a->unprotect ();
2625         }
2626         | event_function_event
2627         ;
2628
2629 direction_reqd_event:
2630         gen_text_def {
2631                 $$ = $1;
2632         }
2633         | script_abbreviation {
2634                 SCM s = parser->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
2635                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
2636                 if (scm_is_string (s))
2637                         a->set_property ("articulation-type", s);
2638                 else parser->parser_error (@1, _ ("expecting string as script definition"));
2639                 $$ = a->unprotect ();
2640         }
2641         ;
2642
2643 octave_check:
2644         /**/ { $$ = SCM_EOL; }
2645         | '=' quotes { $$ = $2; }
2646         ;
2647
2648 quotes:
2649         /* empty */
2650         {
2651                 $$ = SCM_INUM0;
2652         }
2653         | sub_quotes
2654         | sup_quotes
2655         ;
2656
2657 sup_quotes:
2658         '\'' {
2659                 $$ = scm_from_int (1);
2660         }
2661         | sup_quotes '\'' {
2662                 $$ = scm_oneplus ($1);
2663         }
2664         ;
2665
2666 sub_quotes:
2667         ',' {
2668                 $$ = scm_from_int (-1);
2669         }
2670         | sub_quotes ',' {
2671                 $$ = scm_oneminus ($1);
2672         }
2673         ;
2674
2675 steno_pitch:
2676         NOTENAME_PITCH quotes {
2677                 if (!scm_is_eq (SCM_INUM0, $2))
2678                 {
2679                         Pitch p = *unsmob_pitch ($1);
2680                         p = p.transposed (Pitch (scm_to_int ($2),0,0));
2681                         $$ = p.smobbed_copy ();
2682                 }
2683         }
2684         ;
2685
2686 /*
2687 ugh. duplication
2688 */
2689
2690 steno_tonic_pitch:
2691         TONICNAME_PITCH quotes {
2692                 if (!scm_is_eq (SCM_INUM0, $2))
2693                 {
2694                         Pitch p = *unsmob_pitch ($1);
2695                         p = p.transposed (Pitch (scm_to_int ($2),0,0));
2696                         $$ = p.smobbed_copy ();
2697                 }
2698         }
2699         ;
2700
2701 pitch:
2702         steno_pitch
2703         | PITCH_IDENTIFIER
2704         ;
2705
2706 pitch_also_in_chords:
2707         pitch
2708         | steno_tonic_pitch
2709         ;
2710
2711 gen_text_def:
2712         full_markup {
2713                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2714                 t->set_property ("text", $1);
2715                 $$ = t->unprotect ();
2716         }
2717         | STRING {
2718                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2719                 t->set_property ("text",
2720                         make_simple_markup ($1));
2721                 $$ = t->unprotect ();
2722         }
2723         | embedded_scm_closed
2724         {
2725                 Music *m = unsmob_music ($1);
2726                 if (m && m->is_mus_type ("post-event"))
2727                         $$ = $1;
2728                 else if (Text_interface::is_markup ($1)) {
2729                         Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2730                         t->set_property ("text", $1);
2731                         $$ = t->unprotect ();
2732                 } else
2733                         parser->parser_error (@1, _ ("not an articulation"));
2734         }
2735         ;
2736
2737 fingering:
2738         UNSIGNED {
2739                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
2740                 t->set_property ("digit", $1);
2741                 $$ = t->unprotect ();
2742         }
2743         ;
2744
2745 script_abbreviation:
2746         '^'             {
2747                 $$ = scm_from_locale_string ("Hat");
2748         }
2749         | '+'           {
2750                 $$ = scm_from_locale_string ("Plus");
2751         }
2752         | '-'           {
2753                 $$ = scm_from_locale_string ("Dash");
2754         }
2755         | '!'           {
2756                 $$ = scm_from_locale_string ("Bang");
2757         }
2758         | ANGLE_CLOSE   {
2759                 $$ = scm_from_locale_string ("Larger");
2760         }
2761         | '.'           {
2762                 $$ = scm_from_locale_string ("Dot");
2763         }
2764         | '_' {
2765                 $$ = scm_from_locale_string ("Underscore");
2766         }
2767         ;
2768
2769 script_dir:
2770         '_'     { $$ = scm_from_int (DOWN); }
2771         | '^'   { $$ = scm_from_int (UP); }
2772         | '-'   { $$ = SCM_UNDEFINED; }
2773         ;
2774
2775 duration_length:
2776         multiplied_duration {
2777                 $$ = $1;
2778         }
2779         ;
2780
2781 maybe_notemode_duration:
2782         {
2783                 $$ = SCM_UNDEFINED;
2784         }
2785         | multiplied_duration   {
2786                 $$ = $1;
2787                 parser->default_duration_ = *unsmob_duration ($$);
2788         }
2789 ;
2790
2791
2792 optional_notemode_duration:
2793         maybe_notemode_duration
2794         {
2795                 if (SCM_UNBNDP ($$))
2796                         $$ = parser->default_duration_.smobbed_copy ();
2797         }
2798         ;
2799
2800 steno_duration:
2801         UNSIGNED dots           {
2802                 int len = 0;
2803                 int n = scm_to_int ($1);
2804                 if (!is_duration (n))
2805                         parser->parser_error (@1, _f ("not a duration: %d", n));
2806                 else
2807                         len = intlog2 (n);
2808
2809                 $$ = Duration (len, scm_to_int ($2)).smobbed_copy ();
2810         }
2811         | DURATION_IDENTIFIER dots      {
2812                 Duration *d = unsmob_duration ($1);
2813                 Duration k (d->duration_log (),
2814                             d->dot_count () + scm_to_int ($2));
2815                 k = k.compressed (d->factor ());
2816                 scm_remember_upto_here_1 ($1);
2817                 $$ = k.smobbed_copy ();
2818         }
2819         ;
2820
2821 multiplied_duration:
2822         steno_duration {
2823                 $$ = $1;
2824         }
2825         | multiplied_duration '*' UNSIGNED {
2826                 $$ = unsmob_duration ($$)->compressed (scm_to_int ($3)).smobbed_copy ();
2827         }
2828         | multiplied_duration '*' FRACTION {
2829                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2830
2831                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2832         }
2833         ;
2834
2835 dots:
2836         /* empty */     {
2837                 $$ = SCM_INUM0;
2838         }
2839         | dots '.' {
2840                 $$ = scm_oneplus ($1);
2841         }
2842         ;
2843
2844 tremolo_type:
2845         ':'     {
2846                 $$ = SCM_INUM0;
2847         }
2848         | ':' UNSIGNED {
2849                 int n = scm_to_int ($2);
2850                 if (!is_duration (n))
2851                         parser->parser_error (@2, _f ("not a duration: %d", n));
2852                 $$ = $2;
2853         }
2854         ;
2855
2856 bass_number:
2857         UNSIGNED { $$ = $1; }
2858         | STRING { $$ = $1; }
2859         | full_markup { $$ = $1; }
2860         | embedded_scm_bare
2861         {
2862                 // as an integer, it needs to be non-negative, and otherwise
2863                 // it needs to be suitable as a markup.
2864                 if (scm_is_integer ($1)
2865                     ? scm_is_true (scm_negative_p ($1))
2866                     : !Text_interface::is_markup ($1))
2867                 {
2868                         parser->parser_error (@1, _ ("bass number expected"));
2869                         $$ = SCM_INUM0;
2870                 }
2871         }
2872         ;
2873
2874 figured_bass_alteration:
2875         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
2876         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
2877         | '!'   { $$ = scm_from_int (0); }
2878         ;
2879
2880 bass_figure:
2881         FIGURE_SPACE {
2882                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2883                 $$ = bfr->unprotect ();
2884         }
2885         | bass_number  {
2886                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2887                 $$ = bfr->self_scm ();
2888
2889                 if (scm_is_number ($1))
2890                         bfr->set_property ("figure", $1);
2891                 else if (Text_interface::is_markup ($1))
2892                         bfr->set_property ("text", $1);
2893
2894                 bfr->unprotect ();
2895         }
2896         | bass_figure ']' {
2897                 $$ = $1;
2898                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2899         }
2900         | bass_figure figured_bass_alteration {
2901                 Music *m = unsmob_music ($1);
2902                 if (scm_to_double ($2)) {
2903                         SCM salter = m->get_property ("alteration");
2904                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
2905                         m->set_property ("alteration",
2906                                          scm_sum (alter, $2));
2907                 } else {
2908                         m->set_property ("alteration", scm_from_int (0));
2909                 }
2910         }
2911         | bass_figure figured_bass_modification  {
2912                 Music *m = unsmob_music ($1);
2913                 m->set_property ($2, SCM_BOOL_T);
2914         }
2915         ;
2916
2917
2918 figured_bass_modification:
2919         E_PLUS          {
2920                 $$ = ly_symbol2scm ("augmented");
2921         }
2922         | E_EXCLAMATION {
2923                 $$ = ly_symbol2scm ("no-continuation");
2924         }
2925         | '/'           {
2926                 $$ = ly_symbol2scm ("diminished");
2927         }
2928         | E_BACKSLASH {
2929                 $$ = ly_symbol2scm ("augmented-slash");
2930         }
2931         ;
2932
2933 br_bass_figure:
2934         bass_figure {
2935                 $$ = $1;
2936         }
2937         | '[' bass_figure {
2938                 $$ = $2;
2939                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2940         }
2941         ;
2942
2943 figure_list:
2944         /**/            {
2945                 $$ = SCM_EOL;
2946         }
2947         | figure_list br_bass_figure {
2948                 $$ = scm_cons ($2, $1);
2949         }
2950         ;
2951
2952 figure_spec:
2953         FIGURE_OPEN figure_list FIGURE_CLOSE {
2954                 $$ = scm_reverse_x ($2, SCM_EOL);
2955         }
2956         ;
2957
2958
2959 optional_rest:
2960         /**/   { $$ = SCM_BOOL_F; }
2961         | REST { $$ = SCM_BOOL_T; }
2962         ;
2963
2964 simple_element:
2965         pitch exclamations questions octave_check maybe_notemode_duration optional_rest {
2966                 if (!parser->lexer_->is_note_state ())
2967                         parser->parser_error (@1, _ ("have to be in Note mode for notes"));
2968                 if (!SCM_UNBNDP ($2)
2969                     || !SCM_UNBNDP ($3)
2970                     || scm_is_number ($4)
2971                     || !SCM_UNBNDP ($5)
2972                     || scm_is_true ($6))
2973                 {
2974                         Music *n = 0;
2975                         if (scm_is_true ($6))
2976                                 n = MY_MAKE_MUSIC ("RestEvent", @$);
2977                         else
2978                                 n = MY_MAKE_MUSIC ("NoteEvent", @$);
2979
2980                         n->set_property ("pitch", $1);
2981                         if (SCM_UNBNDP ($5))
2982                                 n->set_property ("duration",
2983                                                  parser->default_duration_.smobbed_copy ());
2984                         else
2985                                 n->set_property ("duration", $5);
2986
2987                         if (scm_is_number ($4))
2988                         {
2989                                 int q = scm_to_int ($4);
2990                                 n->set_property ("absolute-octave", scm_from_int (q-1));
2991                         }
2992
2993                         if (to_boolean ($3))
2994                                 n->set_property ("cautionary", SCM_BOOL_T);
2995                         if (to_boolean ($2) || to_boolean ($3))
2996                                 n->set_property ("force-accidental", SCM_BOOL_T);
2997
2998                         $$ = n->unprotect ();
2999                 }
3000         }
3001         | DRUM_PITCH optional_notemode_duration {
3002                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
3003                 n->set_property ("duration", $2);
3004                 n->set_property ("drum-type", $1);
3005
3006                 $$ = n->unprotect ();
3007         }
3008         | RESTNAME optional_notemode_duration           {
3009                 Music *ev = 0;
3010                 if (ly_scm2string ($1) == "s") {
3011                         /* Space */
3012                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
3013                   }
3014                 else {
3015                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
3016
3017                     }
3018                 ev->set_property ("duration", $2);
3019                 $$ = ev->unprotect ();
3020         }
3021         ;
3022
3023 simple_chord_elements:
3024         new_chord {
3025                 if (!parser->lexer_->is_chord_state ())
3026                         parser->parser_error (@1, _ ("have to be in Chord mode for chords"));
3027                 $$ = $1;
3028         }
3029         | figure_spec optional_notemode_duration {
3030                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
3031                 {
3032                         unsmob_music (scm_car (s))->set_property ("duration", $2);
3033                 }
3034                 $$ = $1;
3035         }
3036         ;
3037
3038 lyric_element:
3039         full_markup {
3040                 if (!parser->lexer_->is_lyric_state ())
3041                         parser->parser_error (@1, _ ("markup outside of text script or \\lyricmode"));
3042                 $$ = $1;
3043         }
3044         | STRING {
3045                 if (!parser->lexer_->is_lyric_state ())
3046                         parser->parser_error (@1, _ ("unrecognized string, not in text script or \\lyricmode"));
3047                 $$ = $1;
3048         }
3049         | LYRIC_ELEMENT
3050         ;
3051
3052 lyric_element_music:
3053         lyric_element optional_notemode_duration post_events {
3054                 $$ = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
3055                 if (scm_is_pair ($3))
3056                         unsmob_music ($$)->set_property
3057                                 ("articulations", scm_reverse_x ($3, SCM_EOL));
3058         }
3059         ;
3060
3061 new_chord:
3062         steno_tonic_pitch optional_notemode_duration   {
3063                 $$ = make_chord_elements (@$, $1, $2, SCM_EOL);
3064         }
3065         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
3066                 SCM its = scm_reverse_x ($4, SCM_EOL);
3067                 $$ = make_chord_elements (@$, $1, $2, scm_cons ($3, its));
3068         }
3069         ;
3070
3071 chord_items:
3072         /**/ {
3073                 $$ = SCM_EOL;
3074         }
3075         | chord_items chord_item {
3076                 $$ = scm_cons ($2, $$);
3077         }
3078         ;
3079
3080 chord_separator:
3081         CHORD_COLON {
3082                 $$ = ly_symbol2scm ("chord-colon");
3083         }
3084         | CHORD_CARET {
3085                 $$ = ly_symbol2scm ("chord-caret");
3086         }
3087         | CHORD_SLASH steno_tonic_pitch {
3088                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
3089         }
3090         | CHORD_BASS steno_tonic_pitch {
3091                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
3092         }
3093         ;
3094
3095 chord_item:
3096         chord_separator {
3097                 $$ = $1;
3098         }
3099         | step_numbers {
3100                 $$ = scm_reverse_x ($1, SCM_EOL);
3101         }
3102         | CHORD_MODIFIER  {
3103                 $$ = $1;
3104         }
3105         ;
3106
3107 step_numbers:
3108         step_number { $$ = scm_cons ($1, SCM_EOL); }
3109         | step_numbers '.' step_number {
3110                 $$ = scm_cons ($3, $$);
3111         }
3112         ;
3113
3114 step_number:
3115         UNSIGNED {
3116                 $$ = make_chord_step ($1, 0);
3117         }
3118         | UNSIGNED '+' {
3119                 $$ = make_chord_step ($1, SHARP_ALTERATION);
3120         }
3121         | UNSIGNED CHORD_MINUS {
3122                 $$ = make_chord_step ($1, FLAT_ALTERATION);
3123         }
3124         ;
3125
3126 tempo_range:
3127         UNSIGNED {
3128                 $$ = $1;
3129         }
3130         | UNSIGNED '-' UNSIGNED {
3131                 $$ = scm_cons ($1, $3);
3132         }
3133         ;
3134
3135 /*
3136         UTILITIES
3137
3138 TODO: should deprecate in favor of Scheme?
3139
3140  */
3141 number_expression:
3142         number_expression '+' number_term {
3143                 $$ = scm_sum ($1, $3);
3144         }
3145         | number_expression '-' number_term {
3146                 $$ = scm_difference ($1, $3);
3147         }
3148         | number_term
3149         ;
3150
3151 number_term:
3152         number_factor {
3153                 $$ = $1;
3154         }
3155         | number_factor '*' number_factor {
3156                 $$ = scm_product ($1, $3);
3157         }
3158         | number_factor '/' number_factor {
3159                 $$ = scm_divide ($1, $3);
3160         }
3161         ;
3162
3163 number_factor:
3164         '-'  number_factor { /* %prec UNARY_MINUS */
3165                 $$ = scm_difference ($2, SCM_UNDEFINED);
3166         }
3167         | bare_number
3168         ;
3169
3170
3171 bare_number:
3172         bare_number_closed
3173         | UNSIGNED NUMBER_IDENTIFIER    {
3174                 $$ = scm_product ($1, $2);
3175         }
3176         | REAL NUMBER_IDENTIFIER        {
3177                 $$ = scm_product ($1, $2);
3178         }
3179         ;
3180
3181 bare_number_closed:
3182         UNSIGNED
3183         | REAL
3184         | NUMBER_IDENTIFIER
3185         ;
3186
3187 unsigned_number:
3188         UNSIGNED
3189         | NUMBER_IDENTIFIER
3190         ;
3191
3192 exclamations:
3193                 { $$ = SCM_UNDEFINED; }
3194         | exclamations '!'
3195         {
3196                 if (SCM_UNBNDP ($1))
3197                         $$ = SCM_BOOL_T;
3198                 else
3199                         $$ = scm_not ($1);
3200         }
3201         ;
3202
3203 questions:
3204         { $$ = SCM_UNDEFINED; }
3205         | questions '?'
3206         {
3207                 if (SCM_UNBNDP ($1))
3208                         $$ = SCM_BOOL_T;
3209                 else
3210                         $$ = scm_not ($1);
3211         }
3212         ;
3213
3214 full_markup_list:
3215         MARKUPLIST
3216                 { parser->lexer_->push_markup_state (); }
3217         markup_list {
3218                 $$ = $3;
3219                 parser->lexer_->pop_state ();
3220         }
3221         ;
3222
3223 full_markup:
3224         MARKUP
3225                 { parser->lexer_->push_markup_state (); }
3226         markup_top {
3227                 $$ = $3;
3228                 parser->lexer_->pop_state ();
3229         }
3230         ;
3231
3232 markup_top:
3233         simple_markup_list {
3234                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
3235         }
3236         | markup_head_1_list simple_markup
3237         {
3238                 $$ = scm_car (MAKE_SYNTAX ("composed-markup-list",
3239                                            @2, $1, scm_list_1 ($2)));
3240         }
3241         | simple_markup {
3242                 $$ = $1;
3243         }
3244         ;
3245
3246 markup_scm:
3247         embedded_scm_bare
3248         {
3249                 if (Text_interface::is_markup ($1))
3250                         MYBACKUP (MARKUP_IDENTIFIER, $1, @1);
3251                 else if (Text_interface::is_markup_list ($1))
3252                         MYBACKUP (MARKUPLIST_IDENTIFIER, $1, @1);
3253                 else {
3254                         parser->parser_error (@1, _ ("not a markup"));
3255                         MYBACKUP (MARKUP_IDENTIFIER, scm_string (SCM_EOL), @1);
3256                 }
3257         } BACKUP
3258         ;
3259
3260
3261 simple_markup_list:
3262         markup_composed_list {
3263                 $$ = $1;
3264         }
3265         | markup_uncomposed_list
3266         ;
3267
3268 markup_uncomposed_list:
3269         markup_braced_list {
3270                 $$ = $1;
3271         }
3272         | markup_command_list {
3273                 $$ = scm_list_1 ($1);
3274         }
3275         | markup_scm MARKUPLIST_IDENTIFIER
3276         {
3277                 $$ = $2;
3278         }
3279         ;
3280
3281 markup_list:
3282         simple_markup_list
3283         | markup_score
3284         {
3285                 $$ = scm_list_1 (scm_list_2 (ly_lily_module_constant ("score-lines-markup-list"), $1));
3286         }
3287         ;
3288
3289 markup_score:
3290         SCORE {
3291                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
3292                 parser->lexer_->push_note_state (nn);
3293         } '{' score_body '}' {
3294                 $$ = $4;
3295                 parser->lexer_->pop_state ();
3296         }
3297         ;
3298
3299 markup_composed_list:
3300         markup_head_1_list markup_uncomposed_list {
3301                 $$ = MAKE_SYNTAX ("composed-markup-list",
3302                                   @2, $1, $2);
3303         }
3304         ;
3305
3306 markup_braced_list:
3307         '{' markup_braced_list_body '}' {
3308                 $$ = scm_reverse_x ($2, SCM_EOL);
3309         }
3310         ;
3311
3312 markup_braced_list_body:
3313         /* empty */     {  $$ = SCM_EOL; }
3314         | markup_braced_list_body markup {
3315                 $$ = scm_cons ($2, $1);
3316         }
3317         | markup_braced_list_body simple_markup_list {
3318                 $$ = scm_reverse_x ($2, $1);
3319         }
3320         ;
3321
3322 markup_command_list:
3323         MARKUP_LIST_FUNCTION markup_command_list_arguments {
3324           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
3325         }
3326         ;
3327
3328 markup_command_basic_arguments:
3329         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
3330           $$ = scm_cons ($3, $2);
3331         }
3332         | EXPECT_SCM markup_command_list_arguments embedded_scm_closed {
3333           $$ = check_scheme_arg (parser, @3, $3, $2, $1);
3334         }
3335         | EXPECT_NO_MORE_ARGS {
3336           $$ = SCM_EOL;
3337         }
3338         ;
3339
3340 markup_command_list_arguments:
3341         markup_command_basic_arguments { $$ = $1; }
3342         | EXPECT_MARKUP markup_command_list_arguments markup {
3343           $$ = scm_cons ($3, $2);
3344         }
3345         ;
3346
3347 markup_head_1_item:
3348         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
3349           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
3350         }
3351         ;
3352
3353 markup_head_1_list:
3354         markup_head_1_item      {
3355                 $$ = scm_list_1 ($1);
3356         }
3357         | markup_head_1_list markup_head_1_item {
3358                 $$ = scm_cons ($2, $1);
3359         }
3360         ;
3361
3362 simple_markup:
3363         STRING {
3364                 $$ = make_simple_markup ($1);
3365         }
3366         | MARKUP_FUNCTION markup_command_basic_arguments {
3367                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
3368         }
3369         | markup_scm MARKUP_IDENTIFIER
3370         {
3371                 $$ = $2;
3372         }
3373         | markup_score
3374         {
3375                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), $1);
3376         }
3377         ;
3378
3379 markup:
3380         markup_head_1_list simple_markup
3381         {
3382                 $$ = scm_car (MAKE_SYNTAX ("composed-markup-list",
3383                                            @2, $1, scm_list_1 ($2)));
3384         }
3385         | simple_markup {
3386                 $$ = $1;
3387         }
3388         ;
3389
3390 %%
3391
3392 void
3393 Lily_parser::set_yydebug (bool x)
3394 {
3395         yydebug = x;
3396 }
3397
3398 SCM
3399 Lily_parser::do_yyparse ()
3400 {
3401         SCM retval = SCM_UNDEFINED;
3402         yyparse (this, &retval);
3403         return retval;
3404 }
3405
3406
3407
3408
3409
3410 /*
3411
3412 It is a little strange to have this function in this file, but
3413 otherwise, we have to import music classes into the lexer.
3414
3415 */
3416 int
3417 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
3418 {
3419         if (unsmob_book (sid)) {
3420                 Book *book =  unsmob_book (sid)->clone ();
3421                 *destination = book->self_scm ();
3422                 book->unprotect ();
3423
3424                 return BOOK_IDENTIFIER;
3425         } else if (scm_is_number (sid)) {
3426                 *destination = sid;
3427                 return NUMBER_IDENTIFIER;
3428         } else if (unsmob_context_def (sid)) {
3429                 Context_def *def= unsmob_context_def (sid)->clone ();
3430
3431                 *destination = def->self_scm ();
3432                 def->unprotect ();
3433
3434                 return CONTEXT_DEF_IDENTIFIER;
3435         } else if (unsmob_context_mod (sid)) {
3436                 *destination = unsmob_context_mod (sid)->smobbed_copy ();
3437
3438                 return CONTEXT_MOD_IDENTIFIER;
3439         } else if (Music *mus = unsmob_music (sid)) {
3440                 mus = mus->clone ();
3441                 *destination = mus->self_scm ();
3442                 bool is_event = mus->is_mus_type ("post-event");
3443                 mus->unprotect ();
3444                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
3445         } else if (unsmob_pitch (sid)) {
3446                 *destination = unsmob_pitch (sid)->smobbed_copy ();
3447                 return PITCH_IDENTIFIER;
3448         } else if (unsmob_duration (sid)) {
3449                 *destination = unsmob_duration (sid)->smobbed_copy ();
3450                 return DURATION_IDENTIFIER;
3451         } else if (unsmob_output_def (sid)) {
3452                 Output_def *p = unsmob_output_def (sid);
3453                 p = p->clone ();
3454
3455                 *destination = p->self_scm ();
3456                 p->unprotect ();
3457                 return OUTPUT_DEF_IDENTIFIER;
3458         }
3459
3460         return -1;
3461 }
3462
3463 SCM
3464 get_next_unique_context_id ()
3465 {
3466         return scm_from_locale_string ("$uniqueContextId");
3467 }
3468
3469
3470 SCM
3471 get_next_unique_lyrics_context_id ()
3472 {
3473         static int new_context_count;
3474         char s[128];
3475         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
3476         return scm_from_locale_string (s);
3477 }
3478
3479 // check_scheme_arg checks one argument with a given predicate for use
3480 // in an argument list and throws a syntax error if it is unusable.
3481 // The argument is prepended to the argument list in any case.  After
3482 // throwing a syntax error, the argument list is terminated with #f as
3483 // its last cdr in order to mark it as uncallable while not losing
3484 // track of its total length.
3485 //
3486 // There are a few special considerations: if optional argument disp
3487 // is given (otherwise it defaults to SCM_UNDEFINED), it will be used
3488 // instead of arg in a prospective error message.  This is useful if
3489 // arg is not the actual argument but rather a transformation of it.
3490 //
3491 // If arg itself is SCM_UNDEFINED, the predicate is considered false
3492 // and an error message using disp is produced unconditionally.
3493
3494 SCM check_scheme_arg (Lily_parser *parser, Input loc,
3495                       SCM arg, SCM args, SCM pred, SCM disp)
3496 {
3497         if (SCM_UNBNDP (arg))
3498                 args = scm_cons (disp, args);
3499         else {
3500                 args = scm_cons (arg, args);
3501                 if (scm_is_true (scm_call_1 (pred, arg)))
3502                         return args;
3503         }
3504         scm_set_cdr_x (scm_last_pair (args), SCM_EOL);
3505         MAKE_SYNTAX ("argument-error", loc, scm_length (args), pred,
3506                      SCM_UNBNDP (disp) ? arg : disp);
3507         scm_set_cdr_x (scm_last_pair (args), SCM_BOOL_F);
3508         return args;
3509 }
3510
3511 SCM loc_on_music (Input loc, SCM arg)
3512 {
3513         if (Music *m = unsmob_music (arg))
3514         {
3515                 m = m->clone ();
3516                 m->set_spot (loc);
3517                 return m->unprotect ();
3518         }
3519         return arg;
3520 }
3521
3522 SCM
3523 try_string_variants (SCM pred, SCM str)
3524 {
3525         // a matching predicate is always ok
3526         if (scm_is_true (scm_call_1 (pred, str)))
3527                 return str;
3528         // a symbol may be interpreted as a list of symbols if it helps
3529         if (scm_is_symbol (str)) {
3530                 str = scm_list_1 (str);
3531                 if (scm_is_true (scm_call_1 (pred, str)))
3532                         return str;
3533                 return SCM_UNDEFINED;
3534         }
3535
3536         // If this cannot be a string representation of a symbol list,
3537         // we are through.
3538
3539         if (!is_regular_identifier (str, true))
3540                 return SCM_UNDEFINED;
3541
3542         str = scm_string_split (str, SCM_MAKE_CHAR ('.'));
3543         for (SCM p = str; scm_is_pair (p); p = scm_cdr (p))
3544                 scm_set_car_x (p, scm_string_to_symbol (scm_car (p)));
3545
3546         // Let's attempt the symbol list interpretation first.
3547
3548         if (scm_is_true (scm_call_1 (pred, str)))
3549                 return str;
3550
3551         // If there is just one symbol in the list, we might interpret
3552         // it as a single symbol
3553
3554         if (scm_is_null (scm_cdr (str)))
3555         {
3556                 str = scm_car (str);
3557                 if (scm_is_true (scm_call_1 (pred, str)))
3558                         return str;
3559         }
3560
3561         return SCM_UNDEFINED;
3562 }
3563
3564 bool
3565 is_regular_identifier (SCM id, bool multiple)
3566 {
3567   if (!scm_is_string (id))
3568           return false;
3569
3570   string str = ly_scm2string (id);
3571
3572   bool middle = false;
3573
3574   for (string::iterator it=str.begin(); it != str.end (); it++)
3575   {
3576           int c = *it & 0xff;
3577           if ((c >= 'a' && c <= 'z')
3578               || (c >= 'A' && c <= 'Z')
3579               || c > 0x7f)
3580                   middle = true;
3581           else if (middle && (c == '-' || c == '_' || (multiple && c == '.')))
3582                   middle = false;
3583           else
3584                   return false;
3585   }
3586   return middle;
3587 }
3588
3589 SCM
3590 make_music_from_simple (Lily_parser *parser, Input loc, SCM simple)
3591 {
3592         if (unsmob_music (simple))
3593                 return simple;
3594         if (parser->lexer_->is_note_state ()) {
3595                 if (scm_is_symbol (simple)) {
3596                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
3597                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
3598                         n->set_property ("drum-type", simple);
3599                         return n->unprotect ();
3600                 }
3601                 if (unsmob_pitch (simple)) {
3602                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
3603                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
3604                         n->set_property ("pitch", simple);
3605                         return n->unprotect ();
3606                 }
3607                 return simple;
3608         } else if (parser->lexer_->is_lyric_state ()) {
3609                 if (Text_interface::is_markup (simple))
3610                         return MAKE_SYNTAX ("lyric-event", loc, simple,
3611                                             parser->default_duration_.smobbed_copy ());
3612         } else if (parser->lexer_->is_chord_state ()) {
3613                 if (unsmob_pitch (simple))
3614                         return make_chord_elements (loc, simple,
3615                                                     parser->default_duration_.smobbed_copy (),
3616                                                     SCM_EOL);
3617         }
3618         return simple;
3619 }
3620
3621 Music *
3622 make_music_with_input (SCM name, Input where)
3623 {
3624        Music *m = make_music_by_name (name);
3625        m->set_spot (where);
3626        return m;
3627 }
3628
3629 SCM
3630 make_simple_markup (SCM a)
3631 {
3632         return a;
3633 }
3634
3635 bool
3636 is_duration (int t)
3637 {
3638   return t && t == 1 << intlog2 (t);
3639 }
3640
3641 SCM
3642 make_chord_step (SCM step_scm, Rational alter)
3643 {
3644         int step = scm_to_int (step_scm);
3645
3646         if (step == 7)
3647                 alter += FLAT_ALTERATION;
3648
3649         while (step < 0)
3650                 step += 7;
3651         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
3652         return m.smobbed_copy ();
3653 }
3654
3655
3656 SCM
3657 make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list)
3658 {
3659         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
3660         SCM res = scm_call_3 (chord_ctor, pitch, dur, modification_list);
3661         for (SCM s = res; scm_is_pair (s); s = scm_cdr (s))
3662         {
3663                 unsmob_music (scm_car (s))->set_spot (loc);
3664         }
3665         return res;
3666 }
3667
3668 int
3669 yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser)
3670 {
3671         Lily_lexer *lex = parser->lexer_;
3672
3673         lex->lexval_ = s;
3674         lex->lexloc_ = loc;
3675         lex->prepare_for_next_token ();
3676         return lex->yylex ();
3677 }