scm/music-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2015 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; for define-safe-public when byte-compiling using Guile V2
  20 (use-modules (scm safe-utility-defs))
  21
  22 (use-modules (ice-9 optargs))
  23 (use-modules (srfi srfi-11))
  24
  25 ;;; ly:music-property with setter
  26 ;;; (ly:music-property my-music 'elements)
  27 ;;;   ==> the 'elements property
  28 ;;; (set! (ly:music-property my-music 'elements) value)
  29 ;;;   ==> set the 'elements property and return it
  30 (define-public ly:music-property
  31   (make-procedure-with-setter ly:music-property
  32                               ly:music-set-property!))
  33
  34 (define-safe-public (music-is-of-type? mus type)
  35   "Does @code{mus} belong to the music class @code{type}?"
  36   (memq type (ly:music-property mus 'types)))
  37
  38 ;; TODO move this
  39 (define-public ly:grob-property
  40   (make-procedure-with-setter ly:grob-property
  41                               ly:grob-set-property!))
  42
  43 (define-public ly:grob-object
  44   (make-procedure-with-setter ly:grob-object
  45                               ly:grob-set-object!))
  46
  47 (define-public ly:grob-parent
  48   (make-procedure-with-setter ly:grob-parent
  49                               ly:grob-set-parent!))
  50
  51 (define-public ly:prob-property
  52   (make-procedure-with-setter ly:prob-property
  53                               ly:prob-set-property!))
  54
  55 (define-public ly:context-property
  56   (make-procedure-with-setter ly:context-property
  57                               ly:context-set-property!))
  58
  59 (define-public (music-map function music)
  60   "Apply @var{function} to @var{music} and all of the music it contains.
  61
  62 First it recurses over the children, then the function is applied to
  63 @var{music}."
  64   (let ((es (ly:music-property music 'elements))
  65         (e (ly:music-property music 'element)))
  66     (if (pair? es)
  67         (set! (ly:music-property music 'elements)
  68               (map (lambda (y) (music-map function y)) es)))
  69     (if (ly:music? e)
  70         (set! (ly:music-property music 'element)
  71               (music-map function  e)))
  72     (function music)))
  73
  74 (define-public (music-filter pred? music)
  75   "Filter out music expressions that do not satisfy @var{pred?}."
  76
  77   (define (inner-music-filter pred? music)
  78     "Recursive function."
  79     (let* ((es (ly:music-property music 'elements))
  80            (e (ly:music-property music 'element))
  81            (as (ly:music-property music 'articulations))
  82            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  83            (filtered-e (if (ly:music? e)
  84                            (inner-music-filter pred? e)
  85                            e))
  86            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  87       (if (not (null? e))
  88           (set! (ly:music-property music 'element) filtered-e))
  89       (if (not (null? es))
  90           (set! (ly:music-property music 'elements) filtered-es))
  91       (if (not (null? as))
  92           (set! (ly:music-property music 'articulations) filtered-as))
  93       ;; if filtering emptied the expression, we remove it completely.
  94       (if (or (not (pred? music))
  95               (and (eq? filtered-es '()) (not (ly:music? e))
  96                    (or (not (eq? es '()))
  97                        (ly:music? e))))
  98           (set! music '()))
  99       music))
 100
 101   (set! music (inner-music-filter pred? music))
 102   (if (ly:music? music)
 103       music
 104       (make-music 'Music)))       ;must return music.
 105
 106 (define*-public (display-music music #:optional (port (current-output-port)))
 107   "Display music, not done with @code{music-map} for clarity of
 108 presentation."
 109   (display music port)
 110   (display ": { " port)
 111   (let ((es (ly:music-property music 'elements))
 112         (e (ly:music-property music 'element)))
 113     (display (ly:music-mutable-properties music) port)
 114     (if (pair? es)
 115         (begin (display "\nElements: {\n" port)
 116                (for-each (lambda (m) (display-music m port)) es)
 117                (display "}\n" port)))
 118     (if (ly:music? e)
 119         (begin
 120           (display "\nChild:" port)
 121           (display-music e port))))
 122   (display " }\n" port)
 123   music)
 124
 125 ;;;
 126 ;;; A scheme music pretty printer
 127 ;;;
 128 (define (markup-expression->make-markup markup-expression)
 129   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
 130 For instance,
 131   \\markup \\bold \\italic hello
 132 ==>
 133   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 134   (define (proc->command-keyword proc)
 135     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 136     (let ((cmd-markup (symbol->string (procedure-name proc))))
 137       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 138                                                                   (string-length "-markup")))))))
 139   (define (transform-arg arg)
 140     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 141            (append-map inner-markup->make-markup arg))
 142           ((and (not (string? arg)) (markup? arg)) ;; a markup
 143            (inner-markup->make-markup arg))
 144           (else                                  ;; scheme arg
 145            (music->make-music arg))))
 146   (define (inner-markup->make-markup mrkup)
 147     (if (string? mrkup)
 148         `(#:simple ,mrkup)
 149         (let ((cmd (proc->command-keyword (car mrkup)))
 150               (args (map transform-arg (cdr mrkup))))
 151           `(,cmd ,@args))))
 152   ;; body:
 153   (if (string? markup-expression)
 154       markup-expression
 155       `(markup ,@(inner-markup->make-markup markup-expression))))
 156
 157 (define-public (music->make-music obj)
 158   "Generate an expression that, once evaluated, may return an object
 159 equivalent to @var{obj}, that is, for a music expression, a
 160 @code{(make-music ...)} form."
 161   (define (if-nonzero num)
 162     (if (zero? num) '() (list num)))
 163   (cond (;; markup expression
 164          (markup? obj)
 165          (markup-expression->make-markup obj))
 166         (;; music expression
 167          (ly:music? obj)
 168          `(make-music
 169            ',(ly:music-property obj 'name)
 170            ,@(append-map (lambda (prop)
 171                            `(',(car prop)
 172                              ,(music->make-music (cdr prop))))
 173                          (remove (lambda (prop)
 174                                    (eqv? (car prop) 'origin))
 175                                  (ly:music-mutable-properties obj)))))
 176         (;; moment
 177          (ly:moment? obj)
 178          `(ly:make-moment
 179            ,@(let ((main (ly:moment-main obj))
 180                    (grace (ly:moment-grace obj)))
 181                (cond ((zero? grace) (list main))
 182                      ((negative? grace) (list main grace))
 183                      (else ;;positive grace requires 4-arg form
 184                       (list (numerator main)
 185                             (denominator main)
 186                             (numerator grace)
 187                             (denominator grace)))))))
 188         (;; note duration
 189          (ly:duration? obj)
 190          `(ly:make-duration ,(ly:duration-log obj)
 191                             ,@(if (= (ly:duration-scale obj) 1)
 192                                   (if-nonzero (ly:duration-dot-count obj))
 193                                   (list (ly:duration-dot-count obj)
 194                                         (ly:duration-scale obj)))))
 195         (;; note pitch
 196          (ly:pitch? obj)
 197          `(ly:make-pitch ,(ly:pitch-octave obj)
 198                          ,(ly:pitch-notename obj)
 199                          ,@(if-nonzero (ly:pitch-alteration obj))))
 200         (;; scheme procedure
 201          (procedure? obj)
 202          (or (procedure-name obj) obj))
 203         (;; a symbol (avoid having an unquoted symbol)
 204          (symbol? obj)
 205          `',obj)
 206         (;; an empty list (avoid having an unquoted empty list)
 207          (null? obj)
 208          `'())
 209         (;; a proper list
 210          (list? obj)
 211          `(list ,@(map music->make-music obj)))
 212         (;; a pair
 213          (pair? obj)
 214          `(cons ,(music->make-music (car obj))
 215                 ,(music->make-music (cdr obj))))
 216         (else
 217          obj)))
 218
 219 (use-modules (ice-9 pretty-print))
 220 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 221   "Displays `obj', typically a music expression, in a friendly fashion,
 222 which often can be read back in order to generate an equivalent expression."
 223   (pretty-print (music->make-music obj) port)
 224   (newline port))
 225
 226 ;;;
 227 ;;; Scheme music expression --> Lily-syntax-using string translator
 228 ;;;
 229 (use-modules (srfi srfi-39)
 230              (scm display-lily))
 231
 232 (define*-public (display-lily-music expr parser #:optional (port (current-output-port))
 233                                     #:key force-duration)
 234   "Display the music expression using LilyPond syntax"
 235   (memoize-clef-names supported-clefs)
 236   (parameterize ((*indent* 0)
 237                  (*previous-duration* (ly:make-duration 2))
 238                  (*force-duration* force-duration))
 239                 (display (music->lily-string expr parser) port)
 240                 (newline port)))
 241
 242 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 243
 244 (define-public (shift-one-duration-log music shift dot)
 245   "Add @var{shift} to @code{duration-log} of @code{'duration} in
 246 @var{music} and optionally @var{dot} to any note encountered.
 247 The number of dots in the shifted music may not be less than zero."
 248   (let ((d (ly:music-property music 'duration)))
 249     (if (ly:duration? d)
 250         (let* ((cp (ly:duration-scale d))
 251                (nd (ly:make-duration
 252                     (+ shift (ly:duration-log d))
 253                     (max 0 (+ dot (ly:duration-dot-count d)))
 254                     cp)))
 255           (set! (ly:music-property music 'duration) nd)))
 256     ;clear cached length, since it's no longer valid
 257     (set! (ly:music-property music 'length) '())
 258     music))
 259
 260 (define-public (shift-duration-log music shift dot)
 261   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 262              music))
 263
 264 (define-public (tremolo::get-music-list tremolo)
 265   "Given a tremolo repeat, return a list of music to engrave for it.
 266 This will be a stretched copy of its body, plus a TremoloEvent or
 267 TremoloSpanEvent.
 268
 269 This is called only by Chord_tremolo_iterator."
 270   (define (first-note-duration music)
 271     "Finds the duration of the first NoteEvent by searching
 272 depth-first through MUSIC."
 273     ;; NoteEvent or a non-expanded chord-repetition
 274     ;; We just take anything that actually sports an announced duration.
 275     (if (ly:duration? (ly:music-property music 'duration))
 276         (ly:music-property music 'duration)
 277         (let loop ((elts (if (ly:music? (ly:music-property music 'element))
 278                              (list (ly:music-property music 'element))
 279                              (ly:music-property music 'elements))))
 280           (and (pair? elts)
 281                (let ((dur (first-note-duration (car elts))))
 282                  (if (ly:duration? dur)
 283                      dur
 284                      (loop (cdr elts))))))))
 285   (let* ((times (ly:music-property tremolo 'repeat-count))
 286          (body (ly:music-property tremolo 'element))
 287          (children (if (music-is-of-type? body 'sequential-music)
 288                        ;; \repeat tremolo n { ... }
 289                        (length (extract-named-music body '(EventChord
 290                                                            NoteEvent)))
 291                        ;; \repeat tremolo n c4
 292                        1))
 293          (tremolo-type (if (positive? children)
 294                            (let* ((note-duration (first-note-duration body))
 295                                   (duration-log (if (ly:duration? note-duration)
 296                                                     (ly:duration-log note-duration)
 297                                                     1)))
 298                              (ash 1 duration-log))
 299                            '()))
 300          (stretched (ly:music-deep-copy body)))
 301     (if (positive? children)
 302         ;; # of dots is equal to the 1 in bitwise representation (minus 1)!
 303         (let* ((dots (1- (logcount (* times children))))
 304                ;; The remaining missing multiplier to scale the notes by
 305                ;; times * children
 306                (mult (/ (* times children (ash 1 dots)) (1- (ash 2 dots))))
 307                (shift (- (ly:intlog2 (floor mult)))))
 308           (if (not (and (integer? mult) (= (logcount mult) 1)))
 309               (ly:music-warning
 310                body
 311                (ly:format (_ "invalid tremolo repeat count: ~a") times)))
 312           ;; Make each note take the full duration
 313           (ly:music-compress stretched (ly:make-moment 1 children))
 314           ;; Adjust the displayed note durations
 315           (shift-duration-log stretched shift dots)))
 316     ;; Return the stretched body plus a tremolo event
 317     (if (= children 1)
 318         (list (make-music 'TremoloEvent
 319                           'repeat-count times
 320                           'tremolo-type tremolo-type
 321                           'origin (ly:music-property tremolo 'origin))
 322               stretched)
 323         (list (make-music 'TremoloSpanEvent
 324                           'span-direction START
 325                           'repeat-count times
 326                           'tremolo-type tremolo-type
 327                           'origin (ly:music-property tremolo 'origin))
 328               stretched
 329               (make-music 'TremoloSpanEvent
 330                           'span-direction STOP
 331                           'origin (ly:music-property tremolo 'origin))))))
 332
 333 (define-public (make-repeat name times main alts)
 334   "Create a repeat music expression, with all properties initialized
 335 properly."
 336   (let ((type (or (assoc-get name '(("volta" . VoltaRepeatedMusic)
 337                                     ("unfold" . UnfoldedRepeatedMusic)
 338                                     ("percent" . PercentRepeatedMusic)
 339                                     ("tremolo" . TremoloRepeatedMusic)))
 340                   (begin (ly:warning (_ "unknown repeat type `~S': must be volta, unfold, percent, or tremolo") name)
 341                          'VoltaRepeatedMusic)))
 342         (talts (if (< times (length alts))
 343                    (begin
 344                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 345                      (take alts times))
 346                    alts)))
 347     (make-music type
 348                 'element main
 349                 'repeat-count (max times 1)
 350                 'elements talts)))
 351
 352 (define (calc-repeat-slash-count music)
 353   "Given the child-list @var{music} in @code{PercentRepeatMusic},
 354 calculate the number of slashes based on the durations.  Returns @code{0}
 355 if durations in @var{music} vary, allowing slash beats and double-percent
 356 beats to be distinguished."
 357   (let* ((durs (map duration-of-note
 358                     (extract-named-music music '(EventChord NoteEvent
 359                                                             RestEvent SkipEvent))))
 360          (first-dur (car durs)))
 361
 362     (if (every (lambda (d) (equal? d first-dur)) durs)
 363         (max (- (ly:duration-log first-dur) 2) 1)
 364         0)))
 365
 366 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 367 ;; clusters.
 368
 369 (define-public (note-to-cluster music)
 370   "Replace @code{NoteEvents} by @code{ClusterNoteEvents}."
 371   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 372       (make-music 'ClusterNoteEvent
 373                   'pitch (ly:music-property music 'pitch)
 374                   'duration (ly:music-property music 'duration))
 375       music))
 376
 377 (define-public (notes-to-clusters music)
 378   (music-map note-to-cluster music))
 379
 380 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 381 ;; repeats.
 382
 383 (define-public (unfold-repeats music)
 384   "Replace all repeats with unfolded repeats."
 385   (let ((es (ly:music-property music 'elements))
 386         (e (ly:music-property music 'element)))
 387     (if (music-is-of-type? music 'repeated-music)
 388         (set! music (make-music 'UnfoldedRepeatedMusic music)))
 389     (if (pair? es)
 390         (set! (ly:music-property music 'elements)
 391               (map unfold-repeats es)))
 392     (if (ly:music? e)
 393         (set! (ly:music-property music 'element)
 394               (unfold-repeats e)))
 395     music))
 396
 397 (define-public (unfold-repeats-fully music)
 398   "Unfolds repeats and expands the resulting @code{unfolded-repeated-music}."
 399   (map-some-music
 400    (lambda (m)
 401      (and (music-is-of-type? m 'unfolded-repeated-music)
 402           (make-sequential-music
 403            (ly:music-deep-copy (make-unfolded-set m)))))
 404    (unfold-repeats music)))
 405
 406 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 407 ;; property setting music objs.
 408
 409 (define-safe-public (check-grob-path path #:optional parser location
 410                                      #:key
 411                                      (start 0)
 412                                      default
 413                                      (min 1)
 414                                      max)
 415   "Check a grob path specification @var{path}, a symbol list (or a
 416 single symbol), for validity and possibly complete it.  Returns the
 417 completed specification, or @code{#f} if invalid.  If optional
 418 @var{parser} is given, a syntax error is raised in that case,
 419 optionally using @var{location}.  If an optional keyword argument
 420 @code{#:start @var{start}} is given, the parsing starts at the given
 421 index in the sequence @samp{Context.Grob.property.sub-property...},
 422 with the default of @samp{0} implying the full path.
 423
 424 If there is no valid first element of @var{path} fitting at the given
 425 path location, an optionally given @code{#:default @var{default}} is
 426 used as the respective element instead without checking it for
 427 validity at this position.
 428
 429 The resulting path after possibly prepending @var{default} can be
 430 constrained in length by optional arguments @code{#:min @var{min}} and
 431 @code{#:max @var{max}}, defaulting to @samp{1} and unlimited,
 432 respectively."
 433   (let ((path (if (symbol? path) (list path) path)))
 434     ;; A Guile 1.x bug specific to optargs precludes moving the
 435     ;; defines out of the let
 436     (define (unspecial? s)
 437       (not (or (object-property s 'is-grob?)
 438                (object-property s 'backend-type?))))
 439     (define (grob? s)
 440       (object-property s 'is-grob?))
 441     (define (property? s)
 442       (object-property s 'backend-type?))
 443     (define (check c p) (c p))
 444
 445     (let* ((checkers
 446             (and (< start 3)
 447                  (drop (list unspecial? grob? property?) start)))
 448            (res
 449             (cond
 450              ((null? path)
 451               ;; tricky.  Should we make use of the default when the
 452               ;; list is empty?  In most cases, this question should be
 453               ;; academical as an empty list can only be generated by
 454               ;; Scheme and is likely an error.  We consider this a case
 455               ;; of "no valid first element, and default given".
 456               ;; Usually, invalid use cases should be caught later using
 457               ;; the #:min argument, and if the user explicitly does not
 458               ;; catch this, we just follow through.
 459               (if default (list default) '()))
 460              ((not checkers)
 461               ;; no checkers, so we have a valid first element and just
 462               ;; take the path as-is.
 463               path)
 464              (default
 465                (if ((car checkers) (car path))
 466                    (and (every check (cdr checkers) (cdr path))
 467                         path)
 468                    (and (every check (cdr checkers) path)
 469                         (cons default path))))
 470              (else
 471               (and (every check checkers path)
 472                    path)))))
 473       (if (and res
 474                (if max (<= min (length res) max)
 475                    (<= min (length res))))
 476           res
 477           (begin
 478             (if parser
 479                 (ly:parser-error parser
 480                                  (format #f (_ "bad grob property path ~a")
 481                                          path)
 482                                  location))
 483             #f)))))
 484
 485 (define-public (make-grob-property-set grob gprop val)
 486   "Make a @code{Music} expression that sets @var{gprop} to @var{val} in
 487 @var{grob}.  Does a pop first, i.e., this is not an override."
 488   (make-music 'OverrideProperty
 489               'symbol grob
 490               'grob-property gprop
 491               'grob-value val
 492               'pop-first #t))
 493
 494 (define-public (make-grob-property-override grob gprop val)
 495   "Make a @code{Music} expression that overrides @var{gprop} to @var{val}
 496 in @var{grob}."
 497   (make-music 'OverrideProperty
 498               'symbol grob
 499               'grob-property gprop
 500               'grob-value val))
 501
 502 (define-public (make-grob-property-revert grob gprop)
 503   "Revert the grob property @var{gprop} for @var{grob}."
 504   (make-music 'RevertProperty
 505               'symbol grob
 506               'grob-property gprop))
 507
 508 (define direction-polyphonic-grobs
 509   '(AccidentalSuggestion
 510     DotColumn
 511     Dots
 512     Fingering
 513     LaissezVibrerTie
 514     LigatureBracket
 515     MultiMeasureRest
 516     PhrasingSlur
 517     RepeatTie
 518     Rest
 519     Script
 520     Slur
 521     Stem
 522     TextScript
 523     Tie
 524     TupletBracket
 525     TrillSpanner))
 526
 527 (define general-grace-settings
 528   `((Voice Stem font-size -3)
 529     (Voice Flag font-size -3)
 530     (Voice NoteHead font-size -3)
 531     (Voice TabNoteHead font-size -4)
 532     (Voice Dots font-size -3)
 533     (Voice Stem length-fraction 0.8)
 534     (Voice Stem no-stem-extend #t)
 535     (Voice Beam beam-thickness 0.384)
 536     (Voice Beam length-fraction 0.8)
 537     (Voice Accidental font-size -4)
 538     (Voice AccidentalCautionary font-size -4)
 539     (Voice Script font-size -3)
 540     (Voice Fingering font-size -8)
 541     (Voice StringNumber font-size -8)))
 542
 543 (define-public score-grace-settings
 544   (append
 545     `((Voice Stem direction ,UP)
 546       (Voice Slur direction ,DOWN))
 547     general-grace-settings))
 548
 549 (define-safe-public (make-voice-props-set n)
 550   (make-sequential-music
 551    (append
 552     (map (lambda (x) (make-grob-property-set x 'direction
 553                                              (if (odd? n) -1 1)))
 554          direction-polyphonic-grobs)
 555     (list
 556      (make-property-set 'graceSettings general-grace-settings)
 557      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))))))
 558
 559 (define-safe-public (make-voice-props-override n)
 560   (make-sequential-music
 561    (append
 562     (map (lambda (x) (make-grob-property-override x 'direction
 563                                                   (if (odd? n) -1 1)))
 564          direction-polyphonic-grobs)
 565     (list
 566      (make-property-set 'graceSettings general-grace-settings)
 567      (make-grob-property-override 'NoteColumn 'horizontal-shift (quotient n 2))))))
 568
 569 (define-safe-public (make-voice-props-revert)
 570   (make-sequential-music
 571    (append
 572     (map (lambda (x) (make-grob-property-revert x 'direction))
 573          direction-polyphonic-grobs)
 574     (list (make-property-unset 'graceSettings)
 575           (make-grob-property-revert 'NoteColumn 'horizontal-shift)))))
 576
 577
 578 (define-safe-public (context-spec-music m context #:optional id)
 579   "Add \\context CONTEXT = ID to M."
 580   (let ((cm (make-music 'ContextSpeccedMusic
 581                         'element m
 582                         'context-type context)))
 583     (if (string? id)
 584         (set! (ly:music-property cm 'context-id) id))
 585     cm))
 586
 587 (define-public (descend-to-context m context)
 588   "Like @code{context-spec-music}, but only descending."
 589   (let ((cm (context-spec-music m context)))
 590     (ly:music-set-property! cm 'descend-only #t)
 591     cm))
 592
 593 (define-public (make-non-relative-music mus)
 594   (make-music 'UnrelativableMusic
 595               'element mus))
 596
 597 (define-public (make-apply-context func)
 598   (make-music 'ApplyContext
 599               'procedure func))
 600
 601 (define-public (make-sequential-music elts)
 602   (make-music 'SequentialMusic
 603               'elements elts))
 604
 605 (define-public (make-simultaneous-music elts)
 606   (make-music 'SimultaneousMusic
 607               'elements elts))
 608
 609 (define-safe-public (make-event-chord elts)
 610   (make-music 'EventChord
 611               'elements elts))
 612
 613 (define-public (make-skip-music dur)
 614   (make-music 'SkipMusic
 615               'duration dur))
 616
 617 (define-public (make-grace-music music)
 618   (make-music 'GraceMusic
 619               'element music))
 620
 621 ;;;;;;;;;;;;;;;;
 622
 623 ;; mmrest
 624 (define-public (make-multi-measure-rest duration location)
 625   (make-music 'MultiMeasureRestMusic
 626               'origin location
 627               'duration duration))
 628
 629 (define-public (make-property-set sym val)
 630   (make-music 'PropertySet
 631               'symbol sym
 632               'value val))
 633
 634 (define-public (make-property-unset sym)
 635   (make-music 'PropertyUnset
 636               'symbol sym))
 637
 638 (define-safe-public (make-articulation name . properties)
 639   (apply make-music 'ArticulationEvent
 640          'articulation-type name
 641          properties))
 642
 643 (define-public (make-lyric-event string duration)
 644   (make-music 'LyricEvent
 645               'duration duration
 646               'text string))
 647
 648 (define-safe-public (make-span-event type span-dir)
 649   (make-music type
 650               'span-direction span-dir))
 651
 652 (define-public (override-head-style heads style)
 653   "Override style for @var{heads} to @var{style}."
 654   (make-sequential-music
 655    (if (pair? heads)
 656        (map (lambda (h)
 657               (make-grob-property-override h 'style style))
 658             heads)
 659        (list (make-grob-property-override heads 'style style)))))
 660
 661 (define-public (revert-head-style heads)
 662   "Revert style for @var{heads}."
 663   (make-sequential-music
 664    (if (pair? heads)
 665        (map (lambda (h)
 666               (make-grob-property-revert h 'style))
 667             heads)
 668        (list (make-grob-property-revert heads 'style)))))
 669
 670 (define-public (style-note-heads heads style music)
 671   "Set @var{style} for all @var{heads} in @var{music}.  Works both
 672 inside of and outside of chord construct."
 673   ;; are we inside a <...>?
 674   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 675       ;; yes -> use a tweak
 676       (begin
 677         (set! (ly:music-property music 'tweaks)
 678               (acons 'style style (ly:music-property music 'tweaks)))
 679         music)
 680       ;; not in <...>, so use overrides
 681       (make-sequential-music
 682        (list
 683         (override-head-style heads style)
 684         music
 685         (revert-head-style heads)))))
 686
 687 (define-public (set-mus-properties! m alist)
 688   "Set all of @var{alist} as properties of @var{m}."
 689   (if (pair? alist)
 690       (begin
 691         (set! (ly:music-property m (caar alist)) (cdar alist))
 692         (set-mus-properties! m (cdr alist)))))
 693
 694 (define-public (music-separator? m)
 695   "Is @var{m} a separator?"
 696   (let ((ts (ly:music-property m 'types)))
 697     (memq 'separator ts)))
 698
 699 ;;; expanding repeat chords
 700 (define-public (copy-repeat-chord original-chord repeat-chord duration
 701                                   event-types)
 702   "Copies all events in @var{event-types} (be sure to include
 703 @code{rhythmic-events}) from @var{original-chord} over to
 704 @var{repeat-chord} with their articulations filtered as well.  Any
 705 duration is replaced with the specified @var{duration}."
 706   ;; First remove everything from event-types that can already be
 707   ;; found in the repeated chord.  We don't need to look for
 708   ;; articulations on individual events since they can't actually get
 709   ;; into a repeat chord given its input syntax.
 710
 711   (define (keep-element? m)
 712     (any (lambda (t) (music-is-of-type? m t))
 713          event-types))
 714   (define origin (ly:music-property repeat-chord 'origin #f))
 715   (define (set-origin! l)
 716     (if origin
 717         (for-each (lambda (m) (set! (ly:music-property m 'origin) origin)) l))
 718     l)
 719
 720   (for-each
 721    (lambda (field)
 722      (for-each (lambda (e)
 723                  (for-each (lambda (x)
 724                              (set! event-types (delq x event-types)))
 725                            (ly:music-property e 'types)))
 726                (ly:music-property repeat-chord field)))
 727    '(elements articulations))
 728
 729   ;; now treat the elements
 730   (set! (ly:music-property repeat-chord 'elements)
 731         (let ((elts
 732                (set-origin! (ly:music-deep-copy
 733                              (filter keep-element?
 734                                      (ly:music-property original-chord
 735                                                         'elements))))))
 736           (for-each
 737            (lambda (m)
 738              (let ((arts (ly:music-property m 'articulations)))
 739                (if (pair? arts)
 740                    (set! (ly:music-property m 'articulations)
 741                          (set-origin! (filter! keep-element? arts))))
 742                (if (ly:duration? (ly:music-property m 'duration))
 743                    (set! (ly:music-property m 'duration) duration))
 744                (if (ly:music-property m 'cautionary #f)
 745                    (set! (ly:music-property m 'cautionary) #f))
 746                (if (ly:music-property m 'force-accidental #f)
 747                    (set! (ly:music-property m 'force-accidental) #f))))
 748            elts)
 749           (append! elts (ly:music-property repeat-chord 'elements))))
 750   (let ((arts (filter keep-element?
 751                       (ly:music-property original-chord
 752                                          'articulations))))
 753     (if (pair? arts)
 754         (set! (ly:music-property repeat-chord 'articulations)
 755               (append!
 756                (set-origin! (ly:music-deep-copy arts))
 757                (ly:music-property repeat-chord 'articulations)))))
 758   repeat-chord)
 759
 760
 761 (define-public (expand-repeat-chords! event-types music)
 762   "Walks through @var{music} and fills repeated chords (notable by
 763 having a duration in @code{duration}) with the notes from their
 764 respective predecessor chord."
 765   (let loop ((music music) (last-chord #f))
 766     (if (music-is-of-type? music 'event-chord)
 767         (let ((chord-repeat (ly:music-property music 'duration)))
 768           (cond
 769            ((not (ly:duration? chord-repeat))
 770             (if (any (lambda (m) (ly:duration?
 771                                   (ly:music-property m 'duration)))
 772                      (ly:music-property music 'elements))
 773                 music
 774                 last-chord))
 775            (last-chord
 776             (set! (ly:music-property music 'duration) '())
 777             (copy-repeat-chord last-chord music chord-repeat event-types))
 778            (else
 779             (ly:music-warning music (_ "Bad chord repetition"))
 780             #f)))
 781         (let ((elt (ly:music-property music 'element)))
 782           (fold loop (if (ly:music? elt) (loop elt last-chord) last-chord)
 783                 (ly:music-property music 'elements)))))
 784   music)
 785
 786 ;;; This does _not_ copy any articulations.  Rationale: one main
 787 ;;; incentive for pitch-repeating durations is after ties, such that
 788 ;;; 4~2~8. can stand in for a 15/16 note in \partial 4 position.  In
 789 ;;; this use case, any repeated articulations will be a nuisance.
 790 ;;;
 791 ;;; String assignments in TabStaff might seem like a worthwhile
 792 ;;; exception, but they would be better tackled by the respective
 793 ;;; engravers themselves (see issue 3662).
 794 ;;;
 795 ;;; Repeating chords as well seems problematic for things like
 796 ;;; \score {
 797 ;;;   <<
 798 ;;;     \new Staff { c4 c c <c e> }
 799 ;;;     \new RhythmicStaff { 4 4 4 4 }
 800 ;;;   >>
 801 ;;; }
 802 ;;;
 803 ;;; However, because of MIDI it is not advisable to use RhythmicStaff
 804 ;;; without any initial pitch/drum-type.  For music functions taking
 805 ;;; pure rhythms as an argument, the running of expand-repeat-notes!
 806 ;;; at scorification time is irrelevant: at that point of time, the
 807 ;;; music function has already run.
 808
 809 (define-public (expand-repeat-notes! music)
 810   "Walks through @var{music} and gives pitchless notes (not having a
 811 pitch in code{pitch} or a drum type in @code{drum-type}) the pitch(es)
 812 from the predecessor note/chord if available."
 813   (let ((last-pitch #f))
 814     (map-some-music
 815      (lambda (m)
 816        (define (set-and-ret last)
 817          (set! last-pitch last)
 818          m)
 819        (cond
 820         ((music-is-of-type? m 'event-chord)
 821          (if (any (lambda (m) (music-is-of-type? m 'rhythmic-event))
 822                   (ly:music-property m 'elements))
 823              (set! last-pitch m))
 824          m)
 825         ((music-is-of-type? m 'note-event)
 826          (cond
 827           ((or (ly:music-property m 'pitch #f)
 828                (ly:music-property m 'drum-type #f))
 829            => set-and-ret)
 830           ;; ok, naked rhythm.  Go through the various cases of
 831           ;; last-pitch
 832           ;; nothing available: just keep as-is
 833           ((not last-pitch) m)
 834           ((ly:pitch? last-pitch)
 835            (set! (ly:music-property m 'pitch) last-pitch)
 836            m)
 837           ((symbol? last-pitch)
 838            (set! (ly:music-property m 'drum-type) last-pitch)
 839            m)
 840           ;; Ok, this is the big bad one: the reference is a chord.
 841           ;; For now, we use the repeat chord logic.  That's not
 842           ;; really efficient as cleaning out all articulations is
 843           ;; quite simpler than what copy-repeat-chord does.
 844           (else
 845            (copy-repeat-chord last-pitch
 846                               (make-music 'EventChord
 847                                           'elements
 848                                           (ly:music-property m 'articulations)
 849                                           'origin
 850                                           (ly:music-property m 'origin))
 851                               (ly:music-property m 'duration)
 852                               '(rhythmic-event)))))
 853         (else #f)))
 854      music)))
 855
 856 ;;; splitting chords into voices.
 857 (define (voicify-list lst number)
 858   "Make a list of Musics.
 859
 860 voicify-list :: [ [Music ] ] -> number -> [Music]
 861 LST is a list music-lists.
 862
 863 NUMBER is 0-base, i.e., Voice=1 (upstems) has number 0.
 864 "
 865   (if (null? lst)
 866       '()
 867       (cons (context-spec-music
 868              (make-sequential-music
 869               (list (make-voice-props-set number)
 870                     (make-simultaneous-music (car lst))))
 871              'Bottom  (number->string (1+ number)))
 872             (voicify-list (cdr lst) (1+ number)))))
 873
 874 (define (voicify-chord ch)
 875   "Split the parts of a chord into different Voices using separator"
 876   (let ((es (ly:music-property ch 'elements)))
 877     (set! (ly:music-property  ch 'elements)
 878           (voicify-list (split-list-by-separator es music-separator?) 0))
 879     ch))
 880
 881 (define-public (voicify-music m)
 882   "Recursively split chords that are separated with @code{\\\\}."
 883   (if (not (ly:music? m))
 884       (ly:error (_ "music expected: ~S") m))
 885   (let ((es (ly:music-property m 'elements))
 886         (e (ly:music-property m 'element)))
 887
 888     (if (pair? es)
 889         (set! (ly:music-property m 'elements) (map voicify-music es)))
 890     (if (ly:music? e)
 891         (set! (ly:music-property m 'element)  (voicify-music e)))
 892     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 893              (any music-separator? es))
 894         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 895     m))
 896
 897 (define-public (empty-music)
 898   (make-music 'Music))
 899
 900 ;; Make a function that checks score element for being of a specific type.
 901 (define-public (make-type-checker symbol)
 902   (lambda (elt)
 903     (grob::has-interface elt symbol)))
 904
 905 (define ((outputproperty-compatibility func sym val) grob g-context ao-context)
 906   (if (func grob)
 907       (set! (ly:grob-property grob sym) val)))
 908 (export outputproperty-compatibility)
 909
 910
 911 (define ((set-output-property grob-name symbol val)  grob grob-c context)
 912   "Usage example:
 913 @code{\\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))}"
 914   (let ((meta (ly:grob-property grob 'meta)))
 915     (if (equal? (assoc-get 'name meta) grob-name)
 916         (set! (ly:grob-property grob symbol) val))))
 917 (export set-output-property)
 918
 919
 920 (define-public (skip->rest mus)
 921   "Replace @var{mus} by @code{RestEvent} of the same duration if it is a
 922 @code{SkipEvent}.  Useful for extracting parts from crowded scores."
 923
 924   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 925        (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 926        mus))
 927
 928
 929 (define-public (music-has-type music type)
 930   (memq type (ly:music-property music 'types)))
 931
 932 (define-public (music-clone music . music-properties)
 933   "Clone @var{music} and set properties according to
 934 @var{music-properties}, a list of alternating property symbols and
 935 values:
 936 @example\n(music-clone start-span 'span-direction STOP)
 937 @end example
 938 Only properties that are not overriden by @var{music-properties} are
 939 actually fully cloned."
 940   (let ((old-props (list-copy (ly:music-mutable-properties music)))
 941         (new-props '())
 942         (m (ly:make-music (ly:prob-immutable-properties music))))
 943     (define (set-props mus-props)
 944       (if (and (not (null? mus-props))
 945                (not (null? (cdr mus-props))))
 946           (begin
 947             (set! old-props (assq-remove! old-props (car mus-props)))
 948             (set! new-props
 949                   (assq-set! new-props
 950                              (car mus-props) (cadr mus-props)))
 951             (set-props (cddr mus-props)))))
 952     (set-props music-properties)
 953     (for-each
 954      (lambda (pair)
 955        (set! (ly:music-property m (car pair))
 956              (ly:music-deep-copy (cdr pair))))
 957      old-props)
 958     (for-each
 959      (lambda (pair)
 960        (set! (ly:music-property m (car pair)) (cdr pair)))
 961      new-props)
 962     m))
 963
 964 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 965 ;; warn for bare chords at start.
 966
 967 (define-public (ly:music-message music msg . rest)
 968   (let ((ip (ly:music-property music 'origin)))
 969     (if (ly:input-location? ip)
 970         (apply ly:input-message ip msg rest)
 971         (apply ly:message msg rest))))
 972
 973 (define-public (ly:music-warning music msg . rest)
 974   (let ((ip (ly:music-property music 'origin)))
 975     (if (ly:input-location? ip)
 976         (apply ly:input-warning ip msg rest)
 977         (apply ly:warning msg rest))))
 978
 979 (define-public (ly:event-warning event msg . rest)
 980   (let ((ip (ly:event-property event 'origin)))
 981     (if (ly:input-location? ip)
 982         (apply ly:input-warning ip msg rest)
 983         (apply ly:warning msg rest))))
 984
 985 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 986 ;;
 987 ;; setting stuff for grace context.
 988 ;;
 989
 990 (define (vector-extend v x)
 991   "Make a new vector consisting of V, with X added to the end."
 992   (let* ((n (vector-length v))
 993          (nv (make-vector (+ n 1) '())))
 994     (vector-move-left! v 0 n nv 0)
 995     (vector-set! nv n x)
 996     nv))
 997
 998 (define (vector-map f v)
 999   "Map F over V.  This function returns nothing."
1000   (do ((n (vector-length v))
1001        (i 0 (+ i 1)))
1002       ((>= i n))
1003     (f (vector-ref v i))))
1004
1005 (define (vector-reverse-map f v)
1006   "Map F over V, N to 0 order.  This function returns nothing."
1007   (do ((i (- (vector-length v) 1) (- i 1)))
1008       ((< i 0))
1009     (f (vector-ref v i))))
1010
1011 (define-public (add-grace-property context-name grob sym val)
1012   "Set @var{sym}=@var{val} for @var{grob} in @var{context-name}."
1013   (define (set-prop context)
1014     (let* ((where (or (ly:context-find context context-name) context))
1015            (current (ly:context-property where 'graceSettings))
1016            (new-settings (append current
1017                                  (list (list context-name grob sym val)))))
1018       (ly:context-set-property! where 'graceSettings new-settings)))
1019   (make-apply-context set-prop))
1020
1021 (define-public (remove-grace-property context-name grob sym)
1022   "Remove all @var{sym} for @var{grob} in @var{context-name}."
1023   (define (sym-grob-context? property sym grob context-name)
1024     (and (eq? (car property) context-name)
1025          (eq? (cadr property) grob)
1026          (eq? (caddr property) sym)))
1027   (define (delete-prop context)
1028     (let* ((where (or (ly:context-find context context-name) context))
1029            (current (ly:context-property where 'graceSettings))
1030            (prop-settings (filter
1031                            (lambda(x) (sym-grob-context? x sym grob context-name))
1032                            current))
1033            (new-settings current))
1034       (for-each (lambda(x)
1035                   (set! new-settings (delete x new-settings)))
1036                 prop-settings)
1037       (ly:context-set-property! where 'graceSettings new-settings)))
1038   (make-apply-context delete-prop))
1039
1040
1041 (defmacro-public def-grace-function (start stop . docstring)
1042   "Helper macro for defining grace music"
1043   `(define-music-function (parser location music) (ly:music?)
1044      ,@docstring
1045      (make-music 'GraceMusic
1046                  'origin location
1047                  'element (make-music 'SequentialMusic
1048                                       'elements (list (ly:music-deep-copy ,start)
1049                                                       music
1050                                                       (ly:music-deep-copy ,stop))))))
1051
1052 (defmacro-public define-syntax-function (type args signature . body)
1053   "Helper macro for `ly:make-music-function'.
1054 Syntax:
1055   (define-syntax-function result-type? (parser location arg1 arg2 ...) (arg1-type arg2-type ...)
1056     ...function body...)
1057
1058 argX-type can take one of the forms @code{predicate?} for mandatory
1059 arguments satisfying the predicate, @code{(predicate?)} for optional
1060 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1061 value)}} for optional parameters with a specified default
1062 value (evaluated at definition time).  An optional parameter can be
1063 omitted in a call only when it can't get confused with a following
1064 parameter of different type.
1065
1066 @code{result-type?} can specify a default in the same manner as
1067 predicates, to be used in case of a type error in arguments or
1068 result."
1069
1070   (define (currying-lambda args doc-string? body)
1071     (if (and (pair? args)
1072              (pair? (car args)))
1073         (currying-lambda (car args) doc-string?
1074                          `((lambda ,(cdr args) ,@body)))
1075         `(lambda ,args
1076            ,(format #f "~a\n~a" (cddr args) (or doc-string? ""))
1077            ,@body)))
1078
1079   (set! signature (map (lambda (pred)
1080                          (if (pair? pred)
1081                              `(cons ,(car pred)
1082                                     ,(and (pair? (cdr pred)) (cadr pred)))
1083                              pred))
1084                        (cons type signature)))
1085
1086   (let ((docstring
1087          (and (pair? body) (pair? (cdr body))
1088               (if (string? (car body))
1089                   (car body)
1090                   (and (pair? (car body))
1091                        (eq? '_i (caar body))
1092                        (pair? (cdar body))
1093                        (string? (cadar body))
1094                        (null? (cddar body))
1095                        (cadar body))))))
1096     ;; When the music function definition contains an i10n doc string,
1097     ;; (_i "doc string"), keep the literal string only
1098     `(ly:make-music-function
1099       (list ,@signature)
1100       ,(currying-lambda args docstring (if docstring (cdr body) body)))))
1101
1102 (defmacro-public define-music-function rest
1103   "Defining macro returning music functions.
1104 Syntax:
1105   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
1106     ...function body...)
1107
1108 argX-type can take one of the forms @code{predicate?} for mandatory
1109 arguments satisfying the predicate, @code{(predicate?)} for optional
1110 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1111 value)}} for optional parameters with a specified default
1112 value (evaluated at definition time).  An optional parameter can be
1113 omitted in a call only when it can't get confused with a following
1114 parameter of different type.
1115
1116 Must return a music expression.  The @code{origin} is automatically
1117 set to the @code{location} parameter."
1118
1119   `(define-syntax-function (ly:music? (make-music 'Music 'void #t)) ,@rest))
1120
1121
1122 (defmacro-public define-scheme-function rest
1123   "Defining macro returning Scheme functions.
1124 Syntax:
1125   (define-scheme-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
1126     ...function body...)
1127
1128 argX-type can take one of the forms @code{predicate?} for mandatory
1129 arguments satisfying the predicate, @code{(predicate?)} for optional
1130 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1131 value)}} for optional parameters with a specified default
1132 value (evaluated at definition time).  An optional parameter can be
1133 omitted in a call only when it can't get confused with a following
1134 parameter of different type.
1135
1136 Can return arbitrary expressions.  If a music expression is returned,
1137 its @code{origin} is automatically set to the @code{location}
1138 parameter."
1139
1140   `(define-syntax-function scheme? ,@rest))
1141
1142 (defmacro-public define-void-function rest
1143   "This defines a Scheme function like @code{define-scheme-function} with
1144 void return value (i.e., what most Guile functions with `unspecified'
1145 value return).  Use this when defining functions for executing actions
1146 rather than returning values, to keep Lilypond from trying to interpret
1147 the return value."
1148   `(define-syntax-function (void? *unspecified*) ,@rest *unspecified*))
1149
1150 (defmacro-public define-event-function rest
1151   "Defining macro returning event functions.
1152 Syntax:
1153   (define-event-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
1154     ...function body...)
1155
1156 argX-type can take one of the forms @code{predicate?} for mandatory
1157 arguments satisfying the predicate, @code{(predicate?)} for optional
1158 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1159 value)}} for optional parameters with a specified default
1160 value (evaluated at definition time).  An optional parameter can be
1161 omitted in a call only when it can't get confused with a following
1162 parameter of different type.
1163
1164 Must return an event expression.  The @code{origin} is automatically
1165 set to the @code{location} parameter."
1166
1167   `(define-syntax-function (ly:event? (make-music 'Event 'void #t)) ,@rest))
1168
1169 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1170
1171 (define-public (cue-substitute quote-music)
1172   "Must happen after @code{quote-substitute}."
1173
1174   (if (vector? (ly:music-property quote-music 'quoted-events))
1175       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
1176              (clef (ly:music-property quote-music 'quoted-music-clef #f))
1177              (main-voice (case dir ((1) 1) ((-1) 0) (else #f)))
1178              (cue-voice (and main-voice (- 1 main-voice)))
1179              (cue-type (ly:music-property quote-music 'quoted-context-type #f))
1180              (cue-id (ly:music-property quote-music 'quoted-context-id))
1181              (main-music (ly:music-property quote-music 'element))
1182              (return-value quote-music))
1183
1184         (if main-voice
1185             (set! (ly:music-property quote-music 'element)
1186                   (make-sequential-music
1187                    (list
1188                     (make-voice-props-override main-voice)
1189                     main-music
1190                     (make-voice-props-revert)))))
1191
1192         ;; if we have stem dirs, change both quoted and main music
1193         ;; to have opposite stems.
1194
1195         ;; cannot context-spec Quote-music, since context
1196         ;; for the quotes is determined in the iterator.
1197
1198         (make-sequential-music
1199          (delq! #f
1200                 (list
1201                  (and clef (make-cue-clef-set clef))
1202                  (and cue-type cue-voice
1203                       (context-spec-music
1204                        (make-voice-props-override cue-voice)
1205                        cue-type cue-id))
1206                  quote-music
1207                  (and cue-type cue-voice
1208                       (context-spec-music
1209                        (make-voice-props-revert)
1210                        cue-type cue-id))
1211                  (and clef (make-cue-clef-unset))))))
1212       quote-music))
1213
1214 (define ((quote-substitute quote-tab) music)
1215   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
1216          (quoted-vector (and (string? quoted-name)
1217                              (hash-ref quote-tab quoted-name #f))))
1218
1219
1220     (if (string? quoted-name)
1221         (if (vector? quoted-vector)
1222             (begin
1223               (set! (ly:music-property music 'quoted-events) quoted-vector)
1224               (set! (ly:music-property music 'iterator-ctor)
1225                     ly:quote-iterator::constructor))
1226             (ly:music-warning music (ly:format (_ "cannot find quoted music: `~S'") quoted-name))))
1227     music))
1228 (export quote-substitute)
1229
1230
1231 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1232 ;; switch it on here, so parsing and init isn't checked (too slow!)
1233 ;;
1234 ;; automatic music transformations.
1235
1236 (define (switch-on-debugging m)
1237   (if (defined? 'set-debug-cell-accesses!)
1238       (set-debug-cell-accesses! 15000))
1239   m)
1240
1241 (define (music-check-error music)
1242   (define found #f)
1243   (define (signal m)
1244     (if (and (ly:music? m)
1245              (eq? (ly:music-property m 'error-found) #t))
1246         (set! found #t)))
1247
1248   (for-each signal (ly:music-property music 'elements))
1249   (signal (ly:music-property music 'element))
1250
1251   (if found
1252       (set! (ly:music-property music 'error-found) #t))
1253   music)
1254
1255 (define (precompute-music-length music)
1256   (set! (ly:music-property music 'length)
1257         (ly:music-length music))
1258   music)
1259
1260 (define-public (make-duration-of-length moment)
1261   "Make duration of the given @code{moment} length."
1262   (ly:make-duration 0 0
1263                     (ly:moment-main-numerator moment)
1264                     (ly:moment-main-denominator moment)))
1265
1266 (define (make-skipped moment bool)
1267   "Depending on BOOL, set or unset skipTypesetting,
1268 then make SkipMusic of the given MOMENT length, and
1269 then revert skipTypesetting."
1270   (make-sequential-music
1271    (list
1272     (context-spec-music (make-property-set 'skipTypesetting bool)
1273                         'Score)
1274     (make-music 'SkipMusic 'duration
1275                 (make-duration-of-length moment))
1276     (context-spec-music (make-property-set 'skipTypesetting (not bool))
1277                         'Score))))
1278
1279 (define (skip-as-needed music parser)
1280   "Replace MUSIC by
1281  << {  \\set skipTypesetting = ##f
1282  LENGTHOF(\\showFirstLength)
1283  \\set skipTypesetting = ##t
1284  LENGTHOF(\\showLastLength) }
1285  MUSIC >>
1286  if appropriate.
1287
1288  When only showFirstLength is set,
1289  the 'length property of the music is
1290  overridden to speed up compiling."
1291   (let*
1292       ((show-last (ly:parser-lookup parser 'showLastLength))
1293        (show-first (ly:parser-lookup parser 'showFirstLength))
1294        (show-last-length (and (ly:music? show-last)
1295                               (ly:music-length show-last)))
1296        (show-first-length (and (ly:music? show-first)
1297                                (ly:music-length show-first)))
1298        (orig-length (ly:music-length music)))
1299
1300     ;;FIXME: if using either showFirst- or showLastLength,
1301     ;; make sure that skipBars is not set.
1302
1303     (cond
1304
1305      ;; both properties may be set.
1306      ((and show-first-length show-last-length)
1307       (let
1308           ((skip-length (ly:moment-sub orig-length show-last-length)))
1309         (make-simultaneous-music
1310          (list
1311           (make-sequential-music
1312            (list
1313             (make-skipped skip-length #t)
1314             ;; let's draw a separator between the beginning and the end
1315             (context-spec-music (make-property-set 'whichBar "||")
1316                                 'Timing)))
1317           (make-skipped show-first-length #f)
1318           music))))
1319
1320      ;; we may only want to print the last length
1321      (show-last-length
1322       (let
1323           ((skip-length (ly:moment-sub orig-length show-last-length)))
1324         (make-simultaneous-music
1325          (list
1326           (make-skipped skip-length #t)
1327           music))))
1328
1329      ;; we may only want to print the beginning; in this case
1330      ;; only the first length will be processed (much faster).
1331      (show-first-length
1332       ;; the first length must not exceed the original length.
1333       (if (ly:moment<? show-first-length orig-length)
1334           (set! (ly:music-property music 'length)
1335                 show-first-length))
1336       music)
1337
1338      (else music))))
1339
1340
1341 (define-session-public toplevel-music-functions
1342   (list
1343    (lambda (music parser) (expand-repeat-chords!
1344                            (cons 'rhythmic-event
1345                                  (ly:parser-lookup parser '$chord-repeat-events))
1346                            music))
1347    (lambda (music parser) (expand-repeat-notes! music))
1348    (lambda (music parser) (voicify-music music))
1349    (lambda (x parser) (music-map music-check-error x))
1350    (lambda (x parser) (music-map precompute-music-length x))
1351    (lambda (music parser)
1352
1353      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
1354
1355    ;; switch-on-debugging
1356    (lambda (x parser) (music-map cue-substitute x))
1357
1358    (lambda (x parser)
1359      (skip-as-needed x parser)
1360      )))
1361
1362 ;;;;;;;;;;
1363 ;;; general purpose music functions
1364
1365 (define (shift-octave pitch octave-shift)
1366   (_i "Add @var{octave-shift} to the octave of @var{pitch}.")
1367   (ly:make-pitch
1368    (+ (ly:pitch-octave pitch) octave-shift)
1369    (ly:pitch-notename pitch)
1370    (ly:pitch-alteration pitch)))
1371
1372
1373 ;;;;;;;;;;;;;;;;;
1374 ;; lyrics
1375
1376 (define (apply-durations lyric-music durations)
1377   (define (apply-duration music)
1378     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
1379              (ly:duration?  (ly:music-property music 'duration)))
1380         (begin
1381           (set! (ly:music-property music 'duration) (car durations))
1382           (set! durations (cdr durations)))))
1383
1384   (music-map apply-duration lyric-music))
1385
1386
1387 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1388 ;; accidentals
1389
1390 (define (recent-enough? bar-number alteration-def laziness)
1391   (or (number? alteration-def)
1392       (equal? laziness #t)
1393       (<= bar-number (+ (cadr alteration-def) laziness))))
1394
1395 (define (accidental-invalid? alteration-def)
1396   "Checks an alteration entry for being invalid.
1397
1398 Non-key alterations are invalidated when tying into the next bar or
1399 when there is a clef change, since neither repetition nor cancellation
1400 can be omitted when the same note occurs again.
1401
1402 Returns @code{#f} or the reason for the invalidation, a symbol."
1403   (let* ((def (if (pair? alteration-def)
1404                   (car alteration-def)
1405                   alteration-def)))
1406     (and (symbol? def) def)))
1407
1408 (define (extract-alteration alteration-def)
1409   (cond ((number? alteration-def)
1410          alteration-def)
1411         ((pair? alteration-def)
1412          (car alteration-def))
1413         (else 0)))
1414
1415 (define (check-pitch-against-signature context pitch barnum laziness octaveness all-naturals)
1416   "Checks the need for an accidental and a @q{restore} accidental against
1417 @code{localAlterations} and @code{keyAlterations}.
1418 The @var{laziness} is the number of measures
1419 for which reminder accidentals are used (i.e., if @var{laziness} is zero,
1420 only cancel accidentals in the same measure; if @var{laziness} is three,
1421 we cancel accidentals up to three measures after they first appear.
1422 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1423 specifies whether accidentals should be canceled in different octaves.
1424 If @var{all-naturals} is ##t, notes that do not occur in @code{keyAlterations}
1425 also get an accidental."
1426   (let* ((ignore-octave (cond ((equal? octaveness 'any-octave) #t)
1427                               ((equal? octaveness 'same-octave) #f)
1428                               (else
1429                                (ly:warning (_ "Unknown octaveness type: ~S ") octaveness)
1430                                (ly:warning (_ "Defaulting to 'any-octave."))
1431                                #t)))
1432          (key (ly:context-property context 'keyAlterations))
1433          (local (ly:context-property context 'localAlterations))
1434          (notename (ly:pitch-notename pitch))
1435          (octave (ly:pitch-octave pitch))
1436          (pitch-handle (cons octave notename))
1437          (need-restore #f)
1438          (need-accidental #f)
1439          (previous-alteration #f)
1440          (from-other-octaves #f)
1441          (from-same-octave (assoc-get pitch-handle local))
1442          (from-key-sig (or (assoc-get notename local)
1443
1444                            ;; If no notename match is found from localAlterations, we may have a custom
1445                            ;; type with octave-specific entries of the form ((octave . pitch) alteration)
1446                            ;; instead of (pitch . alteration).  Since this type cannot coexist with entries in
1447                            ;; localAlterations, try extracting from keyAlterations instead.
1448                            (assoc-get pitch-handle key))))
1449
1450     ;; loop through localAlterations to search for a notename match from other octaves
1451     (let loop ((l local))
1452       (if (pair? l)
1453           (let ((entry (car l)))
1454             (if (and (pair? (car entry))
1455                      (= (cdar entry) notename))
1456                 (set! from-other-octaves (cdr entry))
1457                 (loop (cdr l))))))
1458
1459     ;; find previous alteration-def for comparison with pitch
1460     (cond
1461      ;; from same octave?
1462      ((and (not ignore-octave)
1463            from-same-octave
1464            (recent-enough? barnum from-same-octave laziness))
1465       (set! previous-alteration from-same-octave))
1466
1467      ;; from any octave?
1468      ((and ignore-octave
1469            from-other-octaves
1470            (recent-enough? barnum from-other-octaves laziness))
1471       (set! previous-alteration from-other-octaves))
1472
1473      ;; not recent enough, extract from key signature/local key signature
1474      (from-key-sig
1475       (set! previous-alteration from-key-sig)))
1476
1477     (if (accidental-invalid? previous-alteration)
1478         (set! need-accidental #t)
1479
1480         (let* ((prev-alt (extract-alteration previous-alteration))
1481                (this-alt (ly:pitch-alteration pitch)))
1482
1483           (if (or (and all-naturals (eq? #f previous-alteration)) (not (= this-alt prev-alt)))
1484               (begin
1485                 (set! need-accidental #t)
1486                 (if (and (not (= this-alt 0))
1487                          (and (< (abs this-alt) (abs prev-alt))
1488                               (> (* prev-alt this-alt) 0)))
1489                     (set! need-restore #t))))))
1490
1491     (cons need-restore need-accidental)))
1492
1493 (define ((make-accidental-rule octaveness laziness) context pitch barnum measurepos)
1494   "Create an accidental rule that makes its decision based on the octave of
1495 the note and a laziness value.
1496
1497 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1498 defines whether the rule should respond to accidental changes in other
1499 octaves than the current.  @code{'same-octave} is the normal way to typeset
1500 accidentals -- an accidental is made if the alteration is different from the
1501 last active pitch in the same octave.  @code{'any-octave} looks at the last
1502 active pitch in any octave.
1503
1504 @var{laziness} states over how many bars an accidental should be remembered.
1505 @code{0}@tie{}is the default -- accidental lasts over 0@tie{}bar lines, that
1506 is, to the end of current measure.  A positive integer means that the
1507 accidental lasts over that many bar lines.  @w{@code{-1}} is `forget
1508 immediately', that is, only look at key signature.  @code{#t} is `forever'."
1509
1510   (check-pitch-against-signature context pitch barnum laziness octaveness #f))
1511 (export make-accidental-rule)
1512
1513 (define ((make-accidental-dodecaphonic-rule octaveness laziness) context pitch barnum measurepos)
1514   "Variation on function make-accidental-rule that creates an dodecaphonic
1515 accidental rule."
1516
1517   (check-pitch-against-signature context pitch barnum laziness octaveness #t))
1518 (export make-accidental-dodecaphonic-rule)
1519
1520 (define (key-entry-notename entry)
1521   "Return the pitch of an @var{entry} in @code{localAlterations}.
1522 The @samp{car} of the entry is either of the form @code{notename} or
1523 of the form @code{(octave . notename)}.  The latter form is used for special
1524 key signatures or to indicate an explicit accidental.
1525
1526 The @samp{cdr} of the entry is either a rational @code{alter} indicating
1527 a key signature alteration, or of the form
1528 @code{(alter . (barnum . measurepos))} indicating an alteration caused by
1529 an accidental in music."
1530   (if (pair? (car entry))
1531       (cdar entry)
1532       (car entry)))
1533
1534 (define (key-entry-octave entry)
1535   "Return the octave of an entry in @code{localAlterations}
1536 or @code{#f} if the entry does not have an octave.
1537 See @code{key-entry-notename} for details."
1538   (and (pair? (car entry)) (caar entry)))
1539
1540 (define (key-entry-bar-number entry)
1541   "Return the bar number of an entry in @code{localAlterations}
1542 or @code {#f} if the entry does not have a bar number.
1543 See @code{key-entry-notename} for details."
1544   (and (pair? (cdr entry)) (caddr entry)))
1545
1546 (define (key-entry-measure-position entry)
1547   "Return the measure position of an entry in @code{localAlterations}
1548 or @code {#f} if the entry does not have a measure position.
1549 See @code{key-entry-notename} for details."
1550   (and (pair? (cdr entry)) (cdddr entry)))
1551
1552 (define (key-entry-alteration entry)
1553   "Return the alteration of an entry in localAlterations
1554
1555 For convenience, returns @code{0} if entry is @code{#f}."
1556   (if entry
1557       (if (number? (cdr entry))
1558           (cdr entry)
1559           (cadr entry))
1560       0))
1561
1562 (define-public (find-pitch-entry keysig pitch accept-global accept-local)
1563   "Return the first entry in @var{keysig} that matches @var{pitch}
1564 by notename and octave.  Alteration is not considered.
1565 @var{accept-global} states whether key signature entries should be included.
1566 @var{accept-local} states whether local accidentals should be included.
1567 If no matching entry is found, @var{#f} is returned."
1568   (and (pair? keysig)
1569        (let* ((entry (car keysig))
1570               (entryoct (key-entry-octave entry))
1571               (entrynn (key-entry-notename entry))
1572               (nn (ly:pitch-notename pitch)))
1573          (if (and (equal? nn entrynn)
1574                   (or (not entryoct)
1575                       (= entryoct (ly:pitch-octave pitch)))
1576                   (if (key-entry-bar-number entry)
1577                       accept-local
1578                       accept-global))
1579              entry
1580              (find-pitch-entry (cdr keysig) pitch accept-global accept-local)))))
1581
1582 (define-public (neo-modern-accidental-rule context pitch barnum measurepos)
1583   "An accidental rule that typesets an accidental if it differs from the
1584 key signature @emph{and} does not directly follow a note on the same
1585 staff line.  This rule should not be used alone because it does neither
1586 look at bar lines nor different accidentals at the same note name."
1587   (let* ((keysig (ly:context-property context 'localAlterations))
1588          (entry (find-pitch-entry keysig pitch #t #t)))
1589     (if (not entry)
1590         (cons #f #f)
1591         (let* ((global-entry (find-pitch-entry keysig pitch #t #f))
1592                (key-acc (key-entry-alteration global-entry))
1593                (acc (ly:pitch-alteration pitch))
1594                (entrymp (key-entry-measure-position entry))
1595                (entrybn (key-entry-bar-number entry)))
1596           (cons #f (not (or (equal? acc key-acc)
1597                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1598
1599 (define-public (dodecaphonic-no-repeat-rule context pitch barnum measurepos)
1600   "An accidental rule that typesets an accidental before every
1601 note (just as in the dodecaphonic accidental style) @emph{except} if
1602 the note is immediately preceded by a note with the same pitch. This
1603 is a common accidental style in contemporary notation."
1604    (let* ((keysig (ly:context-property context 'localAlterations))
1605           (entry (find-pitch-entry keysig pitch #f #t)))
1606      (if (not entry)
1607          (cons #f #t)
1608          (let ((entrymp (key-entry-measure-position entry))
1609                (entrybn (key-entry-bar-number entry))
1610                (entryalt (key-entry-alteration entry))
1611                (alt (ly:pitch-alteration pitch)))
1612            (cons #t
1613                  (not (and (equal? entrybn barnum)
1614                            (or (equal? measurepos entrymp)
1615                                (ly:moment<? measurepos entrymp))
1616                            (equal? entryalt alt))))))))
1617
1618 (define-public (teaching-accidental-rule context pitch barnum measurepos)
1619   "An accidental rule that typesets a cautionary accidental if it is
1620 included in the key signature @emph{and} does not directly follow a note
1621 on the same staff line."
1622   (let* ((keysig (ly:context-property context 'localAlterations))
1623          (entry (find-pitch-entry keysig pitch #t #t)))
1624     (if (not entry)
1625         (cons #f #f)
1626         (let* ((global-entry (find-pitch-entry keysig pitch #f #f))
1627                (key-acc (key-entry-alteration global-entry))
1628                (acc (ly:pitch-alteration pitch))
1629                (entrymp (key-entry-measure-position entry))
1630                (entrybn (key-entry-bar-number entry)))
1631           (cons #f (not (or (equal? acc key-acc)
1632                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1633
1634 (define-public (set-accidentals-properties extra-natural
1635                                            auto-accs auto-cauts
1636                                            context)
1637   (context-spec-music
1638    (make-sequential-music
1639     (append (if (boolean? extra-natural)
1640                 (list (make-property-set 'extraNatural extra-natural))
1641                 '())
1642             (list (make-property-set 'autoAccidentals auto-accs)
1643                   (make-property-set 'autoCautionaries auto-cauts))))
1644    context))
1645
1646 (define-public (set-accidental-style style . rest)
1647   "Set accidental style to @var{style}.  Optionally take a context
1648 argument, e.g. @code{'Staff} or @code{'Voice}.  The context defaults
1649 to @code{Staff}, except for piano styles, which use @code{GrandStaff}
1650 as a context."
1651   (let ((context (if (pair? rest)
1652                      (car rest) 'Staff))
1653         (pcontext (if (pair? rest)
1654                       (car rest) 'GrandStaff)))
1655     (cond
1656      ;; accidentals as they were common in the 18th century.
1657      ((equal? style 'default)
1658       (set-accidentals-properties #t
1659                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1660                                   '()
1661                                   context))
1662      ;; accidentals from one voice do NOT get canceled in other voices
1663      ((equal? style 'voice)
1664       (set-accidentals-properties #t
1665                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1666                                   '()
1667                                   context))
1668      ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
1669      ;; This includes all the default accidentals, but accidentals also needs canceling
1670      ;; in other octaves and in the next measure.
1671      ((equal? style 'modern)
1672       (set-accidentals-properties #f
1673                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1674                                           ,(make-accidental-rule 'any-octave 0)
1675                                           ,(make-accidental-rule 'same-octave 1))
1676                                   '()
1677                                   context))
1678      ;; the accidentals that Stone adds to the old standard as cautionaries
1679      ((equal? style 'modern-cautionary)
1680       (set-accidentals-properties #f
1681                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1682                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1683                                           ,(make-accidental-rule 'same-octave 1))
1684                                   context))
1685      ;; same as modern, but accidentals different from the key signature are always
1686      ;; typeset - unless they directly follow a note of the same pitch.
1687      ((equal? style 'neo-modern)
1688       (set-accidentals-properties #f
1689                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1690                                           ,(make-accidental-rule 'any-octave 0)
1691                                           ,(make-accidental-rule 'same-octave 1)
1692                                           ,neo-modern-accidental-rule)
1693                                   '()
1694                                   context))
1695      ((equal? style 'neo-modern-cautionary)
1696       (set-accidentals-properties #f
1697                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1698                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1699                                           ,(make-accidental-rule 'same-octave 1)
1700                                           ,neo-modern-accidental-rule)
1701                                   context))
1702      ((equal? style 'neo-modern-voice)
1703       (set-accidentals-properties #f
1704                                   `(Voice ,(make-accidental-rule 'same-octave 0)
1705                                           ,(make-accidental-rule 'any-octave 0)
1706                                           ,(make-accidental-rule 'same-octave 1)
1707                                           ,neo-modern-accidental-rule
1708                                           Staff ,(make-accidental-rule 'same-octave 0)
1709                                           ,(make-accidental-rule 'any-octave 0)
1710                                           ,(make-accidental-rule 'same-octave 1)
1711                                           ,neo-modern-accidental-rule)
1712                                   '()
1713                                   context))
1714      ((equal? style 'neo-modern-voice-cautionary)
1715       (set-accidentals-properties #f
1716                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1717                                   `(Voice ,(make-accidental-rule 'any-octave 0)
1718                                           ,(make-accidental-rule 'same-octave 1)
1719                                           ,neo-modern-accidental-rule
1720                                           Staff ,(make-accidental-rule 'same-octave 0)
1721                                           ,(make-accidental-rule 'any-octave 0)
1722                                           ,(make-accidental-rule 'same-octave 1)
1723                                           ,neo-modern-accidental-rule)
1724                                   context))
1725      ;; Accidentals as they were common in dodecaphonic music with no tonality.
1726      ;; Each note gets one accidental.
1727      ((equal? style 'dodecaphonic)
1728       (set-accidentals-properties #f
1729                                   `(Staff ,(lambda (c p bn mp) '(#f . #t)))
1730                                   '()
1731                                   context))
1732      ;; As in dodecaphonic style with the exception that immediately
1733      ;; repeated notes (in the same voice) don't get an accidental
1734      ((equal? style 'dodecaphonic-no-repeat)
1735       (set-accidentals-properties #f
1736                                   `(Staff ,dodecaphonic-no-repeat-rule)
1737                                   '()
1738                                   context))
1739      ;; Variety of the dodecaphonic style. Each note gets an accidental,
1740      ;; except notes that were already handled in the same measure.
1741      ((equal? style 'dodecaphonic-first)
1742       (set-accidentals-properties #f
1743                                   `(Staff ,(make-accidental-dodecaphonic-rule 'same-octave 0))
1744                                   '()
1745                                   context))
1746
1747      ;; Multivoice accidentals to be read both by musicians playing one voice
1748      ;; and musicians playing all voices.
1749      ;; Accidentals are typeset for each voice, but they ARE canceled across voices.
1750      ((equal? style 'modern-voice)
1751       (set-accidentals-properties  #f
1752                                    `(Voice ,(make-accidental-rule 'same-octave 0)
1753                                            ,(make-accidental-rule 'any-octave 0)
1754                                            ,(make-accidental-rule 'same-octave 1)
1755                                            Staff ,(make-accidental-rule 'same-octave 0)
1756                                            ,(make-accidental-rule 'any-octave 0)
1757                                            ,(make-accidental-rule 'same-octave 1))
1758                                    '()
1759                                    context))
1760      ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
1761      ;; as cautionaries
1762      ((equal? style 'modern-voice-cautionary)
1763       (set-accidentals-properties #f
1764                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1765                                   `(Voice ,(make-accidental-rule 'any-octave 0)
1766                                           ,(make-accidental-rule 'same-octave 1)
1767                                           Staff ,(make-accidental-rule 'same-octave 0)
1768                                           ,(make-accidental-rule 'any-octave 0)
1769                                           ,(make-accidental-rule 'same-octave 1))
1770                                   context))
1771      ;; stone's suggestions for accidentals on grand staff.
1772      ;; Accidentals are canceled across the staves in the same grand staff as well
1773      ((equal? style 'piano)
1774       (set-accidentals-properties #f
1775                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1776                                           ,(make-accidental-rule 'any-octave 0)
1777                                           ,(make-accidental-rule 'same-octave 1)
1778                                           GrandStaff
1779                                           ,(make-accidental-rule 'any-octave 0)
1780                                           ,(make-accidental-rule 'same-octave 1))
1781                                   '()
1782                                   pcontext))
1783      ((equal? style 'piano-cautionary)
1784       (set-accidentals-properties #f
1785                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1786                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1787                                           ,(make-accidental-rule 'same-octave 1)
1788                                           GrandStaff
1789                                           ,(make-accidental-rule 'any-octave 0)
1790                                           ,(make-accidental-rule 'same-octave 1))
1791                                   pcontext))
1792
1793      ;; same as modern, but cautionary accidentals are printed for all sharp or flat
1794      ;; tones specified by the key signature.
1795      ((equal? style 'teaching)
1796       (set-accidentals-properties #f
1797                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1798                                   `(Staff ,(make-accidental-rule 'same-octave 1)
1799                                           ,teaching-accidental-rule)
1800                                   context))
1801
1802      ;; do not set localAlterations when a note alterated differently from
1803      ;; localAlterations is found.
1804      ;; Causes accidentals to be printed at every note instead of
1805      ;; remembered for the duration of a measure.
1806      ;; accidentals not being remembered, causing accidentals always to
1807      ;; be typeset relative to the time signature
1808      ((equal? style 'forget)
1809       (set-accidentals-properties '()
1810                                   `(Staff ,(make-accidental-rule 'same-octave -1))
1811                                   '()
1812                                   context))
1813      ;; Do not reset the key at the start of a measure.  Accidentals will be
1814      ;; printed only once and are in effect until overridden, possibly many
1815      ;; measures later.
1816      ((equal? style 'no-reset)
1817       (set-accidentals-properties '()
1818                                   `(Staff ,(make-accidental-rule 'same-octave #t))
1819                                   '()
1820                                   context))
1821      (else
1822       (ly:warning (_ "unknown accidental style: ~S") style)
1823       (make-sequential-music '())))))
1824
1825 (define-public (invalidate-alterations context)
1826   "Invalidate alterations in @var{context}.
1827
1828 Elements of @code{'localAlterations} corresponding to local
1829 alterations of the key signature have the form
1830 @code{'((octave . notename) . (alter barnum . measurepos))}.
1831 Replace them with a version where @code{alter} is set to @code{'clef}
1832 to force a repetition of accidentals.
1833
1834 Entries that conform with the current key signature are not invalidated."
1835   (let* ((keysig (ly:context-property context 'keyAlterations)))
1836     (set! (ly:context-property context 'localAlterations)
1837           (map-in-order
1838            (lambda (entry)
1839              (let* ((localalt (key-entry-alteration entry)))
1840                (if (or (accidental-invalid? localalt)
1841                        (not (key-entry-bar-number entry))
1842                        (= localalt
1843                           (key-entry-alteration
1844                            (find-pitch-entry
1845                             keysig
1846                             (ly:make-pitch (key-entry-octave entry)
1847                                            (key-entry-notename entry)
1848                                            0)
1849                             #t #t))))
1850                    entry
1851                    (cons (car entry) (cons 'clef (cddr entry))))))
1852            (ly:context-property context 'localAlterations)))))
1853
1854 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1855
1856 (define-public (skip-of-length mus)
1857   "Create a skip of exactly the same length as @var{mus}."
1858   (let* ((skip
1859           (make-music
1860            'SkipEvent
1861            'duration (ly:make-duration 0 0))))
1862
1863     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
1864
1865 (define-public (mmrest-of-length mus)
1866   "Create a multi-measure rest of exactly the same length as @var{mus}."
1867
1868   (let* ((skip
1869           (make-multi-measure-rest
1870            (ly:make-duration 0 0) '())))
1871     (ly:music-compress skip (ly:music-length mus))
1872     skip))
1873
1874 (define-public (pitch-of-note event-chord)
1875   (let ((evs (filter (lambda (x)
1876                        (music-has-type x 'note-event))
1877                      (ly:music-property event-chord 'elements))))
1878
1879     (and (pair? evs)
1880          (ly:music-property (car evs) 'pitch))))
1881
1882 (define-public (duration-of-note event-chord)
1883   (cond
1884    ((pair? event-chord)
1885     (or (duration-of-note (car event-chord))
1886         (duration-of-note (cdr event-chord))))
1887    ((ly:music? event-chord)
1888     (let ((dur (ly:music-property event-chord 'duration)))
1889       (if (ly:duration? dur)
1890           dur
1891           (duration-of-note (ly:music-property event-chord 'elements)))))
1892    (else #f)))
1893
1894 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1895
1896 (define-public (map-some-music map? music)
1897   "Walk through @var{music}, transform all elements calling @var{map?}
1898 and only recurse if this returns @code{#f}.  @code{elements} or
1899 @code{articulations} that are not music expressions are discarded:
1900 this allows some amount of filtering.
1901
1902 @code{map-some-music} may overwrite the original @var{music}."
1903   (let loop ((music music))
1904     (or (map? music)
1905         (let ((elt (ly:music-property music 'element))
1906               (elts (ly:music-property music 'elements))
1907               (arts (ly:music-property music 'articulations)))
1908           (if (ly:music? elt)
1909               (set! (ly:music-property music 'element)
1910                     (loop elt)))
1911           (if (pair? elts)
1912               (set! (ly:music-property music 'elements)
1913                     (filter! ly:music? (map! loop elts))))
1914           (if (pair? arts)
1915               (set! (ly:music-property music 'articulations)
1916                     (filter! ly:music? (map! loop arts))))
1917           music))))
1918
1919 (define-public (for-some-music stop? music)
1920   "Walk through @var{music}, process all elements calling @var{stop?}
1921 and only recurse if this returns @code{#f}."
1922   (let loop ((music music))
1923     (if (not (stop? music))
1924         (let ((elt (ly:music-property music 'element)))
1925           (if (ly:music? elt)
1926               (loop elt))
1927           (for-each loop (ly:music-property music 'elements))
1928           (for-each loop (ly:music-property music 'articulations))))))
1929
1930 (define-public (fold-some-music pred? proc init music)
1931   "This works recursively on music like @code{fold} does on a list,
1932 calling @samp{(@var{pred?} music)} on every music element.  If
1933 @code{#f} is returned for an element, it is processed recursively
1934 with the same initial value of @samp{previous}, otherwise
1935 @samp{(@var{proc} music previous)} replaces @samp{previous}
1936 and no recursion happens.
1937 The top @var{music} is processed using @var{init} for @samp{previous}."
1938   (let loop ((music music) (previous init))
1939     (if (pred? music)
1940         (proc music previous)
1941         (fold loop
1942               (fold loop
1943                     (let ((elt (ly:music-property music 'element)))
1944                       (if (null? elt)
1945                           previous
1946                           (loop elt previous)))
1947                     (ly:music-property music 'elements))
1948               (ly:music-property music 'articulations)))))
1949
1950 (define-public (extract-music music pred?)
1951   "Return a flat list of all music matching @var{pred?} inside of
1952 @var{music}, not recursing into matches themselves."
1953   (reverse! (fold-some-music pred? cons '() music)))
1954
1955 (define-public (extract-named-music music music-name)
1956   "Return a flat list of all music named @var{music-name} (either a
1957 single event symbol or a list of alternatives) inside of @var{music},
1958 not recursing into matches themselves."
1959   (extract-music
1960    music
1961    (if (cheap-list? music-name)
1962        (lambda (m) (memq (ly:music-property m 'name) music-name))
1963        (lambda (m) (eq? (ly:music-property m 'name) music-name)))))
1964
1965 (define-public (extract-typed-music music type)
1966   "Return a flat list of all music with @var{type} (either a single
1967 type symbol or a list of alternatives) inside of @var{music}, not
1968 recursing into matches themselves."
1969   (extract-music
1970    music
1971    (if (cheap-list? type)
1972        (lambda (m)
1973          (any (lambda (t) (music-is-of-type? m t)) type))
1974        (lambda (m) (music-is-of-type? m type)))))
1975
1976 (define*-public (event-chord-wrap! music #:optional parser)
1977   "Wrap isolated rhythmic events and non-postevent events in
1978 @var{music} inside of an @code{EventChord}.  If the optional
1979 @var{parser} argument is given, chord repeats @samp{q} are expanded
1980 using the default settings.  Otherwise, you need to cater for them
1981 yourself."
1982   (map-some-music
1983    (lambda (m)
1984      (cond ((music-is-of-type? m 'event-chord)
1985             (if (pair? (ly:music-property m 'articulations))
1986                 (begin
1987                   (set! (ly:music-property m 'elements)
1988                         (append (ly:music-property m 'elements)
1989                                 (ly:music-property m 'articulations)))
1990                   (set! (ly:music-property m 'articulations) '())))
1991             m)
1992            ((music-is-of-type? m 'rhythmic-event)
1993             (let ((arts (ly:music-property m 'articulations)))
1994               (if (pair? arts)
1995                   (set! (ly:music-property m 'articulations) '()))
1996               (make-event-chord (cons m arts))))
1997            (else #f)))
1998    (if parser
1999        (expand-repeat-chords!
2000         (cons 'rhythmic-event
2001               (ly:parser-lookup parser '$chord-repeat-events))
2002         music)
2003        music)))
2004
2005 (define-public (event-chord-notes event-chord)
2006   "Return a list of all notes from @var{event-chord}."
2007   (filter
2008    (lambda (m) (eq? 'NoteEvent (ly:music-property m 'name)))
2009    (ly:music-property event-chord 'elements)))
2010
2011 (define-public (event-chord-pitches event-chord)
2012   "Return a list of all pitches from @var{event-chord}."
2013   (map (lambda (x) (ly:music-property x 'pitch))
2014        (event-chord-notes event-chord)))
2015
2016 (define-public (event-chord-reduce music)
2017   "Reduces event chords in @var{music} to their first note event,
2018 retaining only the chord articulations.  Returns the modified music."
2019   (map-some-music
2020    (lambda (m)
2021      (and (music-is-of-type? m 'event-chord)
2022           (let*-values (((notes arts) (partition
2023                                        (lambda (mus)
2024                                          (music-is-of-type? mus 'rhythmic-event))
2025                                        (ly:music-property m 'elements)))
2026                         ((dur) (ly:music-property m 'duration))
2027                         ((full-arts) (append arts
2028                                              (ly:music-property m 'articulations)))
2029                         ((first-note) (and (pair? notes) (car notes))))
2030             (cond (first-note
2031                    (set! (ly:music-property first-note 'articulations)
2032                          full-arts)
2033                    first-note)
2034                   ((ly:duration? dur)
2035                    ;; A repeat chord. Produce an unpitched note.
2036                    (make-music 'NoteEvent
2037                                'duration dur
2038                                'articulations full-arts))
2039                   (else
2040                    (ly:music-error m (_ "Missing duration"))
2041                    (make-music 'NoteEvent
2042                                'duration (ly:make-duration 2 0 0)
2043                                'articulations full-arts))))))
2044    music))
2045
2046
2047 (defmacro-public make-relative (variables reference music)
2048   "The list of pitch or music variables in @var{variables} is used as
2049 a sequence for creating relativable music from @var{music}.
2050
2051 When the constructed music is used outside of @code{\\relative}, it
2052 just reflects plugging in the @var{variables} into @var{music}.
2053
2054 The action inside of @code{\\relative}, however, is determined by
2055 first relativizing the surrogate @var{reference} with the variables
2056 plugged in and then using the variables relativized as a side effect
2057 of relativizing @var{reference} for evaluating @var{music}.
2058
2059 Since pitches don't have the object identity required for tracing the
2060 effect of the reference call, they are replaced @emph{only} for the
2061 purpose of evaluating @var{reference} with simple pitched note events.
2062
2063 The surrogate @var{reference} expression has to be written with that
2064 in mind.  In addition, it must @emph{not} contain @emph{copies} of
2065 music that is supposed to be relativized but rather the
2066 @emph{originals}.  This @emph{includes} the pitch expressions.  As a
2067 rule, inside of @code{#@{@dots{}#@}} variables must @emph{only} be
2068 introduced using @code{#}, never via the copying construct @code{$}.
2069 The reference expression will usually just be a sequential or chord
2070 expression naming all variables in sequence, implying that following
2071 music will be relativized according to the resulting pitch of the last
2072 or first variable, respectively.
2073
2074 Since the usual purpose is to create more complex music from general
2075 arguments and since music expression parts must not occur more than
2076 once, one @emph{does} generally need to use copying operators in the
2077 @emph{replacement} expression @var{music} when using an argument more
2078 than once there.  Using an argument more than once in @var{reference},
2079 in contrast, does not make sense.
2080
2081 There is another fine point to mind: @var{music} must @emph{only}
2082 contain freshly constructed elements or copied constructs.  This will
2083 be the case anyway for regular LilyPond code inside of
2084 @code{#@{@dots{}#@}}, but any other elements (apart from the
2085 @var{variables} themselves which are already copied) must be created
2086 or copied as well.
2087
2088 The reason is that it is usually permitted to change music in-place as
2089 long as one does a @var{ly:music-deep-copy} on it, and such a copy of
2090 the whole resulting expression will @emph{not} be able to copy
2091 variables/values inside of closures where the information for
2092 relativization is being stored.
2093 "
2094
2095   ;; pitch and music generator might be stored instead in music
2096   ;; properties, and it might make sense to create a music type of its
2097   ;; own for this kind of construct rather than using
2098   ;; RelativeOctaveMusic
2099   (define ((make-relative::to-relative-callback variables music-call ref-call)
2100            music pitch)
2101     (let* ((ref-vars (map (lambda (v)
2102                             (if (ly:pitch? v)
2103                                 (make-music 'NoteEvent 'pitch v)
2104                                 (ly:music-deep-copy v)))
2105                           variables))
2106            (after-pitch (ly:make-music-relative! (apply ref-call ref-vars) pitch))
2107            (actual-vars (map (lambda (v r)
2108                                (if (ly:pitch? v)
2109                                    (ly:music-property r 'pitch)
2110                                    r))
2111                              variables ref-vars))
2112            (rel-music (apply music-call actual-vars)))
2113       (set! (ly:music-property music 'element) rel-music)
2114       after-pitch))
2115   `(make-music 'RelativeOctaveMusic
2116                'to-relative-callback
2117                (,make-relative::to-relative-callback
2118                 (list ,@variables)
2119                 (lambda ,variables ,music)
2120                 (lambda ,variables ,reference))
2121                'element ,music))
2122
2123 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2124 ;; The following functions are all associated with the crossStaff
2125 ;;  function
2126
2127 (define (close-enough? x y)
2128   "Values are close enough to ignore the difference"
2129   (< (abs (- x y)) 0.0001))
2130
2131 (define (extent-combine extents)
2132   "Combine a list of extents"
2133   (if (pair? (cdr extents))
2134       (interval-union (car extents) (extent-combine (cdr extents)))
2135       (car extents)))
2136
2137 (define ((stem-connectable? ref root) stem)
2138   "Check if the stem is connectable to the root"
2139   ;; The root is always connectable to itself
2140   (or (eq? root stem)
2141       (and
2142        ;; Horizontal positions of the stems must be almost the same
2143        (close-enough? (car (ly:grob-extent root ref X))
2144                       (car (ly:grob-extent stem ref X)))
2145        ;; The stem must be in the direction away from the root's notehead
2146        (positive? (* (ly:grob-property root 'direction)
2147                      (- (car (ly:grob-extent stem ref Y))
2148                         (car (ly:grob-extent root ref Y))))))))
2149
2150 (define (stem-span-stencil span)
2151   "Connect stems if we have at least one stem connectable to the root"
2152   (let* ((system (ly:grob-system span))
2153          (root (ly:grob-parent span X))
2154          (stems (filter (stem-connectable? system root)
2155                         (ly:grob-object span 'stems))))
2156     (if (<= 2 (length stems))
2157         (let* ((yextents (map (lambda (st)
2158                                 (ly:grob-extent st system Y)) stems))
2159                (yextent (extent-combine yextents))
2160                (layout (ly:grob-layout root))
2161                (blot (ly:output-def-lookup layout 'blot-diameter)))
2162           ;; Hide spanned stems
2163           (for-each (lambda (st)
2164                       (set! (ly:grob-property st 'stencil) #f))
2165                     stems)
2166           ;; Draw a nice looking stem with rounded corners
2167           (ly:round-filled-box (ly:grob-extent root root X) yextent blot))
2168         ;; Nothing to connect, don't draw the span
2169         #f)))
2170
2171 (define ((make-stem-span! stems trans) root)
2172   "Create a stem span as a child of the cross-staff stem (the root)"
2173   (let ((span (ly:engraver-make-grob trans 'Stem '())))
2174     (ly:grob-set-parent! span X root)
2175     (set! (ly:grob-object span 'stems) stems)
2176     ;; Suppress positioning, the stem code is confused by this weird stem
2177     (set! (ly:grob-property span 'X-offset) 0)
2178     (set! (ly:grob-property span 'stencil) stem-span-stencil)))
2179
2180 (define-public (cross-staff-connect stem)
2181   "Set cross-staff property of the stem to this function to connect it to
2182 other stems automatically"
2183   #t)
2184
2185 (define (stem-is-root? stem)
2186   "Check if automatic connecting of the stem was requested.  Stems connected
2187 to cross-staff beams are cross-staff, but they should not be connected to
2188 other stems just because of that."
2189   (eq? cross-staff-connect (ly:grob-property-data stem 'cross-staff)))
2190
2191 (define (make-stem-spans! ctx stems trans)
2192   "Create stem spans for cross-staff stems"
2193   ;; Cannot do extensive checks here, just make sure there are at least
2194   ;; two stems at this musical moment
2195   (if (<= 2 (length stems))
2196       (let ((roots (filter stem-is-root? stems)))
2197         (for-each (make-stem-span! stems trans) roots))))
2198
2199 (define-public (Span_stem_engraver ctx)
2200   "Connect cross-staff stems to the stems above in the system"
2201   (let ((stems '()))
2202     (make-engraver
2203      ;; Record all stems for the given moment
2204      (acknowledgers
2205       ((stem-interface trans grob source)
2206        (set! stems (cons grob stems))))
2207      ;; Process stems and reset the stem list to empty
2208      ((process-acknowledged trans)
2209       (make-stem-spans! ctx stems trans)
2210       (set! stems '())))))
2211
2212 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2213 ;; The following is used by the alterBroken function.
2214
2215 (define ((value-for-spanner-piece arg) grob)
2216   "Associate a piece of broken spanner @var{grob} with an element
2217 of list @var{arg}."
2218   (let* ((orig (ly:grob-original grob))
2219          (siblings (ly:spanner-broken-into orig)))
2220
2221     (define (helper sibs arg)
2222       (if (null? arg)
2223           arg
2224           (if (eq? (car sibs) grob)
2225               (car arg)
2226               (helper (cdr sibs) (cdr arg)))))
2227
2228     (if (>= (length siblings) 2)
2229         (helper siblings arg)
2230         (car arg))))
2231 (export value-for-spanner-piece)
2232
2233 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2234 ;; The following are used by the \offset function
2235
2236 (define (find-value-to-offset prop self alist)
2237   "Return the first value of the property @var{prop} in the property
2238 alist @var{alist} -- after having found @var{self}.  If @var{self} is
2239 not found, return the first value of @var{prop}."
2240   (let ((segment (member (cons prop self) alist)))
2241     (if (not segment)
2242         (assoc-get prop alist)
2243         (assoc-get prop (cdr segment)))))
2244
2245 (define (offset-multiple-types arg offsets)
2246   "Displace @var{arg} by @var{offsets} if @var{arg} is a number, a
2247 number pair, or a list of number pairs.  If @var{offsets} is an empty
2248 list or if there is a type-mismatch, @var{arg} will be returned."
2249   (cond
2250     ((and (number? arg) (number? offsets))
2251      (+ arg offsets))
2252     ((and (number-pair? arg)
2253           (or (number? offsets)
2254               (number-pair? offsets)))
2255      (coord-translate arg offsets))
2256     ((and (number-pair-list? arg) (number-pair-list? offsets))
2257      (map
2258        (lambda (x y) (coord-translate x y))
2259        arg offsets))
2260     (else arg)))
2261
2262 (define-public (offsetter property offsets)
2263   "Apply @var{offsets} to the default values of @var{property} of @var{grob}.
2264 Offsets are restricted to immutable properties and values of type @code{number},
2265 @code{number-pair}, or @code{number-pair-list}."
2266   (define (self grob)
2267     (let* ((immutable (ly:grob-basic-properties grob))
2268            ; We need to search the basic-properties alist for our property to
2269            ; obtain values to offset.  Our search is complicated by the fact that
2270            ; calling the music function `offset' as an override conses a pair to
2271            ; the head of the alist.  This pair must be discounted.  The closure it
2272            ; contains is named `self' so it can be easily recognized.  If `offset'
2273            ; is called as a tweak, the basic-property alist is unaffected.
2274            (target (find-value-to-offset property self immutable))
2275            ; if target is a procedure, we need to apply it to our grob to calculate
2276            ; values to offset.
2277            (vals
2278              (if (procedure? target)
2279                  (target grob)
2280                  target))
2281            (can-type-be-offset?
2282              (or (number? vals)
2283                  (number-pair? vals)
2284                  (number-pair-list? vals))))
2285
2286       (if can-type-be-offset?
2287           ; '(+inf.0 . -inf.0) would offset to itself.  This will be confusing to a
2288           ; user unaware of the default value of the property, so issue a warning.
2289           (if (equal? empty-interval vals)
2290               (ly:warning "default '~a of ~a is ~a and can't be offset"
2291                 property grob vals)
2292               (let* ((orig (ly:grob-original grob))
2293                      (siblings
2294                        (if (ly:spanner? grob)
2295                            (ly:spanner-broken-into orig)
2296                            '()))
2297                      (total-found (length siblings))
2298                      ; Since there is some flexibility in input syntax,
2299                      ; structure of `offsets' is normalized.
2300                      (offsets
2301                        (if (or (not (pair? offsets))
2302                                (number-pair? offsets)
2303                                (and (number-pair-list? offsets)
2304                                     (number-pair-list? vals)))
2305                            (list offsets)
2306                            offsets)))
2307
2308                 (define (helper sibs offs)
2309                   ; apply offsets to the siblings of broken spanners
2310                   (if (pair? offs)
2311                       (if (eq? (car sibs) grob)
2312                           (offset-multiple-types vals (car offs))
2313                           (helper (cdr sibs) (cdr offs)))
2314                       vals))
2315
2316                 (if (>= total-found 2)
2317                     (helper siblings offsets)
2318                     (offset-multiple-types vals (car offsets)))))
2319
2320               (begin
2321                 (ly:warning "the property '~a of ~a cannot be offset" property grob)
2322                 vals))))
2323     ; return the closure named `self'
2324     self)
2325
2326
2327 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2328 ;; \magnifyMusic and \magnifyStaff
2329
2330 ;; defined as a function instead of a list because the
2331 ;; all-grob-descriptions alist is not available yet
2332 (define-public (find-named-props prop-name grob-descriptions)
2333   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  When
2334 @var{grob-descriptions} is equal to the @code{all-grob-descriptions}
2335 alist (defined in @file{scm/define-grobs.scm}), this will find all grobs
2336 that can have a value for the @var{prop-name} property, and return them
2337 as a list in the following format:
2338 @example
2339 '((grob prop-name)
2340   (grob prop-name)
2341   ...)
2342 @end example"
2343   (define (find-grobs-with-interface interface grob-descriptions)
2344     (define (has-this-interface? grob-desc)
2345       (let* ((meta (ly:assoc-get 'meta (cdr grob-desc)))
2346              (interfaces (ly:assoc-get 'interfaces meta '())))
2347         (memq interface interfaces)))
2348     (let* ((grob-descriptions-with-this-interface
2349              (filter has-this-interface? grob-descriptions))
2350            (grob-names-with-this-interface
2351              (map car grob-descriptions-with-this-interface)))
2352       grob-names-with-this-interface))
2353   (let* ((interface
2354            (case prop-name
2355              ((baseline-skip word-space) 'text-interface)
2356              ((space-alist)              'break-aligned-interface)
2357              (else (ly:programming-error
2358                      "find-named-props: no interface associated with ~s"
2359                      prop-name))))
2360          (grobs-with-this-prop
2361            (find-grobs-with-interface interface grob-descriptions)))
2362     (map (lambda (x) (list x prop-name))
2363          grobs-with-this-prop)))
2364
2365
2366 (define (magnifyStaff-is-set? context mag)
2367   (let* ((Staff (ly:context-find context 'Staff))
2368          (old-mag (ly:context-property Staff 'magnifyStaffValue)))
2369     (not (null? old-mag))))
2370
2371 (define (staff-magnification-is-changing? context mag)
2372   (let* ((Staff (ly:context-find context 'Staff))
2373          (old-mag (ly:context-property Staff 'magnifyStaffValue 1)))
2374     (not (= old-mag mag))))
2375
2376 (define-public (scale-fontSize func-name mag)
2377   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Look up the
2378 current @code{fontSize} in the appropriate context and scale it by the
2379 magnification factor @var{mag}.  @var{func-name} is either
2380 @code{'magnifyMusic} or @code{'magnifyStaff}."
2381   (make-apply-context
2382     (lambda (context)
2383       (if (or (eq? func-name 'magnifyMusic)
2384               ;; for \magnifyStaff, only scale the fontSize
2385               ;; if staff magnification is changing
2386               ;; and does not equal 1
2387               (and (staff-magnification-is-changing? context mag)
2388                    (not (= mag 1))))
2389         (let* ((where (case func-name
2390                         ((magnifyMusic) context)
2391                         ((magnifyStaff) (ly:context-find context 'Staff))))
2392                (fontSize (ly:context-property where 'fontSize 0))
2393                (new-fontSize (+ fontSize (magnification->font-size mag))))
2394           (ly:context-set-property! where 'fontSize new-fontSize))))))
2395
2396 (define-public (revert-fontSize func-name mag)
2397   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Calculate
2398 the previous @code{fontSize} value (before scaling) by factoring out the
2399 magnification factor @var{mag} (if @var{func-name} is
2400 @code{'magnifyMusic}), or by factoring out the context property
2401 @code{magnifyStaffValue} (if @var{func-name} is @code{'magnifyStaff}).
2402 Revert the @code{fontSize} in the appropriate context accordingly.
2403
2404 With @code{\\magnifyMusic}, the scaling is reverted after the music
2405 block it operates on.  @code{\\magnifyStaff} does not operate on a music
2406 block, so the scaling from a previous call (if there is one) is reverted
2407 before the new scaling takes effect."
2408   (make-apply-context
2409     (lambda (context)
2410       (if (or (eq? func-name 'magnifyMusic)
2411               ;; for \magnifyStaff...
2412               (and
2413                 ;; don't revert the user's fontSize choice
2414                 ;; the first time \magnifyStaff is called
2415                 (magnifyStaff-is-set? context mag)
2416                 ;; only revert the previous fontSize
2417                 ;; if staff magnification is changing
2418                 (staff-magnification-is-changing? context mag)))
2419         (let* ((where
2420                  (case func-name
2421                    ((magnifyMusic) context)
2422                    ((magnifyStaff) (ly:context-find context 'Staff))))
2423                (old-mag
2424                  (case func-name
2425                    ((magnifyMusic) mag)
2426                    ((magnifyStaff)
2427                     (ly:context-property where 'magnifyStaffValue 1))))
2428                (fontSize (ly:context-property where 'fontSize 0))
2429                (old-fontSize (- fontSize (magnification->font-size old-mag))))
2430           (ly:context-set-property! where 'fontSize old-fontSize))))))
2431
2432 (define-public (scale-props func-name mag allowed-to-shrink? props)
2433   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  For each
2434 prop in @var{props}, find the current value of the requested prop, scale
2435 it by the magnification factor @var{mag}, and do the equivalent of a
2436 @code{\\temporary@tie{}\\override} with the new value in the appropriate
2437 context.  If @var{allowed-to-shrink?} is @code{#f}, don't let the new
2438 value be less than the current value.  @var{func-name} is either
2439 @code{'magnifyMusic} or @code{'magnifyStaff}.  The @var{props} list is
2440 formatted like:
2441 @example
2442 '((Stem thickness)
2443   (Slur line-thickness)
2444   ...)
2445 @end example"
2446   (make-apply-context
2447     (lambda (context)
2448       (define (scale-prop grob-prop-list)
2449         (let* ((grob (car grob-prop-list))
2450                (prop (cadr grob-prop-list))
2451                (where (if (eq? grob 'SpacingSpanner)
2452                         (ly:context-find context 'Score)
2453                         (case func-name
2454                           ((magnifyMusic) context)
2455                           ((magnifyStaff) (ly:context-find context 'Staff)))))
2456                (grob-def (ly:context-grob-definition where grob)))
2457           (if (eq? prop 'space-alist)
2458             (let* ((space-alist (ly:assoc-get prop grob-def))
2459                    (scale-spacing-tuple (lambda (x)
2460                                           (cons (car x)
2461                                                 (cons (cadr x)
2462                                                       (* mag (cddr x))))))
2463                    (scaled-tuples (if space-alist
2464                                       (map scale-spacing-tuple space-alist)
2465                                       '()))
2466                    (new-alist (append scaled-tuples space-alist)))
2467               (ly:context-pushpop-property where grob prop new-alist))
2468             (let* ((val (ly:assoc-get prop grob-def (case prop
2469                                                       ((baseline-skip) 3)
2470                                                       ((word-space)    0.6)
2471                                                       (else            1))))
2472                    (proc (lambda (x)
2473                            (if allowed-to-shrink?
2474                              (* x mag)
2475                              (* x (max 1 mag)))))
2476                    (new-val (if (number-pair? val)
2477                               (cons (proc (car val))
2478                                     (proc (cdr val)))
2479                               (proc val))))
2480               (ly:context-pushpop-property where grob prop new-val)))))
2481       (if (or (eq? func-name 'magnifyMusic)
2482               ;; for \magnifyStaff, only scale the properties
2483               ;; if staff magnification is changing
2484               ;; and does not equal 1
2485               (and (staff-magnification-is-changing? context mag)
2486                    (not (= mag 1))))
2487         (for-each scale-prop props)))))
2488
2489 (define-public (revert-props func-name mag props)
2490   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Revert each
2491 prop in @var{props} in the appropriate context.  @var{func-name} is
2492 either @code{'magnifyMusic} or @code{'magnifyStaff}.  The @var{props}
2493 list is formatted like:
2494 @example
2495 '((Stem thickness)
2496   (Slur line-thickness)
2497   ...)
2498 @end example"
2499   (make-apply-context
2500     (lambda (context)
2501       (define (revert-prop grob-prop-list)
2502         (let* ((grob (car grob-prop-list))
2503                (prop (cadr grob-prop-list))
2504                (where (if (eq? grob 'SpacingSpanner)
2505                         (ly:context-find context 'Score)
2506                         (case func-name
2507                           ((magnifyMusic) context)
2508                           ((magnifyStaff) (ly:context-find context 'Staff))))))
2509           (ly:context-pushpop-property where grob prop)))
2510       (if (or (eq? func-name 'magnifyMusic)
2511               ;; for \magnifyStaff...
2512               (and
2513                 ;; don't revert the user's property overrides
2514                 ;; the first time \magnifyStaff is called
2515                 (magnifyStaff-is-set? context mag)
2516                 ;; revert the overrides from the previous \magnifyStaff,
2517                 ;; but only if staff magnification is changing
2518                 (staff-magnification-is-changing? context mag)))
2519         (for-each revert-prop props)))))
2520
2521 ;; \magnifyMusic only
2522 (define-public (scale-beam-thickness mag)
2523   "Used by @code{\\magnifyMusic}.  Scaling @code{Beam.beam-thickness}
2524 exactly to the @var{mag} value will not work.  This uses two reference
2525 values for @code{beam-thickness} to determine an acceptable value when
2526 scaling, then does the equivalent of a
2527 @code{\\temporary@tie{}\\override} with the new value."
2528   (make-apply-context
2529     (lambda (context)
2530       (let* ((grob-def (ly:context-grob-definition context 'Beam))
2531              (val (ly:assoc-get 'beam-thickness grob-def 0.48))
2532              (ratio-to-default (/ val 0.48))
2533              ;; gives beam-thickness=0.48 when mag=1 (like default),
2534              ;; gives beam-thickness=0.35 when mag=0.63 (like CueVoice)
2535              (scaled-default (+ 119/925 (* mag 13/37)))
2536              (new-val (* scaled-default ratio-to-default)))
2537         (ly:context-pushpop-property context 'Beam 'beam-thickness new-val)))))
2538
2539 ;; tag management
2540 ;;
2541
2542 (define tag-groups (make-hash-table))
2543 (call-after-session (lambda () (hash-clear! tag-groups)))
2544
2545 (define-public (define-tag-group tags)
2546   "Define a tag-group consisting of the given @var{tags}, a@tie{}list
2547 of symbols.  Returns @code{#f} if successful, and an error message if
2548 there is a conflicting tag group definition."
2549   (cond ((not (symbol-list? tags)) (format #f (_ "not a symbol list: ~a") tags))
2550         ((any (lambda (tag) (hashq-ref tag-groups tag)) tags)
2551          => (lambda (group) (and (not (lset= eq? group tags))
2552                                  (format #f (_ "conflicting tag group ~a") group))))
2553         (else
2554          (for-each
2555           (lambda (elt) (hashq-set! tag-groups elt tags))
2556           tags)
2557          #f)))
2558
2559 (define-public (tag-group-get tag)
2560   "Return the tag group (as a list of symbols) that the given
2561 @var{tag} symbol belongs to, @code{#f} if none."
2562   (hashq-ref tag-groups tag))
2563
2564 (define-public (tags-remove-predicate tags)
2565   "Returns a predicate that returns @code{#f} for any music that is to
2566 be removed by @{\\removeWithTag} on the given symbol or list of
2567 symbols @var{tags}."
2568   (if (symbol? tags)
2569       (lambda (m)
2570         (not (memq tags (ly:music-property m 'tags))))
2571       (lambda (m)
2572         (not (any (lambda (t) (memq t tags))
2573                   (ly:music-property m 'tags))))))
2574
2575 (define-public (tags-keep-predicate tags)
2576   "Returns a predicate that returns @code{#f} for any music that is to
2577 be removed by @{\\keepWithTag} on the given symbol or list of symbols
2578 @var{tags}."
2579   (if (symbol? tags)
2580       (let ((group (tag-group-get tags)))
2581         (lambda (m)
2582           (let ((music-tags (ly:music-property m 'tags)))
2583             (or
2584              (null? music-tags) ; redundant but very frequent
2585              ;; We know of only one tag to keep.  Either we find it in
2586              ;; the music tags, or all music tags must be from a
2587              ;; different group
2588              (memq tags music-tags)
2589              (not (any (lambda (t) (eq? (tag-group-get t) group)) music-tags))))))
2590       (let ((groups (delete-duplicates (map tag-group-get tags) eq?)))
2591         (lambda (m)
2592           (let ((music-tags (ly:music-property m 'tags)))
2593             (or
2594              (null? music-tags) ; redundant but very frequent
2595              (any (lambda (t) (memq t tags)) music-tags)
2596              ;; if no tag matches, no tag group should match either
2597              (not (any (lambda (t) (memq (tag-group-get t) groups)) music-tags))))))))