scm/ps-to-png.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 2005--2015 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;;
   5 ;;;; LilyPond is free software: you can redistribute it and/or modify
   6 ;;;; it under the terms of the GNU General Public License as published by
   7 ;;;; the Free Software Foundation, either version 3 of the License, or
   8 ;;;; (at your option) any later version.
   9 ;;;;
  10 ;;;; LilyPond is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;;;; GNU General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU General Public License
  16 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 (define-module (scm ps-to-png))
  19
  20 (use-modules
  21  (ice-9 optargs)
  22  (ice-9 regex)
  23  (ice-9 rw)
  24  (srfi srfi-1)
  25  (srfi srfi-13)
  26  (srfi srfi-14)
  27  (lily)
  28  )
  29
  30 (define (re-sub re sub string)
  31   (regexp-substitute/global #f re string 'pre sub 'post))
  32
  33 (define-public (gulp-file file-name . max-size)
  34   (ly:gulp-file file-name (if (pair? max-size) (car max-size))))
  35
  36 (define (search-pngtopam)
  37   (search-executable
  38    (if (eq? PLATFORM 'windows)
  39        '("pngtopam.exe" "pngtopnm.exe")
  40        '("pngtopam" "pngtopnm"))))
  41
  42 (define (search-pamscale)
  43   (search-executable
  44    (if (eq? PLATFORM 'windows)
  45        '("pamscale.exe" "pnmscale.exe")
  46        '("pamscale" "pnmscale"))))
  47
  48 (define (search-pnmtopng)
  49   (search-executable
  50    (if (eq? PLATFORM 'windows)
  51        '("pnmtopng.exe")
  52        '("pnmtopng"))))
  53
  54 (define (scale-down-image factor file)
  55   (let* ((port-tmp1 (make-tmpfile))
  56          (tmp1-name (port-filename port-tmp1))
  57          (port-tmp2 (make-tmpfile))
  58          (tmp2-name (port-filename port-tmp2))
  59          ;; Netpbm commands (pngtopnm, pnmscale, pnmtopng)
  60          ;; outputs only standard output instead of a file.
  61          ;; So we need pipe and redirection.
  62          ;; However, ly:system can't handle them.
  63          ;; Therefore, we use ly:system-with-shell.
  64          (cmd
  65           (ly:format
  66            "~a \"~a\" | ~a -reduce ~a | ~a -compression 9 > \"~a\""
  67            (search-pngtopam) tmp1-name
  68            (search-pamscale) factor
  69            (search-pnmtopng)
  70            tmp2-name)))
  71
  72     (ly:debug (_ "Copying `~a' to `~a'...") file tmp1-name)
  73     (copy-binary-file file tmp1-name)
  74     (ly:system-with-shell cmd)
  75     (ly:debug (_ "Copying `~a' to `~a'...") tmp2-name file)
  76     (copy-binary-file tmp2-name file)
  77     (ly:debug (_ "Deleting `~a'...") tmp1-name)
  78     (delete-file tmp1-name)
  79     (ly:debug (_ "Deleting `~a'...") tmp2-name)
  80     (delete-file tmp2-name)))
  81
  82 (define-public (ps-page-count ps-name)
  83   (let* ((byte-count 10240)
  84          (header (gulp-file ps-name byte-count))
  85          (first-null (string-index header #\nul))
  86          (match (string-match "%%Pages: ([0-9]+)"
  87                               (if (number? first-null)
  88                                   (substring header 0 first-null)
  89                                   header))))
  90     (if match (string->number (match:substring match 1)) 0)))
  91
  92 (define-public (make-ps-images base-name tmp-name is-eps . rest)
  93   (let-keywords*
  94    rest #f
  95    ((resolution 90)
  96     (page-width  100)
  97     (page-height 100)
  98     (rename-page-1 #f)
  99     (be-verbose (ly:get-option 'verbose))
 100     (pixmap-format 'png16m)
 101     (anti-alias-factor 1))
 102
 103    (let* ((format-str (format #f "~a" pixmap-format))
 104           (extension (cond
 105                       ((string-contains format-str "png") "png")
 106                       ((string-contains format-str "jpg") "jpeg")
 107                       ((string-contains format-str "jpeg") "jpeg")
 108                       (else
 109                        (ly:error "Unknown pixmap format ~a" pixmap-format))))
 110           (png1 (format #f "~a.~a" base-name extension))
 111           (pngn (format #f "~a-page%d.~a" base-name extension))
 112           (page-count (ps-page-count tmp-name))
 113           (multi-page? (> page-count 1))
 114
 115           ;; Escape `%' (except `page%d') for ghostscript
 116           (base-name-gs (string-join
 117                          (string-split base-name #\%)
 118                          "%%"))
 119           (png1-gs (format #f "~a.~a" base-name-gs extension))
 120           (pngn-gs (format #f "~a-page%d.~a" base-name-gs extension))
 121           (output-file (if multi-page? pngn-gs png1-gs))
 122
 123           (*unspecified* (if #f #f))
 124           (cmd
 125            (remove (lambda (x) (eq? x *unspecified*))
 126                    (list
 127                     (search-gs)
 128                     (if (ly:get-option 'verbose) *unspecified* "-q")
 129                     (if (or (ly:get-option 'gs-load-fonts)
 130                             (ly:get-option 'gs-load-lily-fonts)
 131                             (eq? PLATFORM 'windows))
 132                         "-dNOSAFER"
 133                         "-dSAFER")
 134
 135                     (if is-eps
 136                         "-dEPSCrop"
 137                         (ly:format "-dDEVICEWIDTHPOINTS=~$" page-width))
 138                     (if is-eps
 139                         *unspecified*
 140                         (ly:format "-dDEVICEHEIGHTPOINTS=~$" page-height))
 141                     "-dGraphicsAlphaBits=4"
 142                     "-dTextAlphaBits=4"
 143                     "-dNOPAUSE"
 144                     "-dBATCH"
 145                     (ly:format "-sDEVICE=~a" pixmap-format)
 146                     (string-append "-sOutputFile=" output-file)
 147                     (ly:format "-r~a" (* anti-alias-factor resolution))
 148                     (string-append "-f" tmp-name))))
 149           (files '()))
 150
 151      (ly:system cmd)
 152
 153      (set! files
 154            (if multi-page?
 155                (map
 156                 (lambda (n)
 157                   (format #f "~a-page~a.png" base-name (1+ n)))
 158                 (iota page-count))
 159                (list (format #f "~a.png" base-name))))
 160
 161      (if (and rename-page-1 multi-page?)
 162          (begin
 163            (rename-file (re-sub "%d" "1" pngn) png1)
 164            (set! files
 165                  (cons png1
 166                        (cdr files)))
 167            ))
 168
 169      (if (not (= 1 anti-alias-factor))
 170          (for-each
 171           (lambda (f) (scale-down-image anti-alias-factor f)) files))
 172      files)))