scm/music-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2015 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; for define-safe-public when byte-compiling using Guile V2
  20 (use-modules (scm safe-utility-defs))
  21
  22 (use-modules (ice-9 optargs))
  23 (use-modules (srfi srfi-11))
  24
  25 ;;; ly:music-property with setter
  26 ;;; (ly:music-property my-music 'elements)
  27 ;;;   ==> the 'elements property
  28 ;;; (set! (ly:music-property my-music 'elements) value)
  29 ;;;   ==> set the 'elements property and return it
  30 (define-public ly:music-property
  31   (make-procedure-with-setter ly:music-property
  32                               ly:music-set-property!))
  33
  34 (define-safe-public (music-is-of-type? mus type)
  35   "Does @code{mus} belong to the music class @code{type}?"
  36   (memq type (ly:music-property mus 'types)))
  37
  38 ;; TODO move this
  39 (define-public ly:grob-property
  40   (make-procedure-with-setter ly:grob-property
  41                               ly:grob-set-property!))
  42
  43 (define-public ly:grob-object
  44   (make-procedure-with-setter ly:grob-object
  45                               ly:grob-set-object!))
  46
  47 (define-public ly:grob-parent
  48   (make-procedure-with-setter ly:grob-parent
  49                               ly:grob-set-parent!))
  50
  51 (define-public ly:prob-property
  52   (make-procedure-with-setter ly:prob-property
  53                               ly:prob-set-property!))
  54
  55 (define-public ly:context-property
  56   (make-procedure-with-setter ly:context-property
  57                               ly:context-set-property!))
  58
  59 (define-public (music-map function music)
  60   "Apply @var{function} to @var{music} and all of the music it contains.
  61
  62 First it recurses over the children, then the function is applied to
  63 @var{music}."
  64   (let ((es (ly:music-property music 'elements))
  65         (e (ly:music-property music 'element)))
  66     (if (pair? es)
  67         (set! (ly:music-property music 'elements)
  68               (map (lambda (y) (music-map function y)) es)))
  69     (if (ly:music? e)
  70         (set! (ly:music-property music 'element)
  71               (music-map function  e)))
  72     (function music)))
  73
  74 (define-public (music-filter pred? music)
  75   "Filter out music expressions that do not satisfy @var{pred?}."
  76
  77   (define (inner-music-filter pred? music)
  78     "Recursive function."
  79     (let* ((es (ly:music-property music 'elements))
  80            (e (ly:music-property music 'element))
  81            (as (ly:music-property music 'articulations))
  82            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  83            (filtered-e (if (ly:music? e)
  84                            (inner-music-filter pred? e)
  85                            e))
  86            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  87       (if (not (null? e))
  88           (set! (ly:music-property music 'element) filtered-e))
  89       (if (not (null? es))
  90           (set! (ly:music-property music 'elements) filtered-es))
  91       (if (not (null? as))
  92           (set! (ly:music-property music 'articulations) filtered-as))
  93       ;; if filtering emptied the expression, we remove it completely.
  94       (if (or (not (pred? music))
  95               (and (eq? filtered-es '()) (not (ly:music? e))
  96                    (or (not (eq? es '()))
  97                        (ly:music? e))))
  98           (set! music '()))
  99       music))
 100
 101   (set! music (inner-music-filter pred? music))
 102   (if (ly:music? music)
 103       music
 104       (make-music 'Music)))       ;must return music.
 105
 106 (define*-public (display-music music #:optional (port (current-output-port)))
 107   "Display music, not done with @code{music-map} for clarity of
 108 presentation."
 109   (display music port)
 110   (display ": { " port)
 111   (let ((es (ly:music-property music 'elements))
 112         (e (ly:music-property music 'element)))
 113     (display (ly:music-mutable-properties music) port)
 114     (if (pair? es)
 115         (begin (display "\nElements: {\n" port)
 116                (for-each (lambda (m) (display-music m port)) es)
 117                (display "}\n" port)))
 118     (if (ly:music? e)
 119         (begin
 120           (display "\nChild:" port)
 121           (display-music e port))))
 122   (display " }\n" port)
 123   music)
 124
 125 ;;;
 126 ;;; A scheme music pretty printer
 127 ;;;
 128 (define (markup-expression->make-markup markup-expression)
 129   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
 130 For instance,
 131   \\markup \\bold \\italic hello
 132 ==>
 133   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 134   (define (proc->command-keyword proc)
 135     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 136     (let ((cmd-markup (symbol->string (procedure-name proc))))
 137       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 138                                                                   (string-length "-markup")))))))
 139   (define (transform-arg arg)
 140     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 141            (append-map inner-markup->make-markup arg))
 142           ((and (not (string? arg)) (markup? arg)) ;; a markup
 143            (inner-markup->make-markup arg))
 144           (else                                  ;; scheme arg
 145            (music->make-music arg))))
 146   (define (inner-markup->make-markup mrkup)
 147     (if (string? mrkup)
 148         `(#:simple ,mrkup)
 149         (let ((cmd (proc->command-keyword (car mrkup)))
 150               (args (map transform-arg (cdr mrkup))))
 151           `(,cmd ,@args))))
 152   ;; body:
 153   (if (string? markup-expression)
 154       markup-expression
 155       `(markup ,@(inner-markup->make-markup markup-expression))))
 156
 157 (define-public (music->make-music obj)
 158   "Generate an expression that, once evaluated, may return an object
 159 equivalent to @var{obj}, that is, for a music expression, a
 160 @code{(make-music ...)} form."
 161   (define (if-nonzero num)
 162     (if (zero? num) '() (list num)))
 163   (cond (;; markup expression
 164          (markup? obj)
 165          (markup-expression->make-markup obj))
 166         (;; music expression
 167          (ly:music? obj)
 168          `(make-music
 169            ',(ly:music-property obj 'name)
 170            ,@(append-map (lambda (prop)
 171                            `(',(car prop)
 172                              ,(music->make-music (cdr prop))))
 173                          (remove (lambda (prop)
 174                                    (eqv? (car prop) 'origin))
 175                                  (ly:music-mutable-properties obj)))))
 176         (;; moment
 177          (ly:moment? obj)
 178          `(ly:make-moment
 179            ,@(let ((main (ly:moment-main obj))
 180                    (grace (ly:moment-grace obj)))
 181                (cond ((zero? grace) (list main))
 182                      ((negative? grace) (list main grace))
 183                      (else ;;positive grace requires 4-arg form
 184                       (list (numerator main)
 185                             (denominator main)
 186                             (numerator grace)
 187                             (denominator grace)))))))
 188         (;; note duration
 189          (ly:duration? obj)
 190          `(ly:make-duration ,(ly:duration-log obj)
 191                             ,@(if (= (ly:duration-scale obj) 1)
 192                                   (if-nonzero (ly:duration-dot-count obj))
 193                                   (list (ly:duration-dot-count obj)
 194                                         (ly:duration-scale obj)))))
 195         (;; note pitch
 196          (ly:pitch? obj)
 197          `(ly:make-pitch ,(ly:pitch-octave obj)
 198                          ,(ly:pitch-notename obj)
 199                          ,@(if-nonzero (ly:pitch-alteration obj))))
 200         (;; scheme procedure
 201          (procedure? obj)
 202          (or (procedure-name obj) obj))
 203         (;; a symbol (avoid having an unquoted symbol)
 204          (symbol? obj)
 205          `',obj)
 206         (;; an empty list (avoid having an unquoted empty list)
 207          (null? obj)
 208          `'())
 209         (;; a proper list
 210          (list? obj)
 211          `(list ,@(map music->make-music obj)))
 212         (;; a pair
 213          (pair? obj)
 214          `(cons ,(music->make-music (car obj))
 215                 ,(music->make-music (cdr obj))))
 216         (else
 217          obj)))
 218
 219 (use-modules (ice-9 pretty-print))
 220 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 221   "Displays `obj', typically a music expression, in a friendly fashion,
 222 which often can be read back in order to generate an equivalent expression."
 223   (pretty-print (music->make-music obj) port)
 224   (newline port))
 225
 226 ;;;
 227 ;;; Scheme music expression --> Lily-syntax-using string translator
 228 ;;;
 229 (use-modules (srfi srfi-39)
 230              (scm display-lily))
 231
 232 (define*-public (display-lily-music expr #:optional (port (current-output-port))
 233                                     #:key force-duration)
 234   "Display the music expression using LilyPond syntax"
 235   (memoize-clef-names supported-clefs)
 236   (parameterize ((*indent* 0)
 237                  (*omit-duration* #f))
 238                 (display (music->lily-string expr) port)
 239                 (newline port)))
 240
 241 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 242
 243 (define-public (shift-one-duration-log music shift dot)
 244   "Add @var{shift} to @code{duration-log} of @code{'duration} in
 245 @var{music} and optionally @var{dot} to any note encountered.
 246 The number of dots in the shifted music may not be less than zero."
 247   (let ((d (ly:music-property music 'duration)))
 248     (if (ly:duration? d)
 249         (let* ((cp (ly:duration-scale d))
 250                (nd (ly:make-duration
 251                     (+ shift (ly:duration-log d))
 252                     (max 0 (+ dot (ly:duration-dot-count d)))
 253                     cp)))
 254           (set! (ly:music-property music 'duration) nd)))
 255     ;clear cached length, since it's no longer valid
 256     (set! (ly:music-property music 'length) '())
 257     music))
 258
 259 (define-public (shift-duration-log music shift dot)
 260   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 261              music))
 262
 263 (define-public (tremolo::get-music-list tremolo)
 264   "Given a tremolo repeat, return a list of music to engrave for it.
 265 This will be a stretched copy of its body, plus a TremoloEvent or
 266 TremoloSpanEvent.
 267
 268 This is called only by Chord_tremolo_iterator."
 269   (define (first-note-duration music)
 270     "Finds the duration of the first NoteEvent by searching
 271 depth-first through MUSIC."
 272     ;; NoteEvent or a non-expanded chord-repetition
 273     ;; We just take anything that actually sports an announced duration.
 274     (if (ly:duration? (ly:music-property music 'duration))
 275         (ly:music-property music 'duration)
 276         (let loop ((elts (if (ly:music? (ly:music-property music 'element))
 277                              (list (ly:music-property music 'element))
 278                              (ly:music-property music 'elements))))
 279           (and (pair? elts)
 280                (let ((dur (first-note-duration (car elts))))
 281                  (if (ly:duration? dur)
 282                      dur
 283                      (loop (cdr elts))))))))
 284   (let* ((times (ly:music-property tremolo 'repeat-count))
 285          (body (ly:music-property tremolo 'element))
 286          (children (if (music-is-of-type? body 'sequential-music)
 287                        ;; \repeat tremolo n { ... }
 288                        (count duration-of-note ; do not count empty <>
 289                               (extract-named-music body
 290                                                    '(EventChord NoteEvent)))
 291                        ;; \repeat tremolo n c4
 292                        1))
 293          (tremolo-type (if (positive? children)
 294                            (let* ((note-duration (first-note-duration body))
 295                                   (duration-log (if (ly:duration? note-duration)
 296                                                     (ly:duration-log note-duration)
 297                                                     1)))
 298                              (ash 1 duration-log))
 299                            '()))
 300          (stretched (ly:music-deep-copy body)))
 301     (if (positive? children)
 302         ;; # of dots is equal to the 1 in bitwise representation (minus 1)!
 303         (let* ((dots (1- (logcount (* times children))))
 304                ;; The remaining missing multiplier to scale the notes by
 305                ;; times * children
 306                (mult (/ (* times children (ash 1 dots)) (1- (ash 2 dots))))
 307                (shift (- (ly:intlog2 (floor mult)))))
 308           (if (not (and (integer? mult) (= (logcount mult) 1)))
 309               (ly:music-warning
 310                body
 311                (ly:format (_ "invalid tremolo repeat count: ~a") times)))
 312           ;; Make each note take the full duration
 313           (ly:music-compress stretched (ly:make-moment 1 children))
 314           ;; Adjust the displayed note durations
 315           (shift-duration-log stretched shift dots)))
 316     ;; Return the stretched body plus a tremolo event
 317     (if (= children 1)
 318         (list (make-music 'TremoloEvent
 319                           'repeat-count times
 320                           'tremolo-type tremolo-type
 321                           'origin (ly:music-property tremolo 'origin))
 322               stretched)
 323         (list (make-music 'TremoloSpanEvent
 324                           'span-direction START
 325                           'repeat-count times
 326                           'tremolo-type tremolo-type
 327                           'origin (ly:music-property tremolo 'origin))
 328               stretched
 329               (make-music 'TremoloSpanEvent
 330                           'span-direction STOP
 331                           'origin (ly:music-property tremolo 'origin))))))
 332
 333 (define-public (make-repeat name times main alts)
 334   "Create a repeat music expression, with all properties initialized
 335 properly."
 336   (let ((type (or (assoc-get name '(("volta" . VoltaRepeatedMusic)
 337                                     ("unfold" . UnfoldedRepeatedMusic)
 338                                     ("percent" . PercentRepeatedMusic)
 339                                     ("tremolo" . TremoloRepeatedMusic)))
 340                   (begin (ly:warning (_ "unknown repeat type `~S': must be volta, unfold, percent, or tremolo") name)
 341                          'VoltaRepeatedMusic)))
 342         (talts (if (< times (length alts))
 343                    (begin
 344                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 345                      (take alts times))
 346                    alts)))
 347     (make-music type
 348                 'element main
 349                 'repeat-count (max times 1)
 350                 'elements talts)))
 351
 352 (define (calc-repeat-slash-count music)
 353   "Given the child-list @var{music} in @code{PercentRepeatMusic},
 354 calculate the number of slashes based on the durations.  Returns @code{0}
 355 if durations in @var{music} vary, allowing slash beats and double-percent
 356 beats to be distinguished."
 357   (let* ((durs (map duration-of-note
 358                     (extract-named-music music '(EventChord NoteEvent
 359                                                             RestEvent SkipEvent))))
 360          (first-dur (car durs)))
 361
 362     (if (every (lambda (d) (equal? d first-dur)) durs)
 363         (max (- (ly:duration-log first-dur) 2) 1)
 364         0)))
 365
 366 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 367 ;; clusters.
 368
 369 (define-public (note-to-cluster music)
 370   "Replace @code{NoteEvents} by @code{ClusterNoteEvents}."
 371   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 372       (make-music 'ClusterNoteEvent
 373                   'pitch (ly:music-property music 'pitch)
 374                   'duration (ly:music-property music 'duration))
 375       music))
 376
 377 (define-public (notes-to-clusters music)
 378   (music-map note-to-cluster music))
 379
 380 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 381 ;; repeats.
 382
 383 (define-public (unfold-repeats music)
 384   "Replace all repeats with unfolded repeats."
 385   (let ((es (ly:music-property music 'elements))
 386         (e (ly:music-property music 'element)))
 387     (if (music-is-of-type? music 'repeated-music)
 388         (set! music (make-music 'UnfoldedRepeatedMusic music)))
 389     (if (pair? es)
 390         (set! (ly:music-property music 'elements)
 391               (map unfold-repeats es)))
 392     (if (ly:music? e)
 393         (set! (ly:music-property music 'element)
 394               (unfold-repeats e)))
 395     music))
 396
 397 (define-public (unfold-repeats-fully music)
 398   "Unfolds repeats and expands the resulting @code{unfolded-repeated-music}."
 399   (map-some-music
 400    (lambda (m)
 401      (and (music-is-of-type? m 'unfolded-repeated-music)
 402           (make-sequential-music
 403            (ly:music-deep-copy (make-unfolded-set m)))))
 404    (unfold-repeats music)))
 405
 406 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 407 ;; property setting music objs.
 408
 409 (define-safe-public (check-grob-path path #:optional location
 410                                      #:key
 411                                      (start 0)
 412                                      default
 413                                      (min 1)
 414                                      max)
 415   "Check a grob path specification @var{path}, a symbol list (or a
 416 single symbol), for validity and possibly complete it.  Returns the
 417 completed specification, or @code{#f} if invalid.  If optional
 418 @var{parser} is given, a syntax error is raised in that case,
 419 optionally using @var{location}.  If an optional keyword argument
 420 @code{#:start @var{start}} is given, the parsing starts at the given
 421 index in the sequence @samp{Context.Grob.property.sub-property...},
 422 with the default of @samp{0} implying the full path.
 423
 424 If there is no valid first element of @var{path} fitting at the given
 425 path location, an optionally given @code{#:default @var{default}} is
 426 used as the respective element instead without checking it for
 427 validity at this position.
 428
 429 The resulting path after possibly prepending @var{default} can be
 430 constrained in length by optional arguments @code{#:min @var{min}} and
 431 @code{#:max @var{max}}, defaulting to @samp{1} and unlimited,
 432 respectively."
 433   (let ((path (if (symbol? path) (list path) path)))
 434     ;; A Guile 1.x bug specific to optargs precludes moving the
 435     ;; defines out of the let
 436     (define (unspecial? s)
 437       (not (or (object-property s 'is-grob?)
 438                (object-property s 'backend-type?))))
 439     (define (grob? s)
 440       (object-property s 'is-grob?))
 441     (define (property? s)
 442       (object-property s 'backend-type?))
 443     (define (check c p) (c p))
 444
 445     (let* ((checkers
 446             (and (< start 3)
 447                  (drop (list unspecial? grob? property?) start)))
 448            (res
 449             (cond
 450              ((null? path)
 451               ;; tricky.  Should we make use of the default when the
 452               ;; list is empty?  In most cases, this question should be
 453               ;; academical as an empty list can only be generated by
 454               ;; Scheme and is likely an error.  We consider this a case
 455               ;; of "no valid first element, and default given".
 456               ;; Usually, invalid use cases should be caught later using
 457               ;; the #:min argument, and if the user explicitly does not
 458               ;; catch this, we just follow through.
 459               (if default (list default) '()))
 460              ((not checkers)
 461               ;; no checkers, so we have a valid first element and just
 462               ;; take the path as-is.
 463               path)
 464              (default
 465                (if ((car checkers) (car path))
 466                    (and (every check (cdr checkers) (cdr path))
 467                         path)
 468                    (and (every check (cdr checkers) path)
 469                         (cons default path))))
 470              (else
 471               (and (every check checkers path)
 472                    path)))))
 473       (if (and res
 474                (if max (<= min (length res) max)
 475                    (<= min (length res))))
 476           res
 477           (begin
 478             (ly:parser-error
 479              (format #f (_ "bad grob property path ~a")
 480                      path)
 481              location)
 482             #f)))))
 483
 484 (define-safe-public (check-context-path path #:optional location)
 485   "Check a context property path specification @var{path}, a symbol
 486 list (or a single symbol), for validity and possibly complete it.
 487 Returns the completed specification, or @code{#f} when rising an
 488 error (using optionally @code{location})."
 489   (let* ((path (if (symbol? path) (list path) path)))
 490     ;; A Guile 1.x bug specific to optargs precludes moving the
 491     ;; defines out of the let
 492     (define (property? s)
 493       (object-property s 'translation-type?))
 494     (define (unspecial? s)
 495       (not (property? s)))
 496     (define (check c p) (c p))
 497     (or (case (length path)
 498           ((1) (and (property? (car path)) (cons 'Bottom path)))
 499           ((2) (and (unspecial? (car path)) (property? (cadr path)) path))
 500           (else #f))
 501         (begin
 502           (ly:parser-error
 503            (format #f (_ "bad context property ~a")
 504                    path)
 505            location)
 506           #f))))
 507
 508 (define-public (make-grob-property-set grob gprop val)
 509   "Make a @code{Music} expression that sets @var{gprop} to @var{val} in
 510 @var{grob}.  Does a pop first, i.e., this is not an override."
 511   (make-music 'OverrideProperty
 512               'symbol grob
 513               'grob-property gprop
 514               'grob-value val
 515               'pop-first #t))
 516
 517 (define-public (make-grob-property-override grob gprop val)
 518   "Make a @code{Music} expression that overrides @var{gprop} to @var{val}
 519 in @var{grob}."
 520   (make-music 'OverrideProperty
 521               'symbol grob
 522               'grob-property gprop
 523               'grob-value val))
 524
 525 (define-public (make-grob-property-revert grob gprop)
 526   "Revert the grob property @var{gprop} for @var{grob}."
 527   (make-music 'RevertProperty
 528               'symbol grob
 529               'grob-property gprop))
 530
 531 (define direction-polyphonic-grobs
 532   '(AccidentalSuggestion
 533     DotColumn
 534     Dots
 535     Fingering
 536     LaissezVibrerTie
 537     LigatureBracket
 538     MultiMeasureRest
 539     PhrasingSlur
 540     RepeatTie
 541     Rest
 542     Script
 543     Slur
 544     Stem
 545     TextScript
 546     Tie
 547     TupletBracket
 548     TrillSpanner))
 549
 550 (define general-grace-settings
 551   `((Voice Stem font-size -3)
 552     (Voice Flag font-size -3)
 553     (Voice NoteHead font-size -3)
 554     (Voice TabNoteHead font-size -4)
 555     (Voice Dots font-size -3)
 556     (Voice Stem length-fraction 0.8)
 557     (Voice Stem no-stem-extend #t)
 558     (Voice Beam beam-thickness 0.384)
 559     (Voice Beam length-fraction 0.8)
 560     (Voice Accidental font-size -4)
 561     (Voice AccidentalCautionary font-size -4)
 562     (Voice Script font-size -3)
 563     (Voice Fingering font-size -8)
 564     (Voice StringNumber font-size -8)))
 565
 566 (define-public score-grace-settings
 567   (append
 568     `((Voice Stem direction ,UP)
 569       (Voice Slur direction ,DOWN))
 570     general-grace-settings))
 571
 572 ;; Getting a unique context id name
 573
 574 (define-session unique-counter -1)
 575 (define-safe-public (get-next-unique-voice-name)
 576   (set! unique-counter (1+ unique-counter))
 577   (format #f "uniqueContext~s" unique-counter))
 578
 579
 580 (define-safe-public (make-voice-props-set n)
 581   (make-sequential-music
 582    (append
 583     (map (lambda (x) (make-grob-property-set x 'direction
 584                                              (if (odd? n) -1 1)))
 585          direction-polyphonic-grobs)
 586     (list
 587      (make-property-set 'graceSettings general-grace-settings)
 588      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))))))
 589
 590 (define-safe-public (make-voice-props-override n)
 591   (make-sequential-music
 592    (append
 593     (map (lambda (x) (make-grob-property-override x 'direction
 594                                                   (if (odd? n) -1 1)))
 595          direction-polyphonic-grobs)
 596     (list
 597      (make-property-set 'graceSettings general-grace-settings)
 598      (make-grob-property-override 'NoteColumn 'horizontal-shift (quotient n 2))))))
 599
 600 (define-safe-public (make-voice-props-revert)
 601   (make-sequential-music
 602    (append
 603     (map (lambda (x) (make-grob-property-revert x 'direction))
 604          direction-polyphonic-grobs)
 605     (list (make-property-unset 'graceSettings)
 606           (make-grob-property-revert 'NoteColumn 'horizontal-shift)))))
 607
 608
 609 (define-safe-public (context-spec-music m context #:optional id)
 610   "Add \\context CONTEXT = ID to M."
 611   (let ((cm (make-music 'ContextSpeccedMusic
 612                         'element m
 613                         'context-type context)))
 614     (if (string? id)
 615         (set! (ly:music-property cm 'context-id) id))
 616     cm))
 617
 618 (define-public (descend-to-context m context)
 619   "Like @code{context-spec-music}, but only descending."
 620   (let ((cm (context-spec-music m context)))
 621     (ly:music-set-property! cm 'descend-only #t)
 622     cm))
 623
 624 (define-public (make-non-relative-music mus)
 625   (make-music 'UnrelativableMusic
 626               'element mus))
 627
 628 (define-public (make-apply-context func)
 629   (make-music 'ApplyContext
 630               'procedure func))
 631
 632 (define-public (make-sequential-music elts)
 633   (make-music 'SequentialMusic
 634               'elements elts))
 635
 636 (define-public (make-simultaneous-music elts)
 637   (make-music 'SimultaneousMusic
 638               'elements elts))
 639
 640 (define-safe-public (make-event-chord elts)
 641   (make-music 'EventChord
 642               'elements elts))
 643
 644 (define-public (make-skip-music dur)
 645   (make-music 'SkipMusic
 646               'duration dur))
 647
 648 (define-public (make-grace-music music)
 649   (make-music 'GraceMusic
 650               'element music))
 651
 652 ;;;;;;;;;;;;;;;;
 653
 654 ;; mmrest
 655 (define-public (make-multi-measure-rest duration location)
 656   (make-music 'MultiMeasureRestMusic
 657               'origin location
 658               'duration duration))
 659
 660 (define-public (make-property-set sym val)
 661   (make-music 'PropertySet
 662               'symbol sym
 663               'value val))
 664
 665 (define-public (make-property-unset sym)
 666   (make-music 'PropertyUnset
 667               'symbol sym))
 668
 669 (define-safe-public (make-articulation name . properties)
 670   (apply make-music 'ArticulationEvent
 671          'articulation-type name
 672          properties))
 673
 674 (define-public (make-lyric-event string duration)
 675   (make-music 'LyricEvent
 676               'duration duration
 677               'text string))
 678
 679 (define-safe-public (make-span-event type span-dir)
 680   (make-music type
 681               'span-direction span-dir))
 682
 683 (define-public (override-head-style heads style)
 684   "Override style for @var{heads} to @var{style}."
 685   (make-sequential-music
 686    (if (pair? heads)
 687        (map (lambda (h)
 688               (make-grob-property-override h 'style style))
 689             heads)
 690        (list (make-grob-property-override heads 'style style)))))
 691
 692 (define-public (revert-head-style heads)
 693   "Revert style for @var{heads}."
 694   (make-sequential-music
 695    (if (pair? heads)
 696        (map (lambda (h)
 697               (make-grob-property-revert h 'style))
 698             heads)
 699        (list (make-grob-property-revert heads 'style)))))
 700
 701 (define-public (style-note-heads heads style music)
 702   "Set @var{style} for all @var{heads} in @var{music}.  Works both
 703 inside of and outside of chord construct."
 704   ;; are we inside a <...>?
 705   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 706       ;; yes -> use a tweak
 707       (begin
 708         (set! (ly:music-property music 'tweaks)
 709               (acons 'style style (ly:music-property music 'tweaks)))
 710         music)
 711       ;; not in <...>, so use overrides
 712       (make-sequential-music
 713        (list
 714         (override-head-style heads style)
 715         music
 716         (revert-head-style heads)))))
 717
 718 (define-public (set-mus-properties! m alist)
 719   "Set all of @var{alist} as properties of @var{m}."
 720   (if (pair? alist)
 721       (begin
 722         (set! (ly:music-property m (caar alist)) (cdar alist))
 723         (set-mus-properties! m (cdr alist)))))
 724
 725 (define-public (music-separator? m)
 726   "Is @var{m} a separator?"
 727   (let ((ts (ly:music-property m 'types)))
 728     (memq 'separator ts)))
 729
 730 ;;; expanding repeat chords
 731 (define-public (copy-repeat-chord original-chord repeat-chord duration
 732                                   event-types)
 733   "Copies all events in @var{event-types} (be sure to include
 734 @code{rhythmic-events}) from @var{original-chord} over to
 735 @var{repeat-chord} with their articulations filtered as well.  Any
 736 duration is replaced with the specified @var{duration}."
 737   ;; First remove everything from event-types that can already be
 738   ;; found in the repeated chord.  We don't need to look for
 739   ;; articulations on individual events since they can't actually get
 740   ;; into a repeat chord given its input syntax.
 741
 742   (define (keep-element? m)
 743     (any (lambda (t) (music-is-of-type? m t))
 744          event-types))
 745
 746   (for-each
 747    (lambda (field)
 748      (for-each (lambda (e)
 749                  (for-each (lambda (x)
 750                              (set! event-types (delq x event-types)))
 751                            (ly:music-property e 'types)))
 752                (ly:music-property repeat-chord field)))
 753    '(elements articulations))
 754
 755   ;; now treat the elements
 756   (set! (ly:music-property repeat-chord 'elements)
 757         (let ((elts
 758                (ly:music-deep-copy (filter keep-element?
 759                                            (ly:music-property original-chord
 760                                                               'elements))
 761                                    repeat-chord)))
 762           (for-each
 763            (lambda (m)
 764              (let ((arts (ly:music-property m 'articulations)))
 765                (if (pair? arts)
 766                    (set! (ly:music-property m 'articulations)
 767                          (ly:set-origin! (filter! keep-element? arts)
 768                                          repeat-chord)))
 769                (if (ly:duration? (ly:music-property m 'duration))
 770                    (set! (ly:music-property m 'duration) duration))
 771                (if (ly:music-property m 'cautionary #f)
 772                    (set! (ly:music-property m 'cautionary) #f))
 773                (if (ly:music-property m 'force-accidental #f)
 774                    (set! (ly:music-property m 'force-accidental) #f))))
 775            elts)
 776           (append! elts (ly:music-property repeat-chord 'elements))))
 777   (let ((arts (filter keep-element?
 778                       (ly:music-property original-chord
 779                                          'articulations))))
 780     (if (pair? arts)
 781         (set! (ly:music-property repeat-chord 'articulations)
 782               (append!
 783                (ly:music-deep-copy arts repeat-chord)
 784                (ly:music-property repeat-chord 'articulations)))))
 785   repeat-chord)
 786
 787
 788 (define-public (expand-repeat-chords! event-types music)
 789   "Walks through @var{music} and fills repeated chords (notable by
 790 having a duration in @code{duration}) with the notes from their
 791 respective predecessor chord."
 792   (let loop ((music music) (last-chord #f))
 793     (if (music-is-of-type? music 'event-chord)
 794         (let ((chord-repeat (ly:music-property music 'duration)))
 795           (cond
 796            ((not (ly:duration? chord-repeat))
 797             (if (any (lambda (m) (ly:duration?
 798                                   (ly:music-property m 'duration)))
 799                      (ly:music-property music 'elements))
 800                 music
 801                 last-chord))
 802            (last-chord
 803             (set! (ly:music-property music 'duration) '())
 804             (copy-repeat-chord last-chord music chord-repeat event-types))
 805            (else
 806             (ly:music-warning music (_ "Bad chord repetition"))
 807             #f)))
 808         (let ((elt (ly:music-property music 'element)))
 809           (fold loop (if (ly:music? elt) (loop elt last-chord) last-chord)
 810                 (ly:music-property music 'elements)))))
 811   music)
 812
 813 ;;; This does _not_ copy any articulations.  Rationale: one main
 814 ;;; incentive for pitch-repeating durations is after ties, such that
 815 ;;; 4~2~8. can stand in for a 15/16 note in \partial 4 position.  In
 816 ;;; this use case, any repeated articulations will be a nuisance.
 817 ;;;
 818 ;;; String assignments in TabStaff might seem like a worthwhile
 819 ;;; exception, but they would be better tackled by the respective
 820 ;;; engravers themselves (see issue 3662).
 821 ;;;
 822 ;;; Repeating chords as well seems problematic for things like
 823 ;;; \score {
 824 ;;;   <<
 825 ;;;     \new Staff { c4 c c <c e> }
 826 ;;;     \new RhythmicStaff { 4 4 4 4 }
 827 ;;;   >>
 828 ;;; }
 829 ;;;
 830 ;;; However, because of MIDI it is not advisable to use RhythmicStaff
 831 ;;; without any initial pitch/drum-type.  For music functions taking
 832 ;;; pure rhythms as an argument, the running of expand-repeat-notes!
 833 ;;; at scorification time is irrelevant: at that point of time, the
 834 ;;; music function has already run.
 835
 836 (define-public (expand-repeat-notes! music)
 837   "Walks through @var{music} and gives pitchless notes (not having a
 838 pitch in code{pitch} or a drum type in @code{drum-type}) the pitch(es)
 839 from the predecessor note/chord if available."
 840   (let ((last-pitch #f))
 841     (map-some-music
 842      (lambda (m)
 843        (define (set-and-ret last)
 844          (set! last-pitch last)
 845          m)
 846        (cond
 847         ((music-is-of-type? m 'event-chord)
 848          (if (any (lambda (m) (music-is-of-type? m 'rhythmic-event))
 849                   (ly:music-property m 'elements))
 850              (set! last-pitch m))
 851          m)
 852         ((music-is-of-type? m 'note-event)
 853          (cond
 854           ((or (ly:music-property m 'pitch #f)
 855                (ly:music-property m 'drum-type #f))
 856            => set-and-ret)
 857           ;; ok, naked rhythm.  Go through the various cases of
 858           ;; last-pitch
 859           ;; nothing available: just keep as-is
 860           ((not last-pitch) m)
 861           ((ly:pitch? last-pitch)
 862            (set! (ly:music-property m 'pitch) last-pitch)
 863            m)
 864           ((symbol? last-pitch)
 865            (set! (ly:music-property m 'drum-type) last-pitch)
 866            m)
 867           ;; Ok, this is the big bad one: the reference is a chord.
 868           ;; For now, we use the repeat chord logic.  That's not
 869           ;; really efficient as cleaning out all articulations is
 870           ;; quite simpler than what copy-repeat-chord does.
 871           (else
 872            (copy-repeat-chord last-pitch
 873                               (make-music 'EventChord
 874                                           'elements
 875                                           (ly:music-property m 'articulations)
 876                                           'origin
 877                                           (ly:music-property m 'origin))
 878                               (ly:music-property m 'duration)
 879                               '(rhythmic-event)))))
 880         (else #f)))
 881      music)))
 882
 883 ;;; splitting chords into voices.
 884 (define (voicify-list lst number)
 885   "Make a list of Musics.
 886
 887 voicify-list :: [ [Music ] ] -> number -> [Music]
 888 LST is a list music-lists.
 889
 890 NUMBER is 0-base, i.e., Voice=1 (upstems) has number 0.
 891 "
 892   (if (null? lst)
 893       '()
 894       (cons (context-spec-music
 895              (make-sequential-music
 896               (list (make-voice-props-set number)
 897                     (make-simultaneous-music (car lst))))
 898              'Bottom  (number->string (1+ number)))
 899             (voicify-list (cdr lst) (1+ number)))))
 900
 901 (define (voicify-chord ch)
 902   "Split the parts of a chord into different Voices using separator"
 903   (let ((es (ly:music-property ch 'elements)))
 904     (set! (ly:music-property  ch 'elements)
 905           (voicify-list (split-list-by-separator es music-separator?) 0))
 906     ch))
 907
 908 (define-public (voicify-music m)
 909   "Recursively split chords that are separated with @code{\\\\}."
 910   (if (not (ly:music? m))
 911       (ly:error (_ "music expected: ~S") m))
 912   (let ((es (ly:music-property m 'elements))
 913         (e (ly:music-property m 'element)))
 914
 915     (if (pair? es)
 916         (set! (ly:music-property m 'elements) (map voicify-music es)))
 917     (if (ly:music? e)
 918         (set! (ly:music-property m 'element)  (voicify-music e)))
 919     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 920              (any music-separator? es))
 921         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 922     m))
 923
 924 (define-public (empty-music)
 925   (make-music 'Music))
 926
 927 ;; Make a function that checks score element for being of a specific type.
 928 (define-public (make-type-checker symbol)
 929   (lambda (elt)
 930     (grob::has-interface elt symbol)))
 931
 932 (define ((outputproperty-compatibility func sym val) grob g-context ao-context)
 933   (if (func grob)
 934       (set! (ly:grob-property grob sym) val)))
 935 (export outputproperty-compatibility)
 936
 937
 938 (define ((set-output-property grob-name symbol val)  grob grob-c context)
 939   "Usage example:
 940 @code{\\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))}"
 941   (let ((meta (ly:grob-property grob 'meta)))
 942     (if (equal? (assoc-get 'name meta) grob-name)
 943         (set! (ly:grob-property grob symbol) val))))
 944 (export set-output-property)
 945
 946
 947 (define-public (skip->rest mus)
 948   "Replace @var{mus} by @code{RestEvent} of the same duration if it is a
 949 @code{SkipEvent}.  Useful for extracting parts from crowded scores."
 950
 951   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 952        (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 953        mus))
 954
 955
 956 (define-public (music-clone music . music-properties)
 957   "Clone @var{music} and set properties according to
 958 @var{music-properties}, a list of alternating property symbols and
 959 values:
 960 @example\n(music-clone start-span 'span-direction STOP)
 961 @end example
 962 Only properties that are not overriden by @var{music-properties} are
 963 actually fully cloned."
 964   (let ((old-props (list-copy (ly:music-mutable-properties music)))
 965         (new-props '())
 966         (m (ly:make-music (ly:prob-immutable-properties music))))
 967     (define (set-props mus-props)
 968       (if (and (not (null? mus-props))
 969                (not (null? (cdr mus-props))))
 970           (begin
 971             (set! old-props (assq-remove! old-props (car mus-props)))
 972             (set! new-props
 973                   (assq-set! new-props
 974                              (car mus-props) (cadr mus-props)))
 975             (set-props (cddr mus-props)))))
 976     (set-props music-properties)
 977     (for-each
 978      (lambda (pair)
 979        (set! (ly:music-property m (car pair))
 980              (ly:music-deep-copy (cdr pair))))
 981      old-props)
 982     (for-each
 983      (lambda (pair)
 984        (set! (ly:music-property m (car pair)) (cdr pair)))
 985      new-props)
 986     m))
 987
 988 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 989 ;; warn for bare chords at start.
 990
 991 (define-public (ly:music-message music msg . rest)
 992   (let ((ip (ly:music-property music 'origin)))
 993     (if (ly:input-location? ip)
 994         (apply ly:input-message ip msg rest)
 995         (apply ly:message msg rest))))
 996
 997 (define-public (ly:music-warning music msg . rest)
 998   (let ((ip (ly:music-property music 'origin)))
 999     (if (ly:input-location? ip)
1000         (apply ly:input-warning ip msg rest)
1001         (apply ly:warning msg rest))))
1002
1003 (define-public (ly:event-warning event msg . rest)
1004   (let ((ip (ly:event-property event 'origin)))
1005     (if (ly:input-location? ip)
1006         (apply ly:input-warning ip msg rest)
1007         (apply ly:warning msg rest))))
1008
1009 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1010 ;;
1011 ;; setting stuff for grace context.
1012 ;;
1013
1014 (define (vector-extend v x)
1015   "Make a new vector consisting of V, with X added to the end."
1016   (let* ((n (vector-length v))
1017          (nv (make-vector (+ n 1) '())))
1018     (vector-move-left! v 0 n nv 0)
1019     (vector-set! nv n x)
1020     nv))
1021
1022 (define (vector-map f v)
1023   "Map F over V.  This function returns nothing."
1024   (do ((n (vector-length v))
1025        (i 0 (+ i 1)))
1026       ((>= i n))
1027     (f (vector-ref v i))))
1028
1029 (define (vector-reverse-map f v)
1030   "Map F over V, N to 0 order.  This function returns nothing."
1031   (do ((i (- (vector-length v) 1) (- i 1)))
1032       ((< i 0))
1033     (f (vector-ref v i))))
1034
1035 (define-public (add-grace-property context-name grob sym val)
1036   "Set @var{sym}=@var{val} for @var{grob} in @var{context-name}."
1037   (define (set-prop context)
1038     (let* ((where (or (ly:context-find context context-name) context))
1039            (current (ly:context-property where 'graceSettings))
1040            (new-settings (append current
1041                                  (list (list context-name grob sym val)))))
1042       (ly:context-set-property! where 'graceSettings new-settings)))
1043   (make-apply-context set-prop))
1044
1045 (define-public (remove-grace-property context-name grob sym)
1046   "Remove all @var{sym} for @var{grob} in @var{context-name}."
1047   (define (sym-grob-context? property sym grob context-name)
1048     (and (eq? (car property) context-name)
1049          (eq? (cadr property) grob)
1050          (eq? (caddr property) sym)))
1051   (define (delete-prop context)
1052     (let* ((where (or (ly:context-find context context-name) context))
1053            (current (ly:context-property where 'graceSettings))
1054            (prop-settings (filter
1055                            (lambda(x) (sym-grob-context? x sym grob context-name))
1056                            current))
1057            (new-settings current))
1058       (for-each (lambda(x)
1059                   (set! new-settings (delete x new-settings)))
1060                 prop-settings)
1061       (ly:context-set-property! where 'graceSettings new-settings)))
1062   (make-apply-context delete-prop))
1063
1064
1065 (defmacro-public def-grace-function (start stop . docstring)
1066   "Helper macro for defining grace music"
1067   `(define-music-function (music) (ly:music?)
1068      ,@docstring
1069      (make-music 'GraceMusic
1070                  'element (make-music 'SequentialMusic
1071                                       'elements (list (ly:music-deep-copy ,start)
1072                                                       music
1073                                                       (ly:music-deep-copy ,stop))))))
1074
1075 (defmacro-public define-syntax-function (type args signature . body)
1076   "Helper macro for `ly:make-music-function'.
1077 Syntax:
1078   (define-syntax-function result-type? (arg1 arg2 ...) (arg1-type arg2-type ...)
1079     ...function body...)
1080
1081 argX-type can take one of the forms @code{predicate?} for mandatory
1082 arguments satisfying the predicate, @code{(predicate?)} for optional
1083 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1084 value)}} for optional parameters with a specified default
1085 value (evaluated at definition time).  An optional parameter can be
1086 omitted in a call only when it can't get confused with a following
1087 parameter of different type.
1088
1089 @code{result-type?} can specify a default in the same manner as
1090 predicates, to be used in case of a type error in arguments or
1091 result."
1092
1093   (define (has-parser/location? arg where)
1094     (let loop ((arg arg))
1095       (if (list? arg)
1096           (any loop arg)
1097           (memq arg where))))
1098   (define (currying-lambda args doc-string? body)
1099     (if (and (pair? args)
1100              (pair? (car args)))
1101         (currying-lambda (car args) doc-string?
1102                          `((lambda ,(cdr args) ,@body)))
1103         (let* ((compatibility? (if (list? args)
1104                                    (= (length args) (+ 2 (length signature)))
1105                                    (and (pair? args) (pair? (cdr args))
1106                                         (eq? (car args) 'parser))))
1107                (realargs (if compatibility? (cddr args) args)))
1108           `(lambda ,realargs
1109              ,(format #f "~a\n~a" realargs (or doc-string? ""))
1110              ,@(if (and compatibility?
1111                         (has-parser/location? body (take args 2)))
1112                    `((let ((,(car args) (*parser*)) (,(cadr args) (*location*)))
1113                        ,@body))
1114                    body)))))
1115
1116   (let ((docstring
1117          (and (pair? body) (pair? (cdr body))
1118               (if (string? (car body))
1119                   (car body)
1120                   (and (pair? (car body))
1121                        (eq? '_i (caar body))
1122                        (pair? (cdar body))
1123                        (string? (cadar body))
1124                        (null? (cddar body))
1125                        (cadar body))))))
1126     ;; When the music function definition contains an i10n doc string,
1127     ;; (_i "doc string"), keep the literal string only
1128     `(ly:make-music-function
1129       (list ,@(map (lambda (pred)
1130                      (if (pair? pred)
1131                          `(cons ,(car pred)
1132                                 ,(and (pair? (cdr pred)) (cadr pred)))
1133                          pred))
1134                    (cons type signature)))
1135       ,(currying-lambda args docstring (if docstring (cdr body) body)))))
1136
1137 (defmacro-public define-music-function rest
1138   "Defining macro returning music functions.
1139 Syntax:
1140   (define-music-function (arg1 arg2 ...) (arg1-type? arg2-type? ...)
1141     ...function body...)
1142
1143 argX-type can take one of the forms @code{predicate?} for mandatory
1144 arguments satisfying the predicate, @code{(predicate?)} for optional
1145 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1146 value)}} for optional parameters with a specified default
1147 value (evaluated at definition time).  An optional parameter can be
1148 omitted in a call only when it can't get confused with a following
1149 parameter of different type.
1150
1151 Must return a music expression.  The @code{origin} is automatically
1152 set to the @code{location} parameter."
1153
1154   `(define-syntax-function (ly:music? (make-music 'Music 'void #t)) ,@rest))
1155
1156
1157 (defmacro-public define-scheme-function rest
1158   "Defining macro returning Scheme functions.
1159 Syntax:
1160   (define-scheme-function (arg1 arg2 ...) (arg1-type? arg2-type? ...)
1161     ...function body...)
1162
1163 argX-type can take one of the forms @code{predicate?} for mandatory
1164 arguments satisfying the predicate, @code{(predicate?)} for optional
1165 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1166 value)}} for optional parameters with a specified default
1167 value (evaluated at definition time).  An optional parameter can be
1168 omitted in a call only when it can't get confused with a following
1169 parameter of different type.
1170
1171 Can return arbitrary expressions.  If a music expression is returned,
1172 its @code{origin} is automatically set to the @code{location}
1173 parameter."
1174
1175   `(define-syntax-function scheme? ,@rest))
1176
1177 (defmacro-public define-void-function rest
1178   "This defines a Scheme function like @code{define-scheme-function} with
1179 void return value (i.e., what most Guile functions with `unspecified'
1180 value return).  Use this when defining functions for executing actions
1181 rather than returning values, to keep Lilypond from trying to interpret
1182 the return value."
1183   `(define-syntax-function (void? *unspecified*) ,@rest *unspecified*))
1184
1185 (defmacro-public define-event-function rest
1186   "Defining macro returning event functions.
1187 Syntax:
1188   (define-event-function (arg1 arg2 ...) (arg1-type? arg2-type? ...)
1189     ...function body...)
1190
1191 argX-type can take one of the forms @code{predicate?} for mandatory
1192 arguments satisfying the predicate, @code{(predicate?)} for optional
1193 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1194 value)}} for optional parameters with a specified default
1195 value (evaluated at definition time).  An optional parameter can be
1196 omitted in a call only when it can't get confused with a following
1197 parameter of different type.
1198
1199 Must return an event expression.  The @code{origin} is automatically
1200 set to the @code{location} parameter."
1201
1202   `(define-syntax-function (ly:event? (make-music 'Event 'void #t)) ,@rest))
1203
1204 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1205
1206 (define-public (cue-substitute quote-music)
1207   "Must happen after @code{quote-substitute}."
1208
1209   (if (vector? (ly:music-property quote-music 'quoted-events))
1210       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
1211              (clef (ly:music-property quote-music 'quoted-music-clef #f))
1212              (main-voice (case dir ((1) 1) ((-1) 0) (else #f)))
1213              (cue-voice (and main-voice (- 1 main-voice)))
1214              (cue-type (ly:music-property quote-music 'quoted-context-type #f))
1215              (cue-id (ly:music-property quote-music 'quoted-context-id))
1216              (main-music (ly:music-property quote-music 'element))
1217              (return-value quote-music))
1218
1219         (if main-voice
1220             (set! (ly:music-property quote-music 'element)
1221                   (make-sequential-music
1222                    (list
1223                     (make-voice-props-override main-voice)
1224                     main-music
1225                     (make-voice-props-revert)))))
1226
1227         ;; if we have stem dirs, change both quoted and main music
1228         ;; to have opposite stems.
1229
1230         ;; cannot context-spec Quote-music, since context
1231         ;; for the quotes is determined in the iterator.
1232
1233         (make-sequential-music
1234          (delq! #f
1235                 (list
1236                  (and clef (make-cue-clef-set clef))
1237                  (and cue-type cue-voice
1238                       (context-spec-music
1239                        (make-voice-props-override cue-voice)
1240                        cue-type cue-id))
1241                  quote-music
1242                  (and cue-type cue-voice
1243                       (context-spec-music
1244                        (make-voice-props-revert)
1245                        cue-type cue-id))
1246                  (and clef (make-cue-clef-unset))))))
1247       quote-music))
1248
1249 (define ((quote-substitute quote-tab) music)
1250   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
1251          (quoted-vector (and (string? quoted-name)
1252                              (hash-ref quote-tab quoted-name #f))))
1253
1254
1255     (if (string? quoted-name)
1256         (if (vector? quoted-vector)
1257             (begin
1258               (set! (ly:music-property music 'quoted-events) quoted-vector)
1259               (set! (ly:music-property music 'iterator-ctor)
1260                     ly:quote-iterator::constructor))
1261             (ly:music-warning music (ly:format (_ "cannot find quoted music: `~S'") quoted-name))))
1262     music))
1263 (export quote-substitute)
1264
1265
1266 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1267 ;; switch it on here, so parsing and init isn't checked (too slow!)
1268 ;;
1269 ;; automatic music transformations.
1270
1271 (define (switch-on-debugging m)
1272   (if (defined? 'set-debug-cell-accesses!)
1273       (set-debug-cell-accesses! 15000))
1274   m)
1275
1276 (define (music-check-error music)
1277   (define found #f)
1278   (define (signal m)
1279     (if (and (ly:music? m)
1280              (eq? (ly:music-property m 'error-found) #t))
1281         (set! found #t)))
1282
1283   (for-each signal (ly:music-property music 'elements))
1284   (signal (ly:music-property music 'element))
1285
1286   (if found
1287       (set! (ly:music-property music 'error-found) #t))
1288   music)
1289
1290 (define (precompute-music-length music)
1291   (set! (ly:music-property music 'length)
1292         (ly:music-length music))
1293   music)
1294
1295 (define-public (make-duration-of-length moment)
1296   "Make duration of the given @code{moment} length."
1297   (ly:make-duration 0 0
1298                     (ly:moment-main-numerator moment)
1299                     (ly:moment-main-denominator moment)))
1300
1301 (define (make-skipped moment bool)
1302   "Depending on BOOL, set or unset skipTypesetting,
1303 then make SkipMusic of the given MOMENT length, and
1304 then revert skipTypesetting."
1305   (make-sequential-music
1306    (list
1307     (context-spec-music (make-property-set 'skipTypesetting bool)
1308                         'Score)
1309     (make-music 'SkipMusic 'duration
1310                 (make-duration-of-length moment))
1311     (context-spec-music (make-property-set 'skipTypesetting (not bool))
1312                         'Score))))
1313
1314 (define (skip-as-needed music)
1315   "Replace MUSIC by
1316  << {  \\set skipTypesetting = ##f
1317  LENGTHOF(\\showFirstLength)
1318  \\set skipTypesetting = ##t
1319  LENGTHOF(\\showLastLength) }
1320  MUSIC >>
1321  if appropriate.
1322
1323  When only showFirstLength is set,
1324  the 'length property of the music is
1325  overridden to speed up compiling."
1326   (let*
1327       ((show-last (ly:parser-lookup 'showLastLength))
1328        (show-first (ly:parser-lookup 'showFirstLength))
1329        (show-last-length (and (ly:music? show-last)
1330                               (ly:music-length show-last)))
1331        (show-first-length (and (ly:music? show-first)
1332                                (ly:music-length show-first)))
1333        (orig-length (ly:music-length music)))
1334
1335     ;;FIXME: if using either showFirst- or showLastLength,
1336     ;; make sure that skipBars is not set.
1337
1338     (cond
1339
1340      ;; both properties may be set.
1341      ((and show-first-length show-last-length)
1342       (let
1343           ((skip-length (ly:moment-sub orig-length show-last-length)))
1344         (make-simultaneous-music
1345          (list
1346           (make-sequential-music
1347            (list
1348             (make-skipped skip-length #t)
1349             ;; let's draw a separator between the beginning and the end
1350             (context-spec-music (make-property-set 'whichBar "||")
1351                                 'Timing)))
1352           (make-skipped show-first-length #f)
1353           music))))
1354
1355      ;; we may only want to print the last length
1356      (show-last-length
1357       (let
1358           ((skip-length (ly:moment-sub orig-length show-last-length)))
1359         (make-simultaneous-music
1360          (list
1361           (make-skipped skip-length #t)
1362           music))))
1363
1364      ;; we may only want to print the beginning; in this case
1365      ;; only the first length will be processed (much faster).
1366      (show-first-length
1367       ;; the first length must not exceed the original length.
1368       (if (ly:moment<? show-first-length orig-length)
1369           (set! (ly:music-property music 'length)
1370                 show-first-length))
1371       music)
1372
1373      (else music))))
1374
1375
1376 (define-session-public toplevel-music-functions
1377   (list
1378    (lambda (music) (expand-repeat-chords!
1379                     (cons 'rhythmic-event
1380                           (ly:parser-lookup '$chord-repeat-events))
1381                     music))
1382    expand-repeat-notes!
1383    voicify-music
1384    (lambda (x) (music-map music-check-error x))
1385    (lambda (x) (music-map precompute-music-length x))
1386    (lambda (music)
1387      (music-map (quote-substitute (ly:parser-lookup 'musicQuotes))  music))
1388
1389    ;; switch-on-debugging
1390    (lambda (x) (music-map cue-substitute x))
1391
1392    skip-as-needed))
1393
1394 ;;;;;;;;;;
1395 ;;; general purpose music functions
1396
1397 (define (shift-octave pitch octave-shift)
1398   (_i "Add @var{octave-shift} to the octave of @var{pitch}.")
1399   (ly:make-pitch
1400    (+ (ly:pitch-octave pitch) octave-shift)
1401    (ly:pitch-notename pitch)
1402    (ly:pitch-alteration pitch)))
1403
1404
1405 ;;;;;;;;;;;;;;;;;
1406 ;; lyrics
1407
1408 (define (apply-durations lyric-music durations)
1409   (define (apply-duration music)
1410     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
1411              (ly:duration?  (ly:music-property music 'duration)))
1412         (begin
1413           (set! (ly:music-property music 'duration) (car durations))
1414           (set! durations (cdr durations)))))
1415
1416   (music-map apply-duration lyric-music))
1417
1418
1419 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1420 ;; accidentals
1421
1422 (define (recent-enough? bar-number alteration-def laziness)
1423   (or (number? alteration-def)
1424       (equal? laziness #t)
1425       (<= bar-number (+ (cadr alteration-def) laziness))))
1426
1427 (define (accidental-invalid? alteration-def)
1428   "Checks an alteration entry for being invalid.
1429
1430 Non-key alterations are invalidated when tying into the next bar or
1431 when there is a clef change, since neither repetition nor cancellation
1432 can be omitted when the same note occurs again.
1433
1434 Returns @code{#f} or the reason for the invalidation, a symbol."
1435   (let* ((def (if (pair? alteration-def)
1436                   (car alteration-def)
1437                   alteration-def)))
1438     (and (symbol? def) def)))
1439
1440 (define (extract-alteration alteration-def)
1441   (cond ((number? alteration-def)
1442          alteration-def)
1443         ((pair? alteration-def)
1444          (car alteration-def))
1445         (else 0)))
1446
1447 (define (check-pitch-against-signature context pitch barnum laziness octaveness all-naturals)
1448   "Checks the need for an accidental and a @q{restore} accidental against
1449 @code{localAlterations} and @code{keyAlterations}.
1450 The @var{laziness} is the number of measures
1451 for which reminder accidentals are used (i.e., if @var{laziness} is zero,
1452 only cancel accidentals in the same measure; if @var{laziness} is three,
1453 we cancel accidentals up to three measures after they first appear.
1454 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1455 specifies whether accidentals should be canceled in different octaves.
1456 If @var{all-naturals} is ##t, notes that do not occur in @code{keyAlterations}
1457 also get an accidental."
1458   (let* ((ignore-octave (cond ((equal? octaveness 'any-octave) #t)
1459                               ((equal? octaveness 'same-octave) #f)
1460                               (else
1461                                (ly:warning (_ "Unknown octaveness type: ~S ") octaveness)
1462                                (ly:warning (_ "Defaulting to 'any-octave."))
1463                                #t)))
1464          (key (ly:context-property context 'keyAlterations))
1465          (local (ly:context-property context 'localAlterations))
1466          (notename (ly:pitch-notename pitch))
1467          (octave (ly:pitch-octave pitch))
1468          (pitch-handle (cons octave notename))
1469          (need-restore #f)
1470          (need-accidental #f)
1471          (previous-alteration #f)
1472          (from-other-octaves #f)
1473          (from-same-octave (assoc-get pitch-handle local))
1474          (from-key-sig (or (assoc-get notename local)
1475
1476                            ;; If no notename match is found from localAlterations, we may have a custom
1477                            ;; type with octave-specific entries of the form ((octave . pitch) alteration)
1478                            ;; instead of (pitch . alteration).  Since this type cannot coexist with entries in
1479                            ;; localAlterations, try extracting from keyAlterations instead.
1480                            (assoc-get pitch-handle key))))
1481
1482     ;; loop through localAlterations to search for a notename match from other octaves
1483     (let loop ((l local))
1484       (if (pair? l)
1485           (let ((entry (car l)))
1486             (if (and (pair? (car entry))
1487                      (= (cdar entry) notename))
1488                 (set! from-other-octaves (cdr entry))
1489                 (loop (cdr l))))))
1490
1491     ;; find previous alteration-def for comparison with pitch
1492     (cond
1493      ;; from same octave?
1494      ((and (not ignore-octave)
1495            from-same-octave
1496            (recent-enough? barnum from-same-octave laziness))
1497       (set! previous-alteration from-same-octave))
1498
1499      ;; from any octave?
1500      ((and ignore-octave
1501            from-other-octaves
1502            (recent-enough? barnum from-other-octaves laziness))
1503       (set! previous-alteration from-other-octaves))
1504
1505      ;; not recent enough, extract from key signature/local key signature
1506      (from-key-sig
1507       (set! previous-alteration from-key-sig)))
1508
1509     (if (accidental-invalid? previous-alteration)
1510         (set! need-accidental #t)
1511
1512         (let* ((prev-alt (extract-alteration previous-alteration))
1513                (this-alt (ly:pitch-alteration pitch)))
1514
1515           (if (or (and all-naturals (eq? #f previous-alteration)) (not (= this-alt prev-alt)))
1516               (begin
1517                 (set! need-accidental #t)
1518                 (if (and (not (= this-alt 0))
1519                          (and (< (abs this-alt) (abs prev-alt))
1520                               (> (* prev-alt this-alt) 0)))
1521                     (set! need-restore #t))))))
1522
1523     (cons need-restore need-accidental)))
1524
1525 (define ((make-accidental-rule octaveness laziness) context pitch barnum measurepos)
1526   "Create an accidental rule that makes its decision based on the octave of
1527 the note and a laziness value.
1528
1529 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1530 defines whether the rule should respond to accidental changes in other
1531 octaves than the current.  @code{'same-octave} is the normal way to typeset
1532 accidentals -- an accidental is made if the alteration is different from the
1533 last active pitch in the same octave.  @code{'any-octave} looks at the last
1534 active pitch in any octave.
1535
1536 @var{laziness} states over how many bars an accidental should be remembered.
1537 @code{0}@tie{}is the default -- accidental lasts over 0@tie{}bar lines, that
1538 is, to the end of current measure.  A positive integer means that the
1539 accidental lasts over that many bar lines.  @w{@code{-1}} is `forget
1540 immediately', that is, only look at key signature.  @code{#t} is `forever'."
1541
1542   (check-pitch-against-signature context pitch barnum laziness octaveness #f))
1543 (export make-accidental-rule)
1544
1545 (define ((make-accidental-dodecaphonic-rule octaveness laziness) context pitch barnum measurepos)
1546   "Variation on function make-accidental-rule that creates an dodecaphonic
1547 accidental rule."
1548
1549   (check-pitch-against-signature context pitch barnum laziness octaveness #t))
1550 (export make-accidental-dodecaphonic-rule)
1551
1552 (define (key-entry-notename entry)
1553   "Return the pitch of an @var{entry} in @code{localAlterations}.
1554 The @samp{car} of the entry is either of the form @code{notename} or
1555 of the form @code{(octave . notename)}.  The latter form is used for special
1556 key signatures or to indicate an explicit accidental.
1557
1558 The @samp{cdr} of the entry is either a rational @code{alter} indicating
1559 a key signature alteration, or of the form
1560 @code{(alter . (barnum . measurepos))} indicating an alteration caused by
1561 an accidental in music."
1562   (if (pair? (car entry))
1563       (cdar entry)
1564       (car entry)))
1565
1566 (define (key-entry-octave entry)
1567   "Return the octave of an entry in @code{localAlterations}
1568 or @code{#f} if the entry does not have an octave.
1569 See @code{key-entry-notename} for details."
1570   (and (pair? (car entry)) (caar entry)))
1571
1572 (define (key-entry-bar-number entry)
1573   "Return the bar number of an entry in @code{localAlterations}
1574 or @code {#f} if the entry does not have a bar number.
1575 See @code{key-entry-notename} for details."
1576   (and (pair? (cdr entry)) (caddr entry)))
1577
1578 (define (key-entry-measure-position entry)
1579   "Return the measure position of an entry in @code{localAlterations}
1580 or @code {#f} if the entry does not have a measure position.
1581 See @code{key-entry-notename} for details."
1582   (and (pair? (cdr entry)) (cdddr entry)))
1583
1584 (define (key-entry-alteration entry)
1585   "Return the alteration of an entry in localAlterations
1586
1587 For convenience, returns @code{0} if entry is @code{#f}."
1588   (if entry
1589       (if (number? (cdr entry))
1590           (cdr entry)
1591           (cadr entry))
1592       0))
1593
1594 (define-public (find-pitch-entry keysig pitch accept-global accept-local)
1595   "Return the first entry in @var{keysig} that matches @var{pitch}
1596 by notename and octave.  Alteration is not considered.
1597 @var{accept-global} states whether key signature entries should be included.
1598 @var{accept-local} states whether local accidentals should be included.
1599 If no matching entry is found, @var{#f} is returned."
1600   (and (pair? keysig)
1601        (let* ((entry (car keysig))
1602               (entryoct (key-entry-octave entry))
1603               (entrynn (key-entry-notename entry))
1604               (nn (ly:pitch-notename pitch)))
1605          (if (and (equal? nn entrynn)
1606                   (or (not entryoct)
1607                       (= entryoct (ly:pitch-octave pitch)))
1608                   (if (key-entry-bar-number entry)
1609                       accept-local
1610                       accept-global))
1611              entry
1612              (find-pitch-entry (cdr keysig) pitch accept-global accept-local)))))
1613
1614 (define-public (neo-modern-accidental-rule context pitch barnum measurepos)
1615   "An accidental rule that typesets an accidental if it differs from the
1616 key signature @emph{and} does not directly follow a note on the same
1617 staff line.  This rule should not be used alone because it does neither
1618 look at bar lines nor different accidentals at the same note name."
1619   (let* ((keysig (ly:context-property context 'localAlterations))
1620          (entry (find-pitch-entry keysig pitch #t #t)))
1621     (if (not entry)
1622         (cons #f #f)
1623         (let* ((global-entry (find-pitch-entry keysig pitch #t #f))
1624                (key-acc (key-entry-alteration global-entry))
1625                (acc (ly:pitch-alteration pitch))
1626                (entrymp (key-entry-measure-position entry))
1627                (entrybn (key-entry-bar-number entry)))
1628           (cons #f (not (or (equal? acc key-acc)
1629                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1630
1631 (define-public (dodecaphonic-no-repeat-rule context pitch barnum measurepos)
1632   "An accidental rule that typesets an accidental before every
1633 note (just as in the dodecaphonic accidental style) @emph{except} if
1634 the note is immediately preceded by a note with the same pitch. This
1635 is a common accidental style in contemporary notation."
1636    (let* ((keysig (ly:context-property context 'localAlterations))
1637           (entry (find-pitch-entry keysig pitch #f #t)))
1638      (if (not entry)
1639          (cons #f #t)
1640          (let ((entrymp (key-entry-measure-position entry))
1641                (entrybn (key-entry-bar-number entry))
1642                (entryalt (key-entry-alteration entry))
1643                (alt (ly:pitch-alteration pitch)))
1644            (cons #t
1645                  (not (and (equal? entrybn barnum)
1646                            (or (equal? measurepos entrymp)
1647                                (ly:moment<? measurepos entrymp))
1648                            (equal? entryalt alt))))))))
1649
1650 (define-public (teaching-accidental-rule context pitch barnum measurepos)
1651   "An accidental rule that typesets a cautionary accidental if it is
1652 included in the key signature @emph{and} does not directly follow a note
1653 on the same staff line."
1654   (let* ((keysig (ly:context-property context 'localAlterations))
1655          (entry (find-pitch-entry keysig pitch #t #t)))
1656     (if (not entry)
1657         (cons #f #f)
1658         (let* ((global-entry (find-pitch-entry keysig pitch #f #f))
1659                (key-acc (key-entry-alteration global-entry))
1660                (acc (ly:pitch-alteration pitch))
1661                (entrymp (key-entry-measure-position entry))
1662                (entrybn (key-entry-bar-number entry)))
1663           (cons #f (not (or (equal? acc key-acc)
1664                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1665
1666 (define-public (set-accidentals-properties extra-natural
1667                                            auto-accs auto-cauts
1668                                            context)
1669   (context-spec-music
1670    (make-sequential-music
1671     (append (if (boolean? extra-natural)
1672                 (list (make-property-set 'extraNatural extra-natural))
1673                 '())
1674             (list (make-property-set 'autoAccidentals auto-accs)
1675                   (make-property-set 'autoCautionaries auto-cauts))))
1676    context))
1677
1678 (define-public (set-accidental-style style . rest)
1679   "Set accidental style to @var{style}.  Optionally take a context
1680 argument, e.g. @code{'Staff} or @code{'Voice}.  The context defaults
1681 to @code{Staff}, except for piano styles, which use @code{GrandStaff}
1682 as a context."
1683   (let ((context (if (pair? rest)
1684                      (car rest) 'Staff))
1685         (pcontext (if (pair? rest)
1686                       (car rest) 'GrandStaff)))
1687     (cond
1688      ;; accidentals as they were common in the 18th century.
1689      ((equal? style 'default)
1690       (set-accidentals-properties #t
1691                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1692                                   '()
1693                                   context))
1694      ;; accidentals from one voice do NOT get canceled in other voices
1695      ((equal? style 'voice)
1696       (set-accidentals-properties #t
1697                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1698                                   '()
1699                                   context))
1700      ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
1701      ;; This includes all the default accidentals, but accidentals also needs canceling
1702      ;; in other octaves and in the next measure.
1703      ((equal? style 'modern)
1704       (set-accidentals-properties #f
1705                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1706                                           ,(make-accidental-rule 'any-octave 0)
1707                                           ,(make-accidental-rule 'same-octave 1))
1708                                   '()
1709                                   context))
1710      ;; the accidentals that Stone adds to the old standard as cautionaries
1711      ((equal? style 'modern-cautionary)
1712       (set-accidentals-properties #f
1713                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1714                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1715                                           ,(make-accidental-rule 'same-octave 1))
1716                                   context))
1717      ;; same as modern, but accidentals different from the key signature are always
1718      ;; typeset - unless they directly follow a note of the same pitch.
1719      ((equal? style 'neo-modern)
1720       (set-accidentals-properties #f
1721                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1722                                           ,(make-accidental-rule 'any-octave 0)
1723                                           ,(make-accidental-rule 'same-octave 1)
1724                                           ,neo-modern-accidental-rule)
1725                                   '()
1726                                   context))
1727      ((equal? style 'neo-modern-cautionary)
1728       (set-accidentals-properties #f
1729                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1730                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1731                                           ,(make-accidental-rule 'same-octave 1)
1732                                           ,neo-modern-accidental-rule)
1733                                   context))
1734      ((equal? style 'neo-modern-voice)
1735       (set-accidentals-properties #f
1736                                   `(Voice ,(make-accidental-rule 'same-octave 0)
1737                                           ,(make-accidental-rule 'any-octave 0)
1738                                           ,(make-accidental-rule 'same-octave 1)
1739                                           ,neo-modern-accidental-rule
1740                                           Staff ,(make-accidental-rule 'same-octave 0)
1741                                           ,(make-accidental-rule 'any-octave 0)
1742                                           ,(make-accidental-rule 'same-octave 1)
1743                                           ,neo-modern-accidental-rule)
1744                                   '()
1745                                   context))
1746      ((equal? style 'neo-modern-voice-cautionary)
1747       (set-accidentals-properties #f
1748                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1749                                   `(Voice ,(make-accidental-rule 'any-octave 0)
1750                                           ,(make-accidental-rule 'same-octave 1)
1751                                           ,neo-modern-accidental-rule
1752                                           Staff ,(make-accidental-rule 'same-octave 0)
1753                                           ,(make-accidental-rule 'any-octave 0)
1754                                           ,(make-accidental-rule 'same-octave 1)
1755                                           ,neo-modern-accidental-rule)
1756                                   context))
1757      ;; Accidentals as they were common in dodecaphonic music with no tonality.
1758      ;; Each note gets one accidental.
1759      ((equal? style 'dodecaphonic)
1760       (set-accidentals-properties #f
1761                                   `(Staff ,(lambda (c p bn mp) '(#f . #t)))
1762                                   '()
1763                                   context))
1764      ;; As in dodecaphonic style with the exception that immediately
1765      ;; repeated notes (in the same voice) don't get an accidental
1766      ((equal? style 'dodecaphonic-no-repeat)
1767       (set-accidentals-properties #f
1768                                   `(Staff ,dodecaphonic-no-repeat-rule)
1769                                   '()
1770                                   context))
1771      ;; Variety of the dodecaphonic style. Each note gets an accidental,
1772      ;; except notes that were already handled in the same measure.
1773      ((equal? style 'dodecaphonic-first)
1774       (set-accidentals-properties #f
1775                                   `(Staff ,(make-accidental-dodecaphonic-rule 'same-octave 0))
1776                                   '()
1777                                   context))
1778
1779      ;; Multivoice accidentals to be read both by musicians playing one voice
1780      ;; and musicians playing all voices.
1781      ;; Accidentals are typeset for each voice, but they ARE canceled across voices.
1782      ((equal? style 'modern-voice)
1783       (set-accidentals-properties  #f
1784                                    `(Voice ,(make-accidental-rule 'same-octave 0)
1785                                            ,(make-accidental-rule 'any-octave 0)
1786                                            ,(make-accidental-rule 'same-octave 1)
1787                                            Staff ,(make-accidental-rule 'same-octave 0)
1788                                            ,(make-accidental-rule 'any-octave 0)
1789                                            ,(make-accidental-rule 'same-octave 1))
1790                                    '()
1791                                    context))
1792      ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
1793      ;; as cautionaries
1794      ((equal? style 'modern-voice-cautionary)
1795       (set-accidentals-properties #f
1796                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1797                                   `(Voice ,(make-accidental-rule 'any-octave 0)
1798                                           ,(make-accidental-rule 'same-octave 1)
1799                                           Staff ,(make-accidental-rule 'same-octave 0)
1800                                           ,(make-accidental-rule 'any-octave 0)
1801                                           ,(make-accidental-rule 'same-octave 1))
1802                                   context))
1803      ;; stone's suggestions for accidentals on grand staff.
1804      ;; Accidentals are canceled across the staves in the same grand staff as well
1805      ((equal? style 'piano)
1806       (set-accidentals-properties #f
1807                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1808                                           ,(make-accidental-rule 'any-octave 0)
1809                                           ,(make-accidental-rule 'same-octave 1)
1810                                           GrandStaff
1811                                           ,(make-accidental-rule 'any-octave 0)
1812                                           ,(make-accidental-rule 'same-octave 1))
1813                                   '()
1814                                   pcontext))
1815      ((equal? style 'piano-cautionary)
1816       (set-accidentals-properties #f
1817                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1818                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1819                                           ,(make-accidental-rule 'same-octave 1)
1820                                           GrandStaff
1821                                           ,(make-accidental-rule 'any-octave 0)
1822                                           ,(make-accidental-rule 'same-octave 1))
1823                                   pcontext))
1824
1825      ;; same as modern, but cautionary accidentals are printed for all sharp or flat
1826      ;; tones specified by the key signature.
1827      ((equal? style 'teaching)
1828       (set-accidentals-properties #f
1829                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1830                                   `(Staff ,(make-accidental-rule 'same-octave 1)
1831                                           ,teaching-accidental-rule)
1832                                   context))
1833
1834      ;; do not set localAlterations when a note alterated differently from
1835      ;; localAlterations is found.
1836      ;; Causes accidentals to be printed at every note instead of
1837      ;; remembered for the duration of a measure.
1838      ;; accidentals not being remembered, causing accidentals always to
1839      ;; be typeset relative to the time signature
1840      ((equal? style 'forget)
1841       (set-accidentals-properties '()
1842                                   `(Staff ,(make-accidental-rule 'same-octave -1))
1843                                   '()
1844                                   context))
1845      ;; Do not reset the key at the start of a measure.  Accidentals will be
1846      ;; printed only once and are in effect until overridden, possibly many
1847      ;; measures later.
1848      ((equal? style 'no-reset)
1849       (set-accidentals-properties '()
1850                                   `(Staff ,(make-accidental-rule 'same-octave #t))
1851                                   '()
1852                                   context))
1853      (else
1854       (ly:warning (_ "unknown accidental style: ~S") style)
1855       (make-sequential-music '())))))
1856
1857 (define-public (invalidate-alterations context)
1858   "Invalidate alterations in @var{context}.
1859
1860 Elements of @code{'localAlterations} corresponding to local
1861 alterations of the key signature have the form
1862 @code{'((octave . notename) . (alter barnum . measurepos))}.
1863 Replace them with a version where @code{alter} is set to @code{'clef}
1864 to force a repetition of accidentals.
1865
1866 Entries that conform with the current key signature are not invalidated."
1867   (let* ((keysig (ly:context-property context 'keyAlterations)))
1868     (set! (ly:context-property context 'localAlterations)
1869           (map-in-order
1870            (lambda (entry)
1871              (let* ((localalt (key-entry-alteration entry)))
1872                (if (or (accidental-invalid? localalt)
1873                        (not (key-entry-bar-number entry))
1874                        (= localalt
1875                           (key-entry-alteration
1876                            (find-pitch-entry
1877                             keysig
1878                             (ly:make-pitch (key-entry-octave entry)
1879                                            (key-entry-notename entry)
1880                                            0)
1881                             #t #t))))
1882                    entry
1883                    (cons (car entry) (cons 'clef (cddr entry))))))
1884            (ly:context-property context 'localAlterations)))))
1885
1886 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1887
1888 (define-public (skip-of-length mus)
1889   "Create a skip of exactly the same length as @var{mus}."
1890   (let* ((skip
1891           (make-music
1892            'SkipEvent
1893            'duration (ly:make-duration 0 0))))
1894
1895     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
1896
1897 (define-public (mmrest-of-length mus)
1898   "Create a multi-measure rest of exactly the same length as @var{mus}."
1899
1900   (let* ((skip
1901           (make-multi-measure-rest
1902            (ly:make-duration 0 0) '())))
1903     (ly:music-compress skip (ly:music-length mus))
1904     skip))
1905
1906 (define-public (pitch-of-note event-chord)
1907   (let ((evs (filter (lambda (x)
1908                        (music-is-of-type? x 'note-event))
1909                      (ly:music-property event-chord 'elements))))
1910
1911     (and (pair? evs)
1912          (ly:music-property (car evs) 'pitch))))
1913
1914 (define-public (duration-of-note event-chord)
1915   (cond
1916    ((pair? event-chord)
1917     (or (duration-of-note (car event-chord))
1918         (duration-of-note (cdr event-chord))))
1919    ((ly:music? event-chord)
1920     (let ((dur (ly:music-property event-chord 'duration)))
1921       (if (ly:duration? dur)
1922           dur
1923           (duration-of-note (ly:music-property event-chord 'elements)))))
1924    (else #f)))
1925
1926 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1927
1928 (define-public (map-some-music map? music)
1929   "Walk through @var{music}, transform all elements calling @var{map?}
1930 and only recurse if this returns @code{#f}.  @code{elements} or
1931 @code{articulations} that are not music expressions are discarded:
1932 this allows some amount of filtering.
1933
1934 @code{map-some-music} may overwrite the original @var{music}."
1935   (let loop ((music music))
1936     (or (map? music)
1937         (let ((elt (ly:music-property music 'element))
1938               (elts (ly:music-property music 'elements))
1939               (arts (ly:music-property music 'articulations)))
1940           (if (ly:music? elt)
1941               (set! (ly:music-property music 'element)
1942                     (loop elt)))
1943           (if (pair? elts)
1944               (set! (ly:music-property music 'elements)
1945                     (filter! ly:music? (map! loop elts))))
1946           (if (pair? arts)
1947               (set! (ly:music-property music 'articulations)
1948                     (filter! ly:music? (map! loop arts))))
1949           music))))
1950
1951 (define-public (for-some-music stop? music)
1952   "Walk through @var{music}, process all elements calling @var{stop?}
1953 and only recurse if this returns @code{#f}."
1954   (let loop ((music music))
1955     (if (not (stop? music))
1956         (let ((elt (ly:music-property music 'element)))
1957           (if (ly:music? elt)
1958               (loop elt))
1959           (for-each loop (ly:music-property music 'elements))
1960           (for-each loop (ly:music-property music 'articulations))))))
1961
1962 (define-public (fold-some-music pred? proc init music)
1963   "This works recursively on music like @code{fold} does on a list,
1964 calling @samp{(@var{pred?} music)} on every music element.  If
1965 @code{#f} is returned for an element, it is processed recursively
1966 with the same initial value of @samp{previous}, otherwise
1967 @samp{(@var{proc} music previous)} replaces @samp{previous}
1968 and no recursion happens.
1969 The top @var{music} is processed using @var{init} for @samp{previous}."
1970   (let loop ((music music) (previous init))
1971     (if (pred? music)
1972         (proc music previous)
1973         (fold loop
1974               (fold loop
1975                     (let ((elt (ly:music-property music 'element)))
1976                       (if (null? elt)
1977                           previous
1978                           (loop elt previous)))
1979                     (ly:music-property music 'elements))
1980               (ly:music-property music 'articulations)))))
1981
1982 (define-public (extract-music music pred?)
1983   "Return a flat list of all music matching @var{pred?} inside of
1984 @var{music}, not recursing into matches themselves."
1985   (reverse! (fold-some-music pred? cons '() music)))
1986
1987 (define-public (extract-named-music music music-name)
1988   "Return a flat list of all music named @var{music-name} (either a
1989 single event symbol or a list of alternatives) inside of @var{music},
1990 not recursing into matches themselves."
1991   (extract-music
1992    music
1993    (if (cheap-list? music-name)
1994        (lambda (m) (memq (ly:music-property m 'name) music-name))
1995        (lambda (m) (eq? (ly:music-property m 'name) music-name)))))
1996
1997 (define-public (extract-typed-music music type)
1998   "Return a flat list of all music with @var{type} (either a single
1999 type symbol or a list of alternatives) inside of @var{music}, not
2000 recursing into matches themselves."
2001   (extract-music
2002    music
2003    (if (cheap-list? type)
2004        (lambda (m)
2005          (any (lambda (t) (music-is-of-type? m t)) type))
2006        (lambda (m) (music-is-of-type? m type)))))
2007
2008 (define*-public (event-chord-wrap! music)
2009   "Wrap isolated rhythmic events and non-postevent events in
2010 @var{music} inside of an @code{EventChord}.  Chord repeats @samp{q}
2011 are expanded using the default settings of the parser."
2012   (map-some-music
2013    (lambda (m)
2014      (cond ((music-is-of-type? m 'event-chord)
2015             (if (pair? (ly:music-property m 'articulations))
2016                 (begin
2017                   (set! (ly:music-property m 'elements)
2018                         (append (ly:music-property m 'elements)
2019                                 (ly:music-property m 'articulations)))
2020                   (set! (ly:music-property m 'articulations) '())))
2021             m)
2022            ((music-is-of-type? m 'rhythmic-event)
2023             (let ((arts (ly:music-property m 'articulations)))
2024               (if (pair? arts)
2025                   (set! (ly:music-property m 'articulations) '()))
2026               (make-event-chord (cons m arts))))
2027            (else #f)))
2028    (expand-repeat-chords!
2029     (cons 'rhythmic-event
2030           (ly:parser-lookup '$chord-repeat-events))
2031     music)))
2032
2033 (define-public (event-chord-notes event-chord)
2034   "Return a list of all notes from @var{event-chord}."
2035   (filter
2036    (lambda (m) (eq? 'NoteEvent (ly:music-property m 'name)))
2037    (ly:music-property event-chord 'elements)))
2038
2039 (define-public (event-chord-pitches event-chord)
2040   "Return a list of all pitches from @var{event-chord}."
2041   (map (lambda (x) (ly:music-property x 'pitch))
2042        (event-chord-notes event-chord)))
2043
2044 (define-public (event-chord-reduce music)
2045   "Reduces event chords in @var{music} to their first note event,
2046 retaining only the chord articulations.  Returns the modified music."
2047   (map-some-music
2048    (lambda (m)
2049      (and (music-is-of-type? m 'event-chord)
2050           (let*-values (((notes arts) (partition
2051                                        (lambda (mus)
2052                                          (music-is-of-type? mus 'rhythmic-event))
2053                                        (ly:music-property m 'elements)))
2054                         ((dur) (ly:music-property m 'duration))
2055                         ((full-arts) (append arts
2056                                              (ly:music-property m 'articulations)))
2057                         ((first-note) (and (pair? notes) (car notes))))
2058             (cond (first-note
2059                    (set! (ly:music-property first-note 'articulations)
2060                          full-arts)
2061                    first-note)
2062                   ((ly:duration? dur)
2063                    ;; A repeat chord. Produce an unpitched note.
2064                    (make-music 'NoteEvent
2065                                'duration dur
2066                                'articulations full-arts))
2067                   (else
2068                    (ly:music-error m (_ "Missing duration"))
2069                    (make-music 'NoteEvent
2070                                'duration (ly:make-duration 2 0 0)
2071                                'articulations full-arts))))))
2072    music))
2073
2074
2075 (defmacro-public make-relative (variables reference music)
2076   "The list of pitch or music variables in @var{variables} is used as
2077 a sequence for creating relativable music from @var{music}.
2078
2079 When the constructed music is used outside of @code{\\relative}, it
2080 just reflects plugging in the @var{variables} into @var{music}.
2081
2082 The action inside of @code{\\relative}, however, is determined by
2083 first relativizing the surrogate @var{reference} with the variables
2084 plugged in and then using the variables relativized as a side effect
2085 of relativizing @var{reference} for evaluating @var{music}.
2086
2087 Since pitches don't have the object identity required for tracing the
2088 effect of the reference call, they are replaced @emph{only} for the
2089 purpose of evaluating @var{reference} with simple pitched note events.
2090
2091 The surrogate @var{reference} expression has to be written with that
2092 in mind.  In addition, it must @emph{not} contain @emph{copies} of
2093 music that is supposed to be relativized but rather the
2094 @emph{originals}.  This @emph{includes} the pitch expressions.  As a
2095 rule, inside of @code{#@{@dots{}#@}} variables must @emph{only} be
2096 introduced using @code{#}, never via the copying construct @code{$}.
2097 The reference expression will usually just be a sequential or chord
2098 expression naming all variables in sequence, implying that following
2099 music will be relativized according to the resulting pitch of the last
2100 or first variable, respectively.
2101
2102 Since the usual purpose is to create more complex music from general
2103 arguments and since music expression parts must not occur more than
2104 once, one @emph{does} generally need to use copying operators in the
2105 @emph{replacement} expression @var{music} when using an argument more
2106 than once there.  Using an argument more than once in @var{reference},
2107 in contrast, does not make sense.
2108
2109 There is another fine point to mind: @var{music} must @emph{only}
2110 contain freshly constructed elements or copied constructs.  This will
2111 be the case anyway for regular LilyPond code inside of
2112 @code{#@{@dots{}#@}}, but any other elements (apart from the
2113 @var{variables} themselves which are already copied) must be created
2114 or copied as well.
2115
2116 The reason is that it is usually permitted to change music in-place as
2117 long as one does a @var{ly:music-deep-copy} on it, and such a copy of
2118 the whole resulting expression will @emph{not} be able to copy
2119 variables/values inside of closures where the information for
2120 relativization is being stored.
2121 "
2122
2123   ;; pitch and music generator might be stored instead in music
2124   ;; properties, and it might make sense to create a music type of its
2125   ;; own for this kind of construct rather than using
2126   ;; RelativeOctaveMusic
2127   (define ((make-relative::to-relative-callback variables music-call ref-call)
2128            music pitch)
2129     (let* ((ref-vars (map (lambda (v)
2130                             (if (ly:pitch? v)
2131                                 (make-music 'NoteEvent 'pitch v)
2132                                 (ly:music-deep-copy v)))
2133                           variables))
2134            (after-pitch (ly:make-music-relative! (apply ref-call ref-vars) pitch))
2135            (actual-vars (map (lambda (v r)
2136                                (if (ly:pitch? v)
2137                                    (ly:music-property r 'pitch)
2138                                    r))
2139                              variables ref-vars))
2140            (rel-music (apply music-call actual-vars)))
2141       (set! (ly:music-property music 'element) rel-music)
2142       after-pitch))
2143   `(make-music 'RelativeOctaveMusic
2144                'to-relative-callback
2145                (,make-relative::to-relative-callback
2146                 (list ,@variables)
2147                 (lambda ,variables ,music)
2148                 (lambda ,variables ,reference))
2149                'element ,music))
2150
2151 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2152 ;; The following functions are all associated with the crossStaff
2153 ;;  function
2154
2155 (define (close-enough? x y)
2156   "Values are close enough to ignore the difference"
2157   (< (abs (- x y)) 0.0001))
2158
2159 (define (extent-combine extents)
2160   "Combine a list of extents"
2161   (if (pair? (cdr extents))
2162       (interval-union (car extents) (extent-combine (cdr extents)))
2163       (car extents)))
2164
2165 (define ((stem-connectable? ref root) stem)
2166   "Check if the stem is connectable to the root"
2167   ;; The root is always connectable to itself
2168   (or (eq? root stem)
2169       (and
2170        ;; Horizontal positions of the stems must be almost the same
2171        (close-enough? (car (ly:grob-extent root ref X))
2172                       (car (ly:grob-extent stem ref X)))
2173        ;; The stem must be in the direction away from the root's notehead
2174        (positive? (* (ly:grob-property root 'direction)
2175                      (- (car (ly:grob-extent stem ref Y))
2176                         (car (ly:grob-extent root ref Y))))))))
2177
2178 (define (stem-span-stencil span)
2179   "Connect stems if we have at least one stem connectable to the root"
2180   (let* ((system (ly:grob-system span))
2181          (root (ly:grob-parent span X))
2182          (stems (filter (stem-connectable? system root)
2183                         (ly:grob-object span 'stems))))
2184     (if (<= 2 (length stems))
2185         (let* ((yextents (map (lambda (st)
2186                                 (ly:grob-extent st system Y)) stems))
2187                (yextent (extent-combine yextents))
2188                (layout (ly:grob-layout root))
2189                (blot (ly:output-def-lookup layout 'blot-diameter)))
2190           ;; Hide spanned stems
2191           (for-each (lambda (st)
2192                       (set! (ly:grob-property st 'stencil) #f))
2193                     stems)
2194           ;; Draw a nice looking stem with rounded corners
2195           (ly:round-filled-box (ly:grob-extent root root X) yextent blot))
2196         ;; Nothing to connect, don't draw the span
2197         #f)))
2198
2199 (define ((make-stem-span! stems trans) root)
2200   "Create a stem span as a child of the cross-staff stem (the root)"
2201   (let ((span (ly:engraver-make-grob trans 'Stem '())))
2202     (ly:grob-set-parent! span X root)
2203     (set! (ly:grob-object span 'stems) stems)
2204     ;; Suppress positioning, the stem code is confused by this weird stem
2205     (set! (ly:grob-property span 'X-offset) 0)
2206     (set! (ly:grob-property span 'stencil) stem-span-stencil)))
2207
2208 (define-public (cross-staff-connect stem)
2209   "Set cross-staff property of the stem to this function to connect it to
2210 other stems automatically"
2211   #t)
2212
2213 (define (stem-is-root? stem)
2214   "Check if automatic connecting of the stem was requested.  Stems connected
2215 to cross-staff beams are cross-staff, but they should not be connected to
2216 other stems just because of that."
2217   (eq? cross-staff-connect (ly:grob-property-data stem 'cross-staff)))
2218
2219 (define (make-stem-spans! ctx stems trans)
2220   "Create stem spans for cross-staff stems"
2221   ;; Cannot do extensive checks here, just make sure there are at least
2222   ;; two stems at this musical moment
2223   (if (<= 2 (length stems))
2224       (let ((roots (filter stem-is-root? stems)))
2225         (for-each (make-stem-span! stems trans) roots))))
2226
2227 (define-public (Span_stem_engraver ctx)
2228   "Connect cross-staff stems to the stems above in the system"
2229   (let ((stems '()))
2230     (make-engraver
2231      ;; Record all stems for the given moment
2232      (acknowledgers
2233       ((stem-interface trans grob source)
2234        (set! stems (cons grob stems))))
2235      ;; Process stems and reset the stem list to empty
2236      ((process-acknowledged trans)
2237       (make-stem-spans! ctx stems trans)
2238       (set! stems '())))))
2239
2240 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2241 ;; The following is used by the alterBroken function.
2242
2243 (define ((value-for-spanner-piece arg) grob)
2244   "Associate a piece of broken spanner @var{grob} with an element
2245 of list @var{arg}."
2246   (let* ((orig (ly:grob-original grob))
2247          (siblings (ly:spanner-broken-into orig)))
2248
2249     (define (helper sibs arg)
2250       (if (null? arg)
2251           arg
2252           (if (eq? (car sibs) grob)
2253               (car arg)
2254               (helper (cdr sibs) (cdr arg)))))
2255
2256     (if (>= (length siblings) 2)
2257         (helper siblings arg)
2258         (car arg))))
2259 (export value-for-spanner-piece)
2260
2261 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2262 ;; The following are used by the \offset function
2263
2264 (define (find-value-to-offset prop self alist)
2265   "Return the first value of the property @var{prop} in the property
2266 alist @var{alist} -- after having found @var{self}.  If @var{self} is
2267 not found, return the first value of @var{prop}."
2268   (let ((segment (member (cons prop self) alist)))
2269     (if (not segment)
2270         (assoc-get prop alist)
2271         (assoc-get prop (cdr segment)))))
2272
2273 (define (offset-multiple-types arg offsets)
2274   "Displace @var{arg} by @var{offsets} if @var{arg} is a number, a
2275 number pair, or a list of number pairs.  If @var{offsets} is an empty
2276 list or if there is a type-mismatch, @var{arg} will be returned."
2277   (cond
2278     ((and (number? arg) (number? offsets))
2279      (+ arg offsets))
2280     ((and (number-pair? arg)
2281           (or (number? offsets)
2282               (number-pair? offsets)))
2283      (coord-translate arg offsets))
2284     ((and (number-pair-list? arg) (number-pair-list? offsets))
2285      (map
2286        (lambda (x y) (coord-translate x y))
2287        arg offsets))
2288     (else arg)))
2289
2290 (define-public (offsetter property offsets)
2291   "Apply @var{offsets} to the default values of @var{property} of @var{grob}.
2292 Offsets are restricted to immutable properties and values of type @code{number},
2293 @code{number-pair}, or @code{number-pair-list}."
2294   (define (self grob)
2295     (let* ((immutable (ly:grob-basic-properties grob))
2296            ; We need to search the basic-properties alist for our property to
2297            ; obtain values to offset.  Our search is complicated by the fact that
2298            ; calling the music function `offset' as an override conses a pair to
2299            ; the head of the alist.  This pair must be discounted.  The closure it
2300            ; contains is named `self' so it can be easily recognized.  If `offset'
2301            ; is called as a tweak, the basic-property alist is unaffected.
2302            (target (find-value-to-offset property self immutable))
2303            ; if target is a procedure, we need to apply it to our grob to calculate
2304            ; values to offset.
2305            (vals
2306              (if (procedure? target)
2307                  (target grob)
2308                  target))
2309            (can-type-be-offset?
2310              (or (number? vals)
2311                  (number-pair? vals)
2312                  (number-pair-list? vals))))
2313
2314       (if can-type-be-offset?
2315           ; '(+inf.0 . -inf.0) would offset to itself.  This will be confusing to a
2316           ; user unaware of the default value of the property, so issue a warning.
2317           (if (equal? empty-interval vals)
2318               (ly:warning "default '~a of ~a is ~a and can't be offset"
2319                 property grob vals)
2320               (let* ((orig (ly:grob-original grob))
2321                      (siblings
2322                        (if (ly:spanner? grob)
2323                            (ly:spanner-broken-into orig)
2324                            '()))
2325                      (total-found (length siblings))
2326                      ; Since there is some flexibility in input syntax,
2327                      ; structure of `offsets' is normalized.
2328                      (offsets
2329                        (if (or (not (pair? offsets))
2330                                (number-pair? offsets)
2331                                (and (number-pair-list? offsets)
2332                                     (number-pair-list? vals)))
2333                            (list offsets)
2334                            offsets)))
2335
2336                 (define (helper sibs offs)
2337                   ; apply offsets to the siblings of broken spanners
2338                   (if (pair? offs)
2339                       (if (eq? (car sibs) grob)
2340                           (offset-multiple-types vals (car offs))
2341                           (helper (cdr sibs) (cdr offs)))
2342                       vals))
2343
2344                 (if (>= total-found 2)
2345                     (helper siblings offsets)
2346                     (offset-multiple-types vals (car offsets)))))
2347
2348               (begin
2349                 (ly:warning "the property '~a of ~a cannot be offset" property grob)
2350                 vals))))
2351     ; return the closure named `self'
2352     self)
2353
2354
2355 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2356 ;; \magnifyMusic and \magnifyStaff
2357
2358 ;; defined as a function instead of a list because the
2359 ;; all-grob-descriptions alist is not available yet
2360 (define-public (find-named-props prop-name grob-descriptions)
2361   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  When
2362 @var{grob-descriptions} is equal to the @code{all-grob-descriptions}
2363 alist (defined in @file{scm/define-grobs.scm}), this will find all grobs
2364 that can have a value for the @var{prop-name} property, and return them
2365 as a list in the following format:
2366 @example
2367 '((grob prop-name)
2368   (grob prop-name)
2369   ...)
2370 @end example"
2371   (define (find-grobs-with-interface interface grob-descriptions)
2372     (define (has-this-interface? grob-desc)
2373       (let* ((meta (ly:assoc-get 'meta (cdr grob-desc)))
2374              (interfaces (ly:assoc-get 'interfaces meta '())))
2375         (memq interface interfaces)))
2376     (let* ((grob-descriptions-with-this-interface
2377              (filter has-this-interface? grob-descriptions))
2378            (grob-names-with-this-interface
2379              (map car grob-descriptions-with-this-interface)))
2380       grob-names-with-this-interface))
2381   (let* ((interface
2382            (case prop-name
2383              ((baseline-skip word-space) 'text-interface)
2384              ((space-alist)              'break-aligned-interface)
2385              (else (ly:programming-error
2386                      "find-named-props: no interface associated with ~s"
2387                      prop-name))))
2388          (grobs-with-this-prop
2389            (find-grobs-with-interface interface grob-descriptions)))
2390     (map (lambda (x) (list x prop-name))
2391          grobs-with-this-prop)))
2392
2393
2394 (define (magnifyStaff-is-set? context mag)
2395   (let* ((Staff (ly:context-find context 'Staff))
2396          (old-mag (ly:context-property Staff 'magnifyStaffValue)))
2397     (not (null? old-mag))))
2398
2399 (define (staff-magnification-is-changing? context mag)
2400   (let* ((Staff (ly:context-find context 'Staff))
2401          (old-mag (ly:context-property Staff 'magnifyStaffValue 1)))
2402     (not (= old-mag mag))))
2403
2404 (define-public (scale-fontSize func-name mag)
2405   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Look up the
2406 current @code{fontSize} in the appropriate context and scale it by the
2407 magnification factor @var{mag}.  @var{func-name} is either
2408 @code{'magnifyMusic} or @code{'magnifyStaff}."
2409   (make-apply-context
2410     (lambda (context)
2411       (if (or (eq? func-name 'magnifyMusic)
2412               ;; for \magnifyStaff, only scale the fontSize
2413               ;; if staff magnification is changing
2414               ;; and does not equal 1
2415               (and (staff-magnification-is-changing? context mag)
2416                    (not (= mag 1))))
2417         (let* ((where (case func-name
2418                         ((magnifyMusic) context)
2419                         ((magnifyStaff) (ly:context-find context 'Staff))))
2420                (fontSize (ly:context-property where 'fontSize 0))
2421                (new-fontSize (+ fontSize (magnification->font-size mag))))
2422           (ly:context-set-property! where 'fontSize new-fontSize))))))
2423
2424 (define-public (revert-fontSize func-name mag)
2425   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Calculate
2426 the previous @code{fontSize} value (before scaling) by factoring out the
2427 magnification factor @var{mag} (if @var{func-name} is
2428 @code{'magnifyMusic}), or by factoring out the context property
2429 @code{magnifyStaffValue} (if @var{func-name} is @code{'magnifyStaff}).
2430 Revert the @code{fontSize} in the appropriate context accordingly.
2431
2432 With @code{\\magnifyMusic}, the scaling is reverted after the music
2433 block it operates on.  @code{\\magnifyStaff} does not operate on a music
2434 block, so the scaling from a previous call (if there is one) is reverted
2435 before the new scaling takes effect."
2436   (make-apply-context
2437     (lambda (context)
2438       (if (or (eq? func-name 'magnifyMusic)
2439               ;; for \magnifyStaff...
2440               (and
2441                 ;; don't revert the user's fontSize choice
2442                 ;; the first time \magnifyStaff is called
2443                 (magnifyStaff-is-set? context mag)
2444                 ;; only revert the previous fontSize
2445                 ;; if staff magnification is changing
2446                 (staff-magnification-is-changing? context mag)))
2447         (let* ((where
2448                  (case func-name
2449                    ((magnifyMusic) context)
2450                    ((magnifyStaff) (ly:context-find context 'Staff))))
2451                (old-mag
2452                  (case func-name
2453                    ((magnifyMusic) mag)
2454                    ((magnifyStaff)
2455                     (ly:context-property where 'magnifyStaffValue 1))))
2456                (fontSize (ly:context-property where 'fontSize 0))
2457                (old-fontSize (- fontSize (magnification->font-size old-mag))))
2458           (ly:context-set-property! where 'fontSize old-fontSize))))))
2459
2460 (define-public (scale-props func-name mag allowed-to-shrink? props)
2461   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  For each
2462 prop in @var{props}, find the current value of the requested prop, scale
2463 it by the magnification factor @var{mag}, and do the equivalent of a
2464 @code{\\temporary@tie{}\\override} with the new value in the appropriate
2465 context.  If @var{allowed-to-shrink?} is @code{#f}, don't let the new
2466 value be less than the current value.  @var{func-name} is either
2467 @code{'magnifyMusic} or @code{'magnifyStaff}.  The @var{props} list is
2468 formatted like:
2469 @example
2470 '((Stem thickness)
2471   (Slur line-thickness)
2472   ...)
2473 @end example"
2474   (make-apply-context
2475     (lambda (context)
2476       (define (scale-prop grob-prop-list)
2477         (let* ((grob (car grob-prop-list))
2478                (prop (cadr grob-prop-list))
2479                (where (if (eq? grob 'SpacingSpanner)
2480                         (ly:context-find context 'Score)
2481                         (case func-name
2482                           ((magnifyMusic) context)
2483                           ((magnifyStaff) (ly:context-find context 'Staff)))))
2484                (grob-def (ly:context-grob-definition where grob)))
2485           (if (eq? prop 'space-alist)
2486             (let* ((space-alist (ly:assoc-get prop grob-def))
2487                    (scale-spacing-tuple (lambda (x)
2488                                           (cons (car x)
2489                                                 (cons (cadr x)
2490                                                       (* mag (cddr x))))))
2491                    (scaled-tuples (if space-alist
2492                                       (map scale-spacing-tuple space-alist)
2493                                       '()))
2494                    (new-alist (append scaled-tuples space-alist)))
2495               (ly:context-pushpop-property where grob prop new-alist))
2496             (let* ((val (ly:assoc-get prop grob-def (case prop
2497                                                       ((baseline-skip) 3)
2498                                                       ((word-space)    0.6)
2499                                                       (else            1))))
2500                    (proc (lambda (x)
2501                            (if allowed-to-shrink?
2502                              (* x mag)
2503                              (* x (max 1 mag)))))
2504                    (new-val (if (number-pair? val)
2505                               (cons (proc (car val))
2506                                     (proc (cdr val)))
2507                               (proc val))))
2508               (ly:context-pushpop-property where grob prop new-val)))))
2509       (if (or (eq? func-name 'magnifyMusic)
2510               ;; for \magnifyStaff, only scale the properties
2511               ;; if staff magnification is changing
2512               ;; and does not equal 1
2513               (and (staff-magnification-is-changing? context mag)
2514                    (not (= mag 1))))
2515         (for-each scale-prop props)))))
2516
2517 (define-public (revert-props func-name mag props)
2518   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Revert each
2519 prop in @var{props} in the appropriate context.  @var{func-name} is
2520 either @code{'magnifyMusic} or @code{'magnifyStaff}.  The @var{props}
2521 list is formatted like:
2522 @example
2523 '((Stem thickness)
2524   (Slur line-thickness)
2525   ...)
2526 @end example"
2527   (make-apply-context
2528     (lambda (context)
2529       (define (revert-prop grob-prop-list)
2530         (let* ((grob (car grob-prop-list))
2531                (prop (cadr grob-prop-list))
2532                (where (if (eq? grob 'SpacingSpanner)
2533                         (ly:context-find context 'Score)
2534                         (case func-name
2535                           ((magnifyMusic) context)
2536                           ((magnifyStaff) (ly:context-find context 'Staff))))))
2537           (ly:context-pushpop-property where grob prop)))
2538       (if (or (eq? func-name 'magnifyMusic)
2539               ;; for \magnifyStaff...
2540               (and
2541                 ;; don't revert the user's property overrides
2542                 ;; the first time \magnifyStaff is called
2543                 (magnifyStaff-is-set? context mag)
2544                 ;; revert the overrides from the previous \magnifyStaff,
2545                 ;; but only if staff magnification is changing
2546                 (staff-magnification-is-changing? context mag)))
2547         (for-each revert-prop props)))))
2548
2549 ;; \magnifyMusic only
2550 (define-public (scale-beam-thickness mag)
2551   "Used by @code{\\magnifyMusic}.  Scaling @code{Beam.beam-thickness}
2552 exactly to the @var{mag} value will not work.  This uses two reference
2553 values for @code{beam-thickness} to determine an acceptable value when
2554 scaling, then does the equivalent of a
2555 @code{\\temporary@tie{}\\override} with the new value."
2556   (make-apply-context
2557     (lambda (context)
2558       (let* ((grob-def (ly:context-grob-definition context 'Beam))
2559              (val (ly:assoc-get 'beam-thickness grob-def 0.48))
2560              (ratio-to-default (/ val 0.48))
2561              ;; gives beam-thickness=0.48 when mag=1 (like default),
2562              ;; gives beam-thickness=0.35 when mag=0.63 (like CueVoice)
2563              (scaled-default (+ 119/925 (* mag 13/37)))
2564              (new-val (* scaled-default ratio-to-default)))
2565         (ly:context-pushpop-property context 'Beam 'beam-thickness new-val)))))
2566
2567 ;; tag management
2568 ;;
2569
2570 (define tag-groups (make-hash-table))
2571 (call-after-session (lambda () (hash-clear! tag-groups)))
2572
2573 (define-public (define-tag-group tags)
2574   "Define a tag-group consisting of the given @var{tags}, a@tie{}list
2575 of symbols.  Returns @code{#f} if successful, and an error message if
2576 there is a conflicting tag group definition."
2577   (cond ((not (symbol-list? tags)) (format #f (_ "not a symbol list: ~a") tags))
2578         ((any (lambda (tag) (hashq-ref tag-groups tag)) tags)
2579          => (lambda (group) (and (not (lset= eq? group tags))
2580                                  (format #f (_ "conflicting tag group ~a") group))))
2581         (else
2582          (for-each
2583           (lambda (elt) (hashq-set! tag-groups elt tags))
2584           tags)
2585          #f)))
2586
2587 (define-public (tag-group-get tag)
2588   "Return the tag group (as a list of symbols) that the given
2589 @var{tag} symbol belongs to, @code{#f} if none."
2590   (hashq-ref tag-groups tag))
2591
2592 (define-public (tags-remove-predicate tags)
2593   "Returns a predicate that returns @code{#f} for any music that is to
2594 be removed by @{\\removeWithTag} on the given symbol or list of
2595 symbols @var{tags}."
2596   (if (symbol? tags)
2597       (lambda (m)
2598         (not (memq tags (ly:music-property m 'tags))))
2599       (lambda (m)
2600         (not (any (lambda (t) (memq t tags))
2601                   (ly:music-property m 'tags))))))
2602
2603 (define-public (tags-keep-predicate tags)
2604   "Returns a predicate that returns @code{#f} for any music that is to
2605 be removed by @{\\keepWithTag} on the given symbol or list of symbols
2606 @var{tags}."
2607   (if (symbol? tags)
2608       (let ((group (tag-group-get tags)))
2609         (lambda (m)
2610           (let ((music-tags (ly:music-property m 'tags)))
2611             (or
2612              (null? music-tags) ; redundant but very frequent
2613              ;; We know of only one tag to keep.  Either we find it in
2614              ;; the music tags, or all music tags must be from a
2615              ;; different group
2616              (memq tags music-tags)
2617              (not (any (lambda (t) (eq? (tag-group-get t) group)) music-tags))))))
2618       (let ((groups (delete-duplicates (map tag-group-get tags) eq?)))
2619         (lambda (m)
2620           (let ((music-tags (ly:music-property m 'tags)))
2621             (or
2622              (null? music-tags) ; redundant but very frequent
2623              (any (lambda (t) (memq t tags)) music-tags)
2624              ;; if no tag matches, no tag group should match either
2625              (not (any (lambda (t) (memq (tag-group-get t) groups)) music-tags))))))))