scm/translation-functions.scm

   1 ;;;; translation-functions.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2006 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6 ;;;;                 Jan Nieuwenhuizen <janneke@gnu.org>
   7
   8 (define-public (denominator-tuplet-formatter mus)
   9   (number->string (ly:music-property mus 'denominator)))
  10
  11 (define-public (fraction-tuplet-formatter mus)
  12   (string-append
  13    (number->string (ly:music-property mus 'denominator))
  14    ":"
  15    (number->string (ly:music-property mus 'numerator))))
  16
  17 ;; metronome marks
  18 (define-public (format-metronome-markup event context)
  19   (let* ((dur (ly:music-property event 'tempo-unit))
  20        (count (ly:music-property event 'metronome-count))
  21        (note-mark (make-smaller-markup
  22                    (make-note-by-number-markup (ly:duration-log dur)
  23                                                (ly:duration-dot-count dur)
  24                                                1))))
  25     (make-line-markup
  26      (list
  27       (make-general-align-markup Y DOWN note-mark)
  28       (make-simple-markup  "=")
  29       (make-simple-markup (number->string count))))))
  30
  31 (define-public (format-mark-alphabet mark context)
  32   (make-bold-markup (make-markalphabet-markup (1- mark))))
  33
  34 (define-public (format-mark-box-alphabet mark context)
  35   (make-bold-markup (make-box-markup (make-markalphabet-markup (1- mark)))))
  36
  37 (define-public (format-mark-circle-alphabet mark context)
  38   (make-bold-markup (make-circle-markup (make-markalphabet-markup (1- mark)))))
  39
  40 (define-public (format-mark-letters mark context)
  41   (make-bold-markup (make-markletter-markup (1- mark))))
  42
  43 (define-public (format-mark-numbers mark context)
  44   (make-bold-markup (number->string mark)))
  45
  46 (define-public (format-mark-barnumbers mark context)
  47   (make-bold-markup (number->string (ly:context-property context 'currentBarNumber))))
  48
  49 (define-public (format-mark-box-letters mark context)
  50   (make-bold-markup (make-box-markup (make-markletter-markup (1- mark)))))
  51
  52 (define-public (format-mark-circle-letters mark context)
  53   (make-bold-markup (make-circle-markup (make-markletter-markup (1- mark)))))
  54
  55 (define-public (format-mark-box-numbers mark context)
  56   (make-bold-markup (make-box-markup (number->string mark))))
  57
  58 (define-public (format-mark-circle-numbers mark context)
  59   (make-bold-markup (make-circle-markup (number->string mark))))
  60
  61 (define-public (format-mark-box-barnumbers mark context)
  62   (make-bold-markup (make-box-markup
  63     (number->string (ly:context-property context 'currentBarNumber)))))
  64
  65 (define-public (format-mark-circle-barnumbers mark context)
  66   (make-bold-markup (make-circle-markup
  67     (number->string (ly:context-property context 'currentBarNumber)))))
  68
  69
  70 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  71 ;; Bass figures.
  72 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  73
  74 (define-public (format-bass-figure figure event context)
  75   (let* ((fig (ly:music-property event 'figure))
  76          (fig-markup (if (number? figure)
  77
  78                          ;; this is not very elegant, but center-aligning all digits
  79                          ;; is problematic with other markups, and shows problems
  80                          ;; in the (lack of) overshoot of feta alphabet glyphs.
  81
  82                          ((if (<= 10 figure)
  83                               (lambda (y) (make-translate-scaled-markup (cons -0.7 0) y))
  84                               identity)
  85
  86                           (if (eq? #t (ly:music-property event 'diminished))
  87                               (markup #:slashed-digit figure)
  88                               (markup #:number (number->string figure 10))))
  89                          #f
  90                          ))
  91          (alt (ly:music-property event 'alteration))
  92          (alt-markup
  93           (if (number? alt)
  94               (markup
  95                #:general-align Y DOWN #:fontsize
  96                (if (not (= alt DOUBLE-SHARP))
  97                    -2 2)
  98                (alteration->text-accidental-markup alt))
  99
 100               #f))
 101          (plus-markup (if (eq? #t (ly:music-property event 'augmented))
 102                           (markup #:number "+")
 103                           #f))
 104
 105          (alt-dir (ly:context-property context 'figuredBassAlterationDirection))
 106          (plus-dir (ly:context-property context 'figuredBassPlusDirection))
 107          )
 108
 109     (if (and (not fig-markup) alt-markup)
 110         (begin
 111           (set! fig-markup (markup #:left-align #:pad-around 0.3 alt-markup))
 112           (set! alt-markup #f)))
 113
 114
 115     ;; hmm, how to get figures centered between note, and
 116     ;; lone accidentals too?
 117
 118     ;;    (if (markup? fig-markup)
 119     ;;  (set!
 120     ;;   fig-markup (markup #:translate (cons 1.0 0)
 121     ;;                      #:hcenter fig-markup)))
 122
 123     (if alt-markup
 124         (set! fig-markup
 125               (markup #:put-adjacent
 126                       fig-markup X
 127                       (if (number? alt-dir)
 128                           alt-dir
 129                           LEFT)
 130                       #:pad-x 0.2 alt-markup
 131                       )))
 132
 133
 134     (if plus-markup
 135         (set! fig-markup
 136               (if fig-markup
 137                   (markup #:put-adjacent
 138                           fig-markup
 139                           X (if (number? plus-dir)
 140                                 plus-dir
 141                                 LEFT)
 142                           #:pad-x 0.2 plus-markup)
 143                   plus-markup)))
 144
 145     (if (markup? fig-markup)
 146         (markup #:fontsize -2 fig-markup)
 147         empty-markup)
 148
 149     ))
 150