stepmake/aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4
   5 ### mostly interal macros
   6
   7 # Get full path of executable ($1)
   8 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
   9     ## which doesn't work in ash, if /usr/bin/which isn't installed
  10     ## type -p doesn't work in ash
  11     ## command -v doesn't work in zsh
  12     ## command -v "$1" 2>&1
  13     ## this test should work in ash, bash, pdksh (ksh), zsh
  14     type -p $1 2>/dev/null | tail -n 1 | awk '{print $NF}'
  15 ])
  16
  17
  18 # Get version string from executable ($1)
  19 AC_DEFUN(STEPMAKE_GET_VERSION, [
  20     ## "$1" --version 2>&1 | grep -v '^$' | head -n 1 | awk '{print $NF}'
  21     ##
  22     ## ARG.
  23     ## Workaround for broken Debian gcc version string:
  24     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  25     ##
  26     ## -V: Workaround for python
  27
  28     changequote(<<, >>)#dnl
  29
  30     ## Assume and hunt for dotted version multiplet.
  31     ## use eval trickery, because we cannot use multi-level $() instead of ``
  32     ## for compatibility reasons.
  33
  34     ## grab the first version number in  --version output.
  35     eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 |
  36                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  37                 head -n 1 |
  38                 tr ' ' '\n' |
  39                 sed 's/\([0-9][0-9]*\.[0-9][0-9.]*\).*/\1/g' |
  40                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  41                 head -n 1\`\"
  42
  43     if test -z "$_ver"; then
  44         ## If empty, try date [fontforge]
  45         eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '[0-9]\{6,8\}' \
  46             | head -n 1 \
  47             | sed -e 's/^[^.0-9]*//' -e 's/[^.0-9]*$//'\`\"
  48     fi
  49     echo "$_ver"
  50     changequote([, ])#dnl
  51 ])
  52
  53 # Calculate simplistic numeric version from version string ($1)
  54 # As yet, we have no need for something more elaborate.
  55 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  56     echo "$1" | awk -F. '
  57     {
  58       if ([$]3) {three = [$]3}
  59       else {three = 0}
  60     }
  61     {printf "%.0f\n", [$]1*1000000 + [$]2*1000 + three}'
  62 ])
  63
  64
  65 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  66 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  67     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  68 ])
  69
  70 # Check if tested program ($2) was found ($1).
  71 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  72 # We could abort here if a 'REQUIRED' program is not found
  73 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  74     STEPMAKE_CHECK_SEARCH_RESULT($1)
  75     if test $? -ne 0; then
  76         STEPMAKE_ADD_ENTRY($3, $2)
  77         if test "$3" = "REQUIRED"; then
  78             command="echo ERROR: $2 not found"
  79             # abort configure process here?
  80         else
  81             command="- echo $2 not found"
  82         fi
  83         eval "$1"='$command'
  84         false
  85     else
  86         true
  87     fi
  88 ])
  89
  90
  91 # Return if tested proram ($1) was found (true) or not (false).
  92 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  93     r="`eval echo '$'"$1"`"
  94     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  95         true
  96     else
  97         ##STEPMAKE_WARN(cannot find $2. $3)
  98         false
  99     fi
 100 ])
 101
 102
 103 # Check version of program ($1)
 104 # If version ($4: optional argument, supply if version cannot be
 105 # parsed using --version or -V ) is smaller than requested ($3), add
 106 # entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
 107 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
 108     r="`eval echo '$'"$1"`"
 109     AC_MSG_CHECKING([$r version])
 110     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 111     if test -n "$4"; then
 112         ver="$4"
 113     else
 114         ver=`STEPMAKE_GET_VERSION($exe)`
 115     fi
 116     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 117     req=`STEPMAKE_NUMERIC_VERSION($3)`
 118     AC_MSG_RESULT([$ver])
 119     if test "$num" -lt "$req"; then
 120         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
 121     fi
 122     vervar="`echo $1 | tr '[a-z]' '[A-Z]'`_VERSION"
 123     eval `echo $vervar=$num`
 124 ##    AC_SUBST(`eval echo $vervar`)
 125 ])
 126
 127 # Check version of program ($1)
 128 # If version is greater than or equals unsupported ($3),
 129 # add entry to unsupported list ($2, 'UNSUPPORTED')
 130 AC_DEFUN(STEPMAKE_CHECK_VERSION_UNSUPPORTED, [
 131     r="`eval echo '$'"$1"`"
 132     AC_MSG_CHECKING([$r version])
 133     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 134     ver=`STEPMAKE_GET_VERSION($exe)`
 135     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 136     sup=`STEPMAKE_NUMERIC_VERSION($3)`
 137     AC_MSG_RESULT([$ver])
 138     if test "$num" -ge "$sup"; then
 139         STEPMAKE_ADD_ENTRY($2, ["$r < $3 (installed: $ver)"])
 140     fi
 141 ])
 142
 143 ### Macros to build configure.in
 144
 145
 146 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 147     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 148     if test "$BIBTEX2HTML" = "bib2html"; then
 149         BIBTEX2HTML_FLAGS='$< $(@)'
 150     else
 151         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 152     fi
 153     AC_SUBST(BIBTEX2HTML)
 154     AC_SUBST(BIBTEX2HTML_FLAGS)
 155 ])
 156
 157
 158 AC_DEFUN(STEPMAKE_BISON, [
 159     # ugh, automake: we want (and check for) bison
 160     AC_PROG_YACC
 161
 162     STEPMAKE_PROGS(BISON, bison, $1)
 163
 164     # urg.  should test functionality rather than version.
 165     if test "$BISON" = "bison" -a -n "$2"; then
 166         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 167     fi
 168 ])
 169
 170 AC_DEFUN(STEPMAKE_COMPILE_BEFORE, [
 171     # -O is necessary to get inlining
 172     CFLAGS=${CFLAGS-""}
 173     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 174     LDFLAGS=${LDFLAGS-""}
 175     optimise_b=yes
 176     profile_b=no
 177     debug_b=yes
 178     pipe_b=yes
 179
 180     AC_ARG_ENABLE(debugging,
 181     [AS_HELP_STRING([--enable-debugging],
 182                     [compile with debugging info.  Default: on])],
 183     [debug_b=$enableval])
 184
 185     AC_ARG_ENABLE(optimising,
 186     [AS_HELP_STRING([--enable-optimising],
 187                     [compile with optimising.  Default: on])],
 188     [optimise_b=$enableval])
 189
 190     AC_ARG_ENABLE(profiling,
 191     [AS_HELP_STRING([--enable-profiling],
 192                     [compile with gprof support.  Default: off])],
 193     [profile_b=$enableval])
 194
 195     AC_ARG_ENABLE(pipe,
 196     [AS_HELP_STRING([--enable-pipe],
 197                     [compile with -pipe.  Default: on])],
 198     [pipe_b=$enableval])
 199
 200     if test "$optimise_b" = yes; then
 201         AC_DEFINE(NDEBUG)
 202         DEFINES="$DEFINES -DNDEBUG"
 203         OPTIMIZE=" -O2 -finline-functions"
 204     fi
 205
 206     if test $profile_b = yes; then
 207         EXTRA_LIBS="-pg"
 208         OPTIMIZE="$OPTIMIZE -pg"
 209     fi
 210
 211     if test $debug_b = yes; then
 212         OPTIMIZE="$OPTIMIZE -g"
 213     fi
 214 ])
 215
 216 AC_DEFUN(STEPMAKE_COMPILE, [
 217
 218     AC_REQUIRE([STEPMAKE_COMPILE_BEFORE])
 219     AC_REQUIRE([AC_PROG_CC])
 220
 221     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 222     LD='$(CC)'
 223     AC_SUBST(LD)
 224
 225     # If -pipe requested, test if it works and add to CFLAGS.
 226     if test "$pipe_b" = yes; then
 227         save_cflags="$CFLAGS"
 228         CFLAGS=" -pipe $CFLAGS";
 229         AC_CACHE_CHECK([whether compiler understands -pipe],
 230             [stepmake_cv_cflags_pipe],
 231             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[/* -pipe test */]])],
 232                 [stepmake_cv_cflags_pipe=yes],
 233                 [stepmake_cv_cflags_pipe=no]))
 234         CFLAGS=$save_cflags
 235         if test $stepmake_cv_cflags_pipe = yes; then
 236             OPTIMIZE="$OPTIMIZE -pipe"
 237         fi
 238     fi
 239
 240     CFLAGS="$CFLAGS $OPTIMIZE"
 241     CPPFLAGS=${CPPFLAGS-""}
 242
 243     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 244     save_cflags="$CFLAGS"
 245     case "$host" in
 246         alpha*-*-*)
 247             dnl should do compile test?
 248             AC_MSG_RESULT(-mieee)
 249             CFLAGS=" -mieee $CFLAGS"
 250             ;;
 251         *)
 252             AC_MSG_RESULT([none])
 253             ;;
 254     esac
 255
 256     AC_SUBST(cross_compiling)
 257     AC_SUBST(CFLAGS)
 258     AC_SUBST(CPPFLAGS)
 259     AC_SUBST(LDFLAGS)
 260     AC_SUBST(DEFINES)
 261     AC_SUBST(EXTRA_LIBS)
 262 ])
 263
 264 AC_DEFUN(STEPMAKE_CXX, [
 265     AC_PROG_CXX
 266     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 267
 268     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 269     LD='$(CXX)'
 270
 271     AC_SUBST(CXX)
 272     AC_SUBST(CXXFLAGS)
 273     AC_SUBST(LD)
 274 ])
 275
 276
 277 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 278     AC_CACHE_CHECK([whether explicit instantiation is needed],
 279         stepmake_cv_need_explicit_instantiation,
 280         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 281     template <class T> struct foo { static int baz; };
 282     template <class T> int foo<T>::baz = 1;
 283     ]], [[ return foo<int>::baz; ]])],[stepmake_cv_need_explicit_instantiation=no],[stepmake_cv_need_explicit_instantiation=yes]))
 284     if test x"$stepmake_cv_need_explicit_instantiation"x = x"yes"x; then
 285         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 286     fi
 287 ])
 288
 289 AC_DEFUN(STEPMAKE_GXXCODEGENBUG, [
 290     AC_MSG_CHECKING([options for known g++ tail call bug])
 291     case "$GXX:$CXX_VERSION" in
 292         yes:400600?)
 293             AC_MSG_RESULT([-fno-optimize-sibling-calls])
 294             CXXFLAGS="$CXXFLAGS -fno-optimize-sibling-calls"
 295             ;;
 296         *) AC_MSG_RESULT([none])
 297     esac
 298     AC_SUBST(CXXFLAGS)
 299 ])
 300
 301
 302 AC_DEFUN(STEPMAKE_DATADIR, [
 303     if test "$datadir" = "\${prefix}/share"; then
 304             datadir='${prefix}/share'
 305     fi
 306     presome=${prefix}
 307     if test "$prefix" = "NONE"; then
 308         presome=${ac_default_prefix}
 309     fi
 310
 311     build_package_datadir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/share/$package
 312
 313     DATADIR=`echo ${datadir} | sed "s!\\\${datarootdir}!${prefix}/share!"`
 314     DATADIR=`echo ${DATADIR} | sed "s!\\\${prefix}!$presome!"`
 315     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 316
 317     AC_SUBST(datadir)
 318     AC_SUBST(datarootdir)
 319     AC_SUBST(build_package_datadir)
 320     AC_DEFINE_UNQUOTED(DATADIR, ["${DATADIR}"])
 321     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, ["${BUILD_PACKAGE_DATADIR}"])
 322 ])
 323
 324 ## ugh: cut & paste programming from datadir.
 325 AC_DEFUN(STEPMAKE_LIBDIR, [
 326
 327     if test "$libdir" = "\${exec_prefix}/lib"; then
 328         libdir='${exec_prefix}/lib'
 329     fi
 330     presome=$exec_prefix
 331     build_package_libdir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/lib/$package
 332
 333     LIBDIR=`echo ${libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 334     BUILD_PACKAGE_LIBDIR=`echo ${build_package_libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 335
 336     AC_SUBST(libdir)
 337     AC_SUBST(build_package_libdir)
 338     AC_DEFINE_UNQUOTED(LIBDIR, ["${LIBDIR}"])
 339     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_LIBDIR, ["${BUILD_PACKAGE_LIBDIR}"])
 340 ])
 341
 342
 343 AC_DEFUN(STEPMAKE_PREFIX_EXPAND_FIXUP, [
 344     # undo expanding of explicit --infodir=/usr/share
 345     # to ease install-time override with prefix=...
 346     strip=`echo $includedir | eval sed s@^$prefix@@`
 347     if test "$includedir" = "`eval echo $prefix$strip`"; then
 348             includedir='${prefix}'$strip''
 349     fi
 350     strip=`echo $libdir | eval sed s@^$exec_prefix@@`
 351     if test "$libdir" = "`eval echo $exec_prefix$strip`"; then
 352             libdir='${exec_prefix}'$strip''
 353     fi
 354     strip=`echo $infodir | eval sed s@^$datarootdir@@`
 355     if test "$infodir" = "`eval echo $datarootdir$strip`"; then
 356             infodir='${datarootdir}'$strip''
 357     fi
 358     strip=`echo $mandir | eval sed s@^$datarootdir@@`
 359     if test "$mandir" = "`eval echo $datarootdir$strip`"; then
 360             mandir='${datarootdir}'$strip''
 361     fi
 362 ])
 363
 364
 365 AC_DEFUN(STEPMAKE_END, [
 366     STEPMAKE_PREFIX_EXPAND_FIXUP
 367
 368     AC_SUBST(OPTIONAL)
 369     AC_SUBST(REQUIRED)
 370
 371     AC_CONFIG_FILES([$CONFIGFILE.make:config.make.in])
 372     AC_OUTPUT
 373
 374     if test -n "$OPTIONAL"; then
 375         echo
 376         echo "WARNING: Please consider installing optional programs: $OPTIONAL"
 377     fi
 378
 379     if test -n "$REQUIRED"; then
 380         echo
 381         echo "ERROR: Please install required programs: $REQUIRED"
 382     fi
 383
 384     if test -n "$UNSUPPORTED"; then
 385         echo
 386         echo "ERROR: Please use older version of programs: $UNSUPPORTED"
 387     fi
 388
 389     if test -n "$OPTIONAL$REQUIRED$UNSUPPORTED"; then
 390         echo
 391         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 392         if test -f config.cache ; then
 393             echo "Remove config.cache before rerunning ./configure"
 394         fi
 395     fi
 396
 397     if test -n "$REQUIRED$UNSUPPORTED"; then
 398         rm -f $srcdir/GNUmakefile
 399         exit 1
 400     fi
 401
 402     # regular in-place build
 403     # test for srcdir_build = yes ?
 404     if test "$srcdir_build" = "yes"; then
 405         rm -f $srcdir/GNUmakefile
 406         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 407         chmod 444 $srcdir/GNUmakefile
 408     else
 409         if test -f $srcdir/GNUmakefile; then
 410             cat <<EOF
 411 Source directory already configured.  Please clean the source directory
 412
 413      make -C $srcdir distclean
 414
 415 and rerun configure.
 416 EOF
 417             exit 2
 418         fi
 419
 420         abssrcdir="`cd $srcdir; pwd`"
 421         absbuilddir="`pwd`"
 422         for d in 2 3 4 5 ; do
 423             for mf in `cd $srcdir ; find . -maxdepth $d -mindepth $d -name GNUmakefile`; do
 424                 case "$abssrcdir" in
 425                     "$absbuilddir"/*)
 426 # source is below build directory, always copy
 427                         ;;
 428                     *)
 429                         case "$abssrcdir/${mf#./}" in
 430                             "$absbuilddir"/*)
 431 # find descended into build directory, don't copy
 432                                 continue
 433                         esac
 434                 esac
 435                 mkdir -p ${mf%/*}
 436                 cat <<EOF | $PYTHON -  > $mf
 437 print 'depth=' + ('../' * ( $d-1 ) )
 438 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 439 print 'include \$(configure-srcdir)/$mf'
 440 print 'MODULE_INCLUDES += \$(src-dir)/\$(outbase)'
 441 EOF
 442             done
 443             for mf in `cd $srcdir ; find . -maxdepth $d -mindepth $d -name '*.make' | grep -v config.make `; do
 444                 case "$abssrcdir" in
 445                     "$absbuilddir"/*)
 446 # source is below build directory, always copy
 447                         ;;
 448                     *)
 449                         case "$abssrcdir/${mf#./}" in
 450                             "$absbuilddir"/*)
 451 # find descended into build directory, don't copy
 452                                 continue
 453                         esac
 454                 esac
 455                 mkdir -p ${mf%/*}
 456                 cat <<EOF | $PYTHON -  > $mf
 457 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 458 print 'include \$(configure-srcdir)/$mf'
 459 EOF
 460             done
 461         done
 462
 463         rm -f GNUmakefile
 464         cat <<EOF > GNUmakefile
 465 depth = .
 466 include config\$(if \$(conf),-\$(conf),).make
 467 include \$(configure-srcdir)/GNUmakefile.in
 468 EOF
 469         chmod 444 GNUmakefile
 470         AC_SUBST(VPATH)
 471     fi
 472 ])
 473
 474
 475 AC_DEFUN(STEPMAKE_FLEX, [
 476     # ugh, automake: we want (and check for) flex
 477     # AC_PROG_LEX
 478     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 479
 480     # AC_PROG_LEX()
 481     # ugh, ugh
 482     ac_cv_prog_lex_root=lex.yy
 483     STEPMAKE_PROGS(FLEX, flex, $1)
 484 ])
 485
 486
 487 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 488     AC_CHECK_HEADERS([FlexLexer.h],[true],[false])
 489     if test $? -ne 0; then
 490         warn='FlexLexer.h (flex package)'
 491         STEPMAKE_ADD_ENTRY($1, $warn)
 492     fi
 493     # check for yyFlexLexer.yy_current_buffer,
 494     # in 2.5.4 <= flex < 2.5.29
 495     AC_CACHE_CHECK([for yyFlexLexer.yy_current_buffer],
 496         [stepmake_cv_flexlexer_yy_current_buffer],
 497         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 498 using namespace std;
 499 #include <FlexLexer.h>
 500 class yy_flex_lexer: public yyFlexLexer
 501 {
 502   public:
 503     yy_flex_lexer ()
 504     {
 505       yy_current_buffer = 0;
 506     }
 507 };
 508 ]])],
 509             [stepmake_cv_flexlexer_yy_current_buffer=yes],
 510             [stepmake_cv_flexlexer_yy_current_buffer=no]))
 511     if test $stepmake_cv_flexlexer_yy_current_buffer = yes; then
 512         AC_DEFINE(HAVE_FLEXLEXER_YY_CURRENT_BUFFER, 1, [Define to 1 if yyFlexLexer has yy_current_buffer.])
 513     fi
 514 ])
 515
 516
 517
 518 AC_DEFUN(STEPMAKE_FLEXLEXER_LOCATION, [
 519         AC_MSG_CHECKING([FlexLexer.h location])
 520
 521         # ugh.
 522         cat <<EOF > conftest.cc
 523 using namespace std;
 524 #include <FlexLexer.h>
 525 EOF
 526         FLEXLEXER_FILE=`eval $ac_cpp conftest.cc | \
 527           sed 's!# 1 "\(.*FlexLexer.h\)"!@FLEXLEXER@\1@@!g' | grep '@@' | \
 528           sed 's!.*@FLEXLEXER@\(.*\)@@.*$!\1!g' ` 1> /dev/null 2> /dev/null
 529         rm conftest.cc
 530         AC_SUBST(FLEXLEXER_FILE)
 531         AC_MSG_RESULT($FLEXLEXER_FILE)
 532 ])
 533
 534 AC_DEFUN(STEPMAKE_GCC_OR_CLANG, [
 535     STEPMAKE_HAS_CLANG()
 536     if test "$HAS_CLANG" = "no"; then
 537         if test "$GCC" = "yes"; then
 538             STEPMAKE_CHECK_VERSION(CC, $1, $2)
 539         else
 540             warn="$CC (Please install *GNU* cc)"
 541             STEPMAKE_ADD_ENTRY($1, $warn)
 542         fi
 543     fi
 544     # no else, we're fine with any clang
 545 ])
 546
 547 AC_DEFUN(STEPMAKE_GETTEXT, [
 548     presome=${prefix}
 549     if test "$prefix" = "NONE"; then
 550             presome=${ac_default_prefix}
 551     fi
 552     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 553
 554     AC_SUBST(localedir)
 555     AC_DEFINE_UNQUOTED(LOCALEDIR, ["${LOCALEDIR}"])
 556     AC_CHECK_LIB(intl, gettext)
 557     AC_CHECK_FUNCS(gettext)
 558 ])
 559
 560
 561 AC_DEFUN(STEPMAKE_GUILE, [
 562     STEPMAKE_PATH_PROG(GUILE, guile guile1, $1)
 563 ])
 564
 565
 566 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 567 #
 568 #   This macro runs the guile-config script, installed with Guile,
 569 #   to find out where Guile's header files and libraries are
 570 #   installed.  It sets two variables, marked for substitution, as
 571 #   by AC_SUBST.
 572 #
 573 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 574 #             code that uses Guile header files.  This is almost
 575 #             always just a -I flag.
 576 #
 577 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 578 #             program against Guile.  This includes -lguile for
 579 #             the Guile library itself, any libraries that Guile
 580 #             itself requires (like -lqthreads), and so on.  It may
 581 #             also include a -L flag to tell the compiler where to
 582 #             find the libraries.
 583
 584 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 585     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 586     if test -x $exe; then
 587         AC_MSG_CHECKING([guile compile flags])
 588         GUILE_CFLAGS="`$guile_config compile`"
 589         AC_MSG_RESULT($GUILE_CFLAGS)
 590         AC_MSG_CHECKING([guile link flags])
 591         GUILE_LDFLAGS="`$guile_config link`"
 592         AC_MSG_RESULT($GUILE_LDFLAGS)
 593     fi
 594     AC_SUBST(GUILE_CFLAGS)
 595     AC_SUBST(GUILE_LDFLAGS)
 596 ])
 597
 598
 599 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 600     ## First, let's just see if we can find Guile at all.
 601     test -n "$target_alias" && target_guile_config=$target_alias-guile-config
 602     test -n "$host_alias" && host_guile_config=$host_alias-guile-config
 603     AC_MSG_CHECKING([for guile-config])
 604     for guile_config in $GUILE_CONFIG $target_guile_config $host_guile_config $build_guile_config guile-config guile1-config; do
 605         AC_MSG_RESULT([$guile_config])
 606         if ! $guile_config --version > /dev/null 2>&1 ; then
 607             AC_MSG_WARN([cannot execute $guile_config])
 608             AC_MSG_CHECKING([if we are cross compiling])
 609             GUILE_CONFIG='echo no guile-config'
 610         else
 611             GUILE_CONFIG=$guile_config
 612             break
 613         fi
 614     done
 615     STEPMAKE_OPTIONAL_REQUIRED(GUILE_CONFIG, $guile_config, $1)
 616     if test $? -ne 0; then
 617         STEPMAKE_ADD_ENTRY($1, 'guile-config (guile-devel, guile-dev or libguile-dev package) or guile1-config (guile1-devel package)')
 618     fi
 619
 620     STEPMAKE_CHECK_SEARCH_RESULT(GUILE_CONFIG)
 621     # urg.  should test functionality rather than version.
 622     if test $? -eq 0 -a -n "$2"; then
 623         STEPMAKE_CHECK_VERSION(GUILE_CONFIG, $1, $2)
 624     fi
 625
 626     AC_SUBST(GUILE_CONFIG)
 627
 628     guile_version="$ver"
 629     changequote(<<, >>)#dnl
 630     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 631     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 632     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 633     changequote([, ])#dnl
 634     STEPMAKE_GUILE_FLAGS
 635     save_CPPFLAGS="$CPPFLAGS"
 636     save_LIBS="$LIBS"
 637     CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 638     LIBS="$GUILE_LDFLAGS $LIBS"
 639     AC_CHECK_HEADERS([libguile.h])
 640     AC_CHECK_LIB(guile, scm_boot_guile)
 641     AC_CHECK_FUNCS(scm_boot_guile,,libguile_b=no)
 642     if test "$libguile_b" = "no"; then
 643             warn='libguile (libguile-dev, guile-devel or guile-dev
 644    package).'
 645             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 646     fi
 647     CPPFLAGS="$save_CPPFLAGS"
 648     LIBS="$save_LIBS"
 649     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 650     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 651     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 652 ])
 653
 654
 655 AC_DEFUN(STEPMAKE_DLOPEN, [
 656     AC_CHECK_LIB(dl, dlopen)
 657     AC_CHECK_FUNCS(dlopen)
 658 ])
 659
 660 AC_DEFUN(STEPMAKE_HAS_CLANG, [
 661     AC_EGREP_CPP(yes,
 662       [#ifdef __clang__
 663        yes
 664        #endif
 665       ], HAS_CLANG=yes, HAS_CLANG=no)
 666 ])
 667
 668 AC_DEFUN(STEPMAKE_GXX_OR_CLANG, [
 669     STEPMAKE_HAS_CLANG()
 670     if test "$HAS_CLANG" = "no"; then
 671         if test "$GXX" = "yes"; then
 672             STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 673         else
 674             warn="$CXX (Please install *GNU* c++)"
 675             STEPMAKE_ADD_ENTRY($1, $warn)
 676         fi
 677     fi
 678     # no else, we're fine with any clang
 679 ])
 680
 681
 682 AC_DEFUN(STEPMAKE_INIT, [
 683
 684     . $srcdir/VERSION
 685     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 686     MICRO_VERSION=$PATCH_LEVEL
 687     TOPLEVEL_VERSION=$FULL_VERSION
 688     if test x$MY_PATCH_LEVEL != x; then
 689         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 690     fi
 691     VERSION=$FULL_VERSION
 692     export MAJOR_VERSION MINOR_VERSION PATCH_LEVEL
 693     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 694     changequote(<<, >>)#dnl
 695     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 696     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 697     changequote([, ])#dnl
 698
 699     # No versioning on directory names of sub-packages
 700     # urg, urg
 701     stepmake=${datadir}/stepmake
 702     presome=${prefix}
 703     if test "$prefix" = "NONE"; then
 704             presome=${ac_default_prefix}
 705     fi
 706     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 707
 708     # urg, how is this supposed to work?
 709     if test "$program_prefix" = "NONE"; then
 710           program_prefix=
 711     fi
 712     if test "$program_suffix" = "NONE"; then
 713           program_suffix=
 714     fi
 715
 716     AC_MSG_CHECKING(Package)
 717     if test "$PACKAGE" = "STEPMAKE"; then
 718         AC_MSG_RESULT(Stepmake package!)
 719
 720         AC_MSG_CHECKING(builddir)
 721
 722         ugh_ugh_autoconf250_builddir="`pwd`"
 723
 724         if test "$srcdir" = "."; then
 725             srcdir_build=yes
 726         else
 727             srcdir_build=no
 728             package_builddir="`dirname $ugh_ugh_autoconf250_builddir`"
 729             package_srcdir="`dirname  $srcdir`"
 730         fi
 731         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 732
 733         (cd stepmake 2>/dev/null || mkdir stepmake)
 734         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 735         stepmake=stepmake
 736     else
 737         AC_MSG_RESULT($PACKAGE)
 738
 739         AC_MSG_CHECKING(builddir)
 740         ugh_ugh_autoconf250_builddir="`pwd`"
 741
 742         here_dir=$(cd . && pwd)
 743         full_src_dir=$(cd $srcdir && pwd)
 744
 745         if test "$full_src_dir" = "$here_dir"; then
 746             srcdir_build=yes
 747         else
 748             srcdir_build=no
 749         fi
 750         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 751
 752         AC_MSG_CHECKING(for stepmake)
 753         # Check for installed stepmake
 754         if test -d $stepmake; then
 755             AC_MSG_RESULT($stepmake)
 756         else
 757             stepmake="`cd $srcdir/stepmake; pwd`"
 758             AC_MSG_RESULT([$srcdir/stepmake  ($datadir/stepmake not found)])
 759         fi
 760     fi
 761
 762     AC_SUBST(ugh_ugh_autoconf250_builddir)
 763
 764     # Use absolute directory for non-srcdir builds, so that build
 765     # dir can be moved.
 766     if test "$srcdir_build" = "no" ;  then
 767         srcdir="`cd $srcdir; pwd`"
 768     fi
 769
 770     AC_SUBST(srcdir)
 771     AC_SUBST(stepmake)
 772     AC_SUBST(package)
 773     AC_SUBST(PACKAGE)
 774     AC_SUBST(PACKAGE_NAME)
 775     AC_SUBST(VERSION)
 776     AC_SUBST(MAJOR_VERSION)
 777     AC_SUBST(MINOR_VERSION)
 778     AC_SUBST(MICRO_VERSION)
 779
 780     # stepmake nonstandard names
 781     AC_SUBST(PATCH_LEVEL)
 782     AC_SUBST(TOPLEVEL_VERSION)
 783
 784     # We don't need the upper case variant,
 785     # so stick to macros are uppercase convention.
 786     # AC_DEFINE_UNQUOTED(package, ["${package}"])
 787     # AC_DEFINE_UNQUOTED(PACKAGE, ["${PACKAGE}"])
 788     AC_DEFINE_UNQUOTED(PACKAGE, ["${package}"])
 789     AC_DEFINE_UNQUOTED(PACKAGE_NAME, ["${PACKAGE_NAME}"])
 790     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, ["${FULL_VERSION}"])
 791
 792     if test -z "$package_depth"; then
 793         package_depth="."
 794     else
 795         package_depth="../$package_depth"
 796     fi
 797     export package_depth
 798     AC_SUBST(package_depth)
 799
 800     AUTOGENERATE="This file was automatically generated by configure"
 801     AC_SUBST(AUTOGENERATE)
 802
 803     CONFIGSUFFIX=
 804     AC_ARG_ENABLE(config,
 805     [AS_HELP_STRING([--enable-config=CONF],
 806                     [put settings in config-CONF.make and config-CONF.h;
 807                     do `make conf=CONF' to get output in ./out-CONF])],
 808     [CONFIGURATION=$enableval])
 809
 810     ##'`#
 811
 812     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 813     CONFIGFILE=config$CONFIGSUFFIX
 814     AC_SUBST(CONFIGSUFFIX)
 815
 816     AC_CANONICAL_HOST
 817     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 818     STEPMAKE_PROGS(FIND, find, REQUIRED)
 819
 820     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 821
 822     if test "$(echo 2)" != "2" ||
 823         test "x`uname`" = "xHP-UX"; then
 824         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 825         AC_PATH_PROG(BASH, bash, $KSH)
 826         STEPMAKE_WARN(avoiding buggy /bin/sh)
 827         AC_PATH_PROG(SHELL, bash, $KSH)
 828     else
 829         SHELL=/bin/sh
 830         AC_PATH_PROG(BASH, bash, $SHELL)
 831     fi
 832     AC_SUBST(SHELL)
 833
 834     STEPMAKE_PYTHON(REQUIRED, 1.5)
 835
 836     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 837         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 838         if test "$?" = 1; then
 839             warn='make (Please install *GNU* make)'
 840             # STEPMAKE_WARN($warn)
 841             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 842         fi
 843     fi
 844
 845     ROOTSEP=':'
 846     DIRSEP='/'
 847     PATHSEP=':'
 848     LN=ln
 849     LN_S='ln -s'
 850     ZIP="zip -r -9"
 851
 852     AC_SUBST(program_prefix)
 853     AC_SUBST(program_suffix)
 854     AC_SUBST(ZIP)
 855     AC_SUBST(LN)
 856     AC_SUBST(LN_S)
 857     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
 858     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
 859     AC_SUBST(DIRSEP)
 860     AC_SUBST(PATHSEP)
 861     AC_SUBST(ROOTSEP)
 862
 863     STEPMAKE_DATADIR
 864     STEPMAKE_LIBDIR
 865 ])
 866
 867
 868 AC_DEFUN(STEPMAKE_LIB, [
 869     STEPMAKE_PROGS(AR, ar, $1)
 870     AC_PROG_RANLIB
 871     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 872 ])
 873
 874
 875 AC_DEFUN(STEPMAKE_LIBTOOL, [
 876     # libtool.info ...
 877     # **Never** try to set library version numbers so that they correspond
 878     # to the release number of your package.  This is an abuse that only
 879     # fosters misunderstanding of the purpose of library versions.
 880
 881     REVISION=$PATCH_LEVEL
 882     # CURRENT=$MINOR_VERSION
 883     CURRENT=`expr $MINOR_VERSION + 1`
 884     # AGE=`expr $MAJOR_VERSION + 1`
 885     AGE=$MAJOR_VERSION
 886     AC_SUBST(CURRENT)
 887     AC_SUBST(REVISION)
 888     AC_SUBST(AGE)
 889 ])
 890
 891
 892 AC_DEFUN(STEPMAKE_LOCALE, [
 893     lang=English
 894     ALL_LINGUAS="en nl"
 895
 896     # with/enable ??
 897     AC_ARG_WITH(localedir,
 898     [AS_HELP_STRING([--with-localedir=DIR],
 899                     [location of locales.  Default: PREFIX/share/locale])],
 900     localedir=$with_localedir,
 901     localedir='${prefix}/share/locale')
 902
 903     AC_ARG_WITH(lang,
 904     [AS_HELP_STRING([--with-lang=LANG],
 905                     [use LANG as language to emit messages])],
 906     language=$with_lang,
 907     language=English)
 908
 909     AC_MSG_CHECKING(language)
 910     case "$language" in
 911       En* | en* | Am* | am* | US* | us*)
 912             lang=English;;
 913       NL | nl | Du* | du* | Ned* | ned*)
 914             lang=Dutch;;
 915       "")
 916             lang=English;;
 917       *)
 918             lang=unknown;;
 919     esac
 920     AC_MSG_RESULT($lang)
 921
 922     if test "$lang" = "unknown" ; then
 923         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 924     fi
 925
 926 ])
 927
 928
 929 AC_DEFUN(STEPMAKE_MAKEINFO, [
 930     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 931 ])
 932
 933
 934 AC_DEFUN(STEPMAKE_MAN, [
 935     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 936     AC_SUBST(GROFF)
 937     STEPMAKE_PROGS(TROFF, troff, $1)
 938     AC_SUBST(TROFF)
 939     STEPMAKE_PROGS(TBL, tbl, $1)
 940     AC_SUBST(TBL)
 941 ])
 942
 943
 944 AC_DEFUN(STEPMAKE_MSGFMT, [
 945     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
 946 ])
 947
 948
 949 # Check for program ($2), set full path result to ($1).
 950 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 951 AC_DEFUN(STEPMAKE_PATH_PROG, [
 952     AC_CHECK_PROGS($1, $2, no)
 953     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 954     if test $? -eq 0; then
 955         AC_PATH_PROGS($1, $2)
 956         if test -n "$4"; then
 957             STEPMAKE_CHECK_VERSION($1, $3, $4)
 958         fi
 959     fi
 960 ])
 961
 962
 963 # Check for program in set of names ($2), set result to ($1) .
 964 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 965 # If exists, and a minimal version ($4) is required
 966 AC_DEFUN(STEPMAKE_PROGS, [
 967     AC_CHECK_PROGS($1, $2, no)
 968     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 969     if test $? -eq 0 -a -n "$4"; then
 970         STEPMAKE_CHECK_VERSION($1, $3, $4)
 971     fi
 972 ])
 973
 974
 975 AC_DEFUN(STEPMAKE_PERL, [
 976     STEPMAKE_PATH_PROG(PERL, perl, $1)
 977 ])
 978
 979
 980 AC_DEFUN(STEPMAKE_PYTHON, [
 981     unset pv
 982     AC_MSG_CHECKING([for python])
 983     for python in $PYTHON python python2 python2.4 python2.3 python2.2 python2.1 python2.0; do
 984         AC_MSG_RESULT([$python])
 985         if ! $python -V > /dev/null 2>&1 ; then
 986             #AC_MSG_WARN([cannot execute $python])
 987             PYTHON='echo no python'
 988         else
 989             unset pv
 990             STEPMAKE_CHECK_VERSION(python, pv, $2)
 991             if test -z "$pv"; then
 992                 PYTHON=$python
 993                 break
 994             fi
 995         fi
 996     done
 997     if test -n "$pv"; then
 998         STEPMAKE_ADD_ENTRY($1, $pv)
 999     fi
1000     # clear cached value since arg 2 might point us to a new binary
1001     unset ac_cv_path_PYTHON
1002
1003     AC_PATH_PROG(PYTHON, $PYTHON)
1004     AC_SUBST(PYTHON)
1005 ])
1006
1007 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
1008     AC_ARG_WITH(python-include,
1009         [AS_HELP_STRING([--with-python-include=DIR],
1010                         [location of the python include dir])],[
1011         if test "$withval" = "yes" -o "$withval" = "no"; then
1012             AC_MSG_WARN(Usage: --with-python-include=includedir)
1013         else
1014             PYTHON_CFLAGS="-I${withval}"
1015         fi
1016     ])
1017
1018     AC_ARG_WITH(python-lib,
1019         [AS_HELP_STRING([--with-python-lib=NAME],
1020                         [name of the python lib])],[
1021         if test "$withval" = "yes" -o "$withval" = "no"; then
1022             AC_MSG_WARN(Usage: --with-python-lib=name)
1023         else
1024             LDFLAGS="$LDFLAGS -l${withval}"
1025         fi
1026     ])
1027
1028     AC_CHECK_PROGS(PYTHON_CONFIG, python-config, no)
1029
1030     if test -z "$PYTHON_CFLAGS" -a "$PYTHON_CONFIG" != "no"; then
1031         # Clean out junk: http://bugs.python.org/issue3290
1032         # Python headers may need some -f* flags, leave them in.
1033         # We want the sed commands to look like 's/-[WDOm][[:alnum:][:punct:]][[:alnum:][:punct:]]*//g' and 's/-arch [^[:space:]]*//g', but automake eats brackets.
1034         PYTHON_CFLAGS=`$PYTHON_CONFIG --cflags | sed -e 's/-[[WDOm]][[[:alnum:][:punct:]]][[[:alnum:][:punct:]]]*//g' | sed -e 's/-arch @<:@^@<:@:space:@:>@@:>@*//g'`
1035         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
1036     fi
1037
1038     if test -z "$PYTHON_CFLAGS" -a "$cross_compiling" = "no"; then
1039         changequote(<<, >>)#dnl
1040         # alternatively, for python >= 2.0
1041         # 'import sys, distutils.sysconfig; sys.stdout.write (distutils.sysconfig.get_python_inc ())'
1042         PYTHON_INCLUDE=`$PYTHON -c 'import sys; sys.stdout.write ("%s/include/python%s" % (sys.prefix, sys.version[:3]))'`
1043         PYTHON_CFLAGS="-I$PYTHON_INCLUDE"
1044         changequote([, ])#dnl
1045     fi
1046
1047     if test -z "$PYTHON_HEADER"; then
1048         CPPFLAGS="$PYTHON_CFLAGS $CPPFLAGS"
1049         AC_CHECK_HEADERS([Python.h],[PYTHON_HEADER=yes])
1050     fi
1051
1052     if test -z "$PYTHON_HEADER"; then
1053         warn="Python.h (python-devel, python-dev or libpython-dev package)"
1054         STEPMAKE_ADD_ENTRY($1, $warn)
1055     fi
1056 ])
1057
1058
1059
1060 AC_DEFUN(STEPMAKE_STL_DATA_METHOD, [
1061     AC_CACHE_CHECK([for stl.data () method],
1062         [stepmake_cv_stl_data_method],
1063         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1064 #include <vector>
1065 using namespace std;
1066 vector <int> v;
1067 void *p = v.data ();
1068 ]])],
1069             [stepmake_cv_stl_data_method=yes],
1070             [stepmake_cv_stl_data_method=no]))
1071     if test $stepmake_cv_stl_data_method = yes; then
1072         AC_DEFINE(HAVE_STL_DATA_METHOD, 1, [define if stl classes have data () method])
1073     fi
1074 ])
1075
1076
1077 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
1078     # ugh
1079     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, OPTIONAL)
1080 ])
1081
1082 AC_DEFUN(STEPMAKE_TEXMF, [
1083     STEPMAKE_PROGS(METAFONT, mf-nowin mf mfw mfont, $1)
1084     STEPMAKE_PROGS(METAPOST, mpost, $1)
1085
1086     AC_MSG_CHECKING(for working metafont mode)
1087     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
1088     for MFMODE in $modelist; do
1089         $METAFONT -progname=mf "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
1090         if test -f mfput.tfm; then
1091             break;
1092         fi
1093     done
1094     AC_MSG_RESULT($MFMODE)
1095
1096     rm -f mfput.*
1097
1098     AC_SUBST(MFMODE)
1099 ])
1100
1101
1102 AC_DEFUN(STEPMAKE_WARN, [
1103     AC_MSG_WARN($1)
1104     warn_b=yes
1105 ])
1106
1107
1108 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1109 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1110 dnl also defines GSTUFF_PKG_ERRORS on error
1111 AC_DEFUN(PKG_CHECK_MODULES, [
1112   succeeded=no
1113
1114   if test -z "$PKG_CONFIG"; then
1115     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1116   fi
1117
1118   if test "$PKG_CONFIG" = "no" ; then
1119      echo "*** The pkg-config script could not be found. Make sure it is"
1120      echo "*** in your path, or set the PKG_CONFIG environment variable"
1121      echo "*** to the full path to pkg-config."
1122      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1123   else
1124      PKG_CONFIG_MIN_VERSION=0.9.0
1125      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1126         AC_MSG_CHECKING(for $2)
1127
1128         if $PKG_CONFIG --exists "$2" ; then
1129             AC_MSG_RESULT(yes)
1130             succeeded=yes
1131
1132             AC_MSG_CHECKING($1_CFLAGS)
1133             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1134             AC_MSG_RESULT($$1_CFLAGS)
1135
1136             AC_MSG_CHECKING($1_LIBS)
1137             $1_LIBS=`$PKG_CONFIG --libs "$2"`
1138             AC_MSG_RESULT($$1_LIBS)
1139         else
1140             $1_CFLAGS=""
1141             $1_LIBS=""
1142             ## If we have a custom action on failure, don't print errors, but
1143             ## do set a variable so people can do so.
1144             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1145             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1146         fi
1147
1148         AC_SUBST($1_CFLAGS)
1149         AC_SUBST($1_LIBS)
1150      fi
1151   fi
1152
1153   if test $succeeded = yes; then
1154      ifelse([$3], , :, [$3])
1155   else
1156      ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
1157   fi
1158 ])
1159
1160 AC_DEFUN(STEPMAKE_FREETYPE2, [
1161     PKG_CHECK_MODULES(FREETYPE2, $1 >= $3, have_freetype2=yes, true)
1162     if test "$have_freetype2" = yes; then
1163         AC_DEFINE(HAVE_FREETYPE2)
1164         save_CPPFLAGS="$CPPFLAGS"
1165         save_LIBS="$LIBS"
1166         CPPFLAGS="$FREETYPE2_CFLAGS $CPPFLAGS"
1167         LIBS="$FREETYPE2_LIBS $LIBS"
1168         AC_SUBST(FREETYPE2_CFLAGS)
1169         AC_SUBST(FREETYPE2_LIBS)
1170         CPPFLAGS="$save_CPPFLAGS"
1171         LIBS="$save_LIBS"
1172     else
1173         # UGR
1174         #r="lib$1-dev or $1-devel"
1175         r="libfreetype6-dev or freetype?-devel"
1176         ver="`pkg-config --modversion $1`"
1177         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1178     fi
1179 ])
1180
1181 AC_DEFUN(STEPMAKE_PANGO, [
1182     PKG_CHECK_MODULES(PANGO, $1 >= $3, have_pango16=yes, true)
1183     if test "$have_pango16" = yes ; then
1184         AC_DEFINE(HAVE_PANGO16)
1185         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1186         save_CPPFLAGS="$CPPFLAGS"
1187         save_LIBS="$LIBS"
1188         CPPFLAGS="$PANGO_CFLAGS $CPPFLAGS"
1189         LIBS="$PANGO_LIBS $LIBS"
1190         AC_CHECK_HEADERS([pango/pangofc-fontmap.h])
1191         AC_CHECK_FUNCS([pango_fc_font_map_add_decoder_find_func])
1192         AC_SUBST(PANGO_CFLAGS)
1193         AC_SUBST(PANGO_LIBS)
1194         CPPFLAGS="$save_CPPFLAGS"
1195         LIBS="$save_LIBS"
1196     else
1197         # UGR
1198         #r="lib$1-dev or $1-devel"
1199         r="libpango1.0-dev or pango1.0-devel"
1200         ver="`pkg-config --modversion $1`"
1201         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1202     fi
1203 ])
1204
1205 AC_DEFUN(STEPMAKE_PANGO_FT2, [
1206     PKG_CHECK_MODULES(PANGO_FT2, $1 >= $3, have_pangoft2=yes, true)
1207     if test "$have_pangoft2" = yes ; then
1208         AC_DEFINE(HAVE_PANGO16)
1209         AC_DEFINE(HAVE_PANGO_FT2)
1210         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1211         save_CPPFLAGS="$CPPFLAGS"
1212         save_LIBS="$LIBS"
1213         CPPFLAGS="$CPPFLAGS $PANGO_FT2_CFLAGS"
1214         LIBS="$PANGO_FT2_LIBS $LIBS"
1215         AC_CHECK_HEADERS([pango/pangoft2.h])
1216         AC_CHECK_FUNCS([pango_ft2_font_map_create_context])
1217         AC_SUBST(PANGO_FT2_CFLAGS)
1218         AC_SUBST(PANGO_FT2_LIBS)
1219         CPPFLAGS="$save_CPPFLAGS"
1220         LIBS="$save_LIBS"
1221     else
1222         # UGR
1223         #r="lib$1-dev or $1-devel"e
1224         r="libpango1.0-dev or pango?-devel"
1225         ver="`pkg-config --modversion $1`"
1226         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1227     fi
1228 ])
1229
1230 AC_DEFUN(STEPMAKE_FONTCONFIG, [
1231     PKG_CHECK_MODULES(FONTCONFIG, $1 >= $3, have_fontconfig=yes, true)
1232     if test "$have_fontconfig" = yes ; then
1233         AC_DEFINE(HAVE_FONTCONFIG)
1234         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1235         save_CPPFLAGS="$CPPFLAGS"
1236         save_LIBS="$LIBS"
1237         CPPFLAGS="$FONTCONFIG_CFLAGS $CPPFLAGS"
1238         LIBS="$FONTCONFIG_LIBS $LIBS"
1239         AC_SUBST(FONTCONFIG_CFLAGS)
1240         AC_SUBST(FONTCONFIG_LIBS)
1241         CPPFLAGS="$save_CPPFLAGS"
1242         LIBS="$save_LIBS"
1243     else
1244         r="lib$1-dev or $1-devel"
1245         ver="`pkg-config --modversion $1`"
1246         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1247     fi
1248 ])
1249
1250 AC_DEFUN(STEPMAKE_WINDOWS, [
1251     AC_CYGWIN
1252     AC_MINGW32
1253
1254     if test "$CYGWIN" = "yes"; then
1255         LN_S='cp -r' # Cygwin symbolic links do not work for native apps.
1256         program_suffix=.exe
1257         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1258     elif test "$MINGW32" = "yes"; then
1259         LN='cp -r'
1260         LN_S='cp -r'
1261         program_suffix=.exe
1262         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1263         PATHSEP=';'
1264     fi
1265
1266     AC_SUBST(LN)
1267     AC_SUBST(LN_S)
1268     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
1269     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
1270     AC_SUBST(DIRSEP)
1271     AC_SUBST(PATHSEP)
1272     AC_SUBST(program_suffix)
1273
1274     AC_MSG_CHECKING([for some flavor of Windows])
1275     if test "$CYGWIN$MINGW32" = "nono"; then
1276         PLATFORM_WINDOWS=no
1277     else
1278         PLATFORM_WINDOWS=yes
1279     fi
1280     AC_MSG_RESULT([$PLATFORM_WINDOWS])
1281     AC_SUBST(PLATFORM_WINDOWS)
1282     STEPMAKE_PROGS(WINDRES, $target-windres windres, x)
1283     AC_SUBST(WINDRES)
1284 ])