scm/translation-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; (c) 1998--2015 Han-Wen Nienhuys <hanwen@xs4all.nl>
   4 ;;;;                 Jan Nieuwenhuizen <janneke@gnu.org>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19
  20 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21 ;; clefs
  22
  23 (define-public (clef-transposition-markup oct style)
  24   "The transposition sign formatting function.  @var{oct} is supposed to be
  25 a string holding the transposition number, @var{style} determines the
  26 way the transposition number is displayed."
  27   (let* ((delim (if (symbol? style)
  28                     (case style
  29                       ((parenthesized) (cons "(" ")"))
  30                       ((bracketed) (cons "[" "]"))
  31                       (else (cons "" "")))
  32                     (cons "" "")))
  33          (text (string-concatenate (list (car delim) oct (cdr delim)))))
  34
  35     (make-vcenter-markup text)))
  36
  37
  38 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  39 ;; metronome marks
  40
  41 (define-public (format-metronome-markup event context)
  42    (let ((hide-note (ly:context-property context 'tempoHideNote #f))
  43          (text (ly:event-property event 'text))
  44          (dur (ly:event-property event 'tempo-unit))
  45          (count (ly:event-property event 'metronome-count)))
  46    (metronome-markup text dur count hide-note)))
  47 (export format-metronome-markup)
  48
  49 (define (metronome-markup text dur count hide-note)
  50   (let* ((note-mark
  51             (if (and (not hide-note) (ly:duration? dur))
  52                 (make-smaller-markup
  53                   (make-note-by-number-markup
  54                     (ly:duration-log dur)
  55                     (ly:duration-dot-count dur)
  56                     UP))
  57                 #f))
  58          (count-markup (cond ((number? count)
  59                               (if (> count 0)
  60                                   (make-simple-markup
  61                                           (number->string count))
  62                                   #f))
  63                              ((pair? count)
  64                               (make-concat-markup
  65                                (list
  66                                 (make-simple-markup
  67                                         (number->string (car count)))
  68                                 (make-simple-markup " ")
  69                                 (make-simple-markup "–")
  70                                 (make-simple-markup " ")
  71                                 (make-simple-markup
  72                                         (number->string (cdr count))))))
  73                              (else #f)))
  74          (note-markup (if (and (not hide-note) count-markup)
  75                           (make-concat-markup
  76                            (list
  77                             (make-general-align-markup Y DOWN note-mark)
  78                             (make-simple-markup " ")
  79                             (make-simple-markup "=")
  80                             (make-simple-markup " ")
  81                             count-markup))
  82                           #f))
  83          (text-markup (if (not (null? text))
  84                           (make-bold-markup text)
  85                           #f)))
  86     (if text-markup
  87         (if (and note-markup (not hide-note))
  88             (make-line-markup (list text-markup
  89                                     (make-concat-markup
  90                                      (list (make-simple-markup "(")
  91                                            note-markup
  92                                            (make-simple-markup ")")))))
  93             (make-line-markup (list text-markup)))
  94         (if note-markup
  95             (make-line-markup (list note-markup))
  96             (make-null-markup)))))
  97
  98 (define-public (format-mark-alphabet mark context)
  99   (make-bold-markup (make-markalphabet-markup (1- mark))))
 100
 101 (define-public (format-mark-box-alphabet mark context)
 102   (make-bold-markup (make-box-markup (make-markalphabet-markup (1- mark)))))
 103
 104 (define-public (format-mark-circle-alphabet mark context)
 105   (make-bold-markup (make-circle-markup (make-markalphabet-markup (1- mark)))))
 106
 107 (define-public (format-mark-letters mark context)
 108   (make-bold-markup (make-markletter-markup (1- mark))))
 109
 110 (define-public (format-mark-numbers mark context)
 111   (make-bold-markup (number->string mark)))
 112
 113 (define-public (format-mark-barnumbers mark context)
 114   (make-bold-markup (number->string (ly:context-property context
 115                                                          'currentBarNumber))))
 116
 117 (define-public (format-mark-box-letters mark context)
 118   (make-bold-markup (make-box-markup (make-markletter-markup (1- mark)))))
 119
 120 (define-public (format-mark-circle-letters mark context)
 121   (make-bold-markup (make-circle-markup (make-markletter-markup (1- mark)))))
 122
 123 (define-public (format-mark-box-numbers mark context)
 124   (make-bold-markup (make-box-markup (number->string mark))))
 125
 126 (define-public (format-mark-circle-numbers mark context)
 127   (make-bold-markup (make-circle-markup (number->string mark))))
 128
 129 (define-public (format-mark-box-barnumbers mark context)
 130   (make-bold-markup (make-box-markup
 131                      (number->string (ly:context-property context
 132                                                           'currentBarNumber)))))
 133
 134 (define-public (format-mark-circle-barnumbers mark context)
 135   (make-bold-markup (make-circle-markup
 136                      (number->string (ly:context-property context
 137                                                           'currentBarNumber)))))
 138
 139
 140 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 141 ;; Bass figures.
 142
 143 (define-public (format-bass-figure figure event context)
 144   (let* ((fig (ly:event-property event 'figure))
 145          (fig-markup (if (number? figure)
 146
 147                          ;; this is not very elegant, but center-aligning
 148                          ;; all digits is problematic with other markups,
 149                          ;; and shows problems in the (lack of) overshoot
 150                          ;; of feta-alphabet glyphs.
 151                          ((if (<= 10 figure)
 152                               (lambda (y) (make-translate-scaled-markup
 153                                            (cons -0.7 0) y))
 154                               identity)
 155
 156                           (cond
 157                            ((eq? #t (ly:event-property event 'diminished))
 158                             (markup #:slashed-digit figure))
 159                            ((eq? #t (ly:event-property event 'augmented-slash))
 160                             (markup #:backslashed-digit figure))
 161                            (else (markup #:number (number->string figure 10)))))
 162                          #f))
 163
 164          (alt (ly:event-property event 'alteration))
 165          (alt-markup
 166           (if (number? alt)
 167               (markup
 168                #:general-align Y DOWN #:fontsize
 169                (if (not (= alt DOUBLE-SHARP))
 170                    -2 2)
 171                (alteration->text-accidental-markup alt))
 172               #f))
 173
 174          (plus-markup (if (eq? #t (ly:event-property event 'augmented))
 175                           (markup #:number "+")
 176                           #f))
 177
 178          (alt-dir (ly:context-property context 'figuredBassAlterationDirection))
 179          (plus-dir (ly:context-property context 'figuredBassPlusDirection)))
 180
 181     (if (and (not fig-markup) alt-markup)
 182         (begin
 183           (set! fig-markup (markup #:left-align #:pad-around 0.3 alt-markup))
 184           (set! alt-markup #f)))
 185
 186
 187     ;; hmm, how to get figures centered between note, and
 188     ;; lone accidentals too?
 189
 190     ;;    (if (markup? fig-markup)
 191     ;;  (set!
 192     ;;   fig-markup (markup #:translate (cons 1.0 0)
 193     ;;                      #:center-align fig-markup)))
 194
 195     (if alt-markup
 196         (set! fig-markup
 197               (markup #:put-adjacent
 198                       X (if (number? alt-dir)
 199                             alt-dir
 200                             LEFT)
 201                       fig-markup
 202                       #:pad-x 0.2 alt-markup)))
 203
 204     (if plus-markup
 205         (set! fig-markup
 206               (if fig-markup
 207                   (markup #:put-adjacent
 208                           X (if (number? plus-dir)
 209                                 plus-dir
 210                                 LEFT)
 211                           fig-markup
 212                           #:pad-x 0.2 plus-markup)
 213                   plus-markup)))
 214
 215     (if (markup? fig-markup)
 216         (markup #:fontsize -2 fig-markup)
 217         empty-markup)))
 218
 219
 220 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 221 ;; fret diagrams
 222
 223 (define (create-fretboard context grob placement-list)
 224   "Convert @var{placement-list} into a fretboard @var{grob}."
 225
 226   (let* ((tunings (ly:context-property context 'stringTunings))
 227          (my-string-count (length tunings))
 228          (details (ly:grob-property grob 'fret-diagram-details)))
 229
 230     ;; Add string-count from string-tunings to fret-diagram-details.
 231     (set! (ly:grob-property grob 'fret-diagram-details)
 232           (acons 'string-count my-string-count details))
 233     ;; Create the dot-placement list for the grob
 234     (set! (ly:grob-property grob 'dot-placement-list) placement-list)))
 235
 236 (define-public
 237   (determine-frets context notes specified-info . rest)
 238   "Determine string numbers and frets for playing @var{notes}
 239 as a chord, given specified information @var{specified-info}.
 240 @var{specified-info} is a list with two list elements,
 241 specified strings @code{defined-strings} and
 242 specified fingerings @code{defined-fingers}.  Only a fingering of@tie{}0
 243 will affect the fret selection, as it specifies an open string.
 244 If @code{defined-strings} is @code{'()}, the context property
 245 @code{defaultStrings} will be used as a list of defined strings.
 246 Will look for predefined fretboards if @code{predefinedFretboardTable}
 247 is not @code {#f}.  If @var{rest} is present, it contains the
 248 @code{FretBoard} grob, and a fretboard will be
 249 created.  Otherwise, a list of @code{(string fret finger)} lists will
 250 be returned.
 251 If the context-property @code{supportNonIntegerFret} is set @code{#t},
 252 micro-tones are supported for TabStaff, but not not for FretBoards."
 253
 254   ;;  helper functions
 255
 256   (define (string-frets->placement-list string-frets string-count)
 257     "Convert @var{string-frets} to @code{fret-diagram-verbose}
 258 dot placement entries."
 259     (let* ((placements (list->vector
 260                         (map (lambda (x) (list 'mute  x))
 261                              (iota string-count 1)))))
 262
 263       (for-each (lambda (sf)
 264                   (let* ((string (car sf))
 265                          (fret (cadr sf))
 266                          (finger (caddr sf)))
 267                     (vector-set!
 268                      placements
 269                      (1- string)
 270                      (if (= 0 fret)
 271                          (list 'open string)
 272                          (if finger
 273                              (list 'place-fret string fret finger)
 274                              (list 'place-fret string fret))))))
 275                 string-frets)
 276       (vector->list placements)))
 277
 278   (define (placement-list->string-frets placement-list)
 279     "Convert @var{placement-list} to string-fret list."
 280     (map (lambda (x) (if (eq? (car x) 'place-fret)
 281                          (cdr x)
 282                          (list (cadr x) 0)))
 283          (filter (lambda (l) (or (eq? (car l) 'place-fret)
 284                                  (eq? (car l) 'open)))
 285                  placement-list)))
 286
 287   (define (entry-count art-list)
 288     "Count the number of entries in a list of articulations."
 289     (length (filter (lambda (x) (not (null? x)))
 290                     art-list)))
 291
 292   (define (string-number event)
 293     "Get the string-number from @var{event}.  Return @var{#f}
 294 if no string-number is present."
 295     (let ((num (ly:event-property event 'string-number)))
 296       (and (integer? num) (positive? num) num)))
 297
 298   (define (determine-frets-and-strings
 299            notes
 300            defined-strings
 301            defined-fingers
 302            minimum-fret
 303            maximum-stretch
 304            tuning)
 305     "Determine the frets and strings used to play the notes in
 306 @var{notes}, given @var{defined-strings} and @var{defined-fingers}
 307 along with @var{minimum-fret}, @var{maximum-stretch}, and
 308 @var{tuning}.  Returns a list of @code{(string fret finger) lists."
 309
 310
 311     (define restrain-open-strings (ly:context-property context
 312                                                        'restrainOpenStrings
 313                                                        #f))
 314     (define specified-frets '())
 315     (define free-strings (iota (length tuning) 1))
 316
 317     (define (calc-fret pitch string tuning)
 318       "Calculate the fret to play @var{pitch} on @var{string} with
 319 @var{tuning}."
 320       (* 2  (- (ly:pitch-tones pitch) (ly:pitch-tones (list-ref tuning (1- string))))))
 321
 322     (define (note-pitch note)
 323       "Get the pitch (in semitones) from @var{note}."
 324       (ly:event-property note 'pitch))
 325
 326     (define (note-finger ev)
 327       "Get the fingering from @var{ev}.  Return @var{#f}
 328 if no fingering is present."
 329       (let* ((articulations (ly:event-property ev 'articulations))
 330              (finger-found #f))
 331         (for-each (lambda (art)
 332                     (let* ((num (ly:event-property art 'digit)))
 333
 334                       (if (and (ly:in-event-class? art 'fingering-event)
 335                                (number? num)
 336                                (> num 0))
 337                           (set! finger-found num))))
 338                   articulations)
 339         finger-found))
 340
 341     (define (delete-free-string string)
 342       (if (number? string)
 343           (set! free-strings
 344                 (delete string free-strings))))
 345
 346     (define (close-enough fret)
 347       "Decide if @var{fret} is acceptable, given the already used frets."
 348       (every (lambda (specced-fret)
 349                (or (zero? specced-fret)
 350                    (zero? fret)
 351                    (>= maximum-stretch (abs (- fret specced-fret)))))
 352              specified-frets))
 353
 354     (define (string-qualifies string pitch)
 355       "Can @var{pitch} be played on @var{string}, given already placed
 356 notes?"
 357       (let* ((fret (calc-fret pitch string tuning)))
 358         (and (or (and (not restrain-open-strings)
 359                       (zero? fret))
 360                  (>= fret minimum-fret))
 361              (if (and
 362                    (ly:context-property context 'supportNonIntegerFret #f)
 363                    (null? rest))
 364                  (integer? (truncate fret))
 365                  (integer? fret))
 366              (close-enough fret))))
 367
 368     (define (open-string string pitch)
 369       "Is @var{pitch} and open-string note on @var{string}, given
 370 the current tuning?"
 371       (let* ((fret (calc-fret pitch string tuning)))
 372         (zero? fret)))
 373
 374     (define (set-fret! pitch-entry string finger)
 375       (let ((this-fret (calc-fret (car pitch-entry)
 376                                   string
 377                                   tuning)))
 378         (if (< this-fret 0)
 379             (ly:warning (_ "Negative fret for pitch ~a on string ~a")
 380                         (car pitch-entry) string)
 381             (if (and
 382                   (not (integer? this-fret))
 383                   (not (ly:context-property context 'supportNonIntegerFret #f)))
 384                 (ly:warning (_ "Missing fret for pitch ~a on string ~a")
 385                             (car pitch-entry) string)))
 386         (delete-free-string string)
 387         (set! specified-frets (cons this-fret specified-frets))
 388         (list-set! string-fret-fingers
 389                    (cdr pitch-entry)
 390                    (list string this-fret finger))))
 391
 392     (define (kill-note! string-fret-fingers note-index)
 393       (list-set! string-fret-fingers note-index (list #f #t)))
 394
 395     (define string-fret-fingers
 396       (map (lambda (string finger)
 397              (if (null? finger)
 398                  (list string #f)
 399                  (list string #f finger)))
 400            defined-strings defined-fingers))
 401
 402     ;;; body of determine-frets-and-strings
 403     (let* ((pitches (map note-pitch notes))
 404            (pitch-alist (map cons pitches (iota (length pitches)))))
 405
 406       ;; handle notes with strings assigned and fingering of 0
 407       (for-each
 408        (lambda (pitch-entry string-fret-finger)
 409          (let* ((string (list-ref string-fret-finger 0))
 410                 (finger (if (= (length string-fret-finger) 3)
 411                             (list-ref string-fret-finger 2)
 412                             '()))
 413                 (pitch (car pitch-entry))
 414                 (digit (if (null? finger)
 415                            #f
 416                            finger)))
 417            (if (or (not (null? string))
 418                    (eqv? digit 0))
 419                (if (eqv? digit 0)
 420                    ;; here we handle fingers of 0 -- open strings
 421                    (let ((fit-string
 422                           (find (lambda (string)
 423                                   (open-string string pitch))
 424                                 free-strings)))
 425                      (if fit-string
 426                          (set-fret! pitch-entry fit-string #f)
 427                          (ly:warning (_ "No open string for pitch ~a")
 428                                      pitch)))
 429                    ;; here we handle assigned strings
 430                    (let ((this-fret
 431                           (calc-fret pitch string tuning))
 432                          (handle-negative
 433                           (ly:context-property context
 434                                                'handleNegativeFrets
 435                                                'recalculate)))
 436                      (cond ((or (and (>= this-fret 0) (integer? this-fret))
 437                                 (eq? handle-negative 'include))
 438                             (set-fret! pitch-entry string finger))
 439                            ((eq? handle-negative 'recalculate)
 440                             (begin
 441                               (ly:warning
 442                                (_ "Requested string for pitch requires negative fret: string ~a pitch ~a")
 443                                string
 444                                pitch)
 445                               (ly:warning (_ "Ignoring string request and recalculating."))
 446                               (list-set! string-fret-fingers
 447                                          (cdr pitch-entry)
 448                                          (if (null? finger)
 449                                              (list '() #f)
 450                                              (list '() #f finger)))))
 451                            ((eq? handle-negative 'ignore)
 452                             (begin
 453                               (ly:warning
 454                                (_ "Requested string for pitch requires negative fret: string ~a pitch ~a")
 455                                string
 456                                pitch)
 457                               (ly:warning (_ "Ignoring note in tablature."))
 458                               (kill-note! string-fret-fingers
 459                                           (cdr pitch-entry))))))))))
 460        pitch-alist string-fret-fingers)
 461       ;; handle notes without strings assigned -- sorted by pitch, so
 462       ;; we need to use the alist to have the note number available
 463       (for-each
 464        (lambda (pitch-entry)
 465          (let* ((string-fret-finger (list-ref string-fret-fingers
 466                                               (cdr pitch-entry)))
 467                 (string (list-ref string-fret-finger 0))
 468                 (finger (if (= (length string-fret-finger) 3)
 469                             (list-ref string-fret-finger 2)
 470                             '()))
 471                 (pitch (car pitch-entry))
 472                 (fit-string
 473                  (find (lambda (string)
 474                          (string-qualifies string pitch))
 475                        free-strings)))
 476            (if (not (list-ref string-fret-finger 1))
 477                (if fit-string
 478                    (set-fret! pitch-entry fit-string finger)
 479                    (begin
 480                      (ly:event-warning
 481                       (list-ref notes (cdr pitch-entry))
 482                       (_ "No string for pitch ~a (given frets ~a)")
 483                       pitch
 484                       specified-frets)
 485                      (kill-note! string-fret-fingers
 486                                  (cdr pitch-entry)))))))
 487        (sort pitch-alist (lambda (pitch-entry-a pitch-entry-b)
 488                            (ly:pitch<? (car pitch-entry-b)
 489                                        (car pitch-entry-a)))))
 490       string-fret-fingers)) ;; end of determine-frets-and-strings
 491
 492   (define (get-predefined-fretboard predefined-fret-table tuning pitches)
 493     "Search through @var{predefined-fret-table} looking for a predefined
 494 fretboard with a key of @var{(tuning . pitches)}.  The search will check
 495 both up and down an octave in order to accomodate transposition of the
 496 chords.  Returns a placement-list."
 497
 498     (define (get-fretboard key)
 499       (let ((hash-handle
 500              (hash-get-handle predefined-fret-table key)))
 501         (if hash-handle
 502             (cdr hash-handle)  ; return table entry
 503             '())))
 504
 505     ;; body of get-predefined-fretboard
 506     (let ((test-fretboard (get-fretboard (cons tuning pitches))))
 507       (if (not (null? test-fretboard))
 508           test-fretboard
 509           (let ((test-fretboard
 510                  (get-fretboard
 511                   (cons tuning (map (lambda (x) (shift-octave x 1)) pitches)))))
 512             (if (not (null? test-fretboard))
 513                 test-fretboard
 514                 (get-fretboard
 515                  (cons tuning (map (lambda (x) (shift-octave x -1))
 516                                    pitches))))))))
 517
 518   ;; body of determine-frets
 519   (let* ((predefined-fret-table
 520           (ly:context-property context 'predefinedDiagramTable))
 521          (tunings (ly:context-property context 'stringTunings))
 522          (string-count (length tunings))
 523          (grob (if (null? rest) '() (car rest)))
 524          (pitches (map (lambda (x) (ly:event-property x 'pitch)) notes))
 525          (defined-strings (map (lambda (x)
 526                                  (if (null? x)
 527                                      x
 528                                      (or (string-number x) '())))
 529                                (car specified-info)))
 530          (defined-fingers (map (lambda (x)
 531                                  (if (null? x)
 532                                      x
 533                                      (ly:event-property x 'digit)))
 534                                (cadr specified-info)))
 535          (default-strings (ly:context-property context 'defaultStrings '()))
 536          (strings-used (if (and (zero? (entry-count defined-strings))
 537                                 (not (zero? (entry-count default-strings))))
 538                            default-strings
 539                            defined-strings))
 540          (predefined-fretboard
 541           (if predefined-fret-table
 542               (get-predefined-fretboard
 543                predefined-fret-table
 544                tunings
 545                pitches)
 546               '())))
 547     (if (null? predefined-fretboard)
 548         (let ((string-frets
 549                (determine-frets-and-strings
 550                 notes
 551                 strings-used
 552                 defined-fingers
 553                 (ly:context-property context 'minimumFret 0)
 554                 (ly:context-property context 'maximumFretStretch 4)
 555                 tunings)))
 556           (if (null? grob)
 557               string-frets
 558               (create-fretboard
 559                context grob (string-frets->placement-list
 560                              (filter (lambda (entry)
 561                                        (car entry))
 562                                      string-frets)
 563                              string-count))))
 564         (if (null? grob)
 565             (placement-list->string-frets predefined-fretboard)
 566             (create-fretboard context grob predefined-fretboard)))))
 567
 568
 569
 570 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 571 ;; tablature
 572
 573 ;; The TabNoteHead tablatureFormat callbacks.
 574
 575 ;; Calculate the fret from pitch and string number as letter
 576 ;; The fret letter is taken from 'fretLabels if present
 577 (define-public (fret-letter-tablature-format
 578                 context string-number fret-number)
 579   (let ((labels (ly:context-property context 'fretLabels)))
 580     (make-translate-scaled-markup '(0 . -0.5)
 581      (cond
 582       ((= 0 (length labels))
 583        (string (integer->char (+ fret-number (char->integer #\a)))))
 584       ((and (<= 0 fret-number) (< fret-number (length labels)))
 585        (list-ref labels fret-number))
 586       (else
 587        (ly:warning (_ "No label for fret ~a (on string ~a);
 588 only ~a fret labels provided")
 589                    fret-number string-number (length labels))
 590        ".")))))
 591
 592 ;; Display the fret number as a number
 593 (define-public (fret-number-tablature-format
 594                 context string-number fret-number)
 595   (if (integer? fret-number)
 596       (make-vcenter-markup
 597         (format #f "~a" fret-number))
 598       ;; for non-integer fret-number print p.e. "2½"
 599       (let* ((whole-part (truncate fret-number))
 600              (remaining (- fret-number whole-part))
 601              (fret
 602                (if (and (zero? whole-part) (not (zero? remaining)))
 603                    ""
 604                    (format #f "~a" whole-part)))
 605              (frac
 606                (if (zero? remaining)
 607                    ""
 608                    (format #f "~a" remaining))))
 609         (make-concat-markup
 610           (list (make-vcenter-markup fret)
 611                 (make-vcenter-markup
 612                   ;; the value `-2.5' is my choice
 613                   (make-fontsize-markup -2.5 frac)))))))
 614
 615 ;; The 5-string banjo has got an extra string, the fifth (duh), which
 616 ;; starts at the fifth fret on the neck.  Frets on the fifth string
 617 ;; are referred to relative to the other frets:
 618 ;;   the "first fret" on the fifth string is really the sixth fret
 619 ;;   on the banjo neck.
 620 ;; We solve this by defining a new fret-number-tablature function:
 621 (define-public (fret-number-tablature-format-banjo
 622                 context string-number fret-number)
 623   (make-vcenter-markup
 624    (number->string (cond
 625                     ((and (> fret-number 0) (= string-number 5))
 626                      (+ fret-number 5))
 627                     (else fret-number)))))
 628
 629 ;;  Tab note head staff position functions
 630 ;;
 631 ;;  Define where in the staff to display a given string.  Some forms of
 632 ;;  tablature put the tab note heads in the spaces, rather than on the
 633 ;;  lines
 634
 635 (define-public (tablature-position-on-lines context string-number)
 636   (let* ((string-tunings (ly:context-property context 'stringTunings))
 637          (string-count (length string-tunings))
 638          (string-one-topmost (ly:context-property context 'stringOneTopmost))
 639          (staff-line (- (* 2 string-number) string-count 1)))
 640     (if string-one-topmost
 641         (- staff-line)
 642         staff-line)))
 643
 644 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 645 ;; bar numbers
 646
 647 (define ((every-nth-bar-number-visible n) barnum mp)
 648   (= 0 (modulo barnum n)))
 649 (export every-nth-bar-number-visible)
 650
 651 (define ((modulo-bar-number-visible n m) barnum mp)
 652   (and (> barnum 1) (= m (modulo barnum n))))
 653 (export modulo-bar-number-visible)
 654
 655 (define ((set-bar-number-visibility n) tr)
 656   (let ((bn (ly:context-property tr 'currentBarNumber)))
 657     (ly:context-set-property! tr 'barNumberVisibility
 658                               (modulo-bar-number-visible n (modulo bn n)))))
 659 (export set-bar-number-visibility)
 660
 661 (define-public (first-bar-number-invisible barnum mp)
 662   (> barnum 1))
 663
 664 (define-public (first-bar-number-invisible-save-broken-bars barnum mp)
 665   (or (> barnum 1)
 666       (> (ly:moment-main-numerator mp) 0)))
 667
 668 (define-public (first-bar-number-invisible-and-no-parenthesized-bar-numbers barnum mp)
 669   (and (> barnum 1)
 670        (= (ly:moment-main-numerator mp) 0)))
 671
 672 (define-public (robust-bar-number-function barnum measure-pos alt-number context)
 673   (define (get-number-and-power an pow)
 674     (if (<= an alt-number)
 675         (get-number-and-power (+ an (expt 26 (1+ pow))) (1+ pow))
 676         (cons (+ alt-number (- (expt 26 pow) an)) (1- pow))))
 677   (define (make-letter so-far an pow)
 678     (if (< pow 0)
 679         so-far
 680         (let ((pos (modulo (quotient an (expt 26 pow)) 26)))
 681           (make-letter (string-append so-far
 682                                       (substring "abcdefghijklmnopqrstuvwxyz"
 683                                                  pos
 684                                                  (1+ pos)))
 685                        an
 686                        (1- pow)))))
 687   (let* ((number-and-power (get-number-and-power 0 0))
 688          (begin-measure (= 0 (ly:moment-main-numerator measure-pos)))
 689          (maybe-open-parenthesis (if begin-measure "" "("))
 690          (maybe-close-parenthesis (if begin-measure "" ")")))
 691     (markup (string-append maybe-open-parenthesis
 692                            (number->string barnum)
 693                            (make-letter ""
 694                                         (car number-and-power)
 695                                         (cdr number-and-power))
 696                            maybe-close-parenthesis))))
 697
 698 (define-public (all-bar-numbers-visible barnum mp) #t)
 699
 700
 701 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 702 ;; percent repeat counters
 703
 704 (define ((every-nth-repeat-count-visible n) count context)
 705   (= 0 (modulo count n)))
 706 (export every-nth-repeat-count-visible)
 707
 708 (define-public (all-repeat-counts-visible count context) #t)
 709
 710 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 711 ;; pitch recognition
 712
 713 (define-public (make-semitone->pitch pitches)
 714   "Convert @var{pitches}, an unordered list of note values
 715 covering (after disregarding octaves) all absolute pitches in need of
 716 conversion, into a function converting semitone numbers (absolute
 717 pitch missing enharmonic information) back into note values.
 718
 719 For a key signature without accidentals
 720 @example
 721 c cis d es e f fis g gis a bes b
 722 @end example
 723 might be a good choice, covering Bb major to A major and their
 724 parallel keys, and melodic/harmonic C minor to A minor."
 725   ;; TODO: short-circuit lcm calculation once we know it will be large
 726   (let* ((size (apply lcm (map (lambda (pitch)
 727                                  (denominator (/ (ly:pitch-tones pitch) 6)))
 728                                pitches)))
 729          ;; Normal tunings need 12 steps per octave, quartertone
 730          ;; tunings 24, Makam needs 108.  But microtunings might cause
 731          ;; trouble.
 732          (lookup (if (> size 400)
 733                      (make-hash-table)
 734                      (make-vector size #f))))
 735     (for-each
 736      (lambda (pitch)
 737        (let* ((rawoct (/ (ly:pitch-tones pitch) 6))
 738               (oct (floor rawoct))
 739               (ref (- rawoct oct))
 740               (val (ly:pitch-transpose pitch
 741                                        (ly:make-pitch (- oct) 0))))
 742          (if (hash-table? lookup)
 743              (hashv-set! lookup ref val)
 744              (vector-set! lookup (* size ref) val))))
 745      pitches)
 746     (lambda (semitone)
 747       "Convert @var{semitone} numbers into note values.  If the
 748 originally specified list of pitches does not contain a note
 749 corresponding to @var{semitone} (disregarding octaves), @code{#f} is
 750 returned."
 751       (let* ((rawoct (/ semitone 12))
 752              (oct (floor rawoct))
 753              (ref (- rawoct oct))
 754              (val (if (hash-table? lookup)
 755                       (hashv-ref lookup ref)
 756                       (let ((ref (* (vector-length lookup) ref)))
 757                         (and (integer? ref)
 758                              (vector-ref lookup ref))))))
 759         (and val
 760              (ly:pitch-transpose val (ly:make-pitch oct 0)))))))
 761
 762 (define ((shift-semitone->pitch key semitone->pitch) semitone)
 763   "Given a function @var{semitone->pitch} converting a semitone number
 764 into a note value for a lookup table created in relation to@tie{}C,
 765 returns a corresponding function in relation to @var{key}.  The note
 766 values returned by this function differ only enharmonically from the
 767 original @var{semitone->pitch} function."
 768   (ly:pitch-transpose (semitone->pitch (- semitone (* 2 (ly:pitch-tones key))))
 769                       key))
 770
 771 (export shift-semitone->pitch)