scm/modal-transforms.scm

   1 ;;; modal-transforms.scm --- Modal transposition, inversion, and retrograde.
   2
   3 ;; Copyright (C) 2011--2015 Ellis & Grant, Inc.
   4
   5 ;; Author: Michael Ellis <michael.f.ellis@gmail.com>
   6
   7 ;; COPYRIGHT NOTICE
   8
   9 ;; This program is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; This program is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  16 ;; or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 ;; for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with this program; if not, write to the Free Software
  21 ;; Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA.
  22
  23
  24 (define (transposer-factory scale)
  25   "Returns a transposer for the specified @var{scale}.
  26 It is an error if either argument to a transposer is not in the scale
  27 it was created with.  A transposer knows nothing about LilyPond
  28 internals.  It treats scales as an ordered list of arbitrary items and
  29 pitches as members of a scale.
  30 "
  31
  32   (define (index item lis)
  33     (list-index (lambda (x) (equal? item x)) lis))
  34
  35   (lambda (from-pitch to-pitch pitch)
  36     (cond
  37      ((not (member from-pitch scale))
  38       (ly:warning (_i "'from' pitch not in scale; ignoring"))
  39       pitch)
  40
  41      ((not (member to-pitch scale))
  42       (ly:warning (_i "'to' pitch not in scale; ignoring"))
  43       pitch)
  44
  45      ((not (member pitch scale))
  46       (ly:warning (_i "pitch to be transposed not in scale; ignoring"))
  47       pitch)
  48
  49      (else
  50       (list-ref scale
  51                 (modulo
  52                  (+ (index pitch scale)
  53                     (- (index to-pitch scale)
  54                        (index from-pitch scale)))
  55                  (length scale)))))))
  56
  57 (define (inverter-factory scale)
  58   "Returns an inverter for the specified @var{scale}.
  59 It is an error if either argument to an inverter
  60 is not in the scale it was created with.  An inverter knows nothing
  61 about LilyPond internals.  It treats scales as an ordered list of
  62 arbitrary items and pitches as members of a scale.
  63 "
  64
  65   (define (index item lis)
  66     (list-index (lambda (x) (equal? item x)) lis))
  67
  68   (lambda (around-pitch to-pitch pitch)
  69     (cond
  70      ((not (member around-pitch scale))
  71       (ly:warning (_i "'around' pitch not in scale; ignoring"))
  72       pitch)
  73
  74      ((not (member to-pitch scale))
  75       (ly:warning (_i "'to' pitch not in scale; ignoring"))
  76       pitch)
  77
  78      ((not (member pitch scale))
  79       (ly:warning (_i "pitch to be inverted not in scale; ignoring"))
  80       pitch)
  81
  82      (else
  83       (list-ref scale
  84                 (modulo
  85                  (+ (index to-pitch scale)
  86                     (- (index around-pitch scale)
  87                        (index pitch scale)))
  88                  (length scale)))))))
  89
  90 (define (replicate-modify lis n mod-proc)
  91   "Apply @code{(mod-proc lis n)} to each element of a list and
  92 concatenate the results.  Knows nothing of LilyPond internals."
  93   (cond
  94    ((< n 0)
  95     (ly:warning (_i "negative replication count; ignoring")))
  96    ((= n 0)
  97     '())
  98    ((= n 1)
  99     (mod-proc lis 1))
 100    ((> n 1)
 101     (append
 102      (replicate-modify lis (- n 1) mod-proc)
 103      (mod-proc lis n)))))
 104
 105
 106
 107 (define-public (change-pitches music converter)
 108   "Recurse through @var{music}, applying @var{converter} to pitches.
 109 Converter is typically a transposer or an inverter as defined above in
 110 this module, but may be user-defined.  The converter function must take
 111 a single pitch as its argument and return a new pitch.  These are
 112 LilyPond scheme pitches, e.g. @code{(ly:make-pitch 0 2 0)}
 113 "
 114   (let ((elements (ly:music-property music 'elements))
 115         (element (ly:music-property music 'element))
 116         (pitch (ly:music-property music 'pitch)))
 117
 118     (cond
 119      ((ly:pitch? pitch)
 120       (ly:music-set-property! music 'pitch (converter pitch)))
 121
 122      ((pair? elements)
 123       (for-each (lambda (x) (change-pitches x converter)) elements))
 124
 125      ((ly:music? element)
 126       (change-pitches element converter)))))
 127
 128
 129 (define (make-scale music)
 130   "Recurse through @var{music}, extracting pitches.
 131 Returns a list of pitch objects, e.g
 132 @code{'((ly:make-pitch 0 2 0) (ly:make-pitch 0 4 0) ... )}
 133 Typically used to construct a scale for input to
 134 @code{transposer-factory}."
 135
 136   (let ((elements (ly:music-property music 'elements))
 137         (element (ly:music-property music 'element))
 138         (pitch (ly:music-property music 'pitch)))
 139
 140     (cond
 141      ((ly:pitch? pitch)
 142       (list pitch))
 143
 144      ((pair? elements)
 145       (append-map make-scale elements))
 146
 147      ((ly:music? element)
 148       (make-scale element)))))
 149
 150 (define (make-extended-scale music)
 151   "Extend scale given by @var{music} by 5 octaves up and down."
 152   ;; This is a bit of a hack since, in theory, someone might want to
 153   ;; transpose further than 5 octaves from the original scale
 154   ;; definition.  In practice this seems unlikely to occur very often.
 155   (define extender
 156     (lambda (lis n)
 157       (map
 158        (lambda (i)
 159          (ly:make-pitch
 160           (+ (- n 6) (ly:pitch-octave i))
 161           (ly:pitch-notename i)
 162           (ly:pitch-alteration i)))
 163        lis)))
 164
 165   (let ((scale (make-scale music)))
 166     (replicate-modify scale 11 extender)))
 167
 168
 169 ;; ------------- PUBLIC FUNCTIONS -----------------------------
 170
 171 (define-public (make-modal-transposer from to scale)
 172   "Wrapper function for transposer-factory."
 173   (let ((transposer (transposer-factory (make-extended-scale scale))))
 174     (lambda (p)
 175       (transposer from to p))))
 176
 177 (define-public (make-modal-inverter around to scale)
 178   "Wrapper function for inverter-factory"
 179   (let ((inverter (inverter-factory (make-extended-scale scale))))
 180     (lambda (p)
 181       (inverter around to p))))
 182
 183
 184 (define-public (retrograde-music music)
 185   "Returns @var{music} in retrograde (reversed) order."
 186   ;; Included here to allow this module to provide a complete set of
 187   ;; common formal operations on motives, i.e transposition,
 188   ;; inversion and retrograding.
 189
 190   (define (reverse-span! m)
 191     ;; invert direction of two-sided spanners
 192     (let ((spd (ly:music-property m 'span-direction)))
 193       (if (ly:dir? spd)
 194           (begin
 195             (set! (ly:music-property m 'span-direction) (- spd))
 196             (case (ly:music-property m 'name)
 197               ((CrescendoEvent)
 198                (make-music 'DecrescendoEvent m))
 199               ((DecrescendoEvent)
 200                (make-music 'CrescendoEvent m))
 201               (else m)))
 202           m)))
 203
 204   ;; carryover is a possible list of tie events, the loop returns any
 205   ;; such trailing list from the given expression
 206   (define (loop m carryover)
 207     (define (filter-ties! m carryover field)
 208       (let ((vals (ly:music-property m field)))
 209         (if (pair? vals)
 210             (call-with-values
 211                 (lambda ()
 212                   (partition! (music-type-predicate
 213                                '(tie-event glissando-event)) vals))
 214               (lambda (ties no-ties)
 215                 (set! (ly:music-property m field)
 216                       (append! (map! reverse-span! no-ties) carryover))
 217                 ties))
 218             (begin
 219               (if (pair? carryover)
 220                   (set! (ly:music-property m field) carryover))
 221               '()))))
 222
 223     ;; The reversal will let some prefatory material stay in front of
 224     ;; the following element.  Most prominently single
 225     ;; overrides/reverts/sets/unsets and applyContext.  This does not
 226     ;; change the position of a clef (which will generally be useless
 227     ;; after retrograding) but it does not jumble the clef change
 228     ;; command internals.  Also, stuff like \once\override stays at
 229     ;; the affected element.
 230
 231     (define (prefatory? m)
 232       (or ((music-type-predicate
 233             '(apply-context apply-output-event layout-instruction-event)) m)
 234           (and
 235            (music-is-of-type? m 'music-wrapper-music)
 236            (prefatory? (ly:music-property m 'element)))))
 237
 238     (define (musiclistreverse lst)
 239       (let loop ((lst lst) (res '()) (zeros '()))
 240         (cond ((null? lst) (reverse! zeros res))
 241               ((prefatory? (car lst))
 242                (loop (cdr lst) res (cons (car lst) zeros)))
 243               (else
 244                (loop (cdr lst) (reverse! zeros (cons (car lst) res)) '())))))
 245
 246     (cond ((music-is-of-type? m 'event-chord)
 247            (let* ((chord-ties
 248                    (append!
 249                     (filter-ties! m carryover 'elements)
 250                     ;; articulations on an event-chord do not occur
 251                     ;; "naturally" but are supported when user-generated
 252                     ;; elsewhere, so we treat them properly
 253                     (filter-ties! m '() 'articulations)))
 254                   ;; in-chord ties are converted to per-chord ties.
 255                   ;; This is less than optimal but pretty much the
 256                   ;; best we can hope to achieve with this approach.
 257                   (element-ties
 258                    (append-map!
 259                     (lambda (m) (filter-ties! m '() 'articulations))
 260                     (ly:music-property m 'elements))))
 261              (append! chord-ties element-ties)))
 262
 263           ((music-is-of-type? m 'rhythmic-event)
 264            (filter-ties! m carryover 'articulations))
 265
 266           ;; The following is hardly correct but tieing inside of
 267           ;; <<...>> is really beyond our pay grade.
 268           ((music-is-of-type? m 'simultaneous-music)
 269            (append-map! (lambda (m) (loop m (ly:music-deep-copy carryover)))
 270                         (ly:music-property m 'elements)))
 271           (else
 272            (let ((elt (ly:music-property m 'element))
 273                  (elts (ly:music-property m 'elements)))
 274              (let ((res
 275                     (fold loop
 276                           (if (ly:music? elt) (loop elt carryover) carryover)
 277                           elts)))
 278                (if (ly:music? elt)
 279                    (set! (ly:music-property m 'element)
 280                          (reverse-span! elt)))
 281                (if (pair? elts)
 282                    (set! (ly:music-property m 'elements)
 283                          (map! reverse-span! (musiclistreverse elts))))
 284                (append! res (filter-ties! m '() 'articulations)))))))
 285   (let ((dangling (loop music '())))
 286     (for-each
 287      (lambda (t) (ly:music-warning t (_ "Dangling tie in \\retrograde")))
 288      dangling))
 289   music)
 290
 291 (define-public (pitch-invert around to music)
 292   "If @var{music} is a single pitch, inverts it about @var{around}
 293 and transposes from @var{around} to @var{to}."
 294   (let ((p (ly:music-property music 'pitch)))
 295     (if (ly:pitch? p)
 296         (ly:music-set-property!
 297          music 'pitch
 298          (ly:pitch-transpose to (ly:pitch-diff around p))))
 299     music))
 300
 301 (define-public (music-invert around to music)
 302   "Applies pitch-invert to all pitches in @var{music}."
 303   (music-map (lambda (x) (pitch-invert around to x)) music))