aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.ac
   3
   4
   5 ### mostly interal macros
   6
   7 # Get full path of executable ($1)
   8 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
   9     ## which doesn't work in ash, if /usr/bin/which isn't installed
  10     ## type -p doesn't work in ash
  11     ## command -v doesn't work in zsh
  12     ## command -v "$1" 2>&1
  13     ## this test should work in ash, bash, pdksh (ksh), zsh
  14     type -p $1 2>/dev/null | tail -n 1 | awk '{print $NF}'
  15 ])
  16
  17
  18 # Get version string from executable ($1)
  19 AC_DEFUN(STEPMAKE_GET_VERSION, [
  20     ## "$1" --version 2>&1 | grep -v '^$' | head -n 1 | awk '{print $NF}'
  21     ##
  22     ## ARG.
  23     ## Workaround for broken Debian gcc version string:
  24     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  25     ##
  26     ## -V: Workaround for python
  27
  28     changequote(<<, >>)#dnl
  29
  30     ## Assume and hunt for dotted version multiplet.
  31     ## use eval trickery, because we cannot use multi-level $() instead of ``
  32     ## for compatibility reasons.
  33
  34     ## grab the first version number in  --version output.
  35     eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 |
  36                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  37                 head -n 1 |
  38                 tr ' ' '\n' |
  39                 sed 's/\([0-9][0-9]*\.[0-9][0-9.]*\).*/\1/g' |
  40                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  41                 head -n 1\`\"
  42
  43     if test -z "$_ver"; then
  44         ## If empty, try date [fontforge]
  45         eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '[0-9]\{6,8\}' \
  46             | head -n 1 \
  47             | sed -e 's/^[^.0-9]*//' -e 's/[^.0-9]*$//'\`\"
  48     fi
  49     echo "$_ver"
  50     changequote([, ])#dnl
  51 ])
  52
  53 # Calculate simplistic numeric version from version string ($1)
  54 # As yet, we have no need for something more elaborate.
  55 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  56     echo "$1" | awk -F. '
  57     {
  58       if ([$]3) {three = [$]3}
  59       else {three = 0}
  60     }
  61     {printf "%.0f\n", [$]1*1000000 + [$]2*1000 + three}'
  62 ])
  63
  64
  65 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  66 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  67     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  68 ])
  69
  70 # Check if tested program ($2) was found ($1).
  71 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  72 # We could abort here if a 'REQUIRED' program is not found
  73 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  74     STEPMAKE_CHECK_SEARCH_RESULT($1)
  75     if test $? -ne 0; then
  76         STEPMAKE_ADD_ENTRY($3, $2)
  77         if test "$3" = "REQUIRED"; then
  78             command="echo ERROR: $2 not found"
  79             # abort configure process here?
  80         else
  81             command="- echo $2 not found"
  82         fi
  83         eval "$1"='$command'
  84         false
  85     else
  86         true
  87     fi
  88 ])
  89
  90
  91 # Return if tested proram ($1) was found (true) or not (false).
  92 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  93     r="`eval echo '$'"$1"`"
  94     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  95         true
  96     else
  97         ##STEPMAKE_WARN(cannot find $2. $3)
  98         false
  99     fi
 100 ])
 101
 102
 103 # Check version of program ($1)
 104 # If version ($4: optional argument, supply if version cannot be
 105 # parsed using --version or -V ) is smaller than requested ($3), add
 106 # entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
 107 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
 108     r="`eval echo '$'"$1"`"
 109     AC_MSG_CHECKING([$r version])
 110     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 111     if test -n "$4"; then
 112         ver="$4"
 113     else
 114         ver=`STEPMAKE_GET_VERSION($exe)`
 115     fi
 116     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 117     req=`STEPMAKE_NUMERIC_VERSION($3)`
 118     AC_MSG_RESULT([$ver])
 119     if test "$num" -lt "$req"; then
 120         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
 121     fi
 122     vervar="`echo $1 | tr '[a-z]' '[A-Z]'`_VERSION"
 123     eval `echo $vervar=$num`
 124 ##    AC_SUBST(`eval echo $vervar`)
 125 ])
 126
 127 # Check version of program ($1)
 128 # If version is greater than or equals unsupported ($3),
 129 # add entry to unsupported list ($2, 'UNSUPPORTED')
 130 AC_DEFUN(STEPMAKE_CHECK_VERSION_UNSUPPORTED, [
 131     r="`eval echo '$'"$1"`"
 132     AC_MSG_CHECKING([$r version])
 133     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 134     ver=`STEPMAKE_GET_VERSION($exe)`
 135     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 136     sup=`STEPMAKE_NUMERIC_VERSION($3)`
 137     AC_MSG_RESULT([$ver])
 138     if test "$num" -ge "$sup"; then
 139         STEPMAKE_ADD_ENTRY($2, ["$r < $3 (installed: $ver)"])
 140     fi
 141 ])
 142
 143 ### Macros to build configure.ac
 144
 145
 146 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 147     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 148     if test "$BIBTEX2HTML" = "bib2html"; then
 149         BIBTEX2HTML_FLAGS='$< $(@)'
 150     else
 151         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 152     fi
 153     AC_SUBST(BIBTEX2HTML)
 154     AC_SUBST(BIBTEX2HTML_FLAGS)
 155 ])
 156
 157
 158 AC_DEFUN(STEPMAKE_BISON, [
 159     # ugh, automake: we want (and check for) bison
 160     AC_PROG_YACC
 161
 162     STEPMAKE_PROGS(BISON, bison, $1)
 163
 164     # urg.  should test functionality rather than version.
 165     if test "$BISON" = "bison" -a -n "$2"; then
 166         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 167     fi
 168 ])
 169
 170 AC_DEFUN(STEPMAKE_COMPILE_BEFORE, [
 171     # -O is necessary to get inlining
 172     CFLAGS=${CFLAGS-""}
 173     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 174     LDFLAGS=${LDFLAGS-""}
 175     optimise_b=yes
 176     profile_b=no
 177     debug_b=yes
 178     pipe_b=yes
 179
 180     AC_ARG_ENABLE(debugging,
 181     [AS_HELP_STRING([--enable-debugging],
 182                     [compile with debugging info.  Default: on])],
 183     [debug_b=$enableval])
 184
 185     AC_ARG_ENABLE(optimising,
 186     [AS_HELP_STRING([--enable-optimising],
 187                     [compile with optimising.  Default: on])],
 188     [optimise_b=$enableval])
 189
 190     AC_ARG_ENABLE(profiling,
 191     [AS_HELP_STRING([--enable-profiling],
 192                     [compile with gprof support.  Default: off])],
 193     [profile_b=$enableval])
 194
 195     AC_ARG_ENABLE(pipe,
 196     [AS_HELP_STRING([--enable-pipe],
 197                     [compile with -pipe.  Default: on])],
 198     [pipe_b=$enableval])
 199
 200     if test "$optimise_b" = yes; then
 201         AC_DEFINE(NDEBUG)
 202         DEFINES="$DEFINES -DNDEBUG"
 203         OPTIMIZE=" -O2 -finline-functions"
 204     fi
 205
 206     if test $profile_b = yes; then
 207         EXTRA_LIBS="-pg"
 208         OPTIMIZE="$OPTIMIZE -pg"
 209     fi
 210
 211     if test $debug_b = yes; then
 212         OPTIMIZE="$OPTIMIZE -g"
 213     fi
 214 ])
 215
 216 AC_DEFUN(STEPMAKE_COMPILE, [
 217
 218     AC_REQUIRE([STEPMAKE_COMPILE_BEFORE])
 219     AC_REQUIRE([AC_PROG_CC])
 220
 221     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 222     LD='$(CC)'
 223     AC_SUBST(LD)
 224
 225     # If -pipe requested, test if it works and add to CFLAGS.
 226     if test "$pipe_b" = yes; then
 227         save_cflags="$CFLAGS"
 228         CFLAGS=" -pipe $CFLAGS";
 229         AC_CACHE_CHECK([whether compiler understands -pipe],
 230             [stepmake_cv_cflags_pipe],
 231             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[/* -pipe test */]])],
 232                 [stepmake_cv_cflags_pipe=yes],
 233                 [stepmake_cv_cflags_pipe=no]))
 234         CFLAGS=$save_cflags
 235         if test $stepmake_cv_cflags_pipe = yes; then
 236             OPTIMIZE="$OPTIMIZE -pipe"
 237         fi
 238     fi
 239
 240     CFLAGS="$CFLAGS $OPTIMIZE"
 241     CPPFLAGS=${CPPFLAGS-""}
 242
 243     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 244     save_cflags="$CFLAGS"
 245     case "$host" in
 246         alpha*-*-*)
 247             dnl should do compile test?
 248             AC_MSG_RESULT(-mieee)
 249             CFLAGS=" -mieee $CFLAGS"
 250             ;;
 251         *)
 252             AC_MSG_RESULT([none])
 253             ;;
 254     esac
 255
 256     AC_SUBST(cross_compiling)
 257     AC_SUBST(CFLAGS)
 258     AC_SUBST(CPPFLAGS)
 259     AC_SUBST(LDFLAGS)
 260     AC_SUBST(DEFINES)
 261     AC_SUBST(EXTRA_LIBS)
 262 ])
 263
 264 AC_DEFUN(STEPMAKE_CXX, [
 265     AC_PROG_CXX
 266     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 267
 268     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 269     LD='$(CXX)'
 270
 271     AC_SUBST(CXX)
 272     AC_SUBST(CXXFLAGS)
 273     AC_SUBST(LD)
 274 ])
 275
 276
 277 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 278     AC_CACHE_CHECK([whether explicit instantiation is needed],
 279         stepmake_cv_need_explicit_instantiation,
 280         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 281     template <class T> struct foo { static int baz; };
 282     template <class T> int foo<T>::baz = 1;
 283     ]], [[ return foo<int>::baz; ]])],[stepmake_cv_need_explicit_instantiation=no],[stepmake_cv_need_explicit_instantiation=yes]))
 284     if test x"$stepmake_cv_need_explicit_instantiation"x = x"yes"x; then
 285         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 286     fi
 287 ])
 288
 289 AC_DEFUN(STEPMAKE_GXXCODEGENBUG, [
 290     AC_MSG_CHECKING([options for known g++ bugs])
 291     case "$GXX:$CXX_VERSION" in
 292         yes:400600[[0-2]])
 293             AC_MSG_RESULT([-fno-optimize-sibling-calls (tail call bug)])
 294             CXXFLAGS="$CXXFLAGS -fno-optimize-sibling-calls"
 295             ;;
 296         yes:400700?)
 297             AC_MSG_RESULT([-fno-tree-vrp (comparison bug)])
 298             CXXFLAGS="$CXXFLAGS -fno-tree-vrp"
 299             ;;
 300         *) AC_MSG_RESULT([none])
 301     esac
 302     AC_SUBST(CXXFLAGS)
 303 ])
 304
 305
 306 AC_DEFUN(STEPMAKE_DATADIR, [
 307     presome=${prefix}
 308     if test "$prefix" = "NONE"; then
 309         presome=${ac_default_prefix}
 310     fi
 311
 312     build_package_datadir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/share/$package
 313
 314     DATADIR=`echo ${datadir} | sed "s!\\\${datarootdir}!${presome}/share!"`
 315     DATADIR=`echo ${DATADIR} | sed "s!\\\${prefix}!$presome!"`
 316     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 317
 318     AC_SUBST(datadir)
 319     AC_SUBST(datarootdir)
 320     AC_SUBST(build_package_datadir)
 321     AC_DEFINE_UNQUOTED(DATADIR, ["${DATADIR}"])
 322     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, ["${BUILD_PACKAGE_DATADIR}"])
 323 ])
 324
 325 ## ugh: cut & paste programming from datadir.
 326 AC_DEFUN(STEPMAKE_LIBDIR, [
 327     presome=${exec_prefix}
 328     if test "$presome" = "NONE"; then
 329             presome=${prefix}
 330     fi
 331     if test "$presome" = "NONE"; then
 332             presome=${ac_default_prefix}
 333     fi
 334
 335     build_package_libdir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/lib/$package
 336
 337     LIBDIR=`echo ${libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 338     BUILD_PACKAGE_LIBDIR=`echo ${build_package_libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 339
 340     AC_SUBST(libdir)
 341     AC_SUBST(build_package_libdir)
 342     AC_DEFINE_UNQUOTED(LIBDIR, ["${LIBDIR}"])
 343     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_LIBDIR, ["${BUILD_PACKAGE_LIBDIR}"])
 344 ])
 345
 346
 347 AC_DEFUN(STEPMAKE_PREFIX_EXPAND_FIXUP, [
 348     # undo expanding of explicit --infodir=/usr/share
 349     # to ease install-time override with prefix=...
 350     strip=`echo $includedir | eval sed s@^$prefix@@`
 351     if test "$includedir" = "`eval echo $prefix$strip`"; then
 352             includedir='${prefix}'$strip''
 353     fi
 354     strip=`echo $libdir | eval sed s@^$exec_prefix@@`
 355     if test "$libdir" = "`eval echo $exec_prefix$strip`"; then
 356             libdir='${exec_prefix}'$strip''
 357     fi
 358     strip=`echo $infodir | eval sed s@^$datarootdir@@`
 359     if test "$infodir" = "`eval echo $datarootdir$strip`"; then
 360             infodir='${datarootdir}'$strip''
 361     fi
 362     strip=`echo $mandir | eval sed s@^$datarootdir@@`
 363     if test "$mandir" = "`eval echo $datarootdir$strip`"; then
 364             mandir='${datarootdir}'$strip''
 365     fi
 366 ])
 367
 368
 369 AC_DEFUN(STEPMAKE_END, [
 370     STEPMAKE_PREFIX_EXPAND_FIXUP
 371
 372     AC_SUBST(OPTIONAL)
 373     AC_SUBST(REQUIRED)
 374
 375     AC_CONFIG_FILES([$CONFIGFILE.make:config.make.in])
 376     AC_OUTPUT
 377
 378     if test -n "$OPTIONAL"; then
 379         echo
 380         echo "WARNING: Please consider installing optional programs or files: $OPTIONAL"
 381     fi
 382
 383     if test -n "$REQUIRED"; then
 384         echo
 385         echo "ERROR: Please install required programs: $REQUIRED"
 386     fi
 387
 388     if test -n "$UNSUPPORTED"; then
 389         echo
 390         echo "ERROR: Please use older version of programs: $UNSUPPORTED"
 391     fi
 392
 393     if test -n "$OPTIONAL$REQUIRED$UNSUPPORTED"; then
 394         echo
 395         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 396         if test -f config.cache ; then
 397             echo "Remove config.cache before rerunning ./configure"
 398         fi
 399     fi
 400
 401     if test -n "$REQUIRED$UNSUPPORTED"; then
 402         rm -f $srcdir/GNUmakefile
 403         exit 1
 404     fi
 405
 406     # regular in-place build
 407     # test for srcdir_build = yes ?
 408     if test "$srcdir_build" = "yes"; then
 409         rm -f $srcdir/GNUmakefile
 410         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 411         chmod 444 $srcdir/GNUmakefile
 412     else
 413         if test -f $srcdir/GNUmakefile; then
 414             cat <<EOF
 415 Source directory already configured.  Please clean the source directory
 416
 417      make -C $srcdir distclean
 418
 419 and rerun configure.
 420 EOF
 421             exit 2
 422         fi
 423
 424         abssrcdir="`cd $srcdir; pwd`"
 425         absbuilddir="`pwd`"
 426         for d in 2 3 4 5 ; do
 427             for mf in `cd $srcdir ; find . -maxdepth $d -mindepth $d -name GNUmakefile`; do
 428                 case "$abssrcdir" in
 429                     "$absbuilddir"/*)
 430 # source is below build directory, always copy
 431                         ;;
 432                     *)
 433                         case "$abssrcdir/${mf#./}" in
 434                             "$absbuilddir"/*)
 435 # find descended into build directory, don't copy
 436                                 continue
 437                         esac
 438                 esac
 439                 mkdir -p ${mf%/*}
 440                 cat <<EOF | $PYTHON -  > $mf
 441 print 'depth=' + ('../' * ( $d-1 ) )
 442 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 443 print 'include \$(configure-srcdir)/$mf'
 444 print 'MODULE_INCLUDES += \$(src-dir)/\$(outbase)'
 445 EOF
 446             done
 447             for mf in `cd $srcdir ; find . -maxdepth $d -mindepth $d -name '*.make' | grep -v config.make `; do
 448                 case "$abssrcdir" in
 449                     "$absbuilddir"/*)
 450 # source is below build directory, always copy
 451                         ;;
 452                     *)
 453                         case "$abssrcdir/${mf#./}" in
 454                             "$absbuilddir"/*)
 455 # find descended into build directory, don't copy
 456                                 continue
 457                         esac
 458                 esac
 459                 mkdir -p ${mf%/*}
 460                 cat <<EOF | $PYTHON -  > $mf
 461 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 462 print 'include \$(configure-srcdir)/$mf'
 463 EOF
 464             done
 465         done
 466
 467         rm -f GNUmakefile
 468         cat <<EOF > GNUmakefile
 469 depth = .
 470 include config\$(if \$(conf),-\$(conf),).make
 471 include \$(configure-srcdir)/GNUmakefile.in
 472 EOF
 473         chmod 444 GNUmakefile
 474         AC_SUBST(VPATH)
 475     fi
 476 ])
 477
 478
 479 AC_DEFUN(STEPMAKE_FLEX, [
 480     # ugh, automake: we want (and check for) flex
 481     # AC_PROG_LEX
 482     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 483
 484     # AC_PROG_LEX()
 485     # ugh, ugh
 486     ac_cv_prog_lex_root=lex.yy
 487     STEPMAKE_PROGS(FLEX, flex, $1)
 488 ])
 489
 490
 491 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 492     AC_CHECK_HEADERS([FlexLexer.h],[true],[false])
 493     if test $? -ne 0; then
 494         warn='FlexLexer.h (flex package)'
 495         STEPMAKE_ADD_ENTRY($1, $warn)
 496     fi
 497     # check for yyFlexLexer.yy_current_buffer,
 498     # in 2.5.4 <= flex < 2.5.29
 499     AC_CACHE_CHECK([for yyFlexLexer.yy_current_buffer],
 500         [stepmake_cv_flexlexer_yy_current_buffer],
 501         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 502 using namespace std;
 503 #include <FlexLexer.h>
 504 class yy_flex_lexer: public yyFlexLexer
 505 {
 506   public:
 507     yy_flex_lexer ()
 508     {
 509       yy_current_buffer = 0;
 510     }
 511 };
 512 ]])],
 513             [stepmake_cv_flexlexer_yy_current_buffer=yes],
 514             [stepmake_cv_flexlexer_yy_current_buffer=no]))
 515     if test $stepmake_cv_flexlexer_yy_current_buffer = yes; then
 516         AC_DEFINE(HAVE_FLEXLEXER_YY_CURRENT_BUFFER, 1, [Define to 1 if yyFlexLexer has yy_current_buffer.])
 517     fi
 518 ])
 519
 520
 521
 522 AC_DEFUN(STEPMAKE_FLEXLEXER_LOCATION, [
 523         AC_MSG_CHECKING([FlexLexer.h location])
 524
 525         # ugh.
 526         cat <<EOF > conftest.cc
 527 using namespace std;
 528 #include <FlexLexer.h>
 529 EOF
 530         FLEXLEXER_FILE=`eval $ac_cpp conftest.cc | \
 531           sed 's!# 1 "\(.*FlexLexer.h\)"!@FLEXLEXER@\1@@!g' | grep '@@' | \
 532           sed 's!.*@FLEXLEXER@\(.*\)@@.*$!\1!g' ` 1> /dev/null 2> /dev/null
 533         rm conftest.cc
 534         AC_SUBST(FLEXLEXER_FILE)
 535         AC_MSG_RESULT($FLEXLEXER_FILE)
 536 ])
 537
 538 AC_DEFUN(STEPMAKE_GCC_OR_CLANG, [
 539     STEPMAKE_HAS_CLANG()
 540     if test "$HAS_CLANG" = "no"; then
 541         if test "$GCC" = "yes"; then
 542             STEPMAKE_CHECK_VERSION(CC, $1, $2)
 543         else
 544             warn="$CC (Please install *GNU* cc)"
 545             STEPMAKE_ADD_ENTRY($1, $warn)
 546         fi
 547     fi
 548     # no else, we're fine with any clang
 549 ])
 550
 551 AC_DEFUN(STEPMAKE_GETTEXT, [
 552     presome=${prefix}
 553     if test "$prefix" = "NONE"; then
 554             presome=${ac_default_prefix}
 555     fi
 556     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 557
 558     AC_SUBST(localedir)
 559     AC_DEFINE_UNQUOTED(LOCALEDIR, ["${LOCALEDIR}"])
 560     AC_CHECK_LIB(intl, gettext)
 561     AC_CHECK_FUNCS(gettext)
 562 ])
 563
 564
 565 # Check for guile, between minimum ($2) and maximum version ($3).
 566 # If missing, add entry to missing-list ($1, one of 'OPTIONAL', 'REQUIRED')
 567 AC_DEFUN(STEPMAKE_GUILE, [
 568     AC_MSG_CHECKING([for guile])
 569     guile="guile"
 570     found="no"
 571     for r in $GUILE guile guile2 guile2.0 guile-2.0 guile1 guile1.9 guile1.8 guile-1 guile-1.9 guile-1.8; do
 572         exe=`STEPMAKE_GET_EXECUTABLE($r)`
 573         if ! $exe --version > /dev/null 2>&1 ; then
 574             continue
 575         fi
 576         ver=`STEPMAKE_GET_VERSION($exe)`
 577         num=`STEPMAKE_NUMERIC_VERSION($ver)`
 578         req=`STEPMAKE_NUMERIC_VERSION($2)`
 579         sup=`STEPMAKE_NUMERIC_VERSION($3)`
 580         if test -n "$2" && test "$num" -lt "$req"; then
 581             guile=["$r >= $2 (installed: $ver)"]
 582             continue
 583         else
 584             if test -n "$3" && test "$num" -ge "$sup"; then
 585                 guile=["$r < $3 (installed: $ver)"]
 586                 continue
 587             else
 588                 guile=$r
 589                 found=$r
 590                 break
 591             fi
 592         fi
 593     done
 594     AC_MSG_RESULT([$found])
 595     if test "$found" != "no"; then
 596         AC_MSG_CHECKING([$guile version])
 597         AC_MSG_RESULT([$ver])
 598         GUILE=$found
 599     else
 600         STEPMAKE_ADD_ENTRY($1, $guile)
 601     fi
 602     STEPMAKE_PATH_PROG(GUILE, $GUILE)
 603 ])
 604
 605
 606 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 607 #
 608 #   This macro runs the guile-config script, installed with Guile,
 609 #   to find out where Guile's header files and libraries are
 610 #   installed.  It sets two variables, marked for substitution, as
 611 #   by AC_SUBST.
 612 #
 613 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 614 #             code that uses Guile header files.  This is almost
 615 #             always just a -I flag.
 616 #
 617 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 618 #             program against Guile.  This includes -lguile for
 619 #             the Guile library itself, any libraries that Guile
 620 #             itself requires (like -lqthreads), and so on.  It may
 621 #             also include a -L flag to tell the compiler where to
 622 #             find the libraries.
 623
 624 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 625     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 626     if test -x $exe; then
 627         AC_MSG_CHECKING([guile compile flags])
 628         GUILE_CFLAGS="`$guile_config compile`"
 629         AC_MSG_RESULT($GUILE_CFLAGS)
 630         AC_MSG_CHECKING([guile link flags])
 631         GUILE_LDFLAGS="`$guile_config link`"
 632         AC_MSG_RESULT($GUILE_LDFLAGS)
 633     fi
 634     AC_SUBST(GUILE_CFLAGS)
 635     AC_SUBST(GUILE_LDFLAGS)
 636 ])
 637
 638
 639 # Check for guile-config, between minimum ($2) and maximum version ($3).
 640 # If missing, add entry to missing-list ($1, one of 'OPTIONAL', 'REQUIRED')
 641 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 642     ## First, let's just see if we can find Guile at all.
 643     test -n "$target_alias" && target_guile_config=$target_alias-guile-config
 644     test -n "$host_alias" && host_guile_config=$host_alias-guile-config
 645     AC_MSG_CHECKING([for guile-config])
 646     guile_config="guile-config"
 647     found="no"
 648     for r in $GUILE_CONFIG $target_guile_config $host_guile_config $build_guile_config guile-config guile2-config guile2.0-config guile-2.0-config guile1-config guile1.9-config guile1.8-config guile-1-config guile-1.9-config guile-1.8-config; do
 649         exe=`STEPMAKE_GET_EXECUTABLE($r)`
 650         if ! $exe --version > /dev/null 2>&1 ; then
 651             continue
 652         fi
 653         ver=`STEPMAKE_GET_VERSION($exe)`
 654         num=`STEPMAKE_NUMERIC_VERSION($ver)`
 655         req=`STEPMAKE_NUMERIC_VERSION($2)`
 656         sup=`STEPMAKE_NUMERIC_VERSION($3)`
 657         if test -n "$2" -a "$num" -lt "$req"; then
 658             guile_config=["$r >= $2 (installed: $ver)"]
 659             continue
 660         else
 661             if test -n "$3" -a "$num" -ge "$sup"; then
 662                 guile_config=["$r < $3 (installed: $ver)"]
 663                 continue
 664             else
 665                 guile_config=$r
 666                 found=$r
 667                 break
 668             fi
 669         fi
 670     done
 671     AC_MSG_RESULT([$found])
 672     if test "$found" != "no"; then
 673         AC_MSG_CHECKING([$guile_config version])
 674         AC_MSG_RESULT([$ver])
 675         GUILE_CONFIG=$found
 676     else
 677         STEPMAKE_ADD_ENTRY($1, "$guile_config (guile-devel, guile-dev or libguile-dev package) or guile1-config (guile1-devel package)")
 678     fi
 679
 680     AC_SUBST(GUILE_CONFIG)
 681
 682     guile_version="$ver"
 683     changequote(<<, >>)#dnl
 684     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 685     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 686     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 687     changequote([, ])#dnl
 688     STEPMAKE_GUILE_FLAGS
 689     save_CPPFLAGS="$CPPFLAGS"
 690     save_LIBS="$LIBS"
 691     CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 692     LIBS="$GUILE_LDFLAGS $LIBS"
 693     AC_CHECK_HEADERS([libguile.h])
 694     AC_CHECK_LIB(guile, scm_boot_guile)
 695     AC_CHECK_FUNCS(scm_boot_guile,,libguile_b=no)
 696     if test "$libguile_b" = "no"; then
 697             warn='libguile (libguile-dev, guile-devel or guile-dev
 698    package).'
 699             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 700     fi
 701     CPPFLAGS="$save_CPPFLAGS"
 702     LIBS="$save_LIBS"
 703     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 704     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 705     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 706 ])
 707
 708
 709 AC_DEFUN(STEPMAKE_DLOPEN, [
 710     AC_CHECK_LIB(dl, dlopen)
 711     AC_CHECK_FUNCS(dlopen)
 712 ])
 713
 714 AC_DEFUN(STEPMAKE_HAS_CLANG, [
 715     AC_EGREP_CPP(yes,
 716       [#ifdef __clang__
 717        yes
 718        #endif
 719       ], HAS_CLANG=yes, HAS_CLANG=no)
 720 ])
 721
 722 AC_DEFUN(STEPMAKE_GXX_OR_CLANG, [
 723     STEPMAKE_HAS_CLANG()
 724     if test "$HAS_CLANG" = "no"; then
 725         if test "$GXX" = "yes"; then
 726             STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 727         else
 728             warn="$CXX (Please install *GNU* c++)"
 729             STEPMAKE_ADD_ENTRY($1, $warn)
 730         fi
 731     fi
 732     # no else, we're fine with any clang
 733 ])
 734
 735
 736 AC_DEFUN(STEPMAKE_INIT, [
 737
 738     . $srcdir/VERSION
 739     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 740     MICRO_VERSION=$PATCH_LEVEL
 741     TOPLEVEL_VERSION=$FULL_VERSION
 742     if test x$MY_PATCH_LEVEL != x; then
 743         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 744     fi
 745     VERSION=$FULL_VERSION
 746     export MAJOR_VERSION MINOR_VERSION PATCH_LEVEL
 747     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 748     changequote(<<, >>)#dnl
 749     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 750     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 751     changequote([, ])#dnl
 752
 753     # No versioning on directory names of sub-packages
 754     # urg, urg
 755     stepmake=${datadir}/stepmake
 756     presome=${prefix}
 757     if test "$prefix" = "NONE"; then
 758             presome=${ac_default_prefix}
 759     fi
 760     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 761
 762     # urg, how is this supposed to work?
 763     if test "$program_prefix" = "NONE"; then
 764           program_prefix=
 765     fi
 766     if test "$program_suffix" = "NONE"; then
 767           program_suffix=
 768     fi
 769
 770     AC_MSG_CHECKING(Package)
 771     if test "$PACKAGE" = "STEPMAKE"; then
 772         AC_MSG_RESULT(Stepmake package!)
 773
 774         AC_MSG_CHECKING(builddir)
 775
 776         ugh_ugh_autoconf250_builddir="`pwd`"
 777
 778         if test "$srcdir" = "."; then
 779             srcdir_build=yes
 780         else
 781             srcdir_build=no
 782             package_builddir="`dirname $ugh_ugh_autoconf250_builddir`"
 783             package_srcdir="`dirname  $srcdir`"
 784         fi
 785         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 786
 787         (cd stepmake 2>/dev/null || mkdir stepmake)
 788         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 789         stepmake=stepmake
 790     else
 791         AC_MSG_RESULT($PACKAGE)
 792
 793         AC_MSG_CHECKING(builddir)
 794         ugh_ugh_autoconf250_builddir="`pwd`"
 795
 796         here_dir=$(cd . && pwd)
 797         full_src_dir=$(cd $srcdir && pwd)
 798
 799         if test "$full_src_dir" = "$here_dir"; then
 800             srcdir_build=yes
 801         else
 802             srcdir_build=no
 803         fi
 804         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 805
 806         AC_MSG_CHECKING(for stepmake)
 807         # Check for installed stepmake
 808         if test -d $stepmake; then
 809             AC_MSG_RESULT($stepmake)
 810         else
 811             stepmake="`cd $srcdir/stepmake; pwd`"
 812             AC_MSG_RESULT([$srcdir/stepmake  ($datadir/stepmake not found)])
 813         fi
 814     fi
 815
 816     AC_SUBST(ugh_ugh_autoconf250_builddir)
 817
 818     # Use absolute directory for non-srcdir builds, so that build
 819     # dir can be moved.
 820     if test "$srcdir_build" = "no" ;  then
 821         srcdir="`cd $srcdir; pwd`"
 822     fi
 823
 824     AC_SUBST(srcdir)
 825     AC_SUBST(stepmake)
 826     AC_SUBST(package)
 827     AC_SUBST(PACKAGE)
 828     AC_SUBST(PACKAGE_NAME)
 829     AC_SUBST(VERSION)
 830     AC_SUBST(MAJOR_VERSION)
 831     AC_SUBST(MINOR_VERSION)
 832     AC_SUBST(MICRO_VERSION)
 833
 834     # stepmake nonstandard names
 835     AC_SUBST(PATCH_LEVEL)
 836     AC_SUBST(TOPLEVEL_VERSION)
 837
 838     # We don't need the upper case variant,
 839     # so stick to macros are uppercase convention.
 840     # AC_DEFINE_UNQUOTED(package, ["${package}"])
 841     # AC_DEFINE_UNQUOTED(PACKAGE, ["${PACKAGE}"])
 842     AC_DEFINE_UNQUOTED(PACKAGE, ["${package}"])
 843     AC_DEFINE_UNQUOTED(PACKAGE_NAME, ["${PACKAGE_NAME}"])
 844     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, ["${FULL_VERSION}"])
 845
 846     if test -z "$package_depth"; then
 847         package_depth="."
 848     else
 849         package_depth="../$package_depth"
 850     fi
 851     export package_depth
 852     AC_SUBST(package_depth)
 853
 854     AUTOGENERATE="This file was automatically generated by configure"
 855     AC_SUBST(AUTOGENERATE)
 856
 857     CONFIGSUFFIX=
 858     AC_ARG_ENABLE(config,
 859     [AS_HELP_STRING([--enable-config=CONF],
 860                     [put settings in config-CONF.make and config-CONF.h;
 861                     do `make conf=CONF' to get output in ./out-CONF])],
 862     [CONFIGURATION=$enableval])
 863
 864     ##'`#
 865
 866     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 867     CONFIGFILE=config$CONFIGSUFFIX
 868     AC_SUBST(CONFIGSUFFIX)
 869
 870     AC_CANONICAL_HOST
 871     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 872     STEPMAKE_PROGS(FIND, find, REQUIRED)
 873
 874     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 875
 876     if test "$(echo 2)" != "2" ||
 877         test "x`uname`" = "xHP-UX"; then
 878         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 879         AC_PATH_PROG(BASH, bash, $KSH)
 880         STEPMAKE_WARN(avoiding buggy /bin/sh)
 881         AC_PATH_PROG(SHELL, bash, $KSH)
 882     else
 883         SHELL=/bin/sh
 884         AC_PATH_PROG(BASH, bash, $SHELL)
 885     fi
 886     AC_SUBST(SHELL)
 887
 888     STEPMAKE_PYTHON(REQUIRED, 1.5, 3.0)
 889
 890     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 891         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 892         if test "$?" = 1; then
 893             warn='make (Please install *GNU* make)'
 894             # STEPMAKE_WARN($warn)
 895             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 896         fi
 897     fi
 898
 899     ROOTSEP=':'
 900     DIRSEP='/'
 901     PATHSEP=':'
 902     LN=ln
 903     LN_S='ln -s'
 904     ZIP="zip -r -9"
 905
 906     AC_SUBST(program_prefix)
 907     AC_SUBST(program_suffix)
 908     AC_SUBST(ZIP)
 909     AC_SUBST(LN)
 910     AC_SUBST(LN_S)
 911     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
 912     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
 913     AC_SUBST(DIRSEP)
 914     AC_SUBST(PATHSEP)
 915     AC_SUBST(ROOTSEP)
 916
 917     STEPMAKE_DATADIR
 918     STEPMAKE_LIBDIR
 919 ])
 920
 921
 922 AC_DEFUN(STEPMAKE_LIB, [
 923     STEPMAKE_PROGS(AR, ar, $1)
 924     AC_PROG_RANLIB
 925     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 926 ])
 927
 928
 929 AC_DEFUN(STEPMAKE_LIBTOOL, [
 930     # libtool.info ...
 931     # **Never** try to set library version numbers so that they correspond
 932     # to the release number of your package.  This is an abuse that only
 933     # fosters misunderstanding of the purpose of library versions.
 934
 935     REVISION=$PATCH_LEVEL
 936     # CURRENT=$MINOR_VERSION
 937     CURRENT=`expr $MINOR_VERSION + 1`
 938     # AGE=`expr $MAJOR_VERSION + 1`
 939     AGE=$MAJOR_VERSION
 940     AC_SUBST(CURRENT)
 941     AC_SUBST(REVISION)
 942     AC_SUBST(AGE)
 943 ])
 944
 945
 946 AC_DEFUN(STEPMAKE_LOCALE, [
 947     lang=English
 948     ALL_LINGUAS="en nl"
 949
 950     # with/enable ??
 951     AC_ARG_WITH(localedir,
 952     [AS_HELP_STRING([--with-localedir=DIR],
 953                     [location of locales.  Default: PREFIX/share/locale])],
 954     localedir=$with_localedir,
 955     localedir='${prefix}/share/locale')
 956
 957     AC_ARG_WITH(lang,
 958     [AS_HELP_STRING([--with-lang=LANG],
 959                     [use LANG as language to emit messages])],
 960     language=$with_lang,
 961     language=English)
 962
 963     AC_MSG_CHECKING(language)
 964     case "$language" in
 965       En* | en* | Am* | am* | US* | us*)
 966             lang=English;;
 967       NL | nl | Du* | du* | Ned* | ned*)
 968             lang=Dutch;;
 969       "")
 970             lang=English;;
 971       *)
 972             lang=unknown;;
 973     esac
 974     AC_MSG_RESULT($lang)
 975
 976     if test "$lang" = "unknown" ; then
 977         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 978     fi
 979
 980 ])
 981
 982
 983 AC_DEFUN(STEPMAKE_MAKEINFO, [
 984     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 985 ])
 986
 987
 988 AC_DEFUN(STEPMAKE_MAN, [
 989     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 990     AC_SUBST(GROFF)
 991     STEPMAKE_PROGS(TROFF, troff, $1)
 992     AC_SUBST(TROFF)
 993     STEPMAKE_PROGS(TBL, tbl, $1)
 994     AC_SUBST(TBL)
 995 ])
 996
 997
 998 AC_DEFUN(STEPMAKE_MSGFMT, [
 999     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
1000 ])
1001
1002
1003 # Check for program ($2), set full path result to ($1).
1004 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
1005 AC_DEFUN(STEPMAKE_PATH_PROG, [
1006     AC_CHECK_PROGS($1, $2, no)
1007     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
1008     if test $? -eq 0; then
1009         AC_PATH_PROGS($1, $2)
1010         if test -n "$4"; then
1011             STEPMAKE_CHECK_VERSION($1, $3, $4)
1012         fi
1013     fi
1014 ])
1015
1016
1017 # Check for program in set of names ($2), set result to ($1) .
1018 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
1019 # If exists, and a minimal version ($4) is required
1020 AC_DEFUN(STEPMAKE_PROGS, [
1021     AC_CHECK_PROGS($1, $2, no)
1022     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
1023     if test $? -eq 0 -a -n "$4"; then
1024         STEPMAKE_CHECK_VERSION($1, $3, $4)
1025     fi
1026 ])
1027
1028
1029 AC_DEFUN(STEPMAKE_PERL, [
1030     STEPMAKE_PATH_PROG(PERL, perl, $1)
1031 ])
1032
1033
1034 # Check for python, between minimum ($2) and maximum version ($3).
1035 # If missing, add entry to missing-list ($1, one of 'OPTIONAL', 'REQUIRED')
1036 AC_DEFUN(STEPMAKE_PYTHON, [
1037     AC_MSG_CHECKING([for python])
1038     python="python"
1039     found="no"
1040     for r in $PYTHON python python3 python3.3 python3.2 python3.1 python3.0 python2 python2.7 python2.6 python2.5 python2.4 python2.3 python2.2 python2.1 python2.0; do
1041         exe=`STEPMAKE_GET_EXECUTABLE($r)`
1042         if ! $exe -V > /dev/null 2>&1 ; then
1043             continue
1044         fi
1045         ver=`STEPMAKE_GET_VERSION($exe)`
1046         num=`STEPMAKE_NUMERIC_VERSION($ver)`
1047         req=`STEPMAKE_NUMERIC_VERSION($2)`
1048         sup=`STEPMAKE_NUMERIC_VERSION($3)`
1049         if test -n "$2" && test "$num" -lt "$req"; then
1050             python=["$r >= $2 (installed: $ver)"]
1051             continue
1052         else
1053             if test -n "$3" && test "$num" -ge "$sup"; then
1054                 python=["$r < $3 (installed: $ver)"]
1055                 continue
1056             else
1057                 python=$r
1058                 found=$r
1059                 break
1060             fi
1061         fi
1062     done
1063     AC_MSG_RESULT([$found])
1064     if test "$found" != "no"; then
1065         AC_MSG_CHECKING([$python version])
1066         AC_MSG_RESULT([$ver])
1067         PYTHON=$found
1068     else
1069         STEPMAKE_ADD_ENTRY($1, $python)
1070     fi
1071     AC_PATH_PROG(PYTHON, $PYTHON)
1072     AC_SUBST(PYTHON)
1073 ])
1074
1075 # Check for python-config, between minimum ($2) and maximum version ($3).
1076 # If missing, add entry to missing-list ($1, one of 'OPTIONAL', 'REQUIRED')
1077 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
1078     AC_ARG_WITH(python-include,
1079         [AS_HELP_STRING([--with-python-include=DIR],
1080                         [location of the python include dir])],[
1081         if test "$withval" = "yes" -o "$withval" = "no"; then
1082             AC_MSG_WARN(Usage: --with-python-include=includedir)
1083         else
1084             PYTHON_CFLAGS="-I${withval}"
1085         fi
1086     ])
1087
1088     AC_ARG_WITH(python-lib,
1089         [AS_HELP_STRING([--with-python-lib=NAME],
1090                         [name of the python lib])],[
1091         if test "$withval" = "yes" -o "$withval" = "no"; then
1092             AC_MSG_WARN(Usage: --with-python-lib=name)
1093         else
1094             LDFLAGS="$LDFLAGS -l${withval}"
1095         fi
1096     ])
1097
1098     STEPMAKE_PYTHON($1, $2, $3)
1099     AC_CHECK_PROGS(PYTHON_CONFIG, `basename $PYTHON`-config, no)
1100
1101     if test -z "$PYTHON_CFLAGS" -a "$PYTHON_CONFIG" != "no"; then
1102         # Clean out junk: http://bugs.python.org/issue3290
1103         # Python headers may need some -f* flags, leave them in.
1104         # We want the sed commands to look like 's/-[WDOm][[:alnum:][:punct:]][[:alnum:][:punct:]]*//g' and 's/-arch [^[:space:]]*//g', but automake eats brackets.
1105          #PYTHON_CFLAGS=`$PYTHON_CONFIG --cflags | sed -e 's/-[[WDOm]][[[:alnum:][:punct:]]][[[:alnum:][:punct:]]]*//g' | sed -e 's/-arch @<:@^@<:@:space:@:>@@:>@*//g'`
1106          # The above sed BRE matches parts of legal options, stipping down part of that option, resulting in invalid gcc arguments. Gentoo Bug #415793
1107          # For instance, '-floop-stip-mime' becomes '-floop-strip', and '-fvect-cost-model' becomes '-fvect-cost'.
1108          # Tentative fix to require a non alphanumeric character before the initial hyphen of the BRE or the hyphen being the first character in the string.
1109          PYTHON_CFLAGS=`$PYTHON_CONFIG --cflags | sed -e 's/\(^\|[[^[:alnum:]]]\)-[[WDOm]][[[:alnum:][:punct:]]][[[:alnum:][:punct:]]]*//g' | sed -e 's/-arch @<:@^@<:@:space:@:>@@:>@*//g'`
1110         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
1111     fi
1112
1113     if test -z "$PYTHON_CFLAGS" -a "$cross_compiling" = "no"; then
1114         changequote(<<, >>)#dnl
1115         # alternatively, for python >= 2.0
1116         # 'import sys, distutils.sysconfig; sys.stdout.write (distutils.sysconfig.get_python_inc ())'
1117         PYTHON_INCLUDE=`$PYTHON -c 'import sys; sys.stdout.write ("%s/include/python%s" % (sys.prefix, sys.version[:3]))'`
1118         PYTHON_CFLAGS="-I$PYTHON_INCLUDE"
1119         changequote([, ])#dnl
1120     fi
1121
1122     if test -z "$PYTHON_HEADER"; then
1123         CPPFLAGS="$PYTHON_CFLAGS $CPPFLAGS"
1124         AC_CHECK_HEADERS([Python.h],[PYTHON_HEADER=yes])
1125     fi
1126
1127     if test -z "$PYTHON_HEADER"; then
1128         warn="Python.h (python-devel, python-dev or libpython-dev package)"
1129         STEPMAKE_ADD_ENTRY($1, $warn)
1130     fi
1131 ])
1132
1133
1134
1135 AC_DEFUN(STEPMAKE_STL_DATA_METHOD, [
1136     AC_CACHE_CHECK([for stl.data () method],
1137         [stepmake_cv_stl_data_method],
1138         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1139 #include <vector>
1140 using namespace std;
1141 vector <int> v;
1142 void *p = v.data ();
1143 ]])],
1144             [stepmake_cv_stl_data_method=yes],
1145             [stepmake_cv_stl_data_method=no]))
1146     if test $stepmake_cv_stl_data_method = yes; then
1147         AC_DEFINE(HAVE_STL_DATA_METHOD, 1, [define if stl classes have data () method])
1148     fi
1149 ])
1150
1151
1152 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
1153     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, $1)
1154
1155     AC_MSG_CHECKING(for metapost required files)
1156     if test "$MFPLAIN_MP" = ""; then
1157         MFPLAIN_MP=`kpsewhich -format=mp mfplain`
1158     fi
1159     if test "$MFPLAIN_MP" = ""; then
1160         AC_MSG_RESULT(no)
1161         STEPMAKE_ADD_ENTRY($1,['metapost CTAN package (texlive-metapost)'])
1162     else
1163         AC_MSG_RESULT(yes)
1164     fi
1165 ])
1166
1167 AC_DEFUN(STEPMAKE_TEXMF, [
1168     STEPMAKE_PROGS(METAFONT, mf-nowin mf mfw mfont, $1)
1169     STEPMAKE_PROGS(METAPOST, mpost, $1)
1170     if test "$METAPOST" != ""; then
1171         ver=`STEPMAKE_GET_VERSION($METAPOST)`
1172         num=`STEPMAKE_NUMERIC_VERSION($ver)`
1173         # Avoid buggy metapost versions: 1.600 <= x < 1.803
1174         if test "$num" -ge "1600000" -a "$num" -lt "1803000"; then
1175             STEPMAKE_ADD_ENTRY($1, ["mpost (due to a bug in metapost, versions 1.600 <= x < 1.803 are not supported; installed: $ver)"])
1176         fi
1177     fi
1178
1179     AC_MSG_CHECKING(for working metafont mode)
1180     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
1181     for MFMODE in $modelist; do
1182         $METAFONT -progname=mf "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
1183         if test -f mfput.tfm; then
1184             break;
1185         fi
1186     done
1187     AC_MSG_RESULT($MFMODE)
1188
1189     rm -f mfput.*
1190
1191     AC_SUBST(MFMODE)
1192 ])
1193
1194
1195 AC_DEFUN(STEPMAKE_WARN, [
1196     AC_MSG_WARN($1)
1197     warn_b=yes
1198 ])
1199
1200
1201 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1202 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1203 dnl also defines GSTUFF_PKG_ERRORS on error
1204 AC_DEFUN(PKG_CHECK_MODULES, [
1205   succeeded=no
1206
1207   if test -z "$PKG_CONFIG"; then
1208     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1209   fi
1210
1211   if test "$PKG_CONFIG" = "no" ; then
1212      echo "*** The pkg-config script could not be found. Make sure it is"
1213      echo "*** in your path, or set the PKG_CONFIG environment variable"
1214      echo "*** to the full path to pkg-config."
1215      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1216   else
1217      PKG_CONFIG_MIN_VERSION=0.9.0
1218      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1219         AC_MSG_CHECKING(for $2)
1220
1221         if $PKG_CONFIG --exists "$2" ; then
1222             AC_MSG_RESULT(yes)
1223             succeeded=yes
1224
1225             AC_MSG_CHECKING($1_CFLAGS)
1226             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1227             AC_MSG_RESULT($$1_CFLAGS)
1228
1229             AC_MSG_CHECKING($1_LIBS)
1230             $1_LIBS=`$PKG_CONFIG --libs "$2"`
1231             AC_MSG_RESULT($$1_LIBS)
1232         else
1233             $1_CFLAGS=""
1234             $1_LIBS=""
1235             ## If we have a custom action on failure, don't print errors, but
1236             ## do set a variable so people can do so.
1237             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1238             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1239         fi
1240
1241         AC_SUBST($1_CFLAGS)
1242         AC_SUBST($1_LIBS)
1243      fi
1244   fi
1245
1246   if test $succeeded = yes; then
1247      ifelse([$3], , :, [$3])
1248   else
1249      ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
1250   fi
1251 ])
1252
1253 AC_DEFUN(STEPMAKE_FREETYPE2, [
1254     PKG_CHECK_MODULES(FREETYPE2, $1 >= $3, have_freetype2=yes, true)
1255     if test "$have_freetype2" = yes; then
1256         AC_DEFINE(HAVE_FREETYPE2)
1257         save_CPPFLAGS="$CPPFLAGS"
1258         save_LIBS="$LIBS"
1259         CPPFLAGS="$FREETYPE2_CFLAGS $CPPFLAGS"
1260         LIBS="$FREETYPE2_LIBS $LIBS"
1261         AC_SUBST(FREETYPE2_CFLAGS)
1262         AC_SUBST(FREETYPE2_LIBS)
1263         CPPFLAGS="$save_CPPFLAGS"
1264         LIBS="$save_LIBS"
1265     else
1266         # UGR
1267         #r="lib$1-dev or $1-devel"
1268         r="libfreetype6-dev or freetype?-devel"
1269         ver="`pkg-config --modversion $1`"
1270         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1271     fi
1272 ])
1273
1274 AC_DEFUN(STEPMAKE_PANGO, [
1275     PKG_CHECK_MODULES(PANGO, $1 >= $3, have_pango16=yes, true)
1276     if test "$have_pango16" = yes ; then
1277         AC_DEFINE(HAVE_PANGO16)
1278         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1279         save_CPPFLAGS="$CPPFLAGS"
1280         save_LIBS="$LIBS"
1281         CPPFLAGS="$PANGO_CFLAGS $CPPFLAGS"
1282         LIBS="$PANGO_LIBS $LIBS"
1283         AC_CHECK_HEADERS([pango/pangofc-fontmap.h])
1284         AC_CHECK_FUNCS([pango_fc_font_map_add_decoder_find_func])
1285         AC_SUBST(PANGO_CFLAGS)
1286         AC_SUBST(PANGO_LIBS)
1287         CPPFLAGS="$save_CPPFLAGS"
1288         LIBS="$save_LIBS"
1289     else
1290         # UGR
1291         #r="lib$1-dev or $1-devel"
1292         r="libpango1.0-dev or pango1.0-devel"
1293         ver="`pkg-config --modversion $1`"
1294         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1295     fi
1296 ])
1297
1298 AC_DEFUN(STEPMAKE_PANGO_FT2, [
1299     PKG_CHECK_MODULES(PANGO_FT2, $1 >= $3, have_pangoft2=yes, true)
1300     if test "$have_pangoft2" = yes ; then
1301         AC_DEFINE(HAVE_PANGO16)
1302         AC_DEFINE(HAVE_PANGO_FT2)
1303         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1304         save_CPPFLAGS="$CPPFLAGS"
1305         save_LIBS="$LIBS"
1306         CPPFLAGS="$CPPFLAGS $PANGO_FT2_CFLAGS"
1307         LIBS="$PANGO_FT2_LIBS $LIBS"
1308         AC_CHECK_HEADERS([pango/pangoft2.h])
1309         AC_CHECK_FUNCS([pango_ft2_font_map_create_context])
1310         AC_SUBST(PANGO_FT2_CFLAGS)
1311         AC_SUBST(PANGO_FT2_LIBS)
1312         CPPFLAGS="$save_CPPFLAGS"
1313         LIBS="$save_LIBS"
1314     else
1315         # UGR
1316         #r="lib$1-dev or $1-devel"e
1317         r="libpango1.0-dev or pango?-devel"
1318         ver="`pkg-config --modversion $1`"
1319         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1320     fi
1321 ])
1322
1323 AC_DEFUN(STEPMAKE_FONTCONFIG, [
1324     PKG_CHECK_MODULES(FONTCONFIG, $1 >= $3, have_fontconfig=yes, true)
1325     if test "$have_fontconfig" = yes ; then
1326         AC_DEFINE(HAVE_FONTCONFIG)
1327         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1328         save_CPPFLAGS="$CPPFLAGS"
1329         save_LIBS="$LIBS"
1330         CPPFLAGS="$FONTCONFIG_CFLAGS $CPPFLAGS"
1331         LIBS="$FONTCONFIG_LIBS $LIBS"
1332         AC_SUBST(FONTCONFIG_CFLAGS)
1333         AC_SUBST(FONTCONFIG_LIBS)
1334         CPPFLAGS="$save_CPPFLAGS"
1335         LIBS="$save_LIBS"
1336     else
1337         r="lib$1-dev or $1-devel"
1338         ver="`pkg-config --modversion $1`"
1339         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1340     fi
1341 ])
1342
1343 AC_DEFUN(STEPMAKE_WINDOWS, [
1344     AC_CYGWIN
1345     AC_MINGW32
1346
1347     if test "$CYGWIN" = "yes"; then
1348         LN_S='cp -r' # Cygwin symbolic links do not work for native apps.
1349         program_suffix=.exe
1350         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1351     elif test "$MINGW32" = "yes"; then
1352         LN='cp -r'
1353         LN_S='cp -r'
1354         program_suffix=.exe
1355         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1356         PATHSEP=';'
1357     fi
1358
1359     AC_SUBST(LN)
1360     AC_SUBST(LN_S)
1361     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
1362     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
1363     AC_SUBST(DIRSEP)
1364     AC_SUBST(PATHSEP)
1365     AC_SUBST(program_suffix)
1366
1367     AC_MSG_CHECKING([for some flavor of Windows])
1368     if test "$CYGWIN$MINGW32" = "nono"; then
1369         PLATFORM_WINDOWS=no
1370     else
1371         PLATFORM_WINDOWS=yes
1372     fi
1373     AC_MSG_RESULT([$PLATFORM_WINDOWS])
1374     AC_SUBST(PLATFORM_WINDOWS)
1375     STEPMAKE_PROGS(WINDRES, $target-windres windres, x)
1376     AC_SUBST(WINDRES)
1377 ])