scm/music-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2015 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; for define-safe-public when byte-compiling using Guile V2
  20 (use-modules (scm safe-utility-defs))
  21
  22 (use-modules (ice-9 optargs))
  23 (use-modules (srfi srfi-11))
  24
  25 ;;; ly:music-property with setter
  26 ;;; (ly:music-property my-music 'elements)
  27 ;;;   ==> the 'elements property
  28 ;;; (set! (ly:music-property my-music 'elements) value)
  29 ;;;   ==> set the 'elements property and return it
  30 (define-public ly:music-property
  31   (make-procedure-with-setter ly:music-property
  32                               ly:music-set-property!))
  33
  34 (define-safe-public (music-is-of-type? mus type)
  35   "Does @code{mus} belong to the music class @code{type}?"
  36   (memq type (ly:music-property mus 'types)))
  37
  38 (define-safe-public (music-type-predicate types)
  39   "Returns a predicate function that can be used for checking
  40 music to have one of the types listed in @var{types}."
  41    (if (cheap-list? types)
  42        (lambda (m)
  43          (any (lambda (t) (music-is-of-type? m t)) types))
  44        (lambda (m) (music-is-of-type? m types))))
  45
  46 ;; TODO move this
  47 (define-public ly:grob-property
  48   (make-procedure-with-setter ly:grob-property
  49                               ly:grob-set-property!))
  50
  51 (define-public ly:grob-object
  52   (make-procedure-with-setter ly:grob-object
  53                               ly:grob-set-object!))
  54
  55 (define-public ly:grob-parent
  56   (make-procedure-with-setter ly:grob-parent
  57                               ly:grob-set-parent!))
  58
  59 (define-public ly:prob-property
  60   (make-procedure-with-setter ly:prob-property
  61                               ly:prob-set-property!))
  62
  63 (define-public ly:context-property
  64   (make-procedure-with-setter ly:context-property
  65                               ly:context-set-property!))
  66
  67 (define-public (music-map function music)
  68   "Apply @var{function} to @var{music} and all of the music it contains.
  69
  70 First it recurses over the children, then the function is applied to
  71 @var{music}."
  72   (let ((es (ly:music-property music 'elements))
  73         (e (ly:music-property music 'element)))
  74     (if (pair? es)
  75         (set! (ly:music-property music 'elements)
  76               (map (lambda (y) (music-map function y)) es)))
  77     (if (ly:music? e)
  78         (set! (ly:music-property music 'element)
  79               (music-map function  e)))
  80     (function music)))
  81
  82 (define-public (music-filter pred? music)
  83   "Filter out music expressions that do not satisfy @var{pred?}."
  84
  85   (define (inner-music-filter pred? music)
  86     "Recursive function."
  87     (let* ((es (ly:music-property music 'elements))
  88            (e (ly:music-property music 'element))
  89            (as (ly:music-property music 'articulations))
  90            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  91            (filtered-e (if (ly:music? e)
  92                            (inner-music-filter pred? e)
  93                            e))
  94            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  95       (if (not (null? e))
  96           (set! (ly:music-property music 'element) filtered-e))
  97       (if (not (null? es))
  98           (set! (ly:music-property music 'elements) filtered-es))
  99       (if (not (null? as))
 100           (set! (ly:music-property music 'articulations) filtered-as))
 101       ;; if filtering emptied the expression, we remove it completely.
 102       (if (or (not (pred? music))
 103               (and (eq? filtered-es '()) (not (ly:music? e))
 104                    (or (not (eq? es '()))
 105                        (ly:music? e))))
 106           (set! music '()))
 107       music))
 108
 109   (set! music (inner-music-filter pred? music))
 110   (if (ly:music? music)
 111       music
 112       (make-music 'Music)))       ;must return music.
 113
 114 (define*-public (display-music music #:optional (port (current-output-port)))
 115   "Display music, not done with @code{music-map} for clarity of
 116 presentation."
 117   (display music port)
 118   (display ": { " port)
 119   (let ((es (ly:music-property music 'elements))
 120         (e (ly:music-property music 'element)))
 121     (display (ly:music-mutable-properties music) port)
 122     (if (pair? es)
 123         (begin (display "\nElements: {\n" port)
 124                (for-each (lambda (m) (display-music m port)) es)
 125                (display "}\n" port)))
 126     (if (ly:music? e)
 127         (begin
 128           (display "\nChild:" port)
 129           (display-music e port))))
 130   (display " }\n" port)
 131   music)
 132
 133 ;;;
 134 ;;; A scheme music pretty printer
 135 ;;;
 136 (define (markup-expression->make-markup markup-expression)
 137   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
 138 For instance,
 139   \\markup \\bold \\italic hello
 140 ==>
 141   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 142   (define (proc->command-keyword proc)
 143     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 144     (let ((cmd-markup (symbol->string (procedure-name proc))))
 145       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 146                                                                   (string-length "-markup")))))))
 147   (define (transform-arg arg)
 148     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 149            (append-map inner-markup->make-markup arg))
 150           ((and (not (string? arg)) (markup? arg)) ;; a markup
 151            (inner-markup->make-markup arg))
 152           (else                                  ;; scheme arg
 153            (music->make-music arg))))
 154   (define (inner-markup->make-markup mrkup)
 155     (if (string? mrkup)
 156         `(#:simple ,mrkup)
 157         (let ((cmd (proc->command-keyword (car mrkup)))
 158               (args (map transform-arg (cdr mrkup))))
 159           `(,cmd ,@args))))
 160   ;; body:
 161   (if (string? markup-expression)
 162       markup-expression
 163       `(markup ,@(inner-markup->make-markup markup-expression))))
 164
 165 (define-public (music->make-music obj)
 166   "Generate an expression that, once evaluated, may return an object
 167 equivalent to @var{obj}, that is, for a music expression, a
 168 @code{(make-music ...)} form."
 169   (define (if-nonzero num)
 170     (if (zero? num) '() (list num)))
 171   (cond (;; markup expression
 172          (markup? obj)
 173          (markup-expression->make-markup obj))
 174         (;; music expression
 175          (ly:music? obj)
 176          `(make-music
 177            ',(ly:music-property obj 'name)
 178            ,@(append-map (lambda (prop)
 179                            `(',(car prop)
 180                              ,(music->make-music (cdr prop))))
 181                          (remove (lambda (prop)
 182                                    (eqv? (car prop) 'origin))
 183                                  (ly:music-mutable-properties obj)))))
 184         (;; moment
 185          (ly:moment? obj)
 186          `(ly:make-moment
 187            ,@(let ((main (ly:moment-main obj))
 188                    (grace (ly:moment-grace obj)))
 189                (cond ((zero? grace) (list main))
 190                      ((negative? grace) (list main grace))
 191                      (else ;;positive grace requires 4-arg form
 192                       (list (numerator main)
 193                             (denominator main)
 194                             (numerator grace)
 195                             (denominator grace)))))))
 196         (;; note duration
 197          (ly:duration? obj)
 198          `(ly:make-duration ,(ly:duration-log obj)
 199                             ,@(if (= (ly:duration-scale obj) 1)
 200                                   (if-nonzero (ly:duration-dot-count obj))
 201                                   (list (ly:duration-dot-count obj)
 202                                         (ly:duration-scale obj)))))
 203         (;; note pitch
 204          (ly:pitch? obj)
 205          `(ly:make-pitch ,(ly:pitch-octave obj)
 206                          ,(ly:pitch-notename obj)
 207                          ,@(if-nonzero (ly:pitch-alteration obj))))
 208         (;; scheme procedure
 209          (procedure? obj)
 210          (or (procedure-name obj) obj))
 211         (;; a symbol (avoid having an unquoted symbol)
 212          (symbol? obj)
 213          `',obj)
 214         (;; an empty list (avoid having an unquoted empty list)
 215          (null? obj)
 216          `'())
 217         (;; a proper list
 218          (list? obj)
 219          `(list ,@(map music->make-music obj)))
 220         (;; a pair
 221          (pair? obj)
 222          `(cons ,(music->make-music (car obj))
 223                 ,(music->make-music (cdr obj))))
 224         (else
 225          obj)))
 226
 227 (use-modules (ice-9 pretty-print))
 228 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 229   "Displays `obj', typically a music expression, in a friendly fashion,
 230 which often can be read back in order to generate an equivalent expression."
 231   (pretty-print (music->make-music obj) port)
 232   (newline port))
 233
 234 ;;;
 235 ;;; Scheme music expression --> Lily-syntax-using string translator
 236 ;;;
 237 (use-modules (srfi srfi-39)
 238              (scm display-lily))
 239
 240 (define*-public (display-lily-music expr #:optional (port (current-output-port))
 241                                     #:key force-duration)
 242   "Display the music expression using LilyPond syntax"
 243   (memoize-clef-names supported-clefs)
 244   (parameterize ((*indent* 0)
 245                  (*omit-duration* #f))
 246                 (display (music->lily-string expr) port)
 247                 (newline port)))
 248
 249 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 250
 251 (define-public (shift-one-duration-log music shift dot)
 252   "Add @var{shift} to @code{duration-log} of @code{'duration} in
 253 @var{music} and optionally @var{dot} to any note encountered.
 254 The number of dots in the shifted music may not be less than zero."
 255   (let ((d (ly:music-property music 'duration)))
 256     (if (ly:duration? d)
 257         (let* ((cp (ly:duration-scale d))
 258                (nd (ly:make-duration
 259                     (+ shift (ly:duration-log d))
 260                     (max 0 (+ dot (ly:duration-dot-count d)))
 261                     cp)))
 262           (set! (ly:music-property music 'duration) nd)))
 263     ;clear cached length, since it's no longer valid
 264     (set! (ly:music-property music 'length) '())
 265     music))
 266
 267 (define-public (shift-duration-log music shift dot)
 268   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 269              music))
 270
 271 (define-public (tremolo::get-music-list tremolo)
 272   "Given a tremolo repeat, return a list of music to engrave for it.
 273 This will be a stretched copy of its body, plus a TremoloEvent or
 274 TremoloSpanEvent.
 275
 276 This is called only by Chord_tremolo_iterator."
 277   (define (first-note-duration music)
 278     "Finds the duration of the first NoteEvent by searching
 279 depth-first through MUSIC."
 280     ;; NoteEvent or a non-expanded chord-repetition
 281     ;; We just take anything that actually sports an announced duration.
 282     (if (ly:duration? (ly:music-property music 'duration))
 283         (ly:music-property music 'duration)
 284         (let loop ((elts (if (ly:music? (ly:music-property music 'element))
 285                              (list (ly:music-property music 'element))
 286                              (ly:music-property music 'elements))))
 287           (and (pair? elts)
 288                (let ((dur (first-note-duration (car elts))))
 289                  (if (ly:duration? dur)
 290                      dur
 291                      (loop (cdr elts))))))))
 292   (let* ((times (ly:music-property tremolo 'repeat-count))
 293          (body (ly:music-property tremolo 'element))
 294          (children (if (music-is-of-type? body 'sequential-music)
 295                        ;; \repeat tremolo n { ... }
 296                        (count duration-of-note ; do not count empty <>
 297                               (extract-named-music body
 298                                                    '(EventChord NoteEvent)))
 299                        ;; \repeat tremolo n c4
 300                        1))
 301          (tremolo-type (if (positive? children)
 302                            (let* ((note-duration (first-note-duration body))
 303                                   (duration-log (if (ly:duration? note-duration)
 304                                                     (ly:duration-log note-duration)
 305                                                     1)))
 306                              (ash 1 duration-log))
 307                            '()))
 308          (stretched (ly:music-deep-copy body)))
 309     (if (positive? children)
 310         ;; # of dots is equal to the 1 in bitwise representation (minus 1)!
 311         (let* ((dots (1- (logcount (* times children))))
 312                ;; The remaining missing multiplier to scale the notes by
 313                ;; times * children
 314                (mult (/ (* times children (ash 1 dots)) (1- (ash 2 dots))))
 315                (shift (- (ly:intlog2 (floor mult)))))
 316           (if (not (and (integer? mult) (= (logcount mult) 1)))
 317               (ly:music-warning
 318                body
 319                (ly:format (_ "invalid tremolo repeat count: ~a") times)))
 320           ;; Make each note take the full duration
 321           (ly:music-compress stretched (ly:make-moment 1 children))
 322           ;; Adjust the displayed note durations
 323           (shift-duration-log stretched shift dots)))
 324     ;; Return the stretched body plus a tremolo event
 325     (if (= children 1)
 326         (list (make-music 'TremoloEvent
 327                           'repeat-count times
 328                           'tremolo-type tremolo-type
 329                           'origin (ly:music-property tremolo 'origin))
 330               stretched)
 331         (list (make-music 'TremoloSpanEvent
 332                           'span-direction START
 333                           'repeat-count times
 334                           'tremolo-type tremolo-type
 335                           'origin (ly:music-property tremolo 'origin))
 336               stretched
 337               (make-music 'TremoloSpanEvent
 338                           'span-direction STOP
 339                           'origin (ly:music-property tremolo 'origin))))))
 340
 341 (define-public (make-repeat name times main alts)
 342   "Create a repeat music expression, with all properties initialized
 343 properly."
 344   (let ((type (or (assoc-get name '(("volta" . VoltaRepeatedMusic)
 345                                     ("unfold" . UnfoldedRepeatedMusic)
 346                                     ("percent" . PercentRepeatedMusic)
 347                                     ("tremolo" . TremoloRepeatedMusic)))
 348                   (begin (ly:warning (_ "unknown repeat type `~S': must be volta, unfold, percent, or tremolo") name)
 349                          'VoltaRepeatedMusic)))
 350         (talts (if (< times (length alts))
 351                    (begin
 352                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 353                      (take alts times))
 354                    alts)))
 355     (make-music type
 356                 'element main
 357                 'repeat-count (max times 1)
 358                 'elements talts)))
 359
 360 (define (calc-repeat-slash-count music)
 361   "Given the child-list @var{music} in @code{PercentRepeatMusic},
 362 calculate the number of slashes based on the durations.  Returns @code{0}
 363 if durations in @var{music} vary, allowing slash beats and double-percent
 364 beats to be distinguished."
 365   (let* ((durs (map duration-of-note
 366                     (extract-named-music music '(EventChord NoteEvent
 367                                                             RestEvent SkipEvent))))
 368          (first-dur (car durs)))
 369
 370     (if (every (lambda (d) (equal? d first-dur)) durs)
 371         (max (- (ly:duration-log first-dur) 2) 1)
 372         0)))
 373
 374 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 375 ;; clusters.
 376
 377 (define-public (note-to-cluster music)
 378   "Replace @code{NoteEvents} by @code{ClusterNoteEvents}."
 379   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 380       (make-music 'ClusterNoteEvent
 381                   'pitch (ly:music-property music 'pitch)
 382                   'duration (ly:music-property music 'duration))
 383       music))
 384
 385 (define-public (notes-to-clusters music)
 386   (music-map note-to-cluster music))
 387
 388 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 389 ;; repeats.
 390
 391 (define-public (unfold-repeats music)
 392   "Replace all repeats with unfolded repeats."
 393   (let ((es (ly:music-property music 'elements))
 394         (e (ly:music-property music 'element)))
 395     (if (music-is-of-type? music 'repeated-music)
 396         (set! music (make-music 'UnfoldedRepeatedMusic music)))
 397     (if (pair? es)
 398         (set! (ly:music-property music 'elements)
 399               (map unfold-repeats es)))
 400     (if (ly:music? e)
 401         (set! (ly:music-property music 'element)
 402               (unfold-repeats e)))
 403     music))
 404
 405 (define-public (unfold-repeats-fully music)
 406   "Unfolds repeats and expands the resulting @code{unfolded-repeated-music}."
 407   (map-some-music
 408    (lambda (m)
 409      (and (music-is-of-type? m 'unfolded-repeated-music)
 410           (make-sequential-music
 411            (ly:music-deep-copy (make-unfolded-set m)))))
 412    (unfold-repeats music)))
 413
 414 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 415 ;; property setting music objs.
 416
 417 (define-safe-public (check-grob-path path #:optional location
 418                                      #:key
 419                                      (start 0)
 420                                      default
 421                                      (min 1)
 422                                      max)
 423   "Check a grob path specification @var{path}, a symbol list (or a
 424 single symbol), for validity and possibly complete it.  Returns the
 425 completed specification, or @code{#f} if invalid.  If optional
 426 @var{parser} is given, a syntax error is raised in that case,
 427 optionally using @var{location}.  If an optional keyword argument
 428 @code{#:start @var{start}} is given, the parsing starts at the given
 429 index in the sequence @samp{Context.Grob.property.sub-property...},
 430 with the default of @samp{0} implying the full path.
 431
 432 If there is no valid first element of @var{path} fitting at the given
 433 path location, an optionally given @code{#:default @var{default}} is
 434 used as the respective element instead without checking it for
 435 validity at this position.
 436
 437 The resulting path after possibly prepending @var{default} can be
 438 constrained in length by optional arguments @code{#:min @var{min}} and
 439 @code{#:max @var{max}}, defaulting to @samp{1} and unlimited,
 440 respectively."
 441   (let ((path (if (symbol? path) (list path) path)))
 442     ;; A Guile 1.x bug specific to optargs precludes moving the
 443     ;; defines out of the let
 444     (define (unspecial? s)
 445       (not (or (object-property s 'is-grob?)
 446                (object-property s 'backend-type?))))
 447     (define (grob? s)
 448       (object-property s 'is-grob?))
 449     (define (property? s)
 450       (object-property s 'backend-type?))
 451     (define (check c p) (c p))
 452
 453     (let* ((checkers
 454             (and (< start 3)
 455                  (drop (list unspecial? grob? property?) start)))
 456            (res
 457             (cond
 458              ((null? path)
 459               ;; tricky.  Should we make use of the default when the
 460               ;; list is empty?  In most cases, this question should be
 461               ;; academical as an empty list can only be generated by
 462               ;; Scheme and is likely an error.  We consider this a case
 463               ;; of "no valid first element, and default given".
 464               ;; Usually, invalid use cases should be caught later using
 465               ;; the #:min argument, and if the user explicitly does not
 466               ;; catch this, we just follow through.
 467               (if default (list default) '()))
 468              ((not checkers)
 469               ;; no checkers, so we have a valid first element and just
 470               ;; take the path as-is.
 471               path)
 472              (default
 473                (if ((car checkers) (car path))
 474                    (and (every check (cdr checkers) (cdr path))
 475                         path)
 476                    (and (every check (cdr checkers) path)
 477                         (cons default path))))
 478              (else
 479               (and (every check checkers path)
 480                    path)))))
 481       (if (and res
 482                (if max (<= min (length res) max)
 483                    (<= min (length res))))
 484           res
 485           (begin
 486             (ly:parser-error
 487              (format #f (_ "bad grob property path ~a")
 488                      path)
 489              location)
 490             #f)))))
 491
 492 (define-safe-public (check-context-path path #:optional location)
 493   "Check a context property path specification @var{path}, a symbol
 494 list (or a single symbol), for validity and possibly complete it.
 495 Returns the completed specification, or @code{#f} when rising an
 496 error (using optionally @code{location})."
 497   (let* ((path (if (symbol? path) (list path) path)))
 498     ;; A Guile 1.x bug specific to optargs precludes moving the
 499     ;; defines out of the let
 500     (define (property? s)
 501       (object-property s 'translation-type?))
 502     (define (unspecial? s)
 503       (not (property? s)))
 504     (define (check c p) (c p))
 505     (or (case (length path)
 506           ((1) (and (property? (car path)) (cons 'Bottom path)))
 507           ((2) (and (unspecial? (car path)) (property? (cadr path)) path))
 508           (else #f))
 509         (begin
 510           (ly:parser-error
 511            (format #f (_ "bad context property ~a")
 512                    path)
 513            location)
 514           #f))))
 515
 516 (define-safe-public (check-music-path path #:optional location #:key default)
 517   "Check a music property path specification @var{path}, a symbol
 518 list (or a single symbol), for validity and possibly complete it.
 519 Returns the completed specification, or @code{#f} when rising an
 520 error (using optionally @code{location})."
 521   (let* ((path (if (symbol? path) (list path) path)))
 522     ;; A Guile 1.x bug specific to optargs precludes moving the
 523     ;; defines out of the let
 524     (define (property? s)
 525       (object-property s 'music-type?))
 526     (define (unspecial? s)
 527       (not (property? s)))
 528     (or (case (length path)
 529           ((1) (and (property? (car path)) (cons default path)))
 530           ((2) (and (unspecial? (car path)) (property? (cadr path)) path))
 531           (else #f))
 532         (begin
 533           (ly:parser-error
 534            (format #f (_ "bad music property ~a")
 535                    path)
 536            location)
 537           #f))))
 538
 539 (define-public (make-grob-property-set grob gprop val)
 540   "Make a @code{Music} expression that sets @var{gprop} to @var{val} in
 541 @var{grob}.  Does a pop first, i.e., this is not an override."
 542   (make-music 'OverrideProperty
 543               'symbol grob
 544               'grob-property gprop
 545               'grob-value val
 546               'pop-first #t))
 547
 548 (define-public (make-grob-property-override grob gprop val)
 549   "Make a @code{Music} expression that overrides @var{gprop} to @var{val}
 550 in @var{grob}."
 551   (make-music 'OverrideProperty
 552               'symbol grob
 553               'grob-property gprop
 554               'grob-value val))
 555
 556 (define-public (make-grob-property-revert grob gprop)
 557   "Revert the grob property @var{gprop} for @var{grob}."
 558   (make-music 'RevertProperty
 559               'symbol grob
 560               'grob-property gprop))
 561
 562 (define direction-polyphonic-grobs
 563   '(AccidentalSuggestion
 564     DotColumn
 565     Dots
 566     Fingering
 567     LaissezVibrerTie
 568     LigatureBracket
 569     MultiMeasureRest
 570     PhrasingSlur
 571     RepeatTie
 572     Rest
 573     Script
 574     Slur
 575     Stem
 576     TextScript
 577     Tie
 578     TupletBracket
 579     TrillSpanner))
 580
 581 (define general-grace-settings
 582   `((Voice Stem font-size -3)
 583     (Voice Flag font-size -3)
 584     (Voice NoteHead font-size -3)
 585     (Voice TabNoteHead font-size -4)
 586     (Voice Dots font-size -3)
 587     (Voice Stem length-fraction 0.8)
 588     (Voice Stem no-stem-extend #t)
 589     (Voice Beam beam-thickness 0.384)
 590     (Voice Beam length-fraction 0.8)
 591     (Voice Accidental font-size -4)
 592     (Voice AccidentalCautionary font-size -4)
 593     (Voice Script font-size -3)
 594     (Voice Fingering font-size -8)
 595     (Voice StringNumber font-size -8)))
 596
 597 (define-public score-grace-settings
 598   (append
 599     `((Voice Stem direction ,UP)
 600       (Voice Slur direction ,DOWN))
 601     general-grace-settings))
 602
 603 ;; Getting a unique context id name
 604
 605 (define-session unique-counter -1)
 606 (define-safe-public (get-next-unique-voice-name)
 607   (set! unique-counter (1+ unique-counter))
 608   (format #f "uniqueContext~s" unique-counter))
 609
 610
 611 (define-safe-public (make-voice-props-set n)
 612   (make-sequential-music
 613    (append
 614     (map (lambda (x) (make-grob-property-set x 'direction
 615                                              (if (odd? n) -1 1)))
 616          direction-polyphonic-grobs)
 617     (list
 618      (make-property-set 'graceSettings general-grace-settings)
 619      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))))))
 620
 621 (define-safe-public (make-voice-props-override n)
 622   (make-sequential-music
 623    (append
 624     (map (lambda (x) (make-grob-property-override x 'direction
 625                                                   (if (odd? n) -1 1)))
 626          direction-polyphonic-grobs)
 627     (list
 628      (make-property-set 'graceSettings general-grace-settings)
 629      (make-grob-property-override 'NoteColumn 'horizontal-shift (quotient n 2))))))
 630
 631 (define-safe-public (make-voice-props-revert)
 632   (make-sequential-music
 633    (append
 634     (map (lambda (x) (make-grob-property-revert x 'direction))
 635          direction-polyphonic-grobs)
 636     (list (make-property-unset 'graceSettings)
 637           (make-grob-property-revert 'NoteColumn 'horizontal-shift)))))
 638
 639
 640 (define-safe-public (context-spec-music m context #:optional id)
 641   "Add \\context CONTEXT = ID to M."
 642   (let ((cm (make-music 'ContextSpeccedMusic
 643                         'element m
 644                         'context-type context)))
 645     (if (string? id)
 646         (set! (ly:music-property cm 'context-id) id))
 647     cm))
 648
 649 (define-public (descend-to-context m context)
 650   "Like @code{context-spec-music}, but only descending."
 651   (let ((cm (context-spec-music m context)))
 652     (ly:music-set-property! cm 'descend-only #t)
 653     cm))
 654
 655 (define-public (make-non-relative-music mus)
 656   (make-music 'UnrelativableMusic
 657               'element mus))
 658
 659 (define-public (make-apply-context func)
 660   (make-music 'ApplyContext
 661               'procedure func))
 662
 663 (define-public (make-sequential-music elts)
 664   (make-music 'SequentialMusic
 665               'elements elts))
 666
 667 (define-public (make-simultaneous-music elts)
 668   (make-music 'SimultaneousMusic
 669               'elements elts))
 670
 671 (define-safe-public (make-event-chord elts)
 672   (make-music 'EventChord
 673               'elements elts))
 674
 675 (define-public (make-skip-music dur)
 676   (make-music 'SkipMusic
 677               'duration dur))
 678
 679 (define-public (make-grace-music music)
 680   (make-music 'GraceMusic
 681               'element music))
 682
 683 ;;;;;;;;;;;;;;;;
 684
 685 ;; mmrest
 686 (define-public (make-multi-measure-rest duration location)
 687   (make-music 'MultiMeasureRestMusic
 688               'origin location
 689               'duration duration))
 690
 691 (define-public (make-property-set sym val)
 692   (make-music 'PropertySet
 693               'symbol sym
 694               'value val))
 695
 696 (define-public (make-property-unset sym)
 697   (make-music 'PropertyUnset
 698               'symbol sym))
 699
 700 (define-safe-public (make-articulation name . properties)
 701   (apply make-music 'ArticulationEvent
 702          'articulation-type name
 703          properties))
 704
 705 (define-public (make-lyric-event string duration)
 706   (make-music 'LyricEvent
 707               'duration duration
 708               'text string))
 709
 710 (define-safe-public (make-span-event type span-dir)
 711   (make-music type
 712               'span-direction span-dir))
 713
 714 (define-public (override-head-style heads style)
 715   "Override style for @var{heads} to @var{style}."
 716   (make-sequential-music
 717    (if (pair? heads)
 718        (map (lambda (h)
 719               (make-grob-property-override h 'style style))
 720             heads)
 721        (list (make-grob-property-override heads 'style style)))))
 722
 723 (define-public (revert-head-style heads)
 724   "Revert style for @var{heads}."
 725   (make-sequential-music
 726    (if (pair? heads)
 727        (map (lambda (h)
 728               (make-grob-property-revert h 'style))
 729             heads)
 730        (list (make-grob-property-revert heads 'style)))))
 731
 732 (define-public (style-note-heads heads style music)
 733   "Set @var{style} for all @var{heads} in @var{music}.  Works both
 734 inside of and outside of chord construct."
 735   ;; are we inside a <...>?
 736   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 737       ;; yes -> use a tweak
 738       (begin
 739         (set! (ly:music-property music 'tweaks)
 740               (acons 'style style (ly:music-property music 'tweaks)))
 741         music)
 742       ;; not in <...>, so use overrides
 743       (make-sequential-music
 744        (list
 745         (override-head-style heads style)
 746         music
 747         (revert-head-style heads)))))
 748
 749 (define-public (set-mus-properties! m alist)
 750   "Set all of @var{alist} as properties of @var{m}."
 751   (if (pair? alist)
 752       (begin
 753         (set! (ly:music-property m (caar alist)) (cdar alist))
 754         (set-mus-properties! m (cdr alist)))))
 755
 756 (define-public (music-separator? m)
 757   "Is @var{m} a separator?"
 758   (let ((ts (ly:music-property m 'types)))
 759     (memq 'separator ts)))
 760
 761 ;;; expanding repeat chords
 762 (define-public (copy-repeat-chord original-chord repeat-chord duration
 763                                   event-types)
 764   "Copies all events in @var{event-types} (be sure to include
 765 @code{rhythmic-events}) from @var{original-chord} over to
 766 @var{repeat-chord} with their articulations filtered as well.  Any
 767 duration is replaced with the specified @var{duration}."
 768   ;; First remove everything from event-types that can already be
 769   ;; found in the repeated chord.  We don't need to look for
 770   ;; articulations on individual events since they can't actually get
 771   ;; into a repeat chord given its input syntax.
 772
 773   (define keep-element? (music-type-predicate event-types))
 774
 775   (for-each
 776    (lambda (field)
 777      (for-each (lambda (e)
 778                  (for-each (lambda (x)
 779                              (set! event-types (delq x event-types)))
 780                            (ly:music-property e 'types)))
 781                (ly:music-property repeat-chord field)))
 782    '(elements articulations))
 783
 784   ;; now treat the elements
 785   (set! (ly:music-property repeat-chord 'elements)
 786         (let ((elts
 787                (ly:music-deep-copy (filter keep-element?
 788                                            (ly:music-property original-chord
 789                                                               'elements))
 790                                    repeat-chord)))
 791           (for-each
 792            (lambda (m)
 793              (let ((arts (ly:music-property m 'articulations)))
 794                (if (pair? arts)
 795                    (set! (ly:music-property m 'articulations)
 796                          (ly:set-origin! (filter! keep-element? arts)
 797                                          repeat-chord)))
 798                (if (ly:duration? (ly:music-property m 'duration))
 799                    (set! (ly:music-property m 'duration) duration))
 800                (if (ly:music-property m 'cautionary #f)
 801                    (set! (ly:music-property m 'cautionary) #f))
 802                (if (ly:music-property m 'force-accidental #f)
 803                    (set! (ly:music-property m 'force-accidental) #f))))
 804            elts)
 805           (append! elts (ly:music-property repeat-chord 'elements))))
 806   (let ((arts (filter keep-element?
 807                       (ly:music-property original-chord
 808                                          'articulations))))
 809     (if (pair? arts)
 810         (set! (ly:music-property repeat-chord 'articulations)
 811               (append!
 812                (ly:music-deep-copy arts repeat-chord)
 813                (ly:music-property repeat-chord 'articulations)))))
 814   repeat-chord)
 815
 816
 817 (define-public (expand-repeat-chords! event-types music)
 818   "Walks through @var{music} and fills repeated chords (notable by
 819 having a duration in @code{duration}) with the notes from their
 820 respective predecessor chord."
 821   (let loop ((music music) (last-chord #f))
 822     (if (music-is-of-type? music 'event-chord)
 823         (let ((chord-repeat (ly:music-property music 'duration)))
 824           (cond
 825            ((not (ly:duration? chord-repeat))
 826             (if (any (lambda (m) (ly:duration?
 827                                   (ly:music-property m 'duration)))
 828                      (ly:music-property music 'elements))
 829                 music
 830                 last-chord))
 831            (last-chord
 832             (set! (ly:music-property music 'duration) '())
 833             (copy-repeat-chord last-chord music chord-repeat event-types))
 834            (else
 835             (ly:music-warning music (_ "Bad chord repetition"))
 836             #f)))
 837         (let ((elt (ly:music-property music 'element)))
 838           (fold loop (if (ly:music? elt) (loop elt last-chord) last-chord)
 839                 (ly:music-property music 'elements)))))
 840   music)
 841
 842 ;;; This does _not_ copy any articulations.  Rationale: one main
 843 ;;; incentive for pitch-repeating durations is after ties, such that
 844 ;;; 4~2~8. can stand in for a 15/16 note in \partial 4 position.  In
 845 ;;; this use case, any repeated articulations will be a nuisance.
 846 ;;;
 847 ;;; String assignments in TabStaff might seem like a worthwhile
 848 ;;; exception, but they would be better tackled by the respective
 849 ;;; engravers themselves (see issue 3662).
 850 ;;;
 851 ;;; Repeating chords as well seems problematic for things like
 852 ;;; \score {
 853 ;;;   <<
 854 ;;;     \new Staff { c4 c c <c e> }
 855 ;;;     \new RhythmicStaff { 4 4 4 4 }
 856 ;;;   >>
 857 ;;; }
 858 ;;;
 859 ;;; However, because of MIDI it is not advisable to use RhythmicStaff
 860 ;;; without any initial pitch/drum-type.  For music functions taking
 861 ;;; pure rhythms as an argument, the running of expand-repeat-notes!
 862 ;;; at scorification time is irrelevant: at that point of time, the
 863 ;;; music function has already run.
 864
 865 (define-public (expand-repeat-notes! music)
 866   "Walks through @var{music} and gives pitchless notes (not having a
 867 pitch in code{pitch} or a drum type in @code{drum-type}) the pitch(es)
 868 from the predecessor note/chord if available."
 869   (let ((last-pitch #f))
 870     (map-some-music
 871      (lambda (m)
 872        (define (set-and-ret last)
 873          (set! last-pitch last)
 874          m)
 875        (cond
 876         ((music-is-of-type? m 'event-chord)
 877          (if (any (lambda (m) (music-is-of-type? m 'rhythmic-event))
 878                   (ly:music-property m 'elements))
 879              (set! last-pitch m))
 880          m)
 881         ((music-is-of-type? m 'note-event)
 882          (cond
 883           ((or (ly:music-property m 'pitch #f)
 884                (ly:music-property m 'drum-type #f))
 885            => set-and-ret)
 886           ;; ok, naked rhythm.  Go through the various cases of
 887           ;; last-pitch
 888           ;; nothing available: just keep as-is
 889           ((not last-pitch) m)
 890           ((ly:pitch? last-pitch)
 891            (set! (ly:music-property m 'pitch) last-pitch)
 892            m)
 893           ((symbol? last-pitch)
 894            (set! (ly:music-property m 'drum-type) last-pitch)
 895            m)
 896           ;; Ok, this is the big bad one: the reference is a chord.
 897           ;; For now, we use the repeat chord logic.  That's not
 898           ;; really efficient as cleaning out all articulations is
 899           ;; quite simpler than what copy-repeat-chord does.
 900           (else
 901            (copy-repeat-chord last-pitch
 902                               (make-music 'EventChord
 903                                           'elements
 904                                           (ly:music-property m 'articulations)
 905                                           'origin
 906                                           (ly:music-property m 'origin))
 907                               (ly:music-property m 'duration)
 908                               '(rhythmic-event)))))
 909         (else #f)))
 910      music)))
 911
 912 ;;; splitting chords into voices.
 913 (define (voicify-list lst number)
 914   "Make a list of Musics.
 915
 916 voicify-list :: [ [Music ] ] -> number -> [Music]
 917 LST is a list music-lists.
 918
 919 NUMBER is 0-base, i.e., Voice=1 (upstems) has number 0.
 920 "
 921   (if (null? lst)
 922       '()
 923       (cons (context-spec-music
 924              (make-sequential-music
 925               (list (make-voice-props-set number)
 926                     (make-simultaneous-music (car lst))))
 927              'Bottom  (number->string (1+ number)))
 928             (voicify-list (cdr lst) (1+ number)))))
 929
 930 (define (voicify-chord ch)
 931   "Split the parts of a chord into different Voices using separator"
 932   (let ((es (ly:music-property ch 'elements)))
 933     (set! (ly:music-property  ch 'elements)
 934           (voicify-list (split-list-by-separator es music-separator?) 0))
 935     ch))
 936
 937 (define-public (voicify-music m)
 938   "Recursively split chords that are separated with @code{\\\\}."
 939   (if (not (ly:music? m))
 940       (ly:error (_ "music expected: ~S") m))
 941   (let ((es (ly:music-property m 'elements))
 942         (e (ly:music-property m 'element)))
 943
 944     (if (pair? es)
 945         (set! (ly:music-property m 'elements) (map voicify-music es)))
 946     (if (ly:music? e)
 947         (set! (ly:music-property m 'element)  (voicify-music e)))
 948     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 949              (any music-separator? es))
 950         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 951     m))
 952
 953 (define-public (empty-music)
 954   (make-music 'Music))
 955
 956 ;; Make a function that checks score element for being of a specific type.
 957 (define-public (make-type-checker symbol)
 958   (lambda (elt)
 959     (grob::has-interface elt symbol)))
 960
 961 (define ((outputproperty-compatibility func sym val) grob g-context ao-context)
 962   (if (func grob)
 963       (set! (ly:grob-property grob sym) val)))
 964 (export outputproperty-compatibility)
 965
 966
 967 (define ((set-output-property grob-name symbol val)  grob grob-c context)
 968   "Usage example:
 969 @code{\\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))}"
 970   (let ((meta (ly:grob-property grob 'meta)))
 971     (if (equal? (assoc-get 'name meta) grob-name)
 972         (set! (ly:grob-property grob symbol) val))))
 973 (export set-output-property)
 974
 975
 976 (define-public (skip->rest mus)
 977   "Replace @var{mus} by @code{RestEvent} of the same duration if it is a
 978 @code{SkipEvent}.  Useful for extracting parts from crowded scores."
 979
 980   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 981        (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 982        mus))
 983
 984
 985 (define-public (music-clone music . music-properties)
 986   "Clone @var{music} and set properties according to
 987 @var{music-properties}, a list of alternating property symbols and
 988 values:
 989 @example\n(music-clone start-span 'span-direction STOP)
 990 @end example
 991 Only properties that are not overriden by @var{music-properties} are
 992 actually fully cloned."
 993   (let ((old-props (list-copy (ly:music-mutable-properties music)))
 994         (new-props '())
 995         (m (ly:make-music (ly:prob-immutable-properties music))))
 996     (define (set-props mus-props)
 997       (if (and (not (null? mus-props))
 998                (not (null? (cdr mus-props))))
 999           (begin
1000             (set! old-props (assq-remove! old-props (car mus-props)))
1001             (set! new-props
1002                   (assq-set! new-props
1003                              (car mus-props) (cadr mus-props)))
1004             (set-props (cddr mus-props)))))
1005     (set-props music-properties)
1006     (for-each
1007      (lambda (pair)
1008        (set! (ly:music-property m (car pair))
1009              (ly:music-deep-copy (cdr pair))))
1010      old-props)
1011     (for-each
1012      (lambda (pair)
1013        (set! (ly:music-property m (car pair)) (cdr pair)))
1014      new-props)
1015     m))
1016
1017 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1018 ;; warn for bare chords at start.
1019
1020 (define-public (ly:music-message music msg . rest)
1021   (let ((ip (ly:music-property music 'origin)))
1022     (if (ly:input-location? ip)
1023         (apply ly:input-message ip msg rest)
1024         (apply ly:message msg rest))))
1025
1026 (define-public (ly:music-warning music msg . rest)
1027   (let ((ip (ly:music-property music 'origin)))
1028     (if (ly:input-location? ip)
1029         (apply ly:input-warning ip msg rest)
1030         (apply ly:warning msg rest))))
1031
1032 (define-public (ly:event-warning event msg . rest)
1033   (let ((ip (ly:event-property event 'origin)))
1034     (if (ly:input-location? ip)
1035         (apply ly:input-warning ip msg rest)
1036         (apply ly:warning msg rest))))
1037
1038 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1039 ;;
1040 ;; setting stuff for grace context.
1041 ;;
1042
1043 (define (vector-extend v x)
1044   "Make a new vector consisting of V, with X added to the end."
1045   (let* ((n (vector-length v))
1046          (nv (make-vector (+ n 1) '())))
1047     (vector-move-left! v 0 n nv 0)
1048     (vector-set! nv n x)
1049     nv))
1050
1051 (define (vector-map f v)
1052   "Map F over V.  This function returns nothing."
1053   (do ((n (vector-length v))
1054        (i 0 (+ i 1)))
1055       ((>= i n))
1056     (f (vector-ref v i))))
1057
1058 (define (vector-reverse-map f v)
1059   "Map F over V, N to 0 order.  This function returns nothing."
1060   (do ((i (- (vector-length v) 1) (- i 1)))
1061       ((< i 0))
1062     (f (vector-ref v i))))
1063
1064 (define-public (add-grace-property context-name grob sym val)
1065   "Set @var{sym}=@var{val} for @var{grob} in @var{context-name}."
1066   (define (set-prop context)
1067     (let* ((where (or (ly:context-find context context-name) context))
1068            (current (ly:context-property where 'graceSettings))
1069            (new-settings (append current
1070                                  (list (list context-name grob sym val)))))
1071       (ly:context-set-property! where 'graceSettings new-settings)))
1072   (make-apply-context set-prop))
1073
1074 (define-public (remove-grace-property context-name grob sym)
1075   "Remove all @var{sym} for @var{grob} in @var{context-name}."
1076   (define (sym-grob-context? property sym grob context-name)
1077     (and (eq? (car property) context-name)
1078          (eq? (cadr property) grob)
1079          (eq? (caddr property) sym)))
1080   (define (delete-prop context)
1081     (let* ((where (or (ly:context-find context context-name) context))
1082            (current (ly:context-property where 'graceSettings))
1083            (prop-settings (filter
1084                            (lambda(x) (sym-grob-context? x sym grob context-name))
1085                            current))
1086            (new-settings current))
1087       (for-each (lambda(x)
1088                   (set! new-settings (delete x new-settings)))
1089                 prop-settings)
1090       (ly:context-set-property! where 'graceSettings new-settings)))
1091   (make-apply-context delete-prop))
1092
1093
1094 (defmacro-public def-grace-function (start stop . docstring)
1095   "Helper macro for defining grace music"
1096   `(define-music-function (music) (ly:music?)
1097      ,@docstring
1098      (make-music 'GraceMusic
1099                  'element (make-music 'SequentialMusic
1100                                       'elements (list (ly:music-deep-copy ,start)
1101                                                       music
1102                                                       (ly:music-deep-copy ,stop))))))
1103
1104 (defmacro-public define-syntax-function (type args signature . body)
1105   "Helper macro for `ly:make-music-function'.
1106 Syntax:
1107   (define-syntax-function result-type? (arg1 arg2 ...) (arg1-type arg2-type ...)
1108     ...function body...)
1109
1110 argX-type can take one of the forms @code{predicate?} for mandatory
1111 arguments satisfying the predicate, @code{(predicate?)} for optional
1112 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1113 value)}} for optional parameters with a specified default
1114 value (evaluated at definition time).  An optional parameter can be
1115 omitted in a call only when it can't get confused with a following
1116 parameter of different type.
1117
1118 @code{result-type?} can specify a default in the same manner as
1119 predicates, to be used in case of a type error in arguments or
1120 result."
1121
1122   (define (has-parser/location? arg where)
1123     (let loop ((arg arg))
1124       (if (list? arg)
1125           (any loop arg)
1126           (memq arg where))))
1127   (define (currying-lambda args doc-string? body)
1128     (if (and (pair? args)
1129              (pair? (car args)))
1130         (currying-lambda (car args) doc-string?
1131                          `((lambda ,(cdr args) ,@body)))
1132         (let* ((compatibility? (if (list? args)
1133                                    (= (length args) (+ 2 (length signature)))
1134                                    (and (pair? args) (pair? (cdr args))
1135                                         (eq? (car args) 'parser))))
1136                (realargs (if compatibility? (cddr args) args)))
1137           `(lambda ,realargs
1138              ,(format #f "~a\n~a" realargs (or doc-string? ""))
1139              ,@(if (and compatibility?
1140                         (has-parser/location? body (take args 2)))
1141                    `((let ((,(car args) (*parser*)) (,(cadr args) (*location*)))
1142                        ,@body))
1143                    body)))))
1144
1145   (let ((docstring
1146          (and (pair? body) (pair? (cdr body))
1147               (if (string? (car body))
1148                   (car body)
1149                   (and (pair? (car body))
1150                        (eq? '_i (caar body))
1151                        (pair? (cdar body))
1152                        (string? (cadar body))
1153                        (null? (cddar body))
1154                        (cadar body))))))
1155     ;; When the music function definition contains an i10n doc string,
1156     ;; (_i "doc string"), keep the literal string only
1157     `(ly:make-music-function
1158       (list ,@(map (lambda (pred)
1159                      (if (pair? pred)
1160                          `(cons ,(car pred)
1161                                 ,(and (pair? (cdr pred)) (cadr pred)))
1162                          pred))
1163                    (cons type signature)))
1164       ,(currying-lambda args docstring (if docstring (cdr body) body)))))
1165
1166 (defmacro-public define-music-function rest
1167   "Defining macro returning music functions.
1168 Syntax:
1169   (define-music-function (arg1 arg2 ...) (arg1-type? arg2-type? ...)
1170     ...function body...)
1171
1172 argX-type can take one of the forms @code{predicate?} for mandatory
1173 arguments satisfying the predicate, @code{(predicate?)} for optional
1174 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1175 value)}} for optional parameters with a specified default
1176 value (evaluated at definition time).  An optional parameter can be
1177 omitted in a call only when it can't get confused with a following
1178 parameter of different type.
1179
1180 Must return a music expression.  The @code{origin} is automatically
1181 set to the @code{location} parameter."
1182
1183   `(define-syntax-function (ly:music? (make-music 'Music 'void #t)) ,@rest))
1184
1185
1186 (defmacro-public define-scheme-function rest
1187   "Defining macro returning Scheme functions.
1188 Syntax:
1189   (define-scheme-function (arg1 arg2 ...) (arg1-type? arg2-type? ...)
1190     ...function body...)
1191
1192 argX-type can take one of the forms @code{predicate?} for mandatory
1193 arguments satisfying the predicate, @code{(predicate?)} for optional
1194 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1195 value)}} for optional parameters with a specified default
1196 value (evaluated at definition time).  An optional parameter can be
1197 omitted in a call only when it can't get confused with a following
1198 parameter of different type.
1199
1200 Can return arbitrary expressions.  If a music expression is returned,
1201 its @code{origin} is automatically set to the @code{location}
1202 parameter."
1203
1204   `(define-syntax-function scheme? ,@rest))
1205
1206 (defmacro-public define-void-function rest
1207   "This defines a Scheme function like @code{define-scheme-function} with
1208 void return value (i.e., what most Guile functions with `unspecified'
1209 value return).  Use this when defining functions for executing actions
1210 rather than returning values, to keep Lilypond from trying to interpret
1211 the return value."
1212   `(define-syntax-function (void? *unspecified*) ,@rest *unspecified*))
1213
1214 (defmacro-public define-event-function rest
1215   "Defining macro returning event functions.
1216 Syntax:
1217   (define-event-function (arg1 arg2 ...) (arg1-type? arg2-type? ...)
1218     ...function body...)
1219
1220 argX-type can take one of the forms @code{predicate?} for mandatory
1221 arguments satisfying the predicate, @code{(predicate?)} for optional
1222 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1223 value)}} for optional parameters with a specified default
1224 value (evaluated at definition time).  An optional parameter can be
1225 omitted in a call only when it can't get confused with a following
1226 parameter of different type.
1227
1228 Must return an event expression.  The @code{origin} is automatically
1229 set to the @code{location} parameter."
1230
1231   `(define-syntax-function (ly:event? (make-music 'Event 'void #t)) ,@rest))
1232
1233 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1234
1235 (define-public (cue-substitute quote-music)
1236   "Must happen after @code{quote-substitute}."
1237
1238   (if (vector? (ly:music-property quote-music 'quoted-events))
1239       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
1240              (clef (ly:music-property quote-music 'quoted-music-clef #f))
1241              (main-voice (case dir ((1) 1) ((-1) 0) (else #f)))
1242              (cue-voice (and main-voice (- 1 main-voice)))
1243              (cue-type (ly:music-property quote-music 'quoted-context-type #f))
1244              (cue-id (ly:music-property quote-music 'quoted-context-id))
1245              (main-music (ly:music-property quote-music 'element))
1246              (return-value quote-music))
1247
1248         (if main-voice
1249             (set! (ly:music-property quote-music 'element)
1250                   (make-sequential-music
1251                    (list
1252                     (make-voice-props-override main-voice)
1253                     main-music
1254                     (make-voice-props-revert)))))
1255
1256         ;; if we have stem dirs, change both quoted and main music
1257         ;; to have opposite stems.
1258
1259         ;; cannot context-spec Quote-music, since context
1260         ;; for the quotes is determined in the iterator.
1261
1262         (make-sequential-music
1263          (delq! #f
1264                 (list
1265                  (and clef (make-cue-clef-set clef))
1266                  (and cue-type cue-voice
1267                       (context-spec-music
1268                        (make-voice-props-override cue-voice)
1269                        cue-type cue-id))
1270                  quote-music
1271                  (and cue-type cue-voice
1272                       (context-spec-music
1273                        (make-voice-props-revert)
1274                        cue-type cue-id))
1275                  (and clef (make-cue-clef-unset))))))
1276       quote-music))
1277
1278 (define ((quote-substitute quote-tab) music)
1279   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
1280          (quoted-vector (and (string? quoted-name)
1281                              (hash-ref quote-tab quoted-name #f))))
1282
1283
1284     (if (string? quoted-name)
1285         (if (vector? quoted-vector)
1286             (begin
1287               (set! (ly:music-property music 'quoted-events) quoted-vector)
1288               (set! (ly:music-property music 'iterator-ctor)
1289                     ly:quote-iterator::constructor))
1290             (ly:music-warning music (ly:format (_ "cannot find quoted music: `~S'") quoted-name))))
1291     music))
1292 (export quote-substitute)
1293
1294
1295 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1296 ;; switch it on here, so parsing and init isn't checked (too slow!)
1297 ;;
1298 ;; automatic music transformations.
1299
1300 (define (switch-on-debugging m)
1301   (if (defined? 'set-debug-cell-accesses!)
1302       (set-debug-cell-accesses! 15000))
1303   m)
1304
1305 (define (music-check-error music)
1306   (define found #f)
1307   (define (signal m)
1308     (if (and (ly:music? m)
1309              (eq? (ly:music-property m 'error-found) #t))
1310         (set! found #t)))
1311
1312   (for-each signal (ly:music-property music 'elements))
1313   (signal (ly:music-property music 'element))
1314
1315   (if found
1316       (set! (ly:music-property music 'error-found) #t))
1317   music)
1318
1319 (define (precompute-music-length music)
1320   (set! (ly:music-property music 'length)
1321         (ly:music-length music))
1322   music)
1323
1324 (define-public (make-duration-of-length moment)
1325   "Make duration of the given @code{moment} length."
1326   (ly:make-duration 0 0
1327                     (ly:moment-main-numerator moment)
1328                     (ly:moment-main-denominator moment)))
1329
1330 (define (make-skipped moment bool)
1331   "Depending on BOOL, set or unset skipTypesetting,
1332 then make SkipMusic of the given MOMENT length, and
1333 then revert skipTypesetting."
1334   (make-sequential-music
1335    (list
1336     (context-spec-music (make-property-set 'skipTypesetting bool)
1337                         'Score)
1338     (make-music 'SkipMusic 'duration
1339                 (make-duration-of-length moment))
1340     (context-spec-music (make-property-set 'skipTypesetting (not bool))
1341                         'Score))))
1342
1343 (define (skip-as-needed music)
1344   "Replace MUSIC by
1345  << {  \\set skipTypesetting = ##f
1346  LENGTHOF(\\showFirstLength)
1347  \\set skipTypesetting = ##t
1348  LENGTHOF(\\showLastLength) }
1349  MUSIC >>
1350  if appropriate.
1351
1352  When only showFirstLength is set,
1353  the 'length property of the music is
1354  overridden to speed up compiling."
1355   (let*
1356       ((show-last (ly:parser-lookup 'showLastLength))
1357        (show-first (ly:parser-lookup 'showFirstLength))
1358        (show-last-length (and (ly:music? show-last)
1359                               (ly:music-length show-last)))
1360        (show-first-length (and (ly:music? show-first)
1361                                (ly:music-length show-first)))
1362        (orig-length (ly:music-length music)))
1363
1364     ;;FIXME: if using either showFirst- or showLastLength,
1365     ;; make sure that skipBars is not set.
1366
1367     (cond
1368
1369      ;; both properties may be set.
1370      ((and show-first-length show-last-length)
1371       (let
1372           ((skip-length (ly:moment-sub orig-length show-last-length)))
1373         (make-simultaneous-music
1374          (list
1375           (make-sequential-music
1376            (list
1377             (make-skipped skip-length #t)
1378             ;; let's draw a separator between the beginning and the end
1379             (context-spec-music (make-property-set 'whichBar "||")
1380                                 'Timing)))
1381           (make-skipped show-first-length #f)
1382           music))))
1383
1384      ;; we may only want to print the last length
1385      (show-last-length
1386       (let
1387           ((skip-length (ly:moment-sub orig-length show-last-length)))
1388         (make-simultaneous-music
1389          (list
1390           (make-skipped skip-length #t)
1391           music))))
1392
1393      ;; we may only want to print the beginning; in this case
1394      ;; only the first length will be processed (much faster).
1395      (show-first-length
1396       ;; the first length must not exceed the original length.
1397       (if (ly:moment<? show-first-length orig-length)
1398           (set! (ly:music-property music 'length)
1399                 show-first-length))
1400       music)
1401
1402      (else music))))
1403
1404
1405 (define-session-public toplevel-music-functions
1406   (list
1407    (lambda (music) (expand-repeat-chords!
1408                     (cons 'rhythmic-event
1409                           (ly:parser-lookup '$chord-repeat-events))
1410                     music))
1411    expand-repeat-notes!
1412    voicify-music
1413    (lambda (x) (music-map music-check-error x))
1414    (lambda (x) (music-map precompute-music-length x))
1415    (lambda (music)
1416      (music-map (quote-substitute (ly:parser-lookup 'musicQuotes))  music))
1417
1418    ;; switch-on-debugging
1419    (lambda (x) (music-map cue-substitute x))
1420
1421    skip-as-needed))
1422
1423 ;;;;;;;;;;
1424 ;;; general purpose music functions
1425
1426 (define (shift-octave pitch octave-shift)
1427   (_i "Add @var{octave-shift} to the octave of @var{pitch}.")
1428   (ly:make-pitch
1429    (+ (ly:pitch-octave pitch) octave-shift)
1430    (ly:pitch-notename pitch)
1431    (ly:pitch-alteration pitch)))
1432
1433
1434 ;;;;;;;;;;;;;;;;;
1435 ;; lyrics
1436
1437 (define (apply-durations lyric-music durations)
1438   (define (apply-duration music)
1439     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
1440              (ly:duration?  (ly:music-property music 'duration)))
1441         (begin
1442           (set! (ly:music-property music 'duration) (car durations))
1443           (set! durations (cdr durations)))))
1444
1445   (music-map apply-duration lyric-music))
1446
1447
1448 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1449 ;; accidentals
1450
1451 (define (recent-enough? bar-number alteration-def laziness)
1452   (or (number? alteration-def)
1453       (equal? laziness #t)
1454       (<= bar-number (+ (cadr alteration-def) laziness))))
1455
1456 (define (accidental-invalid? alteration-def)
1457   "Checks an alteration entry for being invalid.
1458
1459 Non-key alterations are invalidated when tying into the next bar or
1460 when there is a clef change, since neither repetition nor cancellation
1461 can be omitted when the same note occurs again.
1462
1463 Returns @code{#f} or the reason for the invalidation, a symbol."
1464   (let* ((def (if (pair? alteration-def)
1465                   (car alteration-def)
1466                   alteration-def)))
1467     (and (symbol? def) def)))
1468
1469 (define (extract-alteration alteration-def)
1470   (cond ((number? alteration-def)
1471          alteration-def)
1472         ((pair? alteration-def)
1473          (car alteration-def))
1474         (else 0)))
1475
1476 (define (check-pitch-against-signature context pitch barnum laziness octaveness all-naturals)
1477   "Checks the need for an accidental and a @q{restore} accidental against
1478 @code{localAlterations} and @code{keyAlterations}.
1479 The @var{laziness} is the number of measures
1480 for which reminder accidentals are used (i.e., if @var{laziness} is zero,
1481 only cancel accidentals in the same measure; if @var{laziness} is three,
1482 we cancel accidentals up to three measures after they first appear.
1483 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1484 specifies whether accidentals should be canceled in different octaves.
1485 If @var{all-naturals} is ##t, notes that do not occur in @code{keyAlterations}
1486 also get an accidental."
1487   (let* ((ignore-octave (cond ((equal? octaveness 'any-octave) #t)
1488                               ((equal? octaveness 'same-octave) #f)
1489                               (else
1490                                (ly:warning (_ "Unknown octaveness type: ~S ") octaveness)
1491                                (ly:warning (_ "Defaulting to 'any-octave."))
1492                                #t)))
1493          (key (ly:context-property context 'keyAlterations))
1494          (local (ly:context-property context 'localAlterations))
1495          (notename (ly:pitch-notename pitch))
1496          (octave (ly:pitch-octave pitch))
1497          (pitch-handle (cons octave notename))
1498          (need-restore #f)
1499          (need-accidental #f)
1500          (previous-alteration #f)
1501          (from-other-octaves #f)
1502          (from-same-octave (assoc-get pitch-handle local))
1503          (from-key-sig (or (assoc-get notename local)
1504
1505                            ;; If no notename match is found from localAlterations, we may have a custom
1506                            ;; type with octave-specific entries of the form ((octave . pitch) alteration)
1507                            ;; instead of (pitch . alteration).  Since this type cannot coexist with entries in
1508                            ;; localAlterations, try extracting from keyAlterations instead.
1509                            (assoc-get pitch-handle key))))
1510
1511     ;; loop through localAlterations to search for a notename match from other octaves
1512     (let loop ((l local))
1513       (if (pair? l)
1514           (let ((entry (car l)))
1515             (if (and (pair? (car entry))
1516                      (= (cdar entry) notename))
1517                 (set! from-other-octaves (cdr entry))
1518                 (loop (cdr l))))))
1519
1520     ;; find previous alteration-def for comparison with pitch
1521     (cond
1522      ;; from same octave?
1523      ((and (not ignore-octave)
1524            from-same-octave
1525            (recent-enough? barnum from-same-octave laziness))
1526       (set! previous-alteration from-same-octave))
1527
1528      ;; from any octave?
1529      ((and ignore-octave
1530            from-other-octaves
1531            (recent-enough? barnum from-other-octaves laziness))
1532       (set! previous-alteration from-other-octaves))
1533
1534      ;; not recent enough, extract from key signature/local key signature
1535      (from-key-sig
1536       (set! previous-alteration from-key-sig)))
1537
1538     (if (accidental-invalid? previous-alteration)
1539         (set! need-accidental #t)
1540
1541         (let* ((prev-alt (extract-alteration previous-alteration))
1542                (this-alt (ly:pitch-alteration pitch)))
1543
1544           (if (or (and all-naturals (eq? #f previous-alteration)) (not (= this-alt prev-alt)))
1545               (begin
1546                 (set! need-accidental #t)
1547                 (if (and (not (= this-alt 0))
1548                          (and (< (abs this-alt) (abs prev-alt))
1549                               (> (* prev-alt this-alt) 0)))
1550                     (set! need-restore #t))))))
1551
1552     (cons need-restore need-accidental)))
1553
1554 (define ((make-accidental-rule octaveness laziness) context pitch barnum measurepos)
1555   "Create an accidental rule that makes its decision based on the octave of
1556 the note and a laziness value.
1557
1558 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1559 defines whether the rule should respond to accidental changes in other
1560 octaves than the current.  @code{'same-octave} is the normal way to typeset
1561 accidentals -- an accidental is made if the alteration is different from the
1562 last active pitch in the same octave.  @code{'any-octave} looks at the last
1563 active pitch in any octave.
1564
1565 @var{laziness} states over how many bars an accidental should be remembered.
1566 @code{0}@tie{}is the default -- accidental lasts over 0@tie{}bar lines, that
1567 is, to the end of current measure.  A positive integer means that the
1568 accidental lasts over that many bar lines.  @w{@code{-1}} is `forget
1569 immediately', that is, only look at key signature.  @code{#t} is `forever'."
1570
1571   (check-pitch-against-signature context pitch barnum laziness octaveness #f))
1572 (export make-accidental-rule)
1573
1574 (define ((make-accidental-dodecaphonic-rule octaveness laziness) context pitch barnum measurepos)
1575   "Variation on function make-accidental-rule that creates an dodecaphonic
1576 accidental rule."
1577
1578   (check-pitch-against-signature context pitch barnum laziness octaveness #t))
1579 (export make-accidental-dodecaphonic-rule)
1580
1581 (define (key-entry-notename entry)
1582   "Return the pitch of an @var{entry} in @code{localAlterations}.
1583 The @samp{car} of the entry is either of the form @code{notename} or
1584 of the form @code{(octave . notename)}.  The latter form is used for special
1585 key signatures or to indicate an explicit accidental.
1586
1587 The @samp{cdr} of the entry is either a rational @code{alter} indicating
1588 a key signature alteration, or of the form
1589 @code{(alter . (barnum . measurepos))} indicating an alteration caused by
1590 an accidental in music."
1591   (if (pair? (car entry))
1592       (cdar entry)
1593       (car entry)))
1594
1595 (define (key-entry-octave entry)
1596   "Return the octave of an entry in @code{localAlterations}
1597 or @code{#f} if the entry does not have an octave.
1598 See @code{key-entry-notename} for details."
1599   (and (pair? (car entry)) (caar entry)))
1600
1601 (define (key-entry-bar-number entry)
1602   "Return the bar number of an entry in @code{localAlterations}
1603 or @code {#f} if the entry does not have a bar number.
1604 See @code{key-entry-notename} for details."
1605   (and (pair? (cdr entry)) (caddr entry)))
1606
1607 (define (key-entry-measure-position entry)
1608   "Return the measure position of an entry in @code{localAlterations}
1609 or @code {#f} if the entry does not have a measure position.
1610 See @code{key-entry-notename} for details."
1611   (and (pair? (cdr entry)) (cdddr entry)))
1612
1613 (define (key-entry-alteration entry)
1614   "Return the alteration of an entry in localAlterations
1615
1616 For convenience, returns @code{0} if entry is @code{#f}."
1617   (if entry
1618       (if (number? (cdr entry))
1619           (cdr entry)
1620           (cadr entry))
1621       0))
1622
1623 (define-public (find-pitch-entry keysig pitch accept-global accept-local)
1624   "Return the first entry in @var{keysig} that matches @var{pitch}
1625 by notename and octave.  Alteration is not considered.
1626 @var{accept-global} states whether key signature entries should be included.
1627 @var{accept-local} states whether local accidentals should be included.
1628 If no matching entry is found, @var{#f} is returned."
1629   (and (pair? keysig)
1630        (let* ((entry (car keysig))
1631               (entryoct (key-entry-octave entry))
1632               (entrynn (key-entry-notename entry))
1633               (nn (ly:pitch-notename pitch)))
1634          (if (and (equal? nn entrynn)
1635                   (or (not entryoct)
1636                       (= entryoct (ly:pitch-octave pitch)))
1637                   (if (key-entry-bar-number entry)
1638                       accept-local
1639                       accept-global))
1640              entry
1641              (find-pitch-entry (cdr keysig) pitch accept-global accept-local)))))
1642
1643 (define-public (neo-modern-accidental-rule context pitch barnum measurepos)
1644   "An accidental rule that typesets an accidental if it differs from the
1645 key signature @emph{and} does not directly follow a note on the same
1646 staff line.  This rule should not be used alone because it does neither
1647 look at bar lines nor different accidentals at the same note name."
1648   (let* ((keysig (ly:context-property context 'localAlterations))
1649          (entry (find-pitch-entry keysig pitch #t #t)))
1650     (if (not entry)
1651         (cons #f #f)
1652         (let* ((global-entry (find-pitch-entry keysig pitch #t #f))
1653                (key-acc (key-entry-alteration global-entry))
1654                (acc (ly:pitch-alteration pitch))
1655                (entrymp (key-entry-measure-position entry))
1656                (entrybn (key-entry-bar-number entry)))
1657           (cons #f (not (or (equal? acc key-acc)
1658                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1659
1660 (define-public (dodecaphonic-no-repeat-rule context pitch barnum measurepos)
1661   "An accidental rule that typesets an accidental before every
1662 note (just as in the dodecaphonic accidental style) @emph{except} if
1663 the note is immediately preceded by a note with the same pitch. This
1664 is a common accidental style in contemporary notation."
1665    (let* ((keysig (ly:context-property context 'localAlterations))
1666           (entry (find-pitch-entry keysig pitch #f #t)))
1667      (if (not entry)
1668          (cons #f #t)
1669          (let ((entrymp (key-entry-measure-position entry))
1670                (entrybn (key-entry-bar-number entry))
1671                (entryalt (key-entry-alteration entry))
1672                (alt (ly:pitch-alteration pitch)))
1673            (cons #t
1674                  (not (and (equal? entrybn barnum)
1675                            (or (equal? measurepos entrymp)
1676                                (ly:moment<? measurepos entrymp))
1677                            (equal? entryalt alt))))))))
1678
1679 (define-public (teaching-accidental-rule context pitch barnum measurepos)
1680   "An accidental rule that typesets a cautionary accidental if it is
1681 included in the key signature @emph{and} does not directly follow a note
1682 on the same staff line."
1683   (let* ((keysig (ly:context-property context 'localAlterations))
1684          (entry (find-pitch-entry keysig pitch #t #t)))
1685     (if (not entry)
1686         (cons #f #f)
1687         (let* ((global-entry (find-pitch-entry keysig pitch #f #f))
1688                (key-acc (key-entry-alteration global-entry))
1689                (acc (ly:pitch-alteration pitch))
1690                (entrymp (key-entry-measure-position entry))
1691                (entrybn (key-entry-bar-number entry)))
1692           (cons #f (not (or (equal? acc key-acc)
1693                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1694
1695 (define-public (set-accidentals-properties extra-natural
1696                                            auto-accs auto-cauts
1697                                            context)
1698   (context-spec-music
1699    (make-sequential-music
1700     (append (if (boolean? extra-natural)
1701                 (list (make-property-set 'extraNatural extra-natural))
1702                 '())
1703             (list (make-property-set 'autoAccidentals auto-accs)
1704                   (make-property-set 'autoCautionaries auto-cauts))))
1705    context))
1706
1707 (define-public (set-accidental-style style . rest)
1708   "Set accidental style to @var{style}.  Optionally take a context
1709 argument, e.g. @code{'Staff} or @code{'Voice}.  The context defaults
1710 to @code{Staff}, except for piano styles, which use @code{GrandStaff}
1711 as a context."
1712   (let ((context (if (pair? rest)
1713                      (car rest) 'Staff))
1714         (pcontext (if (pair? rest)
1715                       (car rest) 'GrandStaff)))
1716     (cond
1717      ;; accidentals as they were common in the 18th century.
1718      ((equal? style 'default)
1719       (set-accidentals-properties #t
1720                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1721                                   '()
1722                                   context))
1723      ;; accidentals from one voice do NOT get canceled in other voices
1724      ((equal? style 'voice)
1725       (set-accidentals-properties #t
1726                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1727                                   '()
1728                                   context))
1729      ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
1730      ;; This includes all the default accidentals, but accidentals also needs canceling
1731      ;; in other octaves and in the next measure.
1732      ((equal? style 'modern)
1733       (set-accidentals-properties #f
1734                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1735                                           ,(make-accidental-rule 'any-octave 0)
1736                                           ,(make-accidental-rule 'same-octave 1))
1737                                   '()
1738                                   context))
1739      ;; the accidentals that Stone adds to the old standard as cautionaries
1740      ((equal? style 'modern-cautionary)
1741       (set-accidentals-properties #f
1742                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1743                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1744                                           ,(make-accidental-rule 'same-octave 1))
1745                                   context))
1746      ;; same as modern, but accidentals different from the key signature are always
1747      ;; typeset - unless they directly follow a note of the same pitch.
1748      ((equal? style 'neo-modern)
1749       (set-accidentals-properties #f
1750                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1751                                           ,(make-accidental-rule 'any-octave 0)
1752                                           ,(make-accidental-rule 'same-octave 1)
1753                                           ,neo-modern-accidental-rule)
1754                                   '()
1755                                   context))
1756      ((equal? style 'neo-modern-cautionary)
1757       (set-accidentals-properties #f
1758                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1759                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1760                                           ,(make-accidental-rule 'same-octave 1)
1761                                           ,neo-modern-accidental-rule)
1762                                   context))
1763      ((equal? style 'neo-modern-voice)
1764       (set-accidentals-properties #f
1765                                   `(Voice ,(make-accidental-rule 'same-octave 0)
1766                                           ,(make-accidental-rule 'any-octave 0)
1767                                           ,(make-accidental-rule 'same-octave 1)
1768                                           ,neo-modern-accidental-rule
1769                                           Staff ,(make-accidental-rule 'same-octave 0)
1770                                           ,(make-accidental-rule 'any-octave 0)
1771                                           ,(make-accidental-rule 'same-octave 1)
1772                                           ,neo-modern-accidental-rule)
1773                                   '()
1774                                   context))
1775      ((equal? style 'neo-modern-voice-cautionary)
1776       (set-accidentals-properties #f
1777                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1778                                   `(Voice ,(make-accidental-rule 'any-octave 0)
1779                                           ,(make-accidental-rule 'same-octave 1)
1780                                           ,neo-modern-accidental-rule
1781                                           Staff ,(make-accidental-rule 'same-octave 0)
1782                                           ,(make-accidental-rule 'any-octave 0)
1783                                           ,(make-accidental-rule 'same-octave 1)
1784                                           ,neo-modern-accidental-rule)
1785                                   context))
1786      ;; Accidentals as they were common in dodecaphonic music with no tonality.
1787      ;; Each note gets one accidental.
1788      ((equal? style 'dodecaphonic)
1789       (set-accidentals-properties #f
1790                                   `(Staff ,(lambda (c p bn mp) '(#f . #t)))
1791                                   '()
1792                                   context))
1793      ;; As in dodecaphonic style with the exception that immediately
1794      ;; repeated notes (in the same voice) don't get an accidental
1795      ((equal? style 'dodecaphonic-no-repeat)
1796       (set-accidentals-properties #f
1797                                   `(Staff ,dodecaphonic-no-repeat-rule)
1798                                   '()
1799                                   context))
1800      ;; Variety of the dodecaphonic style. Each note gets an accidental,
1801      ;; except notes that were already handled in the same measure.
1802      ((equal? style 'dodecaphonic-first)
1803       (set-accidentals-properties #f
1804                                   `(Staff ,(make-accidental-dodecaphonic-rule 'same-octave 0))
1805                                   '()
1806                                   context))
1807
1808      ;; Multivoice accidentals to be read both by musicians playing one voice
1809      ;; and musicians playing all voices.
1810      ;; Accidentals are typeset for each voice, but they ARE canceled across voices.
1811      ((equal? style 'modern-voice)
1812       (set-accidentals-properties  #f
1813                                    `(Voice ,(make-accidental-rule 'same-octave 0)
1814                                            ,(make-accidental-rule 'any-octave 0)
1815                                            ,(make-accidental-rule 'same-octave 1)
1816                                            Staff ,(make-accidental-rule 'same-octave 0)
1817                                            ,(make-accidental-rule 'any-octave 0)
1818                                            ,(make-accidental-rule 'same-octave 1))
1819                                    '()
1820                                    context))
1821      ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
1822      ;; as cautionaries
1823      ((equal? style 'modern-voice-cautionary)
1824       (set-accidentals-properties #f
1825                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1826                                   `(Voice ,(make-accidental-rule 'any-octave 0)
1827                                           ,(make-accidental-rule 'same-octave 1)
1828                                           Staff ,(make-accidental-rule 'same-octave 0)
1829                                           ,(make-accidental-rule 'any-octave 0)
1830                                           ,(make-accidental-rule 'same-octave 1))
1831                                   context))
1832      ;; stone's suggestions for accidentals on grand staff.
1833      ;; Accidentals are canceled across the staves in the same grand staff as well
1834      ((equal? style 'piano)
1835       (set-accidentals-properties #f
1836                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1837                                           ,(make-accidental-rule 'any-octave 0)
1838                                           ,(make-accidental-rule 'same-octave 1)
1839                                           GrandStaff
1840                                           ,(make-accidental-rule 'any-octave 0)
1841                                           ,(make-accidental-rule 'same-octave 1))
1842                                   '()
1843                                   pcontext))
1844      ((equal? style 'piano-cautionary)
1845       (set-accidentals-properties #f
1846                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1847                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1848                                           ,(make-accidental-rule 'same-octave 1)
1849                                           GrandStaff
1850                                           ,(make-accidental-rule 'any-octave 0)
1851                                           ,(make-accidental-rule 'same-octave 1))
1852                                   pcontext))
1853
1854      ;; same as modern, but cautionary accidentals are printed for all sharp or flat
1855      ;; tones specified by the key signature.
1856      ((equal? style 'teaching)
1857       (set-accidentals-properties #f
1858                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1859                                   `(Staff ,(make-accidental-rule 'same-octave 1)
1860                                           ,teaching-accidental-rule)
1861                                   context))
1862
1863      ;; do not set localAlterations when a note alterated differently from
1864      ;; localAlterations is found.
1865      ;; Causes accidentals to be printed at every note instead of
1866      ;; remembered for the duration of a measure.
1867      ;; accidentals not being remembered, causing accidentals always to
1868      ;; be typeset relative to the time signature
1869      ((equal? style 'forget)
1870       (set-accidentals-properties '()
1871                                   `(Staff ,(make-accidental-rule 'same-octave -1))
1872                                   '()
1873                                   context))
1874      ;; Do not reset the key at the start of a measure.  Accidentals will be
1875      ;; printed only once and are in effect until overridden, possibly many
1876      ;; measures later.
1877      ((equal? style 'no-reset)
1878       (set-accidentals-properties '()
1879                                   `(Staff ,(make-accidental-rule 'same-octave #t))
1880                                   '()
1881                                   context))
1882      (else
1883       (ly:warning (_ "unknown accidental style: ~S") style)
1884       (make-sequential-music '())))))
1885
1886 (define-public (invalidate-alterations context)
1887   "Invalidate alterations in @var{context}.
1888
1889 Elements of @code{'localAlterations} corresponding to local
1890 alterations of the key signature have the form
1891 @code{'((octave . notename) . (alter barnum . measurepos))}.
1892 Replace them with a version where @code{alter} is set to @code{'clef}
1893 to force a repetition of accidentals.
1894
1895 Entries that conform with the current key signature are not invalidated."
1896   (let* ((keysig (ly:context-property context 'keyAlterations)))
1897     (set! (ly:context-property context 'localAlterations)
1898           (map-in-order
1899            (lambda (entry)
1900              (let* ((localalt (key-entry-alteration entry)))
1901                (if (or (accidental-invalid? localalt)
1902                        (not (key-entry-bar-number entry))
1903                        (= localalt
1904                           (key-entry-alteration
1905                            (find-pitch-entry
1906                             keysig
1907                             (ly:make-pitch (key-entry-octave entry)
1908                                            (key-entry-notename entry)
1909                                            0)
1910                             #t #t))))
1911                    entry
1912                    (cons (car entry) (cons 'clef (cddr entry))))))
1913            (ly:context-property context 'localAlterations)))))
1914
1915 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1916
1917 (define-public (skip-of-length mus)
1918   "Create a skip of exactly the same length as @var{mus}."
1919   (let* ((skip
1920           (make-music
1921            'SkipEvent
1922            'duration (ly:make-duration 0 0))))
1923
1924     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
1925
1926 (define-public (mmrest-of-length mus)
1927   "Create a multi-measure rest of exactly the same length as @var{mus}."
1928
1929   (let* ((skip
1930           (make-multi-measure-rest
1931            (ly:make-duration 0 0) '())))
1932     (ly:music-compress skip (ly:music-length mus))
1933     skip))
1934
1935 (define-public (pitch-of-note event-chord)
1936   (let ((evs (filter (lambda (x)
1937                        (music-is-of-type? x 'note-event))
1938                      (ly:music-property event-chord 'elements))))
1939
1940     (and (pair? evs)
1941          (ly:music-property (car evs) 'pitch))))
1942
1943 (define-public (duration-of-note event-chord)
1944   (cond
1945    ((pair? event-chord)
1946     (or (duration-of-note (car event-chord))
1947         (duration-of-note (cdr event-chord))))
1948    ((ly:music? event-chord)
1949     (let ((dur (ly:music-property event-chord 'duration)))
1950       (if (ly:duration? dur)
1951           dur
1952           (duration-of-note (ly:music-property event-chord 'elements)))))
1953    (else #f)))
1954
1955 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1956
1957 (define-public (map-some-music map? music)
1958   "Walk through @var{music}, transform all elements calling @var{map?}
1959 and only recurse if this returns @code{#f}.  @code{elements} or
1960 @code{articulations} that are not music expressions are discarded:
1961 this allows some amount of filtering.
1962
1963 @code{map-some-music} may overwrite the original @var{music}."
1964   (let loop ((music music))
1965     (or (map? music)
1966         (let ((elt (ly:music-property music 'element))
1967               (elts (ly:music-property music 'elements))
1968               (arts (ly:music-property music 'articulations)))
1969           (if (ly:music? elt)
1970               (set! (ly:music-property music 'element)
1971                     (loop elt)))
1972           (if (pair? elts)
1973               (set! (ly:music-property music 'elements)
1974                     (filter! ly:music? (map! loop elts))))
1975           (if (pair? arts)
1976               (set! (ly:music-property music 'articulations)
1977                     (filter! ly:music? (map! loop arts))))
1978           music))))
1979
1980 (define-public (for-some-music stop? music)
1981   "Walk through @var{music}, process all elements calling @var{stop?}
1982 and only recurse if this returns @code{#f}."
1983   (let loop ((music music))
1984     (if (not (stop? music))
1985         (let ((elt (ly:music-property music 'element)))
1986           (if (ly:music? elt)
1987               (loop elt))
1988           (for-each loop (ly:music-property music 'elements))
1989           (for-each loop (ly:music-property music 'articulations))))))
1990
1991 (define-public (fold-some-music pred? proc init music)
1992   "This works recursively on music like @code{fold} does on a list,
1993 calling @samp{(@var{pred?} music)} on every music element.  If
1994 @code{#f} is returned for an element, it is processed recursively
1995 with the same initial value of @samp{previous}, otherwise
1996 @samp{(@var{proc} music previous)} replaces @samp{previous}
1997 and no recursion happens.
1998 The top @var{music} is processed using @var{init} for @samp{previous}."
1999   (let loop ((music music) (previous init))
2000     (if (pred? music)
2001         (proc music previous)
2002         (fold loop
2003               (fold loop
2004                     (let ((elt (ly:music-property music 'element)))
2005                       (if (null? elt)
2006                           previous
2007                           (loop elt previous)))
2008                     (ly:music-property music 'elements))
2009               (ly:music-property music 'articulations)))))
2010
2011 (define-public (extract-music music pred?)
2012   "Return a flat list of all music matching @var{pred?} inside of
2013 @var{music}, not recursing into matches themselves."
2014   (reverse! (fold-some-music pred? cons '() music)))
2015
2016 (define-public (extract-named-music music music-name)
2017   "Return a flat list of all music named @var{music-name} (either a
2018 single event symbol or a list of alternatives) inside of @var{music},
2019 not recursing into matches themselves."
2020   (extract-music
2021    music
2022    (if (cheap-list? music-name)
2023        (lambda (m) (memq (ly:music-property m 'name) music-name))
2024        (lambda (m) (eq? (ly:music-property m 'name) music-name)))))
2025
2026 (define-public (extract-typed-music music type)
2027   "Return a flat list of all music with @var{type} (either a single
2028 type symbol or a list of alternatives) inside of @var{music}, not
2029 recursing into matches themselves."
2030   (extract-music music (music-type-predicate type)))
2031
2032 (define-public (event-chord-wrap! music)
2033   "Wrap isolated rhythmic events and non-postevent events in
2034 @var{music} inside of an @code{EventChord}.  Chord repeats @samp{q}
2035 are expanded using the default settings of the parser."
2036   (map-some-music
2037    (lambda (m)
2038      (cond ((music-is-of-type? m 'event-chord)
2039             (if (pair? (ly:music-property m 'articulations))
2040                 (begin
2041                   (set! (ly:music-property m 'elements)
2042                         (append (ly:music-property m 'elements)
2043                                 (ly:music-property m 'articulations)))
2044                   (set! (ly:music-property m 'articulations) '())))
2045             m)
2046            ((music-is-of-type? m 'rhythmic-event)
2047             (let ((arts (ly:music-property m 'articulations)))
2048               (if (pair? arts)
2049                   (set! (ly:music-property m 'articulations) '()))
2050               (make-event-chord (cons m arts))))
2051            (else #f)))
2052    (expand-repeat-notes!
2053     (expand-repeat-chords!
2054      (cons 'rhythmic-event
2055            (ly:parser-lookup '$chord-repeat-events))
2056      music))))
2057
2058 (define-public (event-chord-notes event-chord)
2059   "Return a list of all notes from @var{event-chord}."
2060   (filter
2061    (lambda (m) (eq? 'NoteEvent (ly:music-property m 'name)))
2062    (ly:music-property event-chord 'elements)))
2063
2064 (define-public (event-chord-pitches event-chord)
2065   "Return a list of all pitches from @var{event-chord}."
2066   (map (lambda (x) (ly:music-property x 'pitch))
2067        (event-chord-notes event-chord)))
2068
2069 (define-public (event-chord-reduce music)
2070   "Reduces event chords in @var{music} to their first note event,
2071 retaining only the chord articulations.  Returns the modified music."
2072   (map-some-music
2073    (lambda (m)
2074      (and (music-is-of-type? m 'event-chord)
2075           (let*-values (((notes arts) (partition
2076                                        (lambda (mus)
2077                                          (music-is-of-type? mus 'rhythmic-event))
2078                                        (ly:music-property m 'elements)))
2079                         ((dur) (ly:music-property m 'duration))
2080                         ((full-arts) (append arts
2081                                              (ly:music-property m 'articulations)))
2082                         ((first-note) (and (pair? notes) (car notes))))
2083             (cond (first-note
2084                    (set! (ly:music-property first-note 'articulations)
2085                          full-arts)
2086                    first-note)
2087                   ((ly:duration? dur)
2088                    ;; A repeat chord. Produce an unpitched note.
2089                    (make-music 'NoteEvent
2090                                'duration dur
2091                                'articulations full-arts))
2092                   (else
2093                    (ly:music-error m (_ "Missing duration"))
2094                    (make-music 'NoteEvent
2095                                'duration (ly:make-duration 2 0 0)
2096                                'articulations full-arts))))))
2097    music))
2098
2099
2100 (defmacro-public make-relative (variables reference music)
2101   "The list of pitch or music variables in @var{variables} is used as
2102 a sequence for creating relativable music from @var{music}.
2103
2104 When the constructed music is used outside of @code{\\relative}, it
2105 just reflects plugging in the @var{variables} into @var{music}.
2106
2107 The action inside of @code{\\relative}, however, is determined by
2108 first relativizing the surrogate @var{reference} with the variables
2109 plugged in and then using the variables relativized as a side effect
2110 of relativizing @var{reference} for evaluating @var{music}.
2111
2112 Since pitches don't have the object identity required for tracing the
2113 effect of the reference call, they are replaced @emph{only} for the
2114 purpose of evaluating @var{reference} with simple pitched note events.
2115
2116 The surrogate @var{reference} expression has to be written with that
2117 in mind.  In addition, it must @emph{not} contain @emph{copies} of
2118 music that is supposed to be relativized but rather the
2119 @emph{originals}.  This @emph{includes} the pitch expressions.  As a
2120 rule, inside of @code{#@{@dots{}#@}} variables must @emph{only} be
2121 introduced using @code{#}, never via the copying construct @code{$}.
2122 The reference expression will usually just be a sequential or chord
2123 expression naming all variables in sequence, implying that following
2124 music will be relativized according to the resulting pitch of the last
2125 or first variable, respectively.
2126
2127 Since the usual purpose is to create more complex music from general
2128 arguments and since music expression parts must not occur more than
2129 once, one @emph{does} generally need to use copying operators in the
2130 @emph{replacement} expression @var{music} when using an argument more
2131 than once there.  Using an argument more than once in @var{reference},
2132 in contrast, does not make sense.
2133
2134 There is another fine point to mind: @var{music} must @emph{only}
2135 contain freshly constructed elements or copied constructs.  This will
2136 be the case anyway for regular LilyPond code inside of
2137 @code{#@{@dots{}#@}}, but any other elements (apart from the
2138 @var{variables} themselves which are already copied) must be created
2139 or copied as well.
2140
2141 The reason is that it is usually permitted to change music in-place as
2142 long as one does a @var{ly:music-deep-copy} on it, and such a copy of
2143 the whole resulting expression will @emph{not} be able to copy
2144 variables/values inside of closures where the information for
2145 relativization is being stored.
2146 "
2147
2148   ;; pitch and music generator might be stored instead in music
2149   ;; properties, and it might make sense to create a music type of its
2150   ;; own for this kind of construct rather than using
2151   ;; RelativeOctaveMusic
2152   (define ((make-relative::to-relative-callback variables music-call ref-call)
2153            music pitch)
2154     (let* ((ref-vars (map (lambda (v)
2155                             (if (ly:pitch? v)
2156                                 (make-music 'NoteEvent 'pitch v)
2157                                 (ly:music-deep-copy v)))
2158                           variables))
2159            (after-pitch (ly:make-music-relative! (apply ref-call ref-vars) pitch))
2160            (actual-vars (map (lambda (v r)
2161                                (if (ly:pitch? v)
2162                                    (ly:music-property r 'pitch)
2163                                    r))
2164                              variables ref-vars))
2165            (rel-music (apply music-call actual-vars)))
2166       (set! (ly:music-property music 'element) rel-music)
2167       after-pitch))
2168   `(make-music 'RelativeOctaveMusic
2169                'to-relative-callback
2170                (,make-relative::to-relative-callback
2171                 (list ,@variables)
2172                 (lambda ,variables ,music)
2173                 (lambda ,variables ,reference))
2174                'element ,music))
2175
2176 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2177 ;; The following functions are all associated with the crossStaff
2178 ;;  function
2179
2180 (define (close-enough? x y)
2181   "Values are close enough to ignore the difference"
2182   (< (abs (- x y)) 0.0001))
2183
2184 (define (extent-combine extents)
2185   "Combine a list of extents"
2186   (if (pair? (cdr extents))
2187       (interval-union (car extents) (extent-combine (cdr extents)))
2188       (car extents)))
2189
2190 (define ((stem-connectable? ref root) stem)
2191   "Check if the stem is connectable to the root"
2192   ;; The root is always connectable to itself
2193   (or (eq? root stem)
2194       (and
2195        ;; Horizontal positions of the stems must be almost the same
2196        (close-enough? (car (ly:grob-extent root ref X))
2197                       (car (ly:grob-extent stem ref X)))
2198        ;; The stem must be in the direction away from the root's notehead
2199        (positive? (* (ly:grob-property root 'direction)
2200                      (- (car (ly:grob-extent stem ref Y))
2201                         (car (ly:grob-extent root ref Y))))))))
2202
2203 (define (stem-span-stencil span)
2204   "Connect stems if we have at least one stem connectable to the root"
2205   (let* ((system (ly:grob-system span))
2206          (root (ly:grob-parent span X))
2207          (stems (filter (stem-connectable? system root)
2208                         (ly:grob-object span 'stems))))
2209     (if (<= 2 (length stems))
2210         (let* ((yextents (map (lambda (st)
2211                                 (ly:grob-extent st system Y)) stems))
2212                (yextent (extent-combine yextents))
2213                (layout (ly:grob-layout root))
2214                (blot (ly:output-def-lookup layout 'blot-diameter)))
2215           ;; Hide spanned stems
2216           (for-each (lambda (st)
2217                       (set! (ly:grob-property st 'stencil) #f))
2218                     stems)
2219           ;; Draw a nice looking stem with rounded corners
2220           (ly:round-filled-box (ly:grob-extent root root X) yextent blot))
2221         ;; Nothing to connect, don't draw the span
2222         #f)))
2223
2224 (define ((make-stem-span! stems trans) root)
2225   "Create a stem span as a child of the cross-staff stem (the root)"
2226   (let ((span (ly:engraver-make-grob trans 'Stem '())))
2227     (ly:grob-set-parent! span X root)
2228     (set! (ly:grob-object span 'stems) stems)
2229     ;; Suppress positioning, the stem code is confused by this weird stem
2230     (set! (ly:grob-property span 'X-offset) 0)
2231     (set! (ly:grob-property span 'stencil) stem-span-stencil)))
2232
2233 (define-public (cross-staff-connect stem)
2234   "Set cross-staff property of the stem to this function to connect it to
2235 other stems automatically"
2236   #t)
2237
2238 (define (stem-is-root? stem)
2239   "Check if automatic connecting of the stem was requested.  Stems connected
2240 to cross-staff beams are cross-staff, but they should not be connected to
2241 other stems just because of that."
2242   (eq? cross-staff-connect (ly:grob-property-data stem 'cross-staff)))
2243
2244 (define (make-stem-spans! ctx stems trans)
2245   "Create stem spans for cross-staff stems"
2246   ;; Cannot do extensive checks here, just make sure there are at least
2247   ;; two stems at this musical moment
2248   (if (<= 2 (length stems))
2249       (let ((roots (filter stem-is-root? stems)))
2250         (for-each (make-stem-span! stems trans) roots))))
2251
2252 (define-public (Span_stem_engraver ctx)
2253   "Connect cross-staff stems to the stems above in the system"
2254   (let ((stems '()))
2255     (make-engraver
2256      ;; Record all stems for the given moment
2257      (acknowledgers
2258       ((stem-interface trans grob source)
2259        (set! stems (cons grob stems))))
2260      ;; Process stems and reset the stem list to empty
2261      ((process-acknowledged trans)
2262       (make-stem-spans! ctx stems trans)
2263       (set! stems '())))))
2264
2265 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2266 ;; The following is used by the alterBroken function.
2267
2268 (define ((value-for-spanner-piece arg) grob)
2269   "Associate a piece of broken spanner @var{grob} with an element
2270 of list @var{arg}."
2271   (let* ((orig (ly:grob-original grob))
2272          (siblings (ly:spanner-broken-into orig)))
2273
2274     (define (helper sibs arg)
2275       (if (null? arg)
2276           arg
2277           (if (eq? (car sibs) grob)
2278               (car arg)
2279               (helper (cdr sibs) (cdr arg)))))
2280
2281     (if (>= (length siblings) 2)
2282         (helper siblings arg)
2283         (car arg))))
2284 (export value-for-spanner-piece)
2285
2286 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2287 ;; The following are used by the \offset function
2288
2289 (define (find-value-to-offset prop self alist)
2290   "Return the first value of the property @var{prop} in the property
2291 alist @var{alist} -- after having found @var{self}.  If @var{self} is
2292 not found, return the first value of @var{prop}."
2293   (let ((segment (member (cons prop self) alist)))
2294     (if (not segment)
2295         (assoc-get prop alist)
2296         (assoc-get prop (cdr segment)))))
2297
2298 (define (offset-multiple-types arg offsets)
2299   "Displace @var{arg} by @var{offsets} if @var{arg} is a number, a
2300 number pair, or a list of number pairs.  If @var{offsets} is an empty
2301 list or if there is a type-mismatch, @var{arg} will be returned."
2302   (cond
2303     ((and (number? arg) (number? offsets))
2304      (+ arg offsets))
2305     ((and (number-pair? arg)
2306           (or (number? offsets)
2307               (number-pair? offsets)))
2308      (coord-translate arg offsets))
2309     ((and (number-pair-list? arg) (number-pair-list? offsets))
2310      (map
2311        (lambda (x y) (coord-translate x y))
2312        arg offsets))
2313     (else arg)))
2314
2315 (define-public (offsetter property offsets)
2316   "Apply @var{offsets} to the default values of @var{property} of @var{grob}.
2317 Offsets are restricted to immutable properties and values of type @code{number},
2318 @code{number-pair}, or @code{number-pair-list}."
2319   (define (worker self container-part grob . rest)
2320     (let* ((immutable (ly:grob-basic-properties grob))
2321            ;; We need to search the basic-properties alist for our
2322            ;; property to obtain values to offset.  Our search is
2323            ;; complicated by the fact that calling the music function
2324            ;; `offset' as an override conses a pair to the head of the
2325            ;; alist.  This pair must be discounted.  The closure it
2326            ;; contains is named `self' so it can be easily recognized.
2327            ;; If `offset' is called as a tweak, the basic-property
2328            ;; alist is unaffected.
2329            (target (find-value-to-offset property self immutable))
2330            ;; if target is a procedure, we need to apply it to our
2331            ;; grob to calculate values to offset.
2332            (vals (cond ((procedure? target) (target grob))
2333                        ;; Argument lists for a pure procedure pulled
2334                        ;; from an unpure-pure-container may be
2335                        ;; different from a normal procedure, so we
2336                        ;; need a different code path and calling
2337                        ;; convention for procedures pulled from an
2338                        ;; container as opposed to from the property
2339                        ((ly:unpure-pure-container? target)
2340                         (let ((part (container-part target)))
2341                           (if (procedure? part)
2342                               (apply part grob rest)
2343                               part)))
2344                        (else target)))
2345            (can-type-be-offset?
2346             (or (number? vals)
2347                 (number-pair? vals)
2348                 (number-pair-list? vals))))
2349
2350       (if can-type-be-offset?
2351           ;; '(+inf.0 . -inf.0) would offset to itself.  This will be
2352           ;; confusing to a user unaware of the default value of the
2353           ;; property, so issue a warning.
2354           (if (equal? empty-interval vals)
2355               (ly:warning "default '~a of ~a is ~a and can't be offset"
2356                 property grob vals)
2357               (let* ((orig (ly:grob-original grob))
2358                      (siblings
2359                        (if (ly:spanner? grob)
2360                            (ly:spanner-broken-into orig)
2361                            '()))
2362                      (total-found (length siblings))
2363                      ;; Since there is some flexibility in input
2364                      ;; syntax, structure of `offsets' is normalized.
2365                      (offsets
2366                        (if (or (not (pair? offsets))
2367                                (number-pair? offsets)
2368                                (and (number-pair-list? offsets)
2369                                     (number-pair-list? vals)))
2370                            (list offsets)
2371                            offsets)))
2372
2373                 (define (helper sibs offs)
2374                   ;; apply offsets to the siblings of broken spanners
2375                   (if (pair? offs)
2376                       (if (eq? (car sibs) grob)
2377                           (offset-multiple-types vals (car offs))
2378                           (helper (cdr sibs) (cdr offs)))
2379                       vals))
2380
2381                 (if (>= total-found 2)
2382                     (helper siblings offsets)
2383                     (offset-multiple-types vals (car offsets)))))
2384
2385           (begin
2386             (ly:warning "the property '~a of ~a cannot be offset" property grob)
2387             vals))))
2388   ;; return the container named `self'.  The container self-reference
2389   ;; seems like chasing its own tail but gets dissolved by
2390   ;; define/lambda separating binding and referencing of "self".
2391   (define self (ly:make-unpure-pure-container
2392                 (lambda (grob)
2393                   (worker self ly:unpure-pure-container-unpure-part grob))
2394                 (lambda (grob . rest)
2395                   (apply worker self ly:unpure-pure-container-pure-part
2396                          grob rest))))
2397   self)
2398
2399 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2400 ;; \magnifyMusic and \magnifyStaff
2401
2402 ;; defined as a function instead of a list because the
2403 ;; all-grob-descriptions alist is not available yet
2404 (define-public (find-named-props prop-name grob-descriptions)
2405   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  When
2406 @var{grob-descriptions} is equal to the @code{all-grob-descriptions}
2407 alist (defined in @file{scm/define-grobs.scm}), this will find all grobs
2408 that can have a value for the @var{prop-name} property, and return them
2409 as a list in the following format:
2410 @example
2411 '((grob prop-name)
2412   (grob prop-name)
2413   ...)
2414 @end example"
2415   (define (find-grobs-with-interface interface grob-descriptions)
2416     (define (has-this-interface? grob-desc)
2417       (let* ((meta (ly:assoc-get 'meta (cdr grob-desc)))
2418              (interfaces (ly:assoc-get 'interfaces meta '())))
2419         (memq interface interfaces)))
2420     (let* ((grob-descriptions-with-this-interface
2421              (filter has-this-interface? grob-descriptions))
2422            (grob-names-with-this-interface
2423              (map car grob-descriptions-with-this-interface)))
2424       grob-names-with-this-interface))
2425   (let* ((interface
2426            (case prop-name
2427              ((baseline-skip word-space) 'text-interface)
2428              ((space-alist)              'break-aligned-interface)
2429              (else (ly:programming-error
2430                      "find-named-props: no interface associated with ~s"
2431                      prop-name))))
2432          (grobs-with-this-prop
2433            (find-grobs-with-interface interface grob-descriptions)))
2434     (map (lambda (x) (list x prop-name))
2435          grobs-with-this-prop)))
2436
2437
2438 (define (magnifyStaff-is-set? context mag)
2439   (let* ((Staff (ly:context-find context 'Staff))
2440          (old-mag (ly:context-property Staff 'magnifyStaffValue)))
2441     (not (null? old-mag))))
2442
2443 (define (staff-magnification-is-changing? context mag)
2444   (let* ((Staff (ly:context-find context 'Staff))
2445          (old-mag (ly:context-property Staff 'magnifyStaffValue 1)))
2446     (not (= old-mag mag))))
2447
2448 (define-public (scale-fontSize func-name mag)
2449   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Look up the
2450 current @code{fontSize} in the appropriate context and scale it by the
2451 magnification factor @var{mag}.  @var{func-name} is either
2452 @code{'magnifyMusic} or @code{'magnifyStaff}."
2453   (make-apply-context
2454     (lambda (context)
2455       (if (or (eq? func-name 'magnifyMusic)
2456               ;; for \magnifyStaff, only scale the fontSize
2457               ;; if staff magnification is changing
2458               ;; and does not equal 1
2459               (and (staff-magnification-is-changing? context mag)
2460                    (not (= mag 1))))
2461         (let* ((where (case func-name
2462                         ((magnifyMusic) context)
2463                         ((magnifyStaff) (ly:context-find context 'Staff))))
2464                (fontSize (ly:context-property where 'fontSize 0))
2465                (new-fontSize (+ fontSize (magnification->font-size mag))))
2466           (ly:context-set-property! where 'fontSize new-fontSize))))))
2467
2468 (define-public (revert-fontSize func-name mag)
2469   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Calculate
2470 the previous @code{fontSize} value (before scaling) by factoring out the
2471 magnification factor @var{mag} (if @var{func-name} is
2472 @code{'magnifyMusic}), or by factoring out the context property
2473 @code{magnifyStaffValue} (if @var{func-name} is @code{'magnifyStaff}).
2474 Revert the @code{fontSize} in the appropriate context accordingly.
2475
2476 With @code{\\magnifyMusic}, the scaling is reverted after the music
2477 block it operates on.  @code{\\magnifyStaff} does not operate on a music
2478 block, so the scaling from a previous call (if there is one) is reverted
2479 before the new scaling takes effect."
2480   (make-apply-context
2481     (lambda (context)
2482       (if (or (eq? func-name 'magnifyMusic)
2483               ;; for \magnifyStaff...
2484               (and
2485                 ;; don't revert the user's fontSize choice
2486                 ;; the first time \magnifyStaff is called
2487                 (magnifyStaff-is-set? context mag)
2488                 ;; only revert the previous fontSize
2489                 ;; if staff magnification is changing
2490                 (staff-magnification-is-changing? context mag)))
2491         (let* ((where
2492                  (case func-name
2493                    ((magnifyMusic) context)
2494                    ((magnifyStaff) (ly:context-find context 'Staff))))
2495                (old-mag
2496                  (case func-name
2497                    ((magnifyMusic) mag)
2498                    ((magnifyStaff)
2499                     (ly:context-property where 'magnifyStaffValue 1))))
2500                (fontSize (ly:context-property where 'fontSize 0))
2501                (old-fontSize (- fontSize (magnification->font-size old-mag))))
2502           (ly:context-set-property! where 'fontSize old-fontSize))))))
2503
2504 (define-public (scale-props func-name mag allowed-to-shrink? props)
2505   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  For each
2506 prop in @var{props}, find the current value of the requested prop, scale
2507 it by the magnification factor @var{mag}, and do the equivalent of a
2508 @code{\\temporary@tie{}\\override} with the new value in the appropriate
2509 context.  If @var{allowed-to-shrink?} is @code{#f}, don't let the new
2510 value be less than the current value.  @var{func-name} is either
2511 @code{'magnifyMusic} or @code{'magnifyStaff}.  The @var{props} list is
2512 formatted like:
2513 @example
2514 '((Stem thickness)
2515   (Slur line-thickness)
2516   ...)
2517 @end example"
2518   (make-apply-context
2519     (lambda (context)
2520       (define (scale-prop grob-prop-list)
2521         (let* ((grob (car grob-prop-list))
2522                (prop (cadr grob-prop-list))
2523                (where (if (eq? grob 'SpacingSpanner)
2524                         (ly:context-find context 'Score)
2525                         (case func-name
2526                           ((magnifyMusic) context)
2527                           ((magnifyStaff) (ly:context-find context 'Staff)))))
2528                (grob-def (ly:context-grob-definition where grob)))
2529           (if (eq? prop 'space-alist)
2530             (let* ((space-alist (ly:assoc-get prop grob-def))
2531                    (scale-spacing-tuple (lambda (x)
2532                                           (cons (car x)
2533                                                 (cons (cadr x)
2534                                                       (* mag (cddr x))))))
2535                    (scaled-tuples (if space-alist
2536                                       (map scale-spacing-tuple space-alist)
2537                                       '()))
2538                    (new-alist (append scaled-tuples space-alist)))
2539               (ly:context-pushpop-property where grob prop new-alist))
2540             (let* ((val (ly:assoc-get prop grob-def (case prop
2541                                                       ((baseline-skip) 3)
2542                                                       ((word-space)    0.6)
2543                                                       (else            1))))
2544                    (proc (lambda (x)
2545                            (if allowed-to-shrink?
2546                              (* x mag)
2547                              (* x (max 1 mag)))))
2548                    (new-val (if (number-pair? val)
2549                               (cons (proc (car val))
2550                                     (proc (cdr val)))
2551                               (proc val))))
2552               (ly:context-pushpop-property where grob prop new-val)))))
2553       (if (or (eq? func-name 'magnifyMusic)
2554               ;; for \magnifyStaff, only scale the properties
2555               ;; if staff magnification is changing
2556               ;; and does not equal 1
2557               (and (staff-magnification-is-changing? context mag)
2558                    (not (= mag 1))))
2559         (for-each scale-prop props)))))
2560
2561 (define-public (revert-props func-name mag props)
2562   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Revert each
2563 prop in @var{props} in the appropriate context.  @var{func-name} is
2564 either @code{'magnifyMusic} or @code{'magnifyStaff}.  The @var{props}
2565 list is formatted like:
2566 @example
2567 '((Stem thickness)
2568   (Slur line-thickness)
2569   ...)
2570 @end example"
2571   (make-apply-context
2572     (lambda (context)
2573       (define (revert-prop grob-prop-list)
2574         (let* ((grob (car grob-prop-list))
2575                (prop (cadr grob-prop-list))
2576                (where (if (eq? grob 'SpacingSpanner)
2577                         (ly:context-find context 'Score)
2578                         (case func-name
2579                           ((magnifyMusic) context)
2580                           ((magnifyStaff) (ly:context-find context 'Staff))))))
2581           (ly:context-pushpop-property where grob prop)))
2582       (if (or (eq? func-name 'magnifyMusic)
2583               ;; for \magnifyStaff...
2584               (and
2585                 ;; don't revert the user's property overrides
2586                 ;; the first time \magnifyStaff is called
2587                 (magnifyStaff-is-set? context mag)
2588                 ;; revert the overrides from the previous \magnifyStaff,
2589                 ;; but only if staff magnification is changing
2590                 (staff-magnification-is-changing? context mag)))
2591         (for-each revert-prop props)))))
2592
2593 ;; \magnifyMusic only
2594 (define-public (scale-beam-thickness mag)
2595   "Used by @code{\\magnifyMusic}.  Scaling @code{Beam.beam-thickness}
2596 exactly to the @var{mag} value will not work.  This uses two reference
2597 values for @code{beam-thickness} to determine an acceptable value when
2598 scaling, then does the equivalent of a
2599 @code{\\temporary@tie{}\\override} with the new value."
2600   (make-apply-context
2601     (lambda (context)
2602       (let* ((grob-def (ly:context-grob-definition context 'Beam))
2603              (val (ly:assoc-get 'beam-thickness grob-def 0.48))
2604              (ratio-to-default (/ val 0.48))
2605              ;; gives beam-thickness=0.48 when mag=1 (like default),
2606              ;; gives beam-thickness=0.35 when mag=0.63 (like CueVoice)
2607              (scaled-default (+ 119/925 (* mag 13/37)))
2608              (new-val (* scaled-default ratio-to-default)))
2609         (ly:context-pushpop-property context 'Beam 'beam-thickness new-val)))))
2610
2611 ;; tag management
2612 ;;
2613
2614 (define tag-groups (make-hash-table))
2615 (call-after-session (lambda () (hash-clear! tag-groups)))
2616
2617 (define-public (define-tag-group tags)
2618   "Define a tag-group consisting of the given @var{tags}, a@tie{}list
2619 of symbols.  Returns @code{#f} if successful, and an error message if
2620 there is a conflicting tag group definition."
2621   (cond ((not (symbol-list? tags)) (format #f (_ "not a symbol list: ~a") tags))
2622         ((any (lambda (tag) (hashq-ref tag-groups tag)) tags)
2623          => (lambda (group) (and (not (lset= eq? group tags))
2624                                  (format #f (_ "conflicting tag group ~a") group))))
2625         (else
2626          (for-each
2627           (lambda (elt) (hashq-set! tag-groups elt tags))
2628           tags)
2629          #f)))
2630
2631 (define-public (tag-group-get tag)
2632   "Return the tag group (as a list of symbols) that the given
2633 @var{tag} symbol belongs to, @code{#f} if none."
2634   (hashq-ref tag-groups tag))
2635
2636 (define-public (tags-remove-predicate tags)
2637   "Returns a predicate that returns @code{#f} for any music that is to
2638 be removed by @{\\removeWithTag} on the given symbol or list of
2639 symbols @var{tags}."
2640   (if (symbol? tags)
2641       (lambda (m)
2642         (not (memq tags (ly:music-property m 'tags))))
2643       (lambda (m)
2644         (not (any (lambda (t) (memq t tags))
2645                   (ly:music-property m 'tags))))))
2646
2647 (define-public (tags-keep-predicate tags)
2648   "Returns a predicate that returns @code{#f} for any music that is to
2649 be removed by @{\\keepWithTag} on the given symbol or list of symbols
2650 @var{tags}."
2651   (if (symbol? tags)
2652       (let ((group (tag-group-get tags)))
2653         (lambda (m)
2654           (let ((music-tags (ly:music-property m 'tags)))
2655             (or
2656              (null? music-tags) ; redundant but very frequent
2657              ;; We know of only one tag to keep.  Either we find it in
2658              ;; the music tags, or all music tags must be from a
2659              ;; different group
2660              (memq tags music-tags)
2661              (not (any (lambda (t) (eq? (tag-group-get t) group)) music-tags))))))
2662       (let ((groups (delete-duplicates (map tag-group-get tags) eq?)))
2663         (lambda (m)
2664           (let ((music-tags (ly:music-property m 'tags)))
2665             (or
2666              (null? music-tags) ; redundant but very frequent
2667              (any (lambda (t) (memq t tags)) music-tags)
2668              ;; if no tag matches, no tag group should match either
2669              (not (any (lambda (t) (memq (tag-group-get t) groups)) music-tags))))))))