lilypond-texi2html.init

   1 #!/usr/bin/env perl
   2
   3 ### texi2html customization script for Lilypond
   4 ### Author: Reinhold Kainhofer <reinhold@kainhofer.com>, 2008.
   5 ###         Some code parts copied from texi2html and adapted.
   6 ### License: GPLv2+
   7 ###
   8 ###
   9 ### Features implemented here:
  10 ### -) For split manuals, the main page is index.html.
  11 ### -) All @unnumbered* sections are placed into the same file
  12 ###    (implemented by split_at_numbered_sections)
  13 ### -) Use our custom CSS file, with IE-specific fixes in another CSS file,
  14 ###    impelmented by lilypond_css_lines
  15 ### -) TOC (folded, with the current page highlighted) in an iframe is added
  16 ###    to every page; implemented by:
  17 ###           lilypond_print_element_header -- building of the TOC
  18 ###           lilypond_toc_body -- generation of customized TOC output
  19 ###           lilypond_print_page_head -- start <div id="main">
  20 ###           print_lilypond_page_foot -- closing id=main, output of footer & TOC
  21 ### -) External refs are formatted only as "Text of the node" (not as >>see
  22 ###    "NODE" section "SECTION" in "BOOK"<< like with default texi2html). Also,
  23 ###    the leading "(book-name)" is removed.
  24 ###    Implemented by overriding lilypond_external_ref
  25 ### -) Navigation bars on top/bottom of the page and between sections are not
  26 ###    left-aligned, but use a combination of left/center/right aligned table
  27 ###    cells; For this, I heavily extend the texi2html code to allow for
  28 ###    differently aligned cells and for multi-line tables);
  29 ###    Implemented in lilypond_print_navigation
  30 ### -) Different formatting than the default: example uses the same formatting
  31 ###    as quote.
  32 ### -) Allow translated section titles: All section titles can be translated,
  33 ###    the original (English) title is associated with @translationof. This is
  34 ###    needed, because the file name / anchor is generated from the original
  35 ###    English title, since otherwise language-autoselection would break with
  36 ###    posted links.
  37 ###    Since it is then no longer possible to obtain the file name from the
  38 ###    section title, I keep a sectionname<=>filename/anchor around. This way,
  39 ###    xrefs from other manuals can simply load that map and retrieve the
  40 ###    correct file name for the link. Implemented in:
  41 ###           lilypond_unknown (handling of @translationof, in case
  42 ###                             extract_texi_filenames.py messes up...)
  43 ###           split_at_numbered_sections (correct file name: use the map)
  44 ###           lilypond_init_map (read in the externally created map from disk)
  45 ###           lilypond_external_href (load the map for xrefs, use the correct
  46 ###                                   link target)
  47 ###
  48 ###
  49 ### Useful helper functions:
  50 ### -) texinfo_file_name($node_name): returns a texinfo-compatible file name
  51 ###    for the given string $node_name (whitespace trimmed/replaced by -,
  52 ###    non-standard chars replaced by _xxxx (ascii char code) and forced to
  53 ###    start with a letter by prepending t_g if necessary)
  54
  55
  56 package Texi2HTML::Config;
  57
  58
  59
  60
  61
  62 #############################################################################
  63 ###  SETTINGS FOR TEXI2HTML
  64 #############################################################################
  65
  66 @Texi2HTML::Config::CSS_REFS      = ("lilypond.css");
  67 $Texi2HTML::Config::USE_ACCESSKEY = 1;
  68 $Texi2HTML::Config::USE_LINKS     = 1;
  69 $Texi2HTML::Config::USE_REL_REV   = 1;
  70 $Texi2HTML::Config::element_file_name    = \&split_at_numbered_sections;
  71 $Texi2HTML::Config::print_element_header = \&lilypond_print_element_header;
  72 $Texi2HTML::Config::print_page_foot      = \&print_lilypond_page_foot;
  73 $Texi2HTML::Config::print_navigation     = \&lilypond_print_navigation;
  74 $Texi2HTML::Config::external_ref         = \&lilypond_external_ref;
  75 $Texi2HTML::Config::external_href        = \&lilypond_external_href;
  76 $Texi2HTML::Config::toc_body             = \&lilypond_toc_body;
  77 $Texi2HTML::Config::css_lines            = \&lilypond_css_lines;
  78 $Texi2HTML::Config::unknown              = \&lilypond_unknown;
  79 $Texi2HTML::Config::print_page_head      = \&lilypond_print_page_head;
  80
  81 # Examples should be formatted similar to quotes:
  82 $Texi2HTML::Config::complex_format_map->{'example'} = {
  83   'begin' => q{"<blockquote><pre class=\"example\">"},
  84   'end' => q{"</pre></blockquote>\n"},
  85  };
  86
  87
  88 my @section_to_filename;
  89
  90
  91
  92
  93 #############################################################################
  94 ###  DEBUGGING
  95 #############################################################################
  96
  97 use Data::Dumper;
  98 $Data::Dumper::Maxdepth = 2;
  99
 100 sub print_element_info($)
 101 {
 102   my $element = shift;
 103   print "~~~~~~~~~~~~~~~~~~~~~~~~~~~~\n";
 104   print "Element: $element\n";
 105   print Dumper($element);
 106 }
 107
 108
 109
 110
 111
 112 #############################################################################
 113 ###  HELPER FUNCTIONS
 114 #############################################################################
 115
 116 # Convert a given node name to its proper file name (normalization as explained
 117 # in the texinfo manual:
 118 # http://www.gnu.org/software/texinfo/manual/texinfo/html_node/HTML-Xref-Node-Name-Expansion.html
 119 sub texinfo_file_name($)
 120 {
 121   my $text = shift;
 122   my $result = '';
 123   # File name normalization by texinfo:
 124   # 1/2: letters and numbers are left unchanged
 125   # 3/4: multiple, leading and trailing whitespace is removed
 126   $text = main::normalise_space($text);
 127   # 5/6: all remaining spaces are converted to '-', all other 7- or 8-bit
 128   #      chars are replaced by _xxxx (xxxx=ascii character code)
 129   while ($text ne '') {
 130     if ($text =~ s/^([A-Za-z0-9]+)//o) { # number or letter stay unchanged
 131       $result .= $1;
 132     } elsif ($text =~ s/^ //o) { # space -> '-'
 133       $result .= '-';
 134     } elsif ($text =~ s/^(.)//o) { # Otherwise use _xxxx (ascii char code)
 135       my $ccode = ord($1);
 136       if ( $ccode <= 0xFFFF ) {
 137         $result .= sprintf("_%04x", $ccode);
 138       } else {
 139         $result .= sprintf("__%06x", $ccode);
 140       }
 141     }
 142   }
 143   # 7: if name does not begin with a letter, prepend 't_g' (so it starts with a letter)
 144   if ($result !~ /^[a-zA-Z]/) {
 145     $result = 't_g' . $result;
 146   }
 147   # DONE
 148   return $result
 149 }
 150
 151
 152 # Load a file containing a nodename<=>filename map (tab-sepatared, i.e.
 153 # NODENAME\tFILENAME\tANCHOR
 154 # Returns a ref to a hash "Node title" => ["FilenameWithoutExt", "Anchor"]
 155 sub load_map_file ($)
 156 {
 157     my $mapfile = shift;
 158     my $node_map = ();
 159
 160     if (open(XREFFILE, $mapfile)) {
 161         my $line;
 162         while ( $line = <XREFFILE> ) {
 163             # parse the tab-separated entries and insert them into the map:
 164             chomp($_);
 165             my @entries = split(/\t/, $line);
 166             if (scalar (@entries) == 3) {
 167               $node_map->{$entries[0]} = [$entries[1], $entries[2]];
 168             } else {
 169               print STDERR "Invalid entry in the node file $mapfile: $line\n";
 170             }
 171         }
 172         close (XREFFILE);
 173     } else {
 174         print STDERR "Unable to load the map file $mapfile\n";
 175     }
 176     return $node_map;
 177 }
 178
 179
 180 # Split the given path into dir and basename (with .texi removed). Used mainly
 181 # to get the path/basename of the original texi input file
 182 sub split_texi_filename ($)
 183 {
 184   my $docu = shift;
 185   my $docu_dir, $docu_name;
 186   if ($docu =~ /(.*\/)/) {
 187     chop($docu_dir = $1);
 188     $docu_name = $docu;
 189     $docu_name =~ s/.*\///;
 190   } else {
 191      $docu_dir = '.';
 192      $docu_name = $docu;
 193   }
 194   $docu_name =~ s/\.te?x(i|info)?$//;
 195   return ($docu_dir, $docu_name);
 196 }
 197
 198
 199
 200
 201
 202 #############################################################################
 203 ###  CSS HANDLING
 204 #############################################################################
 205
 206 # Include our standard CSS file, not hard-coded CSS code directly in the HTML!
 207 # For IE, conditionally include the lilypond-ie-fixes.css style sheet
 208 sub lilypond_css_lines ($$)
 209 {
 210     my $import_lines = shift;
 211     my $rule_lines = shift;
 212     return if (defined($CSS_LINES));
 213     if (@$rule_lines or @$import_lines)
 214     {
 215         $CSS_LINES = "<style type=\"text/css\">\n<!--\n";
 216         $CSS_LINES .= join('',@$import_lines) . "\n" if (@$import_lines);
 217         $CSS_LINES .= join('',@$rule_lines) . "\n" if (@$rule_lines);
 218         $CSS_LINES .= "-->\n</style>\n";
 219     }
 220     foreach my $ref (@CSS_REFS)
 221     {
 222         $CSS_LINES .= "<link rel=\"stylesheet\" type=\"text/css\" href=\"$ref\">\n";
 223     }
 224     $CSS_LINES .= "<!--[if lte IE 7]>\n<link href=\"lilypond-ie-fixes.css\" rel=\"stylesheet\" type=\"text/css\">\n<![endif]-->\n";
 225 }
 226
 227
 228
 229
 230
 231 #############################################################################
 232 ###  SPLITTING BASED ON NUMBERED SECTIONS
 233 #############################################################################
 234
 235 my $lastfilename;
 236 my $docnr = 0;
 237 my $node_to_filename_map = ();
 238
 239 # This function makes sure that files are only generated for numbered sections,
 240 # but not for unnumbered ones. It is called after texi2html has done its own
 241 # splitting and simply returns the filename for the node given as first argument
 242 # Nodes with the same filename will be printed out to the same filename, so
 243 # this really all we need. Also, make sure that the file names for sections
 244 # are derived from the section title. We also might want to name the anchors
 245 # according to node titles, which works by simply overriding the id element of
 246 # the $element hash.
 247 # If an external nodename<=>filename/anchor map file is found (loaded in
 248 # lilypond_init_out, use the externally created values, otherwise use the
 249 # same logic here.
 250 sub split_at_numbered_sections($$$)
 251 {
 252   my $element = shift;
 253   my $type = shift;
 254   my $docu_name = shift;
 255   my $docu_ext = $Texi2HTML::Config::EXTENSION;
 256
 257   my $node_name = main::remove_texi($element->{'node_ref'}->{'texi'});
 258   # the snippets page does not use nodes for the snippets, so in this case
 259   # we'll have to use the section name!
 260   if ($node_name eq '') {
 261     $node_name = main::remove_texi($element->{'texi'});
 262   }
 263
 264   # If we have an entry in the section<=>filename map, use that one, otherwise
 265   # generate the filename/anchor here. In the latter case, external manuals
 266   # will not be able to retrieve the file name for xrefs!!! Still, I already
 267   # had that code, so I'll leave it in in case something goes wrong with the
 268   # extract_texi_filenames.py script in the lilypond build process!
 269   if (exists ($node_to_filename_map->{$node_name})) {
 270     (my $filename, my $anchor) = @{$node_to_filename_map->{$node_name}};
 271     $filename .= ".$docu_ext" if (defined($docu_ext));
 272
 273     $element->{id} = $anchor;
 274     if ($filename eq $lastfilename) {
 275       $$element{doc_nr} = $docnr;
 276     } else {
 277       $docnr += 1;
 278       $$element{doc_nr} = $docnr;
 279       $lastfilename = $filename;
 280     }
 281     return $filename;
 282
 283   } elsif ($type eq "top" or $type eq "toc" or $type eq "doc" or $type eq "stoc" or $type eq "foot" or $type eq "about") {
 284     # TOC, footer, about etc. are called with undefined $element and $type == "toc"|"stoc"|"foot"|"about"
 285     return;
 286   } else {
 287     print STDERR "WARNING: Node '$node_name' was NOT found in the map\n"
 288         unless ($node_name eq '') or ($element->{'tag'} eq 'unnumberedsec')
 289                or ($node_name =~ /NOT REALLY USED/);
 290
 291     # derive the name of the anchor (i.e. the part after # in the links!),
 292     # don't use texi2html's SECx.x default!
 293     my $sec_name = main::remove_texi($element->{'texi'});
 294     # if we have a node, use its name:
 295     if ($element->{'node_ref'}->{'texi'} ne '') {
 296       $sec_name = main::remove_texi($element->{'node_ref'}->{'texi'});
 297     }
 298     my $anchor = $sec_name;
 299     if ($element->{translationof}) {
 300       $anchor = main::remove_texi($$element{translationof});
 301     }
 302     # normalize to the same file name as texinfo
 303     $anchor = texinfo_file_name($anchor);
 304     $$element{id} = $anchor;
 305     # Numbered sections will get a filename Node_title, unnumbered sections will use
 306     # the file name of the previous numbered section:
 307     if (($element->{number}) or ($lastfilename eq '') or ($element->{level} == 1)) {
 308       my $filename = $anchor;
 309       $filename .= ".$docu_ext" if (defined($docu_ext));
 310       $docnr += 1;
 311       $$element{doc_nr} = $docnr;
 312       $lastfilename = $filename;
 313       return $filename;
 314     } else {
 315       $$element{doc_nr} = $docnr;
 316       return $lastfilename;
 317     }
 318   }
 319
 320   return;
 321 }
 322
 323
 324 ## Load the map file for the corrently processed texi file. We do this
 325 #  (mis-)using a command init handler, since texi2html does not have any
 326 #  other hooks that are called after THISDOC is filled but before phase 2
 327 #  of the texi2html conversion.
 328 sub lilypond_init_map ()
 329 {
 330     my ($docu_dir, $docu_name) = split_texi_filename ($Texi2HTML::THISDOC{'input_file_name'});
 331     my $map_filename = "$docu_dir/${docu_name}.xref-map";
 332     $node_to_filename_map = load_map_file ($map_filename);
 333 }
 334 push @Texi2HTML::Config::command_handler_init, \&lilypond_init_map;
 335
 336
 337
 338 #############################################################################
 339 ###  CLEANER LINK TITLE FOR EXTERNAL REFS
 340 #############################################################################
 341
 342 # The default formatting of external refs returns e.g.
 343 # "(lilypond-internals)Timing_translator", so we remove all (...) from the
 344 # file_and_node argument. Also, we want only a very simple format, so we don't
 345 # even call the default handler!
 346 sub lilypond_external_ref($$$$$$)
 347 {
 348   my $type = shift;
 349   my $section = shift;
 350   my $book = shift;
 351   my $file_node = shift;
 352   my $href = shift;
 353   my $cross_ref = shift;
 354
 355   $file_node =~ s/\(.*\)//;
 356   $file_node = &$anchor('', $href, $file_node) if ($file_node ne '');
 357   return &$I('%{node_file_href}', { 'node_file_href' => $file_node });
 358
 359 #  Default: format as "see <a ..>NODE</a> section 'SECTION' in BOOK". We don't want this!
 360 #   return t2h_default_external_ref($type, $section, $book, $file_node, $href, $cross_ref);
 361 }
 362
 363
 364
 365
 366
 367 #############################################################################
 368 ###  HANDLING TRANSLATED SECTIONS: handle @translationof, secname<->filename
 369 ###                  map stored on disk, xrefs in other manuals load that map
 370 #############################################################################
 371
 372
 373 # Try to make use of @translationof to generate files according to the original
 374 # English section title...
 375 sub lilypond_unknown($$$$$)
 376 {
 377     my $macro = shift;
 378     my $line = shift;
 379     my $pass = shift;
 380     my $stack = shift;
 381     my $state = shift;
 382
 383     # the @translationof macro provides the original English section title,
 384     # which should be used for file/anchor naming, while the title will be
 385     # translated to each language
 386     # It is already used by extract_texi_filenames.py, so this should not be
 387     # necessary here at all. Still, I'll leave the code in just in case the
 388     # python script messed up ;-)
 389     if ($pass == 1 and $macro eq "translationof") {
 390       if (ref($state->{'element'}) eq 'HASH') {
 391         $state->{'element'}->{'translationof'} = main::normalise_space($line);
 392       }
 393       return ('', true, undef, undef);
 394     } else {
 395       return t2h_default_unknown($macro, $line, $pass, $stack, $state);
 396     }
 397 }
 398
 399
 400
 401
 402 my %translated_books = ();
 403 # Construct a href to an external source of information.
 404 # node is the node with texinfo @-commands
 405 # node_id is the node transliterated and transformed as explained in the
 406 #         texinfo manual
 407 # node_xhtml_id is the node transformed such that it is unique and can
 408 #     be used to make an html cross ref as explained in the texinfo manual
 409 # file is the file in '(file)node'
 410 sub lilypond_external_href($$$)
 411 {
 412   my $node = shift;
 413   my $node_id = shift;
 414   my $node_hxmlt_id = shift;
 415   my $file = shift;
 416   my $original_func = \&t2h_default_external_href;
 417
 418   # 1) Keep a hash of book->section_map
 419   # 2) if not file in keys hash => try to load the map (assign empty map if
 420   #    non-existent => will load only once!)
 421   # 3) if node in the section=>(file, anchor) map, replace node_id and
 422   #    node_xhtml_id by the map's values
 423   # 4) call the t2h_default_external_href with these values (or the old ones if not found)
 424
 425   if (($node_id ne '') and defined($file) and ($node_id ne 'Top')) {
 426     my $map_name = $file;
 427     $map_name =~ s/-big-page//;
 428
 429     # Load the map if we haven't done so already
 430     if (!exists($translated_books{$map_name})) {
 431       my ($docu_dir, $docu_name) = split_texi_filename ($Texi2HTML::THISDOC{'input_file_name'});
 432       my $map_filename = "$docu_dir/${map_name}.xref-map";
 433       $translated_books{$map_name} = load_map_file ($map_filename);
 434     }
 435
 436     # look up translation. use these values instead of the old filename/anchor
 437     my $section_name_map = $translated_books{$map_name};
 438     my $node_text = main::remove_texi($node);
 439     if (defined($section_name_map->{$node_text})) {
 440       ($node_id, $node_hxmlt_id) = @{$section_name_map->{$node_text}};
 441     } else {
 442       print STDERR "Unable to find key '$node_text' in section_name_map for book $map_name\n";
 443     }
 444   }
 445
 446   if (defined $file) {
 447     return &$original_func($node, $node_id, $node_hxmlt_id, $file);
 448   } else {
 449     return &$original_func($node, $node_id, $node_hxmlt_id);
 450   }
 451 }
 452
 453
 454
 455
 456
 457 #############################################################################
 458 ###  CUSTOM TOC FOR EACH PAGE (in a frame on the left)
 459 #############################################################################
 460
 461 my $page_toc_depth = 2;
 462 my @default_toc = [];
 463
 464 # recursively generate the TOC entries for the element and its children (which
 465 # are only shown up to maxlevel. All ancestors of the current element are also
 466 # shown with their immediate children, irrespective of their level.
 467 # Unnumbered entries are only printed out if they are at top-level or their
 468 # parent element is an ancestor of the currently viewed node.
 469 sub generate_ly_toc_entries($$$$)
 470 {
 471   my $element = shift;
 472   my $element_path = shift;
 473   my $maxlevel = shift;
 474   my $always_show_unnumbered_children = shift;
 475   # Skip undefined sections, plus all sections generated by index splitting
 476   return() if (not defined($element) or exists($element->{'index_page'}));
 477   my @result = ();
 478   my $level = $element->{'toc_level'};
 479   my $is_parent_of_current = $element->{'id'} && $element_path->{$element->{'id'}};
 480   my $print_children = ( ($level < $maxlevel) or $is_parent_of_current );
 481   my $ind = '  ' x $level;
 482   my $this_css_class = $is_parent_of_current ? " class=\"toc_current\"" : "";
 483
 484   my $entry = "$ind<li$this_css_class>" . &$anchor ($element->{'tocid'}, "$element->{'file'}#$element->{'id'}",$element->{'text'});
 485
 486   my $children = $element->{'section_childs'};
 487   # Don't add unnumbered entries, unless they are at top-level or a parent of the current!
 488   if (not ($element->{'number'} or $always_show_unnumbered_children)) {
 489     return @result;
 490   }
 491   if ( $print_children and defined($children) and (ref($children) eq "ARRAY") ) {
 492     push (@result, $entry);
 493     my @child_result = ();
 494     foreach (@$children) {
 495       push (@child_result, generate_ly_toc_entries($_, $element_path, $maxlevel, $is_parent_of_current));
 496     }
 497     # if no child nodes were generated, e.g. for the index, where expanded pages
 498     # are ignored, don't generate a list at all...
 499     if (@child_result) {
 500       push (@result, "\n$ind<ul$NO_BULLET_LIST_ATTRIBUTE>\n");
 501       push (@result, @child_result);
 502       push (@result, "$ind</ul></li>\n");
 503     }
 504   } else {
 505     push (@result, $entry . "</li>\n");
 506   }
 507   return @result;
 508 }
 509
 510
 511 # Print a customized TOC, containing only the first two levels plus the whole
 512 # path to the current page
 513 sub lilypond_generate_page_toc_body($)
 514 {
 515     my $element = shift;
 516     my $current_element = $element;
 517     my %parentelements;
 518     $parentelements{$element->{'id'}} = 1;
 519     # Find the path to the current element
 520     while ( defined($current_element->{'sectionup'}) and
 521            ($current_element->{'sectionup'} ne $current_element) )
 522     {
 523       $parentelements{$current_element->{'sectionup'}->{'id'}} = 1
 524               if ($current_element->{'sectionup'}->{'id'} ne '');
 525       $current_element = $current_element->{'sectionup'};
 526     }
 527     return () if not defined($current_element);
 528     # Create the toc entries recursively
 529     my @toc_entries = ("<div class=\"contents\">\n", "<ul$NO_BULLET_LIST_ATTRIBUTE>\n");
 530     my $children = $current_element->{'section_childs'};
 531     foreach ( @$children ) {
 532       push (@toc_entries, generate_ly_toc_entries($_, \%parentelements, $page_toc_depth, False));
 533     }
 534     push (@toc_entries, "</ul>\n");
 535     push (@toc_entries, "</div>\n");
 536     return @toc_entries;
 537 }
 538
 539 sub lilypond_print_toc_div ($$)
 540 {
 541   my $fh = shift;
 542   my $tocref = shift;
 543   my @lines = @$tocref;
 544   # use default TOC if no custom lines have been generated
 545   @lines = @default_toc if (not @lines);
 546   if (@lines) {
 547     print $fh "\n\n<div id=\"tocframe\">\n";
 548     print $fh '<h4> ' . $Texi2HTML::NAME{'Contents'}  . "</h4>\n";
 549     foreach my $line (@lines) {
 550       print $fh $line;
 551     }
 552     print $fh "</div>\n\n";
 553   }
 554 }
 555
 556 # Create the custom TOC for this page (partially folded, current page is
 557 # highlighted) and store it in a global variable. The TOC is written out after
 558 # the html contents (but positioned correctly using CSS), so that browsers with
 559 # css turned off still show the contents first.
 560 our @this_page_toc = ();
 561 sub lilypond_print_element_header
 562 {
 563   my $fh = shift;
 564   my $first_in_page = shift;
 565   my $previous_is_top = shift;
 566   if ($first_in_page and not @this_page_toc) {
 567     if (defined($Texi2HTML::THIS_ELEMENT)) {
 568       # Create the TOC for this page
 569       @this_page_toc = lilypond_generate_page_toc_body($Texi2HTML::THIS_ELEMENT);
 570     }
 571   }
 572   return T2H_DEFAULT_print_element_header( $fh, $first_in_page, $previous_is_top);
 573 }
 574
 575 # Generate the HTML output for the TOC
 576 sub lilypond_toc_body($)
 577 {
 578     my $elements_list = shift;
 579     # Generate a default TOC for pages without THIS_ELEMENT
 580     @default_toc = lilypond_generate_page_toc_body(@$elements_list[0]);
 581     return T2H_GPL_toc_body($elements_list);
 582 }
 583
 584 # Print out the TOC in a <div> at the beginning of the page
 585 sub lilypond_print_page_head($)
 586 {
 587     my $fh = shift;
 588     T2H_DEFAULT_print_page_head($fh);
 589     print $fh "<div id=\"main\">\n";
 590 }
 591
 592 # Print out the TOC in a <div> at the end of th page, which will be formatted as a
 593 # sidebar mimicking a TOC frame
 594 sub print_lilypond_page_foot($)
 595 {
 596   my $fh = shift;
 597   my $program_string = &$program_string();
 598   print $fh "<p><font size='-1'>$program_string</font><br>$PRE_BODY_CLOSE</p>\n";
 599   print $fh "<!-- FOOTER -->\n\n";
 600   print $fh "<!-- end div#main here -->\n</div>\n\n";
 601
 602   # Print the TOC frame and reset the TOC:
 603   lilypond_print_toc_div ($fh, \@this_page_toc);
 604   @this_page_toc = ();
 605
 606   # Close the page:
 607   print $fh "</body>\n</html>\n";
 608 }
 609
 610
 611
 612
 613
 614 #############################################################################
 615 ###  NICER / MORE FLEXIBLE NAVIGATION PANELS
 616 #############################################################################
 617
 618 sub get_navigation_text
 619 {
 620   my $button = shift;
 621   my $text = $NAVIGATION_TEXT{$button};
 622   if ( ($button eq 'Back') or ($button eq 'FastBack') ) {
 623     $text = $text . $Texi2HTML::NODE{$button} . "&nbsp;";
 624   } elsif ( ($button eq 'Forward') or ($button eq 'FastForward') ) {
 625     $text = "&nbsp;" . $Texi2HTML::NODE{$button} . $text;
 626   } elsif ( $button eq 'Up' ) {
 627     $text = "&nbsp;".$text.":&nbsp;" . $Texi2HTML::NODE{$button} . "&nbsp;";
 628   }
 629   return $text;
 630 }
 631
 632
 633 # Don't automatically create left-aligned table cells for every link, but
 634 # instead create a <td> only on an appropriate '(left|right|center)-aligned-cell-n'
 635 # button text. It's alignment as well as the colspan will be taken from the
 636 # name of the button. Also, add 'newline' button text to create a new table
 637 # row. The texts of the buttons are generated by get_navigation_text and
 638 # will contain the name of the next/previous section/chapter.
 639 sub lilypond_print_navigation
 640 {
 641     my $fh = shift;
 642     my $buttons = shift;
 643     my $vertical = shift;
 644     my $spacing = 1;
 645 #     print $fh '<table cellpadding="', $spacing, '" cellspacing="', $spacing,
 646 #       "\" border=\"0\" class=\"nav_table\">\n";
 647     print $fh "<table class=\"nav_table\">\n";
 648
 649     print $fh "<tr>" unless $vertical;
 650     my $beginofline = 1;
 651     foreach my $button (@$buttons)
 652     {
 653         print $fh qq{<tr valign="top" align="left">\n} if $vertical;
 654         # Allow (left|right|center)-aligned-cell and newline as buttons!
 655         if ( $button =~ /^(.*)-aligned-cell-(.*)$/ )
 656         {
 657           print $fh qq{</td>} unless $beginofline;
 658           print $fh qq{<td valign="middle" align="$1" colspan="$2">};
 659           $beginofline = 0;
 660         }
 661         elsif ( $button eq 'newline' )
 662         {
 663           print $fh qq{</td>} unless $beginofline;
 664           print $fh qq{</tr>};
 665           print $fh qq{<tr>};
 666           $beginofline = 1;
 667
 668         }
 669         elsif (ref($button) eq 'CODE')
 670         {
 671             &$button($fh, $vertical);
 672         }
 673         elsif (ref($button) eq 'SCALAR')
 674         {
 675             print $fh "$$button" if defined($$button);
 676         }
 677         elsif (ref($button) eq 'ARRAY')
 678         {
 679             my $text = $button->[1];
 680             my $button_href = $button->[0];
 681             # verify that $button_href is simple text and text is a reference
 682             if (defined($button_href) and !ref($button_href)
 683                and defined($text) and (ref($text) eq 'SCALAR') and defined($$text))
 684             {             # use given text
 685                 if ($Texi2HTML::HREF{$button_href})
 686                 {
 687                   my $anchor_attributes = '';
 688                   if ($USE_ACCESSKEY and (defined($BUTTONS_ACCESSKEY{$button_href})) and ($BUTTONS_ACCESSKEY{$button_href} ne ''))
 689                   {
 690                       $anchor_attributes = "accesskey=\"$BUTTONS_ACCESSKEY{$button_href}\"";
 691                   }
 692                   if ($USE_REL_REV and (defined($BUTTONS_REL{$button_href})) and ($BUTTONS_REL{$button_href} ne ''))
 693                   {
 694                       $anchor_attributes .= " rel=\"$BUTTONS_REL{$button_href}\"";
 695                   }
 696                   print $fh "" .
 697                         &$anchor('',
 698                                     $Texi2HTML::HREF{$button_href},
 699                                     get_navigation_text($$text),
 700                                     $anchor_attributes
 701                                    );
 702                 }
 703                 else
 704                 {
 705                   print $fh get_navigation_text($$text);
 706                 }
 707             }
 708         }
 709         elsif ($button eq ' ')
 710         {                       # handle space button
 711             print $fh
 712                 ($ICONS && $ACTIVE_ICONS{' '}) ?
 713                     &$button_icon_img($BUTTONS_NAME{$button}, $ACTIVE_ICONS{' '}) :
 714                         $NAVIGATION_TEXT{' '};
 715             #next;
 716         }
 717         elsif ($Texi2HTML::HREF{$button})
 718         {                       # button is active
 719             my $btitle = $BUTTONS_GOTO{$button} ?
 720                 'title="' . $BUTTONS_GOTO{$button} . '"' : '';
 721             if ($USE_ACCESSKEY and (defined($BUTTONS_ACCESSKEY{$button})) and ($BUTTONS_ACCESSKEY{$button} ne ''))
 722             {
 723                 $btitle .= " accesskey=\"$BUTTONS_ACCESSKEY{$button}\"";
 724             }
 725             if ($USE_REL_REV and (defined($BUTTONS_REL{$button})) and ($BUTTONS_REL{$button} ne ''))
 726             {
 727                 $btitle .= " rel=\"$BUTTONS_REL{$button}\"";
 728             }
 729             if ($ICONS && $ACTIVE_ICONS{$button})
 730             {                   # use icon
 731                 print $fh '' .
 732                     &$anchor('',
 733                         $Texi2HTML::HREF{$button},
 734                         &$button_icon_img($BUTTONS_NAME{$button},
 735                                    $ACTIVE_ICONS{$button},
 736                                    $Texi2HTML::SIMPLE_TEXT{$button}),
 737                         $btitle
 738                       );
 739             }
 740             else
 741             {                   # use text
 742                 print $fh
 743                     '[' .
 744                         &$anchor('',
 745                                     $Texi2HTML::HREF{$button},
 746                                     get_navigation_text ($button),
 747                                     $btitle
 748                                    ) .
 749                                        ']';
 750             }
 751         }
 752         else
 753         {                       # button is passive
 754             print $fh
 755                 $ICONS && $PASSIVE_ICONS{$button} ?
 756                     &$button_icon_img($BUTTONS_NAME{$button},
 757                                           $PASSIVE_ICONS{$button},
 758                                           $Texi2HTML::SIMPLE_TEXT{$button}) :
 759
 760                                               "[" . get_navigation_text($button) . "]";
 761         }
 762         print $fh "</td>\n" if $vertical;
 763         print $fh "</tr>\n" if $vertical;
 764     }
 765     print $fh "</td>" unless $beginofline;
 766     print $fh "</tr>" unless $vertical;
 767     print $fh "</table>\n";
 768 }
 769
 770
 771 @Texi2HTML::Config::SECTION_BUTTONS =
 772     ('left-aligned-cell-1', 'FastBack',
 773      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 774      'right-aligned-cell-1', 'FastForward',
 775      'newline',
 776      'left-aligned-cell-2', 'Back',
 777      'center-aligned-cell-1', 'Up',
 778      'right-aligned-cell-2', 'Forward'
 779     );
 780
 781 # buttons for misc stuff
 782 @Texi2HTML::Config::MISC_BUTTONS = ('center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About');
 783
 784 # buttons for chapter file footers
 785 # (and headers but only if SECTION_NAVIGATION is false)
 786 @Texi2HTML::Config::CHAPTER_BUTTONS =
 787     ('left-aligned-cell-1', 'FastBack',
 788      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 789      'right-aligned-cell-1', 'FastForward',
 790     );
 791
 792 # buttons for section file footers
 793 @Texi2HTML::Config::SECTION_FOOTER_BUTTONS =
 794     ('left-aligned-cell-1', 'FastBack',
 795      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 796      'right-aligned-cell-1', 'FastForward',
 797      'newline',
 798      'left-aligned-cell-2', 'Back',
 799      'center-aligned-cell-1', 'Up',
 800      'right-aligned-cell-2', 'Forward'
 801     );
 802
 803 @Texi2HTML::Config::NODE_FOOTER_BUTTONS =
 804     ('left-aligned-cell-1', 'FastBack',
 805      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 806      'right-aligned-cell-1', 'FastForward',
 807      'newline',
 808      'left-aligned-cell-2', 'Back',
 809      'center-aligned-cell-1', 'Up',
 810      'right-aligned-cell-2', 'Forward'
 811     );
 812
 813
 814
 815
 816
 817 #############################################################################
 818 ###  OTHER SETTINGS
 819 #############################################################################
 820
 821 # For split pages, use index.html as start page!
 822 if ($Texi2HTML::Config::SPLIT eq 'section') {
 823   $Texi2HTML::Config::TOP_FILE = 'index.html';
 824 }
 825
 826
 827 return 1;