scm/define-event-classes.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 2005--2012 Erik Sandberg <mandolaerik@gmail.com>
   4 ;;;;
   5 ;;;; LilyPond is free software: you can redistribute it and/or modify
   6 ;;;; it under the terms of the GNU General Public License as published by
   7 ;;;; the Free Software Foundation, either version 3 of the License, or
   8 ;;;; (at your option) any later version.
   9 ;;;;
  10 ;;;; LilyPond is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;;;; GNU General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU General Public License
  16 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 (use-modules (srfi srfi-1))
  20
  21 ;; Event class hierarchy. Each line is on the form (Parent . (List of children))
  22 (define event-classes
  23   '((() . (StreamEvent))
  24     (StreamEvent .
  25                  (RemoveContext ChangeParent Override Revert UnsetProperty
  26                                 SetProperty music-event OldMusicEvent CreateContext Prepare
  27                                 OneTimeStep Finish))
  28     (music-event . (annotate-output-event footnote-event
  29                     arpeggio-event breathing-event extender-event span-event
  30       rhythmic-event dynamic-event break-event label-event percent-event
  31       key-change-event string-number-event stroke-finger-event tie-event
  32       part-combine-event part-combine-force-event
  33       beam-forbid-event script-event tempo-change-event
  34       tremolo-event bend-after-event fingering-event glissando-event
  35       harmonic-event hyphen-event laissez-vibrer-event mark-event
  36       multi-measure-text-event note-grouping-event
  37       pes-or-flexa-event repeat-tie-event spacing-section-event
  38       layout-instruction-event completize-extender-event break-span-event
  39       alternative-event))
  40
  41     (layout-instruction-event . (apply-output-event))
  42     (script-event . (articulation-event text-script-event))
  43     (part-combine-event . (solo-one-event solo-two-event unisono-event))
  44     (break-event . (line-break-event page-break-event page-turn-event))
  45     (dynamic-event . (absolute-dynamic-event))
  46     (span-event . (span-dynamic-event beam-event episema-event ligature-event
  47                                       measure-counter-event pedal-event
  48                                       phrasing-slur-event slur-event
  49                                       staff-span-event text-span-event
  50                                       trill-span-event tremolo-span-event
  51                                       tuplet-span-event))
  52     (span-dynamic-event . (decrescendo-event crescendo-event))
  53     (break-span-event . (break-dynamic-span-event))
  54     (pedal-event . (sostenuto-event sustain-event una-corda-event))
  55     (rhythmic-event . (lyric-event melodic-event multi-measure-rest-event
  56                                    double-percent-event percent-event
  57                                    repeat-slash-event rest-event
  58                                    skip-event bass-figure-event))
  59     (melodic-event . (cluster-note-event note-event))
  60     (() . (Announcement))
  61     (Announcement . (AnnounceNewContext))
  62     ))
  63
  64 (define-public (event-class-cons class parent classlist)
  65   (let ((lineage (assq parent classlist)))
  66     (if (not lineage)
  67         (begin
  68           (if (not (null? parent))
  69               (ly:warning (_ "unknown parent class `~a'") parent))
  70           (set! lineage '())))
  71     (if (symbol? class)
  72         (acons class lineage classlist)
  73         (fold (lambda (elt alist)
  74                 (acons elt lineage alist))
  75               classlist class))))
  76
  77 ;; Each class will be defined as
  78 ;; (class parent grandparent .. )
  79 ;; so that (eq? (cdr class) parent) holds.
  80
  81 (define-public (ly:in-event-class? ev cl)
  82   "Does event @var{ev} belong to event class @var{cl}?"
  83   (memq cl (ly:event-property ev 'class)))
  84
  85 (define-public all-event-classes
  86   (fold (lambda (elt classlist)
  87           (event-class-cons (cdr elt) (car elt) classlist))
  88         '() event-classes))
  89
  90 ;; does this exist in guile already?
  91 (define (map-tree f t)
  92   (cond
  93    ((list? t)
  94     (map (lambda (x) (map-tree f x)) t))
  95    ((pair? t)
  96     (cons (map-tree f (car t)) (map-tree f (cdr t))))
  97    (else (f t))))
  98
  99 ;; expand each non-leaf subtree to (root . children), recursively
 100 (define (expand-event-tree root)
 101   (let ((children (assq root event-classes)))
 102     (if children
 103         (cons root (map expand-event-tree (cdr children)))
 104         root)))
 105
 106 ;; produce neater representation of music event tree.
 107 ;; TODO: switch to this representation for the event-classes list?
 108 (define music-event-tree (expand-event-tree 'music-event))
 109 (define (sort-tree t)
 110   (define (stringify el)
 111               (if (symbol? el)
 112                   (symbol->string el)
 113                   (symbol->string (first el))))
 114   (if (list? t)
 115       (sort (map (lambda (el)
 116                    (if (list? el)
 117                        (cons (car el) (sort-tree (cdr el)))
 118                        el))
 119                  t)
 120             (lambda (a b) (string<? (stringify a) (stringify b))))
 121       t))
 122
 123 ;;(use-modules (ice-9 pretty-print))
 124 ;;(pretty-print (cons (car music-event-tree) (sort-tree (cdr music-event-tree))))
 125
 126 (defmacro-public make-stream-event (expr)
 127   (Stream_event::undump (primitive-eval (list 'quasiquote expr))))
 128
 129 (define* (simplify e)
 130   (cond
 131    ;; Special case for lists reduces stack consumption.
 132    ((list? e) (map simplify e))
 133    ((pair? e) (cons (simplify (car e))
 134                     (simplify (cdr e))))
 135    ((ly:stream-event? e)
 136     (list 'unquote (list 'make-stream-event (simplify (Stream_event::dump e)))))
 137    ((ly:music? e)
 138     (list 'unquote (music->make-music e)))
 139    ((ly:moment? e)
 140     (list 'unquote `(ly:make-moment
 141                      ,(ly:moment-main-numerator e)
 142                      ,(ly:moment-main-denominator e)
 143                      . ,(if (zero? (ly:moment-grace-numerator e))
 144                             '()
 145                             (list (ly:moment-grace-numerator e)
 146                                   (ly:moment-grace-denominator e))))))
 147    ((ly:duration? e)
 148     (list 'unquote `(ly:make-duration
 149                      ,(ly:duration-log e)
 150                      ,(ly:duration-dot-count e)
 151                      ,(ly:duration-scale))))
 152    ((ly:pitch? e)
 153     (list 'unquote `(ly:make-pitch
 154                      ,(ly:pitch-octave e)
 155                      ,(ly:pitch-notename e)
 156                      ,(ly:pitch-alteration e))))
 157    ((ly:input-location? e)
 158     (list 'unquote '(ly:dummy-input-location)))
 159    (#t e)))
 160
 161 (define-public (ly:simplify-scheme e)
 162   (list 'quasiquote (simplify e)))