scm/document-translation.scm

   1 ;;;; document-translation.scm -- Functions for engraver documentation
   2 ;;;;
   3 ;;;; source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2000--2006 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6 ;;;;                 Jan Nieuwenhuizen <janneke@gnu.org>
   7
   8 (define (engraver-makes-grob? name-symbol grav)
   9   (memq name-symbol (assoc 'grobs-created (ly:translator-description grav))))
  10
  11 (define (engraver-accepts-music-type? name-symbol grav)
  12   (memq name-symbol (assoc 'events-accepted (ly:translator-description grav))))
  13
  14 (define (engraver-accepts-music-types? types grav)
  15   (if (null? types)
  16       #f
  17       (or
  18        (engraver-accepts-music-type? (car types) grav)
  19        (engraver-accepts-music-types? (cdr types) grav))))
  20
  21 (define (engraver-doc-string engraver in-which-contexts)
  22   (let* ((propsr (cdr (assoc 'properties-read (ly:translator-description engraver))))
  23          (propsw (cdr (assoc 'properties-written (ly:translator-description engraver))))
  24          (accepted  (cdr (assoc 'events-accepted (ly:translator-description engraver))))
  25          (name-sym  (ly:translator-name engraver))
  26          (name-str (symbol->string name-sym))
  27          (desc (cdr (assoc 'description (ly:translator-description engraver))))
  28          (grobs (engraver-grobs engraver)))
  29
  30     (string-append
  31      desc
  32      "\n\n"
  33      (if (pair? accepted)
  34          (string-append
  35           "Music types accepted:\n\n"
  36           (human-listify
  37            (map (lambda (x)
  38                   (string-append
  39                    "@ref{"
  40                    (symbol->string x)
  41                    "}")) accepted)))
  42          "")
  43      "\n\n"
  44      (if (pair? propsr)
  45          (string-append
  46           "Properties (read)"
  47           (description-list->texi
  48            (map (lambda (x) (property->texi 'translation  x '())) propsr)))
  49          "")
  50
  51      (if (null? propsw)
  52          ""
  53          (string-append
  54           "Properties (write)"
  55           (description-list->texi
  56            (map (lambda (x) (property->texi 'translation  x '())) propsw))))
  57      (if  (null? grobs)
  58           ""
  59           (string-append
  60            "This engraver creates the following layout objects: \n "
  61            (human-listify (map ref-ify (uniq-list (sort grobs string<? ))))
  62            "."))
  63
  64      "\n\n"
  65
  66      (if in-which-contexts
  67          (let* ((layout-alist (ly:output-description $defaultlayout))
  68                 (context-description-alist (map cdr layout-alist))
  69                 (contexts
  70                  (apply append
  71                         (map
  72                          (lambda (x)
  73                            (let* ((context (cdr (assoc 'context-name x)))
  74                                   (group (assq-ref x 'group-type))
  75                                   (consists (append
  76                                              (if group
  77                                                  (list group)
  78                                                  '())
  79                                              (cdr (assoc 'consists x)))))
  80                              (if (member name-sym consists)
  81                                  (list context)
  82                                  '())))
  83                          context-description-alist))))
  84            (string-append
  85             "@code{" name-str "} is part of contexts: "
  86             (human-listify (map ref-ify
  87                                 (sort
  88                                  (map symbol->string contexts) string<?)))))
  89          ""))))
  90
  91 ;; First level Engraver description
  92 (define (engraver-doc grav)
  93   (make <texi-node>
  94     #:name (symbol->string (ly:translator-name grav))
  95     #:text (engraver-doc-string grav #t)))
  96
  97 ;; Second level, part of Context description
  98 (define name->engraver-table (make-vector 61 '()))
  99 (map
 100  (lambda (x)
 101    (hash-set! name->engraver-table (ly:translator-name x) x))
 102  (ly:get-all-translators))
 103
 104 (define (find-engraver-by-name name)
 105   "NAME is a symbol."
 106   (hash-ref name->engraver-table name #f))
 107
 108 (define (document-engraver-by-name name)
 109   "NAME is a symbol."
 110
 111   (let* ((eg (find-engraver-by-name name)))
 112
 113     (cons (string-append "@code{" (ref-ify (symbol->string name)) "}")
 114           (engraver-doc-string eg #f))))
 115
 116 (define (document-property-operation op)
 117   (let ((tag (car op))
 118         (context-sym (cadr op))
 119         (args (cddr op))
 120         )
 121
 122     (cond
 123      ((equal?  tag 'push)
 124       (let*
 125           ((value (car args))
 126            (path (cdr args)))
 127
 128       (string-append
 129        "@item Set "
 130        (format "grob-property @code{~a} " (string-join (map symbol->string path) " "))
 131        (format " in @ref{~a} to @code{~a}.  " context-sym (scm->texi value))
 132        "\n")))
 133      ((equal? (object-property context-sym 'is-grob?) #t) "")
 134      ((equal? tag 'assign)
 135       (format "@item Set translator property @code{~a} to @code{~a}"
 136               context-sym
 137               (scm->texi (car args))))
 138      )))
 139
 140
 141 (define (context-doc context-desc)
 142   (let* ((name-sym (cdr (assoc 'context-name context-desc)))
 143          (name (symbol->string name-sym))
 144          (aliases (map symbol->string (cdr (assoc 'aliases context-desc))))
 145          (desc-handle (assoc 'description context-desc))
 146          (desc (if (and  (pair? desc-handle) (string? (cdr desc-handle)))
 147                    (cdr desc-handle) "(not documented)"))
 148
 149          (accepts (cdr (assoc 'accepts context-desc)))
 150          (consists (cdr (assoc 'consists context-desc)))
 151          (props (cdr (assoc 'property-ops context-desc)))
 152          (grobs  (context-grobs context-desc))
 153          (grob-refs (map (lambda (x) (ref-ify x)) grobs)))
 154
 155     (make <texi-node>
 156       #:name name
 157       #:text
 158       (string-append
 159        desc
 160        (if (pair? aliases)
 161            (string-append "\n\n This context also accepts commands for the following context(s):\n\n"
 162                           (human-listify aliases))
 163            "")
 164        "\n\nThis context creates the following layout objects: \n\n"
 165        (human-listify (uniq-list (sort grob-refs string<? )))
 166        "."
 167        (if (pair? props)
 168            (string-append
 169             "\n\nThis context sets the following properties:\n"
 170             "@itemize @bullet\n"
 171             (apply string-append (map document-property-operation props))
 172             "@end itemize\n")
 173            "")
 174
 175        (if (null? accepts)
 176            "\n\nThis context is a `bottom' context; it can not contain other contexts."
 177            (string-append
 178             "\n\nContext "
 179             name " can contain \n"
 180             (human-listify (map ref-ify (map symbol->string accepts)))))
 181
 182        "\n\nThis context is built from the following engravers: "
 183        (description-list->texi
 184         (map document-engraver-by-name consists))))))
 185
 186 (define (engraver-grobs grav)
 187   (let* ((eg (if (symbol? grav)
 188                  (find-engraver-by-name grav)
 189                  grav)))
 190     (if (eq? eg #f)
 191         '()
 192         (map symbol->string (cdr (assoc 'grobs-created (ly:translator-description eg)))))))
 193
 194 (define (context-grobs context-desc)
 195   (let* ((group (assq-ref context-desc 'group-type))
 196          (consists (append
 197                     (if group
 198                         (list group)
 199                         '())
 200                     (cdr (assoc 'consists context-desc))))
 201          (grobs  (apply append
 202                         (map engraver-grobs consists))))
 203     grobs))
 204
 205 (define (all-contexts-doc)
 206   (let* ((layout-alist
 207           (sort (ly:output-description $defaultlayout)
 208                 (lambda (x y) (symbol<? (car x) (car y)))))
 209          (names (sort (map symbol->string (map car layout-alist)) string<?))
 210          (contexts (map cdr layout-alist)))
 211
 212     (make <texi-node>
 213       #:name "Contexts"
 214       #:desc "Complete descriptions of all contexts"
 215       #:children
 216       (map context-doc contexts))))
 217
 218 (define all-engravers-list  (ly:get-all-translators))
 219 (set! all-engravers-list
 220       (sort all-engravers-list
 221             (lambda (a b) (string<? (symbol->string (ly:translator-name a))
 222                                     (symbol->string (ly:translator-name b))))))
 223
 224 (define (all-engravers-doc)
 225   (make <texi-node>
 226     #:name "Engravers"
 227     #:desc "All separate engravers"
 228     #:text "See @usermanref{Modifying context plug-ins}."
 229     #:children
 230     (map engraver-doc all-engravers-list)))
 231
 232 (define (translation-properties-doc-string lst)
 233   (let* ((ps (sort (map symbol->string lst) string<?))
 234          (sortedsyms (map string->symbol ps))
 235          (propdescs
 236           (map
 237            (lambda (x) (property->texi 'translation  x '()))
 238            sortedsyms))
 239          (texi (description-list->texi propdescs)))
 240     texi))
 241
 242 (define (translation-doc-node)
 243   (make <texi-node>
 244     #:name "Translation"
 245     #:desc "From music to layout"
 246     #:children
 247     (list
 248      (all-contexts-doc)
 249      (all-engravers-doc)
 250      (make <texi-node>
 251        #:name "Tunable context properties"
 252        #:desc "All tunable context properties"
 253        #:text (translation-properties-doc-string
 254                all-user-translation-properties))
 255
 256      (make <texi-node>
 257        #:name "Internal context properties"
 258        #:desc "All internal context properties"
 259        #:text (translation-properties-doc-string
 260                all-internal-translation-properties)))))