lily/parser.yy

   1 /* -*- mode: c++; c-file-style: "linux"; indent-tabs-mode: t -*- */
   2 /*
   3   This file is part of LilyPond, the GNU music typesetter.
   4
   5   Copyright (C) 1997--2015 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6                  Jan Nieuwenhuizen <janneke@gnu.org>
   7
   8   LilyPond is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   LilyPond is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  20 */
  21
  22 /* Mode and indentation are at best a rough approximation based on TAB
  23  * formatting (reasonable for compatibility with unspecific editor
  24  * modes as Bison modes are hard to find) and need manual correction
  25  * frequently.  Without a reasonably dependable way of formatting a
  26  * Bison file sensibly, there is little point in trying to fix the
  27  * inconsistent state of indentation.
  28  */
  29
  30 %{
  31
  32 #define yyerror Lily_parser::parser_error
  33
  34 /* We use custom location type: Input objects */
  35 #define YYLTYPE Input
  36 #define YYSTYPE SCM
  37 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  38         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  39
  40 #define YYPRINT(file, type, value)                                      \
  41         do {                                                            \
  42                 if (scm_is_eq (value, SCM_UNSPECIFIED))                 \
  43                         break;                                          \
  44                 SCM s = Display::value_to_lily_string (value);          \
  45                 char *p = scm_to_locale_string (s);                     \
  46                 fputs (p, file);                                        \
  47                 free (p);                                               \
  48         } while (0)
  49
  50 %}
  51
  52 %parse-param {Lily_parser *parser}
  53 %parse-param {SCM *retval}
  54 %lex-param {Lily_parser *parser}
  55 %error-verbose
  56 %debug
  57
  58 /* We use SCMs to do strings, because it saves us the trouble of
  59 deleting them.  Let's hope that a stack overflow doesn't trigger a move
  60 of the parse stack onto the heap. */
  61
  62 %left PREC_BOT
  63 %nonassoc REPEAT
  64 %nonassoc ALTERNATIVE
  65
  66 /* The above precedences tackle the shift/reduce problem
  67
  68 1.  \repeat
  69         \repeat .. \alternative
  70
  71     \repeat { \repeat .. \alternative }
  72
  73 or
  74
  75     \repeat { \repeat } \alternative
  76 */
  77
  78 %nonassoc COMPOSITE
  79 %left ADDLYRICS
  80
  81 %right ':' UNSIGNED REAL E_UNSIGNED EVENT_IDENTIFIER EVENT_FUNCTION '^' '_'
  82        HYPHEN EXTENDER DURATION_IDENTIFIER '!'
  83
  84  /* The above are needed for collecting tremoli and other items (that
  85     could otherwise be interpreted as belonging to the next function
  86     argument) greedily, and together with the next rule will serve to
  87     join numbers and units greedily instead of allowing them into
  88     separate function arguments
  89  */
  90
  91 %nonassoc NUMBER_IDENTIFIER
  92
  93 %left PREC_TOP
  94
  95
  96
  97
  98 %pure-parser
  99 %locations
 100
 101
 102
 103 %{ // -*-Fundamental-*-
 104
 105 /*
 106 FIXME:
 107
 108    * The rules for who is protecting what are very shady.  Uniformise
 109      this.
 110
 111    * There are too many lexical modes?
 112 */
 113
 114 #include "config.hh"
 115
 116 #include <cctype>
 117 #include <cstdlib>
 118 #include <cstdio>
 119 using namespace std;
 120
 121 #include "book.hh"
 122 #include "context.hh"
 123 #include "context-def.hh"
 124 #include "context-mod.hh"
 125 #include "dimensions.hh"
 126 #include "file-path.hh"
 127 #include "input.hh"
 128 #include "international.hh"
 129 #include "lily-guile.hh"
 130 #include "lily-lexer.hh"
 131 #include "lily-parser.hh"
 132 #include "ly-module.hh"
 133 #include "main.hh"
 134 #include "misc.hh"
 135 #include "music.hh"
 136 #include "output-def.hh"
 137 #include "paper-book.hh"
 138 #include "scm-hash.hh"
 139 #include "score.hh"
 140 #include "text-interface.hh"
 141 #include "warn.hh"
 142 #include "lily-imports.hh"
 143
 144 void
 145 Lily_parser::parser_error (Input const *i, Lily_parser *parser, SCM *, const string &s)
 146 {
 147         parser->parser_error (*i, s);
 148 }
 149
 150 // The following are somewhat precarious constructs as they may change
 151 // the value of the lookahead token.  That implies that the lookahead
 152 // token must not yet have made an impact on the state stack other
 153 // than causing the reduction of the current rule, or switching the
 154 // lookahead token while Bison is mulling it over will cause trouble.
 155
 156 #define MYBACKUP(Token, Value, Location)                                \
 157         do {                                                            \
 158                 if (yychar != YYEMPTY)                                  \
 159                         parser->lexer_->push_extra_token                \
 160                                 (yylloc, yychar, yylval);               \
 161                 if (Token)                                              \
 162                         parser->lexer_->push_extra_token                \
 163                                 (Location, Token, Value);               \
 164                 parser->lexer_->push_extra_token (Location, BACKUP);    \
 165                 yychar = YYEMPTY;                                       \
 166         } while (0)
 167
 168
 169 #define MYREPARSE(Location, Pred, Token, Value)                         \
 170         do {                                                            \
 171                 if (yychar != YYEMPTY)                                  \
 172                         parser->lexer_->push_extra_token                \
 173                                 (yylloc, yychar, yylval);               \
 174                 parser->lexer_->push_extra_token                        \
 175                         (Location, Token, Value);                       \
 176                 parser->lexer_->push_extra_token                        \
 177                         (Location, REPARSE, Pred);                      \
 178                 yychar = YYEMPTY;                                       \
 179         } while (0)
 180
 181 %}
 182
 183
 184 %{
 185
 186 #define MY_MAKE_MUSIC(x, spot) \
 187         make_music_with_input (ly_symbol2scm (x), \
 188                                parser->lexer_->override_input (spot))
 189
 190 /* ES TODO:
 191 - delay application of the function
 192 */
 193
 194 #define LOWLEVEL_MAKE_SYNTAX(location, proc, ...)                       \
 195         with_location                                                   \
 196                 (parser->lexer_->override_input (location).smobbed_copy (), \
 197                  proc,                                                  \
 198                  ##__VA_ARGS__)
 199
 200 /* Syntactic Sugar. */
 201 #define MAKE_SYNTAX(name, location, ...)                                \
 202         LOWLEVEL_MAKE_SYNTAX (location, Syntax::name, ##__VA_ARGS__)
 203
 204 #define START_MAKE_SYNTAX(name, ...)                                    \
 205         scm_list_n (Syntax::name, ##__VA_ARGS__, SCM_UNDEFINED)
 206
 207 #define FINISH_MAKE_SYNTAX(start, location, ...)                        \
 208         LOWLEVEL_MAKE_SYNTAX                                            \
 209                 (location,                                              \
 210                  Guile_user::apply,                                     \
 211                  scm_car (start),                                       \
 212                  scm_append_x                                           \
 213                  (scm_list_2 (scm_cdr (start),                          \
 214                               scm_list_n (__VA_ARGS__, SCM_UNDEFINED))))
 215
 216 SCM get_next_unique_context_id ();
 217 SCM get_next_unique_lyrics_context_id ();
 218
 219 #undef _
 220 #if !HAVE_GETTEXT
 221 #define _(x) x
 222 #else
 223 #include <libintl.h>
 224 #define _(x) gettext (x)
 225 #endif
 226
 227
 228 static Music *make_music_with_input (SCM name, Input where);
 229 SCM check_scheme_arg (Lily_parser *parser, Input loc,
 230                       SCM arg, SCM args, SCM pred, SCM disp = SCM_UNDEFINED);
 231 SCM make_music_from_simple (Lily_parser *parser, Input loc, SCM pitch);
 232 SCM loc_on_music (Lily_parser *parser, Input loc, SCM arg);
 233 SCM make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list);
 234 SCM make_chord_step (SCM step, Rational alter);
 235 SCM make_simple_markup (SCM a);
 236 SCM make_duration (SCM t, int dots = 0, SCM factor = SCM_UNDEFINED);
 237 bool is_regular_identifier (SCM id, bool multiple=false);
 238 SCM try_string_variants (SCM pred, SCM str);
 239 int yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser);
 240
 241 %}
 242
 243 /* The third option is an alias that will be used to display the
 244    syntax error.  Bison CVS now correctly handles backslash escapes.
 245
 246    FIXME: Bison needs to translate some of these, eg, STRING.
 247
 248 */
 249
 250 /* Keyword tokens with plain escaped name.  */
 251 %token END_OF_FILE 0 "end of input"
 252 %token ACCEPTS "\\accepts"
 253 %token ADDLYRICS "\\addlyrics"
 254 %token ALIAS "\\alias"
 255 %token ALTERNATIVE "\\alternative"
 256 %token BOOK "\\book"
 257 %token BOOKPART "\\bookpart"
 258 %token CHANGE "\\change"
 259 %token CHORDMODE "\\chordmode"
 260 %token CHORDS "\\chords"
 261 %token CONSISTS "\\consists"
 262 %token CONTEXT "\\context"
 263 %token DEFAULT "\\default"
 264 %token DEFAULTCHILD "\\defaultchild"
 265 %token DENIES "\\denies"
 266 %token DESCRIPTION "\\description"
 267 %token DRUMMODE "\\drummode"
 268 %token DRUMS "\\drums"
 269 %token ETC "\\etc"
 270 %token FIGUREMODE "\\figuremode"
 271 %token FIGURES "\\figures"
 272 %token HEADER "\\header"
 273 %token INVALID "\\version-error"
 274 %token LAYOUT "\\layout"
 275 %token LYRICMODE "\\lyricmode"
 276 %token LYRICS "\\lyrics"
 277 %token LYRICSTO "\\lyricsto"
 278 %token MARKUP "\\markup"
 279 %token MARKUPLIST "\\markuplist"
 280 %token MIDI "\\midi"
 281 %token NAME "\\name"
 282 %token NOTEMODE "\\notemode"
 283 %token OVERRIDE "\\override"
 284 %token PAPER "\\paper"
 285 %token REMOVE "\\remove"
 286 %token REPEAT "\\repeat"
 287 %token REST "\\rest"
 288 %token REVERT "\\revert"
 289 %token SCORE "\\score"
 290 %token SCORELINES "\\score-lines"
 291 %token SEQUENTIAL "\\sequential"
 292 %token SET "\\set"
 293 %token SIMULTANEOUS "\\simultaneous"
 294 %token TEMPO "\\tempo"
 295 %token TYPE "\\type"
 296 %token UNSET "\\unset"
 297 %token WITH "\\with"
 298
 299 /* Keyword token exceptions.  */
 300 %token NEWCONTEXT "\\new"
 301
 302
 303 /* Other string tokens.  */
 304
 305 %token CHORD_BASS "/+"
 306 %token CHORD_CARET "^"
 307 %token CHORD_COLON ":"
 308 %token CHORD_MINUS "-"
 309 %token CHORD_SLASH "/"
 310 %token ANGLE_OPEN "<"
 311 %token ANGLE_CLOSE ">"
 312 %token DOUBLE_ANGLE_OPEN "<<"
 313 %token DOUBLE_ANGLE_CLOSE ">>"
 314 %token E_BACKSLASH "\\"
 315 %token E_EXCLAMATION "\\!"
 316 %token E_PLUS "\\+"
 317 %token EXTENDER "__"
 318
 319 /*
 320 If we give names, Bison complains.
 321 */
 322 %token FIGURE_CLOSE /* "\\>" */
 323 %token FIGURE_OPEN /* "\\<" */
 324 %token FIGURE_SPACE "_"
 325 %token HYPHEN "--"
 326
 327 %token MULTI_MEASURE_REST
 328
 329
 330 %token E_UNSIGNED
 331 %token UNSIGNED
 332
 333 /* Artificial tokens, for more generic function syntax */
 334 %token EXPECT_MARKUP "markup?"
 335 %token EXPECT_SCM "scheme?"
 336 %token BACKUP "(backed-up?)"
 337 %token REPARSE "(reparsed?)"
 338 %token EXPECT_MARKUP_LIST "markup-list?"
 339 %token EXPECT_OPTIONAL "optional?"
 340 /* After the last argument. */
 341 %token EXPECT_NO_MORE_ARGS;
 342
 343 /* An artificial token for parsing embedded Lilypond */
 344 %token EMBEDDED_LILY "#{"
 345
 346 %token BOOK_IDENTIFIER
 347 %token CHORD_MODIFIER
 348 %token CHORD_REPETITION
 349 %token CONTEXT_MOD_IDENTIFIER
 350 %token DRUM_PITCH
 351  /* Artificial token for durations in argument lists */
 352 %token DURATION_ARG
 353 %token DURATION_IDENTIFIER
 354 %token EVENT_IDENTIFIER
 355 %token EVENT_FUNCTION
 356 %token FRACTION
 357 %token LOOKUP_IDENTIFIER
 358 %token LYRIC_ELEMENT
 359 %token MARKUP_FUNCTION
 360 %token MARKUP_LIST_FUNCTION
 361 %token MARKUP_IDENTIFIER
 362 %token MARKUPLIST_IDENTIFIER
 363 %token MUSIC_FUNCTION
 364 %token MUSIC_IDENTIFIER
 365 %token NOTENAME_PITCH
 366 %token NUMBER_IDENTIFIER
 367 %token PITCH_IDENTIFIER
 368 %token REAL
 369 %token RESTNAME
 370 %token SCM_ARG
 371 %token SCM_FUNCTION
 372 %token SCM_IDENTIFIER
 373 %token SCM_TOKEN
 374 %token STRING
 375 %token SYMBOL_LIST
 376 %token TONICNAME_PITCH
 377
 378 %left '-' '+'
 379
 380 /* We don't assign precedence to / and *, because we might need varied
 381 prec levels in different prods */
 382
 383 %left UNARY_MINUS
 384
 385 %%
 386
 387 start_symbol:
 388         lilypond
 389         | EMBEDDED_LILY {
 390                 parser->lexer_->push_note_state (Lily::pitchnames);
 391         } embedded_lilypond {
 392                 parser->lexer_->pop_state ();
 393                 *retval = $3;
 394         }
 395         ;
 396
 397 lilypond:       /* empty */ { $$ = SCM_UNSPECIFIED; }
 398         | lilypond toplevel_expression {
 399         }
 400         | lilypond assignment {
 401         }
 402         | lilypond error {
 403                 parser->error_level_ = 1;
 404         }
 405         | lilypond INVALID      {
 406                 parser->error_level_ = 1;
 407         }
 408         ;
 409
 410
 411 toplevel_expression:
 412         {
 413                 parser->lexer_->add_scope (get_header (parser));
 414         } lilypond_header {
 415                 parser->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $2);
 416         }
 417         | book_block {
 418                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-book-handler");
 419                 scm_call_1 (proc, $1);
 420         }
 421         | bookpart_block {
 422                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 423                 scm_call_1 (proc, $1);
 424         }
 425         | BOOK_IDENTIFIER {
 426                 SCM proc = parser->lexer_->lookup_identifier
 427                         (unsmob<Book>($1)->paper_
 428                          ? "toplevel-book-handler"
 429                          : "toplevel-bookpart-handler");
 430                 scm_call_1 (proc, $1);
 431         }
 432         | score_block {
 433                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-score-handler");
 434                 scm_call_1 (proc, $1);
 435         }
 436         | composite_music {
 437                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-music-handler");
 438                 scm_call_1 (proc, $1);
 439         }
 440         | full_markup {
 441                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 442                 scm_call_1 (proc, scm_list_1 ($1));
 443         }
 444         | full_markup_list {
 445                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 446                 scm_call_1 (proc, $1);
 447         }
 448         | SCM_TOKEN {
 449                 // Evaluate and ignore #xxx, as opposed to \xxx
 450                 parser->lexer_->eval_scm_token ($1, @1);
 451         }
 452         | embedded_scm_active
 453         {
 454                 SCM out = SCM_UNDEFINED;
 455                 if (Text_interface::is_markup ($1))
 456                         out = scm_list_1 ($1);
 457                 else if (Text_interface::is_markup_list ($1))
 458                         out = $1;
 459                 if (scm_is_pair (out))
 460                 {
 461                         SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 462                         scm_call_1 (proc, out);
 463                 } else if (unsmob<Score> ($1))
 464                 {
 465                         SCM proc = parser->lexer_->lookup_identifier ("toplevel-score-handler");
 466                         scm_call_1 (proc, $1);
 467                 } else if (Output_def * od = unsmob<Output_def> ($1)) {
 468                         SCM id = SCM_EOL;
 469
 470                         if (to_boolean (od->c_variable ("is-paper")))
 471                                 id = ly_symbol2scm ("$defaultpaper");
 472                         else if (to_boolean (od->c_variable ("is-midi")))
 473                                 id = ly_symbol2scm ("$defaultmidi");
 474                         else if (to_boolean (od->c_variable ("is-layout")))
 475                                 id = ly_symbol2scm ("$defaultlayout");
 476
 477                         parser->lexer_->set_identifier (id, $1);
 478                 } else if (!scm_is_eq ($1, SCM_UNSPECIFIED))
 479                         parser->parser_error (@1, _("bad expression type"));
 480         }
 481         | output_def {
 482                 SCM id = SCM_EOL;
 483                 Output_def * od = unsmob<Output_def> ($1);
 484
 485                 if (to_boolean (od->c_variable ("is-paper")))
 486                         id = ly_symbol2scm ("$defaultpaper");
 487                 else if (to_boolean (od->c_variable ("is-midi")))
 488                         id = ly_symbol2scm ("$defaultmidi");
 489                 else if (to_boolean (od->c_variable ("is-layout")))
 490                         id = ly_symbol2scm ("$defaultlayout");
 491
 492                 parser->lexer_->set_identifier (id, $1);
 493         }
 494         ;
 495
 496 lookup:
 497         LOOKUP_IDENTIFIER
 498         | LOOKUP_IDENTIFIER '.' symbol_list_rev
 499         {
 500                 $$ = loc_on_music (parser, @$,
 501                                    nested_property ($1, scm_reverse_x ($3, SCM_EOL)));
 502         }
 503         ;
 504
 505 embedded_scm_bare:
 506         SCM_TOKEN
 507         {
 508                 $$ = parser->lexer_->eval_scm_token ($1, @1);
 509         }
 510         | SCM_IDENTIFIER
 511         ;
 512
 513 embedded_scm_active:
 514         SCM_IDENTIFIER
 515         | scm_function_call
 516         | lookup
 517         ;
 518
 519 embedded_scm_bare_arg:
 520         SCM_ARG
 521         | SCM_TOKEN
 522         {
 523                 $$ = parser->lexer_->eval_scm_token ($1, @1);
 524         }
 525         | FRACTION
 526         | partial_markup
 527         | full_markup_list
 528         | context_modification
 529         | score_block
 530         | context_def_spec_block
 531         | book_block
 532         | bookpart_block
 533         | output_def
 534         | lookup
 535         ;
 536
 537 /* The generic version may end in music, or not */
 538
 539 embedded_scm:
 540         embedded_scm_bare
 541         | scm_function_call
 542         | lookup
 543         ;
 544
 545 /* embedded_scm_arg is _not_ casting pitches to music by default, this
 546  * has to be done by the function itself.  Note that this may cause
 547  * the results of scm_function_call or embedded_scm_bare_arg to be
 548  * turned into music from pitches as well.  Note that this creates a
 549  * distinctly awkward situation for calculated drum pitches.  Those
 550  * are at the current point of time rejected as music constituents as
 551  * they can't be distinguished from "proper" symbols.
 552  */
 553
 554 embedded_scm_arg:
 555         embedded_scm_bare_arg
 556         | scm_function_call
 557         | music_assign
 558         ;
 559
 560 scm_function_call:
 561         SCM_FUNCTION function_arglist {
 562                 $$ = MAKE_SYNTAX (music_function, @$,
 563                                   $1, $2);
 564         }
 565         ;
 566
 567 embedded_lilypond_number:
 568         '-' embedded_lilypond_number
 569         {
 570                 $$ = scm_difference ($2, SCM_UNDEFINED);
 571         }
 572         | bare_number_common
 573         | UNSIGNED NUMBER_IDENTIFIER
 574         {
 575                 $$ = scm_product ($1, $2);
 576         }
 577         ;
 578
 579 embedded_lilypond:
 580         /* empty */
 581         {
 582                 // FIXME: @$ does not contain a useful source location
 583                 // for empty rules, and the only token in the whole
 584                 // production, EMBEDDED_LILY, is synthetic and also
 585                 // contains no source location.
 586                 $$ = MAKE_SYNTAX (void_music, @$);
 587         }
 588         | identifier_init_nonumber
 589         | embedded_lilypond_number
 590         | post_event post_events
 591         {
 592                 $$ = scm_reverse_x ($2, SCM_EOL);
 593                 if (Music *m = unsmob<Music> ($1))
 594                 {
 595                         if (m->is_mus_type ("post-event-wrapper"))
 596                                 $$ = scm_append
 597                                         (scm_list_2 (m->get_property ("elements"),
 598                                                      $$));
 599                         else
 600                                 $$ = scm_cons ($1, $$);
 601                 }
 602                 if (scm_is_pair ($$)
 603                     && scm_is_null (scm_cdr ($$)))
 604                         $$ = scm_car ($$);
 605                 else
 606                 {
 607                         Music * m = MY_MAKE_MUSIC ("PostEvents", @$);
 608                         m->set_property ("elements", $$);
 609                         $$ = m->unprotect ();
 610                 }
 611         }
 612         | multiplied_duration
 613         | music_embedded music_embedded music_list {
 614                 $3 = scm_reverse_x ($3, SCM_EOL);
 615                 if (unsmob<Music> ($2))
 616                         $3 = scm_cons ($2, $3);
 617                 if (unsmob<Music> ($1))
 618                         $3 = scm_cons ($1, $3);
 619                 $$ = MAKE_SYNTAX (sequential_music, @$, $3);
 620         }
 621         | error {
 622                 parser->error_level_ = 1;
 623                 $$ = SCM_UNSPECIFIED;
 624         }
 625         | INVALID embedded_lilypond {
 626                 parser->error_level_ = 1;
 627                 $$ = $2;
 628         }
 629         ;
 630
 631
 632 lilypond_header_body:
 633         /* empty */ { $$ = SCM_UNSPECIFIED; }
 634         | lilypond_header_body assignment  {
 635
 636         }
 637         | lilypond_header_body embedded_scm  {
 638
 639         }
 640         ;
 641
 642 lilypond_header:
 643         HEADER '{' lilypond_header_body '}'     {
 644                 $$ = parser->lexer_->remove_scope ();
 645         }
 646         ;
 647
 648 /*
 649         DECLARATIONS
 650 */
 651 assignment_id:
 652         STRING          { $$ = $1; }
 653         ;
 654
 655 assignment:
 656         assignment_id '=' identifier_init  {
 657                 parser->lexer_->set_identifier ($1, $3);
 658                 $$ = SCM_UNSPECIFIED;
 659         }
 660         | assignment_id '.' property_path '=' identifier_init {
 661                 SCM path = scm_cons (scm_string_to_symbol ($1), $3);
 662                 parser->lexer_->set_identifier (path, $5);
 663                 $$ = SCM_UNSPECIFIED;
 664         }
 665         | assignment_id ',' property_path '=' identifier_init {
 666                 SCM path = scm_cons (scm_string_to_symbol ($1), $3);
 667                 parser->lexer_->set_identifier (path, $5);
 668                 $$ = SCM_UNSPECIFIED;
 669         }
 670         ;
 671
 672
 673 identifier_init:
 674         identifier_init_nonumber
 675         | number_expression
 676         | symbol_list_part_bare '.' property_path
 677         {
 678                 $$ = scm_reverse_x ($1, $3);
 679         }
 680         | symbol_list_part_bare ',' property_path
 681         {
 682                 $$ = scm_reverse_x ($1, $3);
 683         }
 684         | post_event_nofinger post_events
 685         {
 686                 $$ = scm_reverse_x ($2, SCM_EOL);
 687                 if (Music *m = unsmob<Music> ($1))
 688                 {
 689                         if (m->is_mus_type ("post-event-wrapper"))
 690                                 $$ = scm_append
 691                                         (scm_list_2 (m->get_property ("elements"),
 692                                                      $$));
 693                         else
 694                                 $$ = scm_cons ($1, $$);
 695                 }
 696                 if (scm_is_pair ($$)
 697                     && scm_is_null (scm_cdr ($$)))
 698                         $$ = scm_car ($$);
 699                 else
 700                 {
 701                         Music * m = MY_MAKE_MUSIC ("PostEvents", @$);
 702                         m->set_property ("elements", $$);
 703                         $$ = m->unprotect ();
 704                 }
 705         }
 706         ;
 707
 708 identifier_init_nonumber:
 709         score_block
 710         | book_block
 711         | bookpart_block
 712         | output_def
 713         | context_def_spec_block
 714         | music_assign
 715         | pitch_or_music
 716         | FRACTION
 717         | string
 718         | embedded_scm
 719         | partial_markup
 720         | full_markup_list
 721         | context_modification
 722         | partial_function ETC
 723         {
 724                 $$ = MAKE_SYNTAX (partial_music_function, @$,
 725                                   scm_reverse_x ($1, SCM_EOL));
 726         }
 727         ;
 728
 729 // Partial functions
 730 partial_function:
 731         MUSIC_FUNCTION function_arglist_partial
 732         {
 733                 $$ = scm_acons ($1, $2, SCM_EOL);
 734         }
 735         | EVENT_FUNCTION function_arglist_partial
 736         {
 737                 $$ = scm_acons ($1, $2, SCM_EOL);
 738         }
 739         | SCM_FUNCTION function_arglist_partial
 740         {
 741                 $$ = scm_acons ($1, $2, SCM_EOL);
 742         }
 743         | OVERRIDE grob_prop_path '='
 744         {
 745                 if (SCM_UNBNDP ($2))
 746                         $$ = scm_list_1 (SCM_BOOL_F);
 747                 else
 748                         $$ = scm_cons
 749                                 (scm_list_3 (Syntax::property_override_function,
 750                                              scm_cdr ($2), scm_car ($2)),
 751                                  SCM_EOL);
 752         }
 753         | SET context_prop_spec '='
 754         {
 755                 if (SCM_UNBNDP ($2))
 756                         $$ = scm_list_1 (SCM_BOOL_F);
 757                 else
 758                         $$ = scm_cons
 759                                 (scm_list_3 (Syntax::property_set_function,
 760                                              scm_cadr ($2), scm_car ($2)),
 761                                  SCM_EOL);
 762         }
 763         | MUSIC_FUNCTION EXPECT_SCM function_arglist_optional partial_function
 764         {
 765                 $$ = scm_acons ($1, $3, $4);
 766         }
 767         | EVENT_FUNCTION EXPECT_SCM function_arglist_optional partial_function
 768         {
 769                 $$ = scm_acons ($1, $3, $4);
 770         }
 771         | SCM_FUNCTION EXPECT_SCM function_arglist_optional partial_function
 772         {
 773                 $$ = scm_acons ($1, $3, $4);
 774         }
 775         | OVERRIDE grob_prop_path '=' partial_function
 776         {
 777                 if (SCM_UNBNDP ($2))
 778                         $$ = scm_list_1 (SCM_BOOL_F);
 779                 else
 780                         $$ = scm_cons
 781                                 (scm_list_3 (Syntax::property_override_function,
 782                                              scm_cdr ($2), scm_car ($2)),
 783                                  $4);
 784         }
 785         | SET context_prop_spec '=' partial_function
 786         {
 787                 if (SCM_UNBNDP ($2))
 788                         $$ = scm_list_1 (SCM_BOOL_F);
 789                 else
 790                         $$ = scm_cons
 791                                 (scm_list_3 (Syntax::property_set_function,
 792                                              scm_cadr ($2), scm_car ($2)),
 793                                  $4);
 794         }
 795         | MUSIC_FUNCTION EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup partial_function
 796         {
 797                 $$ = scm_acons ($1, $4, $5);
 798         }
 799         | EVENT_FUNCTION EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup partial_function
 800         {
 801                 $$ = scm_acons ($1, $4, $5);
 802         }
 803         | SCM_FUNCTION EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup partial_function
 804         {
 805                 $$ = scm_acons ($1, $4, $5);
 806         }
 807         ;
 808
 809 context_def_spec_block:
 810         CONTEXT '{' context_def_spec_body '}'
 811         {
 812                 $$ = $3;
 813                 Context_def *td = unsmob<Context_def> ($$);
 814                 if (!td) {
 815                         $$ = Context_def::make_scm ();
 816                         td = unsmob<Context_def> ($$);
 817                 }
 818                 td->origin ()->set_spot (@$);
 819         }
 820         ;
 821
 822 context_mod_arg:
 823         embedded_scm
 824         |
 825         {
 826                 parser->lexer_->push_note_state (Lily::pitchnames);
 827         }
 828         composite_music
 829         {
 830                 parser->lexer_->pop_state ();
 831                 $$ = $2;
 832         }
 833         ;
 834
 835
 836 context_def_spec_body:
 837         /**/ {
 838                 $$ = SCM_UNSPECIFIED;
 839         }
 840         | context_def_spec_body context_mod {
 841                 if (!SCM_UNBNDP ($2)) {
 842                         Context_def *td = unsmob<Context_def> ($$);
 843                         if (!td) {
 844                                 $$ = Context_def::make_scm ();
 845                                 td = unsmob<Context_def> ($$);
 846                         }
 847                         unsmob<Context_def> ($$)->add_context_mod ($2);
 848                 }
 849         }
 850         | context_def_spec_body context_modification {
 851                 Context_def *td = unsmob<Context_def> ($$);
 852                 if (!td) {
 853                         $$ = Context_def::make_scm ();
 854                         td = unsmob<Context_def> ($$);
 855                 }
 856                 SCM new_mods = unsmob<Context_mod> ($2)->get_mods ();
 857                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 858                     td->add_context_mod (scm_car (m));
 859                 }
 860         }
 861         | context_def_spec_body context_mod_arg {
 862                 Context_def *td = unsmob<Context_def> ($1);
 863                 if (scm_is_eq ($2, SCM_UNSPECIFIED))
 864                         ;
 865                 else if (!td && unsmob<Context_def> ($2))
 866                         $$ = $2;
 867                 else {
 868                         if (!td) {
 869                                 $$ = Context_def::make_scm ();
 870                                 td = unsmob<Context_def> ($$);
 871                         }
 872                         if (unsmob<Music> ($2)) {
 873                                 SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
 874                                 $2 = scm_call_1 (proc, $2);
 875                         }
 876                         if (Context_mod *cm = unsmob<Context_mod> ($2)) {
 877                                 for (SCM m = cm->get_mods (); scm_is_pair (m); m = scm_cdr (m)) {
 878                                         td->add_context_mod (scm_car (m));
 879                                 }
 880                         } else
 881                                 parser->parser_error (@2, _ ("not a context mod"));
 882                 }
 883         }
 884         ;
 885
 886
 887
 888 book_block:
 889         BOOK '{' book_body '}'  {
 890                 $$ = $3;
 891                 unsmob<Book> ($$)->origin ()->set_spot (@$);
 892                 pop_paper (parser);
 893                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 894         }
 895         ;
 896
 897 /* FIXME:
 898    * Use 'handlers' like for toplevel-* stuff?
 899    * grok \layout and \midi?  */
 900 book_body:
 901         {
 902                 Book *book = new Book;
 903                 init_papers (parser);
 904                 book->paper_ = dynamic_cast<Output_def*> (unsmob<Output_def> (parser->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 905                 book->paper_->unprotect ();
 906                 push_paper (parser, book->paper_);
 907                 book->header_ = get_header (parser);
 908                 $$ = book->unprotect ();
 909                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$);
 910         }
 911         | BOOK_IDENTIFIER {
 912                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 913         }
 914         | book_body paper_block {
 915                 unsmob<Book> ($1)->paper_ = unsmob<Output_def> ($2);
 916                 set_paper (parser, unsmob<Output_def> ($2));
 917         }
 918         | book_body bookpart_block {
 919                 SCM proc = parser->lexer_->lookup_identifier ("book-bookpart-handler");
 920                 scm_call_2 (proc, $1, $2);
 921         }
 922         | book_body score_block {
 923                 SCM proc = parser->lexer_->lookup_identifier ("book-score-handler");
 924                 scm_call_2 (proc, $1, $2);
 925         }
 926         | book_body composite_music {
 927                 SCM proc = parser->lexer_->lookup_identifier ("book-music-handler");
 928                 scm_call_2 (proc, $1, $2);
 929         }
 930         | book_body full_markup {
 931                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 932                 scm_call_2 (proc, $1, scm_list_1 ($2));
 933         }
 934         | book_body full_markup_list {
 935                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 936                 scm_call_2 (proc, $1, $2);
 937         }
 938         | book_body SCM_TOKEN {
 939                 // Evaluate and ignore #xxx, as opposed to \xxx
 940                 parser->lexer_->eval_scm_token ($2, @2);
 941         }
 942         | book_body embedded_scm_active
 943         {
 944                 SCM out = SCM_UNDEFINED;
 945                 if (Text_interface::is_markup ($2))
 946                         out = scm_list_1 ($2);
 947                 else if (Text_interface::is_markup_list ($2))
 948                         out = $2;
 949                 if (scm_is_pair (out))
 950                 {
 951                         SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 952                         scm_call_2 (proc, $1, out);
 953                 } else if (unsmob<Score> ($2))
 954                 {
 955                         SCM proc = parser->lexer_->lookup_identifier ("book-score-handler");
 956                         scm_call_2 (proc, $1, $2);
 957                 } else if (Output_def *od = unsmob<Output_def> ($2)) {
 958                         SCM id = SCM_EOL;
 959
 960                         if (to_boolean (od->c_variable ("is-paper")))
 961                                 id = ly_symbol2scm ("$defaultpaper");
 962                         else if (to_boolean (od->c_variable ("is-midi")))
 963                                 id = ly_symbol2scm ("$defaultmidi");
 964                         else if (to_boolean (od->c_variable ("is-layout")))
 965                                 id = ly_symbol2scm ("$defaultlayout");
 966
 967                         parser->lexer_->set_identifier (id, $2);
 968                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
 969                         parser->parser_error (@2, _("bad expression type"));
 970         }
 971         | book_body
 972         {
 973                 parser->lexer_->add_scope (unsmob<Book> ($1)->header_);
 974         } lilypond_header
 975         | book_body error {
 976                 Book *book = unsmob<Book> ($1);
 977                 book->paper_ = 0;
 978                 book->scores_ = SCM_EOL;
 979                 book->bookparts_ = SCM_EOL;
 980         }
 981         ;
 982
 983 bookpart_block:
 984         BOOKPART '{' bookpart_body '}' {
 985                 $$ = $3;
 986                 unsmob<Book> ($$)->origin ()->set_spot (@$);
 987                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 988         }
 989         ;
 990
 991 bookpart_body:
 992         {
 993                 Book *book = new Book;
 994                 $$ = book->unprotect ();
 995                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$);
 996         }
 997         | BOOK_IDENTIFIER {
 998                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 999         }
1000         | bookpart_body paper_block {
1001                 unsmob<Book> ($$)->paper_ = unsmob<Output_def> ($2);
1002         }
1003         | bookpart_body score_block {
1004                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-score-handler");
1005                 scm_call_2 (proc, $1, $2);
1006         }
1007         | bookpart_body composite_music {
1008                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-music-handler");
1009                 scm_call_2 (proc, $1, $2);
1010         }
1011         | bookpart_body full_markup {
1012                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
1013                 scm_call_2 (proc, $1, scm_list_1 ($2));
1014         }
1015         | bookpart_body full_markup_list {
1016                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
1017                 scm_call_2 (proc, $1, $2);
1018         }
1019         | bookpart_body SCM_TOKEN {
1020                 // Evaluate and ignore #xxx, as opposed to \xxx
1021                 parser->lexer_->eval_scm_token ($2, @2);
1022         }
1023         | bookpart_body embedded_scm_active
1024         {
1025                 SCM out = SCM_UNDEFINED;
1026                 if (Text_interface::is_markup ($2))
1027                         out = scm_list_1 ($2);
1028                 else if (Text_interface::is_markup_list ($2))
1029                         out = $2;
1030                 if (scm_is_pair (out))
1031                 {
1032                         SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
1033                         scm_call_2 (proc, $1, out);
1034                 } else if (unsmob<Score> ($2))
1035                 {
1036                         SCM proc = parser->lexer_->lookup_identifier ("bookpart-score-handler");
1037                         scm_call_2 (proc, $1, $2);
1038                 } else if (Output_def *od = unsmob<Output_def> ($2)) {
1039                         SCM id = SCM_EOL;
1040
1041                         if (to_boolean (od->c_variable ("is-paper")))
1042                                 id = ly_symbol2scm ("$defaultpaper");
1043                         else if (to_boolean (od->c_variable ("is-midi")))
1044                                 id = ly_symbol2scm ("$defaultmidi");
1045                         else if (to_boolean (od->c_variable ("is-layout")))
1046                                 id = ly_symbol2scm ("$defaultlayout");
1047
1048                         parser->lexer_->set_identifier (id, $2);
1049                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
1050                         parser->parser_error (@2, _("bad expression type"));
1051         }
1052         | bookpart_body
1053         {
1054                 Book *book = unsmob<Book> ($1);
1055                 if (!ly_is_module (book->header_))
1056                         book->header_ = ly_make_module (false);
1057                 parser->lexer_->add_scope (book->header_);
1058         } lilypond_header
1059         | bookpart_body error {
1060                 Book *book = unsmob<Book> ($1);
1061                 book->paper_ = 0;
1062                 book->scores_ = SCM_EOL;
1063         }
1064         ;
1065
1066 score_block:
1067         SCORE '{' score_body '}'        {
1068                 unsmob<Score> ($3)->origin ()->set_spot (@$);
1069                 $$ = $3;
1070         }
1071         ;
1072
1073 score_body:
1074         score_items {
1075                 if (!unsmob<Score> ($1)) {
1076                         parser->parser_error (@1, _("Missing music in \\score"));
1077                         $$ = (new Score)->unprotect ();
1078                         if (scm_is_pair ($1) && ly_is_module (scm_car ($1)))
1079                         {
1080                                 unsmob<Score> ($$)->set_header (scm_car ($1));
1081                                 $1 = scm_cdr ($1);
1082                         }
1083                         for (SCM p = scm_reverse_x ($1, SCM_EOL);
1084                              scm_is_pair (p); p = scm_cdr (p))
1085                         {
1086                                 unsmob<Score> ($$)->
1087                                         add_output_def (unsmob<Output_def> (scm_car (p)));
1088                         }
1089                 }
1090         }
1091         | score_body error {
1092                 unsmob<Score> ($$)->error_found_ = true;
1093         }
1094         ;
1095
1096 score_item:
1097         embedded_scm
1098         | music
1099         | output_def
1100         ;
1101
1102 score_items:
1103         /* empty */
1104         {
1105                 $$ = SCM_EOL;
1106         }
1107         | score_items score_item
1108         {
1109                 Output_def *od = unsmob<Output_def> ($2);
1110                 if (od) {
1111                         if (to_boolean (od->lookup_variable (ly_symbol2scm ("is-paper"))))
1112                         {
1113                                 parser->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
1114                                 od = 0;
1115                                 $2 = SCM_UNSPECIFIED;
1116                         }
1117                 } else if (!unsmob<Score> ($$)) {
1118                         if (unsmob<Music> ($2)) {
1119                                 $2 = Lily::scorify_music ($2);
1120                         }
1121                         if (unsmob<Score> ($2))
1122                         {
1123                                 $$ = $2;
1124                                 $2 = SCM_UNSPECIFIED;
1125                         }
1126                 }
1127                 Score *score = unsmob<Score> ($$);
1128                 if (score && scm_is_pair ($1)) {
1129                         if (ly_is_module (scm_car ($1)))
1130                         {
1131                                 score->set_header (scm_car ($1));
1132                                 $1 = scm_cdr ($1);
1133                         }
1134                         for (SCM p = scm_reverse_x ($1, SCM_EOL);
1135                              scm_is_pair (p); p = scm_cdr (p))
1136                         {
1137                                 score->add_output_def (unsmob<Output_def> (scm_car (p)));
1138                         }
1139                 }
1140                 if (od) {
1141                         if (score)
1142                                 score->add_output_def (od);
1143                         else if (scm_is_pair ($$) && ly_is_module (scm_car ($$)))
1144                                 scm_set_cdr_x ($$, scm_cons ($2, scm_cdr ($$)));
1145                         else
1146                                 $$ = scm_cons ($2, $$);
1147                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
1148                         parser->parser_error (@2, _("Spurious expression in \\score"));
1149         }
1150         | score_items
1151         {
1152                 if (Score *score = unsmob<Score> ($1)) {
1153                         if (!ly_is_module (score->get_header ()))
1154                                 score->set_header (ly_make_module (false));
1155                         parser->lexer_->add_scope (score->get_header ());
1156                 } else {
1157                         if (!scm_is_pair ($1) || !ly_is_module (scm_car ($1)))
1158                                 $1 = scm_cons (ly_make_module (false), $1);
1159                         parser->lexer_->add_scope (scm_car ($1));
1160                 }
1161         } lilypond_header
1162         {
1163                 $$ = $1;
1164         }
1165         ;
1166
1167
1168 /*
1169         OUTPUT DEF
1170 */
1171
1172 paper_block:
1173         output_def {
1174                 Output_def *od = unsmob<Output_def> ($1);
1175
1176                 if (!to_boolean (od->lookup_variable (ly_symbol2scm ("is-paper"))))
1177                 {
1178                         parser->parser_error (@1, _ ("need \\paper for paper block"));
1179                         $$ = get_paper (parser)->unprotect ();
1180                 }
1181         }
1182         ;
1183
1184
1185 output_def:
1186         output_def_body '}' {
1187                 if (scm_is_pair ($1))
1188                         $$ = scm_car ($1);
1189
1190                 parser->lexer_->remove_scope ();
1191                 parser->lexer_->pop_state ();
1192         }
1193         ;
1194
1195 output_def_head:
1196         PAPER {
1197                 Output_def *p = get_paper (parser);
1198                 p->input_origin_ = @$;
1199                 parser->lexer_->add_scope (p->scope_);
1200                 $$ = p->unprotect ();
1201         }
1202         | MIDI    {
1203                 Output_def *p = get_midi (parser);
1204                 $$ = p->unprotect ();
1205                 parser->lexer_->add_scope (p->scope_);
1206         }
1207         | LAYOUT        {
1208                 Output_def *p = get_layout (parser);
1209
1210                 parser->lexer_->add_scope (p->scope_);
1211                 $$ = p->unprotect ();
1212         }
1213         ;
1214
1215 output_def_head_with_mode_switch:
1216         output_def_head {
1217                 parser->lexer_->push_initial_state ();
1218                 $$ = $1;
1219         }
1220         ;
1221
1222 // We need this weird nonterminal because both music as well as a
1223 // context definition can start with \context and the difference is
1224 // only apparent after looking at the next token.  If it is '{', there
1225 // is still time to escape from notes mode.
1226
1227 music_or_context_def:
1228         music_assign
1229         | context_def_spec_block
1230         ;
1231
1232 output_def_body:
1233         output_def_head_with_mode_switch '{' {
1234                 unsmob<Output_def> ($1)->input_origin_.set_spot (@$);
1235                 // This is a stupid trick to mark the beginning of the
1236                 // body for deciding whether to allow
1237                 // embedded_scm_active to have an output definition
1238                 $$ = scm_list_1 ($1);
1239         }
1240         | output_def_body assignment  {
1241                 if (scm_is_pair ($1))
1242                         $$ = scm_car ($1);
1243         }
1244         | output_def_body embedded_scm_active
1245         {
1246                 // We don't switch into note mode for Scheme functions
1247                 // here.  Does not seem warranted/required in output
1248                 // definitions.
1249                 if (scm_is_pair ($1))
1250                 {
1251                         Output_def *o = unsmob<Output_def> ($2);
1252                         if (o) {
1253                                 o->input_origin_.set_spot (@$);
1254                                 $1 = o->self_scm ();
1255                                 parser->lexer_->remove_scope ();
1256                                 parser->lexer_->add_scope (o->scope_);
1257                                 $2 = SCM_UNSPECIFIED;
1258                         } else
1259                                 $1 = scm_car ($1);
1260                 }
1261                 if (unsmob<Context_def> ($2))
1262                         assign_context_def (unsmob<Output_def> ($1), $2);
1263                 // Seems unlikely, but let's be complete:
1264                 else if (unsmob<Music> ($2))
1265                 {
1266                         SCM proc = parser->lexer_->lookup_identifier
1267                                 ("output-def-music-handler");
1268                         scm_call_2 (proc, $1, $2);
1269                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
1270                         parser->parser_error (@2, _("bad expression type"));
1271                 $$ = $1;
1272         }
1273         | output_def_body SCM_TOKEN {
1274                 if (scm_is_pair ($1))
1275                         $$ = scm_car ($1);
1276                 // Evaluate and ignore #xxx, as opposed to \xxx
1277                 parser->lexer_->eval_scm_token ($2, @2);
1278         }
1279         | output_def_body
1280         {
1281                 if (scm_is_pair ($1))
1282                         $1 = scm_car ($1);
1283                 parser->lexer_->push_note_state (Lily::pitchnames);
1284         } music_or_context_def
1285         {
1286                 parser->lexer_->pop_state ();
1287                 if (unsmob<Context_def> ($3))
1288                         assign_context_def (unsmob<Output_def> ($1), $3);
1289                 else {
1290
1291                         SCM proc = parser->lexer_->lookup_identifier
1292                                      ("output-def-music-handler");
1293                         scm_call_2 (proc, $1, $3);
1294                 }
1295                 $$ = $1;
1296         }
1297         | output_def_body error {
1298
1299         }
1300         ;
1301
1302 tempo_event:
1303         TEMPO steno_duration '=' tempo_range    {
1304                 $$ = MAKE_SYNTAX (tempo, @$, SCM_EOL, $2, $4);
1305         }
1306         | TEMPO text steno_duration '=' tempo_range     {
1307                 $$ = MAKE_SYNTAX (tempo, @$, $2, $3, $5);
1308         }
1309         | TEMPO text {
1310                 $$ = MAKE_SYNTAX (tempo, @$, $2);
1311         } %prec ':'
1312         ;
1313
1314 /*
1315 The representation of a  list is reversed to have efficient append.  */
1316
1317 music_list:
1318         /* empty */ {
1319                 $$ = SCM_EOL;
1320         }
1321         | music_list music_embedded {
1322                 if (unsmob<Music> ($2))
1323                         $$ = scm_cons ($2, $1);
1324         }
1325         | music_list error {
1326                 Music *m = MY_MAKE_MUSIC("Music", @$);
1327                 // ugh. code dup
1328                 m->set_property ("error-found", SCM_BOOL_T);
1329                 $$ = scm_cons (m->self_scm (), $1);
1330                 m->unprotect (); /* UGH */
1331         }
1332         ;
1333
1334 braced_music_list:
1335         '{' music_list '}'
1336         {
1337                 $$ = scm_reverse_x ($2, SCM_EOL);
1338         }
1339         ;
1340
1341 music:  music_assign
1342         | lyric_element_music
1343         | pitch_as_music
1344         ;
1345
1346 pitch_as_music:
1347         pitch_or_music
1348         {
1349                 $$ = make_music_from_simple (parser, @1, $1);
1350                 if (!unsmob<Music> ($$))
1351                 {
1352                         parser->parser_error (@1, _ ("music expected"));
1353                         $$ = MAKE_SYNTAX (void_music, @$);
1354                 }
1355         }
1356         ;
1357
1358 music_embedded:
1359         music
1360         {
1361                 if (unsmob<Music> ($1)->is_mus_type ("post-event")) {
1362                         parser->parser_error (@1, _ ("unexpected post-event"));
1363                         $$ = SCM_UNSPECIFIED;
1364                 }
1365         }
1366         | music_embedded_backup
1367         {
1368                 $$ = $1;
1369         }
1370         | music_embedded_backup BACKUP lyric_element_music
1371         {
1372                 $$ = $3;
1373         }
1374         | multiplied_duration post_events
1375         {
1376                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1377
1378                 parser->default_duration_ = *unsmob<Duration> ($1);
1379                 n->set_property ("duration", $1);
1380
1381                 if (scm_is_pair ($2))
1382                         n->set_property ("articulations",
1383                                          scm_reverse_x ($2, SCM_EOL));
1384                 $$ = n->unprotect ();
1385         }
1386         ;
1387
1388 music_embedded_backup:
1389         embedded_scm
1390         {
1391                 if (scm_is_eq ($1, SCM_UNSPECIFIED))
1392                         $$ = $1;
1393                 else if (Music *m = unsmob<Music> ($1)) {
1394                         if (m->is_mus_type ("post-event")) {
1395                                 parser->parser_error
1396                                         (@1, _ ("unexpected post-event"));
1397                                 $$ = SCM_UNSPECIFIED;
1398                         } else
1399                                 $$ = $1;
1400                 } else if (parser->lexer_->is_lyric_state ()
1401                            && Text_interface::is_markup ($1))
1402                         MYBACKUP (LYRIC_ELEMENT, $1, @1);
1403                 else {
1404                         @$.warning (_ ("Ignoring non-music expression"));
1405                         $$ = $1;
1406                 }
1407         }
1408         ;
1409
1410 // music_assign does not need to contain lyrics: there are no
1411 // assignments in lyricmode.
1412 music_assign:
1413         simple_music
1414         | composite_music %prec COMPOSITE
1415         ;
1416
1417 repeated_music:
1418         REPEAT simple_string unsigned_number music
1419         {
1420                 $$ = MAKE_SYNTAX (repeat, @$, $2, $3, $4, SCM_EOL);
1421         }
1422         | REPEAT simple_string unsigned_number music ALTERNATIVE braced_music_list
1423         {
1424                 $$ = MAKE_SYNTAX (repeat, @$, $2, $3, $4, $6);
1425         }
1426         ;
1427
1428 sequential_music:
1429         SEQUENTIAL braced_music_list {
1430                 $$ = MAKE_SYNTAX (sequential_music, @$, $2);
1431         }
1432         | braced_music_list {
1433                 $$ = MAKE_SYNTAX (sequential_music, @$, $1);
1434         }
1435         ;
1436
1437 simultaneous_music:
1438         SIMULTANEOUS braced_music_list {
1439                 $$ = MAKE_SYNTAX (simultaneous_music, @$, $2);
1440         }
1441         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1442                 $$ = MAKE_SYNTAX (simultaneous_music, @$, scm_reverse_x ($2, SCM_EOL));
1443         }
1444         ;
1445
1446 simple_music:
1447         event_chord
1448         | music_property_def
1449         | context_change
1450         ;
1451
1452 context_modification:
1453         WITH
1454         {
1455                 parser->lexer_->push_note_state (Lily::pitchnames);
1456         } '{' context_mod_list '}'
1457         {
1458                 parser->lexer_->pop_state ();
1459                 $$ = $4;
1460         }
1461         | WITH CONTEXT_MOD_IDENTIFIER
1462         {
1463                 $$ = $2;
1464         }
1465         | CONTEXT_MOD_IDENTIFIER
1466         {
1467                 $$ = $1;
1468         }
1469         | WITH context_modification_arg
1470         {
1471                 if (unsmob<Music> ($2)) {
1472                         SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
1473                         $2 = scm_call_1 (proc, $2);
1474                 }
1475                 if (unsmob<Context_mod> ($2))
1476                         $$ = $2;
1477                 else {
1478                         parser->parser_error (@2, _ ("not a context mod"));
1479                         $$ = Context_mod ().smobbed_copy ();
1480                 }
1481         }
1482         ;
1483
1484 context_modification_arg:
1485         embedded_scm
1486         | MUSIC_IDENTIFIER
1487         ;
1488
1489 /* A list of single mods collected from a (possibly empty) sequence of
1490  * context modifications, usually written as \with ... \with ...
1491  */
1492
1493 optional_context_mods:
1494         context_modification_mods_list
1495         {
1496                 if (scm_is_pair ($1))
1497                         $$ = scm_append_x (scm_reverse_x ($1, SCM_EOL));
1498         }
1499         ;
1500
1501 /* The worker for optional_context_mods conses a (reversed) list where
1502  * each element contains the list of single context mods from one
1503  * context modification block.  Context_mod::get_mods creates fresh
1504  * copies, so it's okay to use append! on them.
1505  */
1506
1507 context_modification_mods_list:
1508         /**/ {
1509                 $$ = SCM_EOL;
1510         }
1511         | context_modification_mods_list context_modification
1512         {
1513                 if (Context_mod *m = unsmob<Context_mod> ($2))
1514                         $$ = scm_cons (m->get_mods (), $1);
1515         }
1516         ;
1517
1518 /* A Context_mod is a container for a list of context mods like
1519  * \consists ...  \override ... .  context_mod_list produces a
1520  * Context_mod from the inside of a \with { ... } statement.
1521  */
1522
1523 context_mod_list:
1524         /**/ {
1525             $$ = Context_mod ().smobbed_copy ();
1526         }
1527         | context_mod_list context_mod  {
1528                 if (!SCM_UNBNDP ($2))
1529                         unsmob<Context_mod> ($1)->add_context_mod ($2);
1530         }
1531         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1532                  Context_mod *md = unsmob<Context_mod> ($2);
1533                  if (md)
1534                      unsmob<Context_mod> ($1)->add_context_mods (md->get_mods ());
1535         }
1536         | context_mod_list context_mod_arg {
1537                 if (scm_is_eq ($2, SCM_UNSPECIFIED))
1538                         ;
1539                 else if (unsmob<Music> ($2)) {
1540                         SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
1541                         $2 = scm_call_1 (proc, $2);
1542                 }
1543                 if (unsmob<Context_mod> ($2))
1544                         unsmob<Context_mod> ($$)->add_context_mods
1545                                 (unsmob<Context_mod> ($2)->get_mods ());
1546                 else {
1547                         parser->parser_error (@2, _ ("not a context mod"));
1548                 }
1549         }
1550         ;
1551
1552 context_prefix:
1553         CONTEXT symbol optional_id optional_context_mods {
1554                 $$ = START_MAKE_SYNTAX (context_specification, $2, $3, $4, SCM_BOOL_F);
1555         }
1556         | NEWCONTEXT symbol optional_id optional_context_mods {
1557                 $$ = START_MAKE_SYNTAX (context_specification, $2, $3, $4, SCM_BOOL_T);
1558         }
1559         ;
1560
1561 new_lyrics:
1562         ADDLYRICS optional_context_mods lyric_mode_music {
1563                 $$ = scm_acons ($3, $2, SCM_EOL);
1564         }
1565         | new_lyrics ADDLYRICS optional_context_mods lyric_mode_music {
1566                 $$ = scm_acons ($4, $3, $1);
1567         }
1568         ;
1569
1570 /* basic_music is basically the same as composite_music but with
1571  * context-prefixed music and lyricized music explicitly removed.  The
1572  * reason is that in a sequence
1573  *
1574  *   \new Staff \new Voice { ... } \addlyrics { ... } \addlyrics { ... }
1575  *
1576  * we need to group both \addlyrics together (as they go with the same
1577  * voice) but then combine them with \new Voice { ... }, meaning that
1578  * combining \new Voice { ... } needs higher priority than
1579  * { ... } \addlyrics, and *not* have \new Staff \new Voice { ... }
1580  * combine before combining \new Voice { ... } \addlyrics: only one
1581  * layer of context-prefixed music should assemble before \addlyrics
1582  * is integrated.  Total mess, and we sort this mess out with explicit
1583  * rules preferring a single context-prefix.
1584  */
1585
1586 basic_music:
1587         music_function_call
1588         | repeated_music
1589         | music_bare
1590         | LYRICSTO simple_string lyric_mode_music {
1591                 $$ = MAKE_SYNTAX (lyric_combine, @$, $2, SCM_EOL, $3);
1592         }
1593         | LYRICSTO symbol '=' simple_string lyric_mode_music
1594         {
1595                 $$ = MAKE_SYNTAX (lyric_combine, @$, $3, $2, $4);
1596         }
1597         ;
1598
1599 contextable_music:
1600         basic_music
1601         | pitch_as_music
1602         | event_chord
1603         ;
1604
1605 contexted_basic_music:
1606         context_prefix contextable_music new_lyrics
1607         {
1608                 Input i;
1609                 i.set_location (@1, @2);
1610                 $$ = FINISH_MAKE_SYNTAX ($1, i, $2);
1611                 $$ = MAKE_SYNTAX (add_lyrics, @$, $$, scm_reverse_x ($3, SCM_EOL));
1612         } %prec COMPOSITE
1613         | context_prefix contextable_music
1614         {
1615                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1616         } %prec COMPOSITE
1617         | context_prefix contexted_basic_music
1618         {
1619                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1620         }
1621         ;
1622
1623 composite_music:
1624         basic_music %prec COMPOSITE
1625         | contexted_basic_music
1626         | basic_music new_lyrics
1627         {
1628                 $$ = MAKE_SYNTAX (add_lyrics, @$, $1, scm_reverse_x ($2, SCM_EOL));
1629         } %prec COMPOSITE
1630         ;
1631
1632 music_bare:
1633         mode_changed_music
1634         | MUSIC_IDENTIFIER
1635         | grouped_music_list
1636         ;
1637
1638 grouped_music_list:
1639         simultaneous_music              { $$ = $1; }
1640         | sequential_music              { $$ = $1; }
1641         ;
1642
1643 /* Function argument lists are arguably the most complex part in the
1644  * parser.  They are pretty tricky to understand because of the way
1645  * they are processed, and because of optional arguments that can be
1646  * omitted.  When there are several optional arguments in a row,
1647  * omitting one automatically omits all following arguments.  Optional
1648  * arguments can only be omitted when either
1649  *
1650  * a) the omission is explicitly started with \default
1651  * b) the omission is implicitly started by an argument not matching
1652  *    its predicate, and there is a mandatory argument later that can
1653  *    "catch" the argument that does not fit.
1654  *
1655  * When argument parsing starts, the lexer pushes EXPECT_SCM tokens
1656  * (corresponding to mandatory arguments and having a predicate
1657  * function as semantic value) or EXPECT_OPTIONAL EXPECT_SCM (where
1658  * the semantic value of the EXPECT_OPTIONAL token is the default to
1659  * use when the optional argument is omitted, and EXPECT_SCM again has
1660  * the argument predicate as semantic value) in reverse order to the
1661  * parser, followed by EXPECT_NO_MORE_ARGS.  The argument list is then
1662  * processed inside-out while actual tokens are consumed.
1663  *
1664  * This means that the argument list tokens determine the actions
1665  * taken as they arrive.  The structure of the argument list is known
1666  * to the parser and stored in its parse stack when the first argument
1667  * is being parsed.  What the parser does not know is which predicates
1668  * will match and whether or not \default will be appearing in the
1669  * argument list, and where.
1670  *
1671  * Sequences of 0 or more optional arguments are scanned using either
1672  * function_arglist_backup or function_arglist_nonbackup.  The first
1673  * is used when optional arguments are followed by at least one
1674  * mandatory argument: in that case optional arguments may be skipped
1675  * by either a false predicate (in which case the expression will be
1676  * pushed back as one or more tokens, preceded by a BACKUP token) or
1677  * by using \default.
1678  *
1679  * If optional arguments are at the end of the argument list, they are
1680  * instead scanned using function_arglist_nonbackup: here the only
1681  * manner to enter into skipping of optional arguments is the use of
1682  * \default.
1683  *
1684  * The argument list of a normal function call is parsed using
1685  * function_arglist.  The part of an argument list before a mandatory
1686  * argument is parsed using function_arglist_optional.
1687  *
1688  * The difference is that leading optional arguments are scanned using
1689  * function_arglist_nonbackup and function_arglist_backup,
1690  * respectively.
1691  *
1692  * Most other details are obvious in the rules themselves.
1693  *
1694  */
1695
1696 symbol_list_arg:
1697         SYMBOL_LIST
1698         | SYMBOL_LIST '.' symbol_list_rev
1699         {
1700                 $$ = scm_append (scm_list_2 ($1, scm_reverse_x ($3, SCM_EOL)));
1701         }
1702         | SYMBOL_LIST ',' symbol_list_rev
1703         {
1704                 $$ = scm_append (scm_list_2 ($1, scm_reverse_x ($3, SCM_EOL)));
1705         }
1706         ;
1707
1708 symbol_list_rev:
1709         symbol_list_part
1710         | symbol_list_rev '.' symbol_list_part
1711         {
1712                 $$ = scm_append_x (scm_list_2 ($3, $1));
1713         }
1714         | symbol_list_rev ',' symbol_list_part
1715         {
1716                 $$ = scm_append_x (scm_list_2 ($3, $1));
1717         }
1718         ;
1719
1720 // symbol_list_part delivers elements in reverse copy.
1721
1722 symbol_list_part:
1723         symbol_list_element
1724         {
1725                 $$ = try_string_variants (Lily::key_list_p, $1);
1726                 if (SCM_UNBNDP ($$)) {
1727                         parser->parser_error (@1, _("not a key"));
1728                         $$ = SCM_EOL;
1729                 } else
1730                         $$ = scm_reverse ($$);
1731         }
1732         ;
1733
1734
1735 symbol_list_element:
1736         STRING
1737         | embedded_scm_bare
1738         | UNSIGNED
1739         ;
1740
1741 symbol_list_part_bare:
1742         STRING
1743         {
1744                 $$ = try_string_variants (Lily::key_list_p, $1);
1745                 if (SCM_UNBNDP ($$)) {
1746                         parser->parser_error (@1, _("not a key"));
1747                         $$ = SCM_EOL;
1748                 } else
1749                         $$ = scm_reverse ($$);
1750         }
1751         | UNSIGNED
1752         {
1753                 $$ = scm_list_1 ($1);
1754         }
1755         ;
1756
1757 function_arglist_nonbackup:
1758         function_arglist_common
1759         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup post_event_nofinger
1760         {
1761                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1762         }
1763         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' UNSIGNED
1764         {
1765                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1766                 if (scm_is_true (scm_call_1 ($2, n)))
1767                         $$ = scm_cons (n, $3);
1768                 else {
1769                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1770                         t->set_property ("digit", $5);
1771                         $$ = check_scheme_arg (parser, @4, t->unprotect (),
1772                                                $3, $2, n);
1773                 }
1774         }
1775         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' REAL
1776         {
1777                 $$ = check_scheme_arg (parser, @4,
1778                                        scm_difference ($5, SCM_UNDEFINED),
1779                                        $3, $2);
1780         }
1781         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' NUMBER_IDENTIFIER
1782         {
1783                 $$ = check_scheme_arg (parser, @4,
1784                                        scm_difference ($5, SCM_UNDEFINED),
1785                                        $3, $2);
1786         }
1787         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup embedded_scm_arg
1788         {
1789                 if (scm_is_true (scm_call_1 ($2, $4)))
1790                         $$ = scm_cons ($4, $3);
1791                 else
1792                         $$ = check_scheme_arg (parser, @4,
1793                                                make_music_from_simple
1794                                                (parser, @4, $4),
1795                                                $3, $2);
1796         }
1797         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup bare_number_common
1798         {
1799                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1800         }
1801         | function_arglist_nonbackup_reparse REPARSE pitch_or_music
1802         {
1803                 if (scm_is_true (scm_call_1 ($2, $3)))
1804                         $$ = scm_cons ($3, $1);
1805                 else
1806                         $$ = check_scheme_arg (parser, @3,
1807                                                make_music_from_simple
1808                                                (parser, @3, $3),
1809                                                $1, $2);
1810         }
1811         | function_arglist_nonbackup_reparse REPARSE multiplied_duration
1812         {
1813                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1814         }
1815         | function_arglist_nonbackup_reparse REPARSE reparsed_rhythm
1816         {
1817                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1818         }
1819         | function_arglist_nonbackup_reparse REPARSE bare_number_common
1820         {
1821                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1822         }
1823         | function_arglist_nonbackup_reparse REPARSE SCM_ARG
1824         {
1825                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1826         }
1827         | function_arglist_nonbackup_reparse REPARSE lyric_element_music
1828         {
1829                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1830         }
1831         | function_arglist_nonbackup_reparse REPARSE symbol_list_arg
1832         {
1833                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1834         }
1835         ;
1836
1837
1838 reparsed_rhythm:
1839         DURATION_ARG dots multipliers post_events
1840         {
1841                 $$ = make_music_from_simple (parser, @$,
1842                                              make_duration ($1, scm_to_int ($2), $3));
1843                 Music *m = unsmob<Music> ($$);
1844                 assert (m);
1845                 if (scm_is_pair ($4))
1846                         m->set_property ("articulations",
1847                                          scm_reverse_x ($4, SCM_EOL));
1848         } %prec ':'
1849         ;
1850
1851 function_arglist_nonbackup_reparse:
1852         EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup SCM_IDENTIFIER
1853         {
1854                 $$ = $3;
1855                 SCM res = try_string_variants ($2, $4);
1856                 if (!SCM_UNBNDP (res))
1857                         if (scm_is_pair (res))
1858                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1859                         else
1860                                 MYREPARSE (@4, $2, SCM_ARG, res);
1861                 else if (scm_is_true
1862                          (scm_call_1
1863                           ($2, make_music_from_simple
1864                            (parser, @4, $4))))
1865                         MYREPARSE (@4, $2, STRING, $4);
1866                 else
1867                         MYREPARSE (@4, $2, SCM_ARG, $4);
1868         }
1869         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup pitch
1870         {
1871                 $$ = $3;
1872                 if (scm_is_true
1873                     (scm_call_1
1874                      ($2, make_music_from_simple
1875                       (parser, @4, $4))))
1876                         MYREPARSE (@4, $2, PITCH_IDENTIFIER, $4);
1877                 else
1878                         MYREPARSE (@4, $2, SCM_ARG, $4);
1879         }
1880         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup steno_tonic_pitch
1881         {
1882                 $$ = $3;
1883                 if (scm_is_true
1884                     (scm_call_1
1885                      ($2, make_music_from_simple
1886                       (parser, @4, $4))))
1887                         MYREPARSE (@4, $2, TONICNAME_PITCH, $4);
1888                 else
1889                         MYREPARSE (@4, $2, SCM_ARG, $4);
1890         }
1891         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup STRING
1892         {
1893                 $$ = $3;
1894                 SCM res = try_string_variants ($2, $4);
1895                 if (!SCM_UNBNDP (res))
1896                         if (scm_is_pair (res))
1897                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1898                         else
1899                                 MYREPARSE (@4, $2, SCM_ARG, res);
1900                 else if (scm_is_true
1901                          (scm_call_1
1902                           ($2, make_music_from_simple
1903                            (parser, @4, $4))))
1904                         MYREPARSE (@4, $2, STRING, $4);
1905                 else
1906                         MYREPARSE (@4, $2, SCM_ARG, $4);
1907         }
1908         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup full_markup
1909         {
1910                 $$ = $3;
1911                 if (scm_is_true (scm_call_1 ($2, $4)))
1912                         MYREPARSE (@4, $2, SCM_ARG, $4);
1913                 else if (scm_is_true
1914                          (scm_call_1
1915                           ($2, make_music_from_simple
1916                            (parser, @4, $4))))
1917                         MYREPARSE (@4, $2, STRING, $4);
1918                 else
1919                         MYREPARSE (@4, $2, SCM_ARG, $4);
1920         }
1921         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup UNSIGNED
1922         {
1923                 $$ = $3;
1924                 if (scm_is_true (scm_call_1 ($2, $4)))
1925                         // May be 3 \cm or similar
1926                         MYREPARSE (@4, $2, REAL, $4);
1927                 else if (scm_is_true (scm_call_1 ($2, scm_list_1 ($4))))
1928                         MYREPARSE (@4, $2, SYMBOL_LIST, scm_list_1 ($4));
1929                 else {
1930                         SCM d = make_duration ($4);
1931                         if (!SCM_UNBNDP (d)) {
1932                                 if (scm_is_true (scm_call_1 ($2, d)))
1933                                         MYREPARSE (@4, $2, DURATION_IDENTIFIER, d);
1934                                 else if (scm_is_true
1935                                          (scm_call_1
1936                                           ($2, make_music_from_simple (parser, @4, d))))
1937                                         MYREPARSE (@4, $2, DURATION_ARG, d);
1938                                 else
1939                                         MYREPARSE (@4, $2, SCM_ARG, $4); // trigger error
1940                         } else
1941                                 MYREPARSE (@4, $2, SCM_ARG, $4); // trigger error
1942                 }
1943         }
1944         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup DURATION_IDENTIFIER
1945         {
1946                 $$ = $3;
1947                 if (scm_is_true (scm_call_1 ($2, $4)))
1948                         MYREPARSE (@4, $2, DURATION_IDENTIFIER, $4);
1949                 else if (scm_is_true
1950                          (scm_call_1
1951                           ($2, make_music_from_simple (parser, @4, $4))))
1952                         MYREPARSE (@4, $2, DURATION_ARG, $4);
1953                 else
1954                         MYREPARSE (@4, $2, SCM_ARG, $4); // trigger error
1955         }
1956         ;
1957
1958
1959 // function_arglist_backup can't occur at the end of an argument
1960 // list.
1961 function_arglist_backup:
1962         function_arglist_common
1963         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup embedded_scm_arg
1964         {
1965                 if (scm_is_true (scm_call_1 ($2, $4)))
1966                         $$ = scm_cons ($4, $3);
1967                 else {
1968                         $$ = make_music_from_simple (parser, @4, $4);
1969                         if (scm_is_true (scm_call_1 ($2, $$)))
1970                                 $$ = scm_cons ($$, $3);
1971                         else
1972                         {
1973                                 $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
1974                                 MYBACKUP (SCM_ARG, $4, @4);
1975                         }
1976                 }
1977         }
1978         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup post_event_nofinger
1979         {
1980                 if (scm_is_true (scm_call_1 ($2, $4)))
1981                 {
1982                         $$ = scm_cons ($4, $3);
1983                 } else {
1984                         $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
1985                         MYBACKUP (EVENT_IDENTIFIER, $4, @4);
1986                 }
1987         }
1988         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup pitch
1989         {
1990                 if (scm_is_true
1991                     (scm_call_1
1992                      ($2, make_music_from_simple
1993                       (parser, @4, $4))))
1994                 {
1995                         $$ = $3;
1996                         MYREPARSE (@4, $2, PITCH_IDENTIFIER, $4);
1997                 } else if (scm_is_true (scm_call_1 ($2, $4)))
1998                         $$ = scm_cons ($4, $3);
1999                 else {
2000                         $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
2001                         MYBACKUP (PITCH_IDENTIFIER, $4, @4);
2002                 }
2003         }
2004         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup steno_tonic_pitch
2005         {
2006                 if (scm_is_true
2007                     (scm_call_1
2008                      ($2, make_music_from_simple
2009                       (parser, @4, $4))))
2010                 {
2011                         $$ = $3;
2012                         MYREPARSE (@4, $2, TONICNAME_PITCH, $4);
2013                 } else if (scm_is_true (scm_call_1 ($2, $4)))
2014                         $$ = scm_cons ($4, $3);
2015                 else {
2016                         $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
2017                         MYBACKUP (TONICNAME_PITCH, $4, @4);
2018                 }
2019         }
2020         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup full_markup
2021         {
2022                 if (scm_is_true (scm_call_1 ($2, $4)))
2023                         $$ = scm_cons ($4, $3);
2024                 else {
2025                         $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
2026                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
2027                 }
2028         }
2029         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup UNSIGNED
2030         {
2031                 $$ = $3;
2032                 if (scm_is_true (scm_call_1 ($2, $4)))
2033                         // May be 3 \cm or similar
2034                         MYREPARSE (@4, $2, REAL, $4);
2035                 else if (scm_is_true (scm_call_1 ($2, scm_list_1 ($4))))
2036                         MYREPARSE (@4, $2, SYMBOL_LIST, scm_list_1 ($4));
2037                 else {
2038                         SCM d = make_duration ($4);
2039                         if (!SCM_UNBNDP (d)) {
2040                                 if (scm_is_true (scm_call_1 ($2, d)))
2041                                         MYREPARSE (@4, $2, DURATION_IDENTIFIER, d);
2042                                 else if (scm_is_true
2043                                          (scm_call_1
2044                                           ($2, make_music_from_simple (parser, @4, d))))
2045                                         MYREPARSE (@4, $2, DURATION_ARG, d);
2046                                 else {
2047                                         $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
2048                                         MYBACKUP (UNSIGNED, $4, @4);
2049                                 }
2050                         } else {
2051                                 $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
2052                                 MYBACKUP (UNSIGNED, $4, @4);
2053                         }
2054                 }
2055         }
2056         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup REAL
2057         {
2058                 if (scm_is_true (scm_call_1 ($2, $4)))
2059                 {
2060                         $$ = $3;
2061                         MYREPARSE (@4, $2, REAL, $4);
2062                 } else {
2063                         $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
2064                         MYBACKUP (REAL, $4, @4);
2065                 }
2066         }
2067         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup NUMBER_IDENTIFIER
2068         {
2069                 if (scm_is_true (scm_call_1 ($2, $4)))
2070                 {
2071                         $$ = scm_cons ($4, $3);
2072                 } else {
2073                         $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
2074                         MYBACKUP (NUMBER_IDENTIFIER, $4, @4);
2075                 }
2076         }
2077         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' UNSIGNED
2078         {
2079                 SCM n = scm_difference ($5, SCM_UNDEFINED);
2080                 if (scm_is_true (scm_call_1 ($2, n))) {
2081                         $$ = $3;
2082                         MYREPARSE (@5, $2, REAL, n);
2083                 } else {
2084                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
2085                         t->set_property ("digit", $5);
2086                         $$ = t->unprotect ();
2087                         if (scm_is_true (scm_call_1 ($2, $$)))
2088                                 $$ = scm_cons ($$, $3);
2089                         else {
2090                                 $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
2091                                 MYBACKUP (UNSIGNED, $5, @5);
2092                                 parser->lexer_->push_extra_token (@4, '-');
2093                         }
2094                 }
2095         }
2096         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' REAL
2097         {
2098                 SCM n = scm_difference ($5, SCM_UNDEFINED);
2099                 if (scm_is_true (scm_call_1 ($2, n))) {
2100                         MYREPARSE (@5, $2, REAL, n);
2101                         $$ = $3;
2102                 } else {
2103                         $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
2104                         MYBACKUP (REAL, n, @5);
2105                 }
2106         }
2107         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' NUMBER_IDENTIFIER
2108         {
2109                 SCM n = scm_difference ($5, SCM_UNDEFINED);
2110                 if (scm_is_true (scm_call_1 ($2, n))) {
2111                         $$ = scm_cons (n, $3);
2112                 } else {
2113                         $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
2114                         MYBACKUP (NUMBER_IDENTIFIER, n, @5);
2115                 }
2116         }
2117         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup DURATION_IDENTIFIER
2118         {
2119                 $$ = $3;
2120                 if (scm_is_true (scm_call_1 ($2, $4)))
2121                         MYREPARSE (@4, $2, DURATION_IDENTIFIER, $4);
2122                 else if (scm_is_true
2123                          (scm_call_1
2124                           ($2, make_music_from_simple (parser, @4, $4))))
2125                         MYREPARSE (@4, $2, DURATION_ARG, $4);
2126                 else {
2127                         $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
2128                         MYBACKUP (DURATION_IDENTIFIER, $4, @4);
2129                 }
2130         }
2131         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup SCM_IDENTIFIER
2132         {
2133                 SCM res = try_string_variants ($2, $4);
2134                 if (!SCM_UNBNDP (res))
2135                         if (scm_is_pair (res)) {
2136                                 $$ = $3;
2137                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
2138                         }
2139                         else
2140                                 $$ = scm_cons (res, $3);
2141                 else {
2142                         $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
2143                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
2144                 }
2145         }
2146         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup STRING
2147         {
2148                 SCM res = try_string_variants ($2, $4);
2149                 if (!SCM_UNBNDP (res))
2150                         if (scm_is_pair (res)) {
2151                                 $$ = $3;
2152                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
2153                         }
2154                         else
2155                                 $$ = scm_cons (res, $3);
2156                 else {
2157                         $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
2158                         MYBACKUP (STRING, $4, @4);
2159                 }
2160         }
2161         | function_arglist_backup REPARSE pitch_or_music
2162         {
2163                 if (scm_is_true (scm_call_1 ($2, $3)))
2164                         $$ = scm_cons ($3, $1);
2165                 else
2166                         $$ = check_scheme_arg (parser, @3,
2167                                                make_music_from_simple
2168                                                (parser, @3, $3),
2169                                                $1, $2);
2170         }
2171         | function_arglist_backup REPARSE bare_number_common
2172         {
2173                 $$ = check_scheme_arg (parser, @3,
2174                                        $3, $1, $2);
2175         }
2176         | function_arglist_backup REPARSE multiplied_duration
2177         {
2178                 $$ = check_scheme_arg (parser, @3,
2179                                        $3, $1, $2);
2180         }
2181         | function_arglist_backup REPARSE reparsed_rhythm
2182         {
2183                 $$ = check_scheme_arg (parser, @3,
2184                                        $3, $1, $2);
2185         }
2186         | function_arglist_backup REPARSE symbol_list_arg
2187         {
2188                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
2189         }
2190         ;
2191
2192 function_arglist:
2193         function_arglist_nonbackup
2194         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_nonbackup DEFAULT
2195         {
2196                 $$ = scm_cons (loc_on_music (parser, @4, $1), $3);
2197         }
2198         ;
2199
2200 function_arglist_skip_nonbackup:
2201         function_arglist_nonbackup
2202         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_nonbackup
2203         {
2204                 $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
2205         }
2206         ;
2207
2208 // Partial function arglists are returned just in their incomplete
2209 // state: when combined with the music function, the missing parts of
2210 // the signature can be reconstructed
2211 //
2212 // To serve as a partial arglist, the argument list must absolutely
2213 // _not_ be in "skipping optional arguments" mode since then there is
2214 // some backup token that has nowhere to go before \etc.
2215 //
2216 // So we can skim off an arbitrary number of arguments from the end of
2217 // the argument list.  The argument list remaining afterwards has to
2218 // be in not-skipping-optional-arguments mode.
2219
2220 function_arglist_partial:
2221         EXPECT_SCM function_arglist_optional
2222         {
2223                 $$ = $2;
2224         }
2225         | EXPECT_SCM function_arglist_partial_optional
2226         {
2227                 $$ = $2;
2228         }
2229         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup
2230         {
2231                 $$ = $3;
2232         }
2233         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_partial
2234         {
2235                 $$ = $3;
2236         }
2237         ;
2238
2239 function_arglist_partial_optional:
2240         EXPECT_SCM function_arglist_optional
2241         {
2242                 $$ = $2;
2243         }
2244         | EXPECT_SCM function_arglist_partial_optional
2245         {
2246                 $$ = $2;
2247         }
2248         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup
2249         {
2250                 $$ = $3;
2251         }
2252         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_partial_optional
2253         {
2254                 $$ = $3;
2255         }
2256         ;
2257
2258 function_arglist_common:
2259         EXPECT_NO_MORE_ARGS {
2260                 $$ = SCM_EOL;
2261         }
2262         | EXPECT_SCM function_arglist_optional embedded_scm_arg
2263         {
2264                 if (scm_is_true (scm_call_1 ($1, $3)))
2265                         $$ = scm_cons ($3, $2);
2266                 else
2267                         $$ = check_scheme_arg (parser, @3,
2268                                                make_music_from_simple
2269                                                (parser, @3, $3),
2270                                                $2, $1);
2271         }
2272         | EXPECT_SCM function_arglist_optional bare_number_common
2273         {
2274                 $$ = check_scheme_arg (parser, @3,
2275                                        $3, $2, $1);
2276         }
2277         | EXPECT_SCM function_arglist_optional post_event_nofinger
2278         {
2279                 $$ = check_scheme_arg (parser, @3,
2280                                        $3, $2, $1);
2281         }
2282         | EXPECT_SCM function_arglist_optional '-' NUMBER_IDENTIFIER
2283         {
2284                 SCM n = scm_difference ($4, SCM_UNDEFINED);
2285                 $$ = check_scheme_arg (parser, @4, n, $2, $1);
2286         }
2287         | function_arglist_common_reparse REPARSE SCM_ARG
2288         {
2289                 $$ = check_scheme_arg (parser, @3,
2290                                        $3, $1, $2);
2291         }
2292         | function_arglist_common_reparse REPARSE lyric_element_music
2293         {
2294                 $$ = check_scheme_arg (parser, @3,
2295                                        $3, $1, $2);
2296         }
2297         | function_arglist_common_reparse REPARSE pitch_or_music
2298         {
2299                 if (scm_is_true (scm_call_1 ($2, $3)))
2300                         $$ = scm_cons ($3, $1);
2301                 else
2302                         $$ = check_scheme_arg (parser, @3,
2303                                                make_music_from_simple
2304                                                (parser, @3, $3),
2305                                                $1, $2);
2306         }
2307         | function_arglist_common_reparse REPARSE bare_number_common
2308         {
2309                 $$ = check_scheme_arg (parser, @3,
2310                                        $3, $1, $2);
2311         }
2312         | function_arglist_common_reparse REPARSE multiplied_duration
2313         {
2314                 $$ = check_scheme_arg (parser, @3,
2315                                        $3, $1, $2);
2316         }
2317         | function_arglist_common_reparse REPARSE reparsed_rhythm
2318         {
2319                 $$ = check_scheme_arg (parser, @3,
2320                                        $3, $1, $2);
2321         }
2322         | function_arglist_common_reparse REPARSE symbol_list_arg
2323         {
2324                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
2325         }
2326         ;
2327
2328 function_arglist_common_reparse:
2329         EXPECT_SCM function_arglist_optional SCM_IDENTIFIER
2330         {
2331                 $$ = $2;
2332                 SCM res = try_string_variants ($1, $3);
2333                 if (!SCM_UNBNDP (res))
2334                         if (scm_is_pair (res))
2335                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
2336                         else
2337                                 MYREPARSE (@3, $1, SCM_ARG, res);
2338                 else if (scm_is_true
2339                          (scm_call_1
2340                           ($1, make_music_from_simple (parser, @3, $3))))
2341                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
2342                 else
2343                         // This is going to flag a syntax error, we
2344                         // know the predicate to be false.
2345                         MYREPARSE (@3, $1, SCM_ARG, $3);
2346         }
2347         | EXPECT_SCM function_arglist_optional pitch
2348         {
2349                 $$ = $2;
2350                 if (scm_is_true
2351                     (scm_call_1
2352                      ($1, make_music_from_simple
2353                       (parser, @3, $3))))
2354                         MYREPARSE (@3, $1, PITCH_IDENTIFIER, $3);
2355                 else
2356                         MYREPARSE (@3, $1, SCM_ARG, $3);
2357         }
2358         | EXPECT_SCM function_arglist_optional steno_tonic_pitch
2359         {
2360                 $$ = $2;
2361                 if (scm_is_true
2362                     (scm_call_1
2363                      ($1, make_music_from_simple
2364                       (parser, @3, $3))))
2365                         MYREPARSE (@3, $1, TONICNAME_PITCH, $3);
2366                 else
2367                         MYREPARSE (@3, $1, SCM_ARG, $3);
2368         }
2369         | EXPECT_SCM function_arglist_optional STRING
2370         {
2371                 $$ = $2;
2372                 SCM res = try_string_variants ($1, $3);
2373                 if (!SCM_UNBNDP (res))
2374                         if (scm_is_pair (res))
2375                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
2376                         else
2377                                 MYREPARSE (@3, $1, SCM_ARG, res);
2378                 else if (scm_is_true
2379                          (scm_call_1
2380                           ($1, make_music_from_simple (parser, @3, $3))))
2381                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
2382                 else
2383                         // This is going to flag a syntax error, we
2384                         // know the predicate to be false.
2385                         MYREPARSE (@3, $1, SCM_ARG, $3);
2386         }
2387         | EXPECT_SCM function_arglist_optional full_markup
2388         {
2389                 $$ = $2;
2390                 if (scm_is_true (scm_call_1 ($1, $3)))
2391                         MYREPARSE (@3, $1, SCM_ARG, $3);
2392                 else if (scm_is_true
2393                          (scm_call_1
2394                           ($1, make_music_from_simple (parser, @3, $3))))
2395                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
2396                 else
2397                         // This is going to flag a syntax error, we
2398                         // know the predicate to be false.
2399                         MYREPARSE (@3, $1, SCM_ARG, $3);
2400         }
2401         | EXPECT_SCM function_arglist_optional UNSIGNED
2402         {
2403                 $$ = $2;
2404                 if (scm_is_true (scm_call_1 ($1, $3)))
2405                         // May be 3 \cm or similar
2406                         MYREPARSE (@3, $1, REAL, $3);
2407                 else if (scm_is_true (scm_call_1 ($1, scm_list_1 ($3))))
2408                         MYREPARSE (@3, $1, SYMBOL_LIST, scm_list_1 ($3));
2409                 else {
2410                         SCM d = make_duration ($3);
2411                         if (!SCM_UNBNDP (d)) {
2412                                 if (scm_is_true (scm_call_1 ($1, d)))
2413                                         MYREPARSE (@3, $1, DURATION_IDENTIFIER, d);
2414                                 else if (scm_is_true
2415                                          (scm_call_1
2416                                           ($1, make_music_from_simple (parser, @3, d))))
2417                                         MYREPARSE (@3, $1, DURATION_ARG, d);
2418                                 else
2419                                         MYREPARSE (@3, $1, SCM_ARG, $3); // trigger error
2420                         } else
2421                                 MYREPARSE (@3, $1, SCM_ARG, $3); // trigger error
2422                 }
2423         }
2424         | EXPECT_SCM function_arglist_optional DURATION_IDENTIFIER
2425         {
2426                 $$ = $2;
2427                 if (scm_is_true (scm_call_1 ($1, $3)))
2428                         MYREPARSE (@3, $1, DURATION_IDENTIFIER, $3);
2429                 else if (scm_is_true
2430                          (scm_call_1
2431                           ($1, make_music_from_simple (parser, @3, $3))))
2432                         MYREPARSE (@3, $1, DURATION_ARG, $3);
2433                 else
2434                         MYREPARSE (@3, $1, SCM_ARG, $3); // trigger error
2435         }
2436         | EXPECT_SCM function_arglist_optional '-' UNSIGNED
2437         {
2438                 $$ = $2;
2439                 SCM n = scm_difference ($4, SCM_UNDEFINED);
2440                 if (scm_is_true (scm_call_1 ($1, n)))
2441                         MYREPARSE (@4, $1, REAL, n);
2442                 else {
2443                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @4);
2444                         t->set_property ("digit", $4);
2445                         SCM m = t->unprotect ();
2446                         if (scm_is_true (scm_call_1 ($1, m)))
2447                                 MYREPARSE (@4, $1, SCM_ARG, m);
2448                         else
2449                                 MYREPARSE (@4, $1, SCM_ARG, $4);
2450                 }
2451         }
2452         | EXPECT_SCM function_arglist_optional '-' REAL
2453         {
2454                 $$ = $2;
2455                 SCM n = scm_difference ($4, SCM_UNDEFINED);
2456                 MYREPARSE (@4, $1, REAL, n);
2457         }
2458         ;
2459
2460 function_arglist_optional:
2461         function_arglist_backup
2462         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_backup DEFAULT
2463         {
2464                 $$ = scm_cons (loc_on_music (parser, @4, $1), $3);
2465         }
2466         | function_arglist_skip_backup BACKUP
2467         ;
2468
2469 function_arglist_skip_backup:
2470         function_arglist_backup
2471         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_backup
2472         {
2473                 $$ = scm_cons (loc_on_music (parser, @3, $1), $3);
2474         }
2475         ;
2476
2477 music_function_call:
2478         MUSIC_FUNCTION function_arglist {
2479                 $$ = MAKE_SYNTAX (music_function, @$,
2480                                   $1, $2);
2481         }
2482         ;
2483
2484
2485 optional_id:
2486         /**/ { $$ = SCM_EOL; }
2487         | '=' simple_string {
2488                 $$ = $2;
2489         }
2490         ;
2491
2492 // We must not have lookahead tokens parsed in lyric mode.  In order
2493 // to save confusion, we take almost the same set as permitted with
2494 // \lyricmode and/or \lyrics.  However, music identifiers are also
2495 // allowed, and they obviously do not require switching into lyrics
2496 // mode for parsing.
2497
2498 lyric_mode_music:
2499         {
2500                 parser->lexer_->push_lyric_state ();
2501         } grouped_music_list
2502         {
2503                 parser->lexer_->pop_state ();
2504                 $$ = $2;
2505         }
2506         | MUSIC_IDENTIFIER
2507         ;
2508
2509 mode_changed_music:
2510         mode_changing_head grouped_music_list {
2511                 if (scm_is_eq ($1, ly_symbol2scm ("chords")))
2512                 {
2513                   $$ = MAKE_SYNTAX (unrelativable_music, @$, $2);
2514                 }
2515                 else
2516                 {
2517                   $$ = $2;
2518                 }
2519                 parser->lexer_->pop_state ();
2520         }
2521         | mode_changing_head_with_context optional_context_mods grouped_music_list {
2522                 $$ = MAKE_SYNTAX (context_specification, @$, $1, SCM_EOL, $2, SCM_BOOL_T, $3);
2523                 if (scm_is_eq ($1, ly_symbol2scm ("ChordNames")))
2524                 {
2525                   $$ = MAKE_SYNTAX (unrelativable_music, @$, $$);
2526                 }
2527                 parser->lexer_->pop_state ();
2528         }
2529         ;
2530
2531 mode_changing_head:
2532         NOTEMODE {
2533                 parser->lexer_->push_note_state (Lily::pitchnames);
2534
2535                 $$ = ly_symbol2scm ("notes");
2536         }
2537         | DRUMMODE
2538                 {
2539                 parser->lexer_->push_note_state (Lily::drum_pitch_names);
2540
2541                 $$ = ly_symbol2scm ("drums");
2542         }
2543         | FIGUREMODE {
2544                 parser->lexer_->push_figuredbass_state ();
2545
2546                 $$ = ly_symbol2scm ("figures");
2547         }
2548         | CHORDMODE {
2549                 parser->lexer_->chordmodifier_tab_ =
2550                         alist_to_hashq (Lily::chordmodifiers);
2551                 parser->lexer_->push_chord_state (Lily::pitchnames);
2552                 $$ = ly_symbol2scm ("chords");
2553
2554         }
2555         | LYRICMODE
2556                 { parser->lexer_->push_lyric_state ();
2557                 $$ = ly_symbol2scm ("lyrics");
2558         }
2559         ;
2560
2561 mode_changing_head_with_context:
2562         DRUMS {
2563                 parser->lexer_->push_note_state (Lily::drum_pitch_names);
2564
2565                 $$ = ly_symbol2scm ("DrumStaff");
2566         }
2567         | FIGURES {
2568                 parser->lexer_->push_figuredbass_state ();
2569
2570                 $$ = ly_symbol2scm ("FiguredBass");
2571         }
2572         | CHORDS {
2573                 parser->lexer_->chordmodifier_tab_ =
2574                         alist_to_hashq (Lily::chordmodifiers);
2575                 parser->lexer_->push_chord_state (Lily::pitchnames);
2576                 $$ = ly_symbol2scm ("ChordNames");
2577         }
2578         | LYRICS
2579                 { parser->lexer_->push_lyric_state ();
2580                 $$ = ly_symbol2scm ("Lyrics");
2581         }
2582         ;
2583
2584 context_change:
2585         CHANGE symbol '=' simple_string  {
2586                 $$ = MAKE_SYNTAX (context_change, @$, $2, $4);
2587         }
2588         ;
2589
2590
2591 property_path:
2592         symbol_list_rev  {
2593                 $$ = scm_reverse_x ($1, SCM_EOL);
2594         }
2595         ;
2596
2597 property_operation:
2598         symbol '=' scalar {
2599                 $$ = scm_list_3 (ly_symbol2scm ("assign"), $1, $3);
2600         }
2601         | UNSET symbol {
2602                 $$ = scm_list_2 (ly_symbol2scm ("unset"), $2);
2603         }
2604         | OVERRIDE revert_arg '=' scalar {
2605                 if (scm_ilength ($2) < 2) {
2606                         parser->parser_error (@2, _("bad grob property path"));
2607                         $$ = SCM_UNDEFINED;
2608                 } else {
2609                         $$ = scm_cons (ly_symbol2scm ("push"),
2610                                        scm_cons2 (scm_car ($2),
2611                                                   $4,
2612                                                   scm_cdr ($2)));
2613                 }
2614         }
2615         | REVERT revert_arg {
2616                 $$ = scm_cons (ly_symbol2scm ("pop"), $2);
2617         }
2618         ;
2619
2620 // This is all quite awkward for the sake of substantial backward
2621 // compatibility while at the same time allowing a more "natural" form
2622 // of specification not separating grob specification from grob
2623 // property path.  The purpose of this definition of revert_arg is to
2624 // allow the symbol list which specifies grob and property to revert
2625 // to be optionally be split into two parts after the grob (which in
2626 // this case is just the first element of the list).  symbol_list_part
2627 // is only one path component, but it can be parsed without lookahead,
2628 // so we can follow it with a synthetic BACKUP token when needed.  If
2629 // the first symbol_list_part already contains multiple elements (only
2630 // possible if a Scheme expression provides them), we just parse for
2631 // additional elements introduced by '.', which is what the
2632 // SYMBOL_LIST backup in connection with the immediately following
2633 // rule using symbol_list_arg does.
2634 //
2635 // As long as we don't have our coffers filled with both grob and at
2636 // least one grob property specification, the rest of the required
2637 // symbol list chain may be provided either with or without a leading
2638 // dot.  This is for both allowing the traditional
2639 // \revert Accidental #'color
2640 // as well as well as the "naive" form
2641 // \revert Accidental.color
2642
2643 revert_arg:
2644         revert_arg_backup BACKUP symbol_list_arg
2645         {
2646                 $$ = $3;
2647         }
2648         ;
2649
2650 revert_arg_backup:
2651         revert_arg_part
2652         {
2653                 if (scm_is_null ($1)
2654                     || scm_is_null (scm_cdr ($1)))
2655                         MYBACKUP (SCM_ARG, $1, @1);
2656                 else
2657                         MYBACKUP (SYMBOL_LIST, scm_reverse_x ($1, SCM_EOL), @1);
2658         }
2659         ;
2660
2661 // revert_arg_part delivers results in reverse
2662 revert_arg_part:
2663         symbol_list_part
2664         | revert_arg_backup BACKUP SCM_ARG '.' symbol_list_part
2665         {
2666                 $$ = scm_append_x (scm_list_2 ($5, $3));
2667         }
2668         | revert_arg_backup BACKUP SCM_ARG ',' symbol_list_part
2669         {
2670                 $$ = scm_append_x (scm_list_2 ($5, $3));
2671         }
2672         | revert_arg_backup BACKUP SCM_ARG symbol_list_part
2673         {
2674                 $$ = scm_append_x (scm_list_2 ($4, $3));
2675         }
2676         ;
2677
2678 context_def_mod:
2679         CONSISTS { $$ = ly_symbol2scm ("consists"); }
2680         | REMOVE { $$ = ly_symbol2scm ("remove"); }
2681
2682         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
2683         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
2684         | DENIES { $$ = ly_symbol2scm ("denies"); }
2685
2686         | ALIAS { $$ = ly_symbol2scm ("alias"); }
2687         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
2688         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
2689         | NAME { $$ = ly_symbol2scm ("context-name"); }
2690         ;
2691
2692 context_mod:
2693         property_operation { $$ = $1; }
2694         | context_def_mod STRING {
2695                 $$ = scm_list_2 ($1, $2);
2696         }
2697         | context_def_mod embedded_scm
2698         {
2699                 if (!scm_is_string ($2)
2700                     && ly_symbol2scm ("consists") != $1
2701                     && ly_symbol2scm ("remove") != $1)
2702                 {
2703                         $$ = SCM_EOL;
2704                         parser->parser_error (@1, _ ("only \\consists and \\remove take non-string argument."));
2705                 }
2706                 else
2707                 {
2708                         $$ = scm_list_2 ($1, $2);
2709                 }
2710         }
2711         ;
2712
2713 // If defined, at least two members.
2714 grob_prop_spec:
2715         symbol_list_rev
2716         {
2717                 SCM l = scm_reverse_x ($1, SCM_EOL);
2718                 if (scm_is_pair (l)
2719                     && to_boolean
2720                     (scm_object_property (scm_car (l),
2721                                           ly_symbol2scm ("is-grob?"))))
2722                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2723                 if (scm_is_null (l) || scm_is_null (scm_cdr (l))) {
2724                         parser->parser_error (@1, _ ("bad grob property path"));
2725                         l = SCM_UNDEFINED;
2726                 }
2727                 $$ = l;
2728         }
2729         ;
2730
2731 // If defined, at least three members
2732 grob_prop_path:
2733         grob_prop_spec
2734         {
2735                 if (!SCM_UNBNDP ($1) && scm_is_null (scm_cddr ($1)))
2736                 {
2737                         parser->parser_error (@1, _ ("bad grob property path"));
2738                         $$ = SCM_UNDEFINED;
2739                 }
2740         }
2741         | grob_prop_spec property_path
2742         {
2743                 if (!SCM_UNBNDP ($1)) {
2744                         $$ = scm_append_x (scm_list_2 ($1, $2));
2745                         if (scm_is_null (scm_cddr ($$))) {
2746                                 parser->parser_error (@$, _ ("bad grob property path"));
2747                                 $$ = SCM_UNDEFINED;
2748                         }
2749                 }
2750
2751         }
2752         ;
2753
2754 // Exactly two elements or undefined
2755 context_prop_spec:
2756         symbol_list_rev
2757         {
2758                 SCM l = scm_reverse_x ($1, SCM_EOL);
2759                 switch (scm_ilength (l)) {
2760                 case 1:
2761                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2762                 case 2:
2763                         break;
2764                 default:
2765                         parser->parser_error (@1, _ ("bad context property path"));
2766                         l = SCM_UNDEFINED;
2767                 }
2768                 $$ = l;
2769         }
2770         ;
2771
2772
2773 // This is all quite awkward for the sake of substantial backward
2774 // compatibility while at the same time allowing a more "natural" form
2775 // of specification not separating grob specification from grob
2776 // property path.  The purpose of this definition of
2777 // simple_revert_context is to allow the symbol list which specifies
2778 // grob and property to revert to be optionally be split into two
2779 // parts after the grob (which may be preceded by a context
2780 // specification, a case which we distinguish by checking whether the
2781 // first symbol is a valid grob symbol instead).
2782 //
2783 // See revert_arg above for the main work horse of this arrangement.
2784 // simple_revert_context just caters for the context and delegates the
2785 // rest of the job to revert_arg.
2786
2787 simple_revert_context:
2788         symbol_list_part
2789         {
2790                 $1 = scm_reverse_x ($1, SCM_EOL);
2791                 if (scm_is_null ($1)
2792                     || to_boolean
2793                     (scm_object_property (scm_car ($1),
2794                                           ly_symbol2scm ("is-grob?")))) {
2795                         $$ = ly_symbol2scm ("Bottom");
2796                         parser->lexer_->push_extra_token (@1, SCM_IDENTIFIER, $1);
2797                 } else {
2798                         $$ = scm_car ($1);
2799                         parser->lexer_->push_extra_token (@1, SCM_IDENTIFIER,
2800                                                           scm_cdr ($1));
2801                 }
2802         }
2803         ;
2804
2805 music_property_def:
2806         OVERRIDE grob_prop_path '=' scalar {
2807                 if (SCM_UNBNDP ($2))
2808                         $$ = MAKE_SYNTAX (void_music, @$);
2809                 else
2810                         $$ = MAKE_SYNTAX (property_override, @$,
2811                                           scm_car ($2),
2812                                           scm_cdr ($2),
2813                                           $4);
2814         }
2815         | REVERT simple_revert_context revert_arg {
2816                 $$ = MAKE_SYNTAX (property_revert, @$, $2, $3);
2817         }
2818         | SET context_prop_spec '=' scalar {
2819                 if (SCM_UNBNDP ($2))
2820                         $$ = MAKE_SYNTAX (void_music, @$);
2821                 else
2822                         $$ = MAKE_SYNTAX (property_set, @$,
2823                                           scm_car ($2),
2824                                           scm_cadr ($2),
2825                                           $4);
2826         }
2827         | UNSET context_prop_spec {
2828                 if (SCM_UNBNDP ($2))
2829                         $$ = MAKE_SYNTAX (void_music, @$);
2830                 else
2831                         $$ = MAKE_SYNTAX (property_unset, @$,
2832                                           scm_car ($2),
2833                                           scm_cadr ($2));
2834         }
2835         ;
2836
2837 string:
2838         STRING
2839         | full_markup
2840         ;
2841
2842 text:
2843         STRING
2844         | full_markup
2845         | embedded_scm_bare
2846         {
2847                 if (Text_interface::is_markup ($1)) {
2848                         $$ = $1;
2849                 } else {
2850                         parser->parser_error (@1, (_ ("markup expected")));
2851                         $$ = scm_string (SCM_EOL);
2852                 }
2853         }
2854         ;
2855
2856 simple_string: STRING
2857         | embedded_scm_bare
2858         {
2859                 if (scm_is_string ($1)) {
2860                         $$ = $1;
2861                 } else {
2862                         parser->parser_error (@1, (_ ("simple string expected")));
2863                         $$ = scm_string (SCM_EOL);
2864                 }
2865         }
2866         ;
2867
2868 symbol:
2869         STRING {
2870                 $$ = scm_string_to_symbol ($1);
2871         }
2872         | embedded_scm_bare
2873         {
2874                 // This is a bit of overkill but makes the same
2875                 // routine responsible for all symbol interpretations.
2876                 $$ = try_string_variants (Guile_user::symbol_p, $1);
2877                 if (SCM_UNBNDP ($$))
2878                 {
2879                         parser->parser_error (@1, (_ ("symbol expected")));
2880                         // Generate a unique symbol in case it is used
2881                         // for an assignment or similar
2882                         $$ = scm_make_symbol (ly_string2scm ("undefined"));
2883                 }
2884         }
2885         ;
2886
2887 scalar:
2888         embedded_scm_arg
2889         | pitch_or_music
2890         | SCM_IDENTIFIER
2891         | bare_number
2892         // The following is a rather defensive variant of admitting
2893         // negative numbers: the grammar would permit number_factor or
2894         // even number_expression.  However, function arguments allow
2895         // only this simple kind of negative number, so to have things
2896         // like \tweak and \override behave reasonably similar, it
2897         // makes sense to rule out things like -- which are rather an
2898         // accent in function argument contexts.
2899         | '-' bare_number
2900         {
2901                 $$ = scm_difference ($2, SCM_UNDEFINED);
2902         }
2903         | string
2904         | symbol_list_part_bare '.' property_path
2905         {
2906                 $$ = scm_reverse_x ($1, $3);
2907         }
2908         | symbol_list_part_bare ',' property_path
2909         {
2910                 $$ = scm_reverse_x ($1, $3);
2911         }
2912         ;
2913
2914 event_chord:
2915         simple_element post_events {
2916                 // Let the rhythmic music iterator sort this mess out.
2917                 if (scm_is_pair ($2)) {
2918                         unsmob<Music> ($$)->set_property ("articulations",
2919                                                          scm_reverse_x ($2, SCM_EOL));
2920                 }
2921         } %prec ':'
2922         | CHORD_REPETITION optional_notemode_duration post_events {
2923                 Input i;
2924                 i.set_location (@1, @3);
2925                 $$ = MAKE_SYNTAX (repetition_chord, i,
2926                                   $2, scm_reverse_x ($3, SCM_EOL));
2927         } %prec ':'
2928         | MULTI_MEASURE_REST optional_notemode_duration post_events {
2929                 Input i;
2930                 i.set_location (@1, @3);
2931                 $$ = MAKE_SYNTAX (multi_measure_rest, i, $2,
2932                                   scm_reverse_x ($3, SCM_EOL));
2933         } %prec ':'
2934         | tempo_event
2935         | note_chord_element
2936         ;
2937
2938
2939 note_chord_element:
2940         chord_body optional_notemode_duration post_events
2941         {
2942                 Music *m = unsmob<Music> ($1);
2943                 SCM dur = unsmob<Duration> ($2)->smobbed_copy ();
2944                 SCM es = m->get_property ("elements");
2945                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
2946
2947                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
2948                   unsmob<Music> (scm_car (s))->set_property ("duration", dur);
2949                 es = ly_append2 (es, postevs);
2950
2951                 m->set_property ("elements", es);
2952                 m->set_spot (parser->lexer_->override_input (@$));
2953                 $$ = m->self_scm ();
2954         } %prec ':'
2955         ;
2956
2957 chord_body:
2958         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
2959         {
2960                 $$ = MAKE_SYNTAX (event_chord, @$, scm_reverse_x ($2, SCM_EOL));
2961         }
2962         | FIGURE_OPEN figure_list FIGURE_CLOSE
2963         {
2964                 $$ = MAKE_SYNTAX (event_chord, @$, scm_reverse_x ($2, SCM_EOL));
2965         }
2966         ;
2967
2968 chord_body_elements:
2969         /* empty */             { $$ = SCM_EOL; }
2970         | chord_body_elements chord_body_element {
2971                 if (!SCM_UNBNDP ($2))
2972                         $$ = scm_cons ($2, $1);
2973         }
2974         ;
2975
2976 chord_body_element:
2977         pitch_or_tonic_pitch exclamations questions octave_check post_events
2978         {
2979                 bool q = to_boolean ($3);
2980                 bool ex = to_boolean ($2);
2981                 SCM check = $4;
2982                 SCM post = $5;
2983
2984                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2985                 n->set_property ("pitch", $1);
2986                 if (q)
2987                         n->set_property ("cautionary", SCM_BOOL_T);
2988                 if (ex || q)
2989                         n->set_property ("force-accidental", SCM_BOOL_T);
2990
2991                 if (scm_is_pair (post)) {
2992                         SCM arts = scm_reverse_x (post, SCM_EOL);
2993                         n->set_property ("articulations", arts);
2994                 }
2995                 if (scm_is_number (check))
2996                 {
2997                         int q = scm_to_int (check);
2998                         n->set_property ("absolute-octave", scm_from_int (q-1));
2999                 }
3000
3001                 $$ = n->unprotect ();
3002         }
3003         | DRUM_PITCH post_events {
3004                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
3005                 n->set_property ("drum-type", $1);
3006
3007                 if (scm_is_pair ($2)) {
3008                         SCM arts = scm_reverse_x ($2, SCM_EOL);
3009                         n->set_property ("articulations", arts);
3010                 }
3011                 $$ = n->unprotect ();
3012         }
3013         | music_function_chord_body
3014         {
3015                 Music *m = unsmob<Music> ($1);
3016
3017                 while (m && m->is_mus_type ("music-wrapper-music")) {
3018                         $$ = m->get_property ("element");
3019                         m = unsmob<Music> ($$);
3020                 }
3021
3022                 if (!(m && m->is_mus_type ("rhythmic-event"))) {
3023                         parser->parser_error (@$, _ ("not a rhythmic event"));
3024                         $$ = SCM_UNDEFINED;
3025                 }
3026         }
3027         ;
3028
3029 music_function_chord_body:
3030         music_function_call
3031         | MUSIC_IDENTIFIER
3032         | embedded_scm
3033         ;
3034
3035 event_function_event:
3036         EVENT_FUNCTION function_arglist {
3037                 $$ = MAKE_SYNTAX (music_function, @$,
3038                                   $1, $2);
3039         }
3040         ;
3041
3042 post_events:
3043         /* empty */ {
3044                 $$ = SCM_EOL;
3045         }
3046         | post_events post_event {
3047                 $$ = $1;
3048                 if (Music *m = unsmob<Music> ($2))
3049                 {
3050                         if (m->is_mus_type ("post-event-wrapper"))
3051                         {
3052                                 for (SCM p = m->get_property ("elements");
3053                                      scm_is_pair (p);
3054                                      p = scm_cdr (p))
3055                                 {
3056                                         $$ = scm_cons (scm_car (p), $$);
3057                                 }
3058                         } else {
3059                                 m->set_spot (parser->lexer_->override_input (@2));
3060                                 $$ = scm_cons ($2, $$);
3061                         }
3062                 }
3063         }
3064         ;
3065
3066 post_event_nofinger:
3067         direction_less_event {
3068                 $$ = $1;
3069         }
3070         | script_dir music_function_call {
3071                 $$ = $2;
3072                 if (!unsmob<Music> ($2)->is_mus_type ("post-event")) {
3073                         parser->parser_error (@2, _ ("post-event expected"));
3074                         $$ = SCM_UNSPECIFIED;
3075                 } else if (!SCM_UNBNDP ($1))
3076                 {
3077                         unsmob<Music> ($$)->set_property ("direction", $1);
3078                 }
3079         }
3080         | HYPHEN {
3081                 if (!parser->lexer_->is_lyric_state ())
3082                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
3083                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
3084         }
3085         | EXTENDER {
3086                 if (!parser->lexer_->is_lyric_state ())
3087                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
3088                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
3089         }
3090         | script_dir direction_reqd_event {
3091                 if (!SCM_UNBNDP ($1))
3092                 {
3093                         Music *m = unsmob<Music> ($2);
3094                         m->set_property ("direction", $1);
3095                 }
3096                 $$ = $2;
3097         }
3098         | script_dir direction_less_event {
3099                 if (!SCM_UNBNDP ($1))
3100                 {
3101                         Music *m = unsmob<Music> ($2);
3102                         m->set_property ("direction", $1);
3103                 }
3104                 $$ = $2;
3105         }
3106         | '^' fingering
3107         {
3108                 $$ = $2;
3109                 unsmob<Music> ($$)->set_property ("direction", scm_from_int (UP));
3110         }
3111         | '_' fingering
3112         {
3113                 $$ = $2;
3114                 unsmob<Music> ($$)->set_property ("direction", scm_from_int (DOWN));
3115         }
3116         ;
3117
3118 post_event:
3119         post_event_nofinger
3120         | '-' fingering {
3121                 $$ = $2;
3122         }
3123         ;
3124
3125 string_number_event:
3126         E_UNSIGNED {
3127                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
3128                 s->set_property ("string-number", $1);
3129                 $$ = s->unprotect ();
3130         }
3131         ;
3132
3133 direction_less_event:
3134         string_number_event
3135         | EVENT_IDENTIFIER      {
3136                 $$ = $1;
3137         }
3138         | tremolo_type  {
3139                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
3140                a->set_property ("tremolo-type", $1);
3141                $$ = a->unprotect ();
3142         }
3143         | event_function_event
3144         ;
3145
3146 direction_reqd_event:
3147         gen_text_def {
3148                 $$ = $1;
3149         }
3150         | script_abbreviation {
3151                 SCM s = parser->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
3152                 if (scm_is_string (s)) {
3153                         Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
3154                         a->set_property ("articulation-type", s);
3155                         $$ = a->unprotect ();
3156                 } else {
3157                         Music *original = unsmob<Music> (s);
3158                         if (original && original->is_mus_type ("post-event")) {
3159                                 Music *a = original->clone ();
3160                                 a->set_spot (parser->lexer_->override_input (@$));
3161                                 $$ = a->unprotect ();
3162                         } else {
3163                                 parser->parser_error (@1, _ ("expecting string or post-event as script definition"));
3164                                 $$ = MY_MAKE_MUSIC ("PostEvents", @$)->unprotect ();
3165                         }
3166                 }
3167         }
3168         ;
3169
3170 octave_check:
3171         /**/ { $$ = SCM_EOL; }
3172         | '=' quotes { $$ = $2; }
3173         ;
3174
3175 quotes:
3176         /* empty */
3177         {
3178                 $$ = SCM_INUM0;
3179         }
3180         | sub_quotes
3181         | sup_quotes
3182         ;
3183
3184 sup_quotes:
3185         '\'' {
3186                 $$ = scm_from_int (1);
3187         }
3188         | sup_quotes '\'' {
3189                 $$ = scm_oneplus ($1);
3190         }
3191         ;
3192
3193 sub_quotes:
3194         ',' {
3195                 $$ = scm_from_int (-1);
3196         }
3197         | sub_quotes ',' {
3198                 $$ = scm_oneminus ($1);
3199         }
3200         ;
3201
3202 steno_pitch:
3203         NOTENAME_PITCH quotes {
3204                 if (!scm_is_eq (SCM_INUM0, $2))
3205                 {
3206                         Pitch p = *unsmob<Pitch> ($1);
3207                         p = p.transposed (Pitch (scm_to_int ($2), 0));
3208                         $$ = p.smobbed_copy ();
3209                 }
3210         }
3211         ;
3212
3213 /*
3214 ugh. duplication
3215 */
3216
3217 steno_tonic_pitch:
3218         TONICNAME_PITCH quotes {
3219                 if (!scm_is_eq (SCM_INUM0, $2))
3220                 {
3221                         Pitch p = *unsmob<Pitch> ($1);
3222                         p = p.transposed (Pitch (scm_to_int ($2), 0));
3223                         $$ = p.smobbed_copy ();
3224                 }
3225         }
3226         ;
3227
3228 pitch:
3229         steno_pitch
3230         | PITCH_IDENTIFIER quotes {
3231                 if (!scm_is_eq (SCM_INUM0, $2))
3232                 {
3233                         Pitch p = *unsmob<Pitch> ($1);
3234                         p = p.transposed (Pitch (scm_to_int ($2), 0));
3235                         $$ = p.smobbed_copy ();
3236                 }
3237         }
3238         ;
3239
3240 pitch_or_tonic_pitch:
3241         pitch
3242         | steno_tonic_pitch
3243         ;
3244
3245 gen_text_def:
3246         full_markup {
3247                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
3248                 t->set_property ("text", $1);
3249                 $$ = t->unprotect ();
3250         }
3251         | STRING {
3252                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
3253                 t->set_property ("text",
3254                         make_simple_markup ($1));
3255                 $$ = t->unprotect ();
3256         }
3257         | embedded_scm
3258         {
3259                 Music *m = unsmob<Music> ($1);
3260                 if (m && m->is_mus_type ("post-event"))
3261                         $$ = $1;
3262                 else if (Text_interface::is_markup ($1)) {
3263                         Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
3264                         t->set_property ("text", $1);
3265                         $$ = t->unprotect ();
3266                 } else
3267                         parser->parser_error (@1, _ ("not an articulation"));
3268         }
3269         ;
3270
3271 fingering:
3272         UNSIGNED {
3273                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
3274                 t->set_property ("digit", $1);
3275                 $$ = t->unprotect ();
3276         }
3277         ;
3278
3279 script_abbreviation:
3280         '^'             {
3281                 $$ = scm_from_ascii_string ("Hat");
3282         }
3283         | '+'           {
3284                 $$ = scm_from_ascii_string ("Plus");
3285         }
3286         | '-'           {
3287                 $$ = scm_from_ascii_string ("Dash");
3288         }
3289         | '!'           {
3290                 $$ = scm_from_ascii_string ("Bang");
3291         }
3292         | ANGLE_CLOSE   {
3293                 $$ = scm_from_ascii_string ("Larger");
3294         }
3295         | '.'           {
3296                 $$ = scm_from_ascii_string ("Dot");
3297         }
3298         | '_' {
3299                 $$ = scm_from_ascii_string ("Underscore");
3300         }
3301         ;
3302
3303 script_dir:
3304         '_'     { $$ = scm_from_int (DOWN); }
3305         | '^'   { $$ = scm_from_int (UP); }
3306         | '-'   { $$ = SCM_UNDEFINED; }
3307         ;
3308
3309 maybe_notemode_duration:
3310         {
3311                 $$ = SCM_UNDEFINED;
3312         } %prec ':'
3313         | multiplied_duration   {
3314                 $$ = $1;
3315                 parser->default_duration_ = *unsmob<Duration> ($$);
3316         }
3317 ;
3318
3319
3320 optional_notemode_duration:
3321         maybe_notemode_duration
3322         {
3323                 if (SCM_UNBNDP ($$))
3324                         $$ = parser->default_duration_.smobbed_copy ();
3325         }
3326         ;
3327
3328 steno_duration:
3329         UNSIGNED dots           {
3330                 $$ = make_duration ($1, scm_to_int ($2));
3331                 if (SCM_UNBNDP ($$))
3332                 {
3333                         parser->parser_error (@1, _ ("not a duration"));
3334                         $$ = Duration ().smobbed_copy ();
3335                 }
3336         }
3337         | DURATION_IDENTIFIER dots      {
3338                 $$ = make_duration ($1, scm_to_int ($2));
3339         }
3340         ;
3341
3342 multiplied_duration:
3343         steno_duration multipliers {
3344                 $$ = make_duration ($1, 0, $2);
3345         }
3346         ;
3347
3348 dots:
3349         /* empty */     {
3350                 $$ = SCM_INUM0;
3351         }
3352         | dots '.' {
3353                 $$ = scm_oneplus ($1);
3354         }
3355         ;
3356
3357 multipliers:
3358         /* empty */
3359         {
3360                 $$ = SCM_UNDEFINED;
3361         }
3362         | multipliers '*' UNSIGNED
3363         {
3364                 if (!SCM_UNBNDP ($1))
3365                         $$ = scm_product ($1, $3);
3366                 else
3367                         $$ = $3;
3368         }
3369         | multipliers '*' FRACTION
3370         {
3371                 if (!SCM_UNBNDP ($1))
3372                         $$ = scm_product ($1, scm_divide (scm_car ($3),
3373                                                           scm_cdr ($3)));
3374                 else
3375                         $$ = scm_divide (scm_car ($3), scm_cdr ($3));
3376         }
3377         ;
3378
3379 tremolo_type:
3380         ':'     {
3381                 $$ = scm_from_int (parser->default_tremolo_type_);
3382         }
3383         | ':' UNSIGNED {
3384                 if (SCM_UNBNDP (make_duration ($2))) {
3385                         parser->parser_error (@2, _ ("not a duration"));
3386                         $$ = scm_from_int (parser->default_tremolo_type_);
3387                 } else {
3388                         $$ = $2;
3389                         parser->default_tremolo_type_ = scm_to_int ($2);
3390                 }
3391         }
3392         ;
3393
3394 bass_number:
3395         UNSIGNED { $$ = $1; }
3396         | STRING { $$ = $1; }
3397         | full_markup { $$ = $1; }
3398         | embedded_scm_bare
3399         {
3400                 // as an integer, it needs to be non-negative, and otherwise
3401                 // it needs to be suitable as a markup.
3402                 if (scm_is_integer ($1)
3403                     ? scm_is_true (scm_negative_p ($1))
3404                     : !Text_interface::is_markup ($1))
3405                 {
3406                         parser->parser_error (@1, _ ("bass number expected"));
3407                         $$ = SCM_INUM0;
3408                 }
3409         }
3410         ;
3411
3412 figured_bass_alteration:
3413         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
3414         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
3415         | '!'   { $$ = scm_from_int (0); }
3416         ;
3417
3418 bass_figure:
3419         FIGURE_SPACE {
3420                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
3421                 $$ = bfr->unprotect ();
3422         }
3423         | bass_number  {
3424                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
3425                 $$ = bfr->self_scm ();
3426
3427                 if (scm_is_number ($1))
3428                         bfr->set_property ("figure", $1);
3429                 else if (Text_interface::is_markup ($1))
3430                         bfr->set_property ("text", $1);
3431
3432                 bfr->unprotect ();
3433         }
3434         | bass_figure ']' {
3435                 $$ = $1;
3436                 unsmob<Music> ($1)->set_property ("bracket-stop", SCM_BOOL_T);
3437         }
3438         | bass_figure figured_bass_alteration {
3439                 Music *m = unsmob<Music> ($1);
3440                 if (scm_to_double ($2)) {
3441                         SCM salter = m->get_property ("alteration");
3442                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
3443                         m->set_property ("alteration",
3444                                          scm_sum (alter, $2));
3445                 } else {
3446                         m->set_property ("alteration", scm_from_int (0));
3447                 }
3448         }
3449         | bass_figure figured_bass_modification  {
3450                 Music *m = unsmob<Music> ($1);
3451                 m->set_property ($2, SCM_BOOL_T);
3452         }
3453         ;
3454
3455
3456 figured_bass_modification:
3457         E_PLUS          {
3458                 $$ = ly_symbol2scm ("augmented");
3459         }
3460         | E_EXCLAMATION {
3461                 $$ = ly_symbol2scm ("no-continuation");
3462         }
3463         | '/'           {
3464                 $$ = ly_symbol2scm ("diminished");
3465         }
3466         | E_BACKSLASH {
3467                 $$ = ly_symbol2scm ("augmented-slash");
3468         }
3469         ;
3470
3471 br_bass_figure:
3472         bass_figure {
3473                 $$ = $1;
3474         }
3475         | '[' bass_figure {
3476                 $$ = $2;
3477                 unsmob<Music> ($$)->set_property ("bracket-start", SCM_BOOL_T);
3478         }
3479         ;
3480
3481 figure_list:
3482         /**/            {
3483                 $$ = SCM_EOL;
3484         }
3485         | figure_list br_bass_figure {
3486                 $$ = scm_cons ($2, $1);
3487         }
3488         ;
3489
3490 optional_rest:
3491         /**/   { $$ = SCM_BOOL_F; }
3492         | REST { $$ = SCM_BOOL_T; }
3493         ;
3494
3495 pitch_or_music:
3496         pitch exclamations questions octave_check maybe_notemode_duration optional_rest post_events {
3497                 if (!parser->lexer_->is_note_state ())
3498                         parser->parser_error (@1, _ ("have to be in Note mode for notes"));
3499                 if (!SCM_UNBNDP ($2)
3500                     || !SCM_UNBNDP ($3)
3501                     || scm_is_number ($4)
3502                     || !SCM_UNBNDP ($5)
3503                     || scm_is_true ($6)
3504                     || scm_is_pair ($7))
3505                 {
3506                         Music *n = 0;
3507                         if (scm_is_true ($6))
3508                                 n = MY_MAKE_MUSIC ("RestEvent", @$);
3509                         else
3510                                 n = MY_MAKE_MUSIC ("NoteEvent", @$);
3511
3512                         n->set_property ("pitch", $1);
3513                         if (SCM_UNBNDP ($5))
3514                                 n->set_property ("duration",
3515                                                  parser->default_duration_.smobbed_copy ());
3516                         else
3517                                 n->set_property ("duration", $5);
3518
3519                         if (scm_is_number ($4))
3520                         {
3521                                 int q = scm_to_int ($4);
3522                                 n->set_property ("absolute-octave", scm_from_int (q-1));
3523                         }
3524
3525                         if (to_boolean ($3))
3526                                 n->set_property ("cautionary", SCM_BOOL_T);
3527                         if (to_boolean ($2) || to_boolean ($3))
3528                                 n->set_property ("force-accidental", SCM_BOOL_T);
3529                         if (scm_is_pair ($7))
3530                                 n->set_property ("articulations",
3531                                                  scm_reverse_x ($7, SCM_EOL));
3532                         $$ = n->unprotect ();
3533                 }
3534         } %prec ':'
3535         | new_chord post_events {
3536                 if (!parser->lexer_->is_chord_state ())
3537                         parser->parser_error (@1, _ ("have to be in Chord mode for chords"));
3538                 if (scm_is_pair ($2)) {
3539                         if (unsmob<Pitch> ($1))
3540                                 $1 = make_chord_elements (@1,
3541                                                           $1,
3542                                                           parser->default_duration_.smobbed_copy (),
3543                                                           SCM_EOL);
3544
3545                         SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
3546
3547                         $$ = MAKE_SYNTAX (event_chord, @1, elts);
3548                 } else if (!unsmob<Pitch> ($1))
3549                         $$ = MAKE_SYNTAX (event_chord, @1, $1);
3550                 // A mere pitch drops through.
3551         } %prec ':'
3552         ;
3553
3554 simple_element:
3555         DRUM_PITCH optional_notemode_duration {
3556                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
3557                 n->set_property ("duration", $2);
3558                 n->set_property ("drum-type", $1);
3559
3560                 $$ = n->unprotect ();
3561         }
3562         | RESTNAME optional_notemode_duration           {
3563                 Music *ev = 0;
3564                 if (ly_scm2string ($1) == "s") {
3565                         /* Space */
3566                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
3567                   }
3568                 else {
3569                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
3570
3571                     }
3572                 ev->set_property ("duration", $2);
3573                 $$ = ev->unprotect ();
3574         }
3575         ;
3576
3577 lyric_element:
3578         full_markup {
3579                 if (!parser->lexer_->is_lyric_state ())
3580                         parser->parser_error (@1, _ ("markup outside of text script or \\lyricmode"));
3581                 $$ = $1;
3582         }
3583         | STRING {
3584                 if (!parser->lexer_->is_lyric_state ())
3585                         parser->parser_error (@1, _ ("unrecognized string, not in text script or \\lyricmode"));
3586                 $$ = $1;
3587         }
3588         | LYRIC_ELEMENT
3589         ;
3590
3591 lyric_element_music:
3592         lyric_element optional_notemode_duration post_events {
3593                 $$ = MAKE_SYNTAX (lyric_event, @$, $1, $2);
3594                 if (scm_is_pair ($3))
3595                         unsmob<Music> ($$)->set_property
3596                                 ("articulations", scm_reverse_x ($3, SCM_EOL));
3597         } %prec ':'
3598         ;
3599
3600 // Can return a single pitch rather than a list.
3601 new_chord:
3602         steno_tonic_pitch maybe_notemode_duration   {
3603                 if (SCM_UNBNDP ($2))
3604                         $$ = $1;
3605                 else
3606                         $$ = make_chord_elements (@$, $1, $2, SCM_EOL);
3607         }
3608         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
3609                 SCM its = scm_reverse_x ($4, SCM_EOL);
3610                 $$ = make_chord_elements (@$, $1, $2, scm_cons ($3, its));
3611         } %prec ':'
3612         ;
3613
3614 chord_items:
3615         /**/ {
3616                 $$ = SCM_EOL;
3617         }
3618         | chord_items chord_item {
3619                 $$ = scm_cons ($2, $$);
3620         }
3621         ;
3622
3623 chord_separator:
3624         CHORD_COLON {
3625                 $$ = ly_symbol2scm ("chord-colon");
3626         }
3627         | CHORD_CARET {
3628                 $$ = ly_symbol2scm ("chord-caret");
3629         }
3630         | CHORD_SLASH steno_tonic_pitch {
3631                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
3632         }
3633         | CHORD_BASS steno_tonic_pitch {
3634                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
3635         }
3636         ;
3637
3638 chord_item:
3639         chord_separator {
3640                 $$ = $1;
3641         }
3642         | step_numbers {
3643                 $$ = scm_reverse_x ($1, SCM_EOL);
3644         }
3645         | CHORD_MODIFIER  {
3646                 $$ = $1;
3647         }
3648         ;
3649
3650 step_numbers:
3651         step_number { $$ = scm_cons ($1, SCM_EOL); }
3652         | step_numbers '.' step_number {
3653                 $$ = scm_cons ($3, $$);
3654         }
3655         ;
3656
3657 step_number:
3658         UNSIGNED {
3659                 $$ = make_chord_step ($1, 0);
3660         }
3661         | UNSIGNED '+' {
3662                 $$ = make_chord_step ($1, SHARP_ALTERATION);
3663         }
3664         | UNSIGNED CHORD_MINUS {
3665                 $$ = make_chord_step ($1, FLAT_ALTERATION);
3666         }
3667         ;
3668
3669 tempo_range:
3670         unsigned_number {
3671                 $$ = $1;
3672         } %prec ':'
3673         | unsigned_number '-' unsigned_number {
3674                 $$ = scm_cons ($1, $3);
3675         }
3676         ;
3677
3678 /*
3679         UTILITIES
3680
3681 TODO: should deprecate in favor of Scheme?
3682
3683  */
3684 number_expression:
3685         number_expression '+' number_term {
3686                 $$ = scm_sum ($1, $3);
3687         }
3688         | number_expression '-' number_term {
3689                 $$ = scm_difference ($1, $3);
3690         }
3691         | number_term
3692         ;
3693
3694 number_term:
3695         number_factor {
3696                 $$ = $1;
3697         }
3698         | number_factor '*' number_factor {
3699                 $$ = scm_product ($1, $3);
3700         }
3701         | number_factor '/' number_factor {
3702                 $$ = scm_divide ($1, $3);
3703         }
3704         ;
3705
3706 number_factor:
3707         '-'  number_factor { /* %prec UNARY_MINUS */
3708                 $$ = scm_difference ($2, SCM_UNDEFINED);
3709         }
3710         | bare_number
3711         ;
3712
3713 bare_number_common:
3714         REAL
3715         | NUMBER_IDENTIFIER
3716         | REAL NUMBER_IDENTIFIER
3717         {
3718                 $$ = scm_product ($1, $2);
3719         }
3720         ;
3721
3722 bare_number:
3723         bare_number_common
3724         | UNSIGNED
3725         | UNSIGNED NUMBER_IDENTIFIER    {
3726                 $$ = scm_product ($1, $2);
3727         }
3728         ;
3729
3730 unsigned_number:
3731         UNSIGNED
3732         | NUMBER_IDENTIFIER
3733         {
3734                 if (!scm_is_integer ($1)
3735                     || scm_is_true (scm_negative_p ($1)))
3736                 {
3737                         parser->parser_error (@1, _("not an unsigned integer"));
3738                         $$ = SCM_INUM0;
3739                 }
3740         }
3741         | embedded_scm
3742         {
3743                 if (!scm_is_integer ($1)
3744                     || scm_is_true (scm_negative_p ($1)))
3745                 {
3746                         parser->parser_error (@1, _("not an unsigned integer"));
3747                         $$ = SCM_INUM0;
3748                 }
3749         }
3750         ;
3751
3752 exclamations:
3753                 { $$ = SCM_UNDEFINED; }
3754         | exclamations '!'
3755         {
3756                 if (SCM_UNBNDP ($1))
3757                         $$ = SCM_BOOL_T;
3758                 else
3759                         $$ = scm_not ($1);
3760         }
3761         ;
3762
3763 questions:
3764 // This precedence rule is rather weird.  It triggers when '!' is
3765 // encountered after a pitch, and is used for deciding whether to save
3766 // this instead for a figure modification.  This should not actually
3767 // occur in practice as pitches and figures are generated in different
3768 // modes.  Using a greedy (%right) precedence makes sure that we don't
3769 // get stuck in a wrong interpretation.
3770         { $$ = SCM_UNDEFINED; } %prec ':'
3771         | questions '?'
3772         {
3773                 if (SCM_UNBNDP ($1))
3774                         $$ = SCM_BOOL_T;
3775                 else
3776                         $$ = scm_not ($1);
3777         }
3778         ;
3779
3780 full_markup_list:
3781         MARKUPLIST
3782                 { parser->lexer_->push_markup_state (); }
3783         markup_list {
3784                 $$ = $3;
3785                 parser->lexer_->pop_state ();
3786         }
3787         ;
3788
3789 markup_mode:
3790         MARKUP
3791         {
3792                 parser->lexer_->push_markup_state ();
3793         }
3794         ;
3795
3796 full_markup:
3797         markup_mode markup_top {
3798                 $$ = $2;
3799                 parser->lexer_->pop_state ();
3800         }
3801         ;
3802
3803 partial_markup:
3804         markup_mode markup_partial_function ETC
3805         {
3806                 $$ = MAKE_SYNTAX (partial_markup, @2, $2);
3807                 parser->lexer_->pop_state ();
3808         }
3809         ;
3810
3811 markup_top:
3812         markup_list {
3813                 $$ = scm_list_2 (Lily::line_markup,  $1);
3814         }
3815         | markup_head_1_list simple_markup
3816         {
3817                 $$ = scm_car (MAKE_SYNTAX (composed_markup_list,
3818                                            @2, $1, scm_list_1 ($2)));
3819         }
3820         | simple_markup {
3821                 $$ = $1;
3822         }
3823         ;
3824
3825 markup_scm:
3826         embedded_scm
3827         {
3828                 if (Text_interface::is_markup ($1))
3829                         MYBACKUP (MARKUP_IDENTIFIER, $1, @1);
3830                 else if (Text_interface::is_markup_list ($1))
3831                         MYBACKUP (MARKUPLIST_IDENTIFIER, $1, @1);
3832                 else {
3833                         parser->parser_error (@1, _ ("not a markup"));
3834                         MYBACKUP (MARKUP_IDENTIFIER, scm_string (SCM_EOL), @1);
3835                 }
3836         } BACKUP
3837         ;
3838
3839
3840 markup_list:
3841         markup_composed_list {
3842                 $$ = $1;
3843         }
3844         | markup_uncomposed_list
3845         ;
3846
3847 markup_uncomposed_list:
3848         markup_braced_list {
3849                 $$ = $1;
3850         }
3851         | markup_command_list {
3852                 $$ = scm_list_1 ($1);
3853         }
3854         | markup_scm MARKUPLIST_IDENTIFIER
3855         {
3856                 $$ = $2;
3857         }
3858         | SCORELINES {
3859                 parser->lexer_->push_note_state (Lily::pitchnames);
3860         } '{' score_body '}' {
3861                 Score *sc = unsmob<Score> ($4);
3862                 sc->origin ()->set_spot (@$);
3863                 if (sc->defs_.empty ()) {
3864                         Output_def *od = get_layout (parser);
3865                         sc->add_output_def (od);
3866                         od->unprotect ();
3867                 }
3868                 $$ = scm_list_1 (scm_list_2 (Lily::score_lines_markup_list, $4));
3869                 parser->lexer_->pop_state ();
3870         }
3871         ;
3872
3873 markup_composed_list:
3874         markup_head_1_list markup_uncomposed_list {
3875                 $$ = MAKE_SYNTAX (composed_markup_list,
3876                                   @2, $1, $2);
3877         }
3878         ;
3879
3880 markup_braced_list:
3881         '{' markup_braced_list_body '}' {
3882                 $$ = scm_reverse_x ($2, SCM_EOL);
3883         }
3884         ;
3885
3886 markup_braced_list_body:
3887         /* empty */     {  $$ = SCM_EOL; }
3888         | markup_braced_list_body markup {
3889                 $$ = scm_cons ($2, $1);
3890         }
3891         | markup_braced_list_body markup_list {
3892                 $$ = scm_reverse_x ($2, $1);
3893         }
3894         ;
3895
3896 markup_command_list:
3897         MARKUP_LIST_FUNCTION markup_command_list_arguments {
3898           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
3899         }
3900         ;
3901
3902 markup_command_basic_arguments:
3903         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
3904           $$ = scm_cons ($3, $2);
3905         }
3906         | EXPECT_SCM markup_command_list_arguments embedded_scm {
3907           $$ = check_scheme_arg (parser, @3, $3, $2, $1);
3908         }
3909         | EXPECT_NO_MORE_ARGS {
3910           $$ = SCM_EOL;
3911         }
3912         ;
3913
3914 markup_command_list_arguments:
3915         markup_command_basic_arguments { $$ = $1; }
3916         | EXPECT_MARKUP markup_command_list_arguments markup {
3917           $$ = scm_cons ($3, $2);
3918         }
3919         ;
3920
3921 markup_partial_function:
3922         MARKUP_FUNCTION markup_arglist_partial
3923         {
3924                 $$ = scm_list_1 (scm_cons ($1, scm_reverse_x ($2, SCM_EOL)));
3925         }
3926         | markup_head_1_list MARKUP_FUNCTION markup_arglist_partial
3927         {
3928                 $$ = scm_cons (scm_cons ($2, scm_reverse_x ($3, SCM_EOL)),
3929                                $1);
3930         }
3931         ;
3932
3933 markup_arglist_partial:
3934         EXPECT_MARKUP markup_arglist_partial
3935         {
3936                 $$ = $2;
3937         }
3938         | EXPECT_SCM markup_arglist_partial
3939         {
3940                 $$= $2;
3941         }
3942         | EXPECT_MARKUP markup_command_list_arguments
3943         {
3944                 $$ = $2;
3945         }
3946         | EXPECT_SCM markup_command_list_arguments
3947         {
3948                 $$ = $2;
3949         }
3950         ;
3951
3952 markup_head_1_item:
3953         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
3954           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
3955         }
3956         ;
3957
3958 markup_head_1_list:
3959         markup_head_1_item      {
3960                 $$ = scm_list_1 ($1);
3961         }
3962         | markup_head_1_list markup_head_1_item {
3963                 $$ = scm_cons ($2, $1);
3964         }
3965         ;
3966
3967 simple_markup:
3968         STRING {
3969                 $$ = make_simple_markup ($1);
3970         }
3971         | SCORE {
3972                 parser->lexer_->push_note_state (Lily::pitchnames);
3973         } '{' score_body '}' {
3974                 Score *sc = unsmob<Score> ($4);
3975                 sc->origin ()->set_spot (@$);
3976                 if (sc->defs_.empty ()) {
3977                         Output_def *od = get_layout (parser);
3978                         sc->add_output_def (od);
3979                         od->unprotect ();
3980                 }
3981                 $$ = scm_list_2 (Lily::score_markup, $4);
3982                 parser->lexer_->pop_state ();
3983         }
3984         | MARKUP_FUNCTION markup_command_basic_arguments {
3985                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
3986         }
3987         | markup_scm MARKUP_IDENTIFIER
3988         {
3989                 $$ = $2;
3990         }
3991         ;
3992
3993 markup:
3994         markup_head_1_list simple_markup
3995         {
3996                 $$ = scm_car (MAKE_SYNTAX (composed_markup_list,
3997                                            @2, $1, scm_list_1 ($2)));
3998         }
3999         | simple_markup {
4000                 $$ = $1;
4001         }
4002         ;
4003
4004 %%
4005
4006 void
4007 Lily_parser::set_yydebug (bool x)
4008 {
4009         yydebug = x;
4010 }
4011
4012 SCM
4013 Lily_parser::do_yyparse ()
4014 {
4015         return scm_c_with_fluid (Lily::f_parser,
4016                                  self_scm (),
4017                                  do_yyparse_trampoline,
4018                                  static_cast <void *>(this));
4019 }
4020
4021 SCM
4022 Lily_parser::do_yyparse_trampoline (void *parser)
4023 {
4024         SCM retval = SCM_UNDEFINED;
4025         yyparse (static_cast <Lily_parser *>(parser), &retval);
4026         return retval;
4027 }
4028
4029
4030
4031 /*
4032
4033 It is a little strange to have this function in this file, but
4034 otherwise, we have to import music classes into the lexer.
4035
4036 */
4037 int
4038 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
4039 {
4040         if (unsmob<Book> (sid)) {
4041                 Book *book =  unsmob<Book> (sid)->clone ();
4042                 *destination = book->self_scm ();
4043                 book->unprotect ();
4044
4045                 return BOOK_IDENTIFIER;
4046         } else if (scm_is_number (sid)) {
4047                 *destination = sid;
4048                 return NUMBER_IDENTIFIER;
4049         } else if (unsmob<Context_def> (sid))
4050         {
4051                 *destination = unsmob<Context_def> (sid)->clone ()->unprotect ();
4052                 return SCM_IDENTIFIER;
4053         } else if (unsmob<Context_mod> (sid)) {
4054                 *destination = unsmob<Context_mod> (sid)->smobbed_copy ();
4055                 return CONTEXT_MOD_IDENTIFIER;
4056         } else if (Music *mus = unsmob<Music> (sid)) {
4057                 mus = mus->clone ();
4058                 *destination = mus->self_scm ();
4059                 bool is_event = mus->is_mus_type ("post-event");
4060                 mus->unprotect ();
4061                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
4062         } else if (unsmob<Pitch> (sid)) {
4063                 *destination = unsmob<Pitch> (sid)->smobbed_copy ();
4064                 return PITCH_IDENTIFIER;
4065         } else if (unsmob<Duration> (sid)) {
4066                 *destination = unsmob<Duration> (sid)->smobbed_copy ();
4067                 return DURATION_IDENTIFIER;
4068         } else if (unsmob<Output_def> (sid)) {
4069                 *destination = unsmob<Output_def> (sid)->clone ()->unprotect ();
4070                 return SCM_IDENTIFIER;
4071         } else if (unsmob<Score> (sid)) {
4072                 *destination = unsmob<Score> (sid)->clone ()->unprotect ();
4073                 return SCM_IDENTIFIER;
4074         } else if (scm_is_pair (sid)
4075                    && scm_is_pair (scm_car (sid))
4076                    && scm_is_true (Lily::key_p (scm_caar (sid)))) {
4077                 *destination = sid;
4078                 return LOOKUP_IDENTIFIER;
4079         }
4080         return -1;
4081 }
4082
4083 SCM
4084 get_next_unique_context_id ()
4085 {
4086         return scm_from_ascii_string ("$uniqueContextId");
4087 }
4088
4089
4090 SCM
4091 get_next_unique_lyrics_context_id ()
4092 {
4093         static int new_context_count;
4094         char s[128];
4095         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
4096         return scm_from_ascii_string (s);
4097 }
4098
4099 // check_scheme_arg checks one argument with a given predicate for use
4100 // in an argument list and throws a syntax error if it is unusable.
4101 // The argument is prepended to the argument list in any case.  After
4102 // throwing a syntax error, the argument list is terminated with #f as
4103 // its last cdr in order to mark it as uncallable while not losing
4104 // track of its total length.
4105 //
4106 // There are a few special considerations: if optional argument disp
4107 // is given (otherwise it defaults to SCM_UNDEFINED), it will be used
4108 // instead of arg in a prospective error message.  This is useful if
4109 // arg is not the actual argument but rather a transformation of it.
4110 //
4111 // If arg itself is SCM_UNDEFINED, the predicate is considered false
4112 // and an error message using disp is produced unconditionally.
4113
4114 SCM check_scheme_arg (Lily_parser *parser, Input loc,
4115                       SCM arg, SCM args, SCM pred, SCM disp)
4116 {
4117         if (SCM_UNBNDP (arg))
4118                 args = scm_cons (disp, args);
4119         else {
4120                 args = scm_cons (arg, args);
4121                 if (scm_is_true (scm_call_1 (pred, arg)))
4122                         return args;
4123         }
4124         scm_set_cdr_x (scm_last_pair (args), SCM_EOL);
4125         MAKE_SYNTAX (argument_error, loc, scm_length (args), pred,
4126                      SCM_UNBNDP (disp) ? arg : disp);
4127         scm_set_cdr_x (scm_last_pair (args), SCM_BOOL_F);
4128         return args;
4129 }
4130
4131 SCM loc_on_music (Lily_parser *parser, Input loc, SCM arg)
4132 {
4133         if (Music *m = unsmob<Music> (arg))
4134         {
4135                 m = m->clone ();
4136                 m->set_spot (parser->lexer_->override_input (loc));
4137                 return m->unprotect ();
4138         }
4139         return arg;
4140 }
4141
4142 SCM
4143 try_string_variants (SCM pred, SCM str)
4144 {
4145         // a matching predicate is always ok
4146         if (scm_is_true (scm_call_1 (pred, str)))
4147                 return str;
4148         // a symbol may be interpreted as a list of symbols if it helps
4149         if (scm_is_true (Lily::key_p (str))) {
4150                 str = scm_list_1 (str);
4151                 if (scm_is_true (scm_call_1 (pred, str)))
4152                         return str;
4153                 return SCM_UNDEFINED;
4154         }
4155
4156         // If this cannot be a string representation of a symbol list,
4157         // we are through.
4158
4159         if (!is_regular_identifier (str, true))
4160                 return SCM_UNDEFINED;
4161
4162         str = scm_string_split (str, SCM_MAKE_CHAR ('.'));
4163         for (SCM p = str; scm_is_pair (p); p = scm_cdr (p))
4164                 scm_set_car_x (p, scm_string_split (scm_car (p),
4165                                                     SCM_MAKE_CHAR (',')));
4166         str = scm_append_x (str);
4167         for (SCM p = str; scm_is_pair (p); p = scm_cdr (p))
4168                 scm_set_car_x (p, scm_string_to_symbol (scm_car (p)));
4169
4170         // Let's attempt the symbol list interpretation first.
4171
4172         if (scm_is_true (scm_call_1 (pred, str)))
4173                 return str;
4174
4175         // If there is just one symbol in the list, we might interpret
4176         // it as a single symbol
4177
4178         if (scm_is_null (scm_cdr (str)))
4179         {
4180                 str = scm_car (str);
4181                 if (scm_is_true (scm_call_1 (pred, str)))
4182                         return str;
4183         }
4184
4185         return SCM_UNDEFINED;
4186 }
4187
4188 bool
4189 is_regular_identifier (SCM id, bool multiple)
4190 {
4191   if (!scm_is_string (id))
4192           return false;
4193
4194   string str = ly_scm2string (id);
4195
4196   bool middle = false;
4197
4198   for (string::iterator it=str.begin(); it != str.end (); it++)
4199   {
4200           int c = *it & 0xff;
4201           if ((c >= 'a' && c <= 'z')
4202               || (c >= 'A' && c <= 'Z')
4203               || c > 0x7f)
4204                   middle = true;
4205           else if (middle && (c == '-' || c == '_' || (multiple &&
4206                                                        (c == '.' || c == ','))))
4207                   middle = false;
4208           else
4209                   return false;
4210   }
4211   return middle;
4212 }
4213
4214 SCM
4215 make_music_from_simple (Lily_parser *parser, Input loc, SCM simple)
4216 {
4217         if (unsmob<Music> (simple))
4218                 return simple;
4219         if (parser->lexer_->is_note_state ()) {
4220                 if (scm_is_symbol (simple)) {
4221                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
4222                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
4223                         n->set_property ("drum-type", simple);
4224                         return n->unprotect ();
4225                 }
4226                 if (unsmob<Pitch> (simple)) {
4227                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
4228                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
4229                         n->set_property ("pitch", simple);
4230                         return n->unprotect ();
4231                 }
4232                 SCM d = simple;
4233                 if (scm_is_integer (simple))
4234                         d = make_duration (simple);
4235                 if (unsmob<Duration> (d)) {
4236                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
4237                         n->set_property ("duration", d);
4238                         return n->unprotect ();
4239                 }
4240                 return simple;
4241         } else if (parser->lexer_->is_lyric_state ()) {
4242                 if (Text_interface::is_markup (simple))
4243                         return MAKE_SYNTAX (lyric_event, loc, simple,
4244                                             parser->default_duration_.smobbed_copy ());
4245         } else if (parser->lexer_->is_chord_state ()) {
4246                 if (unsmob<Pitch> (simple))
4247                         return MAKE_SYNTAX
4248                                 (event_chord,
4249                                  loc,
4250                                  make_chord_elements (loc, simple,
4251                                                       parser->default_duration_.smobbed_copy (),
4252                                                       SCM_EOL));
4253         }
4254         return simple;
4255 }
4256
4257 Music *
4258 make_music_with_input (SCM name, Input where)
4259 {
4260        Music *m = make_music_by_name (name);
4261        m->set_spot (where);
4262        return m;
4263 }
4264
4265 SCM
4266 make_simple_markup (SCM a)
4267 {
4268         return a;
4269 }
4270
4271 SCM
4272 make_duration (SCM d, int dots, SCM factor)
4273 {
4274         Duration k;
4275
4276         if (Duration *dur = unsmob<Duration> (d)) {
4277                 if (!dots && SCM_UNBNDP (factor))
4278                         return d;
4279                 k = *dur;
4280                 if (dots)
4281                         k = Duration (k.duration_log (), k.dot_count () + dots)
4282                                 .compressed (k.factor ());
4283         } else {
4284                 int t = scm_to_int (d);
4285                 if (t > 0 && (t & (t-1)) == 0)
4286                         k = Duration (intlog2 (t), dots);
4287                 else
4288                         return SCM_UNDEFINED;
4289         }
4290
4291         if (!SCM_UNBNDP (factor))
4292                 k = k.compressed (ly_scm2rational (factor));
4293
4294         return k.smobbed_copy ();
4295 }
4296
4297 SCM
4298 make_chord_step (SCM step_scm, Rational alter)
4299 {
4300         Pitch m (0, scm_to_int (step_scm) - 1, alter);
4301
4302         // Notename/octave are normalized
4303         if (m.get_notename () == 6)
4304                 m = m.transposed (Pitch (0, 0, FLAT_ALTERATION));
4305
4306         return m.smobbed_copy ();
4307 }
4308
4309
4310 SCM
4311 make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list)
4312 {
4313         SCM res = Lily::construct_chord_elements (pitch, dur, modification_list);
4314         for (SCM s = res; scm_is_pair (s); s = scm_cdr (s))
4315         {
4316                 unsmob<Music> (scm_car (s))->set_spot (loc);
4317         }
4318         return res;
4319 }
4320
4321 int
4322 yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser)
4323 {
4324         Lily_lexer *lex = parser->lexer_;
4325
4326         lex->lexval_ = s;
4327         lex->lexloc_ = loc;
4328         int tok = lex->pop_extra_token ();
4329         if (tok >= 0)
4330                 return tok;
4331         lex->prepare_for_next_token ();
4332         return lex->yylex ();
4333 }