scm/document-translation.scm

   1 ;;;; document-translation.scm -- Functions for engraver documentation
   2 ;;;;
   3 ;;;; source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2000--2009 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6 ;;;;                 Jan Nieuwenhuizen <janneke@gnu.org>
   7
   8 (define (engraver-makes-grob? name-symbol grav)
   9   (memq name-symbol (assoc 'grobs-created (ly:translator-description grav))))
  10
  11 (define (engraver-accepts-music-type? name-symbol grav)
  12   (memq name-symbol (assoc 'events-accepted (ly:translator-description grav))))
  13
  14 (define (engraver-accepts-music-types? types grav)
  15   (if (null? types)
  16       #f
  17       (or
  18        (engraver-accepts-music-type? (car types) grav)
  19        (engraver-accepts-music-types? (cdr types) grav))))
  20
  21 (define (engraver-doc-string engraver in-which-contexts)
  22   (let* ((propsr (cdr (assoc 'properties-read (ly:translator-description engraver))))
  23          (propsw (cdr (assoc 'properties-written (ly:translator-description engraver))))
  24          (accepted  (cdr (assoc 'events-accepted (ly:translator-description engraver))))
  25          (name-sym  (ly:translator-name engraver))
  26          (name-str (symbol->string name-sym))
  27          (desc (cdr (assoc 'description (ly:translator-description engraver))))
  28          (grobs (engraver-grobs engraver)))
  29
  30     (string-append
  31      desc
  32      "\n\n"
  33      (if (pair? accepted)
  34          (string-append
  35           "Music types accepted:\n\n"
  36           (human-listify
  37            (map ref-ify (sort (map symbol->string accepted) ly:string-ci<?))))
  38          "")
  39      "\n\n"
  40      (if (pair? propsr)
  41          (string-append
  42           "Properties (read)"
  43           (description-list->texi
  44            (map (lambda (x) (property->texi 'translation x '()))
  45                 (sort propsr ly:symbol-ci<?))
  46            #t))
  47          "")
  48
  49      (if (null? propsw)
  50          ""
  51          (string-append
  52           "Properties (write)"
  53           (description-list->texi
  54            (map (lambda (x) (property->texi 'translation x '()))
  55                 (sort propsw ly:symbol-ci<?))
  56            #t)))
  57      (if  (null? grobs)
  58           ""
  59           (string-append
  60            "\n\nThis engraver creates the following layout object(s):\n\n"
  61            (human-listify (map ref-ify (uniq-list (sort grobs ly:string-ci<?))))
  62            "."))
  63
  64      "\n\n"
  65
  66      (if in-which-contexts
  67          (let* ((layout-alist (ly:output-description $defaultlayout))
  68                 (context-description-alist (map cdr layout-alist))
  69                 (contexts
  70                  (apply append
  71                         (map
  72                          (lambda (x)
  73                            (let* ((context (cdr (assoc 'context-name x)))
  74                                   (group (assq-ref x 'group-type))
  75                                   (consists (append
  76                                              (if group
  77                                                  (list group)
  78                                                  '())
  79                                              (cdr (assoc 'consists x)))))
  80                              (if (member name-sym consists)
  81                                  (list context)
  82                                  '())))
  83                          context-description-alist)))
  84                 (context-list (human-listify (map ref-ify
  85                                                   (sort
  86                                                    (map symbol->string contexts)
  87                                                    ly:string-ci<?)))))
  88            (string-append
  89             "@code{" name-str "} "
  90             (if (equal? context-list "none")
  91                 "is not part of any context"
  92                 (string-append
  93                  "is part of the following context(s): "
  94                  context-list))
  95             "."))
  96          ""))))
  97
  98 ;; First level Engraver description
  99 (define (engraver-doc grav)
 100   (make <texi-node>
 101     #:name (symbol->string (ly:translator-name grav))
 102     #:text (engraver-doc-string grav #t)))
 103
 104 ;; Second level, part of Context description
 105 (define name->engraver-table (make-vector 61 '()))
 106 (map
 107  (lambda (x)
 108    (hash-set! name->engraver-table (ly:translator-name x) x))
 109  (ly:get-all-translators))
 110
 111 (define (find-engraver-by-name name)
 112   "NAME is a symbol."
 113   (hash-ref name->engraver-table name #f))
 114
 115 (define (document-engraver-by-name name)
 116   "NAME is a symbol."
 117
 118   (let* ((eg (find-engraver-by-name name)))
 119
 120     (cons (string-append "@code{" (ref-ify (symbol->string name)) "}")
 121           (engraver-doc-string eg #f))))
 122
 123 (define (document-property-operation op)
 124   (let ((tag (car op))
 125         (context-sym (cadr op))
 126         (args (cddr op))
 127         )
 128
 129     (cond
 130      ((equal?  tag 'push)
 131       (let*
 132           ((value (car args))
 133            (path (cdr args)))
 134
 135       (string-append
 136        "@item Set "
 137        (format "grob-property @code{~a} "
 138                (string-join (map symbol->string path) " "))
 139        (format "in @ref{~a} to ~a."
 140                context-sym (scm->texi value))
 141        "\n")))
 142      ((equal? (object-property context-sym 'is-grob?) #t) "")
 143      ((equal? tag 'assign)
 144       (format "@item Set translator property @code{~a} to ~a.\n"
 145               context-sym
 146               (scm->texi (car args))))
 147      )))
 148
 149
 150 (define (context-doc context-desc)
 151   (let* ((name-sym (cdr (assoc 'context-name context-desc)))
 152          (name (symbol->string name-sym))
 153          (aliases (map symbol->string (cdr (assoc 'aliases context-desc))))
 154          (desc-handle (assoc 'description context-desc))
 155          (desc (if (and  (pair? desc-handle) (string? (cdr desc-handle)))
 156                    (cdr desc-handle) "(not documented)"))
 157
 158          (accepts (cdr (assoc 'accepts context-desc)))
 159          (consists (cdr (assoc 'consists context-desc)))
 160          (props (cdr (assoc 'property-ops context-desc)))
 161          (grobs  (context-grobs context-desc))
 162          (grob-refs (map ref-ify (sort grobs ly:string-ci<?))))
 163
 164     (make <texi-node>
 165       #:name name
 166       #:text
 167       (string-append
 168        desc
 169        (if (pair? aliases)
 170            (string-append
 171             "\n\nThis context also accepts commands for the following context(s):\n\n"
 172             (human-listify (sort aliases ly:string-ci<?))
 173             ".")
 174            "")
 175
 176        "\n\nThis context creates the following layout object(s):\n\n"
 177        (human-listify (uniq-list grob-refs))
 178        "."
 179
 180        (if (and (pair? props) (not (null? props)))
 181            (let ((str (apply string-append
 182                              (sort (map document-property-operation props)
 183                                    ly:string-ci<?))))
 184              (if (string-null? str)
 185                  ""
 186                  (string-append
 187                   "\n\nThis context sets the following properties:\n\n"
 188                   "@itemize @bullet\n"
 189                   str
 190                   "@end itemize\n")))
 191            "")
 192
 193        (if (null? accepts)
 194            "\n\nThis context is a `bottom' context; it cannot contain other contexts."
 195            (string-append
 196             "\n\nContext "
 197             name
 198             " can contain\n"
 199             (human-listify (map ref-ify (sort (map symbol->string accepts)
 200                                               ly:string-ci<?)))
 201             "."))
 202
 203        (if (null? consists)
 204            ""
 205            (string-append
 206             "\n\nThis context is built from the following engraver(s):"
 207             (description-list->texi
 208              (map document-engraver-by-name (sort consists ly:symbol-ci<?))
 209              #t)))))))
 210
 211 (define (engraver-grobs grav)
 212   (let* ((eg (if (symbol? grav)
 213                  (find-engraver-by-name grav)
 214                  grav)))
 215     (if (eq? eg #f)
 216         '()
 217         (map symbol->string (cdr (assoc 'grobs-created (ly:translator-description eg)))))))
 218
 219 (define (context-grobs context-desc)
 220   (let* ((group (assq-ref context-desc 'group-type))
 221          (consists (append
 222                     (if group
 223                         (list group)
 224                         '())
 225                     (cdr (assoc 'consists context-desc))))
 226          (grobs  (apply append
 227                         (map engraver-grobs consists))))
 228     grobs))
 229
 230 (define (all-contexts-doc)
 231   (let* ((layout-alist
 232           (sort (ly:output-description $defaultlayout)
 233                 (lambda (x y) (ly:symbol-ci<? (car x) (car y)))))
 234          (names (sort (map symbol->string (map car layout-alist)) ly:string-ci<?))
 235          (contexts (map cdr layout-alist)))
 236
 237     (make <texi-node>
 238       #:name "Contexts"
 239       #:desc "Complete descriptions of all contexts."
 240       #:children
 241       (map context-doc contexts))))
 242
 243 (define all-engravers-list  (ly:get-all-translators))
 244 (set! all-engravers-list
 245       (sort all-engravers-list
 246             (lambda (a b) (ly:string-ci<? (symbol->string (ly:translator-name a))
 247                                     (symbol->string (ly:translator-name b))))))
 248
 249 (define (all-engravers-doc)
 250   (make <texi-node>
 251     #:name "Engravers and Performers"
 252     #:desc "All separate engravers and performers."
 253     #:text "See @ruser{Modifying context plug-ins}."
 254     #:children
 255     (map engraver-doc all-engravers-list)))
 256
 257 (define (translation-properties-doc-string lst)
 258   (let* ((ps (sort (map symbol->string lst) ly:string-ci<?))
 259          (sortedsyms (map string->symbol ps))
 260          (propdescs
 261           (map
 262            (lambda (x) (property->texi 'translation  x '()))
 263            sortedsyms))
 264          (texi (description-list->texi propdescs #f)))
 265     texi))
 266
 267 (define (translation-doc-node)
 268   (make <texi-node>
 269     #:name "Translation"
 270     #:desc "From music to layout."
 271     #:children
 272     (list
 273      (all-contexts-doc)
 274      (all-engravers-doc)
 275      (make <texi-node>
 276        #:name "Tunable context properties"
 277        #:desc "All tunable context properties."
 278        #:text (translation-properties-doc-string
 279                all-user-translation-properties))
 280
 281      (make <texi-node>
 282        #:name "Internal context properties"
 283        #:desc "All internal context properties."
 284        #:text (translation-properties-doc-string
 285                all-internal-translation-properties)))))