scm/translation-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; (c) 1998--2012 Han-Wen Nienhuys <hanwen@xs4all.nl>
   4 ;;;;                 Jan Nieuwenhuizen <janneke@gnu.org>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19
  20 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21 ;; metronome marks
  22
  23 (define-public (format-metronome-markup event context)
  24   (let ((hide-note (ly:context-property context 'tempoHideNote #f))
  25         (text (ly:event-property event 'text))
  26         (dur (ly:event-property event 'tempo-unit))
  27         (count (ly:event-property event 'metronome-count)))
  28
  29     (metronome-markup text dur count hide-note)))
  30
  31 (define-public (metronome-markup text dur count hide-note)
  32   (let* ((note-mark (if (and (not hide-note) (ly:duration? dur))
  33                         (make-smaller-markup
  34                          (make-note-by-number-markup (ly:duration-log dur)
  35                                                      (ly:duration-dot-count dur)
  36                                                      1))
  37                         #f))
  38          (count-markup (cond ((number? count)
  39                               (if (> count 0)
  40                                   (make-simple-markup (number->string count))
  41                                   #f))
  42                              ((pair? count)
  43                               (make-concat-markup
  44                                (list
  45                                 (make-simple-markup (number->string (car count)))
  46                                 (make-simple-markup " ")
  47                                 (make-simple-markup "–")
  48                                 (make-simple-markup " ")
  49                                 (make-simple-markup (number->string (cdr count))))))
  50                              (else #f)))
  51          (note-markup (if (and (not hide-note) count-markup)
  52                           (make-concat-markup
  53                            (list
  54                             (make-general-align-markup Y DOWN note-mark)
  55                             (make-simple-markup " ")
  56                             (make-simple-markup "=")
  57                             (make-simple-markup " ")
  58                             count-markup))
  59                           #f))
  60          (text-markup (if (not (null? text))
  61                           (make-bold-markup text)
  62                           #f)))
  63     (if text-markup
  64         (if (and note-markup (not hide-note))
  65             (make-line-markup (list text-markup
  66                                     (make-concat-markup
  67                                      (list (make-simple-markup "(")
  68                                            note-markup
  69                                            (make-simple-markup ")")))))
  70             (make-line-markup (list text-markup)))
  71         (if note-markup
  72             (make-line-markup (list note-markup))
  73             (make-null-markup)))))
  74
  75 (define-public (format-mark-alphabet mark context)
  76   (make-bold-markup (make-markalphabet-markup (1- mark))))
  77
  78 (define-public (format-mark-box-alphabet mark context)
  79   (make-bold-markup (make-box-markup (make-markalphabet-markup (1- mark)))))
  80
  81 (define-public (format-mark-circle-alphabet mark context)
  82   (make-bold-markup (make-circle-markup (make-markalphabet-markup (1- mark)))))
  83
  84 (define-public (format-mark-letters mark context)
  85   (make-bold-markup (make-markletter-markup (1- mark))))
  86
  87 (define-public (format-mark-numbers mark context)
  88   (make-bold-markup (number->string mark)))
  89
  90 (define-public (format-mark-barnumbers mark context)
  91   (make-bold-markup (number->string (ly:context-property context
  92                                                          'currentBarNumber))))
  93
  94 (define-public (format-mark-box-letters mark context)
  95   (make-bold-markup (make-box-markup (make-markletter-markup (1- mark)))))
  96
  97 (define-public (format-mark-circle-letters mark context)
  98   (make-bold-markup (make-circle-markup (make-markletter-markup (1- mark)))))
  99
 100 (define-public (format-mark-box-numbers mark context)
 101   (make-bold-markup (make-box-markup (number->string mark))))
 102
 103 (define-public (format-mark-circle-numbers mark context)
 104   (make-bold-markup (make-circle-markup (number->string mark))))
 105
 106 (define-public (format-mark-box-barnumbers mark context)
 107   (make-bold-markup (make-box-markup
 108                      (number->string (ly:context-property context
 109                                                           'currentBarNumber)))))
 110
 111 (define-public (format-mark-circle-barnumbers mark context)
 112   (make-bold-markup (make-circle-markup
 113                      (number->string (ly:context-property context
 114                                                           'currentBarNumber)))))
 115
 116
 117 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 118 ;; Bass figures.
 119
 120 (define-public (format-bass-figure figure event context)
 121   (let* ((fig (ly:event-property event 'figure))
 122          (fig-markup (if (number? figure)
 123
 124                          ;; this is not very elegant, but center-aligning
 125                          ;; all digits is problematic with other markups,
 126                          ;; and shows problems in the (lack of) overshoot
 127                          ;; of feta-alphabet glyphs.
 128                          ((if (<= 10 figure)
 129                               (lambda (y) (make-translate-scaled-markup
 130                                            (cons -0.7 0) y))
 131                               identity)
 132
 133                           (cond
 134                            ((eq? #t (ly:event-property event 'diminished))
 135                             (markup #:slashed-digit figure))
 136                            ((eq? #t (ly:event-property event 'augmented-slash))
 137                             (markup #:backslashed-digit figure))
 138                            (else (markup #:number (number->string figure 10)))))
 139                          #f))
 140
 141          (alt (ly:event-property event 'alteration))
 142          (alt-markup
 143           (if (number? alt)
 144               (markup
 145                #:general-align Y DOWN #:fontsize
 146                (if (not (= alt DOUBLE-SHARP))
 147                    -2 2)
 148                (alteration->text-accidental-markup alt))
 149               #f))
 150
 151          (plus-markup (if (eq? #t (ly:event-property event 'augmented))
 152                           (markup #:number "+")
 153                           #f))
 154
 155          (alt-dir (ly:context-property context 'figuredBassAlterationDirection))
 156          (plus-dir (ly:context-property context 'figuredBassPlusDirection)))
 157
 158     (if (and (not fig-markup) alt-markup)
 159         (begin
 160           (set! fig-markup (markup #:left-align #:pad-around 0.3 alt-markup))
 161           (set! alt-markup #f)))
 162
 163
 164     ;; hmm, how to get figures centered between note, and
 165     ;; lone accidentals too?
 166
 167     ;;    (if (markup? fig-markup)
 168     ;;  (set!
 169     ;;   fig-markup (markup #:translate (cons 1.0 0)
 170     ;;                      #:center-align fig-markup)))
 171
 172     (if alt-markup
 173         (set! fig-markup
 174               (markup #:put-adjacent
 175                       X (if (number? alt-dir)
 176                             alt-dir
 177                             LEFT)
 178                       fig-markup
 179                       #:pad-x 0.2 alt-markup)))
 180
 181     (if plus-markup
 182         (set! fig-markup
 183               (if fig-markup
 184                   (markup #:put-adjacent
 185                           X (if (number? plus-dir)
 186                                 plus-dir
 187                                 LEFT)
 188                           fig-markup
 189                           #:pad-x 0.2 plus-markup)
 190                   plus-markup)))
 191
 192     (if (markup? fig-markup)
 193         (markup #:fontsize -2 fig-markup)
 194         empty-markup)))
 195
 196
 197 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 198 ;; fret diagrams
 199
 200 (define (create-fretboard context grob placement-list)
 201   "Convert @var{placement-list} into a fretboard @var{grob}."
 202
 203   (let* ((tunings (ly:context-property context 'stringTunings))
 204          (my-string-count (length tunings))
 205          (details (ly:grob-property grob 'fret-diagram-details)))
 206
 207     ;; Add string-count from string-tunings to fret-diagram-details.
 208     (set! (ly:grob-property grob 'fret-diagram-details)
 209             (acons 'string-count my-string-count details))
 210     ;; Create the dot-placement list for the grob
 211     (set! (ly:grob-property grob 'dot-placement-list) placement-list)))
 212
 213 (define-public
 214   (determine-frets context notes specified-info . rest)
 215   "Determine string numbers and frets for playing @var{notes}
 216 as a chord, given specified information @var{specified-info}.
 217 @var{specified-info} is a list with two list elements,
 218 specified strings @code{defined-strings} and
 219 specified fingerings @code{defined-fingers}.  Only a fingering of@tie{}0
 220 will affect the fret selection, as it specifies an open string.
 221 If @code{defined-strings} is @code{'()}, the context property
 222 @code{defaultStrings} will be used as a list of defined strings.
 223 Will look for predefined fretboards if @code{predefinedFretboardTable}
 224 is not @code {#f}.  If @var{rest} is present, it contains the
 225 @code{FretBoard} grob, and a fretboard will be
 226 created.  Otherwise, a list of @code{(string fret finger)} lists will
 227 be returned."
 228
 229   ;;  helper functions
 230
 231   (define (string-frets->placement-list string-frets string-count)
 232     "Convert @var{string-frets} to @code{fret-diagram-verbose}
 233 dot placement entries."
 234     (let* ((placements (list->vector
 235                         (map (lambda (x) (list 'mute  x))
 236                              (iota string-count 1)))))
 237
 238       (for-each (lambda (sf)
 239                   (let* ((string (car sf))
 240                          (fret (cadr sf))
 241                          (finger (caddr sf)))
 242                     (vector-set!
 243                       placements
 244                       (1- string)
 245                       (if (= 0 fret)
 246                           (list 'open string)
 247                           (if finger
 248                               (list 'place-fret string fret finger)
 249                               (list 'place-fret string fret))))))
 250                 string-frets)
 251       (vector->list placements)))
 252
 253   (define (placement-list->string-frets placement-list)
 254     "Convert @var{placement-list} to string-fret list."
 255     (map (lambda (x) (if (eq? (car x) 'place-fret)
 256                          (cdr x)
 257                          (list (cadr x) 0)))
 258          (filter (lambda (l) (or (eq? (car l) 'place-fret)
 259                                  (eq? (car l) 'open)))
 260                  placement-list)))
 261
 262   (define (entry-count art-list)
 263     "Count the number of entries in a list of articulations."
 264     (length (filter (lambda (x) (not (null? x)))
 265                     art-list)))
 266
 267   (define (determine-frets-and-strings
 268             notes
 269             defined-strings
 270             defined-fingers
 271             minimum-fret
 272             maximum-stretch
 273             tuning)
 274     "Determine the frets and strings used to play the notes in
 275 @var{notes}, given @var{defined-strings} and @var{defined-fingers}
 276 along with @var{minimum-fret}, @var{maximum-stretch}, and
 277 @var{tuning}.  Returns a list of @code{(string fret finger) lists."
 278
 279     (define specified-frets '())
 280     (define free-strings (iota (length tuning) 1))
 281
 282     (define (calc-fret pitch string tuning)
 283       "Calculate the fret to play @var{pitch} on @var{string} with
 284 @var{tuning}."
 285       (- (ly:pitch-semitones pitch) (ly:pitch-semitones (list-ref tuning (1- string)))))
 286
 287     (define (note-pitch note)
 288       "Get the pitch (in semitones) from @var{note}."
 289       (ly:event-property note 'pitch))
 290
 291     (define (note-finger ev)
 292       "Get the fingering from @var{ev}.  Return @var{#f}
 293 if no fingering is present."
 294       (let* ((articulations (ly:event-property ev 'articulations))
 295              (finger-found #f))
 296         (map (lambda (art)
 297                (let* ((num (ly:event-property art 'digit)))
 298
 299                  (if (and (eq? 'fingering-event (ly:event-property art 'class))
 300                           (number? num)
 301                           (> num 0))
 302                    (set! finger-found num))))
 303              articulations)
 304         finger-found))
 305
 306     (define (string-number event)
 307       "Get the string-number from @var{event}.  Return @var{#f}
 308 if no string-number is present."
 309       (let ((num (ly:event-property event 'string-number)))
 310         (if (number? num)
 311           num
 312           #f)))
 313
 314     (define (delete-free-string string)
 315       (if (number? string)
 316         (set! free-strings
 317           (delete string free-strings))))
 318
 319     (define (close-enough fret)
 320       "Decide if @var{fret} is acceptable, given the already used frets."
 321       (if (null? specified-frets)
 322         #t
 323         (reduce
 324           (lambda (x y)
 325             (and x y))
 326           #t
 327           (map (lambda (specced-fret)
 328                  (or (eq? 0 specced-fret)
 329                      (>= maximum-stretch (abs (- fret specced-fret)))))
 330                specified-frets))))
 331
 332     (define (string-qualifies string pitch)
 333       "Can @var{pitch} be played on @var{string}, given already placed
 334 notes?"
 335       (let* ((fret (calc-fret pitch string tuning)))
 336         (and (>= fret minimum-fret)
 337              (close-enough fret))))
 338
 339     (define (open-string string pitch)
 340       "Is @var{pitch} and open-string note on @var{string}, given
 341 the current tuning?"
 342       (let* ((fret (calc-fret pitch string tuning)))
 343         (eq? fret 0)))
 344
 345     (define (set-fret! pitch-entry string finger)
 346       (let ((this-fret (calc-fret (car pitch-entry)
 347                                   string
 348                                   tuning)))
 349         (if (< this-fret 0)
 350           (ly:warning (_ "Negative fret for pitch ~a on string ~a")
 351                       (car pitch-entry) string))
 352         (delete-free-string string)
 353         (set! specified-frets (cons this-fret specified-frets))
 354         (list-set! string-fret-fingers
 355                    (cdr pitch-entry)
 356                    (list string this-fret finger))))
 357
 358     (define (kill-note! string-fret-fingers note-index)
 359       (list-set! string-fret-fingers note-index (list #f #t)))
 360
 361     (define string-fret-fingers
 362              (map (lambda (string finger)
 363                     (if (null? finger)
 364                         (list string #f)
 365                         (list string #f finger)))
 366                   defined-strings defined-fingers))
 367
 368     ;;; body of determine-frets-and-strings
 369     (let* ((pitch-alist (apply (lambda (mylist)
 370                                  (let ((index -1))
 371                                    (map (lambda (note)
 372                                           (begin
 373                                             (set! index (1+ index))
 374                                             (cons (note-pitch note)
 375                                                   index)))
 376                                         mylist)))
 377                                notes '()))
 378            (pitches (map note-pitch notes)))
 379
 380       ;; handle notes with strings assigned and fingering of 0
 381       (for-each
 382         (lambda (pitch-entry string-fret-finger)
 383           (let* ((string (list-ref string-fret-finger 0))
 384                  (finger (if (eq? (length string-fret-finger) 3)
 385                              (list-ref string-fret-finger 2)
 386                              '()))
 387                  (pitch (car pitch-entry))
 388                  (digit (if (null? finger)
 389                             #f
 390                             finger)))
 391             (if (or (not (null? string))
 392                     (eq? digit 0))
 393                 (if (eq? digit 0)
 394                     ;; here we handle fingers of 0 -- open strings
 395                     (let ((fit-string
 396                             (find (lambda (string)
 397                                     (open-string string pitch))
 398                                   free-strings)))
 399                       (if fit-string
 400                           (set-fret! pitch-entry fit-string #f)
 401                           (ly:warning (_ "No open string for pitch ~a")
 402                                       pitch)))
 403                     ;; here we handle assigned strings
 404                     (let ((this-fret
 405                             (calc-fret pitch string tuning))
 406                           (handle-negative
 407                             (ly:context-property context
 408                                                  'handleNegativeFrets
 409                                                  'recalculate)))
 410                       (cond ((or (>= this-fret 0)
 411                                  (eq? handle-negative 'include))
 412                              (set-fret! pitch-entry string finger))
 413                             ((eq? handle-negative 'recalculate)
 414                              (begin
 415                                (ly:warning
 416                                  (_ "Requested string for pitch requires negative fret: string ~a pitch ~a")
 417                                  string
 418                                  pitch)
 419                                (ly:warning (_ "Ignoring string request and recalculating."))
 420                                (list-set! string-fret-fingers
 421                                           (cdr pitch-entry)
 422                                           (if (null? finger)
 423                                               (list '() #f)
 424                                               (list '() #f finger)))))
 425                             ((eq? handle-negative 'ignore)
 426                              (begin
 427                                (ly:warning
 428                                  (_ "Requested string for pitch requires negative fret: string ~a pitch ~a")
 429                                  string
 430                                  pitch)
 431                                (ly:warning (_ "Ignoring note in tablature."))
 432                                (kill-note! string-fret-fingers
 433                                            (cdr pitch-entry))))))))))
 434         pitch-alist string-fret-fingers)
 435     ;; handle notes without strings assigned -- sorted by pitch, so
 436     ;; we need to use the alist to have the note number available
 437     (for-each
 438       (lambda (pitch-entry)
 439         (let* ((string-fret-finger (list-ref string-fret-fingers
 440                                              (cdr pitch-entry)))
 441                (string (list-ref string-fret-finger 0))
 442                (finger (if (eq? (length string-fret-finger) 3)
 443                            (list-ref string-fret-finger 2)
 444                            '()))
 445                (pitch (car pitch-entry))
 446                (fit-string
 447                  (find (lambda (string)
 448                          (string-qualifies string pitch))
 449                        free-strings)))
 450           (if (not (list-ref string-fret-finger 1))
 451               (if fit-string
 452                   (set-fret! pitch-entry fit-string finger)
 453                   (begin
 454                     (ly:warning (_ "No string for pitch ~a (given frets ~a)")
 455                                 pitch
 456                                 specified-frets)
 457                     (kill-note! string-fret-fingers
 458                                 (cdr pitch-entry)))))))
 459       (sort pitch-alist (lambda (pitch-entry-a pitch-entry-b)
 460                           (ly:pitch<? (car pitch-entry-b)
 461                                       (car pitch-entry-a)))))
 462     string-fret-fingers)) ;; end of determine-frets-and-strings
 463
 464   (define (get-predefined-fretboard predefined-fret-table tuning pitches)
 465     "Search through @var{predefined-fret-table} looking for a predefined
 466 fretboard with a key of @var{(tuning . pitches)}.  The search will check
 467 both up and down an octave in order to accomodate transposition of the
 468 chords.  Returns a placement-list."
 469
 470     (define (get-fretboard key)
 471       (let ((hash-handle
 472              (hash-get-handle predefined-fret-table key)))
 473         (if hash-handle
 474             (cdr hash-handle)  ; return table entry
 475             '())))
 476
 477     ;; body of get-predefined-fretboard
 478     (let ((test-fretboard (get-fretboard (cons tuning pitches))))
 479       (if (not (null? test-fretboard))
 480           test-fretboard
 481           (let ((test-fretboard
 482                  (get-fretboard
 483                   (cons tuning (map (lambda (x) (shift-octave x 1)) pitches)))))
 484             (if (not (null? test-fretboard))
 485                 test-fretboard
 486                 (get-fretboard
 487                  (cons tuning (map (lambda (x) (shift-octave x -1))
 488                                    pitches))))))))
 489
 490   ;; body of determine-frets
 491   (let* ((predefined-fret-table
 492           (ly:context-property context 'predefinedDiagramTable))
 493          (tunings (ly:context-property context 'stringTunings))
 494          (string-count (length tunings))
 495          (grob (if (null? rest) '() (car rest)))
 496          (pitches (map (lambda (x) (ly:event-property x 'pitch)) notes))
 497          (defined-strings (map (lambda (x)
 498                                  (if (null? x)
 499                                      x
 500                                      (ly:event-property x 'string-number)))
 501                                (car specified-info)))
 502          (defined-fingers (map (lambda (x)
 503                                  (if (null? x)
 504                                      x
 505                                      (ly:event-property x 'digit)))
 506                                (cadr specified-info)))
 507          (default-strings (ly:context-property context 'defaultStrings '()))
 508          (strings-used (if (and (zero? (entry-count defined-strings))
 509                                 (not (zero? (entry-count default-strings))))
 510                            default-strings
 511                            defined-strings))
 512          (predefined-fretboard
 513           (if predefined-fret-table
 514               (get-predefined-fretboard
 515                predefined-fret-table
 516                tunings
 517                pitches)
 518               '())))
 519      (if (null? predefined-fretboard)
 520          (let ((string-frets
 521                 (determine-frets-and-strings
 522                  notes
 523                  strings-used
 524                  defined-fingers
 525                  (ly:context-property context 'minimumFret 0)
 526                  (ly:context-property context 'maximumFretStretch 4)
 527                  tunings)))
 528             (if (null? grob)
 529                 string-frets
 530                 (create-fretboard
 531                  context grob (string-frets->placement-list
 532                                 (filter (lambda (entry)
 533                                           (car entry))
 534                                         string-frets)
 535                                 string-count))))
 536          (if (null? grob)
 537              (placement-list->string-frets predefined-fretboard)
 538              (create-fretboard context grob predefined-fretboard)))))
 539
 540
 541
 542 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 543 ;; tablature
 544
 545 ;; The TabNoteHead tablatureFormat callbacks.
 546
 547 ;; Calculate the fret from pitch and string number as letter
 548 ;; The fret letter is taken from 'fretLabels if present
 549 (define-public (fret-letter-tablature-format
 550                 context string-number fret-number)
 551  (let ((labels (ly:context-property context 'fretLabels)))
 552   (make-vcenter-markup
 553    (cond
 554     ((= 0 (length labels))
 555      (string (integer->char (+ fret-number (char->integer #\a)))))
 556     ((and (<= 0 fret-number) (< fret-number (length labels)))
 557      (list-ref labels fret-number))
 558     (else
 559      (ly:warning (_ "No label for fret ~a (on string ~a);
 560 only ~a fret labels provided")
 561                 fret-number string-number (length labels))
 562      ".")))))
 563
 564 ;; Display the fret number as a number
 565 (define-public (fret-number-tablature-format
 566                 context string-number fret-number)
 567   (make-vcenter-markup
 568     (format #f "~a" fret-number)))
 569
 570 ;; The 5-string banjo has got a extra string, the fifth (duh), which
 571 ;; starts at the fifth fret on the neck.  Frets on the fifth string
 572 ;; are referred to relative to the other frets:
 573 ;;   the "first fret" on the fifth string is really the sixth fret
 574 ;;   on the banjo neck.
 575 ;; We solve this by defining a new fret-number-tablature function:
 576 (define-public (fret-number-tablature-format-banjo
 577                 context string-number fret-number)
 578  (make-vcenter-markup
 579   (number->string (cond
 580                    ((and (> fret-number 0) (= string-number 5))
 581                     (+ fret-number 5))
 582                    (else fret-number)))))
 583
 584 ;;  Tab note head staff position functions
 585 ;;
 586 ;;  Define where in the staff to display a given string.  Some forms of
 587 ;;  tablature put the tab note heads in the spaces, rather than on the
 588 ;;  lines
 589
 590 (define-public (tablature-position-on-lines context string-number)
 591  (let* ((string-tunings (ly:context-property context 'stringTunings))
 592         (string-count (length string-tunings))
 593         (string-one-topmost (ly:context-property context 'stringOneTopmost))
 594         (staff-line (- (* 2 string-number) string-count 1)))
 595   (if string-one-topmost
 596       (- staff-line)
 597       staff-line)))
 598
 599 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 600 ;; bar numbers
 601
 602 (define-public ((every-nth-bar-number-visible n) barnum mp)
 603   (= 0 (modulo barnum n)))
 604
 605 (define-public ((modulo-bar-number-visible n m) barnum mp)
 606   (and (> barnum 1) (= m (modulo barnum n))))
 607
 608 (define-public ((set-bar-number-visibility n) tr)
 609   (let ((bn (ly:context-property tr 'currentBarNumber)))
 610     (ly:context-set-property! tr 'barNumberVisibility
 611                               (modulo-bar-number-visible n (modulo bn n)))))
 612
 613 (define-public (first-bar-number-invisible barnum mp)
 614   (> barnum 1))
 615
 616 (define-public (first-bar-number-invisible-save-broken-bars barnum mp)
 617   (or (> barnum 1)
 618       (> (ly:moment-main-numerator mp) 0)))
 619
 620 (define-public (first-bar-number-invisible-and-no-parenthesized-bar-numbers barnum mp)
 621   (and (> barnum 1)
 622        (= (ly:moment-main-numerator mp) 0)))
 623
 624 (define-public (robust-bar-number-function barnum measure-pos alt-number context)
 625   (define (get-number-and-power an pow)
 626     (if (<= an alt-number)
 627         (get-number-and-power (+ an (expt 26 (1+ pow))) (1+ pow))
 628         (cons (+ alt-number (- (expt 26 pow) an)) (1- pow))))
 629   (define (make-letter so-far an pow)
 630     (if (< pow 0)
 631       so-far
 632       (let ((pos (modulo (quotient an (expt 26 pow)) 26)))
 633         (make-letter (string-append so-far
 634                                     (substring "abcdefghijklmnopqrstuvwxyz"
 635                                                pos
 636                                                (1+ pos)))
 637                    an
 638                    (1- pow)))))
 639   (let* ((number-and-power (get-number-and-power 0 0))
 640          (begin-measure (= 0 (ly:moment-main-numerator measure-pos)))
 641          (maybe-open-parenthesis (if begin-measure "" "("))
 642          (maybe-close-parenthesis (if begin-measure "" ")")))
 643     (markup (string-append maybe-open-parenthesis
 644                            (number->string barnum)
 645                            (make-letter ""
 646                                         (car number-and-power)
 647                                         (cdr number-and-power))
 648                            maybe-close-parenthesis))))
 649
 650 (define-public (all-bar-numbers-visible barnum mp) #t)
 651
 652
 653 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 654 ;; percent repeat counters
 655
 656 (define-public ((every-nth-repeat-count-visible n) count context)
 657   (= 0 (modulo count n)))
 658
 659 (define-public (all-repeat-counts-visible count context) #t)