scm/documentation-lib.scm

   1 ;;;;
   2 ;;;; documentation-lib.scm -- Assorted Functions for generated documentation
   3 ;;;;
   4 ;;;; source file of the GNU LilyPond music typesetter
   5 ;;;;
   6 ;;;; (c) 2000--2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7 ;;;;                 Jan Nieuwenhuizen <janneke@gnu.org>
   8
   9 (use-modules (oop goops)
  10              (srfi srfi-13)
  11              (srfi srfi-1))
  12
  13 (define-class <texi-node> ()
  14   (children #:init-value '() #:accessor node-children #:init-keyword #:children)
  15   (text #:init-value "" #:accessor node-text #:init-keyword #:text)
  16   (name #:init-value "" #:accessor node-name #:init-keyword #:name)
  17   (description #:init-value "" #:accessor node-desc #:init-keyword #:desc))
  18
  19 (define (menu-entry x)
  20   (cons
  21    (node-name x)
  22    (node-desc x)))
  23
  24 (define (dump-node node port level)
  25   (display
  26    (string-append
  27     "\n@node "
  28     (node-name node)
  29     "\n\n"
  30     (texi-section-command level) " "
  31     (node-name node)
  32     "\n\n"
  33     (node-text node)
  34     "\n\n"
  35     (if (pair? (node-children node))
  36         (texi-menu
  37          (map (lambda (x) (menu-entry x))
  38               (node-children node)))
  39         ""))
  40    port)
  41   (map (lambda (x) (dump-node x port (+ 1 level)))
  42        (node-children node)))
  43
  44 (define (processing name)
  45   (ly:message (_ "Processing ~S...") name))
  46
  47 (define (self-evaluating? x)
  48   (or (number? x) (string? x) (procedure? x) (boolean? x)))
  49
  50 (define (texify x)
  51   x)
  52
  53 (define (scm->texi x)
  54   (string-append "@code{" (texify (scm->string x)) "}"))
  55
  56
  57
  58 (define (texi-section-command level)
  59   (cdr (assoc level '(
  60                       ;; Hmm, texinfo doesn't have ``part''
  61                       (0 . "@top")
  62                       (1 . "@unnumbered")
  63                       (2 . "@unnumberedsec")
  64                       (3 . "@unnumberedsubsec")
  65                       (4 . "@unnumberedsubsubsec")
  66                       (5 . "@unnumberedsubsubsec")))))
  67
  68 (define (one-item->texi label-desc-pair)
  69   "Document one (LABEL . DESC); return empty string if LABEL is empty string.
  70 "
  71   (if (eq? (car label-desc-pair) "")
  72       ""
  73       (string-append "\n@item " (car label-desc-pair) "\n" (cdr label-desc-pair))))
  74
  75
  76 (define (description-list->texi items-alist)
  77   "Document ITEMS-ALIST in a table. entries contain (item-label
  78 . string-to-use)
  79 "
  80   (string-append
  81    "\n@table @asis\n"
  82    (apply string-append (map one-item->texi items-alist))
  83    "\n@end table\n"))
  84
  85 (define (texi-menu items-alist)
  86   "Generate what is between @menu and @end menu."
  87   (let ((maxwid
  88          (apply max (map (lambda (x) (string-length (car x))) items-alist))))
  89
  90     (string-append
  91      "\n@menu"
  92      (apply string-append
  93             (map (lambda (x)
  94                    (string-append
  95                     (string-pad-right
  96                      (string-append "\n* " (car x) ":: ")
  97                      (+ maxwid 8))
  98                     (cdr x)))
  99                  items-alist))
 100      "\n@end menu\n"
 101      ;; Menus don't appear in html, so we make a list ourselves
 102      "\n@ignore\n"
 103      "\n@ifhtml\n"
 104      (description-list->texi (map (lambda (x) (cons (ref-ify (car x)) (cdr x)))
 105                                   items-alist))
 106      "\n@end ifhtml\n"
 107      "\n@end ignore\n")))
 108
 109 (define (texi-file-head name file-name top)
 110   (string-append
 111    "\\input texinfo @c -*-texinfo-*-"
 112    "\n@setfilename " file-name ".info"
 113    "\n@settitle " name
 114    "\n@dircategory LilyPond"
 115    "\n@direntry"
 116    ;; prepend GNU for dir, must be unique
 117    "\n* GNU " name ": (" file-name ").          " name "."
 118    "\n@end direntry\n"
 119    "@documentlanguage en\n"
 120    "@documentencoding utf-8\n"))
 121
 122 (define (context-name name)
 123   name)
 124
 125 (define (engraver-name name)
 126   name)
 127
 128 (define (grob-name name)
 129   (if (symbol? name)
 130       (symbol->string name)
 131       name))
 132
 133 (define (interface-name name)
 134   name)
 135
 136 (define (ref-ify x)
 137   "Add ref to X"
 138   (string-append "@ref{" x "}"))
 139
 140 (define (human-listify lst)
 141   "Produce a textual enumeration from LST, a list of strings"
 142
 143   (cond
 144    ((null? lst) "none")
 145    ((null? (cdr lst)) (car lst))
 146    ((null? (cddr lst)) (string-append (car lst) " and " (cadr lst)))
 147    (else (string-append (car lst) ", " (human-listify (cdr lst))))))
 148
 149 (define (writing-wip x)
 150   (ly:message (_ "Writing ~S...") x))
 151
 152
 153 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 154 ;; property  stuff.
 155
 156 (define (property->texi where sym . rest)
 157   "Document SYM for WHERE (which can be translation, backend, music),
 158 with init values from ALIST (1st optional argument)
 159 "
 160   (let* ((name (symbol->string sym))
 161          (alist (if (pair? rest) (car rest) '()))
 162          (type?-name (string->symbol
 163                       (string-append (symbol->string where) "-type?")))
 164          (doc-name (string->symbol
 165                     (string-append (symbol->string where) "-doc")))
 166          (type (object-property sym type?-name))
 167          (typename (type-name type))
 168          (desc (object-property sym doc-name))
 169          (handle (assoc sym alist)))
 170
 171     (if (eq? desc #f)
 172         (ly:error (_ "can't find description for property ~S (~S)") sym where))
 173
 174     (cons
 175      (string-append "@code{" name "} "
 176                     "(" typename ")"
 177                     (if handle
 178                         (string-append
 179                          ":\n\n"
 180                          (scm->texi (cdr handle))
 181                          "\n\n")
 182                         ""))
 183      desc)))
 184