scm/framework-ps.scm

   1 ;;;; framework-ps.scm -- structure for PostScript output
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2006 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7 (define-module (scm framework-ps))
   8
   9 ;;; this is still too big a mess.
  10
  11 (use-modules (ice-9 regex)
  12              (ice-9 string-fun)
  13              (ice-9 format)
  14              (guile)
  15              (scm page)
  16              (scm paper-system)
  17              (srfi srfi-1)
  18              (srfi srfi-13)
  19              (lily))
  20
  21
  22 (define framework-ps-module (current-module))
  23
  24 ;;(define pdebug stderr)
  25 (define (pdebug . rest) #f)
  26
  27 (define-public (ps-font-command font)
  28   (let* ((name (ly:font-file-name font))
  29          (magnify (ly:font-magnification font)))
  30
  31     (string-append
  32      "magfont"
  33      (string-regexp-substitute "[ /%]" "_" name)
  34      "m" (string-encode-integer (inexact->exact (round (* 1000 magnify)))))))
  35
  36 (define (tex-font? fontname)
  37   (or
  38    (equal? (substring fontname 0 2) "cm")
  39    (equal? (substring fontname 0 2) "ec")))
  40
  41 (define (define-fonts paper)
  42   (define font-list (ly:paper-fonts paper))
  43   (define (define-font command fontname scaling)
  44     (string-append
  45       "/" command " { /" fontname " " (ly:number->string scaling) " output-scale div selectfont } bind def\n"))
  46
  47   (define (standard-tex-font? x)
  48     (or (equal? (substring x 0 2) "ms")
  49         (equal? (substring x 0 2) "cm")))
  50
  51   (define (font-load-command font)
  52     (let* ((specced-font-name (ly:font-name font))
  53            (fontname (if specced-font-name
  54                           specced-font-name
  55                          (ly:font-file-name font)))
  56            (command (ps-font-command font))
  57
  58            ;; FIXME -- see (ps-font-command )
  59            (plain (ps-font-command font))
  60            (designsize (ly:font-design-size font))
  61            (magnification (* (ly:font-magnification font)))
  62            (ops (ly:output-def-lookup paper 'output-scale))
  63            (scaling (* ops magnification designsize)))
  64
  65       ;; Bluesky pfbs have UPCASE names (sigh.)
  66       ;; FIXME - don't support Bluesky?
  67       (if (standard-tex-font? fontname)
  68           (set! fontname (string-upcase fontname)))
  69       (if (equal? fontname "unknown")
  70           (display (list font fontname)))
  71       (define-font plain fontname scaling)))
  72
  73   (apply string-append
  74          (map (lambda (x) (font-load-command x))
  75               (filter (lambda (x) (not (ly:pango-font? x)))
  76                       font-list))))
  77
  78 ;; FIXME: duplicated in other output backends
  79 ;; FIXME: silly interface name
  80 (define (output-variables layout)
  81   ;; FIXME: duplicates output-layout's scope-entry->string, mostly
  82   (define (value->string val)
  83     (cond
  84      ((string? val) (string-append "(" val ")"))
  85      ((symbol? val) (symbol->string val))
  86      ((number? val) (number->string val))
  87      (else "")))
  88
  89   (define (output-entry ps-key ly-key)
  90     (string-append
  91      "/" ps-key " "
  92      (value->string (ly:output-def-lookup layout ly-key)) " def\n"))
  93
  94   (string-append
  95    "/lily-output-units "
  96      (number->string (/ (ly:bp 1)))
  97      " def %% millimeter\n"
  98    (output-entry "staff-line-thickness" 'line-thickness)
  99    (output-entry "line-width" 'line-width)
 100    (output-entry "paper-size" 'papersizename)
 101    (output-entry "staff-height" 'staff-height)  ;junkme.
 102    "/output-scale "
 103      (number->string (ly:output-def-lookup layout 'output-scale))
 104      " def\n"
 105    (output-entry "page-height" 'paper-height)
 106    (output-entry "page-width" 'paper-width)))
 107
 108 (define (dump-page outputter page page-number page-count landscape?)
 109   (ly:outputter-dump-string
 110    outputter
 111    (string-append
 112     (format "%%Page: ~a ~a\n" page-number page-number)
 113     "%%BeginPageSetup\n"
 114     (if landscape?
 115         "page-width output-scale lily-output-units mul mul 0 translate 90 rotate\n"
 116         "")
 117     "%%EndPageSetup\n"
 118
 119     "true setstrokeadjust\n"
 120     "gsave 0 paper-height translate "
 121     "set-ps-scale-to-lily-scale "
 122     "\n"))
 123   (ly:outputter-dump-stencil outputter page)
 124   (ly:outputter-dump-string outputter "stroke grestore \nshowpage\n"))
 125
 126 (define (supplies-or-needs paper load-fonts?)
 127   (define (extract-names font)
 128     (if (ly:pango-font? font)
 129         (map car (ly:pango-font-physical-fonts font))
 130         (list  (ly:font-name font))))
 131
 132   (let* ((fonts (ly:paper-fonts paper))
 133          (names (apply append (map extract-names fonts))))
 134
 135     (apply string-append
 136            (map (lambda (f)
 137                   (format
 138                    (if load-fonts?
 139                     "%%DocumentSuppliedResources: font ~a\n"
 140                     "%%DocumentNeededResources: font ~a\n")
 141                    f))
 142                 (uniq-list (sort names string<?))))))
 143
 144 (define (eps-header paper bbox load-fonts?)
 145   (string-append "%!PS-Adobe-2.0 EPSF-2.0\n"
 146                  "%%Creator: LilyPond "
 147                  (lilypond-version)
 148                  "\n"
 149                  "%%BoundingBox: "
 150                  (string-join (map ly:number->string bbox) " ") "\n"
 151                  "%%Orientation: "
 152                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 153                      "Landscape\n"
 154                      "Portrait\n")
 155                  (supplies-or-needs paper load-fonts?)
 156                  "%%EndComments\n"))
 157
 158 (define (ps-document-media paper)
 159  (let* ((w (/ (*
 160                (ly:output-def-lookup paper 'output-scale)
 161                (ly:output-def-lookup paper 'paper-width)) (ly:bp 1)))
 162         (h (/ (*
 163                (ly:output-def-lookup paper 'paper-height)
 164                (ly:output-def-lookup paper 'output-scale))
 165             (ly:bp 1)))
 166         (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t)))
 167   (format "%%DocumentMedia: ~a ~$ ~$ ~a ~a ~a\n"
 168    (ly:output-def-lookup paper 'papersizename)
 169    (if landscape? h w)
 170    (if landscape? w h)
 171    80  ;; weight
 172    "()" ;; color
 173    "()"  ;; type
 174   )))
 175
 176
 177 (define (file-header paper page-count load-fonts?)
 178   (string-append "%!PS-Adobe-3.0\n"
 179                  "%%Creator: LilyPond "
 180                  (lilypond-version)
 181                  "\n"
 182
 183                  "%%Pages: " (number->string page-count) "\n"
 184                  "%%PageOrder: Ascend\n"
 185                  "%%Orientation: "
 186                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 187                      "Landscape\n"
 188                      "Portrait\n")
 189                  (ps-document-media paper)
 190                  (supplies-or-needs paper load-fonts?)
 191                  "%%EndComments\n"))
 192
 193 (define (procset file-name)
 194   (format
 195     "%%BeginResource: procset (~a) 1 0
 196 ~a
 197 %%EndResource
 198 "
 199     file-name (cached-file-contents file-name)))
 200
 201 (define (embed-document file-name)
 202   (format "%%BeginDocument: ~a
 203 ~a
 204 %%EndDocument
 205 "
 206     file-name (cached-file-contents file-name)))
 207
 208 (define (setup-variables paper)
 209   (string-append
 210    "\n"
 211    (define-fonts paper)
 212    (output-variables paper)
 213    ))
 214
 215 (define (cff-font? font)
 216   (let*
 217       ((cff-string (ly:otf-font-table-data font "CFF ")))
 218     (> (string-length cff-string) 0)))
 219
 220 (define-public (ps-embed-cff body font-set-name version)
 221   (let* ((binary-data
 222           (string-append
 223            (format "/~a ~s StartData " font-set-name (string-length body))
 224            body))
 225
 226          (header
 227           (format
 228            "%%BeginResource: font ~a
 229 %!PS-Adobe-3.0 Resource-FontSet
 230 %%DocumentNeededResources: ProcSet (FontSetInit)
 231 %%Title: (FontSet/~a)
 232 %%Version: ~s
 233 %%EndComments
 234 %%IncludeResource: ProcSet (FontSetInit)
 235 %%BeginResource: FontSet (~a)
 236 /FontSetInit /ProcSet findresource begin
 237 %%BeginData: ~s Binary Bytes
 238 "
 239            font-set-name font-set-name version font-set-name
 240            (string-length binary-data)))
 241          (footer "\n%%EndData
 242 %%EndResource
 243 %%EndResource\n"))
 244
 245     (string-append
 246      header
 247      binary-data
 248      footer)))
 249
 250
 251 (define (write-preamble paper load-fonts? port)
 252
 253   (define (load-font-via-GS font-name-filename)
 254     (define (ps-load-file name)
 255       (format
 256        (if (string? name)
 257            "(~a) (r) file .loadfont\n"
 258            "% can't find font file: ~a\n")
 259        name))
 260
 261     (let* ((font (car font-name-filename))
 262            (name (cadr font-name-filename))
 263            (file-name (caddr font-name-filename))
 264            (bare-file-name (ly:find-file file-name)))
 265
 266       (cons
 267        name
 268
 269        (if (mac-font? bare-file-name)
 270            (handle-mac-font name bare-file-name)
 271            (cond
 272             ((string-match "^([eE]mmentaler|[Aa]ybabtu)" file-name)
 273              (ps-load-file (ly:find-file
 274                             (format "~a.otf"  file-name))))
 275             ((string? bare-file-name)
 276              (ps-load-file file-name))
 277             (else
 278              (ly:warning (_ "can't embed ~S=~S") name file-name)
 279              "")))
 280
 281           )))
 282
 283   (define (dir-join a b)
 284     (if (equal? a "")
 285         b
 286         (string-append a "/" b)))
 287
 288   (define (dir-listing dir-name)
 289     (define (dir-helper dir lst)
 290       (let ((e (readdir dir)))
 291         (if (eof-object? e) lst (dir-helper dir (cons e lst)))))
 292     (reverse (dir-helper (opendir dir-name) '())))
 293
 294   (define (handle-mac-font name filename)
 295     (let*
 296         ((dir-name  (tmpnam))
 297          (files '())
 298          (status 0)
 299          (embed #f))
 300
 301       (mkdir dir-name #o700)
 302       (set! status (ly:system
 303                     (format "cd ~a && fondu -force '~a'" dir-name filename)))
 304
 305       (set! files (dir-listing dir-name))
 306
 307       (for-each
 308        (lambda (f)
 309          (let*
 310              ((full-name  (dir-join dir-name f)))
 311
 312            (if (and (not embed)
 313                     (equal? 'regular (stat:type (stat full-name)))
 314                     (equal? name (ly:ttf-ps-name full-name)))
 315
 316                (set! embed
 317                      (font-file-as-ps-string name full-name)))
 318
 319            (if (or (equal? "." f)
 320                    (equal? ".." f))
 321                #t
 322                (delete-file full-name))))
 323
 324
 325        files)
 326       (rmdir dir-name)
 327
 328       (if (not embed)
 329           (begin
 330             (set! embed "% failed \n")
 331             (ly:warning (_ "can't extract file matching ~a from ~a") name filename)))
 332       embed))
 333
 334     (define (font-file-as-ps-string name file-name)
 335       (let*
 336           ((downcase-file-name (string-downcase file-name)))
 337
 338       (cond
 339        ((and file-name (string-match "\\.pfa" downcase-file-name))
 340         (embed-document file-name))
 341        ((and file-name (string-match "\\.pfb" downcase-file-name))
 342         (ly:pfb->pfa file-name))
 343        ((and file-name (string-match "\\.ttf" downcase-file-name))
 344         (ly:ttf->pfa file-name))
 345        ((and file-name (string-match "\\.otf" downcase-file-name))
 346         (ps-embed-cff (ly:otf->cff file-name) name 0))
 347        (else
 348         (ly:warning (_ "don't know how to embed ~S=~S") name file-name)
 349         ""))))
 350
 351     (define (mac-font? bare-file-name)
 352       (and
 353        (eq? PLATFORM 'darwin)
 354        bare-file-name
 355        (or
 356         (string-match "\\.dfont" bare-file-name)
 357         (= (stat:size (stat bare-file-name)) 0))))
 358
 359   (define (load-font font-name-filename)
 360     (let* ((font (car font-name-filename))
 361            (name (cadr font-name-filename))
 362            (file-name (caddr font-name-filename))
 363            (bare-file-name (ly:find-file file-name)))
 364
 365       (cons
 366        name
 367        (cond
 368
 369         ((mac-font? bare-file-name)
 370          (handle-mac-font name bare-file-name))
 371
 372         ((and font (cff-font? font))
 373          (ps-embed-cff (ly:otf-font-table-data font "CFF ")
 374                        name
 375                        0))
 376
 377         (bare-file-name (font-file-as-ps-string name bare-file-name))
 378         (else
 379          (ly:warning (_ "don't know how to embed font ~s ~s ~s")
 380                      name file-name font))))))
 381
 382
 383   (define (load-fonts paper)
 384     (let* ((fonts (ly:paper-fonts paper))
 385            (all-font-names
 386             (map
 387              (lambda (font)
 388                (cond
 389                 ((string? (ly:font-file-name font))
 390                  (list (list
 391                         font
 392                         (ly:font-name font)
 393                         (ly:font-file-name font))))
 394                 ((ly:pango-font? font)
 395                  (map
 396                   (lambda (name-psname-pair)
 397                     (list #f
 398                           (car name-psname-pair)
 399                           (cdr name-psname-pair)))
 400                   (ly:pango-font-physical-fonts font)))
 401
 402                 (else
 403                  (ly:font-sub-fonts font))))
 404
 405              fonts))
 406            (font-names
 407             (uniq-list
 408              (sort (apply append all-font-names)
 409                    (lambda (x y) (string<? (cadr x) (cadr y))))))
 410
 411
 412            (font-loader (if (ly:get-option 'gs-load-fonts)
 413                             load-font-via-GS
 414                             load-font))
 415
 416            (pfas (map font-loader font-names)))
 417       pfas))
 418
 419   (display "%%BeginProlog\n" port)
 420   (if load-fonts?
 421       (for-each
 422        (lambda (f)
 423          (format port "\n%%BeginFont: ~a\n" (car f))
 424          (display (cdr f) port)
 425          (display "\n%%EndFont\n" port))
 426        (load-fonts paper)))
 427
 428   (display (setup-variables paper) port)
 429
 430   ;; adobe note 5002: should initialize variables before loading routines.
 431   (display (procset "music-drawing-routines.ps") port)
 432   (display (procset "lilyponddefs.ps") port)
 433
 434   (if (not (ly:get-option 'point-and-click))
 435       (display "/mark_URI { pop pop pop pop pop } bind def\n" port))
 436
 437   (display "%%EndProlog\n" port)
 438
 439   (display "%%BeginSetup\ninit-lilypond-parameters\n%%EndSetup\n\n" port))
 440
 441 (define-public (output-framework basename book scopes fields)
 442   (let* ((filename (format "~a.ps" basename))
 443          (outputter (ly:make-paper-outputter
 444                      ;; FIXME: better wrap open/open-file,
 445                      ;; content-mangling is always bad.
 446                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 447                      (open-file filename "wb")
 448                      "ps"))
 449          (paper (ly:paper-book-paper book))
 450          (systems (ly:paper-book-systems book))
 451          (page-stencils (map page-stencil (ly:paper-book-pages book)))
 452
 453          (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t))
 454          (page-number (1- (ly:output-def-lookup paper 'first-page-number)))
 455          (page-count (length page-stencils))
 456          (port (ly:outputter-port outputter)))
 457
 458     (if (ly:get-option 'dump-signatures)
 459         (write-system-signatures basename (ly:paper-book-systems book) 1))
 460
 461     (output-scopes scopes fields basename)
 462     (display (file-header paper page-count #t) port)
 463
 464
 465     ;; don't do BeginDefaults PageMedia: A4
 466     ;; not necessary and wrong
 467
 468
 469     (write-preamble paper #t port)
 470
 471     (for-each
 472      (lambda (page)
 473        (set! page-number (1+ page-number))
 474        (dump-page outputter page page-number page-count landscape?))
 475      page-stencils)
 476
 477     (display "%%Trailer\n%%EOF\n" port)
 478     (ly:outputter-close outputter)
 479     (postprocess-output book framework-ps-module filename
 480                          (ly:output-formats))))
 481
 482 (define-public (dump-stencil-as-EPS paper dump-me filename load-fonts?)
 483   (define (to-bp-box mmbox)
 484     (let* ((scale (ly:output-def-lookup paper 'output-scale))
 485            (box (map
 486                  (lambda (x)
 487                    (if (or (nan? x) (inf? x))
 488                        0
 489                        (inexact->exact
 490                         (round (/ (* x scale) (ly:bp 1)))))) mmbox)))
 491
 492     (list (car box)
 493           (cadr box)
 494           (max (1+ (car box)) (caddr box))
 495           (max (1+ (cadr box)) (cadddr box))
 496           )))
 497
 498   (let* ((outputter (ly:make-paper-outputter
 499                      ;; FIXME: better wrap open/open-file,
 500                      ;; content-mangling is always bad.
 501                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 502                      (open-file (format "~a.eps" filename) "wb")
 503                      "ps"))
 504
 505          (left-overshoot -3)
 506          (port (ly:outputter-port outputter))
 507          (xext (ly:stencil-extent dump-me X))
 508          (yext (ly:stencil-extent dump-me Y))
 509          (bbox
 510           (map
 511            (lambda (x)
 512              (if (or (nan? x) (inf? x)
 513                      ;; FIXME: huh?
 514                      (equal? (format #f "~S" x) "+#.#")
 515                      (equal? (format #f "~S" x) "-#.#"))
 516                  0.0 x))
 517
 518            ;; the left-overshoot is to make sure that
 519            ;; bar numbers  stick out of margin uniformly.
 520            ;;
 521            (list
 522
 523             (if (ly:get-option 'pad-eps-boxes)
 524                 (min left-overshoot (car xext))
 525                 (car xext))
 526             (car yext) (cdr xext) (cdr yext))))
 527
 528          (rounded-bbox (to-bp-box bbox))
 529          (port (ly:outputter-port outputter))
 530          (header (eps-header paper rounded-bbox load-fonts?)))
 531
 532     (display header port)
 533     (write-preamble paper load-fonts? port)
 534     (display "gsave set-ps-scale-to-lily-scale \n" port)
 535     (ly:outputter-dump-stencil outputter dump-me)
 536     (display "stroke grestore\n%%Trailer\n%%EOF\n" port)
 537     (ly:outputter-close outputter)))
 538
 539 (define-public (output-preview-framework basename book scopes fields)
 540   (let* ((paper (ly:paper-book-paper book))
 541          (systems (ly:paper-book-systems book))
 542          (scale (ly:output-def-lookup paper 'output-scale))
 543          (to-dump-systems '()))
 544
 545     ;; skip booktitles.
 546     (if (and
 547          (not (ly:get-option 'include-book-title-preview))
 548          (pair? systems)
 549          (ly:prob-property (car systems) 'is-book-title #f))
 550
 551         (set! systems (cdr systems)))
 552
 553     (for-each
 554      (lambda (sys)
 555        (if (or
 556             (paper-system-title? sys)
 557             (not (pair? to-dump-systems))
 558             (paper-system-title? (car to-dump-systems)))
 559            (set! to-dump-systems (cons sys to-dump-systems))))
 560      systems)
 561
 562     (dump-stencil-as-EPS
 563      paper
 564      (stack-stencils Y DOWN 0.0
 565                      (map paper-system-stencil (reverse to-dump-systems)))
 566      (format "~a.preview" basename)
 567      #t)
 568
 569     (postprocess-output book framework-ps-module
 570                         (format "~a.preview.eps" basename)
 571                         (cons "png" (ly:output-formats)))))
 572
 573 (if #f
 574     (define-public (output-preview-framework basename book scopes fields)
 575
 576       (let* ((paper (ly:paper-book-paper book))
 577              (systems (ly:paper-book-systems book))
 578              (scale (ly:output-def-lookup paper 'output-scale))
 579              (titles (take-while paper-system-title? systems))
 580              (non-title (find (lambda (x)
 581                                 (not (paper-system-title? x))) systems))
 582              (dump-me
 583               (stack-stencils Y DOWN 0.0
 584                               (map paper-system-stencil
 585                                    (append titles (list non-title))))))
 586         (output-scopes scopes fields basename)
 587         (dump-stencil-as-EPS paper dump-me
 588                              (format "~a.preview" basename)
 589                              #t)
 590
 591         (postprocess-output book framework-ps-module
 592                             (format "~a.preview.eps" basename)
 593                              (ly:output-formats)))))
 594 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 595
 596 (define-public (convert-to-pdf book name)
 597   (let* ((defs (ly:paper-book-paper book))
 598          (landscape (ly:output-def-lookup defs 'landscape))
 599          (output-scale (ly:output-def-lookup defs 'output-scale))
 600          (convert (lambda (x) (* x output-scale (/ (ly:bp 1)))))
 601
 602          (paper-width (convert (ly:output-def-lookup defs 'paper-width)))
 603          (paper-height (convert (ly:output-def-lookup defs 'paper-height)))
 604
 605          (w (if landscape paper-height paper-width))
 606          (h (if landscape paper-width paper-height))
 607          )
 608
 609     (if (equal? (basename name ".ps") "-")
 610         (ly:warning (_ "can't convert <stdout> to ~S" "PDF"))
 611         (postscript->pdf w h name))))
 612
 613 (define-public (convert-to-png book name)
 614   (let* ((defs (ly:paper-book-paper book))
 615          (defs-resolution (ly:output-def-lookup defs 'pngresolution))
 616          (resolution (if (number? defs-resolution)
 617                          defs-resolution
 618                          (ly:get-option 'resolution)))
 619          (paper-width (ly:output-def-lookup defs 'paper-width))
 620          (paper-height (ly:output-def-lookup defs 'paper-height))
 621          (output-scale (ly:output-def-lookup defs 'output-scale)))
 622
 623     (postscript->png resolution
 624                      (* paper-width output-scale (/ (ly:bp 1)))
 625                      (* paper-height output-scale (/ (ly:bp 1)))
 626                      name)))
 627
 628 (define-public (convert-to-dvi book name)
 629   (ly:warning (_ "can't generate ~S using the postscript back-end") "DVI"))
 630
 631 (define-public (convert-to-tex book name)
 632   (ly:warning (_ "can't generate ~S using the postscript back-end") "TeX"))
 633
 634 (define-public (convert-to-ps book name)
 635   #t)
 636
 637 (define-public (output-classic-framework basename book scopes fields)
 638
 639   (ly:error (_ "\nThe PostScript backend does not support the 'classic'
 640 framework. Use the EPS backend instead,
 641
 642   lilypond -b eps <file>
 643
 644 or remove the lilypond-book specific settings from the input.
 645 ")))