scm/framework-ps.scm

   1 ;;;; framework-ps.scm -- structure for PostScript output
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2006 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7 (define-module (scm framework-ps))
   8
   9 ;;; this is still too big a mess.
  10
  11 (use-modules (ice-9 regex)
  12              (ice-9 string-fun)
  13              (ice-9 format)
  14              (guile)
  15              (scm page)
  16              (scm paper-system)
  17              (srfi srfi-1)
  18              (srfi srfi-13)
  19              (lily))
  20
  21
  22 (define framework-ps-module (current-module))
  23
  24 ;;(define pdebug stderr)
  25 (define (pdebug . rest) #f)
  26
  27 (define-public (ps-font-command font)
  28   (let* ((name (ly:font-file-name font))
  29          (magnify (ly:font-magnification font)))
  30
  31     (string-append
  32      "magfont"
  33      (string-regexp-substitute "[ /%]" "_" name)
  34      "m" (string-encode-integer (inexact->exact (round (* 1000 magnify)))))))
  35
  36 (define (tex-font? fontname)
  37   (or
  38    (equal? (substring fontname 0 2) "cm")
  39    (equal? (substring fontname 0 2) "ec")))
  40
  41 (define (define-fonts paper)
  42   (define font-list (ly:paper-fonts paper))
  43   (define (define-font command fontname scaling)
  44     (string-append
  45       "/" command " { /" fontname " " (ly:number->string scaling) " output-scale div selectfont } bind def\n"))
  46
  47   (define (standard-tex-font? x)
  48     (or (equal? (substring x 0 2) "ms")
  49         (equal? (substring x 0 2) "cm")))
  50
  51   (define (font-load-command font)
  52     (let* ((specced-font-name (ly:font-name font))
  53            (fontname (if specced-font-name
  54                           specced-font-name
  55                          (ly:font-file-name font)))
  56            (command (ps-font-command font))
  57
  58            ;; FIXME -- see (ps-font-command )
  59            (plain (ps-font-command font))
  60            (designsize (ly:font-design-size font))
  61            (magnification (* (ly:font-magnification font)))
  62            (ops (ly:output-def-lookup paper 'output-scale))
  63            (scaling (* ops magnification designsize)))
  64
  65       ;; Bluesky pfbs have UPCASE names (sigh.)
  66       ;; FIXME - don't support Bluesky?
  67       (if (standard-tex-font? fontname)
  68           (set! fontname (string-upcase fontname)))
  69       (if (equal? fontname "unknown")
  70           (display (list font fontname)))
  71       (define-font plain fontname scaling)))
  72
  73   (apply string-append
  74          (map (lambda (x) (font-load-command x))
  75               (filter (lambda (x) (not (ly:pango-font? x)))
  76                       font-list))))
  77
  78 ;; FIXME: duplicated in other output backends
  79 ;; FIXME: silly interface name
  80 (define (output-variables layout)
  81   ;; FIXME: duplicates output-layout's scope-entry->string, mostly
  82   (define (value->string val)
  83     (cond
  84      ((string? val) (string-append "(" val ")"))
  85      ((symbol? val) (symbol->string val))
  86      ((number? val) (number->string val))
  87      (else "")))
  88
  89   (define (output-entry ps-key ly-key)
  90     (string-append
  91      "/" ps-key " "
  92      (value->string (ly:output-def-lookup layout ly-key)) " def\n"))
  93
  94   (string-append
  95    "/lily-output-units "
  96      (number->string (/ (ly:bp 1)))
  97      " def %% millimeter\n"
  98    (output-entry "staff-line-thickness" 'line-thickness)
  99    (output-entry "line-width" 'line-width)
 100    (output-entry "paper-size" 'papersizename)
 101    (output-entry "staff-height" 'staff-height)  ;junkme.
 102    "/output-scale "
 103      (number->string (ly:output-def-lookup layout 'output-scale))
 104      " def\n"
 105    (output-entry "page-height" 'paper-height)
 106    (output-entry "page-width" 'paper-width)))
 107
 108 (define (dump-page outputter page page-number page-count landscape?)
 109   (ly:outputter-dump-string
 110    outputter
 111    (string-append
 112     (format "%%Page: ~a ~a\n" page-number page-number)
 113     "%%BeginPageSetup\n"
 114     (if landscape?
 115         "page-width output-scale lily-output-units mul mul 0 translate 90 rotate\n"
 116         "")
 117     "%%EndPageSetup\n"
 118
 119     "gsave 0 paper-height translate "
 120     "set-ps-scale-to-lily-scale "
 121     "\n"))
 122   (ly:outputter-dump-stencil outputter page)
 123   (ly:outputter-dump-string outputter "stroke grestore \nshowpage\n"))
 124
 125 (define (supplies-or-needs paper load-fonts?)
 126   (define (extract-names font)
 127     (if (ly:pango-font? font)
 128         (map car (ly:pango-font-physical-fonts font))
 129         (list  (ly:font-name font))))
 130
 131   (let* ((fonts (ly:paper-fonts paper))
 132          (names (apply append (map extract-names fonts))))
 133
 134     (apply string-append
 135            (map (lambda (f)
 136                   (format
 137                    (if load-fonts?
 138                     "%%DocumentSuppliedResources: font ~a\n"
 139                     "%%DocumentNeededResources: font ~a\n")
 140                    f))
 141                 (uniq-list (sort names string<?))))))
 142
 143 (define (eps-header paper bbox load-fonts?)
 144   (string-append "%!PS-Adobe-2.0 EPSF-2.0\n"
 145                  "%%Creator: LilyPond "
 146                  (lilypond-version)
 147                  "\n"
 148                  "%%BoundingBox: "
 149                  (string-join (map ly:number->string bbox) " ") "\n"
 150                  "%%Orientation: "
 151                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 152                      "Landscape\n"
 153                      "Portrait\n")
 154                  (supplies-or-needs paper load-fonts?)
 155                  "%%EndComments\n"))
 156
 157 (define (ps-document-media paper)
 158  (let* ((w (/ (*
 159                (ly:output-def-lookup paper 'output-scale)
 160                (ly:output-def-lookup paper 'paper-width)) (ly:bp 1)))
 161         (h (/ (*
 162                (ly:output-def-lookup paper 'paper-height)
 163                (ly:output-def-lookup paper 'output-scale))
 164             (ly:bp 1)))
 165         (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t)))
 166   (format "%%DocumentMedia: ~a ~$ ~$ ~a ~a ~a\n"
 167    (ly:output-def-lookup paper 'papersizename)
 168    (if landscape? h w)
 169    (if landscape? w h)
 170    80  ;; weight
 171    "()" ;; color
 172    "()"  ;; type
 173   )))
 174
 175
 176 (define (file-header paper page-count load-fonts?)
 177   (string-append "%!PS-Adobe-3.0\n"
 178                  "%%Creator: LilyPond "
 179                  (lilypond-version)
 180                  "\n"
 181
 182                  "%%Pages: " (number->string page-count) "\n"
 183                  "%%PageOrder: Ascend\n"
 184                  "%%Orientation: "
 185                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 186                      "Landscape\n"
 187                      "Portrait\n")
 188                  (ps-document-media paper)
 189                  (supplies-or-needs paper load-fonts?)
 190                  "%%EndComments\n"))
 191
 192 (define (procset file-name)
 193   (format
 194     "%%BeginResource: procset (~a) 1 0
 195 ~a
 196 %%EndResource
 197 "
 198     file-name (cached-file-contents file-name)))
 199
 200 (define (embed-document file-name)
 201   (format "%%BeginDocument: ~a
 202 ~a
 203 %%EndDocument
 204 "
 205     file-name (cached-file-contents file-name)))
 206
 207 (define (setup-variables paper)
 208   (string-append
 209    "\n"
 210    (define-fonts paper)
 211    (output-variables paper)
 212    ))
 213
 214 (define (cff-font? font)
 215   (let*
 216       ((cff-string (ly:otf-font-table-data font "CFF ")))
 217     (> (string-length cff-string) 0)))
 218
 219 (define-public (ps-embed-cff body font-set-name version)
 220   (let* ((binary-data
 221           (string-append
 222            (format "/~a ~s StartData " font-set-name (string-length body))
 223            body))
 224
 225          (header
 226           (format
 227            "%%BeginResource: font ~a
 228 %!PS-Adobe-3.0 Resource-FontSet
 229 %%DocumentNeededResources: ProcSet (FontSetInit)
 230 %%Title: (FontSet/~a)
 231 %%Version: ~s
 232 %%EndComments
 233 %%IncludeResource: ProcSet (FontSetInit)
 234 %%BeginResource: FontSet (~a)
 235 /FontSetInit /ProcSet findresource begin
 236 %%BeginData: ~s Binary Bytes
 237 "
 238            font-set-name font-set-name version font-set-name
 239            (string-length binary-data)))
 240          (footer "\n%%EndData
 241 %%EndResource
 242 %%EndResource\n"))
 243
 244     (string-append
 245      header
 246      binary-data
 247      footer)))
 248
 249
 250 (define (write-preamble paper load-fonts? port)
 251
 252   (define (load-font-via-GS font-name-filename)
 253     (define (ps-load-file name)
 254       (format
 255        (if (string? name)
 256            "(~a) (r) file .loadfont\n"
 257            "% can't find font file: ~a\n")
 258        name))
 259
 260     (let* ((font (car font-name-filename))
 261            (name (cadr font-name-filename))
 262            (file-name (caddr font-name-filename))
 263            (bare-file-name (ly:find-file file-name)))
 264
 265       (cons
 266        name
 267
 268        (if (mac-font? bare-file-name)
 269            (handle-mac-font name bare-file-name)
 270            (cond
 271             ((string-match "^([eE]mmentaler|[Aa]ybabtu)" file-name)
 272              (ps-load-file (ly:find-file
 273                             (format "~a.otf"  file-name))))
 274             ((string? bare-file-name)
 275              (ps-load-file file-name))
 276             (else
 277              (ly:warning (_ "can't embed ~S=~S") name file-name)
 278              "")))
 279
 280           )))
 281
 282   (define (dir-join a b)
 283     (if (equal? a "")
 284         b
 285         (string-append a "/" b)))
 286
 287   (define (dir-listing dir-name)
 288     (define (dir-helper dir lst)
 289       (let ((e (readdir dir)))
 290         (if (eof-object? e) lst (dir-helper dir (cons e lst)))))
 291     (reverse (dir-helper (opendir dir-name) '())))
 292
 293   (define (handle-mac-font name filename)
 294     (let*
 295         ((dir-name  (tmpnam))
 296          (files '())
 297          (status 0)
 298          (embed #f))
 299
 300       (mkdir dir-name #o700)
 301       (set! status (ly:system
 302                     (format "cd ~a && fondu -force '~a'" dir-name filename)))
 303
 304       (set! files (dir-listing dir-name))
 305
 306       (for-each
 307        (lambda (f)
 308          (let*
 309              ((full-name  (dir-join dir-name f)))
 310
 311            (if (and (not embed)
 312                     (equal? 'regular (stat:type (stat full-name)))
 313                     (equal? name (ly:ttf-ps-name full-name)))
 314
 315                (set! embed
 316                      (font-file-as-ps-string name full-name)))
 317
 318            (if (or (equal? "." f)
 319                    (equal? ".." f))
 320                #t
 321                (delete-file full-name))))
 322
 323
 324        files)
 325       (rmdir dir-name)
 326
 327       (if (not embed)
 328           (begin
 329             (set! embed "% failed \n")
 330             (ly:warning (_ "can't extract file matching ~a from ~a") name filename)))
 331       embed))
 332
 333     (define (font-file-as-ps-string name file-name)
 334       (let*
 335           ((downcase-file-name (string-downcase file-name)))
 336
 337       (cond
 338        ((and file-name (string-match "\\.pfa" downcase-file-name))
 339         (embed-document file-name))
 340        ((and file-name (string-match "\\.pfb" downcase-file-name))
 341         (ly:pfb->pfa file-name))
 342        ((and file-name (string-match "\\.ttf" downcase-file-name))
 343         (ly:ttf->pfa file-name))
 344        ((and file-name (string-match "\\.otf" downcase-file-name))
 345         (ps-embed-cff (ly:otf->cff file-name) name 0))
 346        (else
 347         (ly:warning (_ "don't know how to embed ~S=~S") name file-name)
 348         ""))))
 349
 350     (define (mac-font? bare-file-name)
 351       (and
 352        (eq? PLATFORM 'darwin)
 353        bare-file-name
 354        (or
 355         (string-match "\\.dfont" bare-file-name)
 356         (= (stat:size (stat bare-file-name)) 0))))
 357
 358   (define (load-font font-name-filename)
 359     (let* ((font (car font-name-filename))
 360            (name (cadr font-name-filename))
 361            (file-name (caddr font-name-filename))
 362            (bare-file-name (ly:find-file file-name)))
 363
 364       (cons
 365        name
 366        (cond
 367
 368         ((mac-font? bare-file-name)
 369          (handle-mac-font name bare-file-name))
 370
 371         ((and font (cff-font? font))
 372          (ps-embed-cff (ly:otf-font-table-data font "CFF ")
 373                        name
 374                        0))
 375
 376         (bare-file-name (font-file-as-ps-string name bare-file-name))
 377         (else
 378          (ly:warning (_ "don't know how to embed font ~s ~s ~s")
 379                      name file-name font))))))
 380
 381
 382   (define (load-fonts paper)
 383     (let* ((fonts (ly:paper-fonts paper))
 384            (all-font-names
 385             (map
 386              (lambda (font)
 387                (cond
 388                 ((string? (ly:font-file-name font))
 389                  (list (list
 390                         font
 391                         (ly:font-name font)
 392                         (ly:font-file-name font))))
 393                 ((ly:pango-font? font)
 394                  (map
 395                   (lambda (name-psname-pair)
 396                     (list #f
 397                           (car name-psname-pair)
 398                           (cdr name-psname-pair)))
 399                   (ly:pango-font-physical-fonts font)))
 400
 401                 (else
 402                  (ly:font-sub-fonts font))))
 403
 404              fonts))
 405            (font-names
 406             (uniq-list
 407              (sort (apply append all-font-names)
 408                    (lambda (x y) (string<? (cadr x) (cadr y))))))
 409
 410
 411            (font-loader (if (ly:get-option 'gs-font-load)
 412                             load-font-via-GS
 413                             load-font))
 414
 415            (pfas (map font-loader font-names)))
 416       pfas))
 417
 418   (display "%%BeginProlog\n" port)
 419   (if load-fonts?
 420       (for-each
 421        (lambda (f)
 422          (format port "\n%%BeginFont: ~a\n" (car f))
 423          (display (cdr f) port)
 424          (display "\n%%EndFont\n" port))
 425        (load-fonts paper)))
 426
 427   (display (setup-variables paper) port)
 428
 429   ;; adobe note 5002: should initialize variables before loading routines.
 430   (display (procset "music-drawing-routines.ps") port)
 431   (display (procset "lilyponddefs.ps") port)
 432
 433   (if (not (ly:get-option 'point-and-click))
 434       (display "/mark_URI { pop pop pop pop pop } bind def\n" port))
 435
 436   (display "%%EndProlog\n" port)
 437
 438   (display "%%BeginSetup\ninit-lilypond-parameters\n%%EndSetup\n\n" port))
 439
 440 (define-public (output-framework basename book scopes fields)
 441   (let* ((filename (format "~a.ps" basename))
 442          (outputter (ly:make-paper-outputter
 443                      ;; FIXME: better wrap open/open-file,
 444                      ;; content-mangling is always bad.
 445                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 446                      (open-file filename "wb")
 447                      "ps"))
 448          (paper (ly:paper-book-paper book))
 449          (systems (ly:paper-book-systems book))
 450          (page-stencils (map page-stencil (ly:paper-book-pages book)))
 451
 452          (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t))
 453          (page-number (1- (ly:output-def-lookup paper 'first-page-number)))
 454          (page-count (length page-stencils))
 455          (port (ly:outputter-port outputter)))
 456
 457     (if (ly:get-option 'dump-signatures)
 458         (write-system-signatures basename (ly:paper-book-systems book) 0))
 459
 460     (output-scopes scopes fields basename)
 461     (display (file-header paper page-count #t) port)
 462
 463
 464     ;; don't do BeginDefaults PageMedia: A4
 465     ;; not necessary and wrong
 466
 467
 468     (write-preamble paper #t port)
 469
 470     (for-each
 471      (lambda (page)
 472        (set! page-number (1+ page-number))
 473        (dump-page outputter page page-number page-count landscape?))
 474      page-stencils)
 475
 476     (display "%%Trailer\n%%EOF\n" port)
 477     (ly:outputter-close outputter)
 478     (postprocess-output book framework-ps-module filename
 479                          (ly:output-formats))))
 480
 481 (define-public (dump-stencil-as-EPS paper dump-me filename load-fonts?)
 482   (define (to-bp-box mmbox)
 483     (let* ((scale (ly:output-def-lookup paper 'output-scale))
 484            (box (map
 485                  (lambda (x)
 486                    (if (or (nan? x) (inf? x))
 487                        0
 488                        (inexact->exact
 489                         (round (/ (* x scale) (ly:bp 1)))))) mmbox)))
 490
 491     (list (car box)
 492           (cadr box)
 493           (max (1+ (car box)) (caddr box))
 494           (max (1+ (cadr box)) (cadddr box))
 495           )))
 496
 497   (let* ((outputter (ly:make-paper-outputter
 498                      ;; FIXME: better wrap open/open-file,
 499                      ;; content-mangling is always bad.
 500                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 501                      (open-file (format "~a.eps" filename) "wb")
 502                      "ps"))
 503
 504          (left-overshoot -3)
 505          (port (ly:outputter-port outputter))
 506          (xext (ly:stencil-extent dump-me X))
 507          (yext (ly:stencil-extent dump-me Y))
 508          (bbox
 509           (map
 510            (lambda (x)
 511              (if (or (nan? x) (inf? x)
 512                      ;; FIXME: huh?
 513                      (equal? (format #f "~S" x) "+#.#")
 514                      (equal? (format #f "~S" x) "-#.#"))
 515                  0.0 x))
 516
 517            ;; the left-overshoot is to make sure that
 518            ;; bar numbers  stick out of margin uniformly.
 519            ;;
 520            (list (min left-overshoot (car xext))
 521                  (car yext) (cdr xext) (cdr yext))))
 522          (rounded-bbox (to-bp-box bbox))
 523          (port (ly:outputter-port outputter))
 524          (header (eps-header paper rounded-bbox load-fonts?)))
 525
 526     (display header port)
 527     (write-preamble paper load-fonts? port)
 528     (display "gsave set-ps-scale-to-lily-scale \n" port)
 529     (ly:outputter-dump-stencil outputter dump-me)
 530     (display "stroke grestore\n%%Trailer\n%%EOF\n" port)
 531     (ly:outputter-close outputter)))
 532
 533 (define-public (output-preview-framework basename book scopes fields)
 534   (let* ((paper (ly:paper-book-paper book))
 535          (systems (ly:paper-book-systems book))
 536          (scale (ly:output-def-lookup paper 'output-scale))
 537          (to-dump-systems '()))
 538
 539     ;; skip booktitles.
 540     (if (and
 541          (not (ly:get-option 'preview-include-book-title))
 542          (pair? systems)
 543          (ly:prob-property (car systems) 'is-book-title #f))
 544
 545         (set! systems (cdr systems)))
 546
 547     (for-each
 548      (lambda (sys)
 549        (if (or
 550             (paper-system-title? sys)
 551             (not (pair? to-dump-systems))
 552             (paper-system-title? (car to-dump-systems)))
 553            (set! to-dump-systems (cons sys to-dump-systems))))
 554      systems)
 555
 556     (dump-stencil-as-EPS
 557      paper
 558      (stack-stencils Y DOWN 0.0
 559                      (map paper-system-stencil (reverse to-dump-systems)))
 560      (format "~a.preview" basename)
 561      #t)
 562
 563     (postprocess-output book framework-ps-module
 564                         (format "~a.preview.eps" basename)
 565                         (cons "png" (ly:output-formats)))))
 566
 567 (if #f
 568     (define-public (output-preview-framework basename book scopes fields)
 569
 570       (let* ((paper (ly:paper-book-paper book))
 571              (systems (ly:paper-book-systems book))
 572              (scale (ly:output-def-lookup paper 'output-scale))
 573              (titles (take-while paper-system-title? systems))
 574              (non-title (find (lambda (x)
 575                                 (not (paper-system-title? x))) systems))
 576              (dump-me
 577               (stack-stencils Y DOWN 0.0
 578                               (map paper-system-stencil
 579                                    (append titles (list non-title))))))
 580         (output-scopes scopes fields basename)
 581         (dump-stencil-as-EPS paper dump-me
 582                              (format "~a.preview" basename)
 583                              #t)
 584
 585         (postprocess-output book framework-ps-module
 586                             (format "~a.preview.eps" basename)
 587                              (ly:output-formats)))))
 588 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 589
 590 (define-public (convert-to-pdf book name)
 591   (let* ((defs (ly:paper-book-paper book))
 592          (papersizename (ly:output-def-lookup defs 'papersizename)))
 593
 594     (if (equal? (basename name ".ps") "-")
 595         (ly:warning (_ "can't convert <stdout> to ~S" "PDF"))
 596         (postscript->pdf (if (string? papersizename) papersizename "a4")
 597                          name))))
 598
 599 (define-public (convert-to-png book name)
 600   (let* ((defs (ly:paper-book-paper book))
 601          (defs-resolution (ly:output-def-lookup defs 'pngresolution))
 602          (resolution (if (number? defs-resolution)
 603                          defs-resolution
 604                          (ly:get-option 'resolution)))
 605          (papersizename (ly:output-def-lookup defs 'papersizename)))
 606
 607     (postscript->png resolution
 608                      (if (string? papersizename) papersizename "a4")
 609                      name)))
 610
 611 (define-public (convert-to-dvi book name)
 612   (ly:warning (_ "can't generate ~S using the postscript back-end") "DVI"))
 613
 614 (define-public (convert-to-tex book name)
 615   (ly:warning (_ "can't generate ~S using the postscript back-end") "TeX"))
 616
 617 (define-public (convert-to-ps book name)
 618   #t)
 619
 620 (define-public (output-classic-framework basename book scopes fields)
 621
 622   (ly:error (_ "\nThe PostScript backend does not support the 'classic'
 623 framework. Use the EPS backend instead,
 624
 625   lilypond -b eps <file>
 626
 627 or remove the lilypond-book specific settings from the input.
 628 ")))