lily/parser.yy

   1 /* -*- mode: c++; c-file-style: "linux"; indent-tabs-mode: t -*- */
   2 /*
   3   This file is part of LilyPond, the GNU music typesetter.
   4
   5   Copyright (C) 1997--2015 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6                  Jan Nieuwenhuizen <janneke@gnu.org>
   7
   8   LilyPond is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   LilyPond is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  20 */
  21
  22 /* Mode and indentation are at best a rough approximation based on TAB
  23  * formatting (reasonable for compatibility with unspecific editor
  24  * modes as Bison modes are hard to find) and need manual correction
  25  * frequently.  Without a reasonably dependable way of formatting a
  26  * Bison file sensibly, there is little point in trying to fix the
  27  * inconsistent state of indentation.
  28  */
  29
  30 %{
  31
  32 #define yyerror Lily_parser::parser_error
  33
  34 /* We use custom location type: Input objects */
  35 #define YYLTYPE Input
  36 #define YYSTYPE SCM
  37 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  38         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  39
  40 #define YYPRINT(file, type, value)                                      \
  41         do {                                                            \
  42                 if (scm_is_eq (value, SCM_UNSPECIFIED))                 \
  43                         break;                                          \
  44                 SCM s = scm_call_2 (ly_lily_module_constant ("value->lily-string"), \
  45                                     value,                              \
  46                                     parser->self_scm ());               \
  47                 char *p = scm_to_locale_string (s);                     \
  48                 fputs (p, file);                                        \
  49                 free (p);                                               \
  50         } while (0)
  51
  52 %}
  53
  54 %parse-param {Lily_parser *parser}
  55 %parse-param {SCM *retval}
  56 %lex-param {Lily_parser *parser}
  57 %error-verbose
  58 %debug
  59
  60 /* We use SCMs to do strings, because it saves us the trouble of
  61 deleting them.  Let's hope that a stack overflow doesn't trigger a move
  62 of the parse stack onto the heap. */
  63
  64 %left PREC_BOT
  65 %nonassoc REPEAT
  66 %nonassoc ALTERNATIVE
  67
  68 /* The above precedences tackle the shift/reduce problem
  69
  70 1.  \repeat
  71         \repeat .. \alternative
  72
  73     \repeat { \repeat .. \alternative }
  74
  75 or
  76
  77     \repeat { \repeat } \alternative
  78 */
  79
  80 %nonassoc COMPOSITE
  81 %left ADDLYRICS
  82
  83 %right ':' UNSIGNED REAL E_UNSIGNED EVENT_IDENTIFIER EVENT_FUNCTION '^' '_'
  84        HYPHEN EXTENDER DURATION_IDENTIFIER '!'
  85
  86  /* The above are needed for collecting tremoli and other items (that
  87     could otherwise be interpreted as belonging to the next function
  88     argument) greedily, and together with the next rule will serve to
  89     join numbers and units greedily instead of allowing them into
  90     separate function arguments
  91  */
  92
  93 %nonassoc NUMBER_IDENTIFIER
  94
  95 %left PREC_TOP
  96
  97
  98
  99
 100 %pure-parser
 101 %locations
 102
 103
 104
 105 %{ // -*-Fundamental-*-
 106
 107 /*
 108 FIXME:
 109
 110    * The rules for who is protecting what are very shady.  Uniformise
 111      this.
 112
 113    * There are too many lexical modes?
 114 */
 115
 116 #include "config.hh"
 117
 118 #include <cctype>
 119 #include <cstdlib>
 120 #include <cstdio>
 121 using namespace std;
 122
 123 #include "book.hh"
 124 #include "context-def.hh"
 125 #include "context-mod.hh"
 126 #include "dimensions.hh"
 127 #include "file-path.hh"
 128 #include "input.hh"
 129 #include "international.hh"
 130 #include "lily-guile.hh"
 131 #include "lily-lexer.hh"
 132 #include "lily-parser.hh"
 133 #include "main.hh"
 134 #include "misc.hh"
 135 #include "music.hh"
 136 #include "output-def.hh"
 137 #include "paper-book.hh"
 138 #include "scm-hash.hh"
 139 #include "score.hh"
 140 #include "text-interface.hh"
 141 #include "warn.hh"
 142
 143 void
 144 Lily_parser::parser_error (Input const *i, Lily_parser *parser, SCM *, const string &s)
 145 {
 146         parser->parser_error (*i, s);
 147 }
 148
 149 // The following are somewhat precarious constructs as they may change
 150 // the value of the lookahead token.  That implies that the lookahead
 151 // token must not yet have made an impact on the state stack other
 152 // than causing the reduction of the current rule, or switching the
 153 // lookahead token while Bison is mulling it over will cause trouble.
 154
 155 #define MYBACKUP(Token, Value, Location)                                \
 156         do {                                                            \
 157                 if (yychar != YYEMPTY)                                  \
 158                         parser->lexer_->push_extra_token                \
 159                                 (yylloc, yychar, yylval);               \
 160                 if (Token)                                              \
 161                         parser->lexer_->push_extra_token                \
 162                                 (Location, Token, Value);               \
 163                 parser->lexer_->push_extra_token (Location, BACKUP);    \
 164                 yychar = YYEMPTY;                                       \
 165         } while (0)
 166
 167
 168 #define MYREPARSE(Location, Pred, Token, Value)                         \
 169         do {                                                            \
 170                 if (yychar != YYEMPTY)                                  \
 171                         parser->lexer_->push_extra_token                \
 172                                 (yylloc, yychar, yylval);               \
 173                 parser->lexer_->push_extra_token                        \
 174                         (Location, Token, Value);                       \
 175                 parser->lexer_->push_extra_token                        \
 176                         (Location, REPARSE, Pred);                      \
 177                 yychar = YYEMPTY;                                       \
 178         } while (0)
 179
 180 %}
 181
 182
 183 %{
 184
 185 #define MY_MAKE_MUSIC(x, spot) \
 186         make_music_with_input (ly_symbol2scm (x), \
 187                                parser->lexer_->override_input (spot))
 188
 189 /* ES TODO:
 190 - Don't use lily module, create a new module instead.
 191 - delay application of the function
 192 */
 193 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 194   scm_apply_0 (proc, args)
 195 /* Syntactic Sugar. */
 196 #define MAKE_SYNTAX(name, location, ...)                                \
 197         LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (parser->lexer_->override_input (location).smobbed_copy (), ##__VA_ARGS__, SCM_UNDEFINED))
 198 #define START_MAKE_SYNTAX(name, ...)                                    \
 199         scm_list_n (ly_lily_module_constant (name) , ##__VA_ARGS__, SCM_UNDEFINED)
 200 #define FINISH_MAKE_SYNTAX(start, location, ...)                        \
 201         LOWLEVEL_MAKE_SYNTAX (scm_car (start), scm_cons (parser->lexer_->override_input (location).smobbed_copy (), scm_append_x (scm_list_2 (scm_cdr (start), scm_list_n (__VA_ARGS__, SCM_UNDEFINED)))))
 202
 203 SCM get_next_unique_context_id ();
 204 SCM get_next_unique_lyrics_context_id ();
 205
 206 #undef _
 207 #if !HAVE_GETTEXT
 208 #define _(x) x
 209 #else
 210 #include <libintl.h>
 211 #define _(x) gettext (x)
 212 #endif
 213
 214
 215 static Music *make_music_with_input (SCM name, Input where);
 216 SCM check_scheme_arg (Lily_parser *parser, Input loc,
 217                       SCM arg, SCM args, SCM pred, SCM disp = SCM_UNDEFINED);
 218 SCM make_music_from_simple (Lily_parser *parser, Input loc, SCM pitch);
 219 SCM loc_on_music (Input loc, SCM arg);
 220 SCM make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list);
 221 SCM make_chord_step (SCM step, Rational alter);
 222 SCM make_simple_markup (SCM a);
 223 SCM make_duration (SCM t, int dots = 0);
 224 bool is_regular_identifier (SCM id, bool multiple=false);
 225 SCM try_string_variants (SCM pred, SCM str);
 226 int yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser);
 227
 228 %}
 229
 230 /* The third option is an alias that will be used to display the
 231    syntax error.  Bison CVS now correctly handles backslash escapes.
 232
 233    FIXME: Bison needs to translate some of these, eg, STRING.
 234
 235 */
 236
 237 /* Keyword tokens with plain escaped name.  */
 238 %token END_OF_FILE 0 "end of input"
 239 %token ACCEPTS "\\accepts"
 240 %token ADDLYRICS "\\addlyrics"
 241 %token ALIAS "\\alias"
 242 %token ALTERNATIVE "\\alternative"
 243 %token BOOK "\\book"
 244 %token BOOKPART "\\bookpart"
 245 %token CHANGE "\\change"
 246 %token CHORDMODE "\\chordmode"
 247 %token CHORDS "\\chords"
 248 %token CONSISTS "\\consists"
 249 %token CONTEXT "\\context"
 250 %token DEFAULT "\\default"
 251 %token DEFAULTCHILD "\\defaultchild"
 252 %token DENIES "\\denies"
 253 %token DESCRIPTION "\\description"
 254 %token DRUMMODE "\\drummode"
 255 %token DRUMS "\\drums"
 256 %token FIGUREMODE "\\figuremode"
 257 %token FIGURES "\\figures"
 258 %token HEADER "\\header"
 259 %token INVALID "\\version-error"
 260 %token LAYOUT "\\layout"
 261 %token LYRICMODE "\\lyricmode"
 262 %token LYRICS "\\lyrics"
 263 %token LYRICSTO "\\lyricsto"
 264 %token MARKUP "\\markup"
 265 %token MARKUPLIST "\\markuplist"
 266 %token MIDI "\\midi"
 267 %token NAME "\\name"
 268 %token NOTEMODE "\\notemode"
 269 %token OVERRIDE "\\override"
 270 %token PAPER "\\paper"
 271 %token REMOVE "\\remove"
 272 %token REPEAT "\\repeat"
 273 %token REST "\\rest"
 274 %token REVERT "\\revert"
 275 %token SCORE "\\score"
 276 %token SCORELINES "\\score-lines"
 277 %token SEQUENTIAL "\\sequential"
 278 %token SET "\\set"
 279 %token SIMULTANEOUS "\\simultaneous"
 280 %token TEMPO "\\tempo"
 281 %token TYPE "\\type"
 282 %token UNSET "\\unset"
 283 %token WITH "\\with"
 284
 285 /* Keyword token exceptions.  */
 286 %token NEWCONTEXT "\\new"
 287
 288
 289 /* Other string tokens.  */
 290
 291 %token CHORD_BASS "/+"
 292 %token CHORD_CARET "^"
 293 %token CHORD_COLON ":"
 294 %token CHORD_MINUS "-"
 295 %token CHORD_SLASH "/"
 296 %token ANGLE_OPEN "<"
 297 %token ANGLE_CLOSE ">"
 298 %token DOUBLE_ANGLE_OPEN "<<"
 299 %token DOUBLE_ANGLE_CLOSE ">>"
 300 %token E_BACKSLASH "\\"
 301 %token E_EXCLAMATION "\\!"
 302 %token E_PLUS "\\+"
 303 %token EXTENDER "__"
 304
 305 /*
 306 If we give names, Bison complains.
 307 */
 308 %token FIGURE_CLOSE /* "\\>" */
 309 %token FIGURE_OPEN /* "\\<" */
 310 %token FIGURE_SPACE "_"
 311 %token HYPHEN "--"
 312
 313 %token MULTI_MEASURE_REST
 314
 315
 316 %token E_UNSIGNED
 317 %token UNSIGNED
 318
 319 /* Artificial tokens, for more generic function syntax */
 320 %token EXPECT_MARKUP "markup?"
 321 %token EXPECT_SCM "scheme?"
 322 %token BACKUP "(backed-up?)"
 323 %token REPARSE "(reparsed?)"
 324 %token EXPECT_MARKUP_LIST "markup-list?"
 325 %token EXPECT_OPTIONAL "optional?"
 326 /* After the last argument. */
 327 %token EXPECT_NO_MORE_ARGS;
 328
 329 /* An artificial token for parsing embedded Lilypond */
 330 %token EMBEDDED_LILY "#{"
 331
 332 %token BOOK_IDENTIFIER
 333 %token CHORD_MODIFIER
 334 %token CHORD_REPETITION
 335 %token CONTEXT_MOD_IDENTIFIER
 336 %token DRUM_PITCH
 337 %token PITCH_IDENTIFIER
 338 %token DURATION_IDENTIFIER
 339 %token EVENT_IDENTIFIER
 340 %token EVENT_FUNCTION
 341 %token FRACTION
 342 %token LYRIC_ELEMENT
 343 %token MARKUP_FUNCTION
 344 %token MARKUP_LIST_FUNCTION
 345 %token MARKUP_IDENTIFIER
 346 %token MARKUPLIST_IDENTIFIER
 347 %token MUSIC_FUNCTION
 348 %token MUSIC_IDENTIFIER
 349 %token NOTENAME_PITCH
 350 %token NUMBER_IDENTIFIER
 351 %token REAL
 352 %token RESTNAME
 353 %token SCM_ARG
 354 %token SCM_FUNCTION
 355 %token SCM_IDENTIFIER
 356 %token SCM_TOKEN
 357 %token STRING
 358 %token SYMBOL_LIST
 359 %token TONICNAME_PITCH
 360
 361 %left '-' '+'
 362
 363 /* We don't assign precedence to / and *, because we might need varied
 364 prec levels in different prods */
 365
 366 %left UNARY_MINUS
 367
 368 %%
 369
 370 start_symbol:
 371         lilypond
 372         | EMBEDDED_LILY {
 373                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 374                 parser->lexer_->push_note_state (nn);
 375         } embedded_lilypond {
 376                 parser->lexer_->pop_state ();
 377                 *retval = $3;
 378         }
 379         ;
 380
 381 lilypond:       /* empty */ { $$ = SCM_UNSPECIFIED; }
 382         | lilypond toplevel_expression {
 383         }
 384         | lilypond assignment {
 385         }
 386         | lilypond error {
 387                 parser->error_level_ = 1;
 388         }
 389         | lilypond INVALID      {
 390                 parser->error_level_ = 1;
 391         }
 392         ;
 393
 394
 395 toplevel_expression:
 396         {
 397                 parser->lexer_->add_scope (get_header (parser));
 398         } lilypond_header {
 399                 parser->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $2);
 400         }
 401         | book_block {
 402                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-book-handler");
 403                 scm_call_1 (proc, $1);
 404         }
 405         | bookpart_block {
 406                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 407                 scm_call_1 (proc, $1);
 408         }
 409         | BOOK_IDENTIFIER {
 410                 SCM proc = parser->lexer_->lookup_identifier
 411                         (unsmob<Book>($1)->paper_
 412                          ? "toplevel-book-handler"
 413                          : "toplevel-bookpart-handler");
 414                 scm_call_1 (proc, $1);
 415         }
 416         | score_block {
 417                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-score-handler");
 418                 scm_call_1 (proc, $1);
 419         }
 420         | composite_music {
 421                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-music-handler");
 422                 scm_call_1 (proc, $1);
 423         }
 424         | full_markup {
 425                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 426                 scm_call_1 (proc, scm_list_1 ($1));
 427         }
 428         | full_markup_list {
 429                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 430                 scm_call_1 (proc, $1);
 431         }
 432         | SCM_TOKEN {
 433                 // Evaluate and ignore #xxx, as opposed to \xxx
 434                 parser->lexer_->eval_scm_token ($1, @1);
 435         }
 436         | embedded_scm_active
 437         {
 438                 SCM out = SCM_UNDEFINED;
 439                 if (Text_interface::is_markup ($1))
 440                         out = scm_list_1 ($1);
 441                 else if (Text_interface::is_markup_list ($1))
 442                         out = $1;
 443                 if (scm_is_pair (out))
 444                 {
 445                         SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 446                         scm_call_1 (proc, out);
 447                 } else if (unsmob<Score> ($1))
 448                 {
 449                         SCM proc = parser->lexer_->lookup_identifier ("toplevel-score-handler");
 450                         scm_call_1 (proc, $1);
 451                 } else if (Output_def * od = unsmob<Output_def> ($1)) {
 452                         SCM id = SCM_EOL;
 453
 454                         if (to_boolean (od->c_variable ("is-paper")))
 455                                 id = ly_symbol2scm ("$defaultpaper");
 456                         else if (to_boolean (od->c_variable ("is-midi")))
 457                                 id = ly_symbol2scm ("$defaultmidi");
 458                         else if (to_boolean (od->c_variable ("is-layout")))
 459                                 id = ly_symbol2scm ("$defaultlayout");
 460
 461                         parser->lexer_->set_identifier (id, $1);
 462                 } else if (!scm_is_eq ($1, SCM_UNSPECIFIED))
 463                         parser->parser_error (@1, _("bad expression type"));
 464         }
 465         | output_def {
 466                 SCM id = SCM_EOL;
 467                 Output_def * od = unsmob<Output_def> ($1);
 468
 469                 if (to_boolean (od->c_variable ("is-paper")))
 470                         id = ly_symbol2scm ("$defaultpaper");
 471                 else if (to_boolean (od->c_variable ("is-midi")))
 472                         id = ly_symbol2scm ("$defaultmidi");
 473                 else if (to_boolean (od->c_variable ("is-layout")))
 474                         id = ly_symbol2scm ("$defaultlayout");
 475
 476                 parser->lexer_->set_identifier (id, $1);
 477         }
 478         ;
 479
 480 embedded_scm_bare:
 481         SCM_TOKEN
 482         {
 483                 $$ = parser->lexer_->eval_scm_token ($1, @1);
 484         }
 485         | SCM_IDENTIFIER
 486         ;
 487
 488 embedded_scm_active:
 489         SCM_IDENTIFIER
 490         | scm_function_call
 491         ;
 492
 493 embedded_scm_bare_arg:
 494         SCM_ARG
 495         | SCM_TOKEN
 496         {
 497                 $$ = parser->lexer_->eval_scm_token ($1, @1);
 498         }
 499         | FRACTION
 500         | full_markup_list
 501         | context_modification
 502         | score_block
 503         | context_def_spec_block
 504         | book_block
 505         | bookpart_block
 506         | output_def
 507         ;
 508
 509 /* The generic version may end in music, or not */
 510
 511 embedded_scm:
 512         embedded_scm_bare
 513         | scm_function_call
 514         ;
 515
 516 /* embedded_scm_arg is _not_ casting pitches to music by default, this
 517  * has to be done by the function itself.  Note that this may cause
 518  * the results of scm_function_call or embedded_scm_bare_arg to be
 519  * turned into music from pitches as well.  Note that this creates a
 520  * distinctly awkward situation for calculated drum pitches.  Those
 521  * are at the current point of time rejected as music constituents as
 522  * they can't be distinguished from "proper" symbols.
 523  */
 524
 525 embedded_scm_arg:
 526         embedded_scm_bare_arg
 527         | scm_function_call
 528         | music_assign
 529         ;
 530
 531 scm_function_call:
 532         SCM_FUNCTION function_arglist {
 533                 $$ = MAKE_SYNTAX ("music-function", @$,
 534                                          $1, $2);
 535         }
 536         ;
 537
 538 embedded_lilypond_number:
 539         '-' embedded_lilypond_number
 540         {
 541                 $$ = scm_difference ($2, SCM_UNDEFINED);
 542         }
 543         | bare_number_common
 544         | UNSIGNED NUMBER_IDENTIFIER
 545         {
 546                 $$ = scm_product ($1, $2);
 547         }
 548         ;
 549
 550 embedded_lilypond:
 551         /* empty */
 552         {
 553                 // FIXME: @$ does not contain a useful source location
 554                 // for empty rules, and the only token in the whole
 555                 // production, EMBEDDED_LILY, is synthetic and also
 556                 // contains no source location.
 557                 $$ = MAKE_SYNTAX ("void-music", @$);
 558         }
 559         | identifier_init_nonumber
 560         | embedded_lilypond_number
 561         | post_event post_events
 562         {
 563                 $$ = scm_reverse_x ($2, SCM_EOL);
 564                 if (Music *m = unsmob<Music> ($1))
 565                 {
 566                         if (m->is_mus_type ("post-event-wrapper"))
 567                                 $$ = scm_append
 568                                         (scm_list_2 (m->get_property ("elements"),
 569                                                      $$));
 570                         else
 571                                 $$ = scm_cons ($1, $$);
 572                 }
 573                 if (scm_is_pair ($$)
 574                     && scm_is_null (scm_cdr ($$)))
 575                         $$ = scm_car ($$);
 576                 else
 577                 {
 578                         Music * m = MY_MAKE_MUSIC ("PostEvents", @$);
 579                         m->set_property ("elements", $$);
 580                         $$ = m->unprotect ();
 581                 }
 582         }
 583         | multiplied_duration
 584         | music_embedded music_embedded music_list {
 585                 $3 = scm_reverse_x ($3, SCM_EOL);
 586                 if (unsmob<Music> ($2))
 587                         $3 = scm_cons ($2, $3);
 588                 if (unsmob<Music> ($1))
 589                         $3 = scm_cons ($1, $3);
 590                 $$ = MAKE_SYNTAX ("sequential-music", @$, $3);
 591         }
 592         | error {
 593                 parser->error_level_ = 1;
 594                 $$ = SCM_UNSPECIFIED;
 595         }
 596         | INVALID embedded_lilypond {
 597                 parser->error_level_ = 1;
 598                 $$ = $2;
 599         }
 600         ;
 601
 602
 603 lilypond_header_body:
 604         /* empty */ { $$ = SCM_UNSPECIFIED; }
 605         | lilypond_header_body assignment  {
 606
 607         }
 608         | lilypond_header_body embedded_scm  {
 609
 610         }
 611         ;
 612
 613 lilypond_header:
 614         HEADER '{' lilypond_header_body '}'     {
 615                 $$ = parser->lexer_->remove_scope ();
 616         }
 617         ;
 618
 619 /*
 620         DECLARATIONS
 621 */
 622 assignment_id:
 623         STRING          { $$ = $1; }
 624         ;
 625
 626 assignment:
 627         assignment_id '=' identifier_init  {
 628                 parser->lexer_->set_identifier ($1, $3);
 629                 $$ = SCM_UNSPECIFIED;
 630         }
 631         | assignment_id property_path '=' identifier_init {
 632                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 633                 parser->lexer_->set_identifier (path, $4);
 634                 $$ = SCM_UNSPECIFIED;
 635         }
 636         | assignment_id '.' property_path '=' identifier_init {
 637                 SCM path = scm_cons (scm_string_to_symbol ($1), $3);
 638                 parser->lexer_->set_identifier (path, $5);
 639                 $$ = SCM_UNSPECIFIED;
 640         }
 641         ;
 642
 643
 644 identifier_init:
 645         identifier_init_nonumber
 646         | number_expression
 647         | post_event_nofinger post_events
 648         {
 649                 $$ = scm_reverse_x ($2, SCM_EOL);
 650                 if (Music *m = unsmob<Music> ($1))
 651                 {
 652                         if (m->is_mus_type ("post-event-wrapper"))
 653                                 $$ = scm_append
 654                                         (scm_list_2 (m->get_property ("elements"),
 655                                                      $$));
 656                         else
 657                                 $$ = scm_cons ($1, $$);
 658                 }
 659                 if (scm_is_pair ($$)
 660                     && scm_is_null (scm_cdr ($$)))
 661                         $$ = scm_car ($$);
 662                 else
 663                 {
 664                         Music * m = MY_MAKE_MUSIC ("PostEvents", @$);
 665                         m->set_property ("elements", $$);
 666                         $$ = m->unprotect ();
 667                 }
 668         }
 669         ;
 670
 671 identifier_init_nonumber:
 672         score_block
 673         | book_block
 674         | bookpart_block
 675         | output_def
 676         | context_def_spec_block
 677         | music_assign
 678         | pitch_or_music
 679         | FRACTION
 680         | string
 681         | embedded_scm
 682         | full_markup_list
 683         | context_modification
 684         ;
 685
 686 context_def_spec_block:
 687         CONTEXT '{' context_def_spec_body '}'
 688         {
 689                 $$ = $3;
 690                 Context_def *td = unsmob<Context_def> ($$);
 691                 if (!td) {
 692                         $$ = Context_def::make_scm ();
 693                         td = unsmob<Context_def> ($$);
 694                 }
 695                 td->origin ()->set_spot (@$);
 696         }
 697         ;
 698
 699 context_mod_arg:
 700         embedded_scm
 701         |
 702         {
 703                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 704                 parser->lexer_->push_note_state (nn);
 705         }
 706         composite_music
 707         {
 708                 parser->lexer_->pop_state ();
 709                 $$ = $2;
 710         }
 711         ;
 712
 713
 714 context_def_spec_body:
 715         /**/ {
 716                 $$ = SCM_UNSPECIFIED;
 717         }
 718         | context_def_spec_body context_mod {
 719                 if (!SCM_UNBNDP ($2)) {
 720                         Context_def *td = unsmob<Context_def> ($$);
 721                         if (!td) {
 722                                 $$ = Context_def::make_scm ();
 723                                 td = unsmob<Context_def> ($$);
 724                         }
 725                         unsmob<Context_def> ($$)->add_context_mod ($2);
 726                 }
 727         }
 728         | context_def_spec_body context_modification {
 729                 Context_def *td = unsmob<Context_def> ($$);
 730                 if (!td) {
 731                         $$ = Context_def::make_scm ();
 732                         td = unsmob<Context_def> ($$);
 733                 }
 734                 SCM new_mods = unsmob<Context_mod> ($2)->get_mods ();
 735                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 736                     td->add_context_mod (scm_car (m));
 737                 }
 738         }
 739         | context_def_spec_body context_mod_arg {
 740                 Context_def *td = unsmob<Context_def> ($1);
 741                 if (scm_is_eq ($2, SCM_UNSPECIFIED))
 742                         ;
 743                 else if (!td && unsmob<Context_def> ($2))
 744                         $$ = $2;
 745                 else {
 746                         if (!td) {
 747                                 $$ = Context_def::make_scm ();
 748                                 td = unsmob<Context_def> ($$);
 749                         }
 750                         if (unsmob<Music> ($2)) {
 751                                 SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
 752                                 $2 = scm_call_1 (proc, $2);
 753                         }
 754                         if (Context_mod *cm = unsmob<Context_mod> ($2)) {
 755                                 for (SCM m = cm->get_mods (); scm_is_pair (m); m = scm_cdr (m)) {
 756                                         td->add_context_mod (scm_car (m));
 757                                 }
 758                         } else
 759                                 parser->parser_error (@2, _ ("not a context mod"));
 760                 }
 761         }
 762         ;
 763
 764
 765
 766 book_block:
 767         BOOK '{' book_body '}'  {
 768                 $$ = $3;
 769                 unsmob<Book> ($$)->origin ()->set_spot (@$);
 770                 pop_paper (parser);
 771                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 772         }
 773         ;
 774
 775 /* FIXME:
 776    * Use 'handlers' like for toplevel-* stuff?
 777    * grok \layout and \midi?  */
 778 book_body:
 779         {
 780                 Book *book = new Book;
 781                 init_papers (parser);
 782                 book->paper_ = dynamic_cast<Output_def*> (unsmob<Output_def> (parser->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 783                 book->paper_->unprotect ();
 784                 push_paper (parser, book->paper_);
 785                 book->header_ = get_header (parser);
 786                 $$ = book->unprotect ();
 787                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$);
 788         }
 789         | BOOK_IDENTIFIER {
 790                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 791         }
 792         | book_body paper_block {
 793                 unsmob<Book> ($1)->paper_ = unsmob<Output_def> ($2);
 794                 set_paper (parser, unsmob<Output_def> ($2));
 795         }
 796         | book_body bookpart_block {
 797                 SCM proc = parser->lexer_->lookup_identifier ("book-bookpart-handler");
 798                 scm_call_2 (proc, $1, $2);
 799         }
 800         | book_body score_block {
 801                 SCM proc = parser->lexer_->lookup_identifier ("book-score-handler");
 802                 scm_call_2 (proc, $1, $2);
 803         }
 804         | book_body composite_music {
 805                 SCM proc = parser->lexer_->lookup_identifier ("book-music-handler");
 806                 scm_call_2 (proc, $1, $2);
 807         }
 808         | book_body full_markup {
 809                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 810                 scm_call_2 (proc, $1, scm_list_1 ($2));
 811         }
 812         | book_body full_markup_list {
 813                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 814                 scm_call_2 (proc, $1, $2);
 815         }
 816         | book_body SCM_TOKEN {
 817                 // Evaluate and ignore #xxx, as opposed to \xxx
 818                 parser->lexer_->eval_scm_token ($2, @2);
 819         }
 820         | book_body embedded_scm_active
 821         {
 822                 SCM out = SCM_UNDEFINED;
 823                 if (Text_interface::is_markup ($2))
 824                         out = scm_list_1 ($2);
 825                 else if (Text_interface::is_markup_list ($2))
 826                         out = $2;
 827                 if (scm_is_pair (out))
 828                 {
 829                         SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 830                         scm_call_2 (proc, $1, out);
 831                 } else if (unsmob<Score> ($2))
 832                 {
 833                         SCM proc = parser->lexer_->lookup_identifier ("book-score-handler");
 834                         scm_call_2 (proc, $1, $2);
 835                 } else if (Output_def *od = unsmob<Output_def> ($2)) {
 836                         SCM id = SCM_EOL;
 837
 838                         if (to_boolean (od->c_variable ("is-paper")))
 839                                 id = ly_symbol2scm ("$defaultpaper");
 840                         else if (to_boolean (od->c_variable ("is-midi")))
 841                                 id = ly_symbol2scm ("$defaultmidi");
 842                         else if (to_boolean (od->c_variable ("is-layout")))
 843                                 id = ly_symbol2scm ("$defaultlayout");
 844
 845                         parser->lexer_->set_identifier (id, $2);
 846                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
 847                         parser->parser_error (@2, _("bad expression type"));
 848         }
 849         | book_body
 850         {
 851                 parser->lexer_->add_scope (unsmob<Book> ($1)->header_);
 852         } lilypond_header
 853         | book_body error {
 854                 Book *book = unsmob<Book> ($1);
 855                 book->paper_ = 0;
 856                 book->scores_ = SCM_EOL;
 857                 book->bookparts_ = SCM_EOL;
 858         }
 859         ;
 860
 861 bookpart_block:
 862         BOOKPART '{' bookpart_body '}' {
 863                 $$ = $3;
 864                 unsmob<Book> ($$)->origin ()->set_spot (@$);
 865                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 866         }
 867         ;
 868
 869 bookpart_body:
 870         {
 871                 Book *book = new Book;
 872                 $$ = book->unprotect ();
 873                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$);
 874         }
 875         | BOOK_IDENTIFIER {
 876                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 877         }
 878         | bookpart_body paper_block {
 879                 unsmob<Book> ($$)->paper_ = unsmob<Output_def> ($2);
 880         }
 881         | bookpart_body score_block {
 882                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-score-handler");
 883                 scm_call_2 (proc, $1, $2);
 884         }
 885         | bookpart_body composite_music {
 886                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-music-handler");
 887                 scm_call_2 (proc, $1, $2);
 888         }
 889         | bookpart_body full_markup {
 890                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 891                 scm_call_2 (proc, $1, scm_list_1 ($2));
 892         }
 893         | bookpart_body full_markup_list {
 894                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 895                 scm_call_2 (proc, $1, $2);
 896         }
 897         | bookpart_body SCM_TOKEN {
 898                 // Evaluate and ignore #xxx, as opposed to \xxx
 899                 parser->lexer_->eval_scm_token ($2, @2);
 900         }
 901         | bookpart_body embedded_scm_active
 902         {
 903                 SCM out = SCM_UNDEFINED;
 904                 if (Text_interface::is_markup ($2))
 905                         out = scm_list_1 ($2);
 906                 else if (Text_interface::is_markup_list ($2))
 907                         out = $2;
 908                 if (scm_is_pair (out))
 909                 {
 910                         SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 911                         scm_call_2 (proc, $1, out);
 912                 } else if (unsmob<Score> ($2))
 913                 {
 914                         SCM proc = parser->lexer_->lookup_identifier ("bookpart-score-handler");
 915                         scm_call_2 (proc, $1, $2);
 916                 } else if (Output_def *od = unsmob<Output_def> ($2)) {
 917                         SCM id = SCM_EOL;
 918
 919                         if (to_boolean (od->c_variable ("is-paper")))
 920                                 id = ly_symbol2scm ("$defaultpaper");
 921                         else if (to_boolean (od->c_variable ("is-midi")))
 922                                 id = ly_symbol2scm ("$defaultmidi");
 923                         else if (to_boolean (od->c_variable ("is-layout")))
 924                                 id = ly_symbol2scm ("$defaultlayout");
 925
 926                         parser->lexer_->set_identifier (id, $2);
 927                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
 928                         parser->parser_error (@2, _("bad expression type"));
 929         }
 930         | bookpart_body
 931         {
 932                 Book *book = unsmob<Book> ($1);
 933                 if (!ly_is_module (book->header_))
 934                         book->header_ = ly_make_module (false);
 935                 parser->lexer_->add_scope (book->header_);
 936         } lilypond_header
 937         | bookpart_body error {
 938                 Book *book = unsmob<Book> ($1);
 939                 book->paper_ = 0;
 940                 book->scores_ = SCM_EOL;
 941         }
 942         ;
 943
 944 score_block:
 945         SCORE '{' score_body '}'        {
 946                 unsmob<Score> ($3)->origin ()->set_spot (@$);
 947                 $$ = $3;
 948         }
 949         ;
 950
 951 score_body:
 952         score_items {
 953                 if (!unsmob<Score> ($1)) {
 954                         parser->parser_error (@1, _("Missing music in \\score"));
 955                         $$ = (new Score)->unprotect ();
 956                         if (scm_is_pair ($1) && ly_is_module (scm_car ($1)))
 957                         {
 958                                 unsmob<Score> ($$)->set_header (scm_car ($1));
 959                                 $1 = scm_cdr ($1);
 960                         }
 961                         for (SCM p = scm_reverse_x ($1, SCM_EOL);
 962                              scm_is_pair (p); p = scm_cdr (p))
 963                         {
 964                                 unsmob<Score> ($$)->
 965                                         add_output_def (unsmob<Output_def> (scm_car (p)));
 966                         }
 967                 }
 968         }
 969         | score_body error {
 970                 unsmob<Score> ($$)->error_found_ = true;
 971         }
 972         ;
 973
 974 score_item:
 975         embedded_scm
 976         | music
 977         | output_def
 978         ;
 979
 980 score_items:
 981         /* empty */
 982         {
 983                 $$ = SCM_EOL;
 984         }
 985         | score_items score_item
 986         {
 987                 Output_def *od = unsmob<Output_def> ($2);
 988                 if (od) {
 989                         if (to_boolean (od->lookup_variable (ly_symbol2scm ("is-paper"))))
 990                         {
 991                                 parser->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 992                                 od = 0;
 993                                 $2 = SCM_UNSPECIFIED;
 994                         }
 995                 } else if (!unsmob<Score> ($$)) {
 996                         if (unsmob<Music> ($2)) {
 997                                 SCM scorify = ly_lily_module_constant ("scorify-music");
 998                                 $2 = scm_call_1 (scorify, $2);
 999                         }
1000                         if (unsmob<Score> ($2))
1001                         {
1002                                 $$ = $2;
1003                                 $2 = SCM_UNSPECIFIED;
1004                         }
1005                 }
1006                 Score *score = unsmob<Score> ($$);
1007                 if (score && scm_is_pair ($1)) {
1008                         if (ly_is_module (scm_car ($1)))
1009                         {
1010                                 score->set_header (scm_car ($1));
1011                                 $1 = scm_cdr ($1);
1012                         }
1013                         for (SCM p = scm_reverse_x ($1, SCM_EOL);
1014                              scm_is_pair (p); p = scm_cdr (p))
1015                         {
1016                                 score->add_output_def (unsmob<Output_def> (scm_car (p)));
1017                         }
1018                 }
1019                 if (od) {
1020                         if (score)
1021                                 score->add_output_def (od);
1022                         else if (scm_is_pair ($$) && ly_is_module (scm_car ($$)))
1023                                 scm_set_cdr_x ($$, scm_cons ($2, scm_cdr ($$)));
1024                         else
1025                                 $$ = scm_cons ($2, $$);
1026                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
1027                         parser->parser_error (@2, _("Spurious expression in \\score"));
1028         }
1029         | score_items
1030         {
1031                 if (Score *score = unsmob<Score> ($1)) {
1032                         if (!ly_is_module (score->get_header ()))
1033                                 score->set_header (ly_make_module (false));
1034                         parser->lexer_->add_scope (score->get_header ());
1035                 } else {
1036                         if (!scm_is_pair ($1) || !ly_is_module (scm_car ($1)))
1037                                 $1 = scm_cons (ly_make_module (false), $1);
1038                         parser->lexer_->add_scope (scm_car ($1));
1039                 }
1040         } lilypond_header
1041         {
1042                 $$ = $1;
1043         }
1044         ;
1045
1046
1047 /*
1048         OUTPUT DEF
1049 */
1050
1051 paper_block:
1052         output_def {
1053                 Output_def *od = unsmob<Output_def> ($1);
1054
1055                 if (!to_boolean (od->lookup_variable (ly_symbol2scm ("is-paper"))))
1056                 {
1057                         parser->parser_error (@1, _ ("need \\paper for paper block"));
1058                         $$ = get_paper (parser)->unprotect ();
1059                 }
1060         }
1061         ;
1062
1063
1064 output_def:
1065         output_def_body '}' {
1066                 if (scm_is_pair ($1))
1067                         $$ = scm_car ($1);
1068
1069                 parser->lexer_->remove_scope ();
1070                 parser->lexer_->pop_state ();
1071         }
1072         ;
1073
1074 output_def_head:
1075         PAPER {
1076                 Output_def *p = get_paper (parser);
1077                 p->input_origin_ = @$;
1078                 parser->lexer_->add_scope (p->scope_);
1079                 $$ = p->unprotect ();
1080         }
1081         | MIDI    {
1082                 Output_def *p = get_midi (parser);
1083                 $$ = p->unprotect ();
1084                 parser->lexer_->add_scope (p->scope_);
1085         }
1086         | LAYOUT        {
1087                 Output_def *p = get_layout (parser);
1088
1089                 parser->lexer_->add_scope (p->scope_);
1090                 $$ = p->unprotect ();
1091         }
1092         ;
1093
1094 output_def_head_with_mode_switch:
1095         output_def_head {
1096                 parser->lexer_->push_initial_state ();
1097                 $$ = $1;
1098         }
1099         ;
1100
1101 // We need this weird nonterminal because both music as well as a
1102 // context definition can start with \context and the difference is
1103 // only apparent after looking at the next token.  If it is '{', there
1104 // is still time to escape from notes mode.
1105
1106 music_or_context_def:
1107         music_assign
1108         | context_def_spec_block
1109         ;
1110
1111 output_def_body:
1112         output_def_head_with_mode_switch '{' {
1113                 unsmob<Output_def> ($1)->input_origin_.set_spot (@$);
1114                 // This is a stupid trick to mark the beginning of the
1115                 // body for deciding whether to allow
1116                 // embedded_scm_active to have an output definition
1117                 $$ = scm_list_1 ($1);
1118         }
1119         | output_def_body assignment  {
1120                 if (scm_is_pair ($1))
1121                         $$ = scm_car ($1);
1122         }
1123         | output_def_body embedded_scm_active
1124         {
1125                 // We don't switch into note mode for Scheme functions
1126                 // here.  Does not seem warranted/required in output
1127                 // definitions.
1128                 if (scm_is_pair ($1))
1129                 {
1130                         Output_def *o = unsmob<Output_def> ($2);
1131                         if (o) {
1132                                 o->input_origin_.set_spot (@$);
1133                                 $1 = o->self_scm ();
1134                                 parser->lexer_->remove_scope ();
1135                                 parser->lexer_->add_scope (o->scope_);
1136                                 $2 = SCM_UNSPECIFIED;
1137                         } else
1138                                 $1 = scm_car ($1);
1139                 }
1140                 if (unsmob<Context_def> ($2))
1141                         assign_context_def (unsmob<Output_def> ($1), $2);
1142                 // Seems unlikely, but let's be complete:
1143                 else if (unsmob<Music> ($2))
1144                 {
1145                         SCM proc = parser->lexer_->lookup_identifier
1146                                 ("output-def-music-handler");
1147                         scm_call_2 (proc, $1, $2);
1148                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
1149                         parser->parser_error (@2, _("bad expression type"));
1150                 $$ = $1;
1151         }
1152         | output_def_body SCM_TOKEN {
1153                 if (scm_is_pair ($1))
1154                         $$ = scm_car ($1);
1155                 // Evaluate and ignore #xxx, as opposed to \xxx
1156                 parser->lexer_->eval_scm_token ($2, @2);
1157         }
1158         | output_def_body
1159         {
1160                 if (scm_is_pair ($1))
1161                         $1 = scm_car ($1);
1162                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
1163                 parser->lexer_->push_note_state (nn);
1164         } music_or_context_def
1165         {
1166                 parser->lexer_->pop_state ();
1167                 if (unsmob<Context_def> ($3))
1168                         assign_context_def (unsmob<Output_def> ($1), $3);
1169                 else {
1170
1171                         SCM proc = parser->lexer_->lookup_identifier
1172                                      ("output-def-music-handler");
1173                         scm_call_2 (proc, $1, $3);
1174                 }
1175                 $$ = $1;
1176         }
1177         | output_def_body error {
1178
1179         }
1180         ;
1181
1182 tempo_event:
1183         TEMPO steno_duration '=' tempo_range    {
1184                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_EOL, $2, $4);
1185         }
1186         | TEMPO scalar steno_duration '=' tempo_range   {
1187                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
1188         }
1189         | TEMPO scalar {
1190                 $$ = MAKE_SYNTAX ("tempo", @$, $2);
1191         } %prec ':'
1192         ;
1193
1194 /*
1195 The representation of a  list is reversed to have efficient append.  */
1196
1197 music_list:
1198         /* empty */ {
1199                 $$ = SCM_EOL;
1200         }
1201         | music_list music_embedded {
1202                 if (unsmob<Music> ($2))
1203                         $$ = scm_cons ($2, $1);
1204         }
1205         | music_list error {
1206                 Music *m = MY_MAKE_MUSIC("Music", @$);
1207                 // ugh. code dup
1208                 m->set_property ("error-found", SCM_BOOL_T);
1209                 $$ = scm_cons (m->self_scm (), $1);
1210                 m->unprotect (); /* UGH */
1211         }
1212         ;
1213
1214 braced_music_list:
1215         '{' music_list '}'
1216         {
1217                 $$ = scm_reverse_x ($2, SCM_EOL);
1218         }
1219         ;
1220
1221 music:  music_assign
1222         | lyric_element_music
1223         | pitch_as_music
1224         ;
1225
1226 pitch_as_music:
1227         pitch_or_music
1228         {
1229                 $$ = make_music_from_simple (parser, @1, $1);
1230                 if (!unsmob<Music> ($$))
1231                 {
1232                         parser->parser_error (@1, _ ("music expected"));
1233                         $$ = MAKE_SYNTAX ("void-music", @$);
1234                 }
1235         }
1236         ;
1237
1238 music_embedded:
1239         music
1240         {
1241                 if (unsmob<Music> ($1)->is_mus_type ("post-event")) {
1242                         parser->parser_error (@1, _ ("unexpected post-event"));
1243                         $$ = SCM_UNSPECIFIED;
1244                 }
1245         }
1246         | music_embedded_backup
1247         {
1248                 $$ = $1;
1249         }
1250         | music_embedded_backup BACKUP lyric_element_music
1251         {
1252                 $$ = $3;
1253         }
1254         | multiplied_duration post_events
1255         {
1256                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1257
1258                 parser->default_duration_ = *unsmob<Duration> ($1);
1259                 n->set_property ("duration", $1);
1260
1261                 if (scm_is_pair ($2))
1262                         n->set_property ("articulations",
1263                                          scm_reverse_x ($2, SCM_EOL));
1264                 $$ = n->unprotect ();
1265         }
1266         ;
1267
1268 music_embedded_backup:
1269         embedded_scm
1270         {
1271                 if (scm_is_eq ($1, SCM_UNSPECIFIED))
1272                         $$ = $1;
1273                 else if (Music *m = unsmob<Music> ($1)) {
1274                         if (m->is_mus_type ("post-event")) {
1275                                 parser->parser_error
1276                                         (@1, _ ("unexpected post-event"));
1277                                 $$ = SCM_UNSPECIFIED;
1278                         } else
1279                                 $$ = $1;
1280                 } else if (parser->lexer_->is_lyric_state ()
1281                            && Text_interface::is_markup ($1))
1282                         MYBACKUP (LYRIC_ELEMENT, $1, @1);
1283                 else {
1284                         @$.warning (_ ("Ignoring non-music expression"));
1285                         $$ = $1;
1286                 }
1287         }
1288         ;
1289
1290 // music_assign does not need to contain lyrics: there are no
1291 // assignments in lyricmode.
1292 music_assign:
1293         simple_music
1294         | composite_music %prec COMPOSITE
1295         ;
1296
1297 repeated_music:
1298         REPEAT simple_string unsigned_number music
1299         {
1300                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, SCM_EOL);
1301         }
1302         | REPEAT simple_string unsigned_number music ALTERNATIVE braced_music_list
1303         {
1304                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $6);
1305         }
1306         ;
1307
1308 sequential_music:
1309         SEQUENTIAL braced_music_list {
1310                 $$ = MAKE_SYNTAX ("sequential-music", @$, $2);
1311         }
1312         | braced_music_list {
1313                 $$ = MAKE_SYNTAX ("sequential-music", @$, $1);
1314         }
1315         ;
1316
1317 simultaneous_music:
1318         SIMULTANEOUS braced_music_list {
1319                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, $2);
1320         }
1321         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1322                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($2, SCM_EOL));
1323         }
1324         ;
1325
1326 simple_music:
1327         event_chord
1328         | music_property_def
1329         | context_change
1330         ;
1331
1332 context_modification:
1333         WITH
1334         {
1335                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
1336                 parser->lexer_->push_note_state (nn);
1337         } '{' context_mod_list '}'
1338         {
1339                 parser->lexer_->pop_state ();
1340                 $$ = $4;
1341         }
1342         | WITH CONTEXT_MOD_IDENTIFIER
1343         {
1344                 $$ = $2;
1345         }
1346         | CONTEXT_MOD_IDENTIFIER
1347         {
1348                 $$ = $1;
1349         }
1350         | WITH context_modification_arg
1351         {
1352                 if (unsmob<Music> ($2)) {
1353                         SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
1354                         $2 = scm_call_1 (proc, $2);
1355                 }
1356                 if (unsmob<Context_mod> ($2))
1357                         $$ = $2;
1358                 else {
1359                         parser->parser_error (@2, _ ("not a context mod"));
1360                         $$ = Context_mod ().smobbed_copy ();
1361                 }
1362         }
1363         ;
1364
1365 context_modification_arg:
1366         embedded_scm
1367         | MUSIC_IDENTIFIER
1368         ;
1369
1370 optional_context_mod:
1371         /**/ {
1372             $$ = SCM_EOL;
1373         }
1374         | context_modification
1375         {
1376               $$ = $1;
1377         }
1378         ;
1379
1380 context_mod_list:
1381         /**/ {
1382             $$ = Context_mod ().smobbed_copy ();
1383         }
1384         | context_mod_list context_mod  {
1385                 if (!SCM_UNBNDP ($2))
1386                         unsmob<Context_mod> ($1)->add_context_mod ($2);
1387         }
1388         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1389                  Context_mod *md = unsmob<Context_mod> ($2);
1390                  if (md)
1391                      unsmob<Context_mod> ($1)->add_context_mods (md->get_mods ());
1392         }
1393         | context_mod_list context_mod_arg {
1394                 if (scm_is_eq ($2, SCM_UNSPECIFIED))
1395                         ;
1396                 else if (unsmob<Music> ($2)) {
1397                         SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
1398                         $2 = scm_call_1 (proc, $2);
1399                 }
1400                 if (unsmob<Context_mod> ($2))
1401                         unsmob<Context_mod> ($$)->add_context_mods
1402                                 (unsmob<Context_mod> ($2)->get_mods ());
1403                 else {
1404                         parser->parser_error (@2, _ ("not a context mod"));
1405                 }
1406         }
1407         ;
1408
1409 context_prefix:
1410         CONTEXT symbol optional_id optional_context_mod {
1411                 Context_mod *ctxmod = unsmob<Context_mod> ($4);
1412                 SCM mods = SCM_EOL;
1413                 if (ctxmod)
1414                         mods = ctxmod->get_mods ();
1415                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_F);
1416         }
1417         | NEWCONTEXT symbol optional_id optional_context_mod {
1418                 Context_mod *ctxmod = unsmob<Context_mod> ($4);
1419                 SCM mods = SCM_EOL;
1420                 if (ctxmod)
1421                         mods = ctxmod->get_mods ();
1422                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_T);
1423         }
1424         ;
1425
1426 new_lyrics:
1427         ADDLYRICS lyric_mode_music {
1428                 $$ = scm_list_1 ($2);
1429         }
1430         | new_lyrics ADDLYRICS lyric_mode_music {
1431                 $$ = scm_cons ($3, $1);
1432         }
1433         ;
1434
1435 /* basic_music is basically the same as composite_music but with
1436  * context-prefixed music and lyricized music explicitly removed.  The
1437  * reason is that in a sequence
1438  *
1439  *   \new Staff \new Voice { ... } \addlyrics { ... } \addlyrics { ... }
1440  *
1441  * we need to group both \addlyrics together (as they go with the same
1442  * voice) but then combine them with \new Voice { ... }, meaning that
1443  * combining \new Voice { ... } needs higher priority than
1444  * { ... } \addlyrics, and *not* have \new Staff \new Voice { ... }
1445  * combine before combining \new Voice { ... } \addlyrics: only one
1446  * layer of context-prefixed music should assemble before \addlyrics
1447  * is integrated.  Total mess, and we sort this mess out with explicit
1448  * rules preferring a single context-prefix.
1449  */
1450
1451 basic_music:
1452         music_function_call
1453         | repeated_music
1454         | music_bare
1455         | LYRICSTO simple_string lyric_mode_music {
1456                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, SCM_EOL, $3);
1457         }
1458         | LYRICSTO symbol '=' simple_string lyric_mode_music
1459         {
1460                 $$ = MAKE_SYNTAX ("lyric_combine", @$, $3, $2, $4);
1461         }
1462         ;
1463
1464 contextable_music:
1465         basic_music
1466         | pitch_as_music
1467         | event_chord
1468         ;
1469
1470 contexted_basic_music:
1471         context_prefix contextable_music new_lyrics
1472         {
1473                 Input i;
1474                 i.set_location (@1, @2);
1475                 $$ = FINISH_MAKE_SYNTAX ($1, i, $2);
1476                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $$, scm_reverse_x ($3, SCM_EOL));
1477         } %prec COMPOSITE
1478         | context_prefix contextable_music
1479         {
1480                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1481         } %prec COMPOSITE
1482         | context_prefix contexted_basic_music
1483         {
1484                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1485         }
1486         ;
1487
1488 composite_music:
1489         basic_music %prec COMPOSITE
1490         | contexted_basic_music
1491         | basic_music new_lyrics
1492         {
1493                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1494         } %prec COMPOSITE
1495         ;
1496
1497 music_bare:
1498         mode_changed_music
1499         | MUSIC_IDENTIFIER
1500         | grouped_music_list
1501         ;
1502
1503 grouped_music_list:
1504         simultaneous_music              { $$ = $1; }
1505         | sequential_music              { $$ = $1; }
1506         ;
1507
1508 /* Function argument lists are arguably the most complex part in the
1509  * parser.  They are pretty tricky to understand because of the way
1510  * they are processed, and because of optional arguments that can be
1511  * omitted.  When there are several optional arguments in a row,
1512  * omitting one automatically omits all following arguments.  Optional
1513  * arguments can only be omitted when either
1514  *
1515  * a) the omission is explicitly started with \default
1516  * b) the omission is implicitly started by an argument not matching
1517  *    its predicate, and there is a mandatory argument later that can
1518  *    "catch" the argument that does not fit.
1519  *
1520  * When argument parsing starts, the lexer pushes EXPECT_SCM tokens
1521  * (corresponding to mandatory arguments and having a predicate
1522  * function as semantic value) or EXPECT_OPTIONAL EXPECT_SCM (where
1523  * the semantic value of the EXPECT_OPTIONAL token is the default to
1524  * use when the optional argument is omitted, and EXPECT_SCM again has
1525  * the argument predicate as semantic value) in reverse order to the
1526  * parser, followed by EXPECT_NO_MORE_ARGS.  The argument list is then
1527  * processed inside-out while actual tokens are consumed.
1528  *
1529  * This means that the argument list tokens determine the actions
1530  * taken as they arrive.  The structure of the argument list is known
1531  * to the parser and stored in its parse stack when the first argument
1532  * is being parsed.  What the parser does not know is which predicates
1533  * will match and whether or not \default will be appearing in the
1534  * argument list, and where.
1535  *
1536  * Sequences of 0 or more optional arguments are scanned using either
1537  * function_arglist_backup or function_arglist_nonbackup.  The first
1538  * is used when optional arguments are followed by at least one
1539  * mandatory argument: in that case optional arguments may be skipped
1540  * by either a false predicate (in which case the expression will be
1541  * pushed back as one or more tokens, preceded by a BACKUP token) or
1542  * by using \default.
1543  *
1544  * If optional arguments are at the end of the argument list, they are
1545  * instead scanned using function_arglist_nonbackup: here the only
1546  * manner to enter into skipping of optional arguments is the use of
1547  * \default.
1548  *
1549  * The argument list of a normal function call is parsed using
1550  * function_arglist.  The part of an argument list before a mandatory
1551  * argument is parsed using function_arglist_optional.
1552  *
1553  * The difference is that leading optional arguments are scanned using
1554  * function_arglist_nonbackup and function_arglist_backup,
1555  * respectively.
1556  *
1557  * Most other details are obvious in the rules themselves.
1558  *
1559  */
1560
1561 symbol_list_arg:
1562         SYMBOL_LIST
1563         | SYMBOL_LIST '.' symbol_list_rev
1564         {
1565                 $$ = scm_append (scm_list_2 ($1, scm_reverse_x ($3, SCM_EOL)));
1566         }
1567         ;
1568
1569 symbol_list_rev:
1570         symbol_list_part
1571         | symbol_list_rev '.' symbol_list_part
1572         {
1573                 $$ = scm_append_x (scm_list_2 ($3, $1));
1574         }
1575         ;
1576
1577 // symbol_list_part delivers elements in reverse copy.
1578
1579 symbol_list_part:
1580         symbol_list_element
1581         {
1582                 SCM sym_l_p = ly_lily_module_constant ("symbol-list?");
1583                 $$ = try_string_variants (sym_l_p, $1);
1584                 if (SCM_UNBNDP ($$)) {
1585                         parser->parser_error (@1, _("not a symbol"));
1586                         $$ = SCM_EOL;
1587                 } else
1588                         $$ = scm_reverse ($$);
1589         }
1590         ;
1591
1592
1593 symbol_list_element:
1594         STRING
1595         | embedded_scm_bare
1596         ;
1597
1598
1599 function_arglist_nonbackup:
1600         function_arglist_common
1601         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup post_event_nofinger
1602         {
1603                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1604         }
1605         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' UNSIGNED
1606         {
1607                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1608                 if (scm_is_true (scm_call_1 ($2, n)))
1609                         $$ = scm_cons (n, $3);
1610                 else {
1611                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1612                         t->set_property ("digit", $5);
1613                         $$ = check_scheme_arg (parser, @4, t->unprotect (),
1614                                                $3, $2, n);
1615                 }
1616         }
1617         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' REAL
1618         {
1619                 $$ = check_scheme_arg (parser, @4,
1620                                        scm_difference ($5, SCM_UNDEFINED),
1621                                        $3, $2);
1622         }
1623         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' NUMBER_IDENTIFIER
1624         {
1625                 $$ = check_scheme_arg (parser, @4,
1626                                        scm_difference ($5, SCM_UNDEFINED),
1627                                        $3, $2);
1628         }
1629         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup embedded_scm_arg
1630         {
1631                 if (scm_is_true (scm_call_1 ($2, $4)))
1632                         $$ = scm_cons ($4, $3);
1633                 else
1634                         $$ = check_scheme_arg (parser, @4,
1635                                                make_music_from_simple
1636                                                (parser, @4, $4),
1637                                                $3, $2);
1638         }
1639         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup bare_number_common
1640         {
1641                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1642         }
1643         | function_arglist_nonbackup_reparse REPARSE pitch_or_music
1644         {
1645                 if (scm_is_true (scm_call_1 ($2, $3)))
1646                         $$ = scm_cons ($3, $1);
1647                 else
1648                         $$ = check_scheme_arg (parser, @3,
1649                                                make_music_from_simple
1650                                                (parser, @3, $3),
1651                                                $1, $2);
1652         }
1653         | function_arglist_nonbackup_reparse REPARSE duration_length
1654         {
1655                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1656         }
1657         | function_arglist_nonbackup_reparse REPARSE bare_number_common
1658         {
1659                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1660         }
1661         | function_arglist_nonbackup_reparse REPARSE SCM_ARG
1662         {
1663                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1664         }
1665         | function_arglist_nonbackup_reparse REPARSE lyric_element_music
1666         {
1667                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1668         }
1669         | function_arglist_nonbackup_reparse REPARSE symbol_list_arg
1670         {
1671                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1672         }
1673         ;
1674
1675 function_arglist_nonbackup_reparse:
1676         EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup SCM_IDENTIFIER
1677         {
1678                 $$ = $3;
1679                 SCM res = try_string_variants ($2, $4);
1680                 if (!SCM_UNBNDP (res))
1681                         if (scm_is_pair (res))
1682                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1683                         else
1684                                 MYREPARSE (@4, $2, SCM_ARG, res);
1685                 else if (scm_is_true
1686                          (scm_call_1
1687                           ($2, make_music_from_simple
1688                            (parser, @4, $4))))
1689                         MYREPARSE (@4, $2, STRING, $4);
1690                 else
1691                         MYREPARSE (@4, $2, SCM_ARG, $4);
1692         }
1693         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup pitch
1694         {
1695                 $$ = $3;
1696                 if (scm_is_true
1697                     (scm_call_1
1698                      ($2, make_music_from_simple
1699                       (parser, @4, $4))))
1700                         MYREPARSE (@4, $2, PITCH_IDENTIFIER, $4);
1701                 else
1702                         MYREPARSE (@4, $2, SCM_ARG, $4);
1703         }
1704         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup steno_tonic_pitch
1705         {
1706                 $$ = $3;
1707                 if (scm_is_true
1708                     (scm_call_1
1709                      ($2, make_music_from_simple
1710                       (parser, @4, $4))))
1711                         MYREPARSE (@4, $2, TONICNAME_PITCH, $4);
1712                 else
1713                         MYREPARSE (@4, $2, SCM_ARG, $4);
1714         }
1715         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup STRING
1716         {
1717                 $$ = $3;
1718                 SCM res = try_string_variants ($2, $4);
1719                 if (!SCM_UNBNDP (res))
1720                         if (scm_is_pair (res))
1721                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1722                         else
1723                                 MYREPARSE (@4, $2, SCM_ARG, res);
1724                 else if (scm_is_true
1725                          (scm_call_1
1726                           ($2, make_music_from_simple
1727                            (parser, @4, $4))))
1728                         MYREPARSE (@4, $2, STRING, $4);
1729                 else
1730                         MYREPARSE (@4, $2, SCM_ARG, $4);
1731         }
1732         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup full_markup
1733         {
1734                 $$ = $3;
1735                 if (scm_is_true (scm_call_1 ($2, $4)))
1736                         MYREPARSE (@4, $2, SCM_ARG, $4);
1737                 else if (scm_is_true
1738                          (scm_call_1
1739                           ($2, make_music_from_simple
1740                            (parser, @4, $4))))
1741                         MYREPARSE (@4, $2, STRING, $4);
1742                 else
1743                         MYREPARSE (@4, $2, SCM_ARG, $4);
1744         }
1745         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup UNSIGNED
1746         {
1747                 $$ = $3;
1748                 if (scm_is_true (scm_call_1 ($2, $4)))
1749                         MYREPARSE (@4, $2, REAL, $4);
1750                 else {
1751                         SCM d = make_duration ($4);
1752                         if (SCM_UNBNDP (d) || scm_is_false (scm_call_1 ($2, d)))
1753                                 MYREPARSE (@4, $2, REAL, $4); // trigger error
1754                         else
1755                                 MYREPARSE (@4, $2, DURATION_IDENTIFIER, d);
1756                 }
1757         }
1758         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup DURATION_IDENTIFIER {
1759                 $$ = $3;
1760                 MYREPARSE (@4, $2, DURATION_IDENTIFIER, $4);
1761         }
1762         ;
1763
1764
1765 // function_arglist_backup can't occur at the end of an argument
1766 // list.
1767 function_arglist_backup:
1768         function_arglist_common
1769         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup embedded_scm_arg
1770         {
1771                 if (scm_is_true (scm_call_1 ($2, $4)))
1772                         $$ = scm_cons ($4, $3);
1773                 else {
1774                         $$ = make_music_from_simple (parser, @4, $4);
1775                         if (scm_is_true (scm_call_1 ($2, $$)))
1776                                 $$ = scm_cons ($$, $3);
1777                         else
1778                         {
1779                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1780                                 MYBACKUP (SCM_ARG, $4, @4);
1781                         }
1782                 }
1783         }
1784         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup post_event_nofinger
1785         {
1786                 if (scm_is_true (scm_call_1 ($2, $4)))
1787                 {
1788                         $$ = scm_cons ($4, $3);
1789                 } else {
1790                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1791                         MYBACKUP (EVENT_IDENTIFIER, $4, @4);
1792                 }
1793         }
1794         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup pitch
1795         {
1796                 if (scm_is_true
1797                     (scm_call_1
1798                      ($2, make_music_from_simple
1799                       (parser, @4, $4))))
1800                 {
1801                         $$ = $3;
1802                         MYREPARSE (@4, $2, PITCH_IDENTIFIER, $4);
1803                 } else if (scm_is_true (scm_call_1 ($2, $4)))
1804                         $$ = scm_cons ($4, $3);
1805                 else {
1806                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1807                         MYBACKUP (PITCH_IDENTIFIER, $4, @4);
1808                 }
1809         }
1810         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup steno_tonic_pitch
1811         {
1812                 if (scm_is_true
1813                     (scm_call_1
1814                      ($2, make_music_from_simple
1815                       (parser, @4, $4))))
1816                 {
1817                         $$ = $3;
1818                         MYREPARSE (@4, $2, TONICNAME_PITCH, $4);
1819                 } else if (scm_is_true (scm_call_1 ($2, $4)))
1820                         $$ = scm_cons ($4, $3);
1821                 else {
1822                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1823                         MYBACKUP (TONICNAME_PITCH, $4, @4);
1824                 }
1825         }
1826         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup full_markup
1827         {
1828                 if (scm_is_true (scm_call_1 ($2, $4)))
1829                         $$ = scm_cons ($4, $3);
1830                 else {
1831                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1832                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
1833                 }
1834         }
1835         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup UNSIGNED
1836         {
1837                 if (scm_is_true (scm_call_1 ($2, $4)))
1838                 {
1839                         MYREPARSE (@4, $2, REAL, $4);
1840                         $$ = $3;
1841                 } else {
1842                         SCM d = make_duration ($4);
1843                         if (SCM_UNBNDP (d) || scm_is_false (scm_call_1 ($2, d)))
1844                         {
1845                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1846                                 MYBACKUP (UNSIGNED, $4, @4);
1847                         } else {
1848                                 MYREPARSE (@4, $2, DURATION_IDENTIFIER, d);
1849                                 $$ = $3;
1850                         }
1851                 }
1852         }
1853         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup REAL
1854         {
1855                 if (scm_is_true (scm_call_1 ($2, $4)))
1856                 {
1857                         $$ = $3;
1858                         MYREPARSE (@4, $2, REAL, $4);
1859                 } else {
1860                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1861                         MYBACKUP (REAL, $4, @4);
1862                 }
1863         }
1864         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup NUMBER_IDENTIFIER
1865         {
1866                 if (scm_is_true (scm_call_1 ($2, $4)))
1867                 {
1868                         $$ = scm_cons ($4, $3);
1869                 } else {
1870                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1871                         MYBACKUP (NUMBER_IDENTIFIER, $4, @4);
1872                 }
1873         }
1874         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' UNSIGNED
1875         {
1876                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1877                 if (scm_is_true (scm_call_1 ($2, n))) {
1878                         $$ = $3;
1879                         MYREPARSE (@5, $2, REAL, n);
1880                 } else {
1881                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1882                         t->set_property ("digit", $5);
1883                         $$ = t->unprotect ();
1884                         if (scm_is_true (scm_call_1 ($2, $$)))
1885                                 $$ = scm_cons ($$, $3);
1886                         else {
1887                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1888                                 MYBACKUP (UNSIGNED, $5, @5);
1889                                 parser->lexer_->push_extra_token (@4, '-');
1890                         }
1891                 }
1892         }
1893         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' REAL
1894         {
1895                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1896                 if (scm_is_true (scm_call_1 ($2, n))) {
1897                         MYREPARSE (@5, $2, REAL, n);
1898                         $$ = $3;
1899                 } else {
1900                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1901                         MYBACKUP (REAL, n, @5);
1902                 }
1903         }
1904         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' NUMBER_IDENTIFIER
1905         {
1906                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1907                 if (scm_is_true (scm_call_1 ($2, n))) {
1908                         $$ = scm_cons (n, $3);
1909                 } else {
1910                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1911                         MYBACKUP (NUMBER_IDENTIFIER, n, @5);
1912                 }
1913         }
1914         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup DURATION_IDENTIFIER
1915         {
1916                 if (scm_is_true (scm_call_1 ($2, $4)))
1917                 {
1918                         MYREPARSE (@4, $2, DURATION_IDENTIFIER, $4);
1919                         $$ = $3;
1920                 } else {
1921                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1922                         MYBACKUP (DURATION_IDENTIFIER, $4, @4);
1923                 }
1924         }
1925         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup SCM_IDENTIFIER
1926         {
1927                 SCM res = try_string_variants ($2, $4);
1928                 if (!SCM_UNBNDP (res))
1929                         if (scm_is_pair (res)) {
1930                                 $$ = $3;
1931                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1932                         }
1933                         else
1934                                 $$ = scm_cons (res, $3);
1935                 else {
1936                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1937                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
1938                 }
1939         }
1940         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup STRING
1941         {
1942                 SCM res = try_string_variants ($2, $4);
1943                 if (!SCM_UNBNDP (res))
1944                         if (scm_is_pair (res)) {
1945                                 $$ = $3;
1946                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1947                         }
1948                         else
1949                                 $$ = scm_cons (res, $3);
1950                 else {
1951                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1952                         MYBACKUP (STRING, $4, @4);
1953                 }
1954         }
1955         | function_arglist_backup REPARSE pitch_or_music
1956         {
1957                 if (scm_is_true (scm_call_1 ($2, $3)))
1958                         $$ = scm_cons ($3, $1);
1959                 else
1960                         $$ = check_scheme_arg (parser, @3,
1961                                                make_music_from_simple
1962                                                (parser, @3, $3),
1963                                                $1, $2);
1964         }
1965         | function_arglist_backup REPARSE bare_number_common
1966         {
1967                 $$ = check_scheme_arg (parser, @3,
1968                                        $3, $1, $2);
1969         }
1970         | function_arglist_backup REPARSE duration_length
1971         {
1972                 $$ = check_scheme_arg (parser, @3,
1973                                        $3, $1, $2);
1974         }
1975         | function_arglist_backup REPARSE symbol_list_arg
1976         {
1977                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1978         }
1979         ;
1980
1981 function_arglist:
1982         function_arglist_nonbackup
1983         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_nonbackup DEFAULT
1984         {
1985                 $$ = scm_cons (loc_on_music (@4, $1), $3);
1986         }
1987         ;
1988
1989 function_arglist_skip_nonbackup:
1990         function_arglist_nonbackup
1991         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_nonbackup
1992         {
1993                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1994         }
1995         ;
1996
1997 function_arglist_common:
1998         EXPECT_NO_MORE_ARGS {
1999                 $$ = SCM_EOL;
2000         }
2001         | EXPECT_SCM function_arglist_optional embedded_scm_arg
2002         {
2003                 if (scm_is_true (scm_call_1 ($1, $3)))
2004                         $$ = scm_cons ($3, $2);
2005                 else
2006                         $$ = check_scheme_arg (parser, @3,
2007                                                make_music_from_simple
2008                                                (parser, @3, $3),
2009                                                $2, $1);
2010         }
2011         | EXPECT_SCM function_arglist_optional bare_number_common
2012         {
2013                 $$ = check_scheme_arg (parser, @3,
2014                                        $3, $2, $1);
2015         }
2016         | EXPECT_SCM function_arglist_optional post_event_nofinger
2017         {
2018                 $$ = check_scheme_arg (parser, @3,
2019                                        $3, $2, $1);
2020         }
2021         | EXPECT_SCM function_arglist_optional '-' NUMBER_IDENTIFIER
2022         {
2023                 SCM n = scm_difference ($4, SCM_UNDEFINED);
2024                 $$ = check_scheme_arg (parser, @4, n, $2, $1);
2025         }
2026         | function_arglist_common_reparse REPARSE SCM_ARG
2027         {
2028                 $$ = check_scheme_arg (parser, @3,
2029                                        $3, $1, $2);
2030         }
2031         | function_arglist_common_reparse REPARSE lyric_element_music
2032         {
2033                 $$ = check_scheme_arg (parser, @3,
2034                                        $3, $1, $2);
2035         }
2036         | function_arglist_common_reparse REPARSE pitch_or_music
2037         {
2038                 if (scm_is_true (scm_call_1 ($2, $3)))
2039                         $$ = scm_cons ($3, $1);
2040                 else
2041                         $$ = check_scheme_arg (parser, @3,
2042                                                make_music_from_simple
2043                                                (parser, @3, $3),
2044                                                $1, $2);
2045         }
2046         | function_arglist_common_reparse REPARSE bare_number_common
2047         {
2048                 $$ = check_scheme_arg (parser, @3,
2049                                        $3, $1, $2);
2050         }
2051         | function_arglist_common_reparse REPARSE duration_length
2052         {
2053                 $$ = check_scheme_arg (parser, @3,
2054                                        $3, $1, $2);
2055         }
2056         | function_arglist_common_reparse REPARSE symbol_list_arg
2057         {
2058                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
2059         }
2060         ;
2061
2062 function_arglist_common_reparse:
2063         EXPECT_SCM function_arglist_optional SCM_IDENTIFIER
2064         {
2065                 $$ = $2;
2066                 SCM res = try_string_variants ($1, $3);
2067                 if (!SCM_UNBNDP (res))
2068                         if (scm_is_pair (res))
2069                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
2070                         else
2071                                 MYREPARSE (@3, $1, SCM_ARG, res);
2072                 else if (scm_is_true
2073                          (scm_call_1
2074                           ($1, make_music_from_simple (parser, @3, $3))))
2075                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
2076                 else
2077                         // This is going to flag a syntax error, we
2078                         // know the predicate to be false.
2079                         MYREPARSE (@3, $1, SCM_ARG, $3);
2080         }
2081         | EXPECT_SCM function_arglist_optional pitch
2082         {
2083                 $$ = $2;
2084                 if (scm_is_true
2085                     (scm_call_1
2086                      ($1, make_music_from_simple
2087                       (parser, @3, $3))))
2088                         MYREPARSE (@3, $1, PITCH_IDENTIFIER, $3);
2089                 else
2090                         MYREPARSE (@3, $1, SCM_ARG, $3);
2091         }
2092         | EXPECT_SCM function_arglist_optional steno_tonic_pitch
2093         {
2094                 $$ = $2;
2095                 if (scm_is_true
2096                     (scm_call_1
2097                      ($1, make_music_from_simple
2098                       (parser, @3, $3))))
2099                         MYREPARSE (@3, $1, TONICNAME_PITCH, $3);
2100                 else
2101                         MYREPARSE (@3, $1, SCM_ARG, $3);
2102         }
2103         | EXPECT_SCM function_arglist_optional STRING
2104         {
2105                 $$ = $2;
2106                 SCM res = try_string_variants ($1, $3);
2107                 if (!SCM_UNBNDP (res))
2108                         if (scm_is_pair (res))
2109                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
2110                         else
2111                                 MYREPARSE (@3, $1, SCM_ARG, res);
2112                 else if (scm_is_true
2113                          (scm_call_1
2114                           ($1, make_music_from_simple (parser, @3, $3))))
2115                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
2116                 else
2117                         // This is going to flag a syntax error, we
2118                         // know the predicate to be false.
2119                         MYREPARSE (@3, $1, SCM_ARG, $3);
2120         }
2121         | EXPECT_SCM function_arglist_optional full_markup
2122         {
2123                 $$ = $2;
2124                 if (scm_is_true (scm_call_1 ($1, $3)))
2125                         MYREPARSE (@3, $1, SCM_ARG, $3);
2126                 else if (scm_is_true
2127                          (scm_call_1
2128                           ($1, make_music_from_simple (parser, @3, $3))))
2129                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
2130                 else
2131                         // This is going to flag a syntax error, we
2132                         // know the predicate to be false.
2133                         MYREPARSE (@3, $1, SCM_ARG, $3);
2134         }
2135         | EXPECT_SCM function_arglist_optional UNSIGNED
2136         {
2137                 $$ = $2;
2138                 if (scm_is_true (scm_call_1 ($1, $3)))
2139                         MYREPARSE (@3, $1, REAL, $3);
2140                 else {
2141                         SCM d = make_duration ($3);
2142                         if (SCM_UNBNDP (d) || scm_is_false (scm_call_1 ($1, d)))
2143                                 MYREPARSE (@3, $1, REAL, $3);
2144                         else
2145                                 MYREPARSE (@3, $1, DURATION_IDENTIFIER, d);
2146                 }
2147         }
2148         | EXPECT_SCM function_arglist_optional DURATION_IDENTIFIER
2149         {
2150                 $$ = $2;
2151                 MYREPARSE (@3, $1, DURATION_IDENTIFIER, $3);
2152         }
2153         | EXPECT_SCM function_arglist_optional '-' UNSIGNED
2154         {
2155                 $$ = $2;
2156                 SCM n = scm_difference ($4, SCM_UNDEFINED);
2157                 if (scm_is_true (scm_call_1 ($1, n)))
2158                         MYREPARSE (@4, $1, REAL, n);
2159                 else {
2160                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @4);
2161                         t->set_property ("digit", $4);
2162                         SCM m = t->unprotect ();
2163                         if (scm_is_true (scm_call_1 ($1, m)))
2164                                 MYREPARSE (@4, $1, SCM_ARG, m);
2165                         else
2166                                 MYREPARSE (@4, $1, SCM_ARG, $4);
2167                 }
2168         }
2169         | EXPECT_SCM function_arglist_optional '-' REAL
2170         {
2171                 $$ = $2;
2172                 SCM n = scm_difference ($4, SCM_UNDEFINED);
2173                 MYREPARSE (@4, $1, REAL, n);
2174         }
2175         ;
2176
2177 function_arglist_optional:
2178         function_arglist_backup
2179         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_backup DEFAULT
2180         {
2181                 $$ = scm_cons (loc_on_music (@4, $1), $3);
2182         }
2183         | function_arglist_skip_backup BACKUP
2184         ;
2185
2186 function_arglist_skip_backup:
2187         function_arglist_backup
2188         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_backup
2189         {
2190                 $$ = scm_cons (loc_on_music (@3, $1), $3);
2191         }
2192         ;
2193
2194 music_function_call:
2195         MUSIC_FUNCTION function_arglist {
2196                 $$ = MAKE_SYNTAX ("music-function", @$,
2197                                          $1, $2);
2198         }
2199         ;
2200
2201
2202 optional_id:
2203         /**/ { $$ = SCM_EOL; }
2204         | '=' simple_string {
2205                 $$ = $2;
2206         }
2207         ;
2208
2209 // We must not have lookahead tokens parsed in lyric mode.  In order
2210 // to save confusion, we take almost the same set as permitted with
2211 // \lyricmode and/or \lyrics.  However, music identifiers are also
2212 // allowed, and they obviously do not require switching into lyrics
2213 // mode for parsing.
2214
2215 lyric_mode_music:
2216         {
2217                 parser->lexer_->push_lyric_state ();
2218         } grouped_music_list
2219         {
2220                 parser->lexer_->pop_state ();
2221                 $$ = $2;
2222         }
2223         | MUSIC_IDENTIFIER
2224         ;
2225
2226 mode_changed_music:
2227         mode_changing_head grouped_music_list {
2228                 if (scm_is_eq ($1, ly_symbol2scm ("chords")))
2229                 {
2230                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
2231                 }
2232                 else
2233                 {
2234                   $$ = $2;
2235                 }
2236                 parser->lexer_->pop_state ();
2237         }
2238         | mode_changing_head_with_context optional_context_mod grouped_music_list {
2239                 Context_mod *ctxmod = unsmob<Context_mod> ($2);
2240                 SCM mods = SCM_EOL;
2241                 if (ctxmod)
2242                         mods = ctxmod->get_mods ();
2243                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, mods, SCM_BOOL_T, $3);
2244                 if (scm_is_eq ($1, ly_symbol2scm ("ChordNames")))
2245                 {
2246                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
2247                 }
2248                 parser->lexer_->pop_state ();
2249         }
2250         ;
2251
2252 mode_changing_head:
2253         NOTEMODE {
2254                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
2255                 parser->lexer_->push_note_state (nn);
2256
2257                 $$ = ly_symbol2scm ("notes");
2258         }
2259         | DRUMMODE
2260                 {
2261                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
2262                 parser->lexer_->push_note_state (nn);
2263
2264                 $$ = ly_symbol2scm ("drums");
2265         }
2266         | FIGUREMODE {
2267                 parser->lexer_->push_figuredbass_state ();
2268
2269                 $$ = ly_symbol2scm ("figures");
2270         }
2271         | CHORDMODE {
2272                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
2273                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
2274                 nn = parser->lexer_->lookup_identifier ("pitchnames");
2275                 parser->lexer_->push_chord_state (nn);
2276                 $$ = ly_symbol2scm ("chords");
2277
2278         }
2279         | LYRICMODE
2280                 { parser->lexer_->push_lyric_state ();
2281                 $$ = ly_symbol2scm ("lyrics");
2282         }
2283         ;
2284
2285 mode_changing_head_with_context:
2286         DRUMS {
2287                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
2288                 parser->lexer_->push_note_state (nn);
2289
2290                 $$ = ly_symbol2scm ("DrumStaff");
2291         }
2292         | FIGURES {
2293                 parser->lexer_->push_figuredbass_state ();
2294
2295                 $$ = ly_symbol2scm ("FiguredBass");
2296         }
2297         | CHORDS {
2298                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
2299                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
2300                 nn = parser->lexer_->lookup_identifier ("pitchnames");
2301                 parser->lexer_->push_chord_state (nn);
2302                 $$ = ly_symbol2scm ("ChordNames");
2303         }
2304         | LYRICS
2305                 { parser->lexer_->push_lyric_state ();
2306                 $$ = ly_symbol2scm ("Lyrics");
2307         }
2308         ;
2309
2310 context_change:
2311         CHANGE symbol '=' simple_string  {
2312                 $$ = MAKE_SYNTAX ("context-change", @$, $2, $4);
2313         }
2314         ;
2315
2316
2317 property_path:
2318         symbol_list_rev  {
2319                 $$ = scm_reverse_x ($1, SCM_EOL);
2320         }
2321         | symbol_list_rev property_path {
2322                 $$ = scm_reverse_x ($1, $2);
2323         }
2324         ;
2325
2326 property_operation:
2327         symbol '=' scalar {
2328                 $$ = scm_list_3 (ly_symbol2scm ("assign"), $1, $3);
2329         }
2330         | UNSET symbol {
2331                 $$ = scm_list_2 (ly_symbol2scm ("unset"), $2);
2332         }
2333         | OVERRIDE property_path '=' scalar {
2334                 if (scm_ilength ($2) < 2) {
2335                         parser->parser_error (@2, _("bad grob property path"));
2336                         $$ = SCM_UNDEFINED;
2337                 } else {
2338                         $$ = scm_cons (ly_symbol2scm ("push"),
2339                                        scm_cons2 (scm_car ($2),
2340                                                   $4,
2341                                                   scm_cdr ($2)));
2342                 }
2343         }
2344         | REVERT revert_arg {
2345                 $$ = scm_cons (ly_symbol2scm ("pop"), $2);
2346         }
2347         ;
2348
2349 // This is all quite awkward for the sake of substantial backward
2350 // compatibility while at the same time allowing a more "natural" form
2351 // of specification not separating grob specification from grob
2352 // property path.  The purpose of this definition of revert_arg is to
2353 // allow the symbol list which specifies grob and property to revert
2354 // to be optionally be split into two parts after the grob (which in
2355 // this case is just the first element of the list).  symbol_list_part
2356 // is only one path component, but it can be parsed without lookahead,
2357 // so we can follow it with a synthetic BACKUP token when needed.  If
2358 // the first symbol_list_part already contains multiple elements (only
2359 // possible if a Scheme expression provides them), we just parse for
2360 // additional elements introduced by '.', which is what the
2361 // SYMBOL_LIST backup in connection with the immediately following
2362 // rule using symbol_list_arg does.
2363 //
2364 // As long as we don't have our coffers filled with both grob and at
2365 // least one grob property specification, the rest of the required
2366 // symbol list chain may be provided either with or without a leading
2367 // dot.  This is for both allowing the traditional
2368 // \revert Accidental #'color
2369 // as well as well as the "naive" form
2370 // \revert Accidental.color
2371
2372 revert_arg:
2373         revert_arg_backup BACKUP symbol_list_arg
2374         {
2375                 $$ = $3;
2376         }
2377         ;
2378
2379 revert_arg_backup:
2380         revert_arg_part
2381         {
2382                 if (scm_is_null ($1)
2383                     || scm_is_null (scm_cdr ($1)))
2384                         MYBACKUP (SCM_ARG, $1, @1);
2385                 else
2386                         MYBACKUP (SYMBOL_LIST, scm_reverse_x ($1, SCM_EOL), @1);
2387         }
2388         ;
2389
2390 // revert_arg_part delivers results in reverse
2391 revert_arg_part:
2392         symbol_list_part
2393         | revert_arg_backup BACKUP SCM_ARG '.' symbol_list_part
2394         {
2395                 $$ = scm_append_x (scm_list_2 ($5, $3));
2396         }
2397         | revert_arg_backup BACKUP SCM_ARG symbol_list_part
2398         {
2399                 $$ = scm_append_x (scm_list_2 ($4, $3));
2400         }
2401         ;
2402
2403 context_def_mod:
2404         CONSISTS { $$ = ly_symbol2scm ("consists"); }
2405         | REMOVE { $$ = ly_symbol2scm ("remove"); }
2406
2407         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
2408         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
2409         | DENIES { $$ = ly_symbol2scm ("denies"); }
2410
2411         | ALIAS { $$ = ly_symbol2scm ("alias"); }
2412         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
2413         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
2414         | NAME { $$ = ly_symbol2scm ("context-name"); }
2415         ;
2416
2417 context_mod:
2418         property_operation { $$ = $1; }
2419         | context_def_mod STRING {
2420                 $$ = scm_list_2 ($1, $2);
2421         }
2422         | context_def_mod embedded_scm
2423         {
2424                 if (!scm_is_string ($2)
2425                     && ly_symbol2scm ("consists") != $1
2426                     && ly_symbol2scm ("remove") != $1)
2427                 {
2428                         $$ = SCM_EOL;
2429                         parser->parser_error (@1, _ ("only \\consists and \\remove take non-string argument."));
2430                 }
2431                 else
2432                 {
2433                         $$ = scm_list_2 ($1, $2);
2434                 }
2435         }
2436         ;
2437
2438 // If defined, at least two members.
2439 grob_prop_spec:
2440         symbol_list_rev
2441         {
2442                 SCM l = scm_reverse_x ($1, SCM_EOL);
2443                 if (scm_is_pair (l)
2444                     && to_boolean
2445                     (scm_object_property (scm_car (l),
2446                                           ly_symbol2scm ("is-grob?"))))
2447                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2448                 if (scm_is_null (l) || scm_is_null (scm_cdr (l))) {
2449                         parser->parser_error (@1, _ ("bad grob property path"));
2450                         l = SCM_UNDEFINED;
2451                 }
2452                 $$ = l;
2453         }
2454         ;
2455
2456 // If defined, at least three members
2457 grob_prop_path:
2458         grob_prop_spec
2459         {
2460                 if (!SCM_UNBNDP ($1) && scm_is_null (scm_cddr ($1)))
2461                 {
2462                         parser->parser_error (@1, _ ("bad grob property path"));
2463                         $$ = SCM_UNDEFINED;
2464                 }
2465         }
2466         | grob_prop_spec property_path
2467         {
2468                 if (!SCM_UNBNDP ($1)) {
2469                         $$ = scm_append_x (scm_list_2 ($1, $2));
2470                         if (scm_is_null (scm_cddr ($$))) {
2471                                 parser->parser_error (@$, _ ("bad grob property path"));
2472                                 $$ = SCM_UNDEFINED;
2473                         }
2474                 }
2475
2476         }
2477         ;
2478
2479 // Exactly two elements or undefined
2480 context_prop_spec:
2481         symbol_list_rev
2482         {
2483                 SCM l = scm_reverse_x ($1, SCM_EOL);
2484                 switch (scm_ilength (l)) {
2485                 case 1:
2486                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2487                 case 2:
2488                         break;
2489                 default:
2490                         parser->parser_error (@1, _ ("bad context property path"));
2491                         l = SCM_UNDEFINED;
2492                 }
2493                 $$ = l;
2494         }
2495         ;
2496
2497
2498 // This is all quite awkward for the sake of substantial backward
2499 // compatibility while at the same time allowing a more "natural" form
2500 // of specification not separating grob specification from grob
2501 // property path.  The purpose of this definition of
2502 // simple_revert_context is to allow the symbol list which specifies
2503 // grob and property to revert to be optionally be split into two
2504 // parts after the grob (which may be preceded by a context
2505 // specification, a case which we distinguish by checking whether the
2506 // first symbol is a valid grob symbol instead).
2507 //
2508 // See revert_arg above for the main work horse of this arrangement.
2509 // simple_revert_context just caters for the context and delegates the
2510 // rest of the job to revert_arg.
2511
2512 simple_revert_context:
2513         symbol_list_part
2514         {
2515                 $1 = scm_reverse_x ($1, SCM_EOL);
2516                 if (scm_is_null ($1)
2517                     || to_boolean
2518                     (scm_object_property (scm_car ($1),
2519                                           ly_symbol2scm ("is-grob?")))) {
2520                         $$ = ly_symbol2scm ("Bottom");
2521                         parser->lexer_->push_extra_token (@1, SCM_IDENTIFIER, $1);
2522                 } else {
2523                         $$ = scm_car ($1);
2524                         parser->lexer_->push_extra_token (@1, SCM_IDENTIFIER,
2525                                                           scm_cdr ($1));
2526                 }
2527         }
2528         ;
2529
2530 music_property_def:
2531         OVERRIDE grob_prop_path '=' scalar {
2532                 if (SCM_UNBNDP ($2))
2533                         $$ = MAKE_SYNTAX ("void-music", @$);
2534                 else {
2535                         $$ = MAKE_SYNTAX ("property-operation", @$,
2536                                           scm_car ($2),
2537                                           ly_symbol2scm ("OverrideProperty"),
2538                                           scm_cadr ($2),
2539                                           $4,
2540                                           scm_cddr ($2));
2541                 }
2542         }
2543         | REVERT simple_revert_context revert_arg {
2544                 $$ = MAKE_SYNTAX ("property-operation", @$,
2545                                   $2,
2546                                   ly_symbol2scm ("RevertProperty"),
2547                                   scm_car ($3),
2548                                   scm_cdr ($3));
2549         }
2550         | SET context_prop_spec '=' scalar {
2551                 if (SCM_UNBNDP ($2))
2552                         $$ = MAKE_SYNTAX ("void-music", @$);
2553                 else
2554                         $$ = MAKE_SYNTAX ("property-operation", @$,
2555                                           scm_car ($2),
2556                                           ly_symbol2scm ("PropertySet"),
2557                                           scm_cadr ($2),
2558                                           $4);
2559         }
2560         | UNSET context_prop_spec {
2561                 if (SCM_UNBNDP ($2))
2562                         $$ = MAKE_SYNTAX ("void-music", @$);
2563                 else
2564                         $$ = MAKE_SYNTAX ("property-operation", @$,
2565                                           scm_car ($2),
2566                                           ly_symbol2scm ("PropertyUnset"),
2567                                           scm_cadr ($2));
2568         }
2569         ;
2570
2571 string:
2572         STRING {
2573                 $$ = $1;
2574         }
2575         | full_markup
2576         ;
2577
2578 simple_string: STRING {
2579                 $$ = $1;
2580         }
2581         | embedded_scm_bare
2582         {
2583                 if (scm_is_string ($1)) {
2584                         $$ = $1;
2585                 } else {
2586                         parser->parser_error (@1, (_ ("simple string expected")));
2587                         $$ = scm_string (SCM_EOL);
2588                 }
2589         }
2590         ;
2591
2592 symbol:
2593         STRING {
2594                 $$ = scm_string_to_symbol ($1);
2595         }
2596         | embedded_scm_bare
2597         {
2598                 // This is a bit of overkill but makes the same
2599                 // routine responsible for all symbol interpretations.
2600                 $$ = try_string_variants (ly_lily_module_constant ("symbol?"),
2601                                           $1);
2602                 if (SCM_UNBNDP ($$))
2603                 {
2604                         parser->parser_error (@1, (_ ("symbol expected")));
2605                         // Generate a unique symbol in case it is used
2606                         // for an assignment or similar
2607                         $$ = scm_make_symbol (ly_string2scm ("undefined"));
2608                 }
2609         }
2610         ;
2611
2612 scalar:
2613         embedded_scm_arg
2614         | pitch_or_music
2615         | SCM_IDENTIFIER
2616         | bare_number
2617         // The following is a rather defensive variant of admitting
2618         // negative numbers: the grammar would permit number_factor or
2619         // even number_expression.  However, function arguments allow
2620         // only this simple kind of negative number, so to have things
2621         // like \tweak and \override behave reasonably similar, it
2622         // makes sense to rule out things like -- which are rather an
2623         // accent in function argument contexts.
2624         | '-' bare_number
2625         {
2626                 $$ = scm_difference ($2, SCM_UNDEFINED);
2627         }
2628         | string
2629         ;
2630
2631 event_chord:
2632         simple_element post_events {
2633                 // Let the rhythmic music iterator sort this mess out.
2634                 if (scm_is_pair ($2)) {
2635                         unsmob<Music> ($$)->set_property ("articulations",
2636                                                          scm_reverse_x ($2, SCM_EOL));
2637                 }
2638         } %prec ':'
2639         | CHORD_REPETITION optional_notemode_duration post_events {
2640                 Input i;
2641                 i.set_location (@1, @3);
2642                 $$ = MAKE_SYNTAX ("repetition-chord", i,
2643                                   $2, scm_reverse_x ($3, SCM_EOL));
2644         } %prec ':'
2645         | MULTI_MEASURE_REST optional_notemode_duration post_events {
2646                 Input i;
2647                 i.set_location (@1, @3);
2648                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
2649                                   scm_reverse_x ($3, SCM_EOL));
2650         } %prec ':'
2651         | tempo_event
2652         | note_chord_element
2653         ;
2654
2655
2656 note_chord_element:
2657         chord_body optional_notemode_duration post_events
2658         {
2659                 Music *m = unsmob<Music> ($1);
2660                 SCM dur = unsmob<Duration> ($2)->smobbed_copy ();
2661                 SCM es = m->get_property ("elements");
2662                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
2663
2664                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
2665                   unsmob<Music> (scm_car (s))->set_property ("duration", dur);
2666                 es = ly_append2 (es, postevs);
2667
2668                 m-> set_property ("elements", es);
2669                 m->set_spot (@$);
2670                 $$ = m->self_scm ();
2671         } %prec ':'
2672         ;
2673
2674 chord_body:
2675         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
2676         {
2677                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
2678         }
2679         | FIGURE_OPEN figure_list FIGURE_CLOSE
2680         {
2681                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
2682         }
2683         ;
2684
2685 chord_body_elements:
2686         /* empty */             { $$ = SCM_EOL; }
2687         | chord_body_elements chord_body_element {
2688                 if (!SCM_UNBNDP ($2))
2689                         $$ = scm_cons ($2, $1);
2690         }
2691         ;
2692
2693 chord_body_element:
2694         pitch_or_tonic_pitch exclamations questions octave_check post_events
2695         {
2696                 bool q = to_boolean ($3);
2697                 bool ex = to_boolean ($2);
2698                 SCM check = $4;
2699                 SCM post = $5;
2700
2701                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2702                 n->set_property ("pitch", $1);
2703                 if (q)
2704                         n->set_property ("cautionary", SCM_BOOL_T);
2705                 if (ex || q)
2706                         n->set_property ("force-accidental", SCM_BOOL_T);
2707
2708                 if (scm_is_pair (post)) {
2709                         SCM arts = scm_reverse_x (post, SCM_EOL);
2710                         n->set_property ("articulations", arts);
2711                 }
2712                 if (scm_is_number (check))
2713                 {
2714                         int q = scm_to_int (check);
2715                         n->set_property ("absolute-octave", scm_from_int (q-1));
2716                 }
2717
2718                 $$ = n->unprotect ();
2719         }
2720         | DRUM_PITCH post_events {
2721                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2722                 n->set_property ("drum-type", $1);
2723
2724                 if (scm_is_pair ($2)) {
2725                         SCM arts = scm_reverse_x ($2, SCM_EOL);
2726                         n->set_property ("articulations", arts);
2727                 }
2728                 $$ = n->unprotect ();
2729         }
2730         | music_function_chord_body
2731         {
2732                 Music *m = unsmob<Music> ($1);
2733
2734                 while (m && m->is_mus_type ("music-wrapper-music")) {
2735                         $$ = m->get_property ("element");
2736                         m = unsmob<Music> ($$);
2737                 }
2738
2739                 if (!(m && m->is_mus_type ("rhythmic-event"))) {
2740                         parser->parser_error (@$, _ ("not a rhythmic event"));
2741                         $$ = SCM_UNDEFINED;
2742                 }
2743         }
2744         ;
2745
2746 music_function_chord_body:
2747         music_function_call
2748         | MUSIC_IDENTIFIER
2749         | embedded_scm
2750         ;
2751
2752 event_function_event:
2753         EVENT_FUNCTION function_arglist {
2754                 $$ = MAKE_SYNTAX ("music-function", @$,
2755                                          $1, $2);
2756         }
2757         ;
2758
2759 post_events:
2760         /* empty */ {
2761                 $$ = SCM_EOL;
2762         }
2763         | post_events post_event {
2764                 $$ = $1;
2765                 if (Music *m = unsmob<Music> ($2))
2766                 {
2767                         if (m->is_mus_type ("post-event-wrapper"))
2768                         {
2769                                 for (SCM p = m->get_property ("elements");
2770                                      scm_is_pair (p);
2771                                      p = scm_cdr (p))
2772                                 {
2773                                         $$ = scm_cons (scm_car (p), $$);
2774                                 }
2775                         } else {
2776                                 m->set_spot (@2);
2777                                 $$ = scm_cons ($2, $$);
2778                         }
2779                 }
2780         }
2781         ;
2782
2783 post_event_nofinger:
2784         direction_less_event {
2785                 $$ = $1;
2786         }
2787         | script_dir music_function_call {
2788                 $$ = $2;
2789                 if (!unsmob<Music> ($2)->is_mus_type ("post-event")) {
2790                         parser->parser_error (@2, _ ("post-event expected"));
2791                         $$ = SCM_UNSPECIFIED;
2792                 } else if (!SCM_UNBNDP ($1))
2793                 {
2794                         unsmob<Music> ($$)->set_property ("direction", $1);
2795                 }
2796         }
2797         | HYPHEN {
2798                 if (!parser->lexer_->is_lyric_state ())
2799                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2800                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
2801         }
2802         | EXTENDER {
2803                 if (!parser->lexer_->is_lyric_state ())
2804                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2805                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
2806         }
2807         | script_dir direction_reqd_event {
2808                 if (!SCM_UNBNDP ($1))
2809                 {
2810                         Music *m = unsmob<Music> ($2);
2811                         m->set_property ("direction", $1);
2812                 }
2813                 $$ = $2;
2814         }
2815         | script_dir direction_less_event {
2816                 if (!SCM_UNBNDP ($1))
2817                 {
2818                         Music *m = unsmob<Music> ($2);
2819                         m->set_property ("direction", $1);
2820                 }
2821                 $$ = $2;
2822         }
2823         | '^' fingering
2824         {
2825                 $$ = $2;
2826                 unsmob<Music> ($$)->set_property ("direction", scm_from_int (UP));
2827         }
2828         | '_' fingering
2829         {
2830                 $$ = $2;
2831                 unsmob<Music> ($$)->set_property ("direction", scm_from_int (DOWN));
2832         }
2833         ;
2834
2835 post_event:
2836         post_event_nofinger
2837         | '-' fingering {
2838                 $$ = $2;
2839         }
2840         ;
2841
2842 string_number_event:
2843         E_UNSIGNED {
2844                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
2845                 s->set_property ("string-number", $1);
2846                 $$ = s->unprotect ();
2847         }
2848         ;
2849
2850 direction_less_event:
2851         string_number_event
2852         | EVENT_IDENTIFIER      {
2853                 $$ = $1;
2854         }
2855         | tremolo_type  {
2856                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
2857                a->set_property ("tremolo-type", $1);
2858                $$ = a->unprotect ();
2859         }
2860         | event_function_event
2861         ;
2862
2863 direction_reqd_event:
2864         gen_text_def {
2865                 $$ = $1;
2866         }
2867         | script_abbreviation {
2868                 SCM s = parser->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
2869                 if (scm_is_string (s)) {
2870                         Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
2871                         a->set_property ("articulation-type", s);
2872                         $$ = a->unprotect ();
2873                 } else {
2874                         Music *original = unsmob<Music> (s);
2875                         if (original && original->is_mus_type ("post-event")) {
2876                                 Music *a = original->clone ();
2877                                 a->set_spot (parser->lexer_->override_input (@$));
2878                                 $$ = a->unprotect ();
2879                         } else {
2880                                 parser->parser_error (@1, _ ("expecting string or post-event as script definition"));
2881                                 $$ = MY_MAKE_MUSIC ("PostEvents", @$)->unprotect ();
2882                         }
2883                 }
2884         }
2885         ;
2886
2887 octave_check:
2888         /**/ { $$ = SCM_EOL; }
2889         | '=' quotes { $$ = $2; }
2890         ;
2891
2892 quotes:
2893         /* empty */
2894         {
2895                 $$ = SCM_INUM0;
2896         }
2897         | sub_quotes
2898         | sup_quotes
2899         ;
2900
2901 sup_quotes:
2902         '\'' {
2903                 $$ = scm_from_int (1);
2904         }
2905         | sup_quotes '\'' {
2906                 $$ = scm_oneplus ($1);
2907         }
2908         ;
2909
2910 sub_quotes:
2911         ',' {
2912                 $$ = scm_from_int (-1);
2913         }
2914         | sub_quotes ',' {
2915                 $$ = scm_oneminus ($1);
2916         }
2917         ;
2918
2919 steno_pitch:
2920         NOTENAME_PITCH quotes {
2921                 if (!scm_is_eq (SCM_INUM0, $2))
2922                 {
2923                         Pitch p = *unsmob<Pitch> ($1);
2924                         p = p.transposed (Pitch (scm_to_int ($2), 0));
2925                         $$ = p.smobbed_copy ();
2926                 }
2927         }
2928         ;
2929
2930 /*
2931 ugh. duplication
2932 */
2933
2934 steno_tonic_pitch:
2935         TONICNAME_PITCH quotes {
2936                 if (!scm_is_eq (SCM_INUM0, $2))
2937                 {
2938                         Pitch p = *unsmob<Pitch> ($1);
2939                         p = p.transposed (Pitch (scm_to_int ($2), 0));
2940                         $$ = p.smobbed_copy ();
2941                 }
2942         }
2943         ;
2944
2945 pitch:
2946         steno_pitch
2947         | PITCH_IDENTIFIER quotes {
2948                 if (!scm_is_eq (SCM_INUM0, $2))
2949                 {
2950                         Pitch p = *unsmob<Pitch> ($1);
2951                         p = p.transposed (Pitch (scm_to_int ($2), 0));
2952                         $$ = p.smobbed_copy ();
2953                 }
2954         }
2955         ;
2956
2957 pitch_or_tonic_pitch:
2958         pitch
2959         | steno_tonic_pitch
2960         ;
2961
2962 gen_text_def:
2963         full_markup {
2964                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2965                 t->set_property ("text", $1);
2966                 $$ = t->unprotect ();
2967         }
2968         | STRING {
2969                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2970                 t->set_property ("text",
2971                         make_simple_markup ($1));
2972                 $$ = t->unprotect ();
2973         }
2974         | embedded_scm
2975         {
2976                 Music *m = unsmob<Music> ($1);
2977                 if (m && m->is_mus_type ("post-event"))
2978                         $$ = $1;
2979                 else if (Text_interface::is_markup ($1)) {
2980                         Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2981                         t->set_property ("text", $1);
2982                         $$ = t->unprotect ();
2983                 } else
2984                         parser->parser_error (@1, _ ("not an articulation"));
2985         }
2986         ;
2987
2988 fingering:
2989         UNSIGNED {
2990                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
2991                 t->set_property ("digit", $1);
2992                 $$ = t->unprotect ();
2993         }
2994         ;
2995
2996 script_abbreviation:
2997         '^'             {
2998                 $$ = scm_from_ascii_string ("Hat");
2999         }
3000         | '+'           {
3001                 $$ = scm_from_ascii_string ("Plus");
3002         }
3003         | '-'           {
3004                 $$ = scm_from_ascii_string ("Dash");
3005         }
3006         | '!'           {
3007                 $$ = scm_from_ascii_string ("Bang");
3008         }
3009         | ANGLE_CLOSE   {
3010                 $$ = scm_from_ascii_string ("Larger");
3011         }
3012         | '.'           {
3013                 $$ = scm_from_ascii_string ("Dot");
3014         }
3015         | '_' {
3016                 $$ = scm_from_ascii_string ("Underscore");
3017         }
3018         ;
3019
3020 script_dir:
3021         '_'     { $$ = scm_from_int (DOWN); }
3022         | '^'   { $$ = scm_from_int (UP); }
3023         | '-'   { $$ = SCM_UNDEFINED; }
3024         ;
3025
3026 duration_length:
3027         multiplied_duration {
3028                 $$ = $1;
3029         }
3030         ;
3031
3032 maybe_notemode_duration:
3033         {
3034                 $$ = SCM_UNDEFINED;
3035         } %prec ':'
3036         | multiplied_duration   {
3037                 $$ = $1;
3038                 parser->default_duration_ = *unsmob<Duration> ($$);
3039         }
3040 ;
3041
3042
3043 optional_notemode_duration:
3044         maybe_notemode_duration
3045         {
3046                 if (SCM_UNBNDP ($$))
3047                         $$ = parser->default_duration_.smobbed_copy ();
3048         }
3049         ;
3050
3051 steno_duration:
3052         UNSIGNED dots           {
3053                 $$ = make_duration ($1, scm_to_int ($2));
3054                 if (SCM_UNBNDP ($$))
3055                 {
3056                         parser->parser_error (@1, _ ("not a duration"));
3057                         $$ = Duration ().smobbed_copy ();
3058                 }
3059         }
3060         | DURATION_IDENTIFIER dots      {
3061                 Duration *d = unsmob<Duration> ($1);
3062                 Duration k (d->duration_log (),
3063                             d->dot_count () + scm_to_int ($2));
3064                 k = k.compressed (d->factor ());
3065                 scm_remember_upto_here_1 ($1);
3066                 $$ = k.smobbed_copy ();
3067         }
3068         ;
3069
3070 multiplied_duration:
3071         steno_duration {
3072                 $$ = $1;
3073         }
3074         | multiplied_duration '*' UNSIGNED {
3075                 $$ = unsmob<Duration> ($$)->compressed (scm_to_int ($3)).smobbed_copy ();
3076         }
3077         | multiplied_duration '*' FRACTION {
3078                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
3079
3080                 $$ = unsmob<Duration> ($$)->compressed (m).smobbed_copy ();
3081         }
3082         ;
3083
3084 dots:
3085         /* empty */     {
3086                 $$ = SCM_INUM0;
3087         }
3088         | dots '.' {
3089                 $$ = scm_oneplus ($1);
3090         }
3091         ;
3092
3093 tremolo_type:
3094         ':'     {
3095                 $$ = scm_from_int (parser->default_tremolo_type_);
3096         }
3097         | ':' UNSIGNED {
3098                 if (SCM_UNBNDP (make_duration ($2))) {
3099                         parser->parser_error (@2, _ ("not a duration"));
3100                         $$ = scm_from_int (parser->default_tremolo_type_);
3101                 } else {
3102                         $$ = $2;
3103                         parser->default_tremolo_type_ = scm_to_int ($2);
3104                 }
3105         }
3106         ;
3107
3108 bass_number:
3109         UNSIGNED { $$ = $1; }
3110         | STRING { $$ = $1; }
3111         | full_markup { $$ = $1; }
3112         | embedded_scm_bare
3113         {
3114                 // as an integer, it needs to be non-negative, and otherwise
3115                 // it needs to be suitable as a markup.
3116                 if (scm_is_integer ($1)
3117                     ? scm_is_true (scm_negative_p ($1))
3118                     : !Text_interface::is_markup ($1))
3119                 {
3120                         parser->parser_error (@1, _ ("bass number expected"));
3121                         $$ = SCM_INUM0;
3122                 }
3123         }
3124         ;
3125
3126 figured_bass_alteration:
3127         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
3128         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
3129         | '!'   { $$ = scm_from_int (0); }
3130         ;
3131
3132 bass_figure:
3133         FIGURE_SPACE {
3134                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
3135                 $$ = bfr->unprotect ();
3136         }
3137         | bass_number  {
3138                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
3139                 $$ = bfr->self_scm ();
3140
3141                 if (scm_is_number ($1))
3142                         bfr->set_property ("figure", $1);
3143                 else if (Text_interface::is_markup ($1))
3144                         bfr->set_property ("text", $1);
3145
3146                 bfr->unprotect ();
3147         }
3148         | bass_figure ']' {
3149                 $$ = $1;
3150                 unsmob<Music> ($1)->set_property ("bracket-stop", SCM_BOOL_T);
3151         }
3152         | bass_figure figured_bass_alteration {
3153                 Music *m = unsmob<Music> ($1);
3154                 if (scm_to_double ($2)) {
3155                         SCM salter = m->get_property ("alteration");
3156                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
3157                         m->set_property ("alteration",
3158                                          scm_sum (alter, $2));
3159                 } else {
3160                         m->set_property ("alteration", scm_from_int (0));
3161                 }
3162         }
3163         | bass_figure figured_bass_modification  {
3164                 Music *m = unsmob<Music> ($1);
3165                 m->set_property ($2, SCM_BOOL_T);
3166         }
3167         ;
3168
3169
3170 figured_bass_modification:
3171         E_PLUS          {
3172                 $$ = ly_symbol2scm ("augmented");
3173         }
3174         | E_EXCLAMATION {
3175                 $$ = ly_symbol2scm ("no-continuation");
3176         }
3177         | '/'           {
3178                 $$ = ly_symbol2scm ("diminished");
3179         }
3180         | E_BACKSLASH {
3181                 $$ = ly_symbol2scm ("augmented-slash");
3182         }
3183         ;
3184
3185 br_bass_figure:
3186         bass_figure {
3187                 $$ = $1;
3188         }
3189         | '[' bass_figure {
3190                 $$ = $2;
3191                 unsmob<Music> ($$)->set_property ("bracket-start", SCM_BOOL_T);
3192         }
3193         ;
3194
3195 figure_list:
3196         /**/            {
3197                 $$ = SCM_EOL;
3198         }
3199         | figure_list br_bass_figure {
3200                 $$ = scm_cons ($2, $1);
3201         }
3202         ;
3203
3204 optional_rest:
3205         /**/   { $$ = SCM_BOOL_F; }
3206         | REST { $$ = SCM_BOOL_T; }
3207         ;
3208
3209 pitch_or_music:
3210         pitch exclamations questions octave_check maybe_notemode_duration optional_rest post_events {
3211                 if (!parser->lexer_->is_note_state ())
3212                         parser->parser_error (@1, _ ("have to be in Note mode for notes"));
3213                 if (!SCM_UNBNDP ($2)
3214                     || !SCM_UNBNDP ($3)
3215                     || scm_is_number ($4)
3216                     || !SCM_UNBNDP ($5)
3217                     || scm_is_true ($6)
3218                     || scm_is_pair ($7))
3219                 {
3220                         Music *n = 0;
3221                         if (scm_is_true ($6))
3222                                 n = MY_MAKE_MUSIC ("RestEvent", @$);
3223                         else
3224                                 n = MY_MAKE_MUSIC ("NoteEvent", @$);
3225
3226                         n->set_property ("pitch", $1);
3227                         if (SCM_UNBNDP ($5))
3228                                 n->set_property ("duration",
3229                                                  parser->default_duration_.smobbed_copy ());
3230                         else
3231                                 n->set_property ("duration", $5);
3232
3233                         if (scm_is_number ($4))
3234                         {
3235                                 int q = scm_to_int ($4);
3236                                 n->set_property ("absolute-octave", scm_from_int (q-1));
3237                         }
3238
3239                         if (to_boolean ($3))
3240                                 n->set_property ("cautionary", SCM_BOOL_T);
3241                         if (to_boolean ($2) || to_boolean ($3))
3242                                 n->set_property ("force-accidental", SCM_BOOL_T);
3243                         if (scm_is_pair ($7))
3244                                 n->set_property ("articulations",
3245                                                  scm_reverse_x ($7, SCM_EOL));
3246                         $$ = n->unprotect ();
3247                 }
3248         } %prec ':'
3249         | new_chord post_events {
3250                 if (!parser->lexer_->is_chord_state ())
3251                         parser->parser_error (@1, _ ("have to be in Chord mode for chords"));
3252                 if (scm_is_pair ($2)) {
3253                         if (unsmob<Pitch> ($1))
3254                                 $1 = make_chord_elements (@1,
3255                                                           $1,
3256                                                           parser->default_duration_.smobbed_copy (),
3257                                                           SCM_EOL);
3258
3259                         SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
3260
3261                         $$ = MAKE_SYNTAX ("event-chord", @1, elts);
3262                 } else if (!unsmob<Pitch> ($1))
3263                         $$ = MAKE_SYNTAX ("event-chord", @1, $1);
3264                 // A mere pitch drops through.
3265         } %prec ':'
3266         ;
3267
3268 simple_element:
3269         DRUM_PITCH optional_notemode_duration {
3270                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
3271                 n->set_property ("duration", $2);
3272                 n->set_property ("drum-type", $1);
3273
3274                 $$ = n->unprotect ();
3275         }
3276         | RESTNAME optional_notemode_duration           {
3277                 Music *ev = 0;
3278                 if (ly_scm2string ($1) == "s") {
3279                         /* Space */
3280                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
3281                   }
3282                 else {
3283                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
3284
3285                     }
3286                 ev->set_property ("duration", $2);
3287                 $$ = ev->unprotect ();
3288         }
3289         ;
3290
3291 lyric_element:
3292         full_markup {
3293                 if (!parser->lexer_->is_lyric_state ())
3294                         parser->parser_error (@1, _ ("markup outside of text script or \\lyricmode"));
3295                 $$ = $1;
3296         }
3297         | STRING {
3298                 if (!parser->lexer_->is_lyric_state ())
3299                         parser->parser_error (@1, _ ("unrecognized string, not in text script or \\lyricmode"));
3300                 $$ = $1;
3301         }
3302         | LYRIC_ELEMENT
3303         ;
3304
3305 lyric_element_music:
3306         lyric_element optional_notemode_duration post_events {
3307                 $$ = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
3308                 if (scm_is_pair ($3))
3309                         unsmob<Music> ($$)->set_property
3310                                 ("articulations", scm_reverse_x ($3, SCM_EOL));
3311         } %prec ':'
3312         ;
3313
3314 // Can return a single pitch rather than a list.
3315 new_chord:
3316         steno_tonic_pitch maybe_notemode_duration   {
3317                 if (SCM_UNBNDP ($2))
3318                         $$ = $1;
3319                 else
3320                         $$ = make_chord_elements (@$, $1, $2, SCM_EOL);
3321         }
3322         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
3323                 SCM its = scm_reverse_x ($4, SCM_EOL);
3324                 $$ = make_chord_elements (@$, $1, $2, scm_cons ($3, its));
3325         } %prec ':'
3326         ;
3327
3328 chord_items:
3329         /**/ {
3330                 $$ = SCM_EOL;
3331         }
3332         | chord_items chord_item {
3333                 $$ = scm_cons ($2, $$);
3334         }
3335         ;
3336
3337 chord_separator:
3338         CHORD_COLON {
3339                 $$ = ly_symbol2scm ("chord-colon");
3340         }
3341         | CHORD_CARET {
3342                 $$ = ly_symbol2scm ("chord-caret");
3343         }
3344         | CHORD_SLASH steno_tonic_pitch {
3345                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
3346         }
3347         | CHORD_BASS steno_tonic_pitch {
3348                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
3349         }
3350         ;
3351
3352 chord_item:
3353         chord_separator {
3354                 $$ = $1;
3355         }
3356         | step_numbers {
3357                 $$ = scm_reverse_x ($1, SCM_EOL);
3358         }
3359         | CHORD_MODIFIER  {
3360                 $$ = $1;
3361         }
3362         ;
3363
3364 step_numbers:
3365         step_number { $$ = scm_cons ($1, SCM_EOL); }
3366         | step_numbers '.' step_number {
3367                 $$ = scm_cons ($3, $$);
3368         }
3369         ;
3370
3371 step_number:
3372         UNSIGNED {
3373                 $$ = make_chord_step ($1, 0);
3374         }
3375         | UNSIGNED '+' {
3376                 $$ = make_chord_step ($1, SHARP_ALTERATION);
3377         }
3378         | UNSIGNED CHORD_MINUS {
3379                 $$ = make_chord_step ($1, FLAT_ALTERATION);
3380         }
3381         ;
3382
3383 tempo_range:
3384         unsigned_number {
3385                 $$ = $1;
3386         } %prec ':'
3387         | unsigned_number '-' unsigned_number {
3388                 $$ = scm_cons ($1, $3);
3389         }
3390         ;
3391
3392 /*
3393         UTILITIES
3394
3395 TODO: should deprecate in favor of Scheme?
3396
3397  */
3398 number_expression:
3399         number_expression '+' number_term {
3400                 $$ = scm_sum ($1, $3);
3401         }
3402         | number_expression '-' number_term {
3403                 $$ = scm_difference ($1, $3);
3404         }
3405         | number_term
3406         ;
3407
3408 number_term:
3409         number_factor {
3410                 $$ = $1;
3411         }
3412         | number_factor '*' number_factor {
3413                 $$ = scm_product ($1, $3);
3414         }
3415         | number_factor '/' number_factor {
3416                 $$ = scm_divide ($1, $3);
3417         }
3418         ;
3419
3420 number_factor:
3421         '-'  number_factor { /* %prec UNARY_MINUS */
3422                 $$ = scm_difference ($2, SCM_UNDEFINED);
3423         }
3424         | bare_number
3425         ;
3426
3427 bare_number_common:
3428         REAL
3429         | NUMBER_IDENTIFIER
3430         | REAL NUMBER_IDENTIFIER
3431         {
3432                 $$ = scm_product ($1, $2);
3433         }
3434         ;
3435
3436 bare_number:
3437         bare_number_common
3438         | UNSIGNED
3439         | UNSIGNED NUMBER_IDENTIFIER    {
3440                 $$ = scm_product ($1, $2);
3441         }
3442         ;
3443
3444 unsigned_number:
3445         UNSIGNED
3446         | NUMBER_IDENTIFIER
3447         {
3448                 if (!scm_is_integer ($1)
3449                     || scm_is_true (scm_negative_p ($1)))
3450                 {
3451                         parser->parser_error (@1, _("not an unsigned integer"));
3452                         $$ = SCM_INUM0;
3453                 }
3454         }
3455         | embedded_scm
3456         {
3457                 if (!scm_is_integer ($1)
3458                     || scm_is_true (scm_negative_p ($1)))
3459                 {
3460                         parser->parser_error (@1, _("not an unsigned integer"));
3461                         $$ = SCM_INUM0;
3462                 }
3463         }
3464         ;
3465
3466 exclamations:
3467                 { $$ = SCM_UNDEFINED; }
3468         | exclamations '!'
3469         {
3470                 if (SCM_UNBNDP ($1))
3471                         $$ = SCM_BOOL_T;
3472                 else
3473                         $$ = scm_not ($1);
3474         }
3475         ;
3476
3477 questions:
3478 // This precedence rule is rather weird.  It triggers when '!' is
3479 // encountered after a pitch, and is used for deciding whether to save
3480 // this instead for a figure modification.  This should not actually
3481 // occur in practice as pitches and figures are generated in different
3482 // modes.  Using a greedy (%right) precedence makes sure that we don't
3483 // get stuck in a wrong interpretation.
3484         { $$ = SCM_UNDEFINED; } %prec ':'
3485         | questions '?'
3486         {
3487                 if (SCM_UNBNDP ($1))
3488                         $$ = SCM_BOOL_T;
3489                 else
3490                         $$ = scm_not ($1);
3491         }
3492         ;
3493
3494 full_markup_list:
3495         MARKUPLIST
3496                 { parser->lexer_->push_markup_state (); }
3497         markup_list {
3498                 $$ = $3;
3499                 parser->lexer_->pop_state ();
3500         }
3501         ;
3502
3503 full_markup:
3504         MARKUP
3505                 { parser->lexer_->push_markup_state (); }
3506         markup_top {
3507                 $$ = $3;
3508                 parser->lexer_->pop_state ();
3509         }
3510         ;
3511
3512 markup_top:
3513         markup_list {
3514                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
3515         }
3516         | markup_head_1_list simple_markup
3517         {
3518                 $$ = scm_car (MAKE_SYNTAX ("composed-markup-list",
3519                                            @2, $1, scm_list_1 ($2)));
3520         }
3521         | simple_markup {
3522                 $$ = $1;
3523         }
3524         ;
3525
3526 markup_scm:
3527         embedded_scm_bare
3528         {
3529                 if (Text_interface::is_markup ($1))
3530                         MYBACKUP (MARKUP_IDENTIFIER, $1, @1);
3531                 else if (Text_interface::is_markup_list ($1))
3532                         MYBACKUP (MARKUPLIST_IDENTIFIER, $1, @1);
3533                 else {
3534                         parser->parser_error (@1, _ ("not a markup"));
3535                         MYBACKUP (MARKUP_IDENTIFIER, scm_string (SCM_EOL), @1);
3536                 }
3537         } BACKUP
3538         ;
3539
3540
3541 markup_list:
3542         markup_composed_list {
3543                 $$ = $1;
3544         }
3545         | markup_uncomposed_list
3546         ;
3547
3548 markup_uncomposed_list:
3549         markup_braced_list {
3550                 $$ = $1;
3551         }
3552         | markup_command_list {
3553                 $$ = scm_list_1 ($1);
3554         }
3555         | markup_scm MARKUPLIST_IDENTIFIER
3556         {
3557                 $$ = $2;
3558         }
3559         | SCORELINES {
3560                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
3561                 parser->lexer_->push_note_state (nn);
3562         } '{' score_body '}' {
3563                 Score *sc = unsmob<Score> ($4);
3564                 sc->origin ()->set_spot (@$);
3565                 if (sc->defs_.empty ()) {
3566                         Output_def *od = get_layout (parser);
3567                         sc->add_output_def (od);
3568                         od->unprotect ();
3569                 }
3570                 $$ = scm_list_1 (scm_list_2 (ly_lily_module_constant ("score-lines-markup-list"), $4));
3571                 parser->lexer_->pop_state ();
3572         }
3573         ;
3574
3575 markup_composed_list:
3576         markup_head_1_list markup_uncomposed_list {
3577                 $$ = MAKE_SYNTAX ("composed-markup-list",
3578                                   @2, $1, $2);
3579         }
3580         ;
3581
3582 markup_braced_list:
3583         '{' markup_braced_list_body '}' {
3584                 $$ = scm_reverse_x ($2, SCM_EOL);
3585         }
3586         ;
3587
3588 markup_braced_list_body:
3589         /* empty */     {  $$ = SCM_EOL; }
3590         | markup_braced_list_body markup {
3591                 $$ = scm_cons ($2, $1);
3592         }
3593         | markup_braced_list_body markup_list {
3594                 $$ = scm_reverse_x ($2, $1);
3595         }
3596         ;
3597
3598 markup_command_list:
3599         MARKUP_LIST_FUNCTION markup_command_list_arguments {
3600           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
3601         }
3602         ;
3603
3604 markup_command_basic_arguments:
3605         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
3606           $$ = scm_cons ($3, $2);
3607         }
3608         | EXPECT_SCM markup_command_list_arguments embedded_scm {
3609           $$ = check_scheme_arg (parser, @3, $3, $2, $1);
3610         }
3611         | EXPECT_NO_MORE_ARGS {
3612           $$ = SCM_EOL;
3613         }
3614         ;
3615
3616 markup_command_list_arguments:
3617         markup_command_basic_arguments { $$ = $1; }
3618         | EXPECT_MARKUP markup_command_list_arguments markup {
3619           $$ = scm_cons ($3, $2);
3620         }
3621         ;
3622
3623 markup_head_1_item:
3624         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
3625           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
3626         }
3627         ;
3628
3629 markup_head_1_list:
3630         markup_head_1_item      {
3631                 $$ = scm_list_1 ($1);
3632         }
3633         | markup_head_1_list markup_head_1_item {
3634                 $$ = scm_cons ($2, $1);
3635         }
3636         ;
3637
3638 simple_markup:
3639         STRING {
3640                 $$ = make_simple_markup ($1);
3641         }
3642         | SCORE {
3643                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
3644                 parser->lexer_->push_note_state (nn);
3645         } '{' score_body '}' {
3646                 Score *sc = unsmob<Score> ($4);
3647                 sc->origin ()->set_spot (@$);
3648                 if (sc->defs_.empty ()) {
3649                         Output_def *od = get_layout (parser);
3650                         sc->add_output_def (od);
3651                         od->unprotect ();
3652                 }
3653                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), $4);
3654                 parser->lexer_->pop_state ();
3655         }
3656         | MARKUP_FUNCTION markup_command_basic_arguments {
3657                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
3658         }
3659         | markup_scm MARKUP_IDENTIFIER
3660         {
3661                 $$ = $2;
3662         }
3663         ;
3664
3665 markup:
3666         markup_head_1_list simple_markup
3667         {
3668                 $$ = scm_car (MAKE_SYNTAX ("composed-markup-list",
3669                                            @2, $1, scm_list_1 ($2)));
3670         }
3671         | simple_markup {
3672                 $$ = $1;
3673         }
3674         ;
3675
3676 %%
3677
3678 void
3679 Lily_parser::set_yydebug (bool x)
3680 {
3681         yydebug = x;
3682 }
3683
3684 SCM
3685 Lily_parser::do_yyparse ()
3686 {
3687         return scm_c_with_fluid (ly_lily_module_constant ("%parser"),
3688                                  self_scm (),
3689                                  do_yyparse_trampoline,
3690                                  static_cast <void *>(this));
3691 }
3692
3693 SCM
3694 Lily_parser::do_yyparse_trampoline (void *parser)
3695 {
3696         SCM retval = SCM_UNDEFINED;
3697         yyparse (static_cast <Lily_parser *>(parser), &retval);
3698         return retval;
3699 }
3700
3701
3702
3703 /*
3704
3705 It is a little strange to have this function in this file, but
3706 otherwise, we have to import music classes into the lexer.
3707
3708 */
3709 int
3710 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
3711 {
3712         if (unsmob<Book> (sid)) {
3713                 Book *book =  unsmob<Book> (sid)->clone ();
3714                 *destination = book->self_scm ();
3715                 book->unprotect ();
3716
3717                 return BOOK_IDENTIFIER;
3718         } else if (scm_is_number (sid)) {
3719                 *destination = sid;
3720                 return NUMBER_IDENTIFIER;
3721         } else if (unsmob<Context_def> (sid))
3722         {
3723                 *destination = unsmob<Context_def> (sid)->clone ()->unprotect ();
3724                 return SCM_IDENTIFIER;
3725         } else if (unsmob<Context_mod> (sid)) {
3726                 *destination = unsmob<Context_mod> (sid)->smobbed_copy ();
3727                 return CONTEXT_MOD_IDENTIFIER;
3728         } else if (Music *mus = unsmob<Music> (sid)) {
3729                 mus = mus->clone ();
3730                 *destination = mus->self_scm ();
3731                 bool is_event = mus->is_mus_type ("post-event");
3732                 mus->unprotect ();
3733                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
3734         } else if (unsmob<Pitch> (sid)) {
3735                 *destination = unsmob<Pitch> (sid)->smobbed_copy ();
3736                 return PITCH_IDENTIFIER;
3737         } else if (unsmob<Duration> (sid)) {
3738                 *destination = unsmob<Duration> (sid)->smobbed_copy ();
3739                 return DURATION_IDENTIFIER;
3740         } else if (unsmob<Output_def> (sid)) {
3741                 *destination = unsmob<Output_def> (sid)->clone ()->unprotect ();
3742                 return SCM_IDENTIFIER;
3743         } else if (unsmob<Score> (sid)) {
3744                 *destination = unsmob<Score> (sid)->clone ()->unprotect ();
3745                 return SCM_IDENTIFIER;
3746         }
3747
3748         return -1;
3749 }
3750
3751 SCM
3752 get_next_unique_context_id ()
3753 {
3754         return scm_from_ascii_string ("$uniqueContextId");
3755 }
3756
3757
3758 SCM
3759 get_next_unique_lyrics_context_id ()
3760 {
3761         static int new_context_count;
3762         char s[128];
3763         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
3764         return scm_from_ascii_string (s);
3765 }
3766
3767 // check_scheme_arg checks one argument with a given predicate for use
3768 // in an argument list and throws a syntax error if it is unusable.
3769 // The argument is prepended to the argument list in any case.  After
3770 // throwing a syntax error, the argument list is terminated with #f as
3771 // its last cdr in order to mark it as uncallable while not losing
3772 // track of its total length.
3773 //
3774 // There are a few special considerations: if optional argument disp
3775 // is given (otherwise it defaults to SCM_UNDEFINED), it will be used
3776 // instead of arg in a prospective error message.  This is useful if
3777 // arg is not the actual argument but rather a transformation of it.
3778 //
3779 // If arg itself is SCM_UNDEFINED, the predicate is considered false
3780 // and an error message using disp is produced unconditionally.
3781
3782 SCM check_scheme_arg (Lily_parser *parser, Input loc,
3783                       SCM arg, SCM args, SCM pred, SCM disp)
3784 {
3785         if (SCM_UNBNDP (arg))
3786                 args = scm_cons (disp, args);
3787         else {
3788                 args = scm_cons (arg, args);
3789                 if (scm_is_true (scm_call_1 (pred, arg)))
3790                         return args;
3791         }
3792         scm_set_cdr_x (scm_last_pair (args), SCM_EOL);
3793         MAKE_SYNTAX ("argument-error", loc, scm_length (args), pred,
3794                      SCM_UNBNDP (disp) ? arg : disp);
3795         scm_set_cdr_x (scm_last_pair (args), SCM_BOOL_F);
3796         return args;
3797 }
3798
3799 SCM loc_on_music (Input loc, SCM arg)
3800 {
3801         if (Music *m = unsmob<Music> (arg))
3802         {
3803                 m = m->clone ();
3804                 m->set_spot (loc);
3805                 return m->unprotect ();
3806         }
3807         return arg;
3808 }
3809
3810 SCM
3811 try_string_variants (SCM pred, SCM str)
3812 {
3813         // a matching predicate is always ok
3814         if (scm_is_true (scm_call_1 (pred, str)))
3815                 return str;
3816         // a symbol may be interpreted as a list of symbols if it helps
3817         if (scm_is_symbol (str)) {
3818                 str = scm_list_1 (str);
3819                 if (scm_is_true (scm_call_1 (pred, str)))
3820                         return str;
3821                 return SCM_UNDEFINED;
3822         }
3823
3824         // If this cannot be a string representation of a symbol list,
3825         // we are through.
3826
3827         if (!is_regular_identifier (str, true))
3828                 return SCM_UNDEFINED;
3829
3830         str = scm_string_split (str, SCM_MAKE_CHAR ('.'));
3831         for (SCM p = str; scm_is_pair (p); p = scm_cdr (p))
3832                 scm_set_car_x (p, scm_string_to_symbol (scm_car (p)));
3833
3834         // Let's attempt the symbol list interpretation first.
3835
3836         if (scm_is_true (scm_call_1 (pred, str)))
3837                 return str;
3838
3839         // If there is just one symbol in the list, we might interpret
3840         // it as a single symbol
3841
3842         if (scm_is_null (scm_cdr (str)))
3843         {
3844                 str = scm_car (str);
3845                 if (scm_is_true (scm_call_1 (pred, str)))
3846                         return str;
3847         }
3848
3849         return SCM_UNDEFINED;
3850 }
3851
3852 bool
3853 is_regular_identifier (SCM id, bool multiple)
3854 {
3855   if (!scm_is_string (id))
3856           return false;
3857
3858   string str = ly_scm2string (id);
3859
3860   bool middle = false;
3861
3862   for (string::iterator it=str.begin(); it != str.end (); it++)
3863   {
3864           int c = *it & 0xff;
3865           if ((c >= 'a' && c <= 'z')
3866               || (c >= 'A' && c <= 'Z')
3867               || c > 0x7f)
3868                   middle = true;
3869           else if (middle && (c == '-' || c == '_' || (multiple && c == '.')))
3870                   middle = false;
3871           else
3872                   return false;
3873   }
3874   return middle;
3875 }
3876
3877 SCM
3878 make_music_from_simple (Lily_parser *parser, Input loc, SCM simple)
3879 {
3880         if (unsmob<Music> (simple))
3881                 return simple;
3882         if (parser->lexer_->is_note_state ()) {
3883                 if (scm_is_symbol (simple)) {
3884                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
3885                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
3886                         n->set_property ("drum-type", simple);
3887                         return n->unprotect ();
3888                 }
3889                 if (unsmob<Pitch> (simple)) {
3890                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
3891                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
3892                         n->set_property ("pitch", simple);
3893                         return n->unprotect ();
3894                 }
3895                 return simple;
3896         } else if (parser->lexer_->is_lyric_state ()) {
3897                 if (Text_interface::is_markup (simple))
3898                         return MAKE_SYNTAX ("lyric-event", loc, simple,
3899                                             parser->default_duration_.smobbed_copy ());
3900         } else if (parser->lexer_->is_chord_state ()) {
3901                 if (unsmob<Pitch> (simple))
3902                         return MAKE_SYNTAX
3903                                 ("event-chord",
3904                                  loc,
3905                                  make_chord_elements (loc, simple,
3906                                                       parser->default_duration_.smobbed_copy (),
3907                                                       SCM_EOL));
3908         }
3909         return simple;
3910 }
3911
3912 Music *
3913 make_music_with_input (SCM name, Input where)
3914 {
3915        Music *m = make_music_by_name (name);
3916        m->set_spot (where);
3917        return m;
3918 }
3919
3920 SCM
3921 make_simple_markup (SCM a)
3922 {
3923         return a;
3924 }
3925
3926 SCM
3927 make_duration (SCM d, int dots)
3928 {
3929         int t = scm_to_int (d);
3930         if (t > 0 && (t & (t-1)) == 0)
3931                 return Duration (intlog2 (t), dots).smobbed_copy ();
3932         else
3933                 return SCM_UNDEFINED;
3934 }
3935
3936 SCM
3937 make_chord_step (SCM step_scm, Rational alter)
3938 {
3939         int step = scm_to_int (step_scm);
3940
3941         if (step == 7)
3942                 alter += FLAT_ALTERATION;
3943
3944         while (step < 0)
3945                 step += 7;
3946         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
3947         return m.smobbed_copy ();
3948 }
3949
3950
3951 SCM
3952 make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list)
3953 {
3954         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
3955         SCM res = scm_call_3 (chord_ctor, pitch, dur, modification_list);
3956         for (SCM s = res; scm_is_pair (s); s = scm_cdr (s))
3957         {
3958                 unsmob<Music> (scm_car (s))->set_spot (loc);
3959         }
3960         return res;
3961 }
3962
3963 int
3964 yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser)
3965 {
3966         Lily_lexer *lex = parser->lexer_;
3967
3968         lex->lexval_ = s;
3969         lex->lexloc_ = loc;
3970         int tok = lex->pop_extra_token ();
3971         if (tok >= 0)
3972                 return tok;
3973         lex->prepare_for_next_token ();
3974         return lex->yylex ();
3975 }