scm/music-functions.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2015 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;;                 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; for define-safe-public when byte-compiling using Guile V2
  20 (use-modules (scm safe-utility-defs))
  21
  22 (use-modules (ice-9 optargs))
  23 (use-modules (srfi srfi-11))
  24
  25 ;;; ly:music-property with setter
  26 ;;; (ly:music-property my-music 'elements)
  27 ;;;   ==> the 'elements property
  28 ;;; (set! (ly:music-property my-music 'elements) value)
  29 ;;;   ==> set the 'elements property and return it
  30 (define-public ly:music-property
  31   (make-procedure-with-setter ly:music-property
  32                               ly:music-set-property!))
  33
  34 (define-safe-public (music-is-of-type? mus type)
  35   "Does @code{mus} belong to the music class @code{type}?"
  36   (memq type (ly:music-property mus 'types)))
  37
  38 ;; TODO move this
  39 (define-public ly:grob-property
  40   (make-procedure-with-setter ly:grob-property
  41                               ly:grob-set-property!))
  42
  43 (define-public ly:grob-object
  44   (make-procedure-with-setter ly:grob-object
  45                               ly:grob-set-object!))
  46
  47 (define-public ly:grob-parent
  48   (make-procedure-with-setter ly:grob-parent
  49                               ly:grob-set-parent!))
  50
  51 (define-public ly:prob-property
  52   (make-procedure-with-setter ly:prob-property
  53                               ly:prob-set-property!))
  54
  55 (define-public ly:context-property
  56   (make-procedure-with-setter ly:context-property
  57                               ly:context-set-property!))
  58
  59 (define-public (music-map function music)
  60   "Apply @var{function} to @var{music} and all of the music it contains.
  61
  62 First it recurses over the children, then the function is applied to
  63 @var{music}."
  64   (let ((es (ly:music-property music 'elements))
  65         (e (ly:music-property music 'element)))
  66     (if (pair? es)
  67         (set! (ly:music-property music 'elements)
  68               (map (lambda (y) (music-map function y)) es)))
  69     (if (ly:music? e)
  70         (set! (ly:music-property music 'element)
  71               (music-map function  e)))
  72     (function music)))
  73
  74 (define-public (music-filter pred? music)
  75   "Filter out music expressions that do not satisfy @var{pred?}."
  76
  77   (define (inner-music-filter pred? music)
  78     "Recursive function."
  79     (let* ((es (ly:music-property music 'elements))
  80            (e (ly:music-property music 'element))
  81            (as (ly:music-property music 'articulations))
  82            (filtered-as (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) as)))
  83            (filtered-e (if (ly:music? e)
  84                            (inner-music-filter pred? e)
  85                            e))
  86            (filtered-es (filter ly:music? (map (lambda (y) (inner-music-filter pred? y)) es))))
  87       (if (not (null? e))
  88           (set! (ly:music-property music 'element) filtered-e))
  89       (if (not (null? es))
  90           (set! (ly:music-property music 'elements) filtered-es))
  91       (if (not (null? as))
  92           (set! (ly:music-property music 'articulations) filtered-as))
  93       ;; if filtering emptied the expression, we remove it completely.
  94       (if (or (not (pred? music))
  95               (and (eq? filtered-es '()) (not (ly:music? e))
  96                    (or (not (eq? es '()))
  97                        (ly:music? e))))
  98           (set! music '()))
  99       music))
 100
 101   (set! music (inner-music-filter pred? music))
 102   (if (ly:music? music)
 103       music
 104       (make-music 'Music)))       ;must return music.
 105
 106 (define*-public (display-music music #:optional (port (current-output-port)))
 107   "Display music, not done with @code{music-map} for clarity of
 108 presentation."
 109   (display music port)
 110   (display ": { " port)
 111   (let ((es (ly:music-property music 'elements))
 112         (e (ly:music-property music 'element)))
 113     (display (ly:music-mutable-properties music) port)
 114     (if (pair? es)
 115         (begin (display "\nElements: {\n" port)
 116                (for-each (lambda (m) (display-music m port)) es)
 117                (display "}\n" port)))
 118     (if (ly:music? e)
 119         (begin
 120           (display "\nChild:" port)
 121           (display-music e port))))
 122   (display " }\n" port)
 123   music)
 124
 125 ;;;
 126 ;;; A scheme music pretty printer
 127 ;;;
 128 (define (markup-expression->make-markup markup-expression)
 129   "Transform `markup-expression' into an equivalent, hopefuly readable, scheme expression.
 130 For instance,
 131   \\markup \\bold \\italic hello
 132 ==>
 133   (markup #:line (#:bold (#:italic (#:simple \"hello\"))))"
 134   (define (proc->command-keyword proc)
 135     "Return a keyword, eg. `#:bold', from the `proc' function, eg. #<procedure bold-markup (layout props arg)>"
 136     (let ((cmd-markup (symbol->string (procedure-name proc))))
 137       (symbol->keyword (string->symbol (substring cmd-markup 0 (- (string-length cmd-markup)
 138                                                                   (string-length "-markup")))))))
 139   (define (transform-arg arg)
 140     (cond ((and (pair? arg) (markup? (car arg))) ;; a markup list
 141            (append-map inner-markup->make-markup arg))
 142           ((and (not (string? arg)) (markup? arg)) ;; a markup
 143            (inner-markup->make-markup arg))
 144           (else                                  ;; scheme arg
 145            (music->make-music arg))))
 146   (define (inner-markup->make-markup mrkup)
 147     (if (string? mrkup)
 148         `(#:simple ,mrkup)
 149         (let ((cmd (proc->command-keyword (car mrkup)))
 150               (args (map transform-arg (cdr mrkup))))
 151           `(,cmd ,@args))))
 152   ;; body:
 153   (if (string? markup-expression)
 154       markup-expression
 155       `(markup ,@(inner-markup->make-markup markup-expression))))
 156
 157 (define-public (music->make-music obj)
 158   "Generate an expression that, once evaluated, may return an object
 159 equivalent to @var{obj}, that is, for a music expression, a
 160 @code{(make-music ...)} form."
 161   (define (if-nonzero num)
 162     (if (zero? num) '() (list num)))
 163   (cond (;; markup expression
 164          (markup? obj)
 165          (markup-expression->make-markup obj))
 166         (;; music expression
 167          (ly:music? obj)
 168          `(make-music
 169            ',(ly:music-property obj 'name)
 170            ,@(append-map (lambda (prop)
 171                            `(',(car prop)
 172                              ,(music->make-music (cdr prop))))
 173                          (remove (lambda (prop)
 174                                    (eqv? (car prop) 'origin))
 175                                  (ly:music-mutable-properties obj)))))
 176         (;; moment
 177          (ly:moment? obj)
 178          `(ly:make-moment
 179            ,@(let ((main (ly:moment-main obj))
 180                    (grace (ly:moment-grace obj)))
 181                (cond ((zero? grace) (list main))
 182                      ((negative? grace) (list main grace))
 183                      (else ;;positive grace requires 4-arg form
 184                       (list (numerator main)
 185                             (denominator main)
 186                             (numerator grace)
 187                             (denominator grace)))))))
 188         (;; note duration
 189          (ly:duration? obj)
 190          `(ly:make-duration ,(ly:duration-log obj)
 191                             ,@(if (= (ly:duration-scale obj) 1)
 192                                   (if-nonzero (ly:duration-dot-count obj))
 193                                   (list (ly:duration-dot-count obj)
 194                                         (ly:duration-scale obj)))))
 195         (;; note pitch
 196          (ly:pitch? obj)
 197          `(ly:make-pitch ,(ly:pitch-octave obj)
 198                          ,(ly:pitch-notename obj)
 199                          ,@(if-nonzero (ly:pitch-alteration obj))))
 200         (;; scheme procedure
 201          (procedure? obj)
 202          (or (procedure-name obj) obj))
 203         (;; a symbol (avoid having an unquoted symbol)
 204          (symbol? obj)
 205          `',obj)
 206         (;; an empty list (avoid having an unquoted empty list)
 207          (null? obj)
 208          `'())
 209         (;; a proper list
 210          (list? obj)
 211          `(list ,@(map music->make-music obj)))
 212         (;; a pair
 213          (pair? obj)
 214          `(cons ,(music->make-music (car obj))
 215                 ,(music->make-music (cdr obj))))
 216         (else
 217          obj)))
 218
 219 (use-modules (ice-9 pretty-print))
 220 (define*-public (display-scheme-music obj #:optional (port (current-output-port)))
 221   "Displays `obj', typically a music expression, in a friendly fashion,
 222 which often can be read back in order to generate an equivalent expression."
 223   (pretty-print (music->make-music obj) port)
 224   (newline port))
 225
 226 ;;;
 227 ;;; Scheme music expression --> Lily-syntax-using string translator
 228 ;;;
 229 (use-modules (srfi srfi-39)
 230              (scm display-lily))
 231
 232 (define*-public (display-lily-music expr parser #:optional (port (current-output-port))
 233                                     #:key force-duration)
 234   "Display the music expression using LilyPond syntax"
 235   (memoize-clef-names supported-clefs)
 236   (parameterize ((*indent* 0)
 237                  (*previous-duration* (ly:make-duration 2))
 238                  (*force-duration* force-duration))
 239                 (display (music->lily-string expr parser) port)
 240                 (newline port)))
 241
 242 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 243
 244 (define-public (shift-one-duration-log music shift dot)
 245   "Add @var{shift} to @code{duration-log} of @code{'duration} in
 246 @var{music} and optionally @var{dot} to any note encountered.
 247 The number of dots in the shifted music may not be less than zero."
 248   (let ((d (ly:music-property music 'duration)))
 249     (if (ly:duration? d)
 250         (let* ((cp (ly:duration-scale d))
 251                (nd (ly:make-duration
 252                     (+ shift (ly:duration-log d))
 253                     (max 0 (+ dot (ly:duration-dot-count d)))
 254                     cp)))
 255           (set! (ly:music-property music 'duration) nd)))
 256     ;clear cached length, since it's no longer valid
 257     (set! (ly:music-property music 'length) '())
 258     music))
 259
 260 (define-public (shift-duration-log music shift dot)
 261   (music-map (lambda (x) (shift-one-duration-log x shift dot))
 262              music))
 263
 264 (define-public (tremolo::get-music-list tremolo)
 265   "Given a tremolo repeat, return a list of music to engrave for it.
 266 This will be a stretched copy of its body, plus a TremoloEvent or
 267 TremoloSpanEvent.
 268
 269 This is called only by Chord_tremolo_iterator."
 270   (define (first-note-duration music)
 271     "Finds the duration of the first NoteEvent by searching
 272 depth-first through MUSIC."
 273     ;; NoteEvent or a non-expanded chord-repetition
 274     ;; We just take anything that actually sports an announced duration.
 275     (if (ly:duration? (ly:music-property music 'duration))
 276         (ly:music-property music 'duration)
 277         (let loop ((elts (if (ly:music? (ly:music-property music 'element))
 278                              (list (ly:music-property music 'element))
 279                              (ly:music-property music 'elements))))
 280           (and (pair? elts)
 281                (let ((dur (first-note-duration (car elts))))
 282                  (if (ly:duration? dur)
 283                      dur
 284                      (loop (cdr elts))))))))
 285   (let* ((times (ly:music-property tremolo 'repeat-count))
 286          (body (ly:music-property tremolo 'element))
 287          (children (if (music-is-of-type? body 'sequential-music)
 288                        ;; \repeat tremolo n { ... }
 289                        (length (extract-named-music body '(EventChord
 290                                                            NoteEvent)))
 291                        ;; \repeat tremolo n c4
 292                        1))
 293          (tremolo-type (if (positive? children)
 294                            (let* ((note-duration (first-note-duration body))
 295                                   (duration-log (if (ly:duration? note-duration)
 296                                                     (ly:duration-log note-duration)
 297                                                     1)))
 298                              (ash 1 duration-log))
 299                            '()))
 300          (stretched (ly:music-deep-copy body)))
 301     (if (positive? children)
 302         ;; # of dots is equal to the 1 in bitwise representation (minus 1)!
 303         (let* ((dots (1- (logcount (* times children))))
 304                ;; The remaining missing multiplier to scale the notes by
 305                ;; times * children
 306                (mult (/ (* times children (ash 1 dots)) (1- (ash 2 dots))))
 307                (shift (- (ly:intlog2 (floor mult)))))
 308           (if (not (and (integer? mult) (= (logcount mult) 1)))
 309               (ly:music-warning
 310                body
 311                (ly:format (_ "invalid tremolo repeat count: ~a") times)))
 312           ;; Make each note take the full duration
 313           (ly:music-compress stretched (ly:make-moment 1 children))
 314           ;; Adjust the displayed note durations
 315           (shift-duration-log stretched shift dots)))
 316     ;; Return the stretched body plus a tremolo event
 317     (if (= children 1)
 318         (list (make-music 'TremoloEvent
 319                           'repeat-count times
 320                           'tremolo-type tremolo-type
 321                           'origin (ly:music-property tremolo 'origin))
 322               stretched)
 323         (list (make-music 'TremoloSpanEvent
 324                           'span-direction START
 325                           'repeat-count times
 326                           'tremolo-type tremolo-type
 327                           'origin (ly:music-property tremolo 'origin))
 328               stretched
 329               (make-music 'TremoloSpanEvent
 330                           'span-direction STOP
 331                           'origin (ly:music-property tremolo 'origin))))))
 332
 333 (define-public (make-repeat name times main alts)
 334   "Create a repeat music expression, with all properties initialized
 335 properly."
 336   (let ((type (or (assoc-get name '(("volta" . VoltaRepeatedMusic)
 337                                     ("unfold" . UnfoldedRepeatedMusic)
 338                                     ("percent" . PercentRepeatedMusic)
 339                                     ("tremolo" . TremoloRepeatedMusic)))
 340                   (begin (ly:warning (_ "unknown repeat type `~S': must be volta, unfold, percent, or tremolo") name)
 341                          'VoltaRepeatedMusic)))
 342         (talts (if (< times (length alts))
 343                    (begin
 344                      (ly:warning (_ "More alternatives than repeats.  Junking excess alternatives"))
 345                      (take alts times))
 346                    alts)))
 347     (make-music type
 348                 'element main
 349                 'repeat-count (max times 1)
 350                 'elements talts)))
 351
 352 (define (calc-repeat-slash-count music)
 353   "Given the child-list @var{music} in @code{PercentRepeatMusic},
 354 calculate the number of slashes based on the durations.  Returns @code{0}
 355 if durations in @var{music} vary, allowing slash beats and double-percent
 356 beats to be distinguished."
 357   (let* ((durs (map duration-of-note
 358                     (extract-named-music music '(EventChord NoteEvent
 359                                                             RestEvent SkipEvent))))
 360          (first-dur (car durs)))
 361
 362     (if (every (lambda (d) (equal? d first-dur)) durs)
 363         (max (- (ly:duration-log first-dur) 2) 1)
 364         0)))
 365
 366 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 367 ;; clusters.
 368
 369 (define-public (note-to-cluster music)
 370   "Replace @code{NoteEvents} by @code{ClusterNoteEvents}."
 371   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 372       (make-music 'ClusterNoteEvent
 373                   'pitch (ly:music-property music 'pitch)
 374                   'duration (ly:music-property music 'duration))
 375       music))
 376
 377 (define-public (notes-to-clusters music)
 378   (music-map note-to-cluster music))
 379
 380 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 381 ;; repeats.
 382
 383 (define-public (unfold-repeats music)
 384   "Replace all repeats with unfolded repeats."
 385   (let ((es (ly:music-property music 'elements))
 386         (e (ly:music-property music 'element)))
 387     (if (music-is-of-type? music 'repeated-music)
 388         (set! music (make-music 'UnfoldedRepeatedMusic music)))
 389     (if (pair? es)
 390         (set! (ly:music-property music 'elements)
 391               (map unfold-repeats es)))
 392     (if (ly:music? e)
 393         (set! (ly:music-property music 'element)
 394               (unfold-repeats e)))
 395     music))
 396
 397 (define-public (unfold-repeats-fully music)
 398   "Unfolds repeats and expands the resulting @code{unfolded-repeated-music}."
 399   (map-some-music
 400    (lambda (m)
 401      (and (music-is-of-type? m 'unfolded-repeated-music)
 402           (make-sequential-music
 403            (ly:music-deep-copy
 404             (let ((n (ly:music-property m 'repeat-count))
 405                   (alts (ly:music-property m 'elements))
 406                   (body (ly:music-property m 'element)))
 407               (cond ((<= n 0) '())
 408                     ((null? alts) (make-list n body))
 409                     (else
 410                      (concatenate
 411                       (zip (make-list n body)
 412                            (append! (make-list (max 0 (- n (length alts)))
 413                                                (car alts))
 414                                     alts))))))))))
 415    (unfold-repeats music)))
 416
 417 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 418 ;; property setting music objs.
 419
 420 (define-safe-public (check-grob-path path #:optional parser location
 421                                      #:key
 422                                      (start 0)
 423                                      default
 424                                      (min 1)
 425                                      max)
 426   "Check a grob path specification @var{path}, a symbol list (or a
 427 single symbol), for validity and possibly complete it.  Returns the
 428 completed specification, or @code{#f} if invalid.  If optional
 429 @var{parser} is given, a syntax error is raised in that case,
 430 optionally using @var{location}.  If an optional keyword argument
 431 @code{#:start @var{start}} is given, the parsing starts at the given
 432 index in the sequence @samp{Context.Grob.property.sub-property...},
 433 with the default of @samp{0} implying the full path.
 434
 435 If there is no valid first element of @var{path} fitting at the given
 436 path location, an optionally given @code{#:default @var{default}} is
 437 used as the respective element instead without checking it for
 438 validity at this position.
 439
 440 The resulting path after possibly prepending @var{default} can be
 441 constrained in length by optional arguments @code{#:min @var{min}} and
 442 @code{#:max @var{max}}, defaulting to @samp{1} and unlimited,
 443 respectively."
 444   (let ((path (if (symbol? path) (list path) path)))
 445     ;; A Guile 1.x bug specific to optargs precludes moving the
 446     ;; defines out of the let
 447     (define (unspecial? s)
 448       (not (or (object-property s 'is-grob?)
 449                (object-property s 'backend-type?))))
 450     (define (grob? s)
 451       (object-property s 'is-grob?))
 452     (define (property? s)
 453       (object-property s 'backend-type?))
 454     (define (check c p) (c p))
 455
 456     (let* ((checkers
 457             (and (< start 3)
 458                  (drop (list unspecial? grob? property?) start)))
 459            (res
 460             (cond
 461              ((null? path)
 462               ;; tricky.  Should we make use of the default when the
 463               ;; list is empty?  In most cases, this question should be
 464               ;; academical as an empty list can only be generated by
 465               ;; Scheme and is likely an error.  We consider this a case
 466               ;; of "no valid first element, and default given".
 467               ;; Usually, invalid use cases should be caught later using
 468               ;; the #:min argument, and if the user explicitly does not
 469               ;; catch this, we just follow through.
 470               (if default (list default) '()))
 471              ((not checkers)
 472               ;; no checkers, so we have a valid first element and just
 473               ;; take the path as-is.
 474               path)
 475              (default
 476                (if ((car checkers) (car path))
 477                    (and (every check (cdr checkers) (cdr path))
 478                         path)
 479                    (and (every check (cdr checkers) path)
 480                         (cons default path))))
 481              (else
 482               (and (every check checkers path)
 483                    path)))))
 484       (if (and res
 485                (if max (<= min (length res) max)
 486                    (<= min (length res))))
 487           res
 488           (begin
 489             (if parser
 490                 (ly:parser-error parser
 491                                  (format #f (_ "bad grob property path ~a")
 492                                          path)
 493                                  location))
 494             #f)))))
 495
 496 (define-public (make-grob-property-set grob gprop val)
 497   "Make a @code{Music} expression that sets @var{gprop} to @var{val} in
 498 @var{grob}.  Does a pop first, i.e., this is not an override."
 499   (make-music 'OverrideProperty
 500               'symbol grob
 501               'grob-property gprop
 502               'grob-value val
 503               'pop-first #t))
 504
 505 (define-public (make-grob-property-override grob gprop val)
 506   "Make a @code{Music} expression that overrides @var{gprop} to @var{val}
 507 in @var{grob}."
 508   (make-music 'OverrideProperty
 509               'symbol grob
 510               'grob-property gprop
 511               'grob-value val))
 512
 513 (define-public (make-grob-property-revert grob gprop)
 514   "Revert the grob property @var{gprop} for @var{grob}."
 515   (make-music 'RevertProperty
 516               'symbol grob
 517               'grob-property gprop))
 518
 519 (define direction-polyphonic-grobs
 520   '(AccidentalSuggestion
 521     DotColumn
 522     Dots
 523     Fingering
 524     LaissezVibrerTie
 525     LigatureBracket
 526     MultiMeasureRest
 527     PhrasingSlur
 528     RepeatTie
 529     Rest
 530     Script
 531     Slur
 532     Stem
 533     TextScript
 534     Tie
 535     TupletBracket
 536     TrillSpanner))
 537
 538 (define general-grace-settings
 539   `((Voice Stem font-size -3)
 540     (Voice Flag font-size -3)
 541     (Voice NoteHead font-size -3)
 542     (Voice TabNoteHead font-size -4)
 543     (Voice Dots font-size -3)
 544     (Voice Stem length-fraction 0.8)
 545     (Voice Stem no-stem-extend #t)
 546     (Voice Beam beam-thickness 0.384)
 547     (Voice Beam length-fraction 0.8)
 548     (Voice Accidental font-size -4)
 549     (Voice AccidentalCautionary font-size -4)
 550     (Voice Script font-size -3)
 551     (Voice Fingering font-size -8)
 552     (Voice StringNumber font-size -8)))
 553
 554 (define-public score-grace-settings
 555   (append
 556     `((Voice Stem direction ,UP)
 557       (Voice Slur direction ,DOWN))
 558     general-grace-settings))
 559
 560 (define-safe-public (make-voice-props-set n)
 561   (make-sequential-music
 562    (append
 563     (map (lambda (x) (make-grob-property-set x 'direction
 564                                              (if (odd? n) -1 1)))
 565          direction-polyphonic-grobs)
 566     (list
 567      (make-property-set 'graceSettings general-grace-settings)
 568      (make-grob-property-set 'NoteColumn 'horizontal-shift (quotient n 2))))))
 569
 570 (define-safe-public (make-voice-props-override n)
 571   (make-sequential-music
 572    (append
 573     (map (lambda (x) (make-grob-property-override x 'direction
 574                                                   (if (odd? n) -1 1)))
 575          direction-polyphonic-grobs)
 576     (list
 577      (make-property-set 'graceSettings general-grace-settings)
 578      (make-grob-property-override 'NoteColumn 'horizontal-shift (quotient n 2))))))
 579
 580 (define-safe-public (make-voice-props-revert)
 581   (make-sequential-music
 582    (append
 583     (map (lambda (x) (make-grob-property-revert x 'direction))
 584          direction-polyphonic-grobs)
 585     (list (make-property-unset 'graceSettings)
 586           (make-grob-property-revert 'NoteColumn 'horizontal-shift)))))
 587
 588
 589 (define-safe-public (context-spec-music m context #:optional id)
 590   "Add \\context CONTEXT = ID to M."
 591   (let ((cm (make-music 'ContextSpeccedMusic
 592                         'element m
 593                         'context-type context)))
 594     (if (string? id)
 595         (set! (ly:music-property cm 'context-id) id))
 596     cm))
 597
 598 (define-public (descend-to-context m context)
 599   "Like @code{context-spec-music}, but only descending."
 600   (let ((cm (context-spec-music m context)))
 601     (ly:music-set-property! cm 'descend-only #t)
 602     cm))
 603
 604 (define-public (make-non-relative-music mus)
 605   (make-music 'UnrelativableMusic
 606               'element mus))
 607
 608 (define-public (make-apply-context func)
 609   (make-music 'ApplyContext
 610               'procedure func))
 611
 612 (define-public (make-sequential-music elts)
 613   (make-music 'SequentialMusic
 614               'elements elts))
 615
 616 (define-public (make-simultaneous-music elts)
 617   (make-music 'SimultaneousMusic
 618               'elements elts))
 619
 620 (define-safe-public (make-event-chord elts)
 621   (make-music 'EventChord
 622               'elements elts))
 623
 624 (define-public (make-skip-music dur)
 625   (make-music 'SkipMusic
 626               'duration dur))
 627
 628 (define-public (make-grace-music music)
 629   (make-music 'GraceMusic
 630               'element music))
 631
 632 ;;;;;;;;;;;;;;;;
 633
 634 ;; mmrest
 635 (define-public (make-multi-measure-rest duration location)
 636   (make-music 'MultiMeasureRestMusic
 637               'origin location
 638               'duration duration))
 639
 640 (define-public (make-property-set sym val)
 641   (make-music 'PropertySet
 642               'symbol sym
 643               'value val))
 644
 645 (define-public (make-property-unset sym)
 646   (make-music 'PropertyUnset
 647               'symbol sym))
 648
 649 (define-safe-public (make-articulation name . properties)
 650   (apply make-music 'ArticulationEvent
 651          'articulation-type name
 652          properties))
 653
 654 (define-public (make-lyric-event string duration)
 655   (make-music 'LyricEvent
 656               'duration duration
 657               'text string))
 658
 659 (define-safe-public (make-span-event type span-dir)
 660   (make-music type
 661               'span-direction span-dir))
 662
 663 (define-public (override-head-style heads style)
 664   "Override style for @var{heads} to @var{style}."
 665   (make-sequential-music
 666    (if (pair? heads)
 667        (map (lambda (h)
 668               (make-grob-property-override h 'style style))
 669             heads)
 670        (list (make-grob-property-override heads 'style style)))))
 671
 672 (define-public (revert-head-style heads)
 673   "Revert style for @var{heads}."
 674   (make-sequential-music
 675    (if (pair? heads)
 676        (map (lambda (h)
 677               (make-grob-property-revert h 'style))
 678             heads)
 679        (list (make-grob-property-revert heads 'style)))))
 680
 681 (define-public (style-note-heads heads style music)
 682   "Set @var{style} for all @var{heads} in @var{music}.  Works both
 683 inside of and outside of chord construct."
 684   ;; are we inside a <...>?
 685   (if (eq? (ly:music-property music 'name) 'NoteEvent)
 686       ;; yes -> use a tweak
 687       (begin
 688         (set! (ly:music-property music 'tweaks)
 689               (acons 'style style (ly:music-property music 'tweaks)))
 690         music)
 691       ;; not in <...>, so use overrides
 692       (make-sequential-music
 693        (list
 694         (override-head-style heads style)
 695         music
 696         (revert-head-style heads)))))
 697
 698 (define-public (set-mus-properties! m alist)
 699   "Set all of @var{alist} as properties of @var{m}."
 700   (if (pair? alist)
 701       (begin
 702         (set! (ly:music-property m (caar alist)) (cdar alist))
 703         (set-mus-properties! m (cdr alist)))))
 704
 705 (define-public (music-separator? m)
 706   "Is @var{m} a separator?"
 707   (let ((ts (ly:music-property m 'types)))
 708     (memq 'separator ts)))
 709
 710 ;;; expanding repeat chords
 711 (define-public (copy-repeat-chord original-chord repeat-chord duration
 712                                   event-types)
 713   "Copies all events in @var{event-types} (be sure to include
 714 @code{rhythmic-events}) from @var{original-chord} over to
 715 @var{repeat-chord} with their articulations filtered as well.  Any
 716 duration is replaced with the specified @var{duration}."
 717   ;; First remove everything from event-types that can already be
 718   ;; found in the repeated chord.  We don't need to look for
 719   ;; articulations on individual events since they can't actually get
 720   ;; into a repeat chord given its input syntax.
 721
 722   (define (keep-element? m)
 723     (any (lambda (t) (music-is-of-type? m t))
 724          event-types))
 725   (define origin (ly:music-property repeat-chord 'origin #f))
 726   (define (set-origin! l)
 727     (if origin
 728         (for-each (lambda (m) (set! (ly:music-property m 'origin) origin)) l))
 729     l)
 730
 731   (for-each
 732    (lambda (field)
 733      (for-each (lambda (e)
 734                  (for-each (lambda (x)
 735                              (set! event-types (delq x event-types)))
 736                            (ly:music-property e 'types)))
 737                (ly:music-property repeat-chord field)))
 738    '(elements articulations))
 739
 740   ;; now treat the elements
 741   (set! (ly:music-property repeat-chord 'elements)
 742         (let ((elts
 743                (set-origin! (ly:music-deep-copy
 744                              (filter keep-element?
 745                                      (ly:music-property original-chord
 746                                                         'elements))))))
 747           (for-each
 748            (lambda (m)
 749              (let ((arts (ly:music-property m 'articulations)))
 750                (if (pair? arts)
 751                    (set! (ly:music-property m 'articulations)
 752                          (set-origin! (filter! keep-element? arts))))
 753                (if (ly:duration? (ly:music-property m 'duration))
 754                    (set! (ly:music-property m 'duration) duration))
 755                (if (ly:music-property m 'cautionary #f)
 756                    (set! (ly:music-property m 'cautionary) #f))
 757                (if (ly:music-property m 'force-accidental #f)
 758                    (set! (ly:music-property m 'force-accidental) #f))))
 759            elts)
 760           (append! elts (ly:music-property repeat-chord 'elements))))
 761   (let ((arts (filter keep-element?
 762                       (ly:music-property original-chord
 763                                          'articulations))))
 764     (if (pair? arts)
 765         (set! (ly:music-property repeat-chord 'articulations)
 766               (append!
 767                (set-origin! (ly:music-deep-copy arts))
 768                (ly:music-property repeat-chord 'articulations)))))
 769   repeat-chord)
 770
 771
 772 (define-public (expand-repeat-chords! event-types music)
 773   "Walks through @var{music} and fills repeated chords (notable by
 774 having a duration in @code{duration}) with the notes from their
 775 respective predecessor chord."
 776   (let loop ((music music) (last-chord #f))
 777     (if (music-is-of-type? music 'event-chord)
 778         (let ((chord-repeat (ly:music-property music 'duration)))
 779           (cond
 780            ((not (ly:duration? chord-repeat))
 781             (if (any (lambda (m) (ly:duration?
 782                                   (ly:music-property m 'duration)))
 783                      (ly:music-property music 'elements))
 784                 music
 785                 last-chord))
 786            (last-chord
 787             (set! (ly:music-property music 'duration) '())
 788             (copy-repeat-chord last-chord music chord-repeat event-types))
 789            (else
 790             (ly:music-warning music (_ "Bad chord repetition"))
 791             #f)))
 792         (let ((elt (ly:music-property music 'element)))
 793           (fold loop (if (ly:music? elt) (loop elt last-chord) last-chord)
 794                 (ly:music-property music 'elements)))))
 795   music)
 796
 797 ;;; This does _not_ copy any articulations.  Rationale: one main
 798 ;;; incentive for pitch-repeating durations is after ties, such that
 799 ;;; 4~2~8. can stand in for a 15/16 note in \partial 4 position.  In
 800 ;;; this use case, any repeated articulations will be a nuisance.
 801 ;;;
 802 ;;; String assignments in TabStaff might seem like a worthwhile
 803 ;;; exception, but they would be better tackled by the respective
 804 ;;; engravers themselves (see issue 3662).
 805 ;;;
 806 ;;; Repeating chords as well seems problematic for things like
 807 ;;; \score {
 808 ;;;   <<
 809 ;;;     \new Staff { c4 c c <c e> }
 810 ;;;     \new RhythmicStaff { 4 4 4 4 }
 811 ;;;   >>
 812 ;;; }
 813 ;;;
 814 ;;; However, because of MIDI it is not advisable to use RhythmicStaff
 815 ;;; without any initial pitch/drum-type.  For music functions taking
 816 ;;; pure rhythms as an argument, the running of expand-repeat-notes!
 817 ;;; at scorification time is irrelevant: at that point of time, the
 818 ;;; music function has already run.
 819
 820 (define-public (expand-repeat-notes! music)
 821   "Walks through @var{music} and gives pitchless notes (not having a
 822 pitch in code{pitch} or a drum type in @code{drum-type}) the pitch(es)
 823 from the predecessor note/chord if available."
 824   (let ((last-pitch #f))
 825     (map-some-music
 826      (lambda (m)
 827        (define (set-and-ret last)
 828          (set! last-pitch last)
 829          m)
 830        (cond
 831         ((music-is-of-type? m 'event-chord)
 832          (if (any (lambda (m) (music-is-of-type? m 'rhythmic-event))
 833                   (ly:music-property m 'elements))
 834              (set! last-pitch m))
 835          m)
 836         ((music-is-of-type? m 'note-event)
 837          (cond
 838           ((or (ly:music-property m 'pitch #f)
 839                (ly:music-property m 'drum-type #f))
 840            => set-and-ret)
 841           ;; ok, naked rhythm.  Go through the various cases of
 842           ;; last-pitch
 843           ;; nothing available: just keep as-is
 844           ((not last-pitch) m)
 845           ((ly:pitch? last-pitch)
 846            (set! (ly:music-property m 'pitch) last-pitch)
 847            m)
 848           ((symbol? last-pitch)
 849            (set! (ly:music-property m 'drum-type) last-pitch)
 850            m)
 851           ;; Ok, this is the big bad one: the reference is a chord.
 852           ;; For now, we use the repeat chord logic.  That's not
 853           ;; really efficient as cleaning out all articulations is
 854           ;; quite simpler than what copy-repeat-chord does.
 855           (else
 856            (copy-repeat-chord last-pitch
 857                               (make-music 'EventChord
 858                                           'elements
 859                                           (ly:music-property m 'articulations)
 860                                           'origin
 861                                           (ly:music-property m 'origin))
 862                               (ly:music-property m 'duration)
 863                               '(rhythmic-event)))))
 864         (else #f)))
 865      music)))
 866
 867 ;;; splitting chords into voices.
 868 (define (voicify-list lst number)
 869   "Make a list of Musics.
 870
 871 voicify-list :: [ [Music ] ] -> number -> [Music]
 872 LST is a list music-lists.
 873
 874 NUMBER is 0-base, i.e., Voice=1 (upstems) has number 0.
 875 "
 876   (if (null? lst)
 877       '()
 878       (cons (context-spec-music
 879              (make-sequential-music
 880               (list (make-voice-props-set number)
 881                     (make-simultaneous-music (car lst))))
 882              'Bottom  (number->string (1+ number)))
 883             (voicify-list (cdr lst) (1+ number)))))
 884
 885 (define (voicify-chord ch)
 886   "Split the parts of a chord into different Voices using separator"
 887   (let ((es (ly:music-property ch 'elements)))
 888     (set! (ly:music-property  ch 'elements)
 889           (voicify-list (split-list-by-separator es music-separator?) 0))
 890     ch))
 891
 892 (define-public (voicify-music m)
 893   "Recursively split chords that are separated with @code{\\\\}."
 894   (if (not (ly:music? m))
 895       (ly:error (_ "music expected: ~S") m))
 896   (let ((es (ly:music-property m 'elements))
 897         (e (ly:music-property m 'element)))
 898
 899     (if (pair? es)
 900         (set! (ly:music-property m 'elements) (map voicify-music es)))
 901     (if (ly:music? e)
 902         (set! (ly:music-property m 'element)  (voicify-music e)))
 903     (if (and (equal? (ly:music-property m 'name) 'SimultaneousMusic)
 904              (any music-separator? es))
 905         (set! m (context-spec-music (voicify-chord m) 'Staff)))
 906     m))
 907
 908 (define-public (empty-music)
 909   (make-music 'Music))
 910
 911 ;; Make a function that checks score element for being of a specific type.
 912 (define-public (make-type-checker symbol)
 913   (lambda (elt)
 914     (grob::has-interface elt symbol)))
 915
 916 (define ((outputproperty-compatibility func sym val) grob g-context ao-context)
 917   (if (func grob)
 918       (set! (ly:grob-property grob sym) val)))
 919 (export outputproperty-compatibility)
 920
 921
 922 (define ((set-output-property grob-name symbol val)  grob grob-c context)
 923   "Usage example:
 924 @code{\\applyoutput #(set-output-property 'Clef 'extra-offset '(0 . 1))}"
 925   (let ((meta (ly:grob-property grob 'meta)))
 926     (if (equal? (assoc-get 'name meta) grob-name)
 927         (set! (ly:grob-property grob symbol) val))))
 928 (export set-output-property)
 929
 930
 931 (define-public (skip->rest mus)
 932   "Replace @var{mus} by @code{RestEvent} of the same duration if it is a
 933 @code{SkipEvent}.  Useful for extracting parts from crowded scores."
 934
 935   (if  (memq (ly:music-property mus 'name) '(SkipEvent SkipMusic))
 936        (make-music 'RestEvent 'duration (ly:music-property mus 'duration))
 937        mus))
 938
 939
 940 (define-public (music-has-type music type)
 941   (memq type (ly:music-property music 'types)))
 942
 943 (define-public (music-clone music . music-properties)
 944   "Clone @var{music} and set properties according to
 945 @var{music-properties}, a list of alternating property symbols and
 946 values:
 947 @example\n(music-clone start-span 'span-direction STOP)
 948 @end example
 949 Only properties that are not overriden by @var{music-properties} are
 950 actually fully cloned."
 951   (let ((old-props (list-copy (ly:music-mutable-properties music)))
 952         (new-props '())
 953         (m (ly:make-music (ly:prob-immutable-properties music))))
 954     (define (set-props mus-props)
 955       (if (and (not (null? mus-props))
 956                (not (null? (cdr mus-props))))
 957           (begin
 958             (set! old-props (assq-remove! old-props (car mus-props)))
 959             (set! new-props
 960                   (assq-set! new-props
 961                              (car mus-props) (cadr mus-props)))
 962             (set-props (cddr mus-props)))))
 963     (set-props music-properties)
 964     (for-each
 965      (lambda (pair)
 966        (set! (ly:music-property m (car pair))
 967              (ly:music-deep-copy (cdr pair))))
 968      old-props)
 969     (for-each
 970      (lambda (pair)
 971        (set! (ly:music-property m (car pair)) (cdr pair)))
 972      new-props)
 973     m))
 974
 975 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 976 ;; warn for bare chords at start.
 977
 978 (define-public (ly:music-message music msg . rest)
 979   (let ((ip (ly:music-property music 'origin)))
 980     (if (ly:input-location? ip)
 981         (apply ly:input-message ip msg rest)
 982         (apply ly:message msg rest))))
 983
 984 (define-public (ly:music-warning music msg . rest)
 985   (let ((ip (ly:music-property music 'origin)))
 986     (if (ly:input-location? ip)
 987         (apply ly:input-warning ip msg rest)
 988         (apply ly:warning msg rest))))
 989
 990 (define-public (ly:event-warning event msg . rest)
 991   (let ((ip (ly:event-property event 'origin)))
 992     (if (ly:input-location? ip)
 993         (apply ly:input-warning ip msg rest)
 994         (apply ly:warning msg rest))))
 995
 996 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 997 ;;
 998 ;; setting stuff for grace context.
 999 ;;
1000
1001 (define (vector-extend v x)
1002   "Make a new vector consisting of V, with X added to the end."
1003   (let* ((n (vector-length v))
1004          (nv (make-vector (+ n 1) '())))
1005     (vector-move-left! v 0 n nv 0)
1006     (vector-set! nv n x)
1007     nv))
1008
1009 (define (vector-map f v)
1010   "Map F over V.  This function returns nothing."
1011   (do ((n (vector-length v))
1012        (i 0 (+ i 1)))
1013       ((>= i n))
1014     (f (vector-ref v i))))
1015
1016 (define (vector-reverse-map f v)
1017   "Map F over V, N to 0 order.  This function returns nothing."
1018   (do ((i (- (vector-length v) 1) (- i 1)))
1019       ((< i 0))
1020     (f (vector-ref v i))))
1021
1022 (define-public (add-grace-property context-name grob sym val)
1023   "Set @var{sym}=@var{val} for @var{grob} in @var{context-name}."
1024   (define (set-prop context)
1025     (let* ((where (or (ly:context-find context context-name) context))
1026            (current (ly:context-property where 'graceSettings))
1027            (new-settings (append current
1028                                  (list (list context-name grob sym val)))))
1029       (ly:context-set-property! where 'graceSettings new-settings)))
1030   (make-apply-context set-prop))
1031
1032 (define-public (remove-grace-property context-name grob sym)
1033   "Remove all @var{sym} for @var{grob} in @var{context-name}."
1034   (define (sym-grob-context? property sym grob context-name)
1035     (and (eq? (car property) context-name)
1036          (eq? (cadr property) grob)
1037          (eq? (caddr property) sym)))
1038   (define (delete-prop context)
1039     (let* ((where (or (ly:context-find context context-name) context))
1040            (current (ly:context-property where 'graceSettings))
1041            (prop-settings (filter
1042                            (lambda(x) (sym-grob-context? x sym grob context-name))
1043                            current))
1044            (new-settings current))
1045       (for-each (lambda(x)
1046                   (set! new-settings (delete x new-settings)))
1047                 prop-settings)
1048       (ly:context-set-property! where 'graceSettings new-settings)))
1049   (make-apply-context delete-prop))
1050
1051
1052 (defmacro-public def-grace-function (start stop . docstring)
1053   "Helper macro for defining grace music"
1054   `(define-music-function (parser location music) (ly:music?)
1055      ,@docstring
1056      (make-music 'GraceMusic
1057                  'origin location
1058                  'element (make-music 'SequentialMusic
1059                                       'elements (list (ly:music-deep-copy ,start)
1060                                                       music
1061                                                       (ly:music-deep-copy ,stop))))))
1062
1063 (defmacro-public define-syntax-function (type args signature . body)
1064   "Helper macro for `ly:make-music-function'.
1065 Syntax:
1066   (define-syntax-function result-type? (parser location arg1 arg2 ...) (arg1-type arg2-type ...)
1067     ...function body...)
1068
1069 argX-type can take one of the forms @code{predicate?} for mandatory
1070 arguments satisfying the predicate, @code{(predicate?)} for optional
1071 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1072 value)}} for optional parameters with a specified default
1073 value (evaluated at definition time).  An optional parameter can be
1074 omitted in a call only when it can't get confused with a following
1075 parameter of different type.
1076
1077 @code{result-type?} can specify a default in the same manner as
1078 predicates, to be used in case of a type error in arguments or
1079 result."
1080
1081   (define (currying-lambda args doc-string? body)
1082     (if (and (pair? args)
1083              (pair? (car args)))
1084         (currying-lambda (car args) doc-string?
1085                          `((lambda ,(cdr args) ,@body)))
1086         `(lambda ,args
1087            ,(format #f "~a\n~a" (cddr args) (or doc-string? ""))
1088            ,@body)))
1089
1090   (set! signature (map (lambda (pred)
1091                          (if (pair? pred)
1092                              `(cons ,(car pred)
1093                                     ,(and (pair? (cdr pred)) (cadr pred)))
1094                              pred))
1095                        (cons type signature)))
1096
1097   (let ((docstring
1098          (and (pair? body) (pair? (cdr body))
1099               (if (string? (car body))
1100                   (car body)
1101                   (and (pair? (car body))
1102                        (eq? '_i (caar body))
1103                        (pair? (cdar body))
1104                        (string? (cadar body))
1105                        (null? (cddar body))
1106                        (cadar body))))))
1107     ;; When the music function definition contains an i10n doc string,
1108     ;; (_i "doc string"), keep the literal string only
1109     `(ly:make-music-function
1110       (list ,@signature)
1111       ,(currying-lambda args docstring (if docstring (cdr body) body)))))
1112
1113 (defmacro-public define-music-function rest
1114   "Defining macro returning music functions.
1115 Syntax:
1116   (define-music-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
1117     ...function body...)
1118
1119 argX-type can take one of the forms @code{predicate?} for mandatory
1120 arguments satisfying the predicate, @code{(predicate?)} for optional
1121 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1122 value)}} for optional parameters with a specified default
1123 value (evaluated at definition time).  An optional parameter can be
1124 omitted in a call only when it can't get confused with a following
1125 parameter of different type.
1126
1127 Must return a music expression.  The @code{origin} is automatically
1128 set to the @code{location} parameter."
1129
1130   `(define-syntax-function (ly:music? (make-music 'Music 'void #t)) ,@rest))
1131
1132
1133 (defmacro-public define-scheme-function rest
1134   "Defining macro returning Scheme functions.
1135 Syntax:
1136   (define-scheme-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
1137     ...function body...)
1138
1139 argX-type can take one of the forms @code{predicate?} for mandatory
1140 arguments satisfying the predicate, @code{(predicate?)} for optional
1141 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1142 value)}} for optional parameters with a specified default
1143 value (evaluated at definition time).  An optional parameter can be
1144 omitted in a call only when it can't get confused with a following
1145 parameter of different type.
1146
1147 Can return arbitrary expressions.  If a music expression is returned,
1148 its @code{origin} is automatically set to the @code{location}
1149 parameter."
1150
1151   `(define-syntax-function scheme? ,@rest))
1152
1153 (defmacro-public define-void-function rest
1154   "This defines a Scheme function like @code{define-scheme-function} with
1155 void return value (i.e., what most Guile functions with `unspecified'
1156 value return).  Use this when defining functions for executing actions
1157 rather than returning values, to keep Lilypond from trying to interpret
1158 the return value."
1159   `(define-syntax-function (void? *unspecified*) ,@rest *unspecified*))
1160
1161 (defmacro-public define-event-function rest
1162   "Defining macro returning event functions.
1163 Syntax:
1164   (define-event-function (parser location arg1 arg2 ...) (arg1-type? arg2-type? ...)
1165     ...function body...)
1166
1167 argX-type can take one of the forms @code{predicate?} for mandatory
1168 arguments satisfying the predicate, @code{(predicate?)} for optional
1169 parameters of that type defaulting to @code{#f}, @code{@w{(predicate?
1170 value)}} for optional parameters with a specified default
1171 value (evaluated at definition time).  An optional parameter can be
1172 omitted in a call only when it can't get confused with a following
1173 parameter of different type.
1174
1175 Must return an event expression.  The @code{origin} is automatically
1176 set to the @code{location} parameter."
1177
1178   `(define-syntax-function (ly:event? (make-music 'Event 'void #t)) ,@rest))
1179
1180 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1181
1182 (define-public (cue-substitute quote-music)
1183   "Must happen after @code{quote-substitute}."
1184
1185   (if (vector? (ly:music-property quote-music 'quoted-events))
1186       (let* ((dir (ly:music-property quote-music 'quoted-voice-direction))
1187              (clef (ly:music-property quote-music 'quoted-music-clef #f))
1188              (main-voice (case dir ((1) 1) ((-1) 0) (else #f)))
1189              (cue-voice (and main-voice (- 1 main-voice)))
1190              (cue-type (ly:music-property quote-music 'quoted-context-type #f))
1191              (cue-id (ly:music-property quote-music 'quoted-context-id))
1192              (main-music (ly:music-property quote-music 'element))
1193              (return-value quote-music))
1194
1195         (if main-voice
1196             (set! (ly:music-property quote-music 'element)
1197                   (make-sequential-music
1198                    (list
1199                     (make-voice-props-override main-voice)
1200                     main-music
1201                     (make-voice-props-revert)))))
1202
1203         ;; if we have stem dirs, change both quoted and main music
1204         ;; to have opposite stems.
1205
1206         ;; cannot context-spec Quote-music, since context
1207         ;; for the quotes is determined in the iterator.
1208
1209         (make-sequential-music
1210          (delq! #f
1211                 (list
1212                  (and clef (make-cue-clef-set clef))
1213                  (and cue-type cue-voice
1214                       (context-spec-music
1215                        (make-voice-props-override cue-voice)
1216                        cue-type cue-id))
1217                  quote-music
1218                  (and cue-type cue-voice
1219                       (context-spec-music
1220                        (make-voice-props-revert)
1221                        cue-type cue-id))
1222                  (and clef (make-cue-clef-unset))))))
1223       quote-music))
1224
1225 (define ((quote-substitute quote-tab) music)
1226   (let* ((quoted-name (ly:music-property music 'quoted-music-name))
1227          (quoted-vector (and (string? quoted-name)
1228                              (hash-ref quote-tab quoted-name #f))))
1229
1230
1231     (if (string? quoted-name)
1232         (if (vector? quoted-vector)
1233             (begin
1234               (set! (ly:music-property music 'quoted-events) quoted-vector)
1235               (set! (ly:music-property music 'iterator-ctor)
1236                     ly:quote-iterator::constructor))
1237             (ly:music-warning music (ly:format (_ "cannot find quoted music: `~S'") quoted-name))))
1238     music))
1239 (export quote-substitute)
1240
1241
1242 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1243 ;; switch it on here, so parsing and init isn't checked (too slow!)
1244 ;;
1245 ;; automatic music transformations.
1246
1247 (define (switch-on-debugging m)
1248   (if (defined? 'set-debug-cell-accesses!)
1249       (set-debug-cell-accesses! 15000))
1250   m)
1251
1252 (define (music-check-error music)
1253   (define found #f)
1254   (define (signal m)
1255     (if (and (ly:music? m)
1256              (eq? (ly:music-property m 'error-found) #t))
1257         (set! found #t)))
1258
1259   (for-each signal (ly:music-property music 'elements))
1260   (signal (ly:music-property music 'element))
1261
1262   (if found
1263       (set! (ly:music-property music 'error-found) #t))
1264   music)
1265
1266 (define (precompute-music-length music)
1267   (set! (ly:music-property music 'length)
1268         (ly:music-length music))
1269   music)
1270
1271 (define-public (make-duration-of-length moment)
1272   "Make duration of the given @code{moment} length."
1273   (ly:make-duration 0 0
1274                     (ly:moment-main-numerator moment)
1275                     (ly:moment-main-denominator moment)))
1276
1277 (define (make-skipped moment bool)
1278   "Depending on BOOL, set or unset skipTypesetting,
1279 then make SkipMusic of the given MOMENT length, and
1280 then revert skipTypesetting."
1281   (make-sequential-music
1282    (list
1283     (context-spec-music (make-property-set 'skipTypesetting bool)
1284                         'Score)
1285     (make-music 'SkipMusic 'duration
1286                 (make-duration-of-length moment))
1287     (context-spec-music (make-property-set 'skipTypesetting (not bool))
1288                         'Score))))
1289
1290 (define (skip-as-needed music parser)
1291   "Replace MUSIC by
1292  << {  \\set skipTypesetting = ##f
1293  LENGTHOF(\\showFirstLength)
1294  \\set skipTypesetting = ##t
1295  LENGTHOF(\\showLastLength) }
1296  MUSIC >>
1297  if appropriate.
1298
1299  When only showFirstLength is set,
1300  the 'length property of the music is
1301  overridden to speed up compiling."
1302   (let*
1303       ((show-last (ly:parser-lookup parser 'showLastLength))
1304        (show-first (ly:parser-lookup parser 'showFirstLength))
1305        (show-last-length (and (ly:music? show-last)
1306                               (ly:music-length show-last)))
1307        (show-first-length (and (ly:music? show-first)
1308                                (ly:music-length show-first)))
1309        (orig-length (ly:music-length music)))
1310
1311     ;;FIXME: if using either showFirst- or showLastLength,
1312     ;; make sure that skipBars is not set.
1313
1314     (cond
1315
1316      ;; both properties may be set.
1317      ((and show-first-length show-last-length)
1318       (let
1319           ((skip-length (ly:moment-sub orig-length show-last-length)))
1320         (make-simultaneous-music
1321          (list
1322           (make-sequential-music
1323            (list
1324             (make-skipped skip-length #t)
1325             ;; let's draw a separator between the beginning and the end
1326             (context-spec-music (make-property-set 'whichBar "||")
1327                                 'Timing)))
1328           (make-skipped show-first-length #f)
1329           music))))
1330
1331      ;; we may only want to print the last length
1332      (show-last-length
1333       (let
1334           ((skip-length (ly:moment-sub orig-length show-last-length)))
1335         (make-simultaneous-music
1336          (list
1337           (make-skipped skip-length #t)
1338           music))))
1339
1340      ;; we may only want to print the beginning; in this case
1341      ;; only the first length will be processed (much faster).
1342      (show-first-length
1343       ;; the first length must not exceed the original length.
1344       (if (ly:moment<? show-first-length orig-length)
1345           (set! (ly:music-property music 'length)
1346                 show-first-length))
1347       music)
1348
1349      (else music))))
1350
1351
1352 (define-session-public toplevel-music-functions
1353   (list
1354    (lambda (music parser) (expand-repeat-chords!
1355                            (cons 'rhythmic-event
1356                                  (ly:parser-lookup parser '$chord-repeat-events))
1357                            music))
1358    (lambda (music parser) (expand-repeat-notes! music))
1359    (lambda (music parser) (voicify-music music))
1360    (lambda (x parser) (music-map music-check-error x))
1361    (lambda (x parser) (music-map precompute-music-length x))
1362    (lambda (music parser)
1363
1364      (music-map (quote-substitute (ly:parser-lookup parser 'musicQuotes))  music))
1365
1366    ;; switch-on-debugging
1367    (lambda (x parser) (music-map cue-substitute x))
1368
1369    (lambda (x parser)
1370      (skip-as-needed x parser)
1371      )))
1372
1373 ;;;;;;;;;;
1374 ;;; general purpose music functions
1375
1376 (define (shift-octave pitch octave-shift)
1377   (_i "Add @var{octave-shift} to the octave of @var{pitch}.")
1378   (ly:make-pitch
1379    (+ (ly:pitch-octave pitch) octave-shift)
1380    (ly:pitch-notename pitch)
1381    (ly:pitch-alteration pitch)))
1382
1383
1384 ;;;;;;;;;;;;;;;;;
1385 ;; lyrics
1386
1387 (define (apply-durations lyric-music durations)
1388   (define (apply-duration music)
1389     (if (and (not (equal? (ly:music-length music) ZERO-MOMENT))
1390              (ly:duration?  (ly:music-property music 'duration)))
1391         (begin
1392           (set! (ly:music-property music 'duration) (car durations))
1393           (set! durations (cdr durations)))))
1394
1395   (music-map apply-duration lyric-music))
1396
1397
1398 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1399 ;; accidentals
1400
1401 (define (recent-enough? bar-number alteration-def laziness)
1402   (or (number? alteration-def)
1403       (equal? laziness #t)
1404       (<= bar-number (+ (cadr alteration-def) laziness))))
1405
1406 (define (accidental-invalid? alteration-def)
1407   "Checks an alteration entry for being invalid.
1408
1409 Non-key alterations are invalidated when tying into the next bar or
1410 when there is a clef change, since neither repetition nor cancellation
1411 can be omitted when the same note occurs again.
1412
1413 Returns @code{#f} or the reason for the invalidation, a symbol."
1414   (let* ((def (if (pair? alteration-def)
1415                   (car alteration-def)
1416                   alteration-def)))
1417     (and (symbol? def) def)))
1418
1419 (define (extract-alteration alteration-def)
1420   (cond ((number? alteration-def)
1421          alteration-def)
1422         ((pair? alteration-def)
1423          (car alteration-def))
1424         (else 0)))
1425
1426 (define (check-pitch-against-signature context pitch barnum laziness octaveness all-naturals)
1427   "Checks the need for an accidental and a @q{restore} accidental against
1428 @code{localAlterations} and @code{keyAlterations}.
1429 The @var{laziness} is the number of measures
1430 for which reminder accidentals are used (i.e., if @var{laziness} is zero,
1431 only cancel accidentals in the same measure; if @var{laziness} is three,
1432 we cancel accidentals up to three measures after they first appear.
1433 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1434 specifies whether accidentals should be canceled in different octaves.
1435 If @var{all-naturals} is ##t, notes that do not occur in @code{keyAlterations}
1436 also get an accidental."
1437   (let* ((ignore-octave (cond ((equal? octaveness 'any-octave) #t)
1438                               ((equal? octaveness 'same-octave) #f)
1439                               (else
1440                                (ly:warning (_ "Unknown octaveness type: ~S ") octaveness)
1441                                (ly:warning (_ "Defaulting to 'any-octave."))
1442                                #t)))
1443          (key (ly:context-property context 'keyAlterations))
1444          (local (ly:context-property context 'localAlterations))
1445          (notename (ly:pitch-notename pitch))
1446          (octave (ly:pitch-octave pitch))
1447          (pitch-handle (cons octave notename))
1448          (need-restore #f)
1449          (need-accidental #f)
1450          (previous-alteration #f)
1451          (from-other-octaves #f)
1452          (from-same-octave (assoc-get pitch-handle local))
1453          (from-key-sig (or (assoc-get notename local)
1454
1455                            ;; If no notename match is found from localAlterations, we may have a custom
1456                            ;; type with octave-specific entries of the form ((octave . pitch) alteration)
1457                            ;; instead of (pitch . alteration).  Since this type cannot coexist with entries in
1458                            ;; localAlterations, try extracting from keyAlterations instead.
1459                            (assoc-get pitch-handle key))))
1460
1461     ;; loop through localAlterations to search for a notename match from other octaves
1462     (let loop ((l local))
1463       (if (pair? l)
1464           (let ((entry (car l)))
1465             (if (and (pair? (car entry))
1466                      (= (cdar entry) notename))
1467                 (set! from-other-octaves (cdr entry))
1468                 (loop (cdr l))))))
1469
1470     ;; find previous alteration-def for comparison with pitch
1471     (cond
1472      ;; from same octave?
1473      ((and (not ignore-octave)
1474            from-same-octave
1475            (recent-enough? barnum from-same-octave laziness))
1476       (set! previous-alteration from-same-octave))
1477
1478      ;; from any octave?
1479      ((and ignore-octave
1480            from-other-octaves
1481            (recent-enough? barnum from-other-octaves laziness))
1482       (set! previous-alteration from-other-octaves))
1483
1484      ;; not recent enough, extract from key signature/local key signature
1485      (from-key-sig
1486       (set! previous-alteration from-key-sig)))
1487
1488     (if (accidental-invalid? previous-alteration)
1489         (set! need-accidental #t)
1490
1491         (let* ((prev-alt (extract-alteration previous-alteration))
1492                (this-alt (ly:pitch-alteration pitch)))
1493
1494           (if (or (and all-naturals (eq? #f previous-alteration)) (not (= this-alt prev-alt)))
1495               (begin
1496                 (set! need-accidental #t)
1497                 (if (and (not (= this-alt 0))
1498                          (and (< (abs this-alt) (abs prev-alt))
1499                               (> (* prev-alt this-alt) 0)))
1500                     (set! need-restore #t))))))
1501
1502     (cons need-restore need-accidental)))
1503
1504 (define ((make-accidental-rule octaveness laziness) context pitch barnum measurepos)
1505   "Create an accidental rule that makes its decision based on the octave of
1506 the note and a laziness value.
1507
1508 @var{octaveness} is either @code{'same-octave} or @code{'any-octave} and
1509 defines whether the rule should respond to accidental changes in other
1510 octaves than the current.  @code{'same-octave} is the normal way to typeset
1511 accidentals -- an accidental is made if the alteration is different from the
1512 last active pitch in the same octave.  @code{'any-octave} looks at the last
1513 active pitch in any octave.
1514
1515 @var{laziness} states over how many bars an accidental should be remembered.
1516 @code{0}@tie{}is the default -- accidental lasts over 0@tie{}bar lines, that
1517 is, to the end of current measure.  A positive integer means that the
1518 accidental lasts over that many bar lines.  @w{@code{-1}} is `forget
1519 immediately', that is, only look at key signature.  @code{#t} is `forever'."
1520
1521   (check-pitch-against-signature context pitch barnum laziness octaveness #f))
1522 (export make-accidental-rule)
1523
1524 (define ((make-accidental-dodecaphonic-rule octaveness laziness) context pitch barnum measurepos)
1525   "Variation on function make-accidental-rule that creates an dodecaphonic
1526 accidental rule."
1527
1528   (check-pitch-against-signature context pitch barnum laziness octaveness #t))
1529 (export make-accidental-dodecaphonic-rule)
1530
1531 (define (key-entry-notename entry)
1532   "Return the pitch of an @var{entry} in @code{localAlterations}.
1533 The @samp{car} of the entry is either of the form @code{notename} or
1534 of the form @code{(octave . notename)}.  The latter form is used for special
1535 key signatures or to indicate an explicit accidental.
1536
1537 The @samp{cdr} of the entry is either a rational @code{alter} indicating
1538 a key signature alteration, or of the form
1539 @code{(alter . (barnum . measurepos))} indicating an alteration caused by
1540 an accidental in music."
1541   (if (pair? (car entry))
1542       (cdar entry)
1543       (car entry)))
1544
1545 (define (key-entry-octave entry)
1546   "Return the octave of an entry in @code{localAlterations}
1547 or @code{#f} if the entry does not have an octave.
1548 See @code{key-entry-notename} for details."
1549   (and (pair? (car entry)) (caar entry)))
1550
1551 (define (key-entry-bar-number entry)
1552   "Return the bar number of an entry in @code{localAlterations}
1553 or @code {#f} if the entry does not have a bar number.
1554 See @code{key-entry-notename} for details."
1555   (and (pair? (cdr entry)) (caddr entry)))
1556
1557 (define (key-entry-measure-position entry)
1558   "Return the measure position of an entry in @code{localAlterations}
1559 or @code {#f} if the entry does not have a measure position.
1560 See @code{key-entry-notename} for details."
1561   (and (pair? (cdr entry)) (cdddr entry)))
1562
1563 (define (key-entry-alteration entry)
1564   "Return the alteration of an entry in localAlterations
1565
1566 For convenience, returns @code{0} if entry is @code{#f}."
1567   (if entry
1568       (if (number? (cdr entry))
1569           (cdr entry)
1570           (cadr entry))
1571       0))
1572
1573 (define-public (find-pitch-entry keysig pitch accept-global accept-local)
1574   "Return the first entry in @var{keysig} that matches @var{pitch}
1575 by notename and octave.  Alteration is not considered.
1576 @var{accept-global} states whether key signature entries should be included.
1577 @var{accept-local} states whether local accidentals should be included.
1578 If no matching entry is found, @var{#f} is returned."
1579   (and (pair? keysig)
1580        (let* ((entry (car keysig))
1581               (entryoct (key-entry-octave entry))
1582               (entrynn (key-entry-notename entry))
1583               (nn (ly:pitch-notename pitch)))
1584          (if (and (equal? nn entrynn)
1585                   (or (not entryoct)
1586                       (= entryoct (ly:pitch-octave pitch)))
1587                   (if (key-entry-bar-number entry)
1588                       accept-local
1589                       accept-global))
1590              entry
1591              (find-pitch-entry (cdr keysig) pitch accept-global accept-local)))))
1592
1593 (define-public (neo-modern-accidental-rule context pitch barnum measurepos)
1594   "An accidental rule that typesets an accidental if it differs from the
1595 key signature @emph{and} does not directly follow a note on the same
1596 staff line.  This rule should not be used alone because it does neither
1597 look at bar lines nor different accidentals at the same note name."
1598   (let* ((keysig (ly:context-property context 'localAlterations))
1599          (entry (find-pitch-entry keysig pitch #t #t)))
1600     (if (not entry)
1601         (cons #f #f)
1602         (let* ((global-entry (find-pitch-entry keysig pitch #t #f))
1603                (key-acc (key-entry-alteration global-entry))
1604                (acc (ly:pitch-alteration pitch))
1605                (entrymp (key-entry-measure-position entry))
1606                (entrybn (key-entry-bar-number entry)))
1607           (cons #f (not (or (equal? acc key-acc)
1608                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1609
1610 (define-public (dodecaphonic-no-repeat-rule context pitch barnum measurepos)
1611   "An accidental rule that typesets an accidental before every
1612 note (just as in the dodecaphonic accidental style) @emph{except} if
1613 the note is immediately preceded by a note with the same pitch. This
1614 is a common accidental style in contemporary notation."
1615    (let* ((keysig (ly:context-property context 'localAlterations))
1616           (entry (find-pitch-entry keysig pitch #f #t)))
1617      (if (not entry)
1618          (cons #f #t)
1619          (let ((entrymp (key-entry-measure-position entry))
1620                (entrybn (key-entry-bar-number entry))
1621                (entryalt (key-entry-alteration entry))
1622                (alt (ly:pitch-alteration pitch)))
1623            (cons #t
1624                  (not (and (equal? entrybn barnum)
1625                            (or (equal? measurepos entrymp)
1626                                (ly:moment<? measurepos entrymp))
1627                            (equal? entryalt alt))))))))
1628
1629 (define-public (teaching-accidental-rule context pitch barnum measurepos)
1630   "An accidental rule that typesets a cautionary accidental if it is
1631 included in the key signature @emph{and} does not directly follow a note
1632 on the same staff line."
1633   (let* ((keysig (ly:context-property context 'localAlterations))
1634          (entry (find-pitch-entry keysig pitch #t #t)))
1635     (if (not entry)
1636         (cons #f #f)
1637         (let* ((global-entry (find-pitch-entry keysig pitch #f #f))
1638                (key-acc (key-entry-alteration global-entry))
1639                (acc (ly:pitch-alteration pitch))
1640                (entrymp (key-entry-measure-position entry))
1641                (entrybn (key-entry-bar-number entry)))
1642           (cons #f (not (or (equal? acc key-acc)
1643                             (and (equal? entrybn barnum) (equal? entrymp measurepos)))))))))
1644
1645 (define-public (set-accidentals-properties extra-natural
1646                                            auto-accs auto-cauts
1647                                            context)
1648   (context-spec-music
1649    (make-sequential-music
1650     (append (if (boolean? extra-natural)
1651                 (list (make-property-set 'extraNatural extra-natural))
1652                 '())
1653             (list (make-property-set 'autoAccidentals auto-accs)
1654                   (make-property-set 'autoCautionaries auto-cauts))))
1655    context))
1656
1657 (define-public (set-accidental-style style . rest)
1658   "Set accidental style to @var{style}.  Optionally take a context
1659 argument, e.g. @code{'Staff} or @code{'Voice}.  The context defaults
1660 to @code{Staff}, except for piano styles, which use @code{GrandStaff}
1661 as a context."
1662   (let ((context (if (pair? rest)
1663                      (car rest) 'Staff))
1664         (pcontext (if (pair? rest)
1665                       (car rest) 'GrandStaff)))
1666     (cond
1667      ;; accidentals as they were common in the 18th century.
1668      ((equal? style 'default)
1669       (set-accidentals-properties #t
1670                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1671                                   '()
1672                                   context))
1673      ;; accidentals from one voice do NOT get canceled in other voices
1674      ((equal? style 'voice)
1675       (set-accidentals-properties #t
1676                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1677                                   '()
1678                                   context))
1679      ;; accidentals as suggested by Kurt Stone, Music Notation in the 20th century.
1680      ;; This includes all the default accidentals, but accidentals also needs canceling
1681      ;; in other octaves and in the next measure.
1682      ((equal? style 'modern)
1683       (set-accidentals-properties #f
1684                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1685                                           ,(make-accidental-rule 'any-octave 0)
1686                                           ,(make-accidental-rule 'same-octave 1))
1687                                   '()
1688                                   context))
1689      ;; the accidentals that Stone adds to the old standard as cautionaries
1690      ((equal? style 'modern-cautionary)
1691       (set-accidentals-properties #f
1692                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1693                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1694                                           ,(make-accidental-rule 'same-octave 1))
1695                                   context))
1696      ;; same as modern, but accidentals different from the key signature are always
1697      ;; typeset - unless they directly follow a note of the same pitch.
1698      ((equal? style 'neo-modern)
1699       (set-accidentals-properties #f
1700                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1701                                           ,(make-accidental-rule 'any-octave 0)
1702                                           ,(make-accidental-rule 'same-octave 1)
1703                                           ,neo-modern-accidental-rule)
1704                                   '()
1705                                   context))
1706      ((equal? style 'neo-modern-cautionary)
1707       (set-accidentals-properties #f
1708                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1709                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1710                                           ,(make-accidental-rule 'same-octave 1)
1711                                           ,neo-modern-accidental-rule)
1712                                   context))
1713      ((equal? style 'neo-modern-voice)
1714       (set-accidentals-properties #f
1715                                   `(Voice ,(make-accidental-rule 'same-octave 0)
1716                                           ,(make-accidental-rule 'any-octave 0)
1717                                           ,(make-accidental-rule 'same-octave 1)
1718                                           ,neo-modern-accidental-rule
1719                                           Staff ,(make-accidental-rule 'same-octave 0)
1720                                           ,(make-accidental-rule 'any-octave 0)
1721                                           ,(make-accidental-rule 'same-octave 1)
1722                                           ,neo-modern-accidental-rule)
1723                                   '()
1724                                   context))
1725      ((equal? style 'neo-modern-voice-cautionary)
1726       (set-accidentals-properties #f
1727                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1728                                   `(Voice ,(make-accidental-rule 'any-octave 0)
1729                                           ,(make-accidental-rule 'same-octave 1)
1730                                           ,neo-modern-accidental-rule
1731                                           Staff ,(make-accidental-rule 'same-octave 0)
1732                                           ,(make-accidental-rule 'any-octave 0)
1733                                           ,(make-accidental-rule 'same-octave 1)
1734                                           ,neo-modern-accidental-rule)
1735                                   context))
1736      ;; Accidentals as they were common in dodecaphonic music with no tonality.
1737      ;; Each note gets one accidental.
1738      ((equal? style 'dodecaphonic)
1739       (set-accidentals-properties #f
1740                                   `(Staff ,(lambda (c p bn mp) '(#f . #t)))
1741                                   '()
1742                                   context))
1743      ;; As in dodecaphonic style with the exception that immediately
1744      ;; repeated notes (in the same voice) don't get an accidental
1745      ((equal? style 'dodecaphonic-no-repeat)
1746       (set-accidentals-properties #f
1747                                   `(Staff ,dodecaphonic-no-repeat-rule)
1748                                   '()
1749                                   context))
1750      ;; Variety of the dodecaphonic style. Each note gets an accidental,
1751      ;; except notes that were already handled in the same measure.
1752      ((equal? style 'dodecaphonic-first)
1753       (set-accidentals-properties #f
1754                                   `(Staff ,(make-accidental-dodecaphonic-rule 'same-octave 0))
1755                                   '()
1756                                   context))
1757
1758      ;; Multivoice accidentals to be read both by musicians playing one voice
1759      ;; and musicians playing all voices.
1760      ;; Accidentals are typeset for each voice, but they ARE canceled across voices.
1761      ((equal? style 'modern-voice)
1762       (set-accidentals-properties  #f
1763                                    `(Voice ,(make-accidental-rule 'same-octave 0)
1764                                            ,(make-accidental-rule 'any-octave 0)
1765                                            ,(make-accidental-rule 'same-octave 1)
1766                                            Staff ,(make-accidental-rule 'same-octave 0)
1767                                            ,(make-accidental-rule 'any-octave 0)
1768                                            ,(make-accidental-rule 'same-octave 1))
1769                                    '()
1770                                    context))
1771      ;; same as modernVoiceAccidental eccept that all special accidentals are typeset
1772      ;; as cautionaries
1773      ((equal? style 'modern-voice-cautionary)
1774       (set-accidentals-properties #f
1775                                   `(Voice ,(make-accidental-rule 'same-octave 0))
1776                                   `(Voice ,(make-accidental-rule 'any-octave 0)
1777                                           ,(make-accidental-rule 'same-octave 1)
1778                                           Staff ,(make-accidental-rule 'same-octave 0)
1779                                           ,(make-accidental-rule 'any-octave 0)
1780                                           ,(make-accidental-rule 'same-octave 1))
1781                                   context))
1782      ;; stone's suggestions for accidentals on grand staff.
1783      ;; Accidentals are canceled across the staves in the same grand staff as well
1784      ((equal? style 'piano)
1785       (set-accidentals-properties #f
1786                                   `(Staff ,(make-accidental-rule 'same-octave 0)
1787                                           ,(make-accidental-rule 'any-octave 0)
1788                                           ,(make-accidental-rule 'same-octave 1)
1789                                           GrandStaff
1790                                           ,(make-accidental-rule 'any-octave 0)
1791                                           ,(make-accidental-rule 'same-octave 1))
1792                                   '()
1793                                   pcontext))
1794      ((equal? style 'piano-cautionary)
1795       (set-accidentals-properties #f
1796                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1797                                   `(Staff ,(make-accidental-rule 'any-octave 0)
1798                                           ,(make-accidental-rule 'same-octave 1)
1799                                           GrandStaff
1800                                           ,(make-accidental-rule 'any-octave 0)
1801                                           ,(make-accidental-rule 'same-octave 1))
1802                                   pcontext))
1803
1804      ;; same as modern, but cautionary accidentals are printed for all sharp or flat
1805      ;; tones specified by the key signature.
1806      ((equal? style 'teaching)
1807       (set-accidentals-properties #f
1808                                   `(Staff ,(make-accidental-rule 'same-octave 0))
1809                                   `(Staff ,(make-accidental-rule 'same-octave 1)
1810                                           ,teaching-accidental-rule)
1811                                   context))
1812
1813      ;; do not set localAlterations when a note alterated differently from
1814      ;; localAlterations is found.
1815      ;; Causes accidentals to be printed at every note instead of
1816      ;; remembered for the duration of a measure.
1817      ;; accidentals not being remembered, causing accidentals always to
1818      ;; be typeset relative to the time signature
1819      ((equal? style 'forget)
1820       (set-accidentals-properties '()
1821                                   `(Staff ,(make-accidental-rule 'same-octave -1))
1822                                   '()
1823                                   context))
1824      ;; Do not reset the key at the start of a measure.  Accidentals will be
1825      ;; printed only once and are in effect until overridden, possibly many
1826      ;; measures later.
1827      ((equal? style 'no-reset)
1828       (set-accidentals-properties '()
1829                                   `(Staff ,(make-accidental-rule 'same-octave #t))
1830                                   '()
1831                                   context))
1832      (else
1833       (ly:warning (_ "unknown accidental style: ~S") style)
1834       (make-sequential-music '())))))
1835
1836 (define-public (invalidate-alterations context)
1837   "Invalidate alterations in @var{context}.
1838
1839 Elements of @code{'localAlterations} corresponding to local
1840 alterations of the key signature have the form
1841 @code{'((octave . notename) . (alter barnum . measurepos))}.
1842 Replace them with a version where @code{alter} is set to @code{'clef}
1843 to force a repetition of accidentals.
1844
1845 Entries that conform with the current key signature are not invalidated."
1846   (let* ((keysig (ly:context-property context 'keyAlterations)))
1847     (set! (ly:context-property context 'localAlterations)
1848           (map-in-order
1849            (lambda (entry)
1850              (let* ((localalt (key-entry-alteration entry)))
1851                (if (or (accidental-invalid? localalt)
1852                        (not (key-entry-bar-number entry))
1853                        (= localalt
1854                           (key-entry-alteration
1855                            (find-pitch-entry
1856                             keysig
1857                             (ly:make-pitch (key-entry-octave entry)
1858                                            (key-entry-notename entry)
1859                                            0)
1860                             #t #t))))
1861                    entry
1862                    (cons (car entry) (cons 'clef (cddr entry))))))
1863            (ly:context-property context 'localAlterations)))))
1864
1865 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1866
1867 (define-public (skip-of-length mus)
1868   "Create a skip of exactly the same length as @var{mus}."
1869   (let* ((skip
1870           (make-music
1871            'SkipEvent
1872            'duration (ly:make-duration 0 0))))
1873
1874     (make-event-chord (list (ly:music-compress skip (ly:music-length mus))))))
1875
1876 (define-public (mmrest-of-length mus)
1877   "Create a multi-measure rest of exactly the same length as @var{mus}."
1878
1879   (let* ((skip
1880           (make-multi-measure-rest
1881            (ly:make-duration 0 0) '())))
1882     (ly:music-compress skip (ly:music-length mus))
1883     skip))
1884
1885 (define-public (pitch-of-note event-chord)
1886   (let ((evs (filter (lambda (x)
1887                        (music-has-type x 'note-event))
1888                      (ly:music-property event-chord 'elements))))
1889
1890     (and (pair? evs)
1891          (ly:music-property (car evs) 'pitch))))
1892
1893 (define-public (duration-of-note event-chord)
1894   (cond
1895    ((pair? event-chord)
1896     (or (duration-of-note (car event-chord))
1897         (duration-of-note (cdr event-chord))))
1898    ((ly:music? event-chord)
1899     (let ((dur (ly:music-property event-chord 'duration)))
1900       (if (ly:duration? dur)
1901           dur
1902           (duration-of-note (ly:music-property event-chord 'elements)))))
1903    (else #f)))
1904
1905 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1906
1907 (define-public (map-some-music map? music)
1908   "Walk through @var{music}, transform all elements calling @var{map?}
1909 and only recurse if this returns @code{#f}.  @code{elements} or
1910 @code{articulations} that are not music expressions are discarded:
1911 this allows some amount of filtering.
1912
1913 @code{map-some-music} may overwrite the original @var{music}."
1914   (let loop ((music music))
1915     (or (map? music)
1916         (let ((elt (ly:music-property music 'element))
1917               (elts (ly:music-property music 'elements))
1918               (arts (ly:music-property music 'articulations)))
1919           (if (ly:music? elt)
1920               (set! (ly:music-property music 'element)
1921                     (loop elt)))
1922           (if (pair? elts)
1923               (set! (ly:music-property music 'elements)
1924                     (filter! ly:music? (map! loop elts))))
1925           (if (pair? arts)
1926               (set! (ly:music-property music 'articulations)
1927                     (filter! ly:music? (map! loop arts))))
1928           music))))
1929
1930 (define-public (for-some-music stop? music)
1931   "Walk through @var{music}, process all elements calling @var{stop?}
1932 and only recurse if this returns @code{#f}."
1933   (let loop ((music music))
1934     (if (not (stop? music))
1935         (let ((elt (ly:music-property music 'element)))
1936           (if (ly:music? elt)
1937               (loop elt))
1938           (for-each loop (ly:music-property music 'elements))
1939           (for-each loop (ly:music-property music 'articulations))))))
1940
1941 (define-public (fold-some-music pred? proc init music)
1942   "This works recursively on music like @code{fold} does on a list,
1943 calling @samp{(@var{pred?} music)} on every music element.  If
1944 @code{#f} is returned for an element, it is processed recursively
1945 with the same initial value of @samp{previous}, otherwise
1946 @samp{(@var{proc} music previous)} replaces @samp{previous}
1947 and no recursion happens.
1948 The top @var{music} is processed using @var{init} for @samp{previous}."
1949   (let loop ((music music) (previous init))
1950     (if (pred? music)
1951         (proc music previous)
1952         (fold loop
1953               (fold loop
1954                     (let ((elt (ly:music-property music 'element)))
1955                       (if (null? elt)
1956                           previous
1957                           (loop elt previous)))
1958                     (ly:music-property music 'elements))
1959               (ly:music-property music 'articulations)))))
1960
1961 (define-public (extract-music music pred?)
1962   "Return a flat list of all music matching @var{pred?} inside of
1963 @var{music}, not recursing into matches themselves."
1964   (reverse! (fold-some-music pred? cons '() music)))
1965
1966 (define-public (extract-named-music music music-name)
1967   "Return a flat list of all music named @var{music-name} (either a
1968 single event symbol or a list of alternatives) inside of @var{music},
1969 not recursing into matches themselves."
1970   (extract-music
1971    music
1972    (if (cheap-list? music-name)
1973        (lambda (m) (memq (ly:music-property m 'name) music-name))
1974        (lambda (m) (eq? (ly:music-property m 'name) music-name)))))
1975
1976 (define-public (extract-typed-music music type)
1977   "Return a flat list of all music with @var{type} (either a single
1978 type symbol or a list of alternatives) inside of @var{music}, not
1979 recursing into matches themselves."
1980   (extract-music
1981    music
1982    (if (cheap-list? type)
1983        (lambda (m)
1984          (any (lambda (t) (music-is-of-type? m t)) type))
1985        (lambda (m) (music-is-of-type? m type)))))
1986
1987 (define*-public (event-chord-wrap! music #:optional parser)
1988   "Wrap isolated rhythmic events and non-postevent events in
1989 @var{music} inside of an @code{EventChord}.  If the optional
1990 @var{parser} argument is given, chord repeats @samp{q} are expanded
1991 using the default settings.  Otherwise, you need to cater for them
1992 yourself."
1993   (map-some-music
1994    (lambda (m)
1995      (cond ((music-is-of-type? m 'event-chord)
1996             (if (pair? (ly:music-property m 'articulations))
1997                 (begin
1998                   (set! (ly:music-property m 'elements)
1999                         (append (ly:music-property m 'elements)
2000                                 (ly:music-property m 'articulations)))
2001                   (set! (ly:music-property m 'articulations) '())))
2002             m)
2003            ((music-is-of-type? m 'rhythmic-event)
2004             (let ((arts (ly:music-property m 'articulations)))
2005               (if (pair? arts)
2006                   (set! (ly:music-property m 'articulations) '()))
2007               (make-event-chord (cons m arts))))
2008            (else #f)))
2009    (if parser
2010        (expand-repeat-chords!
2011         (cons 'rhythmic-event
2012               (ly:parser-lookup parser '$chord-repeat-events))
2013         music)
2014        music)))
2015
2016 (define-public (event-chord-notes event-chord)
2017   "Return a list of all notes from @var{event-chord}."
2018   (filter
2019    (lambda (m) (eq? 'NoteEvent (ly:music-property m 'name)))
2020    (ly:music-property event-chord 'elements)))
2021
2022 (define-public (event-chord-pitches event-chord)
2023   "Return a list of all pitches from @var{event-chord}."
2024   (map (lambda (x) (ly:music-property x 'pitch))
2025        (event-chord-notes event-chord)))
2026
2027 (define-public (event-chord-reduce music)
2028   "Reduces event chords in @var{music} to their first note event,
2029 retaining only the chord articulations.  Returns the modified music."
2030   (map-some-music
2031    (lambda (m)
2032      (and (music-is-of-type? m 'event-chord)
2033           (let*-values (((notes arts) (partition
2034                                        (lambda (mus)
2035                                          (music-is-of-type? mus 'rhythmic-event))
2036                                        (ly:music-property m 'elements)))
2037                         ((dur) (ly:music-property m 'duration))
2038                         ((full-arts) (append arts
2039                                              (ly:music-property m 'articulations)))
2040                         ((first-note) (and (pair? notes) (car notes))))
2041             (cond (first-note
2042                    (set! (ly:music-property first-note 'articulations)
2043                          full-arts)
2044                    first-note)
2045                   ((ly:duration? dur)
2046                    ;; A repeat chord. Produce an unpitched note.
2047                    (make-music 'NoteEvent
2048                                'duration dur
2049                                'articulations full-arts))
2050                   (else
2051                    (ly:music-error m (_ "Missing duration"))
2052                    (make-music 'NoteEvent
2053                                'duration (ly:make-duration 2 0 0)
2054                                'articulations full-arts))))))
2055    music))
2056
2057
2058 (defmacro-public make-relative (variables reference music)
2059   "The list of pitch or music variables in @var{variables} is used as
2060 a sequence for creating relativable music from @var{music}.
2061
2062 When the constructed music is used outside of @code{\\relative}, it
2063 just reflects plugging in the @var{variables} into @var{music}.
2064
2065 The action inside of @code{\\relative}, however, is determined by
2066 first relativizing the surrogate @var{reference} with the variables
2067 plugged in and then using the variables relativized as a side effect
2068 of relativizing @var{reference} for evaluating @var{music}.
2069
2070 Since pitches don't have the object identity required for tracing the
2071 effect of the reference call, they are replaced @emph{only} for the
2072 purpose of evaluating @var{reference} with simple pitched note events.
2073
2074 The surrogate @var{reference} expression has to be written with that
2075 in mind.  In addition, it must @emph{not} contain @emph{copies} of
2076 music that is supposed to be relativized but rather the
2077 @emph{originals}.  This @emph{includes} the pitch expressions.  As a
2078 rule, inside of @code{#@{@dots{}#@}} variables must @emph{only} be
2079 introduced using @code{#}, never via the copying construct @code{$}.
2080 The reference expression will usually just be a sequential or chord
2081 expression naming all variables in sequence, implying that following
2082 music will be relativized according to the resulting pitch of the last
2083 or first variable, respectively.
2084
2085 Since the usual purpose is to create more complex music from general
2086 arguments and since music expression parts must not occur more than
2087 once, one @emph{does} generally need to use copying operators in the
2088 @emph{replacement} expression @var{music} when using an argument more
2089 than once there.  Using an argument more than once in @var{reference},
2090 in contrast, does not make sense.
2091
2092 There is another fine point to mind: @var{music} must @emph{only}
2093 contain freshly constructed elements or copied constructs.  This will
2094 be the case anyway for regular LilyPond code inside of
2095 @code{#@{@dots{}#@}}, but any other elements (apart from the
2096 @var{variables} themselves which are already copied) must be created
2097 or copied as well.
2098
2099 The reason is that it is usually permitted to change music in-place as
2100 long as one does a @var{ly:music-deep-copy} on it, and such a copy of
2101 the whole resulting expression will @emph{not} be able to copy
2102 variables/values inside of closures where the information for
2103 relativization is being stored.
2104 "
2105
2106   ;; pitch and music generator might be stored instead in music
2107   ;; properties, and it might make sense to create a music type of its
2108   ;; own for this kind of construct rather than using
2109   ;; RelativeOctaveMusic
2110   (define ((make-relative::to-relative-callback variables music-call ref-call)
2111            music pitch)
2112     (let* ((ref-vars (map (lambda (v)
2113                             (if (ly:pitch? v)
2114                                 (make-music 'NoteEvent 'pitch v)
2115                                 (ly:music-deep-copy v)))
2116                           variables))
2117            (after-pitch (ly:make-music-relative! (apply ref-call ref-vars) pitch))
2118            (actual-vars (map (lambda (v r)
2119                                (if (ly:pitch? v)
2120                                    (ly:music-property r 'pitch)
2121                                    r))
2122                              variables ref-vars))
2123            (rel-music (apply music-call actual-vars)))
2124       (set! (ly:music-property music 'element) rel-music)
2125       after-pitch))
2126   `(make-music 'RelativeOctaveMusic
2127                'to-relative-callback
2128                (,make-relative::to-relative-callback
2129                 (list ,@variables)
2130                 (lambda ,variables ,music)
2131                 (lambda ,variables ,reference))
2132                'element ,music))
2133
2134 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2135 ;; The following functions are all associated with the crossStaff
2136 ;;  function
2137
2138 (define (close-enough? x y)
2139   "Values are close enough to ignore the difference"
2140   (< (abs (- x y)) 0.0001))
2141
2142 (define (extent-combine extents)
2143   "Combine a list of extents"
2144   (if (pair? (cdr extents))
2145       (interval-union (car extents) (extent-combine (cdr extents)))
2146       (car extents)))
2147
2148 (define ((stem-connectable? ref root) stem)
2149   "Check if the stem is connectable to the root"
2150   ;; The root is always connectable to itself
2151   (or (eq? root stem)
2152       (and
2153        ;; Horizontal positions of the stems must be almost the same
2154        (close-enough? (car (ly:grob-extent root ref X))
2155                       (car (ly:grob-extent stem ref X)))
2156        ;; The stem must be in the direction away from the root's notehead
2157        (positive? (* (ly:grob-property root 'direction)
2158                      (- (car (ly:grob-extent stem ref Y))
2159                         (car (ly:grob-extent root ref Y))))))))
2160
2161 (define (stem-span-stencil span)
2162   "Connect stems if we have at least one stem connectable to the root"
2163   (let* ((system (ly:grob-system span))
2164          (root (ly:grob-parent span X))
2165          (stems (filter (stem-connectable? system root)
2166                         (ly:grob-object span 'stems))))
2167     (if (<= 2 (length stems))
2168         (let* ((yextents (map (lambda (st)
2169                                 (ly:grob-extent st system Y)) stems))
2170                (yextent (extent-combine yextents))
2171                (layout (ly:grob-layout root))
2172                (blot (ly:output-def-lookup layout 'blot-diameter)))
2173           ;; Hide spanned stems
2174           (for-each (lambda (st)
2175                       (set! (ly:grob-property st 'stencil) #f))
2176                     stems)
2177           ;; Draw a nice looking stem with rounded corners
2178           (ly:round-filled-box (ly:grob-extent root root X) yextent blot))
2179         ;; Nothing to connect, don't draw the span
2180         #f)))
2181
2182 (define ((make-stem-span! stems trans) root)
2183   "Create a stem span as a child of the cross-staff stem (the root)"
2184   (let ((span (ly:engraver-make-grob trans 'Stem '())))
2185     (ly:grob-set-parent! span X root)
2186     (set! (ly:grob-object span 'stems) stems)
2187     ;; Suppress positioning, the stem code is confused by this weird stem
2188     (set! (ly:grob-property span 'X-offset) 0)
2189     (set! (ly:grob-property span 'stencil) stem-span-stencil)))
2190
2191 (define-public (cross-staff-connect stem)
2192   "Set cross-staff property of the stem to this function to connect it to
2193 other stems automatically"
2194   #t)
2195
2196 (define (stem-is-root? stem)
2197   "Check if automatic connecting of the stem was requested.  Stems connected
2198 to cross-staff beams are cross-staff, but they should not be connected to
2199 other stems just because of that."
2200   (eq? cross-staff-connect (ly:grob-property-data stem 'cross-staff)))
2201
2202 (define (make-stem-spans! ctx stems trans)
2203   "Create stem spans for cross-staff stems"
2204   ;; Cannot do extensive checks here, just make sure there are at least
2205   ;; two stems at this musical moment
2206   (if (<= 2 (length stems))
2207       (let ((roots (filter stem-is-root? stems)))
2208         (for-each (make-stem-span! stems trans) roots))))
2209
2210 (define-public (Span_stem_engraver ctx)
2211   "Connect cross-staff stems to the stems above in the system"
2212   (let ((stems '()))
2213     (make-engraver
2214      ;; Record all stems for the given moment
2215      (acknowledgers
2216       ((stem-interface trans grob source)
2217        (set! stems (cons grob stems))))
2218      ;; Process stems and reset the stem list to empty
2219      ((process-acknowledged trans)
2220       (make-stem-spans! ctx stems trans)
2221       (set! stems '())))))
2222
2223 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2224 ;; The following is used by the alterBroken function.
2225
2226 (define ((value-for-spanner-piece arg) grob)
2227   "Associate a piece of broken spanner @var{grob} with an element
2228 of list @var{arg}."
2229   (let* ((orig (ly:grob-original grob))
2230          (siblings (ly:spanner-broken-into orig)))
2231
2232     (define (helper sibs arg)
2233       (if (null? arg)
2234           arg
2235           (if (eq? (car sibs) grob)
2236               (car arg)
2237               (helper (cdr sibs) (cdr arg)))))
2238
2239     (if (>= (length siblings) 2)
2240         (helper siblings arg)
2241         (car arg))))
2242 (export value-for-spanner-piece)
2243
2244 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2245 ;; The following are used by the \offset function
2246
2247 (define (find-value-to-offset prop self alist)
2248   "Return the first value of the property @var{prop} in the property
2249 alist @var{alist} -- after having found @var{self}.  If @var{self} is
2250 not found, return the first value of @var{prop}."
2251   (let ((segment (member (cons prop self) alist)))
2252     (if (not segment)
2253         (assoc-get prop alist)
2254         (assoc-get prop (cdr segment)))))
2255
2256 (define (offset-multiple-types arg offsets)
2257   "Displace @var{arg} by @var{offsets} if @var{arg} is a number, a
2258 number pair, or a list of number pairs.  If @var{offsets} is an empty
2259 list or if there is a type-mismatch, @var{arg} will be returned."
2260   (cond
2261     ((and (number? arg) (number? offsets))
2262      (+ arg offsets))
2263     ((and (number-pair? arg)
2264           (or (number? offsets)
2265               (number-pair? offsets)))
2266      (coord-translate arg offsets))
2267     ((and (number-pair-list? arg) (number-pair-list? offsets))
2268      (map
2269        (lambda (x y) (coord-translate x y))
2270        arg offsets))
2271     (else arg)))
2272
2273 (define-public (offsetter property offsets)
2274   "Apply @var{offsets} to the default values of @var{property} of @var{grob}.
2275 Offsets are restricted to immutable properties and values of type @code{number},
2276 @code{number-pair}, or @code{number-pair-list}."
2277   (define (self grob)
2278     (let* ((immutable (ly:grob-basic-properties grob))
2279            ; We need to search the basic-properties alist for our property to
2280            ; obtain values to offset.  Our search is complicated by the fact that
2281            ; calling the music function `offset' as an override conses a pair to
2282            ; the head of the alist.  This pair must be discounted.  The closure it
2283            ; contains is named `self' so it can be easily recognized.  If `offset'
2284            ; is called as a tweak, the basic-property alist is unaffected.
2285            (target (find-value-to-offset property self immutable))
2286            ; if target is a procedure, we need to apply it to our grob to calculate
2287            ; values to offset.
2288            (vals
2289              (if (procedure? target)
2290                  (target grob)
2291                  target))
2292            (can-type-be-offset?
2293              (or (number? vals)
2294                  (number-pair? vals)
2295                  (number-pair-list? vals))))
2296
2297       (if can-type-be-offset?
2298           ; '(+inf.0 . -inf.0) would offset to itself.  This will be confusing to a
2299           ; user unaware of the default value of the property, so issue a warning.
2300           (if (equal? empty-interval vals)
2301               (ly:warning "default '~a of ~a is ~a and can't be offset"
2302                 property grob vals)
2303               (let* ((orig (ly:grob-original grob))
2304                      (siblings
2305                        (if (ly:spanner? grob)
2306                            (ly:spanner-broken-into orig)
2307                            '()))
2308                      (total-found (length siblings))
2309                      ; Since there is some flexibility in input syntax,
2310                      ; structure of `offsets' is normalized.
2311                      (offsets
2312                        (if (or (not (pair? offsets))
2313                                (number-pair? offsets)
2314                                (and (number-pair-list? offsets)
2315                                     (number-pair-list? vals)))
2316                            (list offsets)
2317                            offsets)))
2318
2319                 (define (helper sibs offs)
2320                   ; apply offsets to the siblings of broken spanners
2321                   (if (pair? offs)
2322                       (if (eq? (car sibs) grob)
2323                           (offset-multiple-types vals (car offs))
2324                           (helper (cdr sibs) (cdr offs)))
2325                       vals))
2326
2327                 (if (>= total-found 2)
2328                     (helper siblings offsets)
2329                     (offset-multiple-types vals (car offsets)))))
2330
2331               (begin
2332                 (ly:warning "the property '~a of ~a cannot be offset" property grob)
2333                 vals))))
2334     ; return the closure named `self'
2335     self)
2336
2337
2338 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2339 ;; \magnifyMusic and \magnifyStaff
2340
2341 ;; defined as a function instead of a list because the
2342 ;; all-grob-descriptions alist is not available yet
2343 (define-public (find-named-props prop-name grob-descriptions)
2344   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  When
2345 @var{grob-descriptions} is equal to the @code{all-grob-descriptions}
2346 alist (defined in @file{scm/define-grobs.scm}), this will find all grobs
2347 that can have a value for the @var{prop-name} property, and return them
2348 as a list in the following format:
2349 @example
2350 '((grob prop-name)
2351   (grob prop-name)
2352   ...)
2353 @end example"
2354   (define (find-grobs-with-interface interface grob-descriptions)
2355     (define (has-this-interface? grob-desc)
2356       (let* ((meta (ly:assoc-get 'meta (cdr grob-desc)))
2357              (interfaces (ly:assoc-get 'interfaces meta '())))
2358         (memq interface interfaces)))
2359     (let* ((grob-descriptions-with-this-interface
2360              (filter has-this-interface? grob-descriptions))
2361            (grob-names-with-this-interface
2362              (map car grob-descriptions-with-this-interface)))
2363       grob-names-with-this-interface))
2364   (let* ((interface
2365            (case prop-name
2366              ((baseline-skip word-space) 'text-interface)
2367              ((space-alist)              'break-aligned-interface)
2368              (else (ly:programming-error
2369                      "find-named-props: no interface associated with ~s"
2370                      prop-name))))
2371          (grobs-with-this-prop
2372            (find-grobs-with-interface interface grob-descriptions)))
2373     (map (lambda (x) (list x prop-name))
2374          grobs-with-this-prop)))
2375
2376
2377 (define (magnifyStaff-is-set? context mag)
2378   (let* ((Staff (ly:context-find context 'Staff))
2379          (old-mag (ly:context-property Staff 'magnifyStaffValue)))
2380     (not (null? old-mag))))
2381
2382 (define (staff-magnification-is-changing? context mag)
2383   (let* ((Staff (ly:context-find context 'Staff))
2384          (old-mag (ly:context-property Staff 'magnifyStaffValue 1)))
2385     (not (= old-mag mag))))
2386
2387 (define-public (scale-fontSize func-name mag)
2388   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Look up the
2389 current @code{fontSize} in the appropriate context and scale it by the
2390 magnification factor @var{mag}.  @var{func-name} is either
2391 @code{'magnifyMusic} or @code{'magnifyStaff}."
2392   (make-apply-context
2393     (lambda (context)
2394       (if (or (eq? func-name 'magnifyMusic)
2395               ;; for \magnifyStaff, only scale the fontSize
2396               ;; if staff magnification is changing
2397               ;; and does not equal 1
2398               (and (staff-magnification-is-changing? context mag)
2399                    (not (= mag 1))))
2400         (let* ((where (case func-name
2401                         ((magnifyMusic) context)
2402                         ((magnifyStaff) (ly:context-find context 'Staff))))
2403                (fontSize (ly:context-property where 'fontSize 0))
2404                (new-fontSize (+ fontSize (magnification->font-size mag))))
2405           (ly:context-set-property! where 'fontSize new-fontSize))))))
2406
2407 (define-public (revert-fontSize func-name mag)
2408   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Calculate
2409 the previous @code{fontSize} value (before scaling) by factoring out the
2410 magnification factor @var{mag} (if @var{func-name} is
2411 @code{'magnifyMusic}), or by factoring out the context property
2412 @code{magnifyStaffValue} (if @var{func-name} is @code{'magnifyStaff}).
2413 Revert the @code{fontSize} in the appropriate context accordingly.
2414
2415 With @code{\\magnifyMusic}, the scaling is reverted after the music
2416 block it operates on.  @code{\\magnifyStaff} does not operate on a music
2417 block, so the scaling from a previous call (if there is one) is reverted
2418 before the new scaling takes effect."
2419   (make-apply-context
2420     (lambda (context)
2421       (if (or (eq? func-name 'magnifyMusic)
2422               ;; for \magnifyStaff...
2423               (and
2424                 ;; don't revert the user's fontSize choice
2425                 ;; the first time \magnifyStaff is called
2426                 (magnifyStaff-is-set? context mag)
2427                 ;; only revert the previous fontSize
2428                 ;; if staff magnification is changing
2429                 (staff-magnification-is-changing? context mag)))
2430         (let* ((where
2431                  (case func-name
2432                    ((magnifyMusic) context)
2433                    ((magnifyStaff) (ly:context-find context 'Staff))))
2434                (old-mag
2435                  (case func-name
2436                    ((magnifyMusic) mag)
2437                    ((magnifyStaff)
2438                     (ly:context-property where 'magnifyStaffValue 1))))
2439                (fontSize (ly:context-property where 'fontSize 0))
2440                (old-fontSize (- fontSize (magnification->font-size old-mag))))
2441           (ly:context-set-property! where 'fontSize old-fontSize))))))
2442
2443 (define-public (scale-props func-name mag allowed-to-shrink? props)
2444   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  For each
2445 prop in @var{props}, find the current value of the requested prop, scale
2446 it by the magnification factor @var{mag}, and do the equivalent of a
2447 @code{\\temporary@tie{}\\override} with the new value in the appropriate
2448 context.  If @var{allowed-to-shrink?} is @code{#f}, don't let the new
2449 value be less than the current value.  @var{func-name} is either
2450 @code{'magnifyMusic} or @code{'magnifyStaff}.  The @var{props} list is
2451 formatted like:
2452 @example
2453 '((Stem thickness)
2454   (Slur line-thickness)
2455   ...)
2456 @end example"
2457   (make-apply-context
2458     (lambda (context)
2459       (define (scale-prop grob-prop-list)
2460         (let* ((grob (car grob-prop-list))
2461                (prop (cadr grob-prop-list))
2462                (where (if (eq? grob 'SpacingSpanner)
2463                         (ly:context-find context 'Score)
2464                         (case func-name
2465                           ((magnifyMusic) context)
2466                           ((magnifyStaff) (ly:context-find context 'Staff)))))
2467                (grob-def (ly:context-grob-definition where grob)))
2468           (if (eq? prop 'space-alist)
2469             (let* ((space-alist (ly:assoc-get prop grob-def))
2470                    (scale-spacing-tuple (lambda (x)
2471                                           (cons (car x)
2472                                                 (cons (cadr x)
2473                                                       (* mag (cddr x))))))
2474                    (scaled-tuples (if space-alist
2475                                       (map scale-spacing-tuple space-alist)
2476                                       '()))
2477                    (new-alist (append scaled-tuples space-alist)))
2478               (ly:context-pushpop-property where grob prop new-alist))
2479             (let* ((val (ly:assoc-get prop grob-def (case prop
2480                                                       ((baseline-skip) 3)
2481                                                       ((word-space)    0.6)
2482                                                       (else            1))))
2483                    (proc (lambda (x)
2484                            (if allowed-to-shrink?
2485                              (* x mag)
2486                              (* x (max 1 mag)))))
2487                    (new-val (if (number-pair? val)
2488                               (cons (proc (car val))
2489                                     (proc (cdr val)))
2490                               (proc val))))
2491               (ly:context-pushpop-property where grob prop new-val)))))
2492       (if (or (eq? func-name 'magnifyMusic)
2493               ;; for \magnifyStaff, only scale the properties
2494               ;; if staff magnification is changing
2495               ;; and does not equal 1
2496               (and (staff-magnification-is-changing? context mag)
2497                    (not (= mag 1))))
2498         (for-each scale-prop props)))))
2499
2500 (define-public (revert-props func-name mag props)
2501   "Used by @code{\\magnifyMusic} and @code{\\magnifyStaff}.  Revert each
2502 prop in @var{props} in the appropriate context.  @var{func-name} is
2503 either @code{'magnifyMusic} or @code{'magnifyStaff}.  The @var{props}
2504 list is formatted like:
2505 @example
2506 '((Stem thickness)
2507   (Slur line-thickness)
2508   ...)
2509 @end example"
2510   (make-apply-context
2511     (lambda (context)
2512       (define (revert-prop grob-prop-list)
2513         (let* ((grob (car grob-prop-list))
2514                (prop (cadr grob-prop-list))
2515                (where (if (eq? grob 'SpacingSpanner)
2516                         (ly:context-find context 'Score)
2517                         (case func-name
2518                           ((magnifyMusic) context)
2519                           ((magnifyStaff) (ly:context-find context 'Staff))))))
2520           (ly:context-pushpop-property where grob prop)))
2521       (if (or (eq? func-name 'magnifyMusic)
2522               ;; for \magnifyStaff...
2523               (and
2524                 ;; don't revert the user's property overrides
2525                 ;; the first time \magnifyStaff is called
2526                 (magnifyStaff-is-set? context mag)
2527                 ;; revert the overrides from the previous \magnifyStaff,
2528                 ;; but only if staff magnification is changing
2529                 (staff-magnification-is-changing? context mag)))
2530         (for-each revert-prop props)))))
2531
2532 ;; \magnifyMusic only
2533 (define-public (scale-beam-thickness mag)
2534   "Used by @code{\\magnifyMusic}.  Scaling @code{Beam.beam-thickness}
2535 exactly to the @var{mag} value will not work.  This uses two reference
2536 values for @code{beam-thickness} to determine an acceptable value when
2537 scaling, then does the equivalent of a
2538 @code{\\temporary@tie{}\\override} with the new value."
2539   (make-apply-context
2540     (lambda (context)
2541       (let* ((grob-def (ly:context-grob-definition context 'Beam))
2542              (val (ly:assoc-get 'beam-thickness grob-def 0.48))
2543              (ratio-to-default (/ val 0.48))
2544              ;; gives beam-thickness=0.48 when mag=1 (like default),
2545              ;; gives beam-thickness=0.35 when mag=0.63 (like CueVoice)
2546              (scaled-default (+ 119/925 (* mag 13/37)))
2547              (new-val (* scaled-default ratio-to-default)))
2548         (ly:context-pushpop-property context 'Beam 'beam-thickness new-val)))))
2549
2550 ;; tag management
2551 ;;
2552
2553 (define tag-groups (make-hash-table))
2554 (call-after-session (lambda () (hash-clear! tag-groups)))
2555
2556 (define-public (define-tag-group tags)
2557   "Define a tag-group consisting of the given @var{tags}, a@tie{}list
2558 of symbols.  Returns @code{#f} if successful, and an error message if
2559 there is a conflicting tag group definition."
2560   (cond ((not (symbol-list? tags)) (format #f (_ "not a symbol list: ~a") tags))
2561         ((any (lambda (tag) (hashq-ref tag-groups tag)) tags)
2562          => (lambda (group) (and (not (lset= eq? group tags))
2563                                  (format #f (_ "conflicting tag group ~a") group))))
2564         (else
2565          (for-each
2566           (lambda (elt) (hashq-set! tag-groups elt tags))
2567           tags)
2568          #f)))
2569
2570 (define-public (tag-group-get tag)
2571   "Return the tag group (as a list of symbols) that the given
2572 @var{tag} symbol belongs to, @code{#f} if none."
2573   (hashq-ref tag-groups tag))
2574
2575 (define-public (tags-remove-predicate tags)
2576   "Returns a predicate that returns @code{#f} for any music that is to
2577 be removed by @{\\removeWithTag} on the given symbol or list of
2578 symbols @var{tags}."
2579   (if (symbol? tags)
2580       (lambda (m)
2581         (not (memq tags (ly:music-property m 'tags))))
2582       (lambda (m)
2583         (not (any (lambda (t) (memq t tags))
2584                   (ly:music-property m 'tags))))))
2585
2586 (define-public (tags-keep-predicate tags)
2587   "Returns a predicate that returns @code{#f} for any music that is to
2588 be removed by @{\\keepWithTag} on the given symbol or list of symbols
2589 @var{tags}."
2590   (if (symbol? tags)
2591       (let ((group (tag-group-get tags)))
2592         (lambda (m)
2593           (let ((music-tags (ly:music-property m 'tags)))
2594             (or
2595              (null? music-tags) ; redundant but very frequent
2596              ;; We know of only one tag to keep.  Either we find it in
2597              ;; the music tags, or all music tags must be from a
2598              ;; different group
2599              (memq tags music-tags)
2600              (not (any (lambda (t) (eq? (tag-group-get t) group)) music-tags))))))
2601       (let ((groups (delete-duplicates (map tag-group-get tags) eq?)))
2602         (lambda (m)
2603           (let ((music-tags (ly:music-property m 'tags)))
2604             (or
2605              (null? music-tags) ; redundant but very frequent
2606              (any (lambda (t) (memq t tags)) music-tags)
2607              ;; if no tag matches, no tag group should match either
2608              (not (any (lambda (t) (memq (tag-group-get t) groups)) music-tags))))))))