scm/page.scm

   1 ;;
   2 ;; page.scm -- implement Page stuff.
   3 ;;
   4 ;; source file of the GNU LilyPond music typesetter
   5 ;;
   6 ;; (c) 2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7 ;;
   8
   9 (define-module (scm page)
  10
  11   #:export (make-page
  12             page-property
  13             page-set-property!
  14             page-prev
  15             page-printable-height
  16             layout->page-init
  17             page-lines
  18             page-force
  19             page-penalty
  20             page-configuration
  21             page-lines
  22             page-page-number
  23             page-system-numbers
  24             page-stencil
  25             page-free-height
  26             page?
  27             ))
  28
  29 (use-modules (lily)
  30              (scm paper-system)
  31              (srfi srfi-1))
  32
  33
  34 (define (annotate? layout)
  35   (eq? #t (ly:output-def-lookup layout 'annotate-spacing)))
  36
  37
  38 (define page-module (current-module))
  39
  40 (define (make-page paper-book  . args)
  41   (let*
  42       ((p (apply ly:make-prob (append
  43                                (list 'page (layout->page-init (ly:paper-book-paper paper-book))
  44                                      'paper-book paper-book)
  45                                args))))
  46
  47     (page-set-property! p 'head-stencil (page-header p))
  48     (page-set-property! p 'foot-stencil (page-footer p))
  49
  50     p))
  51
  52 (define page-property ly:prob-property)
  53 (define page-set-property! ly:prob-set-property!)
  54 (define (page-property? page sym)
  55   (eq? #t (page-property page sym)))
  56 (define (page? x)  (ly:prob-type? x 'page))
  57
  58
  59 ;; define accessors.
  60 (for-each
  61  (lambda (j)
  62    (module-define!
  63     page-module
  64     (string->symbol (format "page-~a" j))
  65     (lambda (pg)
  66       (page-property pg j))))
  67
  68  '(page-number prev lines force penalty lines))
  69
  70 (define (page-system-numbers page)
  71   (map (lambda (ps) (ly:prob-property ps 'number))
  72        (page-lines page)))
  73
  74 (define (page-translate-systems page)
  75   (for-each
  76
  77    (lambda (sys-off)
  78      (let*
  79          ((sys (car sys-off))
  80           (off (cadr sys-off)))
  81
  82        (if (not (number? (ly:prob-property sys 'Y-offset)))
  83            (ly:prob-set-property! sys 'Y-offset off))))
  84
  85    (zip (page-property page 'lines)
  86         (page-property page 'configuration))))
  87
  88 (define (annotate-top-space first-system layout header-stencil stencil)
  89   (let* ((top-margin (ly:output-def-lookup layout 'top-margin))
  90          (sym (if (paper-system-title? first-system)
  91                   'top-title-spacing
  92                   'top-system-spacing))
  93          (spacing-spec (ly:output-def-lookup layout sym))
  94          (X-offset (ly:prob-property first-system 'X-offset 5))
  95          (header-extent (ly:stencil-extent header-stencil Y)))
  96
  97     (set! stencil
  98           (ly:stencil-add stencil
  99                           (ly:stencil-translate-axis
 100                            (annotate-spacing-spec layout
 101                                                   spacing-spec
 102                                                   (- top-margin)
 103                                                   (car header-extent)
 104                                                   #:base-color red)
 105                            X-offset X)))
 106     stencil))
 107
 108
 109 (define (annotate-page layout stencil)
 110   (let ((top-margin (ly:output-def-lookup layout 'top-margin))
 111         (paper-height (ly:output-def-lookup layout 'paper-height))
 112         (bottom-margin (ly:output-def-lookup layout 'bottom-margin))
 113         (add-stencil (lambda (y)
 114                        (set! stencil
 115                              (ly:stencil-add stencil
 116                                              (ly:stencil-translate-axis y 6 X))))))
 117     (add-stencil
 118      (ly:stencil-translate-axis
 119       (annotate-y-interval layout "paper-height"
 120                            (cons (- paper-height) 0)
 121                            #t)
 122       1 X))
 123     (add-stencil
 124      (ly:stencil-translate-axis
 125       (annotate-y-interval layout "top-margin"
 126                            (cons (- top-margin) 0)
 127                            #t)
 128       2 X))
 129     (add-stencil
 130      (ly:stencil-translate-axis
 131       (annotate-y-interval layout "bottom-margin"
 132                            (cons (- paper-height) (- bottom-margin paper-height))
 133                            #t)
 134       2 X))
 135     stencil))
 136
 137 (define (annotate-space-left page)
 138   (let*
 139       ((paper-book (page-property page 'paper-book))
 140        (layout (ly:paper-book-paper paper-book))
 141        (arrow (annotate-y-interval layout
 142                                    "space left"
 143                                    (cons (- 0.0
 144                                             (page-property page 'bottom-edge)
 145                                             (let ((foot (page-property page 'foot-stencil)))
 146                                               (if (and (ly:stencil? foot)
 147                                                        (not (ly:stencil-empty? foot)))
 148                                                   (car (ly:stencil-extent foot Y))
 149                                                   0.0)))
 150                                          (page-property page  'bottom-system-edge))
 151                                    #t)))
 152
 153     (set! arrow (ly:stencil-translate-axis arrow 8 X))
 154
 155     arrow))
 156
 157
 158 (define (page-header-or-footer page dir)
 159     (let*
 160       ((paper-book (page-property page 'paper-book))
 161        (layout (ly:paper-book-paper paper-book))
 162        (scopes (ly:paper-book-scopes paper-book))
 163        (number (page-page-number page))
 164        (is-last-bookpart (page-property page 'is-last-bookpart))
 165        (is-bookpart-last-page (page-property page 'is-bookpart-last-page))
 166        (sym (if (= dir UP)
 167                 'make-header
 168                 'make-footer))
 169        (header-proc (ly:output-def-lookup layout sym)))
 170
 171       (if (procedure? header-proc)
 172           (header-proc layout scopes number is-last-bookpart is-bookpart-last-page)
 173           #f)))
 174
 175
 176 (define (page-header page)
 177   (page-header-or-footer page UP))
 178
 179 (define (page-footer page)
 180   (page-header-or-footer page DOWN))
 181
 182 (define (layout->page-init layout)
 183   "Alist of settings for page layout"
 184   (let*
 185       ((paper-height (ly:output-def-lookup layout 'paper-height))
 186        (paper-width (ly:output-def-lookup layout 'paper-width))
 187        (left-margin (ly:output-def-lookup layout 'left-margin))
 188        (bottom-edge (- paper-height
 189                        (ly:output-def-lookup layout 'bottom-margin)) )
 190        (top-margin (ly:output-def-lookup layout 'top-margin))
 191        )
 192
 193     `((paper-height . ,paper-height)
 194       (paper-width . ,paper-width)
 195       (left-margin . ,left-margin)
 196       (top-margin . ,top-margin)
 197       (bottom-edge . ,bottom-edge)
 198       )))
 199
 200 (define (make-page-stencil page)
 201   "Construct a stencil representing the page from PAGE."
 202
 203
 204   (page-translate-systems page)
 205   (let*
 206       ((paper-book (page-property page 'paper-book))
 207        (prop (lambda (sym) (page-property page sym)))
 208        (layout (ly:paper-book-paper paper-book))
 209        (scopes (ly:paper-book-scopes paper-book))
 210        (lines (page-lines page))
 211        (number (page-page-number page))
 212
 213        ;; TODO: naming paper-height/paper-width not analogous to TeX.
 214
 215        (system-xoffset (ly:output-def-lookup layout 'horizontal-shift 0.0))
 216        (system-separator-markup (ly:output-def-lookup layout 'system-separator-markup))
 217        (system-separator-stencil (if (markup? system-separator-markup)
 218                                      (interpret-markup layout
 219                                                        (layout-extract-page-properties layout)
 220                                                        system-separator-markup)
 221                                      #f))
 222
 223        (page-stencil (ly:make-stencil '()))
 224
 225        (last-system #f)
 226        (last-y 0.0)
 227        (add-to-page (lambda (stencil x y)
 228                       (set! page-stencil
 229                             (ly:stencil-add page-stencil
 230                                             (ly:stencil-translate stencil
 231                                                                   (cons
 232                                                                    (+ system-xoffset x)
 233                                                                    (- 0 y (prop 'top-margin)))
 234
 235                                                                   )))))
 236        (add-system
 237         (lambda (system)
 238           (let* ((stencil (paper-system-stencil system))
 239                  (y (ly:prob-property system 'Y-offset))
 240                  (is-title (paper-system-title?
 241                             system)))
 242             (add-to-page stencil
 243                          (ly:prob-property system 'X-offset 0.0)
 244                          y)
 245             (if (and (ly:stencil? system-separator-stencil)
 246                      last-system
 247                      (not (paper-system-title? system))
 248                      (not (paper-system-title? last-system)))
 249                 (add-to-page
 250                  system-separator-stencil
 251                  0
 252                  (average (- last-y
 253                              (car (paper-system-staff-extents last-system)))
 254                           (- y
 255                              (cdr (paper-system-staff-extents system))))))
 256             (set! last-system system)
 257             (set! last-y y))))
 258        (head (prop 'head-stencil))
 259        (foot (prop 'foot-stencil))
 260        )
 261
 262     (if (and
 263          (ly:stencil? head)
 264          (not (ly:stencil-empty? head)))
 265         (begin
 266           ;; Ensure that the top of the header just touches the top margin.
 267           (set! head (ly:stencil-translate-axis head
 268                                                 (- 0 (cdr (ly:stencil-extent head Y)) (prop 'top-margin)) Y))
 269           (set! page-stencil (ly:stencil-add page-stencil head))))
 270
 271     (if (and
 272          (annotate? layout)
 273          (pair? lines))
 274
 275         (begin
 276           (set! page-stencil (annotate-top-space (car lines) layout head page-stencil))
 277
 278           (for-each (lambda (sys next-sys)
 279                       (paper-system-annotate sys next-sys layout))
 280                     lines
 281                     (append (cdr lines) (list #f)))
 282           (paper-system-annotate-last (car (last-pair lines)) layout)))
 283
 284     (map add-system lines)
 285
 286
 287     (ly:prob-set-property! page 'bottom-system-edge
 288                            (car (ly:stencil-extent page-stencil Y)))
 289     (ly:prob-set-property! page 'space-left
 290                            (+ (prop 'bottom-edge)
 291                               (prop 'bottom-system-edge)
 292                               (if (and (ly:stencil? foot)
 293                                        (not (ly:stencil-empty? foot)))
 294                                   (car (ly:stencil-extent foot Y))
 295                                   0.0)))
 296
 297     (if (annotate? layout)
 298         (set! page-stencil
 299               (ly:stencil-add page-stencil
 300                               (annotate-space-left page))))
 301
 302     (if (and (ly:stencil? foot)
 303              (not (ly:stencil-empty? foot)))
 304         (set! page-stencil
 305               (ly:stencil-add
 306                page-stencil
 307                (ly:stencil-translate
 308                 foot
 309                 (cons 0
 310                       (+ (- (prop 'bottom-edge))
 311                          (- (car (ly:stencil-extent foot Y)))))))))
 312
 313     (set! page-stencil
 314           (ly:stencil-translate page-stencil (cons (prop 'left-margin) 0)))
 315
 316     ;; annotation.
 317     (if (annotate? layout)
 318         (set! page-stencil (annotate-page layout page-stencil)))
 319
 320     page-stencil))
 321
 322
 323 (define-public (page-stencil page)
 324   (if (not (ly:stencil? (page-property page 'stencil)))
 325
 326       ;; todo: make tweakable.
 327       ;; via property + callbacks.
 328
 329       (page-set-property! page 'stencil (make-page-stencil page)))
 330   (page-property page 'stencil))
 331
 332 (define (calc-printable-height page)
 333   "Printable area for music and titles; matches default-page-make-stencil."
 334   (let*
 335       ((paper-book (page-property page 'paper-book))
 336        (layout (ly:paper-book-paper paper-book))
 337        (h (- (ly:output-def-lookup layout 'paper-height)
 338                (ly:output-def-lookup layout 'top-margin)
 339                (ly:output-def-lookup layout 'bottom-margin)))
 340
 341        (head (page-property page 'head-stencil))
 342        (foot (page-property page 'foot-stencil))
 343        (available
 344         (- h (if (ly:stencil? head)
 345                  (interval-length (ly:stencil-extent head Y))
 346                  0)
 347            (if (ly:stencil? foot)
 348                (interval-length (ly:stencil-extent foot Y))
 349                0))))
 350
 351     ;; (display (list "\n available" available head foot))
 352     available))
 353
 354 (define (page-printable-height page)
 355   (if (not (number? (page-property page 'printable-height)))
 356       (page-set-property! page 'printable-height (calc-printable-height page)))
 357
 358   (page-property page 'printable-height))
 359