scm/layout-page-dump.scm

   1 ;;;; layout-page-tweaks.scm -- page breaking and page layout
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6 ;;;;     2006 Nicolas Sceaux <nicolas.sceaux@free.fr>
   7
   8 (define-module (scm layout-page-dump)
   9   #:use-module (srfi srfi-1)
  10   #:use-module (ice-9 pretty-print)
  11   #:use-module (scm paper-system)
  12   #:use-module (scm page)
  13   #:use-module (scm layout-page-layout)
  14   #:use-module (lily)
  15   #:export (write-page-breaks
  16             ;; utilisties for writing other page dump functions
  17             record-tweaks dump-all-tweaks))
  18
  19 (define (record-tweaks what property-pairs tweaks)
  20   (let ((key (ly:output-def-lookup (ly:grob-layout what)
  21                                    'tweak-key
  22                                    "tweaks"))
  23         (when (ly:grob-property what 'when)))
  24     (if (not (hash-ref tweaks key))
  25         (hash-set! tweaks key '()))
  26     (hash-set! tweaks key
  27                (acons when property-pairs
  28                       (hash-ref tweaks key)))))
  29
  30 (define (graceless-moment mom)
  31   (ly:make-moment (ly:moment-main-numerator mom)
  32                   (ly:moment-main-denominator mom)
  33                   0 0))
  34
  35 (define (moment->skip mom)
  36   (let ((main (if (> (ly:moment-main-numerator mom) 0)
  37                   (format "\\skip 1*~a/~a"
  38                           (ly:moment-main-numerator mom)
  39                           (ly:moment-main-denominator mom))
  40                     ""))
  41         (grace (if (< (ly:moment-grace-numerator mom) 0)
  42                    (format "\\grace { \\skip 1*~a/~a }"
  43                            (- (ly:moment-grace-numerator mom))
  44                            (ly:moment-grace-denominator mom))
  45                    "")))
  46     (format "~a~a" main grace)))
  47
  48 (define (dump-tweaks out-port tweak-list last-moment)
  49   (if (not (null? tweak-list))
  50       (let* ((now (caar tweak-list))
  51              (diff (ly:moment-sub now last-moment))
  52              (these-tweaks (cdar tweak-list))
  53              (skip (moment->skip diff))
  54              (line-break-str (if (assoc-get 'line-break these-tweaks #f)
  55                                  "\\break\n"
  56                                  ""))
  57              (page-break-str (if (assoc-get 'page-break these-tweaks #f)
  58                                  "\\pageBreak\n"
  59                                  ""))
  60              (space-tweaks (format "\\spacingTweaks #'~a\n"
  61                                    (with-output-to-string
  62                                      (lambda ()
  63                                        (pretty-print
  64                                         (assoc-get 'spacing-parameters
  65                                                    these-tweaks '()))))))
  66              (base (format "~a~a~a"
  67                            line-break-str
  68                            page-break-str
  69                            space-tweaks)))
  70         (format out-port "~a\n~a\n" skip base)
  71         (dump-tweaks out-port (cdr tweak-list) (graceless-moment now)))))
  72
  73 (define (dump-all-tweaks pages tweaks)
  74   (let* ((paper (ly:paper-book-paper (page-property  (car pages) 'paper-book)))
  75          (parser (ly:output-def-parser paper))
  76          (name  (format "~a-page-layout.ly"
  77                         (ly:parser-output-name parser)))
  78          (out-port (open-output-file name)))
  79     (ly:message "Writing page layout to ~a" name)
  80     (hash-for-each
  81      (lambda (key val)
  82        (format out-port "~a = {" key)
  83        (dump-tweaks out-port (reverse val) (ly:make-moment 0 1))
  84        (display "}" out-port))
  85      tweaks)
  86     (close-port out-port)))
  87
  88 (define (write-page-breaks pages)
  89   "Dump page breaks and tweaks"
  90   (let ((tweaks (make-hash-table 60)))
  91     (define (handle-page page)
  92       "Computes vertical stretch for each music line of `page' (starting by
  93       the smallest lines), then record the tweak parameters  of each line to
  94       the `tweaks' hash-table."
  95       (let* ((lines (page-property page 'lines))
  96              (line-count (length lines))
  97              (compute-max-stretch (ly:output-def-lookup
  98                                    (ly:paper-book-paper (page-property page
  99                                                                        'paper-book))
 100                                     'system-maximum-stretch-procedure))
 101              (page-number (page-property page 'page-number)))
 102         (let set-line-stretch! ((sorted-lines (sort lines
 103                                                     (lambda (l1 l2)
 104                                                       (< (line-height l1)
 105                                                          (line-height l2)))))
 106                                 (rest-height ;; sum of stretchable line heights
 107                                  (reduce + 0.0
 108                                          (map line-height
 109                                               (filter stretchable-line? lines))))
 110                                 (space-left (page-maximum-space-left page)))
 111           (if (not (null? sorted-lines))
 112               (let* ((line (first sorted-lines))
 113                      (height (line-height line))
 114                      (stretch (min (compute-max-stretch line)
 115                                    (if (and (stretchable-line? line)
 116                                             (positive? rest-height))
 117                                        (/ (* height space-left) rest-height)
 118                                        0.0))))
 119                 (set! (ly:prob-property line 'stretch) stretch)
 120                 (set-line-stretch! (cdr sorted-lines)
 121                                    (if (stretchable-line? line)
 122                                        (- rest-height height)
 123                                        rest-height)
 124                                    (- space-left stretch)))))
 125         (let record-line-tweak ((lines lines)
 126                                 (is-first-line #t)
 127                                 (index 0))
 128           (if (not (null? lines))
 129               (let ((line (first lines)))
 130                 (if (not (ly:prob-property? line 'is-title))
 131                     (record-tweaks
 132                      (ly:spanner-bound (ly:prob-property line 'system-grob) LEFT)
 133                      `((line-break . #t)
 134                        (page-break . ,is-first-line)
 135                        (spacing-parameters
 136                         . ((page-number . ,page-number)
 137                            (system-index . ,index)
 138                            (system-stretch . ,(ly:prob-property line 'stretch))
 139                            (system-Y-extent . ,(paper-system-extent line Y))
 140                            (system-refpoint-Y-extent . ,(paper-system-staff-extents line))
 141                            (page-system-count . ,line-count)
 142                            (page-printable-height . ,(page-printable-height page))
 143                            (page-space-left . ,(page-property page 'space-left)))))
 144                      tweaks))
 145                 (record-line-tweak (cdr lines) #f (1+ index)))))))
 146     ;; Compute tweaks for each page, then dump them to the page-layout file
 147     (for-each handle-page pages)
 148     (dump-all-tweaks pages tweaks)))