lily/parser.yy

   1 /* -*- mode: c++; c-file-style: "linux"; indent-tabs-mode: t -*- */
   2 /*
   3   This file is part of LilyPond, the GNU music typesetter.
   4
   5   Copyright (C) 1997--2014 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6                  Jan Nieuwenhuizen <janneke@gnu.org>
   7
   8   LilyPond is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   LilyPond is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  20 */
  21
  22 /* Mode and indentation are at best a rough approximation based on TAB
  23  * formatting (reasonable for compatibility with unspecific editor
  24  * modes as Bison modes are hard to find) and need manual correction
  25  * frequently.  Without a reasonably dependable way of formatting a
  26  * Bison file sensibly, there is little point in trying to fix the
  27  * inconsistent state of indentation.
  28  */
  29
  30 %{
  31
  32 #define yyerror Lily_parser::parser_error
  33
  34 /* We use custom location type: Input objects */
  35 #define YYLTYPE Input
  36 #define YYSTYPE SCM
  37 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  38         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  39
  40 #define YYPRINT(file, type, value)                                      \
  41         do {                                                            \
  42                 if (scm_is_eq (value, SCM_UNSPECIFIED))                 \
  43                         break;                                          \
  44                 SCM s = scm_call_2 (ly_lily_module_constant ("value->lily-string"), \
  45                                     value,                              \
  46                                     parser->self_scm ());               \
  47                 char *p = scm_to_locale_string (s);                     \
  48                 fputs (p, file);                                        \
  49                 free (p);                                               \
  50         } while (0)
  51
  52 %}
  53
  54 %parse-param {Lily_parser *parser}
  55 %parse-param {SCM *retval}
  56 %lex-param {Lily_parser *parser}
  57 %error-verbose
  58 %debug
  59
  60 /* We use SCMs to do strings, because it saves us the trouble of
  61 deleting them.  Let's hope that a stack overflow doesn't trigger a move
  62 of the parse stack onto the heap. */
  63
  64 %left PREC_BOT
  65 %nonassoc REPEAT
  66 %nonassoc ALTERNATIVE
  67
  68 /* The above precedences tackle the shift/reduce problem
  69
  70 1.  \repeat
  71         \repeat .. \alternative
  72
  73     \repeat { \repeat .. \alternative }
  74
  75 or
  76
  77     \repeat { \repeat } \alternative
  78 */
  79
  80 %nonassoc COMPOSITE
  81 %left ADDLYRICS
  82
  83 %right ':' UNSIGNED REAL E_UNSIGNED EVENT_IDENTIFIER EVENT_FUNCTION '^' '_'
  84        HYPHEN EXTENDER DURATION_IDENTIFIER '!'
  85
  86  /* The above are needed for collecting tremoli and other items (that
  87     could otherwise be interpreted as belonging to the next function
  88     argument) greedily, and together with the next rule will serve to
  89     join numbers and units greedily instead of allowing them into
  90     separate function arguments
  91  */
  92
  93 %nonassoc NUMBER_IDENTIFIER
  94
  95 %left PREC_TOP
  96
  97
  98
  99
 100 %pure-parser
 101 %locations
 102
 103
 104
 105 %{ // -*-Fundamental-*-
 106
 107 /*
 108 FIXME:
 109
 110    * The rules for who is protecting what are very shady.  Uniformise
 111      this.
 112
 113    * There are too many lexical modes?
 114 */
 115
 116 #include "config.hh"
 117
 118 #include <cctype>
 119 #include <cstdlib>
 120 #include <cstdio>
 121 using namespace std;
 122
 123 #include "book.hh"
 124 #include "context-def.hh"
 125 #include "context-mod.hh"
 126 #include "dimensions.hh"
 127 #include "file-path.hh"
 128 #include "input.hh"
 129 #include "international.hh"
 130 #include "lily-guile.hh"
 131 #include "lily-lexer.hh"
 132 #include "lily-parser.hh"
 133 #include "main.hh"
 134 #include "misc.hh"
 135 #include "music.hh"
 136 #include "output-def.hh"
 137 #include "paper-book.hh"
 138 #include "scm-hash.hh"
 139 #include "score.hh"
 140 #include "text-interface.hh"
 141 #include "warn.hh"
 142
 143 void
 144 Lily_parser::parser_error (Input const *i, Lily_parser *parser, SCM *, const string &s)
 145 {
 146         parser->parser_error (*i, s);
 147 }
 148
 149 // The following are somewhat precarious constructs as they may change
 150 // the value of the lookahead token.  That implies that the lookahead
 151 // token must not yet have made an impact on the state stack other
 152 // than causing the reduction of the current rule, or switching the
 153 // lookahead token while Bison is mulling it over will cause trouble.
 154
 155 #define MYBACKUP(Token, Value, Location)                                \
 156         do {                                                            \
 157                 if (yychar != YYEMPTY)                                  \
 158                         parser->lexer_->push_extra_token                \
 159                                 (yylloc, yychar, yylval);               \
 160                 if (Token)                                              \
 161                         parser->lexer_->push_extra_token                \
 162                                 (Location, Token, Value);               \
 163                 parser->lexer_->push_extra_token (Location, BACKUP);    \
 164                 yychar = YYEMPTY;                                       \
 165         } while (0)
 166
 167
 168 #define MYREPARSE(Location, Pred, Token, Value)                         \
 169         do {                                                            \
 170                 if (yychar != YYEMPTY)                                  \
 171                         parser->lexer_->push_extra_token                \
 172                                 (yylloc, yychar, yylval);               \
 173                 parser->lexer_->push_extra_token                        \
 174                         (Location, Token, Value);                       \
 175                 parser->lexer_->push_extra_token                        \
 176                         (Location, REPARSE, Pred);                      \
 177                 yychar = YYEMPTY;                                       \
 178         } while (0)
 179
 180 %}
 181
 182
 183 %{
 184
 185 #define MY_MAKE_MUSIC(x, spot) \
 186         make_music_with_input (ly_symbol2scm (x), \
 187                                parser->lexer_->override_input (spot))
 188
 189 /* ES TODO:
 190 - Don't use lily module, create a new module instead.
 191 - delay application of the function
 192 */
 193 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 194   scm_apply_0 (proc, args)
 195 /* Syntactic Sugar. */
 196 #define MAKE_SYNTAX(name, location, ...)                                \
 197         LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (parser->self_scm (), parser->lexer_->override_input (location).smobbed_copy (), ##__VA_ARGS__, SCM_UNDEFINED))
 198 #define START_MAKE_SYNTAX(name, ...)                                    \
 199         scm_list_n (ly_lily_module_constant (name) , ##__VA_ARGS__, SCM_UNDEFINED)
 200 #define FINISH_MAKE_SYNTAX(start, location, ...)                        \
 201         LOWLEVEL_MAKE_SYNTAX (scm_car (start), scm_cons2 (parser->self_scm (), parser->lexer_->override_input (location).smobbed_copy (), scm_append_x (scm_list_2 (scm_cdr (start), scm_list_n (__VA_ARGS__, SCM_UNDEFINED)))))
 202
 203 SCM get_next_unique_context_id ();
 204 SCM get_next_unique_lyrics_context_id ();
 205
 206 #undef _
 207 #if !HAVE_GETTEXT
 208 #define _(x) x
 209 #else
 210 #include <libintl.h>
 211 #define _(x) gettext (x)
 212 #endif
 213
 214
 215 static Music *make_music_with_input (SCM name, Input where);
 216 SCM check_scheme_arg (Lily_parser *parser, Input loc,
 217                       SCM arg, SCM args, SCM pred, SCM disp = SCM_UNDEFINED);
 218 SCM make_music_from_simple (Lily_parser *parser, Input loc, SCM pitch);
 219 SCM loc_on_music (Input loc, SCM arg);
 220 SCM make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list);
 221 SCM make_chord_step (SCM step, Rational alter);
 222 SCM make_simple_markup (SCM a);
 223 SCM make_duration (SCM t, int dots = 0);
 224 bool is_regular_identifier (SCM id, bool multiple=false);
 225 SCM try_string_variants (SCM pred, SCM str);
 226 int yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser);
 227
 228 %}
 229
 230 /* The third option is an alias that will be used to display the
 231    syntax error.  Bison CVS now correctly handles backslash escapes.
 232
 233    FIXME: Bison needs to translate some of these, eg, STRING.
 234
 235 */
 236
 237 /* Keyword tokens with plain escaped name.  */
 238 %token END_OF_FILE 0 "end of input"
 239 %token ACCEPTS "\\accepts"
 240 %token ADDLYRICS "\\addlyrics"
 241 %token ALIAS "\\alias"
 242 %token ALTERNATIVE "\\alternative"
 243 %token BOOK "\\book"
 244 %token BOOKPART "\\bookpart"
 245 %token CHANGE "\\change"
 246 %token CHORDMODE "\\chordmode"
 247 %token CHORDS "\\chords"
 248 %token CONSISTS "\\consists"
 249 %token CONTEXT "\\context"
 250 %token DEFAULT "\\default"
 251 %token DEFAULTCHILD "\\defaultchild"
 252 %token DENIES "\\denies"
 253 %token DESCRIPTION "\\description"
 254 %token DRUMMODE "\\drummode"
 255 %token DRUMS "\\drums"
 256 %token FIGUREMODE "\\figuremode"
 257 %token FIGURES "\\figures"
 258 %token HEADER "\\header"
 259 %token INVALID "\\version-error"
 260 %token LAYOUT "\\layout"
 261 %token LYRICMODE "\\lyricmode"
 262 %token LYRICS "\\lyrics"
 263 %token LYRICSTO "\\lyricsto"
 264 %token MARKUP "\\markup"
 265 %token MARKUPLIST "\\markuplist"
 266 %token MIDI "\\midi"
 267 %token NAME "\\name"
 268 %token NOTEMODE "\\notemode"
 269 %token OVERRIDE "\\override"
 270 %token PAPER "\\paper"
 271 %token REMOVE "\\remove"
 272 %token REPEAT "\\repeat"
 273 %token REST "\\rest"
 274 %token REVERT "\\revert"
 275 %token SCORE "\\score"
 276 %token SCORELINES "\\score-lines"
 277 %token SEQUENTIAL "\\sequential"
 278 %token SET "\\set"
 279 %token SIMULTANEOUS "\\simultaneous"
 280 %token TEMPO "\\tempo"
 281 %token TYPE "\\type"
 282 %token UNSET "\\unset"
 283 %token WITH "\\with"
 284
 285 /* Keyword token exceptions.  */
 286 %token NEWCONTEXT "\\new"
 287
 288
 289 /* Other string tokens.  */
 290
 291 %token CHORD_BASS "/+"
 292 %token CHORD_CARET "^"
 293 %token CHORD_COLON ":"
 294 %token CHORD_MINUS "-"
 295 %token CHORD_SLASH "/"
 296 %token ANGLE_OPEN "<"
 297 %token ANGLE_CLOSE ">"
 298 %token DOUBLE_ANGLE_OPEN "<<"
 299 %token DOUBLE_ANGLE_CLOSE ">>"
 300 %token E_BACKSLASH "\\"
 301 %token E_EXCLAMATION "\\!"
 302 %token E_PLUS "\\+"
 303 %token EXTENDER "__"
 304
 305 /*
 306 If we give names, Bison complains.
 307 */
 308 %token FIGURE_CLOSE /* "\\>" */
 309 %token FIGURE_OPEN /* "\\<" */
 310 %token FIGURE_SPACE "_"
 311 %token HYPHEN "--"
 312
 313 %token MULTI_MEASURE_REST
 314
 315
 316 %token E_UNSIGNED
 317 %token UNSIGNED
 318
 319 /* Artificial tokens, for more generic function syntax */
 320 %token EXPECT_MARKUP "markup?"
 321 %token EXPECT_SCM "scheme?"
 322 %token BACKUP "(backed-up?)"
 323 %token REPARSE "(reparsed?)"
 324 %token EXPECT_MARKUP_LIST "markup-list?"
 325 %token EXPECT_OPTIONAL "optional?"
 326 /* After the last argument. */
 327 %token EXPECT_NO_MORE_ARGS;
 328
 329 /* An artificial token for parsing embedded Lilypond */
 330 %token EMBEDDED_LILY "#{"
 331
 332 %token BOOK_IDENTIFIER
 333 %token CHORD_MODIFIER
 334 %token CHORD_REPETITION
 335 %token CONTEXT_MOD_IDENTIFIER
 336 %token DRUM_PITCH
 337 %token PITCH_IDENTIFIER
 338 %token DURATION_IDENTIFIER
 339 %token EVENT_IDENTIFIER
 340 %token EVENT_FUNCTION
 341 %token FRACTION
 342 %token LYRIC_ELEMENT
 343 %token MARKUP_FUNCTION
 344 %token MARKUP_LIST_FUNCTION
 345 %token MARKUP_IDENTIFIER
 346 %token MARKUPLIST_IDENTIFIER
 347 %token MUSIC_FUNCTION
 348 %token MUSIC_IDENTIFIER
 349 %token NOTENAME_PITCH
 350 %token NUMBER_IDENTIFIER
 351 %token REAL
 352 %token RESTNAME
 353 %token SCM_ARG
 354 %token SCM_FUNCTION
 355 %token SCM_IDENTIFIER
 356 %token SCM_TOKEN
 357 %token STRING
 358 %token SYMBOL_LIST
 359 %token TONICNAME_PITCH
 360
 361 %left '-' '+'
 362
 363 /* We don't assign precedence to / and *, because we might need varied
 364 prec levels in different prods */
 365
 366 %left UNARY_MINUS
 367
 368 %%
 369
 370 start_symbol:
 371         lilypond
 372         | EMBEDDED_LILY {
 373                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 374                 parser->lexer_->push_note_state (nn);
 375         } embedded_lilypond {
 376                 parser->lexer_->pop_state ();
 377                 *retval = $3;
 378         }
 379         ;
 380
 381 lilypond:       /* empty */ { $$ = SCM_UNSPECIFIED; }
 382         | lilypond toplevel_expression {
 383         }
 384         | lilypond assignment {
 385         }
 386         | lilypond error {
 387                 parser->error_level_ = 1;
 388         }
 389         | lilypond INVALID      {
 390                 parser->error_level_ = 1;
 391         }
 392         ;
 393
 394
 395 toplevel_expression:
 396         {
 397                 parser->lexer_->add_scope (get_header (parser));
 398         } lilypond_header {
 399                 parser->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $2);
 400         }
 401         | book_block {
 402                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-book-handler");
 403                 scm_call_2 (proc, parser->self_scm (), $1);
 404         }
 405         | bookpart_block {
 406                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 407                 scm_call_2 (proc, parser->self_scm (), $1);
 408         }
 409         | BOOK_IDENTIFIER {
 410                 SCM proc = parser->lexer_->lookup_identifier
 411                         (Book::unsmob($1)->paper_
 412                          ? "toplevel-book-handler"
 413                          : "toplevel-bookpart-handler");
 414                 scm_call_2 (proc, parser->self_scm (), $1);
 415         }
 416         | score_block {
 417                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-score-handler");
 418                 scm_call_2 (proc, parser->self_scm (), $1);
 419         }
 420         | composite_music {
 421                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-music-handler");
 422                 scm_call_2 (proc, parser->self_scm (), $1);
 423         }
 424         | full_markup {
 425                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 426                 scm_call_2 (proc, parser->self_scm (), scm_list_1 ($1));
 427         }
 428         | full_markup_list {
 429                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 430                 scm_call_2 (proc, parser->self_scm (), $1);
 431         }
 432         | SCM_TOKEN {
 433                 // Evaluate and ignore #xxx, as opposed to \xxx
 434                 parser->lexer_->eval_scm_token ($1, @1);
 435         }
 436         | embedded_scm_active
 437         {
 438                 SCM out = SCM_UNDEFINED;
 439                 if (Text_interface::is_markup ($1))
 440                         out = scm_list_1 ($1);
 441                 else if (Text_interface::is_markup_list ($1))
 442                         out = $1;
 443                 if (scm_is_pair (out))
 444                 {
 445                         SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 446                         scm_call_2 (proc, parser->self_scm (), out);
 447                 } else if (Score::unsmob ($1))
 448                 {
 449                         SCM proc = parser->lexer_->lookup_identifier ("toplevel-score-handler");
 450                         scm_call_2 (proc, parser->self_scm (), $1);
 451                 } else if (Output_def * od = Output_def::unsmob ($1)) {
 452                         SCM id = SCM_EOL;
 453
 454                         if (od->c_variable ("is-paper") == SCM_BOOL_T)
 455                                 id = ly_symbol2scm ("$defaultpaper");
 456                         else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 457                                 id = ly_symbol2scm ("$defaultmidi");
 458                         else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 459                                 id = ly_symbol2scm ("$defaultlayout");
 460
 461                         parser->lexer_->set_identifier (id, $1);
 462                 } else if (!scm_is_eq ($1, SCM_UNSPECIFIED))
 463                         parser->parser_error (@1, _("bad expression type"));
 464         }
 465         | output_def {
 466                 SCM id = SCM_EOL;
 467                 Output_def * od = Output_def::unsmob ($1);
 468
 469                 if (od->c_variable ("is-paper") == SCM_BOOL_T)
 470                         id = ly_symbol2scm ("$defaultpaper");
 471                 else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 472                         id = ly_symbol2scm ("$defaultmidi");
 473                 else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 474                         id = ly_symbol2scm ("$defaultlayout");
 475
 476                 parser->lexer_->set_identifier (id, $1);
 477         }
 478         ;
 479
 480 embedded_scm_bare:
 481         SCM_TOKEN
 482         {
 483                 $$ = parser->lexer_->eval_scm_token ($1, @1);
 484         }
 485         | SCM_IDENTIFIER
 486         ;
 487
 488 embedded_scm_active:
 489         SCM_IDENTIFIER
 490         | scm_function_call
 491         ;
 492
 493 embedded_scm_bare_arg:
 494         SCM_ARG
 495         | SCM_TOKEN
 496         {
 497                 $$ = parser->lexer_->eval_scm_token ($1, @1);
 498         }
 499         | FRACTION
 500         | full_markup_list
 501         | context_modification
 502         | score_block
 503         | context_def_spec_block
 504         | book_block
 505         | bookpart_block
 506         | output_def
 507         ;
 508
 509 /* The generic version may end in music, or not */
 510
 511 embedded_scm:
 512         embedded_scm_bare
 513         | scm_function_call
 514         ;
 515
 516 /* embedded_scm_arg is _not_ casting pitches to music by default, this
 517  * has to be done by the function itself.  Note that this may cause
 518  * the results of scm_function_call or embedded_scm_bare_arg to be
 519  * turned into music from pitches as well.  Note that this creates a
 520  * distinctly awkward situation for calculated drum pitches.  Those
 521  * are at the current point of time rejected as music constituents as
 522  * they can't be distinguished from "proper" symbols.
 523  */
 524
 525 embedded_scm_arg:
 526         embedded_scm_bare_arg
 527         | scm_function_call
 528         | music_assign
 529         ;
 530
 531 scm_function_call:
 532         SCM_FUNCTION function_arglist {
 533                 $$ = MAKE_SYNTAX ("music-function", @$,
 534                                          $1, $2);
 535         }
 536         ;
 537
 538 embedded_lilypond_number:
 539         '-' embedded_lilypond_number
 540         {
 541                 $$ = scm_difference ($2, SCM_UNDEFINED);
 542         }
 543         | bare_number_common
 544         | UNSIGNED NUMBER_IDENTIFIER
 545         {
 546                 $$ = scm_product ($1, $2);
 547         }
 548         ;
 549
 550 embedded_lilypond:
 551         /* empty */
 552         {
 553                 // FIXME: @$ does not contain a useful source location
 554                 // for empty rules, and the only token in the whole
 555                 // production, EMBEDDED_LILY, is synthetic and also
 556                 // contains no source location.
 557                 $$ = MAKE_SYNTAX ("void-music", @$);
 558         }
 559         | identifier_init_nonumber
 560         | embedded_lilypond_number
 561         | post_event post_events
 562         {
 563                 $$ = scm_reverse_x ($2, SCM_EOL);
 564                 if (Music *m = Music::unsmob ($1))
 565                 {
 566                         if (m->is_mus_type ("post-event-wrapper"))
 567                                 $$ = scm_append
 568                                         (scm_list_2 (m->get_property ("elements"),
 569                                                      $$));
 570                         else
 571                                 $$ = scm_cons ($1, $$);
 572                 }
 573                 if (scm_is_pair ($$)
 574                     && scm_is_null (scm_cdr ($$)))
 575                         $$ = scm_car ($$);
 576                 else
 577                 {
 578                         Music * m = MY_MAKE_MUSIC ("PostEvents", @$);
 579                         m->set_property ("elements", $$);
 580                         $$ = m->unprotect ();
 581                 }
 582         }
 583         | multiplied_duration
 584         | music_embedded music_embedded music_list {
 585                 $3 = scm_reverse_x ($3, SCM_EOL);
 586                 if (Music::unsmob ($2))
 587                         $3 = scm_cons ($2, $3);
 588                 if (Music::unsmob ($1))
 589                         $3 = scm_cons ($1, $3);
 590                 $$ = MAKE_SYNTAX ("sequential-music", @$, $3);
 591         }
 592         | error {
 593                 parser->error_level_ = 1;
 594                 $$ = SCM_UNSPECIFIED;
 595         }
 596         | INVALID embedded_lilypond {
 597                 parser->error_level_ = 1;
 598                 $$ = $2;
 599         }
 600         ;
 601
 602
 603 lilypond_header_body:
 604         /* empty */ { $$ = SCM_UNSPECIFIED; }
 605         | lilypond_header_body assignment  {
 606
 607         }
 608         | lilypond_header_body embedded_scm  {
 609
 610         }
 611         ;
 612
 613 lilypond_header:
 614         HEADER '{' lilypond_header_body '}'     {
 615                 $$ = parser->lexer_->remove_scope ();
 616         }
 617         ;
 618
 619 /*
 620         DECLARATIONS
 621 */
 622 assignment_id:
 623         STRING          { $$ = $1; }
 624         ;
 625
 626 assignment:
 627         assignment_id '=' identifier_init  {
 628                 parser->lexer_->set_identifier ($1, $3);
 629                 $$ = SCM_UNSPECIFIED;
 630         }
 631         | assignment_id property_path '=' identifier_init {
 632                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 633                 parser->lexer_->set_identifier (path, $4);
 634                 $$ = SCM_UNSPECIFIED;
 635         }
 636         | assignment_id '.' property_path '=' identifier_init {
 637                 SCM path = scm_cons (scm_string_to_symbol ($1), $3);
 638                 parser->lexer_->set_identifier (path, $5);
 639                 $$ = SCM_UNSPECIFIED;
 640         }
 641         ;
 642
 643
 644 identifier_init:
 645         identifier_init_nonumber
 646         | number_expression
 647         | post_event_nofinger post_events
 648         {
 649                 $$ = scm_reverse_x ($2, SCM_EOL);
 650                 if (Music *m = Music::unsmob ($1))
 651                 {
 652                         if (m->is_mus_type ("post-event-wrapper"))
 653                                 $$ = scm_append
 654                                         (scm_list_2 (m->get_property ("elements"),
 655                                                      $$));
 656                         else
 657                                 $$ = scm_cons ($1, $$);
 658                 }
 659                 if (scm_is_pair ($$)
 660                     && scm_is_null (scm_cdr ($$)))
 661                         $$ = scm_car ($$);
 662                 else
 663                 {
 664                         Music * m = MY_MAKE_MUSIC ("PostEvents", @$);
 665                         m->set_property ("elements", $$);
 666                         $$ = m->unprotect ();
 667                 }
 668         }
 669         ;
 670
 671 identifier_init_nonumber:
 672         score_block
 673         | book_block
 674         | bookpart_block
 675         | output_def
 676         | context_def_spec_block
 677         | music_assign
 678         | pitch_or_music
 679         | FRACTION
 680         | string
 681         | embedded_scm
 682         | full_markup_list
 683         | context_modification
 684         ;
 685
 686 context_def_spec_block:
 687         CONTEXT '{' context_def_spec_body '}'
 688         {
 689                 $$ = $3;
 690                 Context_def *td = Context_def::unsmob ($$);
 691                 if (!td) {
 692                         $$ = Context_def::make_scm ();
 693                         td = Context_def::unsmob ($$);
 694                 }
 695                 td->origin ()->set_spot (@$);
 696         }
 697         ;
 698
 699 context_mod_arg:
 700         embedded_scm
 701         |
 702         {
 703                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 704                 parser->lexer_->push_note_state (nn);
 705         }
 706         composite_music
 707         {
 708                 parser->lexer_->pop_state ();
 709                 $$ = $2;
 710         }
 711         ;
 712
 713
 714 context_def_spec_body:
 715         /**/ {
 716                 $$ = SCM_UNSPECIFIED;
 717         }
 718         | context_def_spec_body context_mod {
 719                 if (!SCM_UNBNDP ($2)) {
 720                         Context_def *td = Context_def::unsmob ($$);
 721                         if (!td) {
 722                                 $$ = Context_def::make_scm ();
 723                                 td = Context_def::unsmob ($$);
 724                         }
 725                         Context_def::unsmob ($$)->add_context_mod ($2);
 726                 }
 727         }
 728         | context_def_spec_body context_modification {
 729                 Context_def *td = Context_def::unsmob ($$);
 730                 if (!td) {
 731                         $$ = Context_def::make_scm ();
 732                         td = Context_def::unsmob ($$);
 733                 }
 734                 SCM new_mods = Context_mod::unsmob ($2)->get_mods ();
 735                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 736                     td->add_context_mod (scm_car (m));
 737                 }
 738         }
 739         | context_def_spec_body context_mod_arg {
 740                 Context_def *td = Context_def::unsmob ($1);
 741                 if (scm_is_eq ($2, SCM_UNSPECIFIED))
 742                         ;
 743                 else if (!td && Context_def::unsmob ($2))
 744                         $$ = $2;
 745                 else {
 746                         if (!td) {
 747                                 $$ = Context_def::make_scm ();
 748                                 td = Context_def::unsmob ($$);
 749                         }
 750                         if (Music::unsmob ($2)) {
 751                                 SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
 752                                 $2 = scm_call_2 (proc, parser->self_scm (), $2);
 753                         }
 754                         if (Context_mod *cm = Context_mod::unsmob ($2)) {
 755                                 for (SCM m = cm->get_mods (); scm_is_pair (m); m = scm_cdr (m)) {
 756                                         td->add_context_mod (scm_car (m));
 757                                 }
 758                         } else
 759                                 parser->parser_error (@2, _ ("not a context mod"));
 760                 }
 761         }
 762         ;
 763
 764
 765
 766 book_block:
 767         BOOK '{' book_body '}'  {
 768                 $$ = $3;
 769                 Book::unsmob ($$)->origin ()->set_spot (@$);
 770                 pop_paper (parser);
 771                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 772         }
 773         ;
 774
 775 /* FIXME:
 776    * Use 'handlers' like for toplevel-* stuff?
 777    * grok \layout and \midi?  */
 778 book_body:
 779         {
 780                 Book *book = new Book;
 781                 init_papers (parser);
 782                 book->paper_ = dynamic_cast<Output_def*> (Output_def::unsmob (parser->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 783                 book->paper_->unprotect ();
 784                 push_paper (parser, book->paper_);
 785                 book->header_ = get_header (parser);
 786                 $$ = book->unprotect ();
 787                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$);
 788         }
 789         | BOOK_IDENTIFIER {
 790                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 791         }
 792         | book_body paper_block {
 793                 Book::unsmob ($1)->paper_ = Output_def::unsmob ($2);
 794                 set_paper (parser, Output_def::unsmob ($2));
 795         }
 796         | book_body bookpart_block {
 797                 SCM proc = parser->lexer_->lookup_identifier ("book-bookpart-handler");
 798                 scm_call_2 (proc, $1, $2);
 799         }
 800         | book_body score_block {
 801                 SCM proc = parser->lexer_->lookup_identifier ("book-score-handler");
 802                 scm_call_2 (proc, $1, $2);
 803         }
 804         | book_body composite_music {
 805                 SCM proc = parser->lexer_->lookup_identifier ("book-music-handler");
 806                 scm_call_3 (proc, parser->self_scm (), $1, $2);
 807         }
 808         | book_body full_markup {
 809                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 810                 scm_call_2 (proc, $1, scm_list_1 ($2));
 811         }
 812         | book_body full_markup_list {
 813                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 814                 scm_call_2 (proc, $1, $2);
 815         }
 816         | book_body SCM_TOKEN {
 817                 // Evaluate and ignore #xxx, as opposed to \xxx
 818                 parser->lexer_->eval_scm_token ($2, @2);
 819         }
 820         | book_body embedded_scm_active
 821         {
 822                 SCM out = SCM_UNDEFINED;
 823                 if (Text_interface::is_markup ($2))
 824                         out = scm_list_1 ($2);
 825                 else if (Text_interface::is_markup_list ($2))
 826                         out = $2;
 827                 if (scm_is_pair (out))
 828                 {
 829                         SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 830                         scm_call_2 (proc, $1, out);
 831                 } else if (Score::unsmob ($2))
 832                 {
 833                         SCM proc = parser->lexer_->lookup_identifier ("book-score-handler");
 834                         scm_call_2 (proc, $1, $2);
 835                 } else if (Output_def *od = Output_def::unsmob ($2)) {
 836                         SCM id = SCM_EOL;
 837
 838                         if (od->c_variable ("is-paper") == SCM_BOOL_T)
 839                                 id = ly_symbol2scm ("$defaultpaper");
 840                         else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 841                                 id = ly_symbol2scm ("$defaultmidi");
 842                         else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 843                                 id = ly_symbol2scm ("$defaultlayout");
 844
 845                         parser->lexer_->set_identifier (id, $2);
 846                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
 847                         parser->parser_error (@2, _("bad expression type"));
 848         }
 849         | book_body
 850         {
 851                 parser->lexer_->add_scope (Book::unsmob ($1)->header_);
 852         } lilypond_header
 853         | book_body error {
 854                 Book *book = Book::unsmob ($1);
 855                 book->paper_ = 0;
 856                 book->scores_ = SCM_EOL;
 857                 book->bookparts_ = SCM_EOL;
 858         }
 859         ;
 860
 861 bookpart_block:
 862         BOOKPART '{' bookpart_body '}' {
 863                 $$ = $3;
 864                 Book::unsmob ($$)->origin ()->set_spot (@$);
 865                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 866         }
 867         ;
 868
 869 bookpart_body:
 870         {
 871                 Book *book = new Book;
 872                 $$ = book->unprotect ();
 873                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$);
 874         }
 875         | BOOK_IDENTIFIER {
 876                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 877         }
 878         | bookpart_body paper_block {
 879                 Book::unsmob ($$)->paper_ = Output_def::unsmob ($2);
 880         }
 881         | bookpart_body score_block {
 882                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-score-handler");
 883                 scm_call_2 (proc, $1, $2);
 884         }
 885         | bookpart_body composite_music {
 886                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-music-handler");
 887                 scm_call_3 (proc, parser->self_scm (), $1, $2);
 888         }
 889         | bookpart_body full_markup {
 890                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 891                 scm_call_2 (proc, $1, scm_list_1 ($2));
 892         }
 893         | bookpart_body full_markup_list {
 894                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 895                 scm_call_2 (proc, $1, $2);
 896         }
 897         | bookpart_body SCM_TOKEN {
 898                 // Evaluate and ignore #xxx, as opposed to \xxx
 899                 parser->lexer_->eval_scm_token ($2, @2);
 900         }
 901         | bookpart_body embedded_scm_active
 902         {
 903                 SCM out = SCM_UNDEFINED;
 904                 if (Text_interface::is_markup ($2))
 905                         out = scm_list_1 ($2);
 906                 else if (Text_interface::is_markup_list ($2))
 907                         out = $2;
 908                 if (scm_is_pair (out))
 909                 {
 910                         SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 911                         scm_call_2 (proc, $1, out);
 912                 } else if (Score::unsmob ($2))
 913                 {
 914                         SCM proc = parser->lexer_->lookup_identifier ("bookpart-score-handler");
 915                         scm_call_2 (proc, $1, $2);
 916                 } else if (Output_def *od = Output_def::unsmob ($2)) {
 917                         SCM id = SCM_EOL;
 918
 919                         if (od->c_variable ("is-paper") == SCM_BOOL_T)
 920                                 id = ly_symbol2scm ("$defaultpaper");
 921                         else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 922                                 id = ly_symbol2scm ("$defaultmidi");
 923                         else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 924                                 id = ly_symbol2scm ("$defaultlayout");
 925
 926                         parser->lexer_->set_identifier (id, $2);
 927                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
 928                         parser->parser_error (@2, _("bad expression type"));
 929         }
 930         | bookpart_body
 931         {
 932                 Book *book = Book::unsmob ($1);
 933                 if (!ly_is_module (book->header_))
 934                         book->header_ = ly_make_module (false);
 935                 parser->lexer_->add_scope (book->header_);
 936         } lilypond_header
 937         | bookpart_body error {
 938                 Book *book = Book::unsmob ($1);
 939                 book->paper_ = 0;
 940                 book->scores_ = SCM_EOL;
 941         }
 942         ;
 943
 944 score_block:
 945         SCORE '{' score_body '}'        {
 946                 Score::unsmob ($3)->origin ()->set_spot (@$);
 947                 $$ = $3;
 948         }
 949         ;
 950
 951 score_body:
 952         score_items {
 953                 if (!Score::unsmob ($1)) {
 954                         parser->parser_error (@1, _("Missing music in \\score"));
 955                         $$ = (new Score)->unprotect ();
 956                         if (scm_is_pair ($1) && ly_is_module (scm_car ($1)))
 957                         {
 958                                 Score::unsmob ($$)->set_header (scm_car ($1));
 959                                 $1 = scm_cdr ($1);
 960                         }
 961                         for (SCM p = scm_reverse_x ($1, SCM_EOL);
 962                              scm_is_pair (p); p = scm_cdr (p))
 963                         {
 964                                 Score::unsmob ($$)->
 965                                         add_output_def (Output_def::unsmob (scm_car (p)));
 966                         }
 967                 }
 968         }
 969         | score_body error {
 970                 Score::unsmob ($$)->error_found_ = true;
 971         }
 972         ;
 973
 974 score_item:
 975         embedded_scm
 976         | music
 977         | output_def
 978         ;
 979
 980 score_items:
 981         /* empty */
 982         {
 983                 $$ = SCM_EOL;
 984         }
 985         | score_items score_item
 986         {
 987                 Output_def *od = Output_def::unsmob ($2);
 988                 if (od) {
 989                         if (od->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 990                         {
 991                                 parser->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 992                                 od = 0;
 993                                 $2 = SCM_UNSPECIFIED;
 994                         }
 995                 } else if (!Score::unsmob ($$)) {
 996                         if (Music::unsmob ($2)) {
 997                                 SCM scorify = ly_lily_module_constant ("scorify-music");
 998                                 $2 = scm_call_2 (scorify, $2, parser->self_scm ());
 999                         }
1000                         if (Score::unsmob ($2))
1001                         {
1002                                 $$ = $2;
1003                                 $2 = SCM_UNSPECIFIED;
1004                         }
1005                 }
1006                 Score *score = Score::unsmob ($$);
1007                 if (score && scm_is_pair ($1)) {
1008                         if (ly_is_module (scm_car ($1)))
1009                         {
1010                                 score->set_header (scm_car ($1));
1011                                 $1 = scm_cdr ($1);
1012                         }
1013                         for (SCM p = scm_reverse_x ($1, SCM_EOL);
1014                              scm_is_pair (p); p = scm_cdr (p))
1015                         {
1016                                 score->add_output_def (Output_def::unsmob (scm_car (p)));
1017                         }
1018                 }
1019                 if (od) {
1020                         if (score)
1021                                 score->add_output_def (od);
1022                         else if (scm_is_pair ($$) && ly_is_module (scm_car ($$)))
1023                                 scm_set_cdr_x ($$, scm_cons ($2, scm_cdr ($$)));
1024                         else
1025                                 $$ = scm_cons ($2, $$);
1026                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
1027                         parser->parser_error (@2, _("Spurious expression in \\score"));
1028         }
1029         | score_items
1030         {
1031                 if (Score *score = Score::unsmob ($1)) {
1032                         if (!ly_is_module (score->get_header ()))
1033                                 score->set_header (ly_make_module (false));
1034                         parser->lexer_->add_scope (score->get_header ());
1035                 } else {
1036                         if (!scm_is_pair ($1) || !ly_is_module (scm_car ($1)))
1037                                 $1 = scm_cons (ly_make_module (false), $1);
1038                         parser->lexer_->add_scope (scm_car ($1));
1039                 }
1040         } lilypond_header
1041         {
1042                 $$ = $1;
1043         }
1044         ;
1045
1046
1047 /*
1048         OUTPUT DEF
1049 */
1050
1051 paper_block:
1052         output_def {
1053                 Output_def *od = Output_def::unsmob ($1);
1054
1055                 if (od->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
1056                 {
1057                         parser->parser_error (@1, _ ("need \\paper for paper block"));
1058                         $$ = get_paper (parser)->unprotect ();
1059                 }
1060         }
1061         ;
1062
1063
1064 output_def:
1065         output_def_body '}' {
1066                 if (scm_is_pair ($1))
1067                         $$ = scm_car ($1);
1068
1069                 parser->lexer_->remove_scope ();
1070                 parser->lexer_->pop_state ();
1071         }
1072         ;
1073
1074 output_def_head:
1075         PAPER {
1076                 Output_def *p = get_paper (parser);
1077                 p->input_origin_ = @$;
1078                 parser->lexer_->add_scope (p->scope_);
1079                 $$ = p->unprotect ();
1080         }
1081         | MIDI    {
1082                 Output_def *p = get_midi (parser);
1083                 $$ = p->unprotect ();
1084                 parser->lexer_->add_scope (p->scope_);
1085         }
1086         | LAYOUT        {
1087                 Output_def *p = get_layout (parser);
1088
1089                 parser->lexer_->add_scope (p->scope_);
1090                 $$ = p->unprotect ();
1091         }
1092         ;
1093
1094 output_def_head_with_mode_switch:
1095         output_def_head {
1096                 parser->lexer_->push_initial_state ();
1097                 $$ = $1;
1098         }
1099         ;
1100
1101 // We need this weird nonterminal because both music as well as a
1102 // context definition can start with \context and the difference is
1103 // only apparent after looking at the next token.  If it is '{', there
1104 // is still time to escape from notes mode.
1105
1106 music_or_context_def:
1107         music_assign
1108         | context_def_spec_block
1109         ;
1110
1111 output_def_body:
1112         output_def_head_with_mode_switch '{' {
1113                 Output_def::unsmob ($1)->input_origin_.set_spot (@$);
1114                 // This is a stupid trick to mark the beginning of the
1115                 // body for deciding whether to allow
1116                 // embedded_scm_active to have an output definition
1117                 $$ = scm_list_1 ($1);
1118         }
1119         | output_def_body assignment  {
1120                 if (scm_is_pair ($1))
1121                         $$ = scm_car ($1);
1122         }
1123         | output_def_body embedded_scm_active
1124         {
1125                 // We don't switch into note mode for Scheme functions
1126                 // here.  Does not seem warranted/required in output
1127                 // definitions.
1128                 if (scm_is_pair ($1))
1129                 {
1130                         Output_def *o = Output_def::unsmob ($2);
1131                         if (o) {
1132                                 o->input_origin_.set_spot (@$);
1133                                 $1 = o->self_scm ();
1134                                 parser->lexer_->remove_scope ();
1135                                 parser->lexer_->add_scope (o->scope_);
1136                                 $2 = SCM_UNSPECIFIED;
1137                         } else
1138                                 $1 = scm_car ($1);
1139                 }
1140                 if (Context_def::unsmob ($2))
1141                         assign_context_def (Output_def::unsmob ($1), $2);
1142                 // Seems unlikely, but let's be complete:
1143                 else if (Music::unsmob ($2))
1144                 {
1145                         SCM proc = parser->lexer_->lookup_identifier
1146                                 ("output-def-music-handler");
1147                         scm_call_3 (proc, parser->self_scm (),
1148                                     $1, $2);
1149                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
1150                         parser->parser_error (@2, _("bad expression type"));
1151                 $$ = $1;
1152         }
1153         | output_def_body SCM_TOKEN {
1154                 if (scm_is_pair ($1))
1155                         $$ = scm_car ($1);
1156                 // Evaluate and ignore #xxx, as opposed to \xxx
1157                 parser->lexer_->eval_scm_token ($2, @2);
1158         }
1159         | output_def_body
1160         {
1161                 if (scm_is_pair ($1))
1162                         $1 = scm_car ($1);
1163                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
1164                 parser->lexer_->push_note_state (nn);
1165         } music_or_context_def
1166         {
1167                 parser->lexer_->pop_state ();
1168                 if (Context_def::unsmob ($3))
1169                         assign_context_def (Output_def::unsmob ($1), $3);
1170                 else {
1171
1172                         SCM proc = parser->lexer_->lookup_identifier
1173                                      ("output-def-music-handler");
1174                         scm_call_3 (proc, parser->self_scm (),
1175                                     $1, $3);
1176                 }
1177                 $$ = $1;
1178         }
1179         | output_def_body error {
1180
1181         }
1182         ;
1183
1184 tempo_event:
1185         TEMPO steno_duration '=' tempo_range    {
1186                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_EOL, $2, $4);
1187         }
1188         | TEMPO scalar steno_duration '=' tempo_range   {
1189                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
1190         }
1191         | TEMPO scalar {
1192                 $$ = MAKE_SYNTAX ("tempo", @$, $2);
1193         } %prec ':'
1194         ;
1195
1196 /*
1197 The representation of a  list is reversed to have efficient append.  */
1198
1199 music_list:
1200         /* empty */ {
1201                 $$ = SCM_EOL;
1202         }
1203         | music_list music_embedded {
1204                 if (Music::unsmob ($2))
1205                         $$ = scm_cons ($2, $1);
1206         }
1207         | music_list error {
1208                 Music *m = MY_MAKE_MUSIC("Music", @$);
1209                 // ugh. code dup
1210                 m->set_property ("error-found", SCM_BOOL_T);
1211                 $$ = scm_cons (m->self_scm (), $1);
1212                 m->unprotect (); /* UGH */
1213         }
1214         ;
1215
1216 braced_music_list:
1217         '{' music_list '}'
1218         {
1219                 $$ = scm_reverse_x ($2, SCM_EOL);
1220         }
1221         ;
1222
1223 music:  music_assign
1224         | lyric_element_music
1225         | pitch_or_music
1226         {
1227                 $$ = make_music_from_simple (parser, @1, $1);
1228                 if (!Music::unsmob ($$))
1229                 {
1230                         parser->parser_error (@1, _ ("music expected"));
1231                         $$ = MAKE_SYNTAX ("void-music", @$);
1232                 }
1233         }
1234         ;
1235
1236 music_embedded:
1237         music
1238         {
1239                 if (Music::unsmob ($1)->is_mus_type ("post-event")) {
1240                         parser->parser_error (@1, _ ("unexpected post-event"));
1241                         $$ = SCM_UNSPECIFIED;
1242                 }
1243         }
1244         | music_embedded_backup
1245         {
1246                 $$ = $1;
1247         }
1248         | music_embedded_backup BACKUP lyric_element_music
1249         {
1250                 $$ = $3;
1251         }
1252         | multiplied_duration post_events
1253         {
1254                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1255
1256                 parser->default_duration_ = *Duration::unsmob ($1);
1257                 n->set_property ("duration", $1);
1258
1259                 if (scm_is_pair ($2))
1260                         n->set_property ("articulations",
1261                                          scm_reverse_x ($2, SCM_EOL));
1262                 $$ = n->unprotect ();
1263         }
1264         ;
1265
1266 music_embedded_backup:
1267         embedded_scm
1268         {
1269                 if (scm_is_eq ($1, SCM_UNSPECIFIED))
1270                         $$ = $1;
1271                 else if (Music *m = Music::unsmob ($1)) {
1272                         if (m->is_mus_type ("post-event")) {
1273                                 parser->parser_error
1274                                         (@1, _ ("unexpected post-event"));
1275                                 $$ = SCM_UNSPECIFIED;
1276                         } else
1277                                 $$ = $1;
1278                 } else if (parser->lexer_->is_lyric_state ()
1279                            && Text_interface::is_markup ($1))
1280                         MYBACKUP (LYRIC_ELEMENT, $1, @1);
1281                 else {
1282                         @$.warning (_ ("Ignoring non-music expression"));
1283                         $$ = $1;
1284                 }
1285         }
1286         ;
1287
1288 // music_assign does not need to contain lyrics: there are no
1289 // assignments in lyricmode.
1290 music_assign:
1291         simple_music
1292         | composite_music %prec COMPOSITE
1293         ;
1294
1295 repeated_music:
1296         REPEAT simple_string unsigned_number music
1297         {
1298                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, SCM_EOL);
1299         }
1300         | REPEAT simple_string unsigned_number music ALTERNATIVE braced_music_list
1301         {
1302                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $6);
1303         }
1304         ;
1305
1306 sequential_music:
1307         SEQUENTIAL braced_music_list {
1308                 $$ = MAKE_SYNTAX ("sequential-music", @$, $2);
1309         }
1310         | braced_music_list {
1311                 $$ = MAKE_SYNTAX ("sequential-music", @$, $1);
1312         }
1313         ;
1314
1315 simultaneous_music:
1316         SIMULTANEOUS braced_music_list {
1317                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, $2);
1318         }
1319         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1320                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($2, SCM_EOL));
1321         }
1322         ;
1323
1324 simple_music:
1325         event_chord
1326         | music_property_def
1327         | context_change
1328         ;
1329
1330 context_modification:
1331         WITH
1332         {
1333                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
1334                 parser->lexer_->push_note_state (nn);
1335         } '{' context_mod_list '}'
1336         {
1337                 parser->lexer_->pop_state ();
1338                 $$ = $4;
1339         }
1340         | WITH CONTEXT_MOD_IDENTIFIER
1341         {
1342                 $$ = $2;
1343         }
1344         | CONTEXT_MOD_IDENTIFIER
1345         {
1346                 $$ = $1;
1347         }
1348         | WITH context_modification_arg
1349         {
1350                 if (Music::unsmob ($2)) {
1351                         SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
1352                         $2 = scm_call_2 (proc, parser->self_scm (), $2);
1353                 }
1354                 if (Context_mod::unsmob ($2))
1355                         $$ = $2;
1356                 else {
1357                         parser->parser_error (@2, _ ("not a context mod"));
1358                         $$ = Context_mod ().smobbed_copy ();
1359                 }
1360         }
1361         ;
1362
1363 context_modification_arg:
1364         embedded_scm
1365         | MUSIC_IDENTIFIER
1366         ;
1367
1368 optional_context_mod:
1369         /**/ {
1370             $$ = SCM_EOL;
1371         }
1372         | context_modification
1373         {
1374               $$ = $1;
1375         }
1376         ;
1377
1378 context_mod_list:
1379         /**/ {
1380             $$ = Context_mod ().smobbed_copy ();
1381         }
1382         | context_mod_list context_mod  {
1383                 if (!SCM_UNBNDP ($2))
1384                         Context_mod::unsmob ($1)->add_context_mod ($2);
1385         }
1386         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1387                  Context_mod *md = Context_mod::unsmob ($2);
1388                  if (md)
1389                      Context_mod::unsmob ($1)->add_context_mods (md->get_mods ());
1390         }
1391         | context_mod_list context_mod_arg {
1392                 if (scm_is_eq ($2, SCM_UNSPECIFIED))
1393                         ;
1394                 else if (Music::unsmob ($2)) {
1395                         SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
1396                         $2 = scm_call_2 (proc, parser->self_scm (), $2);
1397                 }
1398                 if (Context_mod::unsmob ($2))
1399                         Context_mod::unsmob ($$)->add_context_mods
1400                                 (Context_mod::unsmob ($2)->get_mods ());
1401                 else {
1402                         parser->parser_error (@2, _ ("not a context mod"));
1403                 }
1404         }
1405         ;
1406
1407 context_prefix:
1408         CONTEXT symbol optional_id optional_context_mod {
1409                 Context_mod *ctxmod = Context_mod::unsmob ($4);
1410                 SCM mods = SCM_EOL;
1411                 if (ctxmod)
1412                         mods = ctxmod->get_mods ();
1413                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_F);
1414         }
1415         | NEWCONTEXT symbol optional_id optional_context_mod {
1416                 Context_mod *ctxmod = Context_mod::unsmob ($4);
1417                 SCM mods = SCM_EOL;
1418                 if (ctxmod)
1419                         mods = ctxmod->get_mods ();
1420                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_T);
1421         }
1422         ;
1423
1424 composite_music:
1425         music_function_call
1426         | repeated_music                { $$ = $1; }
1427         | re_rhythmed_music     { $$ = $1; }
1428         | context_prefix music
1429         {
1430                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1431         }
1432         | music_bare
1433         ;
1434
1435 music_bare:
1436         mode_changed_music
1437         | MUSIC_IDENTIFIER
1438         | grouped_music_list
1439         ;
1440
1441 grouped_music_list:
1442         simultaneous_music              { $$ = $1; }
1443         | sequential_music              { $$ = $1; }
1444         ;
1445
1446 /* Function argument lists are arguably the most complex part in the
1447  * parser.  They are pretty tricky to understand because of the way
1448  * they are processed, and because of optional arguments that can be
1449  * omitted.  When there are several optional arguments in a row,
1450  * omitting one automatically omits all following arguments.  Optional
1451  * arguments can only be omitted when either
1452  *
1453  * a) the omission is explicitly started with \default
1454  * b) the omission is implicitly started by an argument not matching
1455  *    its predicate, and there is a mandatory argument later that can
1456  *    "catch" the argument that does not fit.
1457  *
1458  * When argument parsing starts, the lexer pushes EXPECT_SCM tokens
1459  * (corresponding to mandatory arguments and having a predicate
1460  * function as semantic value) or EXPECT_OPTIONAL EXPECT_SCM (where
1461  * the semantic value of the EXPECT_OPTIONAL token is the default to
1462  * use when the optional argument is omitted, and EXPECT_SCM again has
1463  * the argument predicate as semantic value) in reverse order to the
1464  * parser, followed by EXPECT_NO_MORE_ARGS.  The argument list is then
1465  * processed inside-out while actual tokens are consumed.
1466  *
1467  * This means that the argument list tokens determine the actions
1468  * taken as they arrive.  The structure of the argument list is known
1469  * to the parser and stored in its parse stack when the first argument
1470  * is being parsed.  What the parser does not know is which predicates
1471  * will match and whether or not \default will be appearing in the
1472  * argument list, and where.
1473  *
1474  * Sequences of 0 or more optional arguments are scanned using either
1475  * function_arglist_backup or function_arglist_nonbackup.  The first
1476  * is used when optional arguments are followed by at least one
1477  * mandatory argument: in that case optional arguments may be skipped
1478  * by either a false predicate (in which case the expression will be
1479  * pushed back as one or more tokens, preceded by a BACKUP token) or
1480  * by using \default.
1481  *
1482  * If optional arguments are at the end of the argument list, they are
1483  * instead scanned using function_arglist_nonbackup: here the only
1484  * manner to enter into skipping of optional arguments is the use of
1485  * \default.
1486  *
1487  * The argument list of a normal function call is parsed using
1488  * function_arglist.  The part of an argument list before a mandatory
1489  * argument is parsed using function_arglist_optional.
1490  *
1491  * The difference is that leading optional arguments are scanned using
1492  * function_arglist_nonbackup and function_arglist_backup,
1493  * respectively.
1494  *
1495  * Most other details are obvious in the rules themselves.
1496  *
1497  */
1498
1499 symbol_list_arg:
1500         SYMBOL_LIST
1501         | SYMBOL_LIST '.' symbol_list_rev
1502         {
1503                 $$ = scm_append (scm_list_2 ($1, scm_reverse_x ($3, SCM_EOL)));
1504         }
1505         ;
1506
1507 symbol_list_rev:
1508         symbol_list_part
1509         | symbol_list_rev '.' symbol_list_part
1510         {
1511                 $$ = scm_append_x (scm_list_2 ($3, $1));
1512         }
1513         ;
1514
1515 // symbol_list_part delivers elements in reverse copy.
1516
1517 symbol_list_part:
1518         symbol_list_element
1519         {
1520                 SCM sym_l_p = ly_lily_module_constant ("symbol-list?");
1521                 $$ = try_string_variants (sym_l_p, $1);
1522                 if (SCM_UNBNDP ($$)) {
1523                         parser->parser_error (@1, _("not a symbol"));
1524                         $$ = SCM_EOL;
1525                 } else
1526                         $$ = scm_reverse ($$);
1527         }
1528         ;
1529
1530
1531 symbol_list_element:
1532         STRING
1533         | embedded_scm_bare
1534         ;
1535
1536
1537 function_arglist_nonbackup:
1538         function_arglist_common
1539         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup post_event_nofinger
1540         {
1541                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1542         }
1543         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' UNSIGNED
1544         {
1545                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1546                 if (scm_is_true (scm_call_1 ($2, n)))
1547                         $$ = scm_cons (n, $3);
1548                 else {
1549                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1550                         t->set_property ("digit", $5);
1551                         $$ = check_scheme_arg (parser, @4, t->unprotect (),
1552                                                $3, $2, n);
1553                 }
1554         }
1555         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' REAL
1556         {
1557                 $$ = check_scheme_arg (parser, @4,
1558                                        scm_difference ($5, SCM_UNDEFINED),
1559                                        $3, $2);
1560         }
1561         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' NUMBER_IDENTIFIER
1562         {
1563                 $$ = check_scheme_arg (parser, @4,
1564                                        scm_difference ($5, SCM_UNDEFINED),
1565                                        $3, $2);
1566         }
1567         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup embedded_scm_arg
1568         {
1569                 if (scm_is_true (scm_call_1 ($2, $4)))
1570                         $$ = scm_cons ($4, $3);
1571                 else
1572                         $$ = check_scheme_arg (parser, @4,
1573                                                make_music_from_simple
1574                                                (parser, @4, $4),
1575                                                $3, $2);
1576         }
1577         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup bare_number_common
1578         {
1579                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1580         }
1581         | function_arglist_nonbackup_reparse REPARSE pitch_or_music
1582         {
1583                 if (scm_is_true (scm_call_1 ($2, $3)))
1584                         $$ = scm_cons ($3, $1);
1585                 else
1586                         $$ = check_scheme_arg (parser, @3,
1587                                                make_music_from_simple
1588                                                (parser, @3, $3),
1589                                                $1, $2);
1590         }
1591         | function_arglist_nonbackup_reparse REPARSE duration_length
1592         {
1593                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1594         }
1595         | function_arglist_nonbackup_reparse REPARSE bare_number_common
1596         {
1597                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1598         }
1599         | function_arglist_nonbackup_reparse REPARSE SCM_ARG
1600         {
1601                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1602         }
1603         | function_arglist_nonbackup_reparse REPARSE lyric_element_music
1604         {
1605                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1606         }
1607         | function_arglist_nonbackup_reparse REPARSE symbol_list_arg
1608         {
1609                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1610         }
1611         ;
1612
1613 function_arglist_nonbackup_reparse:
1614         EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup SCM_IDENTIFIER
1615         {
1616                 $$ = $3;
1617                 SCM res = try_string_variants ($2, $4);
1618                 if (!SCM_UNBNDP (res))
1619                         if (scm_is_pair (res))
1620                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1621                         else
1622                                 MYREPARSE (@4, $2, SCM_ARG, res);
1623                 else if (scm_is_true
1624                          (scm_call_1
1625                           ($2, make_music_from_simple
1626                            (parser, @4, $4))))
1627                         MYREPARSE (@4, $2, STRING, $4);
1628                 else
1629                         MYREPARSE (@4, $2, SCM_ARG, $4);
1630         }
1631         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup pitch
1632         {
1633                 $$ = $3;
1634                 if (scm_is_true
1635                     (scm_call_1
1636                      ($2, make_music_from_simple
1637                       (parser, @4, $4))))
1638                         MYREPARSE (@4, $2, PITCH_IDENTIFIER, $4);
1639                 else
1640                         MYREPARSE (@4, $2, SCM_ARG, $4);
1641         }
1642         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup steno_tonic_pitch
1643         {
1644                 $$ = $3;
1645                 if (scm_is_true
1646                     (scm_call_1
1647                      ($2, make_music_from_simple
1648                       (parser, @4, $4))))
1649                         MYREPARSE (@4, $2, TONICNAME_PITCH, $4);
1650                 else
1651                         MYREPARSE (@4, $2, SCM_ARG, $4);
1652         }
1653         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup STRING
1654         {
1655                 $$ = $3;
1656                 SCM res = try_string_variants ($2, $4);
1657                 if (!SCM_UNBNDP (res))
1658                         if (scm_is_pair (res))
1659                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1660                         else
1661                                 MYREPARSE (@4, $2, SCM_ARG, res);
1662                 else if (scm_is_true
1663                          (scm_call_1
1664                           ($2, make_music_from_simple
1665                            (parser, @4, $4))))
1666                         MYREPARSE (@4, $2, STRING, $4);
1667                 else
1668                         MYREPARSE (@4, $2, SCM_ARG, $4);
1669         }
1670         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup full_markup
1671         {
1672                 $$ = $3;
1673                 if (scm_is_true (scm_call_1 ($2, $4)))
1674                         MYREPARSE (@4, $2, SCM_ARG, $4);
1675                 else if (scm_is_true
1676                          (scm_call_1
1677                           ($2, make_music_from_simple
1678                            (parser, @4, $4))))
1679                         MYREPARSE (@4, $2, STRING, $4);
1680                 else
1681                         MYREPARSE (@4, $2, SCM_ARG, $4);
1682         }
1683         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup UNSIGNED
1684         {
1685                 $$ = $3;
1686                 if (scm_is_true (scm_call_1 ($2, $4)))
1687                         MYREPARSE (@4, $2, REAL, $4);
1688                 else {
1689                         SCM d = make_duration ($4);
1690                         if (SCM_UNBNDP (d) || scm_is_false (scm_call_1 ($2, d)))
1691                                 MYREPARSE (@4, $2, REAL, $4); // trigger error
1692                         else
1693                                 MYREPARSE (@4, $2, DURATION_IDENTIFIER, d);
1694                 }
1695         }
1696         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup DURATION_IDENTIFIER {
1697                 $$ = $3;
1698                 MYREPARSE (@4, $2, DURATION_IDENTIFIER, $4);
1699         }
1700         ;
1701
1702
1703 // function_arglist_backup can't occur at the end of an argument
1704 // list.
1705 function_arglist_backup:
1706         function_arglist_common
1707         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup embedded_scm_arg
1708         {
1709                 if (scm_is_true (scm_call_1 ($2, $4)))
1710                         $$ = scm_cons ($4, $3);
1711                 else {
1712                         $$ = make_music_from_simple (parser, @4, $4);
1713                         if (scm_is_true (scm_call_1 ($2, $$)))
1714                                 $$ = scm_cons ($$, $3);
1715                         else
1716                         {
1717                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1718                                 MYBACKUP (SCM_ARG, $4, @4);
1719                         }
1720                 }
1721         }
1722         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup post_event_nofinger
1723         {
1724                 if (scm_is_true (scm_call_1 ($2, $4)))
1725                 {
1726                         $$ = scm_cons ($4, $3);
1727                 } else {
1728                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1729                         MYBACKUP (EVENT_IDENTIFIER, $4, @4);
1730                 }
1731         }
1732         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup pitch
1733         {
1734                 if (scm_is_true
1735                     (scm_call_1
1736                      ($2, make_music_from_simple
1737                       (parser, @4, $4))))
1738                 {
1739                         $$ = $3;
1740                         MYREPARSE (@4, $2, PITCH_IDENTIFIER, $4);
1741                 } else if (scm_is_true (scm_call_1 ($2, $4)))
1742                         $$ = scm_cons ($4, $3);
1743                 else {
1744                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1745                         MYBACKUP (PITCH_IDENTIFIER, $4, @4);
1746                 }
1747         }
1748         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup steno_tonic_pitch
1749         {
1750                 if (scm_is_true
1751                     (scm_call_1
1752                      ($2, make_music_from_simple
1753                       (parser, @4, $4))))
1754                 {
1755                         $$ = $3;
1756                         MYREPARSE (@4, $2, TONICNAME_PITCH, $4);
1757                 } else if (scm_is_true (scm_call_1 ($2, $4)))
1758                         $$ = scm_cons ($4, $3);
1759                 else {
1760                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1761                         MYBACKUP (TONICNAME_PITCH, $4, @4);
1762                 }
1763         }
1764         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup full_markup
1765         {
1766                 if (scm_is_true (scm_call_1 ($2, $4)))
1767                         $$ = scm_cons ($4, $3);
1768                 else {
1769                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1770                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
1771                 }
1772         }
1773         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup UNSIGNED
1774         {
1775                 if (scm_is_true (scm_call_1 ($2, $4)))
1776                 {
1777                         MYREPARSE (@4, $2, REAL, $4);
1778                         $$ = $3;
1779                 } else {
1780                         SCM d = make_duration ($4);
1781                         if (SCM_UNBNDP (d) || scm_is_false (scm_call_1 ($2, d)))
1782                         {
1783                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1784                                 MYBACKUP (UNSIGNED, $4, @4);
1785                         } else {
1786                                 MYREPARSE (@4, $2, DURATION_IDENTIFIER, d);
1787                                 $$ = $3;
1788                         }
1789                 }
1790         }
1791         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup REAL
1792         {
1793                 if (scm_is_true (scm_call_1 ($2, $4)))
1794                 {
1795                         $$ = $3;
1796                         MYREPARSE (@4, $2, REAL, $4);
1797                 } else {
1798                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1799                         MYBACKUP (REAL, $4, @4);
1800                 }
1801         }
1802         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup NUMBER_IDENTIFIER
1803         {
1804                 if (scm_is_true (scm_call_1 ($2, $4)))
1805                 {
1806                         $$ = scm_cons ($4, $3);
1807                 } else {
1808                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1809                         MYBACKUP (NUMBER_IDENTIFIER, $4, @4);
1810                 }
1811         }
1812         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' UNSIGNED
1813         {
1814                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1815                 if (scm_is_true (scm_call_1 ($2, n))) {
1816                         $$ = $3;
1817                         MYREPARSE (@5, $2, REAL, n);
1818                 } else {
1819                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1820                         t->set_property ("digit", $5);
1821                         $$ = t->unprotect ();
1822                         if (scm_is_true (scm_call_1 ($2, $$)))
1823                                 $$ = scm_cons ($$, $3);
1824                         else {
1825                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1826                                 MYBACKUP (UNSIGNED, $5, @5);
1827                                 parser->lexer_->push_extra_token (@4, '-');
1828                         }
1829                 }
1830         }
1831         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' REAL
1832         {
1833                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1834                 if (scm_is_true (scm_call_1 ($2, n))) {
1835                         MYREPARSE (@5, $2, REAL, n);
1836                         $$ = $3;
1837                 } else {
1838                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1839                         MYBACKUP (REAL, n, @5);
1840                 }
1841         }
1842         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' NUMBER_IDENTIFIER
1843         {
1844                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1845                 if (scm_is_true (scm_call_1 ($2, n))) {
1846                         $$ = scm_cons (n, $3);
1847                 } else {
1848                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1849                         MYBACKUP (NUMBER_IDENTIFIER, n, @5);
1850                 }
1851         }
1852         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup DURATION_IDENTIFIER
1853         {
1854                 if (scm_is_true (scm_call_1 ($2, $4)))
1855                 {
1856                         MYREPARSE (@4, $2, DURATION_IDENTIFIER, $4);
1857                         $$ = $3;
1858                 } else {
1859                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1860                         MYBACKUP (DURATION_IDENTIFIER, $4, @4);
1861                 }
1862         }
1863         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup SCM_IDENTIFIER
1864         {
1865                 SCM res = try_string_variants ($2, $4);
1866                 if (!SCM_UNBNDP (res))
1867                         if (scm_is_pair (res)) {
1868                                 $$ = $3;
1869                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1870                         }
1871                         else
1872                                 $$ = scm_cons (res, $3);
1873                 else {
1874                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1875                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
1876                 }
1877         }
1878         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup STRING
1879         {
1880                 SCM res = try_string_variants ($2, $4);
1881                 if (!SCM_UNBNDP (res))
1882                         if (scm_is_pair (res)) {
1883                                 $$ = $3;
1884                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1885                         }
1886                         else
1887                                 $$ = scm_cons (res, $3);
1888                 else {
1889                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1890                         MYBACKUP (STRING, $4, @4);
1891                 }
1892         }
1893         | function_arglist_backup REPARSE pitch_or_music
1894         {
1895                 if (scm_is_true (scm_call_1 ($2, $3)))
1896                         $$ = scm_cons ($3, $1);
1897                 else
1898                         $$ = check_scheme_arg (parser, @3,
1899                                                make_music_from_simple
1900                                                (parser, @3, $3),
1901                                                $1, $2);
1902         }
1903         | function_arglist_backup REPARSE bare_number_common
1904         {
1905                 $$ = check_scheme_arg (parser, @3,
1906                                        $3, $1, $2);
1907         }
1908         | function_arglist_backup REPARSE duration_length
1909         {
1910                 $$ = check_scheme_arg (parser, @3,
1911                                        $3, $1, $2);
1912         }
1913         | function_arglist_backup REPARSE symbol_list_arg
1914         {
1915                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1916         }
1917         ;
1918
1919 function_arglist:
1920         function_arglist_nonbackup
1921         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_nonbackup DEFAULT
1922         {
1923                 $$ = scm_cons (loc_on_music (@4, $1), $3);
1924         }
1925         ;
1926
1927 function_arglist_skip_nonbackup:
1928         function_arglist_nonbackup
1929         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_nonbackup
1930         {
1931                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1932         }
1933         ;
1934
1935 function_arglist_common:
1936         EXPECT_NO_MORE_ARGS {
1937                 $$ = SCM_EOL;
1938         }
1939         | EXPECT_SCM function_arglist_optional embedded_scm_arg
1940         {
1941                 if (scm_is_true (scm_call_1 ($1, $3)))
1942                         $$ = scm_cons ($3, $2);
1943                 else
1944                         $$ = check_scheme_arg (parser, @3,
1945                                                make_music_from_simple
1946                                                (parser, @3, $3),
1947                                                $2, $1);
1948         }
1949         | EXPECT_SCM function_arglist_optional bare_number_common
1950         {
1951                 $$ = check_scheme_arg (parser, @3,
1952                                        $3, $2, $1);
1953         }
1954         | EXPECT_SCM function_arglist_optional post_event_nofinger
1955         {
1956                 $$ = check_scheme_arg (parser, @3,
1957                                        $3, $2, $1);
1958         }
1959         | EXPECT_SCM function_arglist_optional '-' NUMBER_IDENTIFIER
1960         {
1961                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1962                 $$ = check_scheme_arg (parser, @4, n, $2, $1);
1963         }
1964         | function_arglist_common_reparse REPARSE SCM_ARG
1965         {
1966                 $$ = check_scheme_arg (parser, @3,
1967                                        $3, $1, $2);
1968         }
1969         | function_arglist_common_reparse REPARSE lyric_element_music
1970         {
1971                 $$ = check_scheme_arg (parser, @3,
1972                                        $3, $1, $2);
1973         }
1974         | function_arglist_common_reparse REPARSE pitch_or_music
1975         {
1976                 if (scm_is_true (scm_call_1 ($2, $3)))
1977                         $$ = scm_cons ($3, $1);
1978                 else
1979                         $$ = check_scheme_arg (parser, @3,
1980                                                make_music_from_simple
1981                                                (parser, @3, $3),
1982                                                $1, $2);
1983         }
1984         | function_arglist_common_reparse REPARSE bare_number_common
1985         {
1986                 $$ = check_scheme_arg (parser, @3,
1987                                        $3, $1, $2);
1988         }
1989         | function_arglist_common_reparse REPARSE duration_length
1990         {
1991                 $$ = check_scheme_arg (parser, @3,
1992                                        $3, $1, $2);
1993         }
1994         | function_arglist_common_reparse REPARSE symbol_list_arg
1995         {
1996                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1997         }
1998         ;
1999
2000 function_arglist_common_reparse:
2001         EXPECT_SCM function_arglist_optional SCM_IDENTIFIER
2002         {
2003                 $$ = $2;
2004                 SCM res = try_string_variants ($1, $3);
2005                 if (!SCM_UNBNDP (res))
2006                         if (scm_is_pair (res))
2007                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
2008                         else
2009                                 MYREPARSE (@3, $1, SCM_ARG, res);
2010                 else if (scm_is_true
2011                          (scm_call_1
2012                           ($1, make_music_from_simple (parser, @3, $3))))
2013                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
2014                 else
2015                         // This is going to flag a syntax error, we
2016                         // know the predicate to be false.
2017                         MYREPARSE (@3, $1, SCM_ARG, $3);
2018         }
2019         | EXPECT_SCM function_arglist_optional pitch
2020         {
2021                 $$ = $2;
2022                 if (scm_is_true
2023                     (scm_call_1
2024                      ($1, make_music_from_simple
2025                       (parser, @3, $3))))
2026                         MYREPARSE (@3, $1, PITCH_IDENTIFIER, $3);
2027                 else
2028                         MYREPARSE (@3, $1, SCM_ARG, $3);
2029         }
2030         | EXPECT_SCM function_arglist_optional steno_tonic_pitch
2031         {
2032                 $$ = $2;
2033                 if (scm_is_true
2034                     (scm_call_1
2035                      ($1, make_music_from_simple
2036                       (parser, @3, $3))))
2037                         MYREPARSE (@3, $1, TONICNAME_PITCH, $3);
2038                 else
2039                         MYREPARSE (@3, $1, SCM_ARG, $3);
2040         }
2041         | EXPECT_SCM function_arglist_optional STRING
2042         {
2043                 $$ = $2;
2044                 SCM res = try_string_variants ($1, $3);
2045                 if (!SCM_UNBNDP (res))
2046                         if (scm_is_pair (res))
2047                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
2048                         else
2049                                 MYREPARSE (@3, $1, SCM_ARG, res);
2050                 else if (scm_is_true
2051                          (scm_call_1
2052                           ($1, make_music_from_simple (parser, @3, $3))))
2053                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
2054                 else
2055                         // This is going to flag a syntax error, we
2056                         // know the predicate to be false.
2057                         MYREPARSE (@3, $1, SCM_ARG, $3);
2058         }
2059         | EXPECT_SCM function_arglist_optional full_markup
2060         {
2061                 $$ = $2;
2062                 if (scm_is_true (scm_call_1 ($1, $3)))
2063                         MYREPARSE (@3, $1, SCM_ARG, $3);
2064                 else if (scm_is_true
2065                          (scm_call_1
2066                           ($1, make_music_from_simple (parser, @3, $3))))
2067                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
2068                 else
2069                         // This is going to flag a syntax error, we
2070                         // know the predicate to be false.
2071                         MYREPARSE (@3, $1, SCM_ARG, $3);
2072         }
2073         | EXPECT_SCM function_arglist_optional UNSIGNED
2074         {
2075                 $$ = $2;
2076                 if (scm_is_true (scm_call_1 ($1, $3)))
2077                         MYREPARSE (@3, $1, REAL, $3);
2078                 else {
2079                         SCM d = make_duration ($3);
2080                         if (SCM_UNBNDP (d) || scm_is_false (scm_call_1 ($1, d)))
2081                                 MYREPARSE (@3, $1, REAL, $3);
2082                         else
2083                                 MYREPARSE (@3, $1, DURATION_IDENTIFIER, d);
2084                 }
2085         }
2086         | EXPECT_SCM function_arglist_optional DURATION_IDENTIFIER
2087         {
2088                 $$ = $2;
2089                 MYREPARSE (@3, $1, DURATION_IDENTIFIER, $3);
2090         }
2091         | EXPECT_SCM function_arglist_optional '-' UNSIGNED
2092         {
2093                 $$ = $2;
2094                 SCM n = scm_difference ($4, SCM_UNDEFINED);
2095                 if (scm_is_true (scm_call_1 ($1, n)))
2096                         MYREPARSE (@4, $1, REAL, n);
2097                 else {
2098                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @4);
2099                         t->set_property ("digit", $4);
2100                         SCM m = t->unprotect ();
2101                         if (scm_is_true (scm_call_1 ($1, m)))
2102                                 MYREPARSE (@4, $1, SCM_ARG, m);
2103                         else
2104                                 MYREPARSE (@4, $1, SCM_ARG, $4);
2105                 }
2106         }
2107         | EXPECT_SCM function_arglist_optional '-' REAL
2108         {
2109                 $$ = $2;
2110                 SCM n = scm_difference ($4, SCM_UNDEFINED);
2111                 MYREPARSE (@4, $1, REAL, n);
2112         }
2113         ;
2114
2115 function_arglist_optional:
2116         function_arglist_backup
2117         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_backup DEFAULT
2118         {
2119                 $$ = scm_cons (loc_on_music (@4, $1), $3);
2120         }
2121         | function_arglist_skip_backup BACKUP
2122         ;
2123
2124 function_arglist_skip_backup:
2125         function_arglist_backup
2126         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_backup
2127         {
2128                 $$ = scm_cons (loc_on_music (@3, $1), $3);
2129         }
2130         ;
2131
2132 music_function_call:
2133         MUSIC_FUNCTION function_arglist {
2134                 $$ = MAKE_SYNTAX ("music-function", @$,
2135                                          $1, $2);
2136         }
2137         ;
2138
2139
2140 optional_id:
2141         /**/ { $$ = SCM_EOL; }
2142         | '=' simple_string {
2143                 $$ = $2;
2144         }
2145         ;
2146
2147 // We must not have lookahead tokens parsed in lyric mode.  In order
2148 // to save confusion, we take almost the same set as permitted with
2149 // \lyricmode and/or \lyrics.  However, music identifiers are also
2150 // allowed, and they obviously do not require switching into lyrics
2151 // mode for parsing.
2152
2153 lyric_mode_music:
2154         {
2155                 parser->lexer_->push_lyric_state ();
2156         } grouped_music_list
2157         {
2158                 parser->lexer_->pop_state ();
2159                 $$ = $2;
2160         }
2161         | MUSIC_IDENTIFIER
2162         ;
2163
2164 mode_changed_music:
2165         mode_changing_head grouped_music_list {
2166                 if ($1 == ly_symbol2scm ("chords"))
2167                 {
2168                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
2169                 }
2170                 else
2171                 {
2172                   $$ = $2;
2173                 }
2174                 parser->lexer_->pop_state ();
2175         }
2176         | mode_changing_head_with_context optional_context_mod grouped_music_list {
2177                 Context_mod *ctxmod = Context_mod::unsmob ($2);
2178                 SCM mods = SCM_EOL;
2179                 if (ctxmod)
2180                         mods = ctxmod->get_mods ();
2181                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, mods, SCM_BOOL_T, $3);
2182                 if ($1 == ly_symbol2scm ("ChordNames"))
2183                 {
2184                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
2185                 }
2186                 parser->lexer_->pop_state ();
2187         }
2188         ;
2189
2190 mode_changing_head:
2191         NOTEMODE {
2192                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
2193                 parser->lexer_->push_note_state (nn);
2194
2195                 $$ = ly_symbol2scm ("notes");
2196         }
2197         | DRUMMODE
2198                 {
2199                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
2200                 parser->lexer_->push_note_state (nn);
2201
2202                 $$ = ly_symbol2scm ("drums");
2203         }
2204         | FIGUREMODE {
2205                 parser->lexer_->push_figuredbass_state ();
2206
2207                 $$ = ly_symbol2scm ("figures");
2208         }
2209         | CHORDMODE {
2210                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
2211                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
2212                 nn = parser->lexer_->lookup_identifier ("pitchnames");
2213                 parser->lexer_->push_chord_state (nn);
2214                 $$ = ly_symbol2scm ("chords");
2215
2216         }
2217         | LYRICMODE
2218                 { parser->lexer_->push_lyric_state ();
2219                 $$ = ly_symbol2scm ("lyrics");
2220         }
2221         ;
2222
2223 mode_changing_head_with_context:
2224         DRUMS {
2225                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
2226                 parser->lexer_->push_note_state (nn);
2227
2228                 $$ = ly_symbol2scm ("DrumStaff");
2229         }
2230         | FIGURES {
2231                 parser->lexer_->push_figuredbass_state ();
2232
2233                 $$ = ly_symbol2scm ("FiguredBass");
2234         }
2235         | CHORDS {
2236                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
2237                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
2238                 nn = parser->lexer_->lookup_identifier ("pitchnames");
2239                 parser->lexer_->push_chord_state (nn);
2240                 $$ = ly_symbol2scm ("ChordNames");
2241         }
2242         | LYRICS
2243                 { parser->lexer_->push_lyric_state ();
2244                 $$ = ly_symbol2scm ("Lyrics");
2245         }
2246         ;
2247
2248 new_lyrics:
2249         ADDLYRICS lyric_mode_music {
2250                 $$ = scm_list_1 ($2);
2251         }
2252         | new_lyrics ADDLYRICS lyric_mode_music {
2253                 $$ = scm_cons ($3, $1);
2254         }
2255         ;
2256
2257 re_rhythmed_music:
2258         composite_music new_lyrics {
2259                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
2260         } %prec COMPOSITE
2261         | LYRICSTO simple_string lyric_mode_music {
2262                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $3);
2263         }
2264         ;
2265
2266 context_change:
2267         CHANGE symbol '=' simple_string  {
2268                 $$ = MAKE_SYNTAX ("context-change", @$, $2, $4);
2269         }
2270         ;
2271
2272
2273 property_path:
2274         symbol_list_rev  {
2275                 $$ = scm_reverse_x ($1, SCM_EOL);
2276         }
2277         | symbol_list_rev property_path {
2278                 $$ = scm_reverse_x ($1, $2);
2279         }
2280         ;
2281
2282 property_operation:
2283         symbol '=' scalar {
2284                 $$ = scm_list_3 (ly_symbol2scm ("assign"), $1, $3);
2285         }
2286         | UNSET symbol {
2287                 $$ = scm_list_2 (ly_symbol2scm ("unset"), $2);
2288         }
2289         | OVERRIDE property_path '=' scalar {
2290                 if (scm_ilength ($2) < 2) {
2291                         parser->parser_error (@2, _("bad grob property path"));
2292                         $$ = SCM_UNDEFINED;
2293                 } else {
2294                         $$ = scm_cons (ly_symbol2scm ("push"),
2295                                        scm_cons2 (scm_car ($2),
2296                                                   $4,
2297                                                   scm_cdr ($2)));
2298                 }
2299         }
2300         | REVERT revert_arg {
2301                 $$ = scm_cons (ly_symbol2scm ("pop"), $2);
2302         }
2303         ;
2304
2305 // This is all quite awkward for the sake of substantial backward
2306 // compatibility while at the same time allowing a more "natural" form
2307 // of specification not separating grob specification from grob
2308 // property path.  The purpose of this definition of revert_arg is to
2309 // allow the symbol list which specifies grob and property to revert
2310 // to be optionally be split into two parts after the grob (which in
2311 // this case is just the first element of the list).  symbol_list_part
2312 // is only one path component, but it can be parsed without lookahead,
2313 // so we can follow it with a synthetic BACKUP token when needed.  If
2314 // the first symbol_list_part already contains multiple elements (only
2315 // possible if a Scheme expression provides them), we just parse for
2316 // additional elements introduced by '.', which is what the
2317 // SYMBOL_LIST backup in connection with the immediately following
2318 // rule using symbol_list_arg does.
2319 //
2320 // As long as we don't have our coffers filled with both grob and at
2321 // least one grob property specification, the rest of the required
2322 // symbol list chain may be provided either with or without a leading
2323 // dot.  This is for both allowing the traditional
2324 // \revert Accidental #'color
2325 // as well as well as the "naive" form
2326 // \revert Accidental.color
2327
2328 revert_arg:
2329         revert_arg_backup BACKUP symbol_list_arg
2330         {
2331                 $$ = $3;
2332         }
2333         ;
2334
2335 revert_arg_backup:
2336         revert_arg_part
2337         {
2338                 if (scm_is_null ($1)
2339                     || scm_is_null (scm_cdr ($1)))
2340                         MYBACKUP (SCM_ARG, $1, @1);
2341                 else
2342                         MYBACKUP (SYMBOL_LIST, scm_reverse_x ($1, SCM_EOL), @1);
2343         }
2344         ;
2345
2346 // revert_arg_part delivers results in reverse
2347 revert_arg_part:
2348         symbol_list_part
2349         | revert_arg_backup BACKUP SCM_ARG '.' symbol_list_part
2350         {
2351                 $$ = scm_append_x (scm_list_2 ($5, $3));
2352         }
2353         | revert_arg_backup BACKUP SCM_ARG symbol_list_part
2354         {
2355                 $$ = scm_append_x (scm_list_2 ($4, $3));
2356         }
2357         ;
2358
2359 context_def_mod:
2360         CONSISTS { $$ = ly_symbol2scm ("consists"); }
2361         | REMOVE { $$ = ly_symbol2scm ("remove"); }
2362
2363         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
2364         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
2365         | DENIES { $$ = ly_symbol2scm ("denies"); }
2366
2367         | ALIAS { $$ = ly_symbol2scm ("alias"); }
2368         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
2369         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
2370         | NAME { $$ = ly_symbol2scm ("context-name"); }
2371         ;
2372
2373 context_mod:
2374         property_operation { $$ = $1; }
2375         | context_def_mod STRING {
2376                 $$ = scm_list_2 ($1, $2);
2377         }
2378         | context_def_mod embedded_scm
2379         {
2380                 if (!scm_is_string ($2)
2381                     && ly_symbol2scm ("consists") != $1
2382                     && ly_symbol2scm ("remove") != $1)
2383                 {
2384                         $$ = SCM_EOL;
2385                         parser->parser_error (@1, _ ("only \\consists and \\remove take non-string argument."));
2386                 }
2387                 else
2388                 {
2389                         $$ = scm_list_2 ($1, $2);
2390                 }
2391         }
2392         ;
2393
2394 // If defined, at least two members.
2395 grob_prop_spec:
2396         symbol_list_rev
2397         {
2398                 SCM l = scm_reverse_x ($1, SCM_EOL);
2399                 if (scm_is_pair (l)
2400                     && to_boolean
2401                     (scm_object_property (scm_car (l),
2402                                           ly_symbol2scm ("is-grob?"))))
2403                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2404                 if (scm_is_null (l) || scm_is_null (scm_cdr (l))) {
2405                         parser->parser_error (@1, _ ("bad grob property path"));
2406                         l = SCM_UNDEFINED;
2407                 }
2408                 $$ = l;
2409         }
2410         ;
2411
2412 // If defined, at least three members
2413 grob_prop_path:
2414         grob_prop_spec
2415         {
2416                 if (!SCM_UNBNDP ($1) && scm_is_null (scm_cddr ($1)))
2417                 {
2418                         parser->parser_error (@1, _ ("bad grob property path"));
2419                         $$ = SCM_UNDEFINED;
2420                 }
2421         }
2422         | grob_prop_spec property_path
2423         {
2424                 if (!SCM_UNBNDP ($1)) {
2425                         $$ = scm_append_x (scm_list_2 ($1, $2));
2426                         if (scm_is_null (scm_cddr ($$))) {
2427                                 parser->parser_error (@$, _ ("bad grob property path"));
2428                                 $$ = SCM_UNDEFINED;
2429                         }
2430                 }
2431
2432         }
2433         ;
2434
2435 // Exactly two elements or undefined
2436 context_prop_spec:
2437         symbol_list_rev
2438         {
2439                 SCM l = scm_reverse_x ($1, SCM_EOL);
2440                 switch (scm_ilength (l)) {
2441                 case 1:
2442                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2443                 case 2:
2444                         break;
2445                 default:
2446                         parser->parser_error (@1, _ ("bad context property path"));
2447                         l = SCM_UNDEFINED;
2448                 }
2449                 $$ = l;
2450         }
2451         ;
2452
2453 simple_music_property_def:
2454         OVERRIDE grob_prop_path '=' scalar {
2455                 if (SCM_UNBNDP ($2))
2456                         $$ = SCM_UNDEFINED;
2457                 else {
2458                         $$ = scm_list_5 (scm_car ($2),
2459                                          ly_symbol2scm ("OverrideProperty"),
2460                                          scm_cadr ($2),
2461                                          $4,
2462                                          scm_cddr ($2));
2463                 }
2464         }
2465         | REVERT simple_revert_context revert_arg {
2466                 $$ = scm_list_4 ($2,
2467                                  ly_symbol2scm ("RevertProperty"),
2468                                  scm_car ($3),
2469                                  scm_cdr ($3));
2470         }
2471         | SET context_prop_spec '=' scalar {
2472                 if (SCM_UNBNDP ($2))
2473                         $$ = SCM_UNDEFINED;
2474                 else
2475                         $$ = scm_list_4 (scm_car ($2),
2476                                          ly_symbol2scm ("PropertySet"),
2477                                          scm_cadr ($2),
2478                                          $4);
2479         }
2480         | UNSET context_prop_spec {
2481                 if (SCM_UNBNDP ($2))
2482                         $$ = SCM_UNDEFINED;
2483                 else
2484                         $$ = scm_list_3 (scm_car ($2),
2485                                          ly_symbol2scm ("PropertyUnset"),
2486                                          scm_cadr ($2));
2487         }
2488         ;
2489
2490
2491 // This is all quite awkward for the sake of substantial backward
2492 // compatibility while at the same time allowing a more "natural" form
2493 // of specification not separating grob specification from grob
2494 // property path.  The purpose of this definition of
2495 // simple_revert_context is to allow the symbol list which specifies
2496 // grob and property to revert to be optionally be split into two
2497 // parts after the grob (which may be preceded by a context
2498 // specification, a case which we distinguish by checking whether the
2499 // first symbol is a valid grob symbol instead).
2500 //
2501 // See revert_arg above for the main work horse of this arrangement.
2502 // simple_revert_context just caters for the context and delegates the
2503 // rest of the job to revert_arg.
2504
2505 simple_revert_context:
2506         symbol_list_part
2507         {
2508                 $1 = scm_reverse_x ($1, SCM_EOL);
2509                 if (scm_is_null ($1)
2510                     || to_boolean
2511                     (scm_object_property (scm_car ($1),
2512                                           ly_symbol2scm ("is-grob?")))) {
2513                         $$ = ly_symbol2scm ("Bottom");
2514                         parser->lexer_->push_extra_token (@1, SCM_IDENTIFIER, $1);
2515                 } else {
2516                         $$ = scm_car ($1);
2517                         parser->lexer_->push_extra_token (@1, SCM_IDENTIFIER,
2518                                                           scm_cdr ($1));
2519                 }
2520         }
2521         ;
2522
2523 music_property_def:
2524         simple_music_property_def {
2525                 if (SCM_UNBNDP ($1))
2526                         $$ = MAKE_SYNTAX ("void-music", @1);
2527                 else
2528                         $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons2 (parser->self_scm (), @$.smobbed_copy (), $1));
2529         }
2530         ;
2531
2532 string:
2533         STRING {
2534                 $$ = $1;
2535         }
2536         | full_markup
2537         ;
2538
2539 simple_string: STRING {
2540                 $$ = $1;
2541         }
2542         | embedded_scm_bare
2543         {
2544                 if (scm_is_string ($1)) {
2545                         $$ = $1;
2546                 } else {
2547                         parser->parser_error (@1, (_ ("simple string expected")));
2548                         $$ = scm_string (SCM_EOL);
2549                 }
2550         }
2551         ;
2552
2553 symbol:
2554         STRING {
2555                 $$ = scm_string_to_symbol ($1);
2556         }
2557         | embedded_scm_bare
2558         {
2559                 // This is a bit of overkill but makes the same
2560                 // routine responsible for all symbol interpretations.
2561                 $$ = try_string_variants (ly_lily_module_constant ("symbol?"),
2562                                           $1);
2563                 if (SCM_UNBNDP ($$))
2564                 {
2565                         parser->parser_error (@1, (_ ("symbol expected")));
2566                         // Generate a unique symbol in case it is used
2567                         // for an assignment or similar
2568                         $$ = scm_make_symbol (ly_string2scm ("undefined"));
2569                 }
2570         }
2571         ;
2572
2573 scalar:
2574         embedded_scm_arg
2575         | pitch_or_music
2576         | SCM_IDENTIFIER
2577         | bare_number
2578         // The following is a rather defensive variant of admitting
2579         // negative numbers: the grammar would permit number_factor or
2580         // even number_expression.  However, function arguments allow
2581         // only this simple kind of negative number, so to have things
2582         // like \tweak and \override behave reasonably similar, it
2583         // makes sense to rule out things like -- which are rather an
2584         // accent in function argument contexts.
2585         | '-' bare_number
2586         {
2587                 $$ = scm_difference ($2, SCM_UNDEFINED);
2588         }
2589         | string
2590         ;
2591
2592 event_chord:
2593         simple_element post_events {
2594                 // Let the rhythmic music iterator sort this mess out.
2595                 if (scm_is_pair ($2)) {
2596                         Music::unsmob ($$)->set_property ("articulations",
2597                                                          scm_reverse_x ($2, SCM_EOL));
2598                 }
2599         } %prec ':'
2600         | CHORD_REPETITION optional_notemode_duration post_events {
2601                 Input i;
2602                 i.set_location (@1, @3);
2603                 $$ = MAKE_SYNTAX ("repetition-chord", i,
2604                                   $2, scm_reverse_x ($3, SCM_EOL));
2605         } %prec ':'
2606         | MULTI_MEASURE_REST optional_notemode_duration post_events {
2607                 Input i;
2608                 i.set_location (@1, @3);
2609                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
2610                                   scm_reverse_x ($3, SCM_EOL));
2611         } %prec ':'
2612         | tempo_event
2613         | note_chord_element
2614         ;
2615
2616
2617 note_chord_element:
2618         chord_body optional_notemode_duration post_events
2619         {
2620                 Music *m = Music::unsmob ($1);
2621                 SCM dur = Duration::unsmob ($2)->smobbed_copy ();
2622                 SCM es = m->get_property ("elements");
2623                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
2624
2625                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
2626                   Music::unsmob (scm_car (s))->set_property ("duration", dur);
2627                 es = ly_append2 (es, postevs);
2628
2629                 m-> set_property ("elements", es);
2630                 m->set_spot (@$);
2631                 $$ = m->self_scm ();
2632         } %prec ':'
2633         ;
2634
2635 chord_body:
2636         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
2637         {
2638                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
2639         }
2640         | FIGURE_OPEN figure_list FIGURE_CLOSE
2641         {
2642                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
2643         }
2644         ;
2645
2646 chord_body_elements:
2647         /* empty */             { $$ = SCM_EOL; }
2648         | chord_body_elements chord_body_element {
2649                 if (!SCM_UNBNDP ($2))
2650                         $$ = scm_cons ($2, $1);
2651         }
2652         ;
2653
2654 chord_body_element:
2655         pitch_or_tonic_pitch exclamations questions octave_check post_events
2656         {
2657                 bool q = to_boolean ($3);
2658                 bool ex = to_boolean ($2);
2659                 SCM check = $4;
2660                 SCM post = $5;
2661
2662                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2663                 n->set_property ("pitch", $1);
2664                 if (q)
2665                         n->set_property ("cautionary", SCM_BOOL_T);
2666                 if (ex || q)
2667                         n->set_property ("force-accidental", SCM_BOOL_T);
2668
2669                 if (scm_is_pair (post)) {
2670                         SCM arts = scm_reverse_x (post, SCM_EOL);
2671                         n->set_property ("articulations", arts);
2672                 }
2673                 if (scm_is_number (check))
2674                 {
2675                         int q = scm_to_int (check);
2676                         n->set_property ("absolute-octave", scm_from_int (q-1));
2677                 }
2678
2679                 $$ = n->unprotect ();
2680         }
2681         | DRUM_PITCH post_events {
2682                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2683                 n->set_property ("drum-type", $1);
2684
2685                 if (scm_is_pair ($2)) {
2686                         SCM arts = scm_reverse_x ($2, SCM_EOL);
2687                         n->set_property ("articulations", arts);
2688                 }
2689                 $$ = n->unprotect ();
2690         }
2691         | music_function_chord_body
2692         {
2693                 Music *m = Music::unsmob ($1);
2694
2695                 while (m && m->is_mus_type ("music-wrapper-music")) {
2696                         $$ = m->get_property ("element");
2697                         m = Music::unsmob ($$);
2698                 }
2699
2700                 if (!(m && m->is_mus_type ("rhythmic-event"))) {
2701                         parser->parser_error (@$, _ ("not a rhythmic event"));
2702                         $$ = SCM_UNDEFINED;
2703                 }
2704         }
2705         ;
2706
2707 music_function_chord_body:
2708         music_function_call
2709         | MUSIC_IDENTIFIER
2710         | embedded_scm
2711         ;
2712
2713 event_function_event:
2714         EVENT_FUNCTION function_arglist {
2715                 $$ = MAKE_SYNTAX ("music-function", @$,
2716                                          $1, $2);
2717         }
2718         ;
2719
2720 post_events:
2721         /* empty */ {
2722                 $$ = SCM_EOL;
2723         }
2724         | post_events post_event {
2725                 $$ = $1;
2726                 if (Music *m = Music::unsmob ($2))
2727                 {
2728                         if (m->is_mus_type ("post-event-wrapper"))
2729                         {
2730                                 for (SCM p = m->get_property ("elements");
2731                                      scm_is_pair (p);
2732                                      p = scm_cdr (p))
2733                                 {
2734                                         $$ = scm_cons (scm_car (p), $$);
2735                                 }
2736                         } else {
2737                                 m->set_spot (@2);
2738                                 $$ = scm_cons ($2, $$);
2739                         }
2740                 }
2741         }
2742         ;
2743
2744 post_event_nofinger:
2745         direction_less_event {
2746                 $$ = $1;
2747         }
2748         | script_dir music_function_call {
2749                 $$ = $2;
2750                 if (!Music::unsmob ($2)->is_mus_type ("post-event")) {
2751                         parser->parser_error (@2, _ ("post-event expected"));
2752                         $$ = SCM_UNSPECIFIED;
2753                 } else if (!SCM_UNBNDP ($1))
2754                 {
2755                         Music::unsmob ($$)->set_property ("direction", $1);
2756                 }
2757         }
2758         | HYPHEN {
2759                 if (!parser->lexer_->is_lyric_state ())
2760                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2761                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
2762         }
2763         | EXTENDER {
2764                 if (!parser->lexer_->is_lyric_state ())
2765                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2766                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
2767         }
2768         | script_dir direction_reqd_event {
2769                 if (!SCM_UNBNDP ($1))
2770                 {
2771                         Music *m = Music::unsmob ($2);
2772                         m->set_property ("direction", $1);
2773                 }
2774                 $$ = $2;
2775         }
2776         | script_dir direction_less_event {
2777                 if (!SCM_UNBNDP ($1))
2778                 {
2779                         Music *m = Music::unsmob ($2);
2780                         m->set_property ("direction", $1);
2781                 }
2782                 $$ = $2;
2783         }
2784         | '^' fingering
2785         {
2786                 $$ = $2;
2787                 Music::unsmob ($$)->set_property ("direction", scm_from_int (UP));
2788         }
2789         | '_' fingering
2790         {
2791                 $$ = $2;
2792                 Music::unsmob ($$)->set_property ("direction", scm_from_int (DOWN));
2793         }
2794         ;
2795
2796 post_event:
2797         post_event_nofinger
2798         | '-' fingering {
2799                 $$ = $2;
2800         }
2801         ;
2802
2803 string_number_event:
2804         E_UNSIGNED {
2805                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
2806                 s->set_property ("string-number", $1);
2807                 $$ = s->unprotect ();
2808         }
2809         ;
2810
2811 direction_less_event:
2812         string_number_event
2813         | EVENT_IDENTIFIER      {
2814                 $$ = $1;
2815         }
2816         | tremolo_type  {
2817                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
2818                a->set_property ("tremolo-type", $1);
2819                $$ = a->unprotect ();
2820         }
2821         | event_function_event
2822         ;
2823
2824 direction_reqd_event:
2825         gen_text_def {
2826                 $$ = $1;
2827         }
2828         | script_abbreviation {
2829                 SCM s = parser->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
2830                 if (scm_is_string (s)) {
2831                         Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
2832                         a->set_property ("articulation-type", s);
2833                         $$ = a->unprotect ();
2834                 } else {
2835                         Music *original = Music::unsmob (s);
2836                         if (original && original->is_mus_type ("post-event")) {
2837                                 Music *a = original->clone ();
2838                                 a->set_spot (parser->lexer_->override_input (@$));
2839                                 $$ = a->unprotect ();
2840                         } else {
2841                                 parser->parser_error (@1, _ ("expecting string or post-event as script definition"));
2842                                 $$ = MY_MAKE_MUSIC ("PostEvents", @$)->unprotect ();
2843                         }
2844                 }
2845         }
2846         ;
2847
2848 octave_check:
2849         /**/ { $$ = SCM_EOL; }
2850         | '=' quotes { $$ = $2; }
2851         ;
2852
2853 quotes:
2854         /* empty */
2855         {
2856                 $$ = SCM_INUM0;
2857         }
2858         | sub_quotes
2859         | sup_quotes
2860         ;
2861
2862 sup_quotes:
2863         '\'' {
2864                 $$ = scm_from_int (1);
2865         }
2866         | sup_quotes '\'' {
2867                 $$ = scm_oneplus ($1);
2868         }
2869         ;
2870
2871 sub_quotes:
2872         ',' {
2873                 $$ = scm_from_int (-1);
2874         }
2875         | sub_quotes ',' {
2876                 $$ = scm_oneminus ($1);
2877         }
2878         ;
2879
2880 steno_pitch:
2881         NOTENAME_PITCH quotes {
2882                 if (!scm_is_eq (SCM_INUM0, $2))
2883                 {
2884                         Pitch p = *Pitch::unsmob ($1);
2885                         p = p.transposed (Pitch (scm_to_int ($2), 0));
2886                         $$ = p.smobbed_copy ();
2887                 }
2888         }
2889         ;
2890
2891 /*
2892 ugh. duplication
2893 */
2894
2895 steno_tonic_pitch:
2896         TONICNAME_PITCH quotes {
2897                 if (!scm_is_eq (SCM_INUM0, $2))
2898                 {
2899                         Pitch p = *Pitch::unsmob ($1);
2900                         p = p.transposed (Pitch (scm_to_int ($2), 0));
2901                         $$ = p.smobbed_copy ();
2902                 }
2903         }
2904         ;
2905
2906 pitch:
2907         steno_pitch
2908         | PITCH_IDENTIFIER quotes {
2909                 if (!scm_is_eq (SCM_INUM0, $2))
2910                 {
2911                         Pitch p = *Pitch::unsmob ($1);
2912                         p = p.transposed (Pitch (scm_to_int ($2), 0));
2913                         $$ = p.smobbed_copy ();
2914                 }
2915         }
2916         ;
2917
2918 pitch_or_tonic_pitch:
2919         pitch
2920         | steno_tonic_pitch
2921         ;
2922
2923 gen_text_def:
2924         full_markup {
2925                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2926                 t->set_property ("text", $1);
2927                 $$ = t->unprotect ();
2928         }
2929         | STRING {
2930                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2931                 t->set_property ("text",
2932                         make_simple_markup ($1));
2933                 $$ = t->unprotect ();
2934         }
2935         | embedded_scm
2936         {
2937                 Music *m = Music::unsmob ($1);
2938                 if (m && m->is_mus_type ("post-event"))
2939                         $$ = $1;
2940                 else if (Text_interface::is_markup ($1)) {
2941                         Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2942                         t->set_property ("text", $1);
2943                         $$ = t->unprotect ();
2944                 } else
2945                         parser->parser_error (@1, _ ("not an articulation"));
2946         }
2947         ;
2948
2949 fingering:
2950         UNSIGNED {
2951                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
2952                 t->set_property ("digit", $1);
2953                 $$ = t->unprotect ();
2954         }
2955         ;
2956
2957 script_abbreviation:
2958         '^'             {
2959                 $$ = scm_from_locale_string ("Hat");
2960         }
2961         | '+'           {
2962                 $$ = scm_from_locale_string ("Plus");
2963         }
2964         | '-'           {
2965                 $$ = scm_from_locale_string ("Dash");
2966         }
2967         | '!'           {
2968                 $$ = scm_from_locale_string ("Bang");
2969         }
2970         | ANGLE_CLOSE   {
2971                 $$ = scm_from_locale_string ("Larger");
2972         }
2973         | '.'           {
2974                 $$ = scm_from_locale_string ("Dot");
2975         }
2976         | '_' {
2977                 $$ = scm_from_locale_string ("Underscore");
2978         }
2979         ;
2980
2981 script_dir:
2982         '_'     { $$ = scm_from_int (DOWN); }
2983         | '^'   { $$ = scm_from_int (UP); }
2984         | '-'   { $$ = SCM_UNDEFINED; }
2985         ;
2986
2987 duration_length:
2988         multiplied_duration {
2989                 $$ = $1;
2990         }
2991         ;
2992
2993 maybe_notemode_duration:
2994         {
2995                 $$ = SCM_UNDEFINED;
2996         } %prec ':'
2997         | multiplied_duration   {
2998                 $$ = $1;
2999                 parser->default_duration_ = *Duration::unsmob ($$);
3000         }
3001 ;
3002
3003
3004 optional_notemode_duration:
3005         maybe_notemode_duration
3006         {
3007                 if (SCM_UNBNDP ($$))
3008                         $$ = parser->default_duration_.smobbed_copy ();
3009         }
3010         ;
3011
3012 steno_duration:
3013         UNSIGNED dots           {
3014                 $$ = make_duration ($1, scm_to_int ($2));
3015                 if (SCM_UNBNDP ($$))
3016                 {
3017                         parser->parser_error (@1, _ ("not a duration"));
3018                         $$ = Duration ().smobbed_copy ();
3019                 }
3020         }
3021         | DURATION_IDENTIFIER dots      {
3022                 Duration *d = Duration::unsmob ($1);
3023                 Duration k (d->duration_log (),
3024                             d->dot_count () + scm_to_int ($2));
3025                 k = k.compressed (d->factor ());
3026                 scm_remember_upto_here_1 ($1);
3027                 $$ = k.smobbed_copy ();
3028         }
3029         ;
3030
3031 multiplied_duration:
3032         steno_duration {
3033                 $$ = $1;
3034         }
3035         | multiplied_duration '*' UNSIGNED {
3036                 $$ = Duration::unsmob ($$)->compressed (scm_to_int ($3)).smobbed_copy ();
3037         }
3038         | multiplied_duration '*' FRACTION {
3039                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
3040
3041                 $$ = Duration::unsmob ($$)->compressed (m).smobbed_copy ();
3042         }
3043         ;
3044
3045 dots:
3046         /* empty */     {
3047                 $$ = SCM_INUM0;
3048         }
3049         | dots '.' {
3050                 $$ = scm_oneplus ($1);
3051         }
3052         ;
3053
3054 tremolo_type:
3055         ':'     {
3056                 $$ = scm_from_int (parser->default_tremolo_type_);
3057         }
3058         | ':' UNSIGNED {
3059                 if (SCM_UNBNDP (make_duration ($2))) {
3060                         parser->parser_error (@2, _ ("not a duration"));
3061                         $$ = scm_from_int (parser->default_tremolo_type_);
3062                 } else {
3063                         $$ = $2;
3064                         parser->default_tremolo_type_ = scm_to_int ($2);
3065                 }
3066         }
3067         ;
3068
3069 bass_number:
3070         UNSIGNED { $$ = $1; }
3071         | STRING { $$ = $1; }
3072         | full_markup { $$ = $1; }
3073         | embedded_scm_bare
3074         {
3075                 // as an integer, it needs to be non-negative, and otherwise
3076                 // it needs to be suitable as a markup.
3077                 if (scm_is_integer ($1)
3078                     ? scm_is_true (scm_negative_p ($1))
3079                     : !Text_interface::is_markup ($1))
3080                 {
3081                         parser->parser_error (@1, _ ("bass number expected"));
3082                         $$ = SCM_INUM0;
3083                 }
3084         }
3085         ;
3086
3087 figured_bass_alteration:
3088         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
3089         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
3090         | '!'   { $$ = scm_from_int (0); }
3091         ;
3092
3093 bass_figure:
3094         FIGURE_SPACE {
3095                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
3096                 $$ = bfr->unprotect ();
3097         }
3098         | bass_number  {
3099                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
3100                 $$ = bfr->self_scm ();
3101
3102                 if (scm_is_number ($1))
3103                         bfr->set_property ("figure", $1);
3104                 else if (Text_interface::is_markup ($1))
3105                         bfr->set_property ("text", $1);
3106
3107                 bfr->unprotect ();
3108         }
3109         | bass_figure ']' {
3110                 $$ = $1;
3111                 Music::unsmob ($1)->set_property ("bracket-stop", SCM_BOOL_T);
3112         }
3113         | bass_figure figured_bass_alteration {
3114                 Music *m = Music::unsmob ($1);
3115                 if (scm_to_double ($2)) {
3116                         SCM salter = m->get_property ("alteration");
3117                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
3118                         m->set_property ("alteration",
3119                                          scm_sum (alter, $2));
3120                 } else {
3121                         m->set_property ("alteration", scm_from_int (0));
3122                 }
3123         }
3124         | bass_figure figured_bass_modification  {
3125                 Music *m = Music::unsmob ($1);
3126                 m->set_property ($2, SCM_BOOL_T);
3127         }
3128         ;
3129
3130
3131 figured_bass_modification:
3132         E_PLUS          {
3133                 $$ = ly_symbol2scm ("augmented");
3134         }
3135         | E_EXCLAMATION {
3136                 $$ = ly_symbol2scm ("no-continuation");
3137         }
3138         | '/'           {
3139                 $$ = ly_symbol2scm ("diminished");
3140         }
3141         | E_BACKSLASH {
3142                 $$ = ly_symbol2scm ("augmented-slash");
3143         }
3144         ;
3145
3146 br_bass_figure:
3147         bass_figure {
3148                 $$ = $1;
3149         }
3150         | '[' bass_figure {
3151                 $$ = $2;
3152                 Music::unsmob ($$)->set_property ("bracket-start", SCM_BOOL_T);
3153         }
3154         ;
3155
3156 figure_list:
3157         /**/            {
3158                 $$ = SCM_EOL;
3159         }
3160         | figure_list br_bass_figure {
3161                 $$ = scm_cons ($2, $1);
3162         }
3163         ;
3164
3165 optional_rest:
3166         /**/   { $$ = SCM_BOOL_F; }
3167         | REST { $$ = SCM_BOOL_T; }
3168         ;
3169
3170 pitch_or_music:
3171         pitch exclamations questions octave_check maybe_notemode_duration optional_rest post_events {
3172                 if (!parser->lexer_->is_note_state ())
3173                         parser->parser_error (@1, _ ("have to be in Note mode for notes"));
3174                 if (!SCM_UNBNDP ($2)
3175                     || !SCM_UNBNDP ($3)
3176                     || scm_is_number ($4)
3177                     || !SCM_UNBNDP ($5)
3178                     || scm_is_true ($6)
3179                     || scm_is_pair ($7))
3180                 {
3181                         Music *n = 0;
3182                         if (scm_is_true ($6))
3183                                 n = MY_MAKE_MUSIC ("RestEvent", @$);
3184                         else
3185                                 n = MY_MAKE_MUSIC ("NoteEvent", @$);
3186
3187                         n->set_property ("pitch", $1);
3188                         if (SCM_UNBNDP ($5))
3189                                 n->set_property ("duration",
3190                                                  parser->default_duration_.smobbed_copy ());
3191                         else
3192                                 n->set_property ("duration", $5);
3193
3194                         if (scm_is_number ($4))
3195                         {
3196                                 int q = scm_to_int ($4);
3197                                 n->set_property ("absolute-octave", scm_from_int (q-1));
3198                         }
3199
3200                         if (to_boolean ($3))
3201                                 n->set_property ("cautionary", SCM_BOOL_T);
3202                         if (to_boolean ($2) || to_boolean ($3))
3203                                 n->set_property ("force-accidental", SCM_BOOL_T);
3204                         if (scm_is_pair ($7))
3205                                 n->set_property ("articulations",
3206                                                  scm_reverse_x ($7, SCM_EOL));
3207                         $$ = n->unprotect ();
3208                 }
3209         } %prec ':'
3210         | new_chord post_events {
3211                 if (!parser->lexer_->is_chord_state ())
3212                         parser->parser_error (@1, _ ("have to be in Chord mode for chords"));
3213                 if (scm_is_pair ($2)) {
3214                         if (Pitch::unsmob ($1))
3215                                 $1 = make_chord_elements (@1,
3216                                                           $1,
3217                                                           parser->default_duration_.smobbed_copy (),
3218                                                           SCM_EOL);
3219
3220                         SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
3221
3222                         $$ = MAKE_SYNTAX ("event-chord", @1, elts);
3223                 } else if (!Pitch::unsmob ($1))
3224                         $$ = MAKE_SYNTAX ("event-chord", @1, $1);
3225                 // A mere pitch drops through.
3226         } %prec ':'
3227         ;
3228
3229 simple_element:
3230         DRUM_PITCH optional_notemode_duration {
3231                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
3232                 n->set_property ("duration", $2);
3233                 n->set_property ("drum-type", $1);
3234
3235                 $$ = n->unprotect ();
3236         }
3237         | RESTNAME optional_notemode_duration           {
3238                 Music *ev = 0;
3239                 if (ly_scm2string ($1) == "s") {
3240                         /* Space */
3241                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
3242                   }
3243                 else {
3244                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
3245
3246                     }
3247                 ev->set_property ("duration", $2);
3248                 $$ = ev->unprotect ();
3249         }
3250         ;
3251
3252 lyric_element:
3253         full_markup {
3254                 if (!parser->lexer_->is_lyric_state ())
3255                         parser->parser_error (@1, _ ("markup outside of text script or \\lyricmode"));
3256                 $$ = $1;
3257         }
3258         | STRING {
3259                 if (!parser->lexer_->is_lyric_state ())
3260                         parser->parser_error (@1, _ ("unrecognized string, not in text script or \\lyricmode"));
3261                 $$ = $1;
3262         }
3263         | LYRIC_ELEMENT
3264         ;
3265
3266 lyric_element_music:
3267         lyric_element optional_notemode_duration post_events {
3268                 $$ = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
3269                 if (scm_is_pair ($3))
3270                         Music::unsmob ($$)->set_property
3271                                 ("articulations", scm_reverse_x ($3, SCM_EOL));
3272         } %prec ':'
3273         ;
3274
3275 // Can return a single pitch rather than a list.
3276 new_chord:
3277         steno_tonic_pitch maybe_notemode_duration   {
3278                 if (SCM_UNBNDP ($2))
3279                         $$ = $1;
3280                 else
3281                         $$ = make_chord_elements (@$, $1, $2, SCM_EOL);
3282         }
3283         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
3284                 SCM its = scm_reverse_x ($4, SCM_EOL);
3285                 $$ = make_chord_elements (@$, $1, $2, scm_cons ($3, its));
3286         } %prec ':'
3287         ;
3288
3289 chord_items:
3290         /**/ {
3291                 $$ = SCM_EOL;
3292         }
3293         | chord_items chord_item {
3294                 $$ = scm_cons ($2, $$);
3295         }
3296         ;
3297
3298 chord_separator:
3299         CHORD_COLON {
3300                 $$ = ly_symbol2scm ("chord-colon");
3301         }
3302         | CHORD_CARET {
3303                 $$ = ly_symbol2scm ("chord-caret");
3304         }
3305         | CHORD_SLASH steno_tonic_pitch {
3306                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
3307         }
3308         | CHORD_BASS steno_tonic_pitch {
3309                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
3310         }
3311         ;
3312
3313 chord_item:
3314         chord_separator {
3315                 $$ = $1;
3316         }
3317         | step_numbers {
3318                 $$ = scm_reverse_x ($1, SCM_EOL);
3319         }
3320         | CHORD_MODIFIER  {
3321                 $$ = $1;
3322         }
3323         ;
3324
3325 step_numbers:
3326         step_number { $$ = scm_cons ($1, SCM_EOL); }
3327         | step_numbers '.' step_number {
3328                 $$ = scm_cons ($3, $$);
3329         }
3330         ;
3331
3332 step_number:
3333         UNSIGNED {
3334                 $$ = make_chord_step ($1, 0);
3335         }
3336         | UNSIGNED '+' {
3337                 $$ = make_chord_step ($1, SHARP_ALTERATION);
3338         }
3339         | UNSIGNED CHORD_MINUS {
3340                 $$ = make_chord_step ($1, FLAT_ALTERATION);
3341         }
3342         ;
3343
3344 tempo_range:
3345         unsigned_number {
3346                 $$ = $1;
3347         } %prec ':'
3348         | unsigned_number '-' unsigned_number {
3349                 $$ = scm_cons ($1, $3);
3350         }
3351         ;
3352
3353 /*
3354         UTILITIES
3355
3356 TODO: should deprecate in favor of Scheme?
3357
3358  */
3359 number_expression:
3360         number_expression '+' number_term {
3361                 $$ = scm_sum ($1, $3);
3362         }
3363         | number_expression '-' number_term {
3364                 $$ = scm_difference ($1, $3);
3365         }
3366         | number_term
3367         ;
3368
3369 number_term:
3370         number_factor {
3371                 $$ = $1;
3372         }
3373         | number_factor '*' number_factor {
3374                 $$ = scm_product ($1, $3);
3375         }
3376         | number_factor '/' number_factor {
3377                 $$ = scm_divide ($1, $3);
3378         }
3379         ;
3380
3381 number_factor:
3382         '-'  number_factor { /* %prec UNARY_MINUS */
3383                 $$ = scm_difference ($2, SCM_UNDEFINED);
3384         }
3385         | bare_number
3386         ;
3387
3388 bare_number_common:
3389         REAL
3390         | NUMBER_IDENTIFIER
3391         | REAL NUMBER_IDENTIFIER
3392         {
3393                 $$ = scm_product ($1, $2);
3394         }
3395         ;
3396
3397 bare_number:
3398         bare_number_common
3399         | UNSIGNED
3400         | UNSIGNED NUMBER_IDENTIFIER    {
3401                 $$ = scm_product ($1, $2);
3402         }
3403         ;
3404
3405 unsigned_number:
3406         UNSIGNED
3407         | NUMBER_IDENTIFIER
3408         {
3409                 if (!scm_is_integer ($1)
3410                     || scm_is_true (scm_negative_p ($1)))
3411                 {
3412                         parser->parser_error (@1, _("not an unsigned integer"));
3413                         $$ = SCM_INUM0;
3414                 }
3415         }
3416         | embedded_scm
3417         {
3418                 if (!scm_is_integer ($1)
3419                     || scm_is_true (scm_negative_p ($1)))
3420                 {
3421                         parser->parser_error (@1, _("not an unsigned integer"));
3422                         $$ = SCM_INUM0;
3423                 }
3424         }
3425         ;
3426
3427 exclamations:
3428                 { $$ = SCM_UNDEFINED; }
3429         | exclamations '!'
3430         {
3431                 if (SCM_UNBNDP ($1))
3432                         $$ = SCM_BOOL_T;
3433                 else
3434                         $$ = scm_not ($1);
3435         }
3436         ;
3437
3438 questions:
3439 // This precedence rule is rather weird.  It triggers when '!' is
3440 // encountered after a pitch, and is used for deciding whether to save
3441 // this instead for a figure modification.  This should not actually
3442 // occur in practice as pitches and figures are generated in different
3443 // modes.  Using a greedy (%right) precedence makes sure that we don't
3444 // get stuck in a wrong interpretation.
3445         { $$ = SCM_UNDEFINED; } %prec ':'
3446         | questions '?'
3447         {
3448                 if (SCM_UNBNDP ($1))
3449                         $$ = SCM_BOOL_T;
3450                 else
3451                         $$ = scm_not ($1);
3452         }
3453         ;
3454
3455 full_markup_list:
3456         MARKUPLIST
3457                 { parser->lexer_->push_markup_state (); }
3458         markup_list {
3459                 $$ = $3;
3460                 parser->lexer_->pop_state ();
3461         }
3462         ;
3463
3464 full_markup:
3465         MARKUP
3466                 { parser->lexer_->push_markup_state (); }
3467         markup_top {
3468                 $$ = $3;
3469                 parser->lexer_->pop_state ();
3470         }
3471         ;
3472
3473 markup_top:
3474         markup_list {
3475                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
3476         }
3477         | markup_head_1_list simple_markup
3478         {
3479                 $$ = scm_car (MAKE_SYNTAX ("composed-markup-list",
3480                                            @2, $1, scm_list_1 ($2)));
3481         }
3482         | simple_markup {
3483                 $$ = $1;
3484         }
3485         ;
3486
3487 markup_scm:
3488         embedded_scm_bare
3489         {
3490                 if (Text_interface::is_markup ($1))
3491                         MYBACKUP (MARKUP_IDENTIFIER, $1, @1);
3492                 else if (Text_interface::is_markup_list ($1))
3493                         MYBACKUP (MARKUPLIST_IDENTIFIER, $1, @1);
3494                 else {
3495                         parser->parser_error (@1, _ ("not a markup"));
3496                         MYBACKUP (MARKUP_IDENTIFIER, scm_string (SCM_EOL), @1);
3497                 }
3498         } BACKUP
3499         ;
3500
3501
3502 markup_list:
3503         markup_composed_list {
3504                 $$ = $1;
3505         }
3506         | markup_uncomposed_list
3507         ;
3508
3509 markup_uncomposed_list:
3510         markup_braced_list {
3511                 $$ = $1;
3512         }
3513         | markup_command_list {
3514                 $$ = scm_list_1 ($1);
3515         }
3516         | markup_scm MARKUPLIST_IDENTIFIER
3517         {
3518                 $$ = $2;
3519         }
3520         | SCORELINES {
3521                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
3522                 parser->lexer_->push_note_state (nn);
3523         } '{' score_body '}' {
3524                 Score *sc = Score::unsmob ($4);
3525                 sc->origin ()->set_spot (@$);
3526                 if (sc->defs_.empty ()) {
3527                         Output_def *od = get_layout (parser);
3528                         sc->add_output_def (od);
3529                         od->unprotect ();
3530                 }
3531                 $$ = scm_list_1 (scm_list_2 (ly_lily_module_constant ("score-lines-markup-list"), $4));
3532                 parser->lexer_->pop_state ();
3533         }
3534         ;
3535
3536 markup_composed_list:
3537         markup_head_1_list markup_uncomposed_list {
3538                 $$ = MAKE_SYNTAX ("composed-markup-list",
3539                                   @2, $1, $2);
3540         }
3541         ;
3542
3543 markup_braced_list:
3544         '{' markup_braced_list_body '}' {
3545                 $$ = scm_reverse_x ($2, SCM_EOL);
3546         }
3547         ;
3548
3549 markup_braced_list_body:
3550         /* empty */     {  $$ = SCM_EOL; }
3551         | markup_braced_list_body markup {
3552                 $$ = scm_cons ($2, $1);
3553         }
3554         | markup_braced_list_body markup_list {
3555                 $$ = scm_reverse_x ($2, $1);
3556         }
3557         ;
3558
3559 markup_command_list:
3560         MARKUP_LIST_FUNCTION markup_command_list_arguments {
3561           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
3562         }
3563         ;
3564
3565 markup_command_basic_arguments:
3566         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
3567           $$ = scm_cons ($3, $2);
3568         }
3569         | EXPECT_SCM markup_command_list_arguments embedded_scm {
3570           $$ = check_scheme_arg (parser, @3, $3, $2, $1);
3571         }
3572         | EXPECT_NO_MORE_ARGS {
3573           $$ = SCM_EOL;
3574         }
3575         ;
3576
3577 markup_command_list_arguments:
3578         markup_command_basic_arguments { $$ = $1; }
3579         | EXPECT_MARKUP markup_command_list_arguments markup {
3580           $$ = scm_cons ($3, $2);
3581         }
3582         ;
3583
3584 markup_head_1_item:
3585         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
3586           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
3587         }
3588         ;
3589
3590 markup_head_1_list:
3591         markup_head_1_item      {
3592                 $$ = scm_list_1 ($1);
3593         }
3594         | markup_head_1_list markup_head_1_item {
3595                 $$ = scm_cons ($2, $1);
3596         }
3597         ;
3598
3599 simple_markup:
3600         STRING {
3601                 $$ = make_simple_markup ($1);
3602         }
3603         | SCORE {
3604                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
3605                 parser->lexer_->push_note_state (nn);
3606         } '{' score_body '}' {
3607                 Score *sc = Score::unsmob ($4);
3608                 sc->origin ()->set_spot (@$);
3609                 if (sc->defs_.empty ()) {
3610                         Output_def *od = get_layout (parser);
3611                         sc->add_output_def (od);
3612                         od->unprotect ();
3613                 }
3614                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), $4);
3615                 parser->lexer_->pop_state ();
3616         }
3617         | MARKUP_FUNCTION markup_command_basic_arguments {
3618                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
3619         }
3620         | markup_scm MARKUP_IDENTIFIER
3621         {
3622                 $$ = $2;
3623         }
3624         ;
3625
3626 markup:
3627         markup_head_1_list simple_markup
3628         {
3629                 $$ = scm_car (MAKE_SYNTAX ("composed-markup-list",
3630                                            @2, $1, scm_list_1 ($2)));
3631         }
3632         | simple_markup {
3633                 $$ = $1;
3634         }
3635         ;
3636
3637 %%
3638
3639 void
3640 Lily_parser::set_yydebug (bool x)
3641 {
3642         yydebug = x;
3643 }
3644
3645 SCM
3646 Lily_parser::do_yyparse ()
3647 {
3648         SCM retval = SCM_UNDEFINED;
3649         yyparse (this, &retval);
3650         return retval;
3651 }
3652
3653
3654
3655
3656
3657 /*
3658
3659 It is a little strange to have this function in this file, but
3660 otherwise, we have to import music classes into the lexer.
3661
3662 */
3663 int
3664 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
3665 {
3666         if (Book::unsmob (sid)) {
3667                 Book *book =  Book::unsmob (sid)->clone ();
3668                 *destination = book->self_scm ();
3669                 book->unprotect ();
3670
3671                 return BOOK_IDENTIFIER;
3672         } else if (scm_is_number (sid)) {
3673                 *destination = sid;
3674                 return NUMBER_IDENTIFIER;
3675         } else if (Context_def::unsmob (sid))
3676         {
3677                 *destination = Context_def::unsmob (sid)->clone ()->unprotect ();
3678                 return SCM_IDENTIFIER;
3679         } else if (Context_mod::unsmob (sid)) {
3680                 *destination = Context_mod::unsmob (sid)->smobbed_copy ();
3681                 return CONTEXT_MOD_IDENTIFIER;
3682         } else if (Music *mus = Music::unsmob (sid)) {
3683                 mus = mus->clone ();
3684                 *destination = mus->self_scm ();
3685                 bool is_event = mus->is_mus_type ("post-event");
3686                 mus->unprotect ();
3687                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
3688         } else if (Pitch::unsmob (sid)) {
3689                 *destination = Pitch::unsmob (sid)->smobbed_copy ();
3690                 return PITCH_IDENTIFIER;
3691         } else if (Duration::unsmob (sid)) {
3692                 *destination = Duration::unsmob (sid)->smobbed_copy ();
3693                 return DURATION_IDENTIFIER;
3694         } else if (Output_def::unsmob (sid)) {
3695                 *destination = Output_def::unsmob (sid)->clone ()->unprotect ();
3696                 return SCM_IDENTIFIER;
3697         } else if (Score::unsmob (sid)) {
3698                 *destination = Score::unsmob (sid)->clone ()->unprotect ();
3699                 return SCM_IDENTIFIER;
3700         }
3701
3702         return -1;
3703 }
3704
3705 SCM
3706 get_next_unique_context_id ()
3707 {
3708         return scm_from_locale_string ("$uniqueContextId");
3709 }
3710
3711
3712 SCM
3713 get_next_unique_lyrics_context_id ()
3714 {
3715         static int new_context_count;
3716         char s[128];
3717         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
3718         return scm_from_locale_string (s);
3719 }
3720
3721 // check_scheme_arg checks one argument with a given predicate for use
3722 // in an argument list and throws a syntax error if it is unusable.
3723 // The argument is prepended to the argument list in any case.  After
3724 // throwing a syntax error, the argument list is terminated with #f as
3725 // its last cdr in order to mark it as uncallable while not losing
3726 // track of its total length.
3727 //
3728 // There are a few special considerations: if optional argument disp
3729 // is given (otherwise it defaults to SCM_UNDEFINED), it will be used
3730 // instead of arg in a prospective error message.  This is useful if
3731 // arg is not the actual argument but rather a transformation of it.
3732 //
3733 // If arg itself is SCM_UNDEFINED, the predicate is considered false
3734 // and an error message using disp is produced unconditionally.
3735
3736 SCM check_scheme_arg (Lily_parser *parser, Input loc,
3737                       SCM arg, SCM args, SCM pred, SCM disp)
3738 {
3739         if (SCM_UNBNDP (arg))
3740                 args = scm_cons (disp, args);
3741         else {
3742                 args = scm_cons (arg, args);
3743                 if (scm_is_true (scm_call_1 (pred, arg)))
3744                         return args;
3745         }
3746         scm_set_cdr_x (scm_last_pair (args), SCM_EOL);
3747         MAKE_SYNTAX ("argument-error", loc, scm_length (args), pred,
3748                      SCM_UNBNDP (disp) ? arg : disp);
3749         scm_set_cdr_x (scm_last_pair (args), SCM_BOOL_F);
3750         return args;
3751 }
3752
3753 SCM loc_on_music (Input loc, SCM arg)
3754 {
3755         if (Music *m = Music::unsmob (arg))
3756         {
3757                 m = m->clone ();
3758                 m->set_spot (loc);
3759                 return m->unprotect ();
3760         }
3761         return arg;
3762 }
3763
3764 SCM
3765 try_string_variants (SCM pred, SCM str)
3766 {
3767         // a matching predicate is always ok
3768         if (scm_is_true (scm_call_1 (pred, str)))
3769                 return str;
3770         // a symbol may be interpreted as a list of symbols if it helps
3771         if (scm_is_symbol (str)) {
3772                 str = scm_list_1 (str);
3773                 if (scm_is_true (scm_call_1 (pred, str)))
3774                         return str;
3775                 return SCM_UNDEFINED;
3776         }
3777
3778         // If this cannot be a string representation of a symbol list,
3779         // we are through.
3780
3781         if (!is_regular_identifier (str, true))
3782                 return SCM_UNDEFINED;
3783
3784         str = scm_string_split (str, SCM_MAKE_CHAR ('.'));
3785         for (SCM p = str; scm_is_pair (p); p = scm_cdr (p))
3786                 scm_set_car_x (p, scm_string_to_symbol (scm_car (p)));
3787
3788         // Let's attempt the symbol list interpretation first.
3789
3790         if (scm_is_true (scm_call_1 (pred, str)))
3791                 return str;
3792
3793         // If there is just one symbol in the list, we might interpret
3794         // it as a single symbol
3795
3796         if (scm_is_null (scm_cdr (str)))
3797         {
3798                 str = scm_car (str);
3799                 if (scm_is_true (scm_call_1 (pred, str)))
3800                         return str;
3801         }
3802
3803         return SCM_UNDEFINED;
3804 }
3805
3806 bool
3807 is_regular_identifier (SCM id, bool multiple)
3808 {
3809   if (!scm_is_string (id))
3810           return false;
3811
3812   string str = ly_scm2string (id);
3813
3814   bool middle = false;
3815
3816   for (string::iterator it=str.begin(); it != str.end (); it++)
3817   {
3818           int c = *it & 0xff;
3819           if ((c >= 'a' && c <= 'z')
3820               || (c >= 'A' && c <= 'Z')
3821               || c > 0x7f)
3822                   middle = true;
3823           else if (middle && (c == '-' || c == '_' || (multiple && c == '.')))
3824                   middle = false;
3825           else
3826                   return false;
3827   }
3828   return middle;
3829 }
3830
3831 SCM
3832 make_music_from_simple (Lily_parser *parser, Input loc, SCM simple)
3833 {
3834         if (Music::unsmob (simple))
3835                 return simple;
3836         if (parser->lexer_->is_note_state ()) {
3837                 if (scm_is_symbol (simple)) {
3838                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
3839                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
3840                         n->set_property ("drum-type", simple);
3841                         return n->unprotect ();
3842                 }
3843                 if (Pitch::unsmob (simple)) {
3844                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
3845                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
3846                         n->set_property ("pitch", simple);
3847                         return n->unprotect ();
3848                 }
3849                 return simple;
3850         } else if (parser->lexer_->is_lyric_state ()) {
3851                 if (Text_interface::is_markup (simple))
3852                         return MAKE_SYNTAX ("lyric-event", loc, simple,
3853                                             parser->default_duration_.smobbed_copy ());
3854         } else if (parser->lexer_->is_chord_state ()) {
3855                 if (Pitch::unsmob (simple))
3856                         return MAKE_SYNTAX
3857                                 ("event-chord",
3858                                  loc,
3859                                  make_chord_elements (loc, simple,
3860                                                       parser->default_duration_.smobbed_copy (),
3861                                                       SCM_EOL));
3862         }
3863         return simple;
3864 }
3865
3866 Music *
3867 make_music_with_input (SCM name, Input where)
3868 {
3869        Music *m = make_music_by_name (name);
3870        m->set_spot (where);
3871        return m;
3872 }
3873
3874 SCM
3875 make_simple_markup (SCM a)
3876 {
3877         return a;
3878 }
3879
3880 SCM
3881 make_duration (SCM d, int dots)
3882 {
3883         int t = scm_to_int (d);
3884         if (t > 0 && (t & (t-1)) == 0)
3885                 return Duration (intlog2 (t), dots).smobbed_copy ();
3886         else
3887                 return SCM_UNDEFINED;
3888 }
3889
3890 SCM
3891 make_chord_step (SCM step_scm, Rational alter)
3892 {
3893         int step = scm_to_int (step_scm);
3894
3895         if (step == 7)
3896                 alter += FLAT_ALTERATION;
3897
3898         while (step < 0)
3899                 step += 7;
3900         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
3901         return m.smobbed_copy ();
3902 }
3903
3904
3905 SCM
3906 make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list)
3907 {
3908         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
3909         SCM res = scm_call_3 (chord_ctor, pitch, dur, modification_list);
3910         for (SCM s = res; scm_is_pair (s); s = scm_cdr (s))
3911         {
3912                 Music::unsmob (scm_car (s))->set_spot (loc);
3913         }
3914         return res;
3915 }
3916
3917 int
3918 yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser)
3919 {
3920         Lily_lexer *lex = parser->lexer_;
3921
3922         lex->lexval_ = s;
3923         lex->lexloc_ = loc;
3924         int tok = lex->pop_extra_token ();
3925         if (tok >= 0)
3926                 return tok;
3927         lex->prepare_for_next_token ();
3928         return lex->yylex ();
3929 }