scm/chord-ignatzek-names.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 2000--2011  Han-Wen Nienhuys <hanwen@xs4all.nl>
   4 ;;;;
   5 ;;;; LilyPond is free software: you can redistribute it and/or modify
   6 ;;;; it under the terms of the GNU General Public License as published by
   7 ;;;; the Free Software Foundation, either version 3 of the License, or
   8 ;;;; (at your option) any later version.
   9 ;;;;
  10 ;;;; LilyPond is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;;;; GNU General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU General Public License
  16 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19
  20 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  22 ;;
  23 ;; jazz-part 2
  24 ;;
  25 ;; after Klaus Ignatzek,   Die Jazzmethode fuer Klavier 1.
  26 ;;
  27 ;; The idea is: split chords into
  28 ;;
  29 ;;  ROOT PREFIXES MAIN-NAME ALTERATIONS SUFFIXES ADDITIONS
  30 ;;
  31 ;; and put that through a layout routine.
  32 ;;
  33 ;; the split is a procedural process, with lots of set!.
  34 ;;
  35
  36
  37 ;; todo: naming is confusing: steps  (0 based) vs. steps (1 based).
  38 (define (pitch-step p)
  39   "Musicological notation for an interval.  Eg. C to D is 2."
  40   (+ 1 (ly:pitch-steps p)))
  41
  42 (define (get-step x ps)
  43   "Does PS have the X step? Return that step if it does."
  44   (if (null? ps)
  45       #f
  46       (if (= (- x 1) (ly:pitch-steps (car ps)))
  47           (car ps)
  48           (get-step x (cdr ps)))))
  49
  50 (define (replace-step p ps)
  51   "Copy PS, but replace the step of P in PS."
  52   (if (null? ps)
  53       '()
  54       (let* ((t (replace-step p (cdr ps))))
  55         (if (= (ly:pitch-steps p) (ly:pitch-steps (car ps)))
  56             (cons p t)
  57             (cons (car ps) t)))))
  58
  59 (define (remove-step x ps)
  60   "Copy PS, but leave out the Xth step."
  61   (if (null? ps)
  62       '()
  63       (let* ((t (remove-step x (cdr ps))))
  64         (if (= (- x 1) (ly:pitch-steps (car ps)))
  65             t
  66             (cons (car ps) t)))))
  67
  68
  69 (define-public (ignatzek-chord-names
  70                 in-pitches bass inversion
  71                 context)
  72
  73   (define (remove-uptil-step x ps)
  74     "Copy PS, but leave out everything below the Xth step."
  75     (if (null? ps)
  76         '()
  77         (if (< (ly:pitch-steps (car ps)) (- x 1))
  78             (remove-uptil-step x (cdr ps))
  79             ps)))
  80
  81   (define name-root (ly:context-property context 'chordRootNamer))
  82   (define name-note
  83     (let ((nn (ly:context-property context 'chordNoteNamer)))
  84       (if (eq? nn '())
  85           ;; replacing the next line with name-root gives guile-error...? -rz
  86
  87           ;; apparently sequence of defines is equivalent to let, not let* ? -hwn
  88           (ly:context-property context 'chordRootNamer)
  89           ;; name-root
  90           nn)))
  91
  92   (define (is-natural-alteration? p)
  93     (= (natural-chord-alteration p) (ly:pitch-alteration p)))
  94
  95   (define (ignatzek-format-chord-name
  96            root
  97            prefix-modifiers
  98            main-name
  99            alteration-pitches
 100            addition-pitches
 101            suffix-modifiers
 102            bass-pitch
 103            lowercase-root?)
 104
 105     "Format for the given (lists of) pitches.  This is actually more
 106 work than classifying the pitches."
 107
 108     (define (filter-main-name p)
 109       "The main name: don't print anything for natural 5 or 3."
 110       (if
 111        (or (not (ly:pitch? p))
 112            (and (is-natural-alteration? p)
 113                 (or (= (pitch-step p) 5)
 114                     (= (pitch-step p) 3))))
 115        '()
 116        (list (name-step p))))
 117
 118     (define (glue-word-to-step word x)
 119       (make-line-markup
 120        (list
 121         (make-simple-markup word)
 122         (name-step x))))
 123
 124     (define (suffix-modifier->markup mod)
 125       (if (or (= 4 (pitch-step mod))
 126               (= 2 (pitch-step mod)))
 127           (glue-word-to-step "sus" mod)
 128           (glue-word-to-step "huh" mod)))
 129
 130     (define (prefix-modifier->markup mod)
 131       (if (and (= 3 (pitch-step mod))
 132                (= FLAT (ly:pitch-alteration mod)))
 133           (if lowercase-root?
 134               empty-markup
 135               (ly:context-property context 'minorChordModifier))
 136           (make-simple-markup "huh")))
 137
 138     (define (filter-alterations alters)
 139       "Filter out uninteresting (natural) pitches from ALTERS."
 140
 141       (define (altered? p)
 142         (not (is-natural-alteration? p)))
 143
 144       (if
 145        (null? alters)
 146        '()
 147        (let* ((lst (filter altered? alters))
 148               (lp (last-pair alters)))
 149
 150          ;; we want the highest also if unaltered
 151          (if (and (not (altered? (car lp)))
 152                   (> (pitch-step (car lp)) 5))
 153              (append lst (last-pair alters))
 154              lst))))
 155
 156     (define (name-step pitch)
 157       (define (step-alteration pitch)
 158         (- (ly:pitch-alteration pitch)
 159            (natural-chord-alteration pitch)))
 160
 161       (let* ((num-markup (make-simple-markup
 162                           (number->string (pitch-step pitch))))
 163              (args (list num-markup))
 164              (total (if (= (ly:pitch-alteration pitch) 0)
 165                         (if (= (pitch-step pitch) 7)
 166                             (list (ly:context-property context 'majorSevenSymbol))
 167                             args)
 168                         (cons (accidental->markup (step-alteration pitch)) args))))
 169
 170         (make-line-markup total)))
 171
 172     (let* ((sep (ly:context-property context 'chordNameSeparator))
 173            (slashsep (ly:context-property context 'slashChordSeparator))
 174            (root-markup (name-root root lowercase-root?))
 175            (add-markups (map (lambda (x) (glue-word-to-step "add" x))
 176                              addition-pitches))
 177            (filtered-alterations (filter-alterations alteration-pitches))
 178            (alterations (map name-step filtered-alterations))
 179            (suffixes (map suffix-modifier->markup suffix-modifiers))
 180            (prefixes (map prefix-modifier->markup prefix-modifiers))
 181            (main-markups (filter-main-name main-name))
 182            (to-be-raised-stuff (markup-join
 183                                 (append
 184                                  main-markups
 185                                  alterations
 186                                  suffixes
 187                                  add-markups) sep))
 188            (base-stuff (if (ly:pitch? bass-pitch)
 189                            (list slashsep (name-note bass-pitch #f))
 190                            '())))
 191
 192       (set! base-stuff
 193             (append
 194              (list root-markup
 195                    (conditional-kern-before (markup-join prefixes sep)
 196                                             (and (not (null? prefixes))
 197                                                  (= (ly:pitch-alteration root) NATURAL))
 198                                             (ly:context-property context 'chordPrefixSpacer))
 199                    (make-super-markup to-be-raised-stuff))
 200              base-stuff))
 201       (make-line-markup base-stuff)))
 202
 203   (define (ignatzek-format-exception
 204            root
 205            exception-markup
 206            bass-pitch
 207            lowercase-root?)
 208
 209     (make-line-markup
 210      `(
 211        ,(name-root root lowercase-root?)
 212        ,exception-markup
 213        .
 214        ,(if (ly:pitch? bass-pitch)
 215             (list (ly:context-property context 'slashChordSeparator)
 216                   (name-note bass-pitch #f))
 217             '()))))
 218
 219   (let* ((root (car in-pitches))
 220          (pitches (map (lambda (x) (ly:pitch-diff x root)) (cdr in-pitches)))
 221          (lowercase-root?
 222           (and (ly:context-property context 'chordNameLowercaseMinor)
 223        (let ((third (get-step 3 pitches)))
 224             (and third (= (ly:pitch-alteration third) FLAT)))))
 225          (exceptions (ly:context-property context 'chordNameExceptions))
 226          (exception (assoc-get pitches exceptions))
 227          (prefixes '())
 228          (suffixes '())
 229          (add-steps '())
 230          (main-name #f)
 231          (bass-note
 232           (if (ly:pitch? inversion)
 233               inversion
 234               bass))
 235          (alterations '()))
 236
 237     (if exception
 238         (ignatzek-format-exception root exception bass-note lowercase-root?)
 239
 240         (begin
 241           ;; no exception.
 242           ;; handle sus4 and sus2 suffix: if there is a 3 together with
 243           ;; sus2 or sus4, then we explicitly say add3.
 244           (map
 245            (lambda (j)
 246              (if (get-step j pitches)
 247                  (begin
 248                    (if (get-step 3 pitches)
 249                        (begin
 250                          (set! add-steps (cons (get-step 3 pitches) add-steps))
 251                          (set! pitches (remove-step 3 pitches))))
 252                    (set! suffixes (cons (get-step j pitches) suffixes)))))
 253            '(2 4))
 254
 255           ;; do minor-3rd modifier.
 256           (if (and (get-step 3 pitches)
 257                    (= (ly:pitch-alteration (get-step 3 pitches)) FLAT))
 258               (set! prefixes (cons (get-step 3 pitches) prefixes)))
 259
 260           ;; lazy bum. Should write loop.
 261           (cond
 262            ((get-step 7 pitches) (set! main-name (get-step 7 pitches)))
 263            ((get-step 6 pitches) (set! main-name (get-step 6 pitches)))
 264            ((get-step 5 pitches) (set! main-name (get-step 5 pitches)))
 265            ((get-step 4 pitches) (set! main-name (get-step 4 pitches)))
 266            ((get-step 3 pitches) (set! main-name (get-step 3 pitches))))
 267
 268           (let* ((3-diff? (lambda (x y)
 269                             (= (- (pitch-step y) (pitch-step x)) 2)))
 270                  (split (split-at-predicate
 271                          3-diff? (remove-uptil-step 5 pitches))))
 272             (set! alterations (append alterations (car split)))
 273             (set! add-steps (append add-steps (cdr split)))
 274             (set! alterations (delq main-name alterations))
 275             (set! add-steps (delq main-name add-steps))
 276
 277
 278             ;; chords with natural (5 7 9 11 13) or leading subsequence.
 279             ;; etc. are named by the top pitch, without any further
 280             ;; alterations.
 281             (if (and
 282                  (ly:pitch? main-name)
 283                  (= 7 (pitch-step main-name))
 284                  (is-natural-alteration? main-name)
 285                  (pair? (remove-uptil-step 7 alterations))
 286                  (reduce (lambda (x y) (and x y)) #t
 287                          (map is-natural-alteration? alterations)))
 288                 (begin
 289                   (set! main-name (last alterations))
 290                   (set! alterations '())))
 291
 292             (ignatzek-format-chord-name
 293              root prefixes main-name alterations add-steps suffixes bass-note
 294              lowercase-root?))))))