lily/parser.yy

   1 /* -*- mode: c++; c-file-style: "linux"; indent-tabs-mode: t -*- */
   2 /*
   3   This file is part of LilyPond, the GNU music typesetter.
   4
   5   Copyright (C) 1997--2014 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6                  Jan Nieuwenhuizen <janneke@gnu.org>
   7
   8   LilyPond is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   LilyPond is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  20 */
  21
  22 /* Mode and indentation are at best a rough approximation based on TAB
  23  * formatting (reasonable for compatibility with unspecific editor
  24  * modes as Bison modes are hard to find) and need manual correction
  25  * frequently.  Without a reasonably dependable way of formatting a
  26  * Bison file sensibly, there is little point in trying to fix the
  27  * inconsistent state of indentation.
  28  */
  29
  30 %{
  31
  32 #define yyerror Lily_parser::parser_error
  33
  34 /* We use custom location type: Input objects */
  35 #define YYLTYPE Input
  36 #define YYSTYPE SCM
  37 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  38         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  39
  40 #define YYPRINT(file, type, value)                                      \
  41         do {                                                            \
  42                 if (scm_is_eq (value, SCM_UNSPECIFIED))                 \
  43                         break;                                          \
  44                 SCM s = scm_call_2 (ly_lily_module_constant ("value->lily-string"), \
  45                                     value,                              \
  46                                     parser->self_scm ());               \
  47                 char *p = scm_to_locale_string (s);                     \
  48                 fputs (p, file);                                        \
  49                 free (p);                                               \
  50         } while (0)
  51
  52 %}
  53
  54 %parse-param {Lily_parser *parser}
  55 %parse-param {SCM *retval}
  56 %lex-param {Lily_parser *parser}
  57 %error-verbose
  58 %debug
  59
  60 /* We use SCMs to do strings, because it saves us the trouble of
  61 deleting them.  Let's hope that a stack overflow doesn't trigger a move
  62 of the parse stack onto the heap. */
  63
  64 %left PREC_BOT
  65 %nonassoc REPEAT
  66 %nonassoc ALTERNATIVE
  67
  68 /* The above precedences tackle the shift/reduce problem
  69
  70 1.  \repeat
  71         \repeat .. \alternative
  72
  73     \repeat { \repeat .. \alternative }
  74
  75 or
  76
  77     \repeat { \repeat } \alternative
  78 */
  79
  80 %nonassoc COMPOSITE
  81 %left ADDLYRICS
  82
  83 %right ':' UNSIGNED REAL E_UNSIGNED EVENT_IDENTIFIER EVENT_FUNCTION '^' '_'
  84        HYPHEN EXTENDER DURATION_IDENTIFIER '!'
  85
  86  /* The above are needed for collecting tremoli and other items (that
  87     could otherwise be interpreted as belonging to the next function
  88     argument) greedily, and together with the next rule will serve to
  89     join numbers and units greedily instead of allowing them into
  90     separate function arguments
  91  */
  92
  93 %nonassoc NUMBER_IDENTIFIER
  94
  95 %left PREC_TOP
  96
  97
  98
  99
 100 %pure-parser
 101 %locations
 102
 103
 104
 105 %{ // -*-Fundamental-*-
 106
 107 /*
 108 FIXME:
 109
 110    * The rules for who is protecting what are very shady.  Uniformise
 111      this.
 112
 113    * There are too many lexical modes?
 114 */
 115
 116 #include "config.hh"
 117
 118 #include <cctype>
 119 #include <cstdlib>
 120 #include <cstdio>
 121 using namespace std;
 122
 123 #include "book.hh"
 124 #include "context-def.hh"
 125 #include "context-mod.hh"
 126 #include "dimensions.hh"
 127 #include "file-path.hh"
 128 #include "input.hh"
 129 #include "international.hh"
 130 #include "lily-guile.hh"
 131 #include "lily-lexer.hh"
 132 #include "lily-parser.hh"
 133 #include "main.hh"
 134 #include "misc.hh"
 135 #include "music.hh"
 136 #include "output-def.hh"
 137 #include "paper-book.hh"
 138 #include "scm-hash.hh"
 139 #include "score.hh"
 140 #include "text-interface.hh"
 141 #include "warn.hh"
 142
 143 void
 144 Lily_parser::parser_error (Input const *i, Lily_parser *parser, SCM *, const string &s)
 145 {
 146         parser->parser_error (*i, s);
 147 }
 148
 149 // The following are somewhat precarious constructs as they may change
 150 // the value of the lookahead token.  That implies that the lookahead
 151 // token must not yet have made an impact on the state stack other
 152 // than causing the reduction of the current rule, or switching the
 153 // lookahead token while Bison is mulling it over will cause trouble.
 154
 155 #define MYBACKUP(Token, Value, Location)                                \
 156         do {                                                            \
 157                 if (yychar != YYEMPTY)                                  \
 158                         parser->lexer_->push_extra_token                \
 159                                 (yylloc, yychar, yylval);               \
 160                 if (Token)                                              \
 161                         parser->lexer_->push_extra_token                \
 162                                 (Location, Token, Value);               \
 163                 parser->lexer_->push_extra_token (Location, BACKUP);    \
 164                 yychar = YYEMPTY;                                       \
 165         } while (0)
 166
 167
 168 #define MYREPARSE(Location, Pred, Token, Value)                         \
 169         do {                                                            \
 170                 if (yychar != YYEMPTY)                                  \
 171                         parser->lexer_->push_extra_token                \
 172                                 (yylloc, yychar, yylval);               \
 173                 parser->lexer_->push_extra_token                        \
 174                         (Location, Token, Value);                       \
 175                 parser->lexer_->push_extra_token                        \
 176                         (Location, REPARSE, Pred);                      \
 177                 yychar = YYEMPTY;                                       \
 178         } while (0)
 179
 180 %}
 181
 182
 183 %{
 184
 185 #define MY_MAKE_MUSIC(x, spot) \
 186         make_music_with_input (ly_symbol2scm (x), \
 187                                parser->lexer_->override_input (spot))
 188
 189 /* ES TODO:
 190 - Don't use lily module, create a new module instead.
 191 - delay application of the function
 192 */
 193 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 194   scm_apply_0 (proc, args)
 195 /* Syntactic Sugar. */
 196 #define MAKE_SYNTAX(name, location, ...)                                \
 197         LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (parser->self_scm (), parser->lexer_->override_input (location).smobbed_copy (), ##__VA_ARGS__, SCM_UNDEFINED))
 198 #define START_MAKE_SYNTAX(name, ...)                                    \
 199         scm_list_n (ly_lily_module_constant (name) , ##__VA_ARGS__, SCM_UNDEFINED)
 200 #define FINISH_MAKE_SYNTAX(start, location, ...)                        \
 201         LOWLEVEL_MAKE_SYNTAX (scm_car (start), scm_cons2 (parser->self_scm (), parser->lexer_->override_input (location).smobbed_copy (), scm_append_x (scm_list_2 (scm_cdr (start), scm_list_n (__VA_ARGS__, SCM_UNDEFINED)))))
 202
 203 SCM get_next_unique_context_id ();
 204 SCM get_next_unique_lyrics_context_id ();
 205
 206 #undef _
 207 #if !HAVE_GETTEXT
 208 #define _(x) x
 209 #else
 210 #include <libintl.h>
 211 #define _(x) gettext (x)
 212 #endif
 213
 214
 215 static Music *make_music_with_input (SCM name, Input where);
 216 SCM check_scheme_arg (Lily_parser *parser, Input loc,
 217                       SCM arg, SCM args, SCM pred, SCM disp = SCM_UNDEFINED);
 218 SCM make_music_from_simple (Lily_parser *parser, Input loc, SCM pitch);
 219 SCM loc_on_music (Input loc, SCM arg);
 220 SCM make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list);
 221 SCM make_chord_step (SCM step, Rational alter);
 222 SCM make_simple_markup (SCM a);
 223 SCM make_duration (SCM t, int dots = 0);
 224 bool is_regular_identifier (SCM id, bool multiple=false);
 225 SCM try_string_variants (SCM pred, SCM str);
 226 int yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser);
 227
 228 %}
 229
 230 /* The third option is an alias that will be used to display the
 231    syntax error.  Bison CVS now correctly handles backslash escapes.
 232
 233    FIXME: Bison needs to translate some of these, eg, STRING.
 234
 235 */
 236
 237 /* Keyword tokens with plain escaped name.  */
 238 %token END_OF_FILE 0 "end of input"
 239 %token ACCEPTS "\\accepts"
 240 %token ADDLYRICS "\\addlyrics"
 241 %token ALIAS "\\alias"
 242 %token ALTERNATIVE "\\alternative"
 243 %token BOOK "\\book"
 244 %token BOOKPART "\\bookpart"
 245 %token CHANGE "\\change"
 246 %token CHORDMODE "\\chordmode"
 247 %token CHORDS "\\chords"
 248 %token CONSISTS "\\consists"
 249 %token CONTEXT "\\context"
 250 %token DEFAULT "\\default"
 251 %token DEFAULTCHILD "\\defaultchild"
 252 %token DENIES "\\denies"
 253 %token DESCRIPTION "\\description"
 254 %token DRUMMODE "\\drummode"
 255 %token DRUMS "\\drums"
 256 %token FIGUREMODE "\\figuremode"
 257 %token FIGURES "\\figures"
 258 %token HEADER "\\header"
 259 %token INVALID "\\version-error"
 260 %token LAYOUT "\\layout"
 261 %token LYRICMODE "\\lyricmode"
 262 %token LYRICS "\\lyrics"
 263 %token LYRICSTO "\\lyricsto"
 264 %token MARKUP "\\markup"
 265 %token MARKUPLIST "\\markuplist"
 266 %token MIDI "\\midi"
 267 %token NAME "\\name"
 268 %token NOTEMODE "\\notemode"
 269 %token OVERRIDE "\\override"
 270 %token PAPER "\\paper"
 271 %token REMOVE "\\remove"
 272 %token REPEAT "\\repeat"
 273 %token REST "\\rest"
 274 %token REVERT "\\revert"
 275 %token SCORE "\\score"
 276 %token SCORELINES "\\score-lines"
 277 %token SEQUENTIAL "\\sequential"
 278 %token SET "\\set"
 279 %token SIMULTANEOUS "\\simultaneous"
 280 %token TEMPO "\\tempo"
 281 %token TYPE "\\type"
 282 %token UNSET "\\unset"
 283 %token WITH "\\with"
 284
 285 /* Keyword token exceptions.  */
 286 %token NEWCONTEXT "\\new"
 287
 288
 289 /* Other string tokens.  */
 290
 291 %token CHORD_BASS "/+"
 292 %token CHORD_CARET "^"
 293 %token CHORD_COLON ":"
 294 %token CHORD_MINUS "-"
 295 %token CHORD_SLASH "/"
 296 %token ANGLE_OPEN "<"
 297 %token ANGLE_CLOSE ">"
 298 %token DOUBLE_ANGLE_OPEN "<<"
 299 %token DOUBLE_ANGLE_CLOSE ">>"
 300 %token E_BACKSLASH "\\"
 301 %token E_EXCLAMATION "\\!"
 302 %token E_PLUS "\\+"
 303 %token EXTENDER "__"
 304
 305 /*
 306 If we give names, Bison complains.
 307 */
 308 %token FIGURE_CLOSE /* "\\>" */
 309 %token FIGURE_OPEN /* "\\<" */
 310 %token FIGURE_SPACE "_"
 311 %token HYPHEN "--"
 312
 313 %token MULTI_MEASURE_REST
 314
 315
 316 %token E_UNSIGNED
 317 %token UNSIGNED
 318
 319 /* Artificial tokens, for more generic function syntax */
 320 %token EXPECT_MARKUP "markup?"
 321 %token EXPECT_SCM "scheme?"
 322 %token BACKUP "(backed-up?)"
 323 %token REPARSE "(reparsed?)"
 324 %token EXPECT_MARKUP_LIST "markup-list?"
 325 %token EXPECT_OPTIONAL "optional?"
 326 /* After the last argument. */
 327 %token EXPECT_NO_MORE_ARGS;
 328
 329 /* An artificial token for parsing embedded Lilypond */
 330 %token EMBEDDED_LILY "#{"
 331
 332 %token BOOK_IDENTIFIER
 333 %token CHORD_MODIFIER
 334 %token CHORD_REPETITION
 335 %token CONTEXT_MOD_IDENTIFIER
 336 %token DRUM_PITCH
 337 %token PITCH_IDENTIFIER
 338 %token DURATION_IDENTIFIER
 339 %token EVENT_IDENTIFIER
 340 %token EVENT_FUNCTION
 341 %token FRACTION
 342 %token LYRIC_ELEMENT
 343 %token MARKUP_FUNCTION
 344 %token MARKUP_LIST_FUNCTION
 345 %token MARKUP_IDENTIFIER
 346 %token MARKUPLIST_IDENTIFIER
 347 %token MUSIC_FUNCTION
 348 %token MUSIC_IDENTIFIER
 349 %token NOTENAME_PITCH
 350 %token NUMBER_IDENTIFIER
 351 %token REAL
 352 %token RESTNAME
 353 %token SCM_ARG
 354 %token SCM_FUNCTION
 355 %token SCM_IDENTIFIER
 356 %token SCM_TOKEN
 357 %token STRING
 358 %token SYMBOL_LIST
 359 %token TONICNAME_PITCH
 360
 361 %left '-' '+'
 362
 363 /* We don't assign precedence to / and *, because we might need varied
 364 prec levels in different prods */
 365
 366 %left UNARY_MINUS
 367
 368 %%
 369
 370 start_symbol:
 371         lilypond
 372         | EMBEDDED_LILY {
 373                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 374                 parser->lexer_->push_note_state (nn);
 375         } embedded_lilypond {
 376                 parser->lexer_->pop_state ();
 377                 *retval = $3;
 378         }
 379         ;
 380
 381 lilypond:       /* empty */ { $$ = SCM_UNSPECIFIED; }
 382         | lilypond toplevel_expression {
 383         }
 384         | lilypond assignment {
 385         }
 386         | lilypond error {
 387                 parser->error_level_ = 1;
 388         }
 389         | lilypond INVALID      {
 390                 parser->error_level_ = 1;
 391         }
 392         ;
 393
 394
 395 toplevel_expression:
 396         {
 397                 parser->lexer_->add_scope (get_header (parser));
 398         } lilypond_header {
 399                 parser->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $2);
 400         }
 401         | book_block {
 402                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-book-handler");
 403                 scm_call_2 (proc, parser->self_scm (), $1);
 404         }
 405         | bookpart_block {
 406                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 407                 scm_call_2 (proc, parser->self_scm (), $1);
 408         }
 409         | BOOK_IDENTIFIER {
 410                 SCM proc = parser->lexer_->lookup_identifier
 411                         (Book::unsmob($1)->paper_
 412                          ? "toplevel-book-handler"
 413                          : "toplevel-bookpart-handler");
 414                 scm_call_2 (proc, parser->self_scm (), $1);
 415         }
 416         | score_block {
 417                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-score-handler");
 418                 scm_call_2 (proc, parser->self_scm (), $1);
 419         }
 420         | composite_music {
 421                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-music-handler");
 422                 scm_call_2 (proc, parser->self_scm (), $1);
 423         }
 424         | full_markup {
 425                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 426                 scm_call_2 (proc, parser->self_scm (), scm_list_1 ($1));
 427         }
 428         | full_markup_list {
 429                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 430                 scm_call_2 (proc, parser->self_scm (), $1);
 431         }
 432         | SCM_TOKEN {
 433                 // Evaluate and ignore #xxx, as opposed to \xxx
 434                 parser->lexer_->eval_scm_token ($1, @1);
 435         }
 436         | embedded_scm_active
 437         {
 438                 SCM out = SCM_UNDEFINED;
 439                 if (Text_interface::is_markup ($1))
 440                         out = scm_list_1 ($1);
 441                 else if (Text_interface::is_markup_list ($1))
 442                         out = $1;
 443                 if (scm_is_pair (out))
 444                 {
 445                         SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 446                         scm_call_2 (proc, parser->self_scm (), out);
 447                 } else if (Score::unsmob ($1))
 448                 {
 449                         SCM proc = parser->lexer_->lookup_identifier ("toplevel-score-handler");
 450                         scm_call_2 (proc, parser->self_scm (), $1);
 451                 } else if (Output_def * od = Output_def::unsmob ($1)) {
 452                         SCM id = SCM_EOL;
 453
 454                         if (od->c_variable ("is-paper") == SCM_BOOL_T)
 455                                 id = ly_symbol2scm ("$defaultpaper");
 456                         else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 457                                 id = ly_symbol2scm ("$defaultmidi");
 458                         else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 459                                 id = ly_symbol2scm ("$defaultlayout");
 460
 461                         parser->lexer_->set_identifier (id, $1);
 462                 } else if (!scm_is_eq ($1, SCM_UNSPECIFIED))
 463                         parser->parser_error (@1, _("bad expression type"));
 464         }
 465         | output_def {
 466                 SCM id = SCM_EOL;
 467                 Output_def * od = Output_def::unsmob ($1);
 468
 469                 if (od->c_variable ("is-paper") == SCM_BOOL_T)
 470                         id = ly_symbol2scm ("$defaultpaper");
 471                 else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 472                         id = ly_symbol2scm ("$defaultmidi");
 473                 else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 474                         id = ly_symbol2scm ("$defaultlayout");
 475
 476                 parser->lexer_->set_identifier (id, $1);
 477         }
 478         ;
 479
 480 embedded_scm_bare:
 481         SCM_TOKEN
 482         {
 483                 $$ = parser->lexer_->eval_scm_token ($1, @1);
 484         }
 485         | SCM_IDENTIFIER
 486         ;
 487
 488 embedded_scm_active:
 489         SCM_IDENTIFIER
 490         | scm_function_call
 491         ;
 492
 493 embedded_scm_bare_arg:
 494         SCM_ARG
 495         | SCM_TOKEN
 496         {
 497                 $$ = parser->lexer_->eval_scm_token ($1, @1);
 498         }
 499         | FRACTION
 500         | full_markup_list
 501         | context_modification
 502         | score_block
 503         | context_def_spec_block
 504         | book_block
 505         | bookpart_block
 506         | output_def
 507         ;
 508
 509 /* The generic version may end in music, or not */
 510
 511 embedded_scm:
 512         embedded_scm_bare
 513         | scm_function_call
 514         ;
 515
 516 /* embedded_scm_arg is _not_ casting pitches to music by default, this
 517  * has to be done by the function itself.  Note that this may cause
 518  * the results of scm_function_call or embedded_scm_bare_arg to be
 519  * turned into music from pitches as well.  Note that this creates a
 520  * distinctly awkward situation for calculated drum pitches.  Those
 521  * are at the current point of time rejected as music constituents as
 522  * they can't be distinguished from "proper" symbols.
 523  */
 524
 525 embedded_scm_arg:
 526         embedded_scm_bare_arg
 527         | scm_function_call
 528         | music_assign
 529         ;
 530
 531 scm_function_call:
 532         SCM_FUNCTION function_arglist {
 533                 $$ = MAKE_SYNTAX ("music-function", @$,
 534                                          $1, $2);
 535         }
 536         ;
 537
 538 embedded_lilypond_number:
 539         '-' embedded_lilypond_number
 540         {
 541                 $$ = scm_difference ($2, SCM_UNDEFINED);
 542         }
 543         | bare_number_common
 544         | UNSIGNED NUMBER_IDENTIFIER
 545         {
 546                 $$ = scm_product ($1, $2);
 547         }
 548         ;
 549
 550 embedded_lilypond:
 551         /* empty */
 552         {
 553                 // FIXME: @$ does not contain a useful source location
 554                 // for empty rules, and the only token in the whole
 555                 // production, EMBEDDED_LILY, is synthetic and also
 556                 // contains no source location.
 557                 $$ = MAKE_SYNTAX ("void-music", @$);
 558         }
 559         | identifier_init_nonumber
 560         | embedded_lilypond_number
 561         | post_event post_events
 562         {
 563                 $$ = scm_reverse_x ($2, SCM_EOL);
 564                 if (Music *m = Music::unsmob ($1))
 565                 {
 566                         if (m->is_mus_type ("post-event-wrapper"))
 567                                 $$ = scm_append
 568                                         (scm_list_2 (m->get_property ("elements"),
 569                                                      $$));
 570                         else
 571                                 $$ = scm_cons ($1, $$);
 572                 }
 573                 if (scm_is_pair ($$)
 574                     && scm_is_null (scm_cdr ($$)))
 575                         $$ = scm_car ($$);
 576                 else
 577                 {
 578                         Music * m = MY_MAKE_MUSIC ("PostEvents", @$);
 579                         m->set_property ("elements", $$);
 580                         $$ = m->unprotect ();
 581                 }
 582         }
 583         | multiplied_duration
 584         | music_embedded music_embedded music_list {
 585                 $3 = scm_reverse_x ($3, SCM_EOL);
 586                 if (Music::unsmob ($2))
 587                         $3 = scm_cons ($2, $3);
 588                 if (Music::unsmob ($1))
 589                         $3 = scm_cons ($1, $3);
 590                 $$ = MAKE_SYNTAX ("sequential-music", @$, $3);
 591         }
 592         | error {
 593                 parser->error_level_ = 1;
 594                 $$ = SCM_UNSPECIFIED;
 595         }
 596         | INVALID embedded_lilypond {
 597                 parser->error_level_ = 1;
 598                 $$ = $2;
 599         }
 600         ;
 601
 602
 603 lilypond_header_body:
 604         /* empty */ { $$ = SCM_UNSPECIFIED; }
 605         | lilypond_header_body assignment  {
 606
 607         }
 608         | lilypond_header_body embedded_scm  {
 609
 610         }
 611         ;
 612
 613 lilypond_header:
 614         HEADER '{' lilypond_header_body '}'     {
 615                 $$ = parser->lexer_->remove_scope ();
 616         }
 617         ;
 618
 619 /*
 620         DECLARATIONS
 621 */
 622 assignment_id:
 623         STRING          { $$ = $1; }
 624         ;
 625
 626 assignment:
 627         assignment_id '=' identifier_init  {
 628                 parser->lexer_->set_identifier ($1, $3);
 629                 $$ = SCM_UNSPECIFIED;
 630         }
 631         | assignment_id property_path '=' identifier_init {
 632                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 633                 parser->lexer_->set_identifier (path, $4);
 634                 $$ = SCM_UNSPECIFIED;
 635         }
 636         | assignment_id '.' property_path '=' identifier_init {
 637                 SCM path = scm_cons (scm_string_to_symbol ($1), $3);
 638                 parser->lexer_->set_identifier (path, $5);
 639                 $$ = SCM_UNSPECIFIED;
 640         }
 641         ;
 642
 643
 644 identifier_init:
 645         identifier_init_nonumber
 646         | number_expression
 647         | post_event_nofinger post_events
 648         {
 649                 $$ = scm_reverse_x ($2, SCM_EOL);
 650                 if (Music *m = Music::unsmob ($1))
 651                 {
 652                         if (m->is_mus_type ("post-event-wrapper"))
 653                                 $$ = scm_append
 654                                         (scm_list_2 (m->get_property ("elements"),
 655                                                      $$));
 656                         else
 657                                 $$ = scm_cons ($1, $$);
 658                 }
 659                 if (scm_is_pair ($$)
 660                     && scm_is_null (scm_cdr ($$)))
 661                         $$ = scm_car ($$);
 662                 else
 663                 {
 664                         Music * m = MY_MAKE_MUSIC ("PostEvents", @$);
 665                         m->set_property ("elements", $$);
 666                         $$ = m->unprotect ();
 667                 }
 668         }
 669         ;
 670
 671 identifier_init_nonumber:
 672         score_block
 673         | book_block
 674         | bookpart_block
 675         | output_def
 676         | context_def_spec_block
 677         | music_assign
 678         | pitch_or_music
 679         | FRACTION
 680         | string
 681         | embedded_scm
 682         | full_markup_list
 683         | context_modification
 684         ;
 685
 686 context_def_spec_block:
 687         CONTEXT '{' context_def_spec_body '}'
 688         {
 689                 $$ = $3;
 690                 Context_def *td = Context_def::unsmob ($$);
 691                 if (!td) {
 692                         $$ = Context_def::make_scm ();
 693                         td = Context_def::unsmob ($$);
 694                 }
 695                 td->origin ()->set_spot (@$);
 696         }
 697         ;
 698
 699 context_mod_arg:
 700         embedded_scm
 701         |
 702         {
 703                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 704                 parser->lexer_->push_note_state (nn);
 705         }
 706         composite_music
 707         {
 708                 parser->lexer_->pop_state ();
 709                 $$ = $2;
 710         }
 711         ;
 712
 713
 714 context_def_spec_body:
 715         /**/ {
 716                 $$ = SCM_UNSPECIFIED;
 717         }
 718         | context_def_spec_body context_mod {
 719                 if (!SCM_UNBNDP ($2)) {
 720                         Context_def *td = Context_def::unsmob ($$);
 721                         if (!td) {
 722                                 $$ = Context_def::make_scm ();
 723                                 td = Context_def::unsmob ($$);
 724                         }
 725                         Context_def::unsmob ($$)->add_context_mod ($2);
 726                 }
 727         }
 728         | context_def_spec_body context_modification {
 729                 Context_def *td = Context_def::unsmob ($$);
 730                 if (!td) {
 731                         $$ = Context_def::make_scm ();
 732                         td = Context_def::unsmob ($$);
 733                 }
 734                 SCM new_mods = Context_mod::unsmob ($2)->get_mods ();
 735                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 736                     td->add_context_mod (scm_car (m));
 737                 }
 738         }
 739         | context_def_spec_body context_mod_arg {
 740                 Context_def *td = Context_def::unsmob ($1);
 741                 if (scm_is_eq ($2, SCM_UNSPECIFIED))
 742                         ;
 743                 else if (!td && Context_def::unsmob ($2))
 744                         $$ = $2;
 745                 else {
 746                         if (!td) {
 747                                 $$ = Context_def::make_scm ();
 748                                 td = Context_def::unsmob ($$);
 749                         }
 750                         if (Music::unsmob ($2)) {
 751                                 SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
 752                                 $2 = scm_call_2 (proc, parser->self_scm (), $2);
 753                         }
 754                         if (Context_mod *cm = Context_mod::unsmob ($2)) {
 755                                 for (SCM m = cm->get_mods (); scm_is_pair (m); m = scm_cdr (m)) {
 756                                         td->add_context_mod (scm_car (m));
 757                                 }
 758                         } else
 759                                 parser->parser_error (@2, _ ("not a context mod"));
 760                 }
 761         }
 762         ;
 763
 764
 765
 766 book_block:
 767         BOOK '{' book_body '}'  {
 768                 $$ = $3;
 769                 Book::unsmob ($$)->origin ()->set_spot (@$);
 770                 pop_paper (parser);
 771                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 772         }
 773         ;
 774
 775 /* FIXME:
 776    * Use 'handlers' like for toplevel-* stuff?
 777    * grok \layout and \midi?  */
 778 book_body:
 779         {
 780                 Book *book = new Book;
 781                 init_papers (parser);
 782                 book->paper_ = dynamic_cast<Output_def*> (Output_def::unsmob (parser->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 783                 book->paper_->unprotect ();
 784                 push_paper (parser, book->paper_);
 785                 book->header_ = get_header (parser);
 786                 $$ = book->unprotect ();
 787                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$);
 788         }
 789         | BOOK_IDENTIFIER {
 790                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 791         }
 792         | book_body paper_block {
 793                 Book::unsmob ($1)->paper_ = Output_def::unsmob ($2);
 794                 set_paper (parser, Output_def::unsmob ($2));
 795         }
 796         | book_body bookpart_block {
 797                 SCM proc = parser->lexer_->lookup_identifier ("book-bookpart-handler");
 798                 scm_call_2 (proc, $1, $2);
 799         }
 800         | book_body score_block {
 801                 SCM proc = parser->lexer_->lookup_identifier ("book-score-handler");
 802                 scm_call_2 (proc, $1, $2);
 803         }
 804         | book_body composite_music {
 805                 SCM proc = parser->lexer_->lookup_identifier ("book-music-handler");
 806                 scm_call_3 (proc, parser->self_scm (), $1, $2);
 807         }
 808         | book_body full_markup {
 809                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 810                 scm_call_2 (proc, $1, scm_list_1 ($2));
 811         }
 812         | book_body full_markup_list {
 813                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 814                 scm_call_2 (proc, $1, $2);
 815         }
 816         | book_body SCM_TOKEN {
 817                 // Evaluate and ignore #xxx, as opposed to \xxx
 818                 parser->lexer_->eval_scm_token ($2, @2);
 819         }
 820         | book_body embedded_scm_active
 821         {
 822                 SCM out = SCM_UNDEFINED;
 823                 if (Text_interface::is_markup ($2))
 824                         out = scm_list_1 ($2);
 825                 else if (Text_interface::is_markup_list ($2))
 826                         out = $2;
 827                 if (scm_is_pair (out))
 828                 {
 829                         SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 830                         scm_call_2 (proc, $1, out);
 831                 } else if (Score::unsmob ($2))
 832                 {
 833                         SCM proc = parser->lexer_->lookup_identifier ("book-score-handler");
 834                         scm_call_2 (proc, $1, $2);
 835                 } else if (Output_def *od = Output_def::unsmob ($2)) {
 836                         SCM id = SCM_EOL;
 837
 838                         if (od->c_variable ("is-paper") == SCM_BOOL_T)
 839                                 id = ly_symbol2scm ("$defaultpaper");
 840                         else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 841                                 id = ly_symbol2scm ("$defaultmidi");
 842                         else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 843                                 id = ly_symbol2scm ("$defaultlayout");
 844
 845                         parser->lexer_->set_identifier (id, $2);
 846                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
 847                         parser->parser_error (@2, _("bad expression type"));
 848         }
 849         | book_body
 850         {
 851                 parser->lexer_->add_scope (Book::unsmob ($1)->header_);
 852         } lilypond_header
 853         | book_body error {
 854                 Book *book = Book::unsmob ($1);
 855                 book->paper_ = 0;
 856                 book->scores_ = SCM_EOL;
 857                 book->bookparts_ = SCM_EOL;
 858         }
 859         ;
 860
 861 bookpart_block:
 862         BOOKPART '{' bookpart_body '}' {
 863                 $$ = $3;
 864                 Book::unsmob ($$)->origin ()->set_spot (@$);
 865                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 866         }
 867         ;
 868
 869 bookpart_body:
 870         {
 871                 Book *book = new Book;
 872                 $$ = book->unprotect ();
 873                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$);
 874         }
 875         | BOOK_IDENTIFIER {
 876                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 877         }
 878         | bookpart_body paper_block {
 879                 Book::unsmob ($$)->paper_ = Output_def::unsmob ($2);
 880         }
 881         | bookpart_body score_block {
 882                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-score-handler");
 883                 scm_call_2 (proc, $1, $2);
 884         }
 885         | bookpart_body composite_music {
 886                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-music-handler");
 887                 scm_call_3 (proc, parser->self_scm (), $1, $2);
 888         }
 889         | bookpart_body full_markup {
 890                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 891                 scm_call_2 (proc, $1, scm_list_1 ($2));
 892         }
 893         | bookpart_body full_markup_list {
 894                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 895                 scm_call_2 (proc, $1, $2);
 896         }
 897         | bookpart_body SCM_TOKEN {
 898                 // Evaluate and ignore #xxx, as opposed to \xxx
 899                 parser->lexer_->eval_scm_token ($2, @2);
 900         }
 901         | bookpart_body embedded_scm_active
 902         {
 903                 SCM out = SCM_UNDEFINED;
 904                 if (Text_interface::is_markup ($2))
 905                         out = scm_list_1 ($2);
 906                 else if (Text_interface::is_markup_list ($2))
 907                         out = $2;
 908                 if (scm_is_pair (out))
 909                 {
 910                         SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 911                         scm_call_2 (proc, $1, out);
 912                 } else if (Score::unsmob ($2))
 913                 {
 914                         SCM proc = parser->lexer_->lookup_identifier ("bookpart-score-handler");
 915                         scm_call_2 (proc, $1, $2);
 916                 } else if (Output_def *od = Output_def::unsmob ($2)) {
 917                         SCM id = SCM_EOL;
 918
 919                         if (od->c_variable ("is-paper") == SCM_BOOL_T)
 920                                 id = ly_symbol2scm ("$defaultpaper");
 921                         else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 922                                 id = ly_symbol2scm ("$defaultmidi");
 923                         else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 924                                 id = ly_symbol2scm ("$defaultlayout");
 925
 926                         parser->lexer_->set_identifier (id, $2);
 927                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
 928                         parser->parser_error (@2, _("bad expression type"));
 929         }
 930         | bookpart_body
 931         {
 932                 Book *book = Book::unsmob ($1);
 933                 if (!ly_is_module (book->header_))
 934                         book->header_ = ly_make_module (false);
 935                 parser->lexer_->add_scope (book->header_);
 936         } lilypond_header
 937         | bookpart_body error {
 938                 Book *book = Book::unsmob ($1);
 939                 book->paper_ = 0;
 940                 book->scores_ = SCM_EOL;
 941         }
 942         ;
 943
 944 score_block:
 945         SCORE '{' score_body '}'        {
 946                 Score::unsmob ($3)->origin ()->set_spot (@$);
 947                 $$ = $3;
 948         }
 949         ;
 950
 951 score_body:
 952         score_items {
 953                 if (!Score::unsmob ($1)) {
 954                         parser->parser_error (@1, _("Missing music in \\score"));
 955                         $$ = (new Score)->unprotect ();
 956                         if (scm_is_pair ($1) && ly_is_module (scm_car ($1)))
 957                         {
 958                                 Score::unsmob ($$)->set_header (scm_car ($1));
 959                                 $1 = scm_cdr ($1);
 960                         }
 961                         for (SCM p = scm_reverse_x ($1, SCM_EOL);
 962                              scm_is_pair (p); p = scm_cdr (p))
 963                         {
 964                                 Score::unsmob ($$)->
 965                                         add_output_def (Output_def::unsmob (scm_car (p)));
 966                         }
 967                 }
 968         }
 969         | score_body error {
 970                 Score::unsmob ($$)->error_found_ = true;
 971         }
 972         ;
 973
 974 score_item:
 975         embedded_scm
 976         | music
 977         | output_def
 978         ;
 979
 980 score_items:
 981         /* empty */
 982         {
 983                 $$ = SCM_EOL;
 984         }
 985         | score_items score_item
 986         {
 987                 Output_def *od = Output_def::unsmob ($2);
 988                 if (od) {
 989                         if (od->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 990                         {
 991                                 parser->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 992                                 od = 0;
 993                                 $2 = SCM_UNSPECIFIED;
 994                         }
 995                 } else if (!Score::unsmob ($$)) {
 996                         if (Music::unsmob ($2)) {
 997                                 SCM scorify = ly_lily_module_constant ("scorify-music");
 998                                 $2 = scm_call_2 (scorify, $2, parser->self_scm ());
 999                         }
1000                         if (Score::unsmob ($2))
1001                         {
1002                                 $$ = $2;
1003                                 $2 = SCM_UNSPECIFIED;
1004                         }
1005                 }
1006                 Score *score = Score::unsmob ($$);
1007                 if (score && scm_is_pair ($1)) {
1008                         if (ly_is_module (scm_car ($1)))
1009                         {
1010                                 score->set_header (scm_car ($1));
1011                                 $1 = scm_cdr ($1);
1012                         }
1013                         for (SCM p = scm_reverse_x ($1, SCM_EOL);
1014                              scm_is_pair (p); p = scm_cdr (p))
1015                         {
1016                                 score->add_output_def (Output_def::unsmob (scm_car (p)));
1017                         }
1018                 }
1019                 if (od) {
1020                         if (score)
1021                                 score->add_output_def (od);
1022                         else if (scm_is_pair ($$) && ly_is_module (scm_car ($$)))
1023                                 scm_set_cdr_x ($$, scm_cons ($2, scm_cdr ($$)));
1024                         else
1025                                 $$ = scm_cons ($2, $$);
1026                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
1027                         parser->parser_error (@2, _("Spurious expression in \\score"));
1028         }
1029         | score_items
1030         {
1031                 if (Score *score = Score::unsmob ($1)) {
1032                         if (!ly_is_module (score->get_header ()))
1033                                 score->set_header (ly_make_module (false));
1034                         parser->lexer_->add_scope (score->get_header ());
1035                 } else {
1036                         if (!scm_is_pair ($1) || !ly_is_module (scm_car ($1)))
1037                                 $1 = scm_cons (ly_make_module (false), $1);
1038                         parser->lexer_->add_scope (scm_car ($1));
1039                 }
1040         } lilypond_header
1041         {
1042                 $$ = $1;
1043         }
1044         ;
1045
1046
1047 /*
1048         OUTPUT DEF
1049 */
1050
1051 paper_block:
1052         output_def {
1053                 Output_def *od = Output_def::unsmob ($1);
1054
1055                 if (od->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
1056                 {
1057                         parser->parser_error (@1, _ ("need \\paper for paper block"));
1058                         $$ = get_paper (parser)->unprotect ();
1059                 }
1060         }
1061         ;
1062
1063
1064 output_def:
1065         output_def_body '}' {
1066                 if (scm_is_pair ($1))
1067                         $$ = scm_car ($1);
1068
1069                 parser->lexer_->remove_scope ();
1070                 parser->lexer_->pop_state ();
1071         }
1072         ;
1073
1074 output_def_head:
1075         PAPER {
1076                 Output_def *p = get_paper (parser);
1077                 p->input_origin_ = @$;
1078                 parser->lexer_->add_scope (p->scope_);
1079                 $$ = p->unprotect ();
1080         }
1081         | MIDI    {
1082                 Output_def *p = get_midi (parser);
1083                 $$ = p->unprotect ();
1084                 parser->lexer_->add_scope (p->scope_);
1085         }
1086         | LAYOUT        {
1087                 Output_def *p = get_layout (parser);
1088
1089                 parser->lexer_->add_scope (p->scope_);
1090                 $$ = p->unprotect ();
1091         }
1092         ;
1093
1094 output_def_head_with_mode_switch:
1095         output_def_head {
1096                 parser->lexer_->push_initial_state ();
1097                 $$ = $1;
1098         }
1099         ;
1100
1101 // We need this weird nonterminal because both music as well as a
1102 // context definition can start with \context and the difference is
1103 // only apparent after looking at the next token.  If it is '{', there
1104 // is still time to escape from notes mode.
1105
1106 music_or_context_def:
1107         music_assign
1108         | context_def_spec_block
1109         ;
1110
1111 output_def_body:
1112         output_def_head_with_mode_switch '{' {
1113                 Output_def::unsmob ($1)->input_origin_.set_spot (@$);
1114                 // This is a stupid trick to mark the beginning of the
1115                 // body for deciding whether to allow
1116                 // embedded_scm_active to have an output definition
1117                 $$ = scm_list_1 ($1);
1118         }
1119         | output_def_body assignment  {
1120                 if (scm_is_pair ($1))
1121                         $$ = scm_car ($1);
1122         }
1123         | output_def_body embedded_scm_active
1124         {
1125                 // We don't switch into note mode for Scheme functions
1126                 // here.  Does not seem warranted/required in output
1127                 // definitions.
1128                 if (scm_is_pair ($1))
1129                 {
1130                         Output_def *o = Output_def::unsmob ($2);
1131                         if (o) {
1132                                 o->input_origin_.set_spot (@$);
1133                                 $1 = o->self_scm ();
1134                                 parser->lexer_->remove_scope ();
1135                                 parser->lexer_->add_scope (o->scope_);
1136                                 $2 = SCM_UNSPECIFIED;
1137                         } else
1138                                 $1 = scm_car ($1);
1139                 }
1140                 if (Context_def::unsmob ($2))
1141                         assign_context_def (Output_def::unsmob ($1), $2);
1142                 // Seems unlikely, but let's be complete:
1143                 else if (Music::unsmob ($2))
1144                 {
1145                         SCM proc = parser->lexer_->lookup_identifier
1146                                 ("output-def-music-handler");
1147                         scm_call_3 (proc, parser->self_scm (),
1148                                     $1, $2);
1149                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
1150                         parser->parser_error (@2, _("bad expression type"));
1151                 $$ = $1;
1152         }
1153         | output_def_body SCM_TOKEN {
1154                 if (scm_is_pair ($1))
1155                         $$ = scm_car ($1);
1156                 // Evaluate and ignore #xxx, as opposed to \xxx
1157                 parser->lexer_->eval_scm_token ($2, @2);
1158         }
1159         | output_def_body
1160         {
1161                 if (scm_is_pair ($1))
1162                         $1 = scm_car ($1);
1163                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
1164                 parser->lexer_->push_note_state (nn);
1165         } music_or_context_def
1166         {
1167                 parser->lexer_->pop_state ();
1168                 if (Context_def::unsmob ($3))
1169                         assign_context_def (Output_def::unsmob ($1), $3);
1170                 else {
1171
1172                         SCM proc = parser->lexer_->lookup_identifier
1173                                      ("output-def-music-handler");
1174                         scm_call_3 (proc, parser->self_scm (),
1175                                     $1, $3);
1176                 }
1177                 $$ = $1;
1178         }
1179         | output_def_body error {
1180
1181         }
1182         ;
1183
1184 tempo_event:
1185         TEMPO steno_duration '=' tempo_range    {
1186                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_EOL, $2, $4);
1187         }
1188         | TEMPO scalar steno_duration '=' tempo_range   {
1189                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
1190         }
1191         | TEMPO scalar {
1192                 $$ = MAKE_SYNTAX ("tempo", @$, $2);
1193         } %prec ':'
1194         ;
1195
1196 /*
1197 The representation of a  list is reversed to have efficient append.  */
1198
1199 music_list:
1200         /* empty */ {
1201                 $$ = SCM_EOL;
1202         }
1203         | music_list music_embedded {
1204                 if (Music::unsmob ($2))
1205                         $$ = scm_cons ($2, $1);
1206         }
1207         | music_list error {
1208                 Music *m = MY_MAKE_MUSIC("Music", @$);
1209                 // ugh. code dup
1210                 m->set_property ("error-found", SCM_BOOL_T);
1211                 $$ = scm_cons (m->self_scm (), $1);
1212                 m->unprotect (); /* UGH */
1213         }
1214         ;
1215
1216 braced_music_list:
1217         '{' music_list '}'
1218         {
1219                 $$ = scm_reverse_x ($2, SCM_EOL);
1220         }
1221         ;
1222
1223 music:  music_assign
1224         | lyric_element_music
1225         | pitch_or_music
1226         {
1227                 $$ = make_music_from_simple (parser, @1, $1);
1228                 if (!Music::unsmob ($$))
1229                 {
1230                         parser->parser_error (@1, _ ("music expected"));
1231                         $$ = MAKE_SYNTAX ("void-music", @$);
1232                 }
1233         }
1234         ;
1235
1236 music_embedded:
1237         music
1238         {
1239                 if (Music::unsmob ($1)->is_mus_type ("post-event")) {
1240                         parser->parser_error (@1, _ ("unexpected post-event"));
1241                         $$ = SCM_UNSPECIFIED;
1242                 }
1243         }
1244         | music_embedded_backup
1245         {
1246                 $$ = $1;
1247         }
1248         | music_embedded_backup BACKUP lyric_element_music
1249         {
1250                 $$ = $3;
1251         }
1252         | multiplied_duration post_events
1253         {
1254                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1255
1256                 parser->default_duration_ = *Duration::unsmob ($1);
1257                 n->set_property ("duration", $1);
1258
1259                 if (scm_is_pair ($2))
1260                         n->set_property ("articulations",
1261                                          scm_reverse_x ($2, SCM_EOL));
1262                 $$ = n->unprotect ();
1263         }
1264         ;
1265
1266 music_embedded_backup:
1267         embedded_scm
1268         {
1269                 if (scm_is_eq ($1, SCM_UNSPECIFIED))
1270                         $$ = $1;
1271                 else if (Music *m = Music::unsmob ($1)) {
1272                         if (m->is_mus_type ("post-event")) {
1273                                 parser->parser_error
1274                                         (@1, _ ("unexpected post-event"));
1275                                 $$ = SCM_UNSPECIFIED;
1276                         } else
1277                                 $$ = $1;
1278                 } else if (parser->lexer_->is_lyric_state ()
1279                            && Text_interface::is_markup ($1))
1280                         MYBACKUP (LYRIC_ELEMENT, $1, @1);
1281                 else {
1282                         @$.warning (_ ("Ignoring non-music expression"));
1283                         $$ = $1;
1284                 }
1285         }
1286         ;
1287
1288 // music_assign does not need to contain lyrics: there are no
1289 // assignments in lyricmode.
1290 music_assign:
1291         simple_music
1292         | composite_music %prec COMPOSITE
1293         ;
1294
1295 repeated_music:
1296         REPEAT simple_string unsigned_number music
1297         {
1298                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, SCM_EOL);
1299         }
1300         | REPEAT simple_string unsigned_number music ALTERNATIVE braced_music_list
1301         {
1302                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $6);
1303         }
1304         ;
1305
1306 sequential_music:
1307         SEQUENTIAL braced_music_list {
1308                 $$ = MAKE_SYNTAX ("sequential-music", @$, $2);
1309         }
1310         | braced_music_list {
1311                 $$ = MAKE_SYNTAX ("sequential-music", @$, $1);
1312         }
1313         ;
1314
1315 simultaneous_music:
1316         SIMULTANEOUS braced_music_list {
1317                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, $2);
1318         }
1319         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1320                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($2, SCM_EOL));
1321         }
1322         ;
1323
1324 simple_music:
1325         event_chord
1326         | music_property_def
1327         | context_change
1328         ;
1329
1330 context_modification:
1331         WITH
1332         {
1333                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
1334                 parser->lexer_->push_note_state (nn);
1335         } '{' context_mod_list '}'
1336         {
1337                 parser->lexer_->pop_state ();
1338                 $$ = $4;
1339         }
1340         | WITH CONTEXT_MOD_IDENTIFIER
1341         {
1342                 $$ = $2;
1343         }
1344         | CONTEXT_MOD_IDENTIFIER
1345         {
1346                 $$ = $1;
1347         }
1348         | WITH context_modification_arg
1349         {
1350                 if (Music::unsmob ($2)) {
1351                         SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
1352                         $2 = scm_call_2 (proc, parser->self_scm (), $2);
1353                 }
1354                 if (Context_mod::unsmob ($2))
1355                         $$ = $2;
1356                 else {
1357                         parser->parser_error (@2, _ ("not a context mod"));
1358                         $$ = Context_mod ().smobbed_copy ();
1359                 }
1360         }
1361         ;
1362
1363 context_modification_arg:
1364         embedded_scm
1365         | MUSIC_IDENTIFIER
1366         ;
1367
1368 optional_context_mod:
1369         /**/ {
1370             $$ = SCM_EOL;
1371         }
1372         | context_modification
1373         {
1374               $$ = $1;
1375         }
1376         ;
1377
1378 context_mod_list:
1379         /**/ {
1380             $$ = Context_mod ().smobbed_copy ();
1381         }
1382         | context_mod_list context_mod  {
1383                 if (!SCM_UNBNDP ($2))
1384                         Context_mod::unsmob ($1)->add_context_mod ($2);
1385         }
1386         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1387                  Context_mod *md = Context_mod::unsmob ($2);
1388                  if (md)
1389                      Context_mod::unsmob ($1)->add_context_mods (md->get_mods ());
1390         }
1391         | context_mod_list context_mod_arg {
1392                 if (scm_is_eq ($2, SCM_UNSPECIFIED))
1393                         ;
1394                 else if (Music::unsmob ($2)) {
1395                         SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
1396                         $2 = scm_call_2 (proc, parser->self_scm (), $2);
1397                 }
1398                 if (Context_mod::unsmob ($2))
1399                         Context_mod::unsmob ($$)->add_context_mods
1400                                 (Context_mod::unsmob ($2)->get_mods ());
1401                 else {
1402                         parser->parser_error (@2, _ ("not a context mod"));
1403                 }
1404         }
1405         ;
1406
1407 context_prefix:
1408         CONTEXT symbol optional_id optional_context_mod {
1409                 Context_mod *ctxmod = Context_mod::unsmob ($4);
1410                 SCM mods = SCM_EOL;
1411                 if (ctxmod)
1412                         mods = ctxmod->get_mods ();
1413                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_F);
1414         }
1415         | NEWCONTEXT symbol optional_id optional_context_mod {
1416                 Context_mod *ctxmod = Context_mod::unsmob ($4);
1417                 SCM mods = SCM_EOL;
1418                 if (ctxmod)
1419                         mods = ctxmod->get_mods ();
1420                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_T);
1421         }
1422         ;
1423
1424 new_lyrics:
1425         ADDLYRICS lyric_mode_music {
1426                 $$ = scm_list_1 ($2);
1427         }
1428         | new_lyrics ADDLYRICS lyric_mode_music {
1429                 $$ = scm_cons ($3, $1);
1430         }
1431         ;
1432
1433 composite_music:
1434         music_function_call
1435         | repeated_music                { $$ = $1; }
1436         | context_prefix music
1437         {
1438                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1439         }
1440         | composite_music new_lyrics {
1441                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1442         } %prec COMPOSITE
1443         | LYRICSTO simple_string lyric_mode_music {
1444                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $3);
1445         }
1446         | music_bare
1447         ;
1448
1449 music_bare:
1450         mode_changed_music
1451         | MUSIC_IDENTIFIER
1452         | grouped_music_list
1453         ;
1454
1455 grouped_music_list:
1456         simultaneous_music              { $$ = $1; }
1457         | sequential_music              { $$ = $1; }
1458         ;
1459
1460 /* Function argument lists are arguably the most complex part in the
1461  * parser.  They are pretty tricky to understand because of the way
1462  * they are processed, and because of optional arguments that can be
1463  * omitted.  When there are several optional arguments in a row,
1464  * omitting one automatically omits all following arguments.  Optional
1465  * arguments can only be omitted when either
1466  *
1467  * a) the omission is explicitly started with \default
1468  * b) the omission is implicitly started by an argument not matching
1469  *    its predicate, and there is a mandatory argument later that can
1470  *    "catch" the argument that does not fit.
1471  *
1472  * When argument parsing starts, the lexer pushes EXPECT_SCM tokens
1473  * (corresponding to mandatory arguments and having a predicate
1474  * function as semantic value) or EXPECT_OPTIONAL EXPECT_SCM (where
1475  * the semantic value of the EXPECT_OPTIONAL token is the default to
1476  * use when the optional argument is omitted, and EXPECT_SCM again has
1477  * the argument predicate as semantic value) in reverse order to the
1478  * parser, followed by EXPECT_NO_MORE_ARGS.  The argument list is then
1479  * processed inside-out while actual tokens are consumed.
1480  *
1481  * This means that the argument list tokens determine the actions
1482  * taken as they arrive.  The structure of the argument list is known
1483  * to the parser and stored in its parse stack when the first argument
1484  * is being parsed.  What the parser does not know is which predicates
1485  * will match and whether or not \default will be appearing in the
1486  * argument list, and where.
1487  *
1488  * Sequences of 0 or more optional arguments are scanned using either
1489  * function_arglist_backup or function_arglist_nonbackup.  The first
1490  * is used when optional arguments are followed by at least one
1491  * mandatory argument: in that case optional arguments may be skipped
1492  * by either a false predicate (in which case the expression will be
1493  * pushed back as one or more tokens, preceded by a BACKUP token) or
1494  * by using \default.
1495  *
1496  * If optional arguments are at the end of the argument list, they are
1497  * instead scanned using function_arglist_nonbackup: here the only
1498  * manner to enter into skipping of optional arguments is the use of
1499  * \default.
1500  *
1501  * The argument list of a normal function call is parsed using
1502  * function_arglist.  The part of an argument list before a mandatory
1503  * argument is parsed using function_arglist_optional.
1504  *
1505  * The difference is that leading optional arguments are scanned using
1506  * function_arglist_nonbackup and function_arglist_backup,
1507  * respectively.
1508  *
1509  * Most other details are obvious in the rules themselves.
1510  *
1511  */
1512
1513 symbol_list_arg:
1514         SYMBOL_LIST
1515         | SYMBOL_LIST '.' symbol_list_rev
1516         {
1517                 $$ = scm_append (scm_list_2 ($1, scm_reverse_x ($3, SCM_EOL)));
1518         }
1519         ;
1520
1521 symbol_list_rev:
1522         symbol_list_part
1523         | symbol_list_rev '.' symbol_list_part
1524         {
1525                 $$ = scm_append_x (scm_list_2 ($3, $1));
1526         }
1527         ;
1528
1529 // symbol_list_part delivers elements in reverse copy.
1530
1531 symbol_list_part:
1532         symbol_list_element
1533         {
1534                 SCM sym_l_p = ly_lily_module_constant ("symbol-list?");
1535                 $$ = try_string_variants (sym_l_p, $1);
1536                 if (SCM_UNBNDP ($$)) {
1537                         parser->parser_error (@1, _("not a symbol"));
1538                         $$ = SCM_EOL;
1539                 } else
1540                         $$ = scm_reverse ($$);
1541         }
1542         ;
1543
1544
1545 symbol_list_element:
1546         STRING
1547         | embedded_scm_bare
1548         ;
1549
1550
1551 function_arglist_nonbackup:
1552         function_arglist_common
1553         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup post_event_nofinger
1554         {
1555                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1556         }
1557         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' UNSIGNED
1558         {
1559                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1560                 if (scm_is_true (scm_call_1 ($2, n)))
1561                         $$ = scm_cons (n, $3);
1562                 else {
1563                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1564                         t->set_property ("digit", $5);
1565                         $$ = check_scheme_arg (parser, @4, t->unprotect (),
1566                                                $3, $2, n);
1567                 }
1568         }
1569         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' REAL
1570         {
1571                 $$ = check_scheme_arg (parser, @4,
1572                                        scm_difference ($5, SCM_UNDEFINED),
1573                                        $3, $2);
1574         }
1575         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' NUMBER_IDENTIFIER
1576         {
1577                 $$ = check_scheme_arg (parser, @4,
1578                                        scm_difference ($5, SCM_UNDEFINED),
1579                                        $3, $2);
1580         }
1581         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup embedded_scm_arg
1582         {
1583                 if (scm_is_true (scm_call_1 ($2, $4)))
1584                         $$ = scm_cons ($4, $3);
1585                 else
1586                         $$ = check_scheme_arg (parser, @4,
1587                                                make_music_from_simple
1588                                                (parser, @4, $4),
1589                                                $3, $2);
1590         }
1591         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup bare_number_common
1592         {
1593                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1594         }
1595         | function_arglist_nonbackup_reparse REPARSE pitch_or_music
1596         {
1597                 if (scm_is_true (scm_call_1 ($2, $3)))
1598                         $$ = scm_cons ($3, $1);
1599                 else
1600                         $$ = check_scheme_arg (parser, @3,
1601                                                make_music_from_simple
1602                                                (parser, @3, $3),
1603                                                $1, $2);
1604         }
1605         | function_arglist_nonbackup_reparse REPARSE duration_length
1606         {
1607                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1608         }
1609         | function_arglist_nonbackup_reparse REPARSE bare_number_common
1610         {
1611                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1612         }
1613         | function_arglist_nonbackup_reparse REPARSE SCM_ARG
1614         {
1615                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1616         }
1617         | function_arglist_nonbackup_reparse REPARSE lyric_element_music
1618         {
1619                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1620         }
1621         | function_arglist_nonbackup_reparse REPARSE symbol_list_arg
1622         {
1623                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1624         }
1625         ;
1626
1627 function_arglist_nonbackup_reparse:
1628         EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup SCM_IDENTIFIER
1629         {
1630                 $$ = $3;
1631                 SCM res = try_string_variants ($2, $4);
1632                 if (!SCM_UNBNDP (res))
1633                         if (scm_is_pair (res))
1634                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1635                         else
1636                                 MYREPARSE (@4, $2, SCM_ARG, res);
1637                 else if (scm_is_true
1638                          (scm_call_1
1639                           ($2, make_music_from_simple
1640                            (parser, @4, $4))))
1641                         MYREPARSE (@4, $2, STRING, $4);
1642                 else
1643                         MYREPARSE (@4, $2, SCM_ARG, $4);
1644         }
1645         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup pitch
1646         {
1647                 $$ = $3;
1648                 if (scm_is_true
1649                     (scm_call_1
1650                      ($2, make_music_from_simple
1651                       (parser, @4, $4))))
1652                         MYREPARSE (@4, $2, PITCH_IDENTIFIER, $4);
1653                 else
1654                         MYREPARSE (@4, $2, SCM_ARG, $4);
1655         }
1656         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup steno_tonic_pitch
1657         {
1658                 $$ = $3;
1659                 if (scm_is_true
1660                     (scm_call_1
1661                      ($2, make_music_from_simple
1662                       (parser, @4, $4))))
1663                         MYREPARSE (@4, $2, TONICNAME_PITCH, $4);
1664                 else
1665                         MYREPARSE (@4, $2, SCM_ARG, $4);
1666         }
1667         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup STRING
1668         {
1669                 $$ = $3;
1670                 SCM res = try_string_variants ($2, $4);
1671                 if (!SCM_UNBNDP (res))
1672                         if (scm_is_pair (res))
1673                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1674                         else
1675                                 MYREPARSE (@4, $2, SCM_ARG, res);
1676                 else if (scm_is_true
1677                          (scm_call_1
1678                           ($2, make_music_from_simple
1679                            (parser, @4, $4))))
1680                         MYREPARSE (@4, $2, STRING, $4);
1681                 else
1682                         MYREPARSE (@4, $2, SCM_ARG, $4);
1683         }
1684         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup full_markup
1685         {
1686                 $$ = $3;
1687                 if (scm_is_true (scm_call_1 ($2, $4)))
1688                         MYREPARSE (@4, $2, SCM_ARG, $4);
1689                 else if (scm_is_true
1690                          (scm_call_1
1691                           ($2, make_music_from_simple
1692                            (parser, @4, $4))))
1693                         MYREPARSE (@4, $2, STRING, $4);
1694                 else
1695                         MYREPARSE (@4, $2, SCM_ARG, $4);
1696         }
1697         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup UNSIGNED
1698         {
1699                 $$ = $3;
1700                 if (scm_is_true (scm_call_1 ($2, $4)))
1701                         MYREPARSE (@4, $2, REAL, $4);
1702                 else {
1703                         SCM d = make_duration ($4);
1704                         if (SCM_UNBNDP (d) || scm_is_false (scm_call_1 ($2, d)))
1705                                 MYREPARSE (@4, $2, REAL, $4); // trigger error
1706                         else
1707                                 MYREPARSE (@4, $2, DURATION_IDENTIFIER, d);
1708                 }
1709         }
1710         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup DURATION_IDENTIFIER {
1711                 $$ = $3;
1712                 MYREPARSE (@4, $2, DURATION_IDENTIFIER, $4);
1713         }
1714         ;
1715
1716
1717 // function_arglist_backup can't occur at the end of an argument
1718 // list.
1719 function_arglist_backup:
1720         function_arglist_common
1721         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup embedded_scm_arg
1722         {
1723                 if (scm_is_true (scm_call_1 ($2, $4)))
1724                         $$ = scm_cons ($4, $3);
1725                 else {
1726                         $$ = make_music_from_simple (parser, @4, $4);
1727                         if (scm_is_true (scm_call_1 ($2, $$)))
1728                                 $$ = scm_cons ($$, $3);
1729                         else
1730                         {
1731                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1732                                 MYBACKUP (SCM_ARG, $4, @4);
1733                         }
1734                 }
1735         }
1736         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup post_event_nofinger
1737         {
1738                 if (scm_is_true (scm_call_1 ($2, $4)))
1739                 {
1740                         $$ = scm_cons ($4, $3);
1741                 } else {
1742                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1743                         MYBACKUP (EVENT_IDENTIFIER, $4, @4);
1744                 }
1745         }
1746         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup pitch
1747         {
1748                 if (scm_is_true
1749                     (scm_call_1
1750                      ($2, make_music_from_simple
1751                       (parser, @4, $4))))
1752                 {
1753                         $$ = $3;
1754                         MYREPARSE (@4, $2, PITCH_IDENTIFIER, $4);
1755                 } else if (scm_is_true (scm_call_1 ($2, $4)))
1756                         $$ = scm_cons ($4, $3);
1757                 else {
1758                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1759                         MYBACKUP (PITCH_IDENTIFIER, $4, @4);
1760                 }
1761         }
1762         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup steno_tonic_pitch
1763         {
1764                 if (scm_is_true
1765                     (scm_call_1
1766                      ($2, make_music_from_simple
1767                       (parser, @4, $4))))
1768                 {
1769                         $$ = $3;
1770                         MYREPARSE (@4, $2, TONICNAME_PITCH, $4);
1771                 } else if (scm_is_true (scm_call_1 ($2, $4)))
1772                         $$ = scm_cons ($4, $3);
1773                 else {
1774                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1775                         MYBACKUP (TONICNAME_PITCH, $4, @4);
1776                 }
1777         }
1778         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup full_markup
1779         {
1780                 if (scm_is_true (scm_call_1 ($2, $4)))
1781                         $$ = scm_cons ($4, $3);
1782                 else {
1783                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1784                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
1785                 }
1786         }
1787         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup UNSIGNED
1788         {
1789                 if (scm_is_true (scm_call_1 ($2, $4)))
1790                 {
1791                         MYREPARSE (@4, $2, REAL, $4);
1792                         $$ = $3;
1793                 } else {
1794                         SCM d = make_duration ($4);
1795                         if (SCM_UNBNDP (d) || scm_is_false (scm_call_1 ($2, d)))
1796                         {
1797                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1798                                 MYBACKUP (UNSIGNED, $4, @4);
1799                         } else {
1800                                 MYREPARSE (@4, $2, DURATION_IDENTIFIER, d);
1801                                 $$ = $3;
1802                         }
1803                 }
1804         }
1805         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup REAL
1806         {
1807                 if (scm_is_true (scm_call_1 ($2, $4)))
1808                 {
1809                         $$ = $3;
1810                         MYREPARSE (@4, $2, REAL, $4);
1811                 } else {
1812                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1813                         MYBACKUP (REAL, $4, @4);
1814                 }
1815         }
1816         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup NUMBER_IDENTIFIER
1817         {
1818                 if (scm_is_true (scm_call_1 ($2, $4)))
1819                 {
1820                         $$ = scm_cons ($4, $3);
1821                 } else {
1822                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1823                         MYBACKUP (NUMBER_IDENTIFIER, $4, @4);
1824                 }
1825         }
1826         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' UNSIGNED
1827         {
1828                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1829                 if (scm_is_true (scm_call_1 ($2, n))) {
1830                         $$ = $3;
1831                         MYREPARSE (@5, $2, REAL, n);
1832                 } else {
1833                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1834                         t->set_property ("digit", $5);
1835                         $$ = t->unprotect ();
1836                         if (scm_is_true (scm_call_1 ($2, $$)))
1837                                 $$ = scm_cons ($$, $3);
1838                         else {
1839                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1840                                 MYBACKUP (UNSIGNED, $5, @5);
1841                                 parser->lexer_->push_extra_token (@4, '-');
1842                         }
1843                 }
1844         }
1845         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' REAL
1846         {
1847                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1848                 if (scm_is_true (scm_call_1 ($2, n))) {
1849                         MYREPARSE (@5, $2, REAL, n);
1850                         $$ = $3;
1851                 } else {
1852                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1853                         MYBACKUP (REAL, n, @5);
1854                 }
1855         }
1856         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' NUMBER_IDENTIFIER
1857         {
1858                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1859                 if (scm_is_true (scm_call_1 ($2, n))) {
1860                         $$ = scm_cons (n, $3);
1861                 } else {
1862                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1863                         MYBACKUP (NUMBER_IDENTIFIER, n, @5);
1864                 }
1865         }
1866         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup DURATION_IDENTIFIER
1867         {
1868                 if (scm_is_true (scm_call_1 ($2, $4)))
1869                 {
1870                         MYREPARSE (@4, $2, DURATION_IDENTIFIER, $4);
1871                         $$ = $3;
1872                 } else {
1873                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1874                         MYBACKUP (DURATION_IDENTIFIER, $4, @4);
1875                 }
1876         }
1877         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup SCM_IDENTIFIER
1878         {
1879                 SCM res = try_string_variants ($2, $4);
1880                 if (!SCM_UNBNDP (res))
1881                         if (scm_is_pair (res)) {
1882                                 $$ = $3;
1883                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1884                         }
1885                         else
1886                                 $$ = scm_cons (res, $3);
1887                 else {
1888                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1889                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
1890                 }
1891         }
1892         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup STRING
1893         {
1894                 SCM res = try_string_variants ($2, $4);
1895                 if (!SCM_UNBNDP (res))
1896                         if (scm_is_pair (res)) {
1897                                 $$ = $3;
1898                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1899                         }
1900                         else
1901                                 $$ = scm_cons (res, $3);
1902                 else {
1903                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1904                         MYBACKUP (STRING, $4, @4);
1905                 }
1906         }
1907         | function_arglist_backup REPARSE pitch_or_music
1908         {
1909                 if (scm_is_true (scm_call_1 ($2, $3)))
1910                         $$ = scm_cons ($3, $1);
1911                 else
1912                         $$ = check_scheme_arg (parser, @3,
1913                                                make_music_from_simple
1914                                                (parser, @3, $3),
1915                                                $1, $2);
1916         }
1917         | function_arglist_backup REPARSE bare_number_common
1918         {
1919                 $$ = check_scheme_arg (parser, @3,
1920                                        $3, $1, $2);
1921         }
1922         | function_arglist_backup REPARSE duration_length
1923         {
1924                 $$ = check_scheme_arg (parser, @3,
1925                                        $3, $1, $2);
1926         }
1927         | function_arglist_backup REPARSE symbol_list_arg
1928         {
1929                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1930         }
1931         ;
1932
1933 function_arglist:
1934         function_arglist_nonbackup
1935         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_nonbackup DEFAULT
1936         {
1937                 $$ = scm_cons (loc_on_music (@4, $1), $3);
1938         }
1939         ;
1940
1941 function_arglist_skip_nonbackup:
1942         function_arglist_nonbackup
1943         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_nonbackup
1944         {
1945                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1946         }
1947         ;
1948
1949 function_arglist_common:
1950         EXPECT_NO_MORE_ARGS {
1951                 $$ = SCM_EOL;
1952         }
1953         | EXPECT_SCM function_arglist_optional embedded_scm_arg
1954         {
1955                 if (scm_is_true (scm_call_1 ($1, $3)))
1956                         $$ = scm_cons ($3, $2);
1957                 else
1958                         $$ = check_scheme_arg (parser, @3,
1959                                                make_music_from_simple
1960                                                (parser, @3, $3),
1961                                                $2, $1);
1962         }
1963         | EXPECT_SCM function_arglist_optional bare_number_common
1964         {
1965                 $$ = check_scheme_arg (parser, @3,
1966                                        $3, $2, $1);
1967         }
1968         | EXPECT_SCM function_arglist_optional post_event_nofinger
1969         {
1970                 $$ = check_scheme_arg (parser, @3,
1971                                        $3, $2, $1);
1972         }
1973         | EXPECT_SCM function_arglist_optional '-' NUMBER_IDENTIFIER
1974         {
1975                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1976                 $$ = check_scheme_arg (parser, @4, n, $2, $1);
1977         }
1978         | function_arglist_common_reparse REPARSE SCM_ARG
1979         {
1980                 $$ = check_scheme_arg (parser, @3,
1981                                        $3, $1, $2);
1982         }
1983         | function_arglist_common_reparse REPARSE lyric_element_music
1984         {
1985                 $$ = check_scheme_arg (parser, @3,
1986                                        $3, $1, $2);
1987         }
1988         | function_arglist_common_reparse REPARSE pitch_or_music
1989         {
1990                 if (scm_is_true (scm_call_1 ($2, $3)))
1991                         $$ = scm_cons ($3, $1);
1992                 else
1993                         $$ = check_scheme_arg (parser, @3,
1994                                                make_music_from_simple
1995                                                (parser, @3, $3),
1996                                                $1, $2);
1997         }
1998         | function_arglist_common_reparse REPARSE bare_number_common
1999         {
2000                 $$ = check_scheme_arg (parser, @3,
2001                                        $3, $1, $2);
2002         }
2003         | function_arglist_common_reparse REPARSE duration_length
2004         {
2005                 $$ = check_scheme_arg (parser, @3,
2006                                        $3, $1, $2);
2007         }
2008         | function_arglist_common_reparse REPARSE symbol_list_arg
2009         {
2010                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
2011         }
2012         ;
2013
2014 function_arglist_common_reparse:
2015         EXPECT_SCM function_arglist_optional SCM_IDENTIFIER
2016         {
2017                 $$ = $2;
2018                 SCM res = try_string_variants ($1, $3);
2019                 if (!SCM_UNBNDP (res))
2020                         if (scm_is_pair (res))
2021                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
2022                         else
2023                                 MYREPARSE (@3, $1, SCM_ARG, res);
2024                 else if (scm_is_true
2025                          (scm_call_1
2026                           ($1, make_music_from_simple (parser, @3, $3))))
2027                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
2028                 else
2029                         // This is going to flag a syntax error, we
2030                         // know the predicate to be false.
2031                         MYREPARSE (@3, $1, SCM_ARG, $3);
2032         }
2033         | EXPECT_SCM function_arglist_optional pitch
2034         {
2035                 $$ = $2;
2036                 if (scm_is_true
2037                     (scm_call_1
2038                      ($1, make_music_from_simple
2039                       (parser, @3, $3))))
2040                         MYREPARSE (@3, $1, PITCH_IDENTIFIER, $3);
2041                 else
2042                         MYREPARSE (@3, $1, SCM_ARG, $3);
2043         }
2044         | EXPECT_SCM function_arglist_optional steno_tonic_pitch
2045         {
2046                 $$ = $2;
2047                 if (scm_is_true
2048                     (scm_call_1
2049                      ($1, make_music_from_simple
2050                       (parser, @3, $3))))
2051                         MYREPARSE (@3, $1, TONICNAME_PITCH, $3);
2052                 else
2053                         MYREPARSE (@3, $1, SCM_ARG, $3);
2054         }
2055         | EXPECT_SCM function_arglist_optional STRING
2056         {
2057                 $$ = $2;
2058                 SCM res = try_string_variants ($1, $3);
2059                 if (!SCM_UNBNDP (res))
2060                         if (scm_is_pair (res))
2061                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
2062                         else
2063                                 MYREPARSE (@3, $1, SCM_ARG, res);
2064                 else if (scm_is_true
2065                          (scm_call_1
2066                           ($1, make_music_from_simple (parser, @3, $3))))
2067                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
2068                 else
2069                         // This is going to flag a syntax error, we
2070                         // know the predicate to be false.
2071                         MYREPARSE (@3, $1, SCM_ARG, $3);
2072         }
2073         | EXPECT_SCM function_arglist_optional full_markup
2074         {
2075                 $$ = $2;
2076                 if (scm_is_true (scm_call_1 ($1, $3)))
2077                         MYREPARSE (@3, $1, SCM_ARG, $3);
2078                 else if (scm_is_true
2079                          (scm_call_1
2080                           ($1, make_music_from_simple (parser, @3, $3))))
2081                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
2082                 else
2083                         // This is going to flag a syntax error, we
2084                         // know the predicate to be false.
2085                         MYREPARSE (@3, $1, SCM_ARG, $3);
2086         }
2087         | EXPECT_SCM function_arglist_optional UNSIGNED
2088         {
2089                 $$ = $2;
2090                 if (scm_is_true (scm_call_1 ($1, $3)))
2091                         MYREPARSE (@3, $1, REAL, $3);
2092                 else {
2093                         SCM d = make_duration ($3);
2094                         if (SCM_UNBNDP (d) || scm_is_false (scm_call_1 ($1, d)))
2095                                 MYREPARSE (@3, $1, REAL, $3);
2096                         else
2097                                 MYREPARSE (@3, $1, DURATION_IDENTIFIER, d);
2098                 }
2099         }
2100         | EXPECT_SCM function_arglist_optional DURATION_IDENTIFIER
2101         {
2102                 $$ = $2;
2103                 MYREPARSE (@3, $1, DURATION_IDENTIFIER, $3);
2104         }
2105         | EXPECT_SCM function_arglist_optional '-' UNSIGNED
2106         {
2107                 $$ = $2;
2108                 SCM n = scm_difference ($4, SCM_UNDEFINED);
2109                 if (scm_is_true (scm_call_1 ($1, n)))
2110                         MYREPARSE (@4, $1, REAL, n);
2111                 else {
2112                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @4);
2113                         t->set_property ("digit", $4);
2114                         SCM m = t->unprotect ();
2115                         if (scm_is_true (scm_call_1 ($1, m)))
2116                                 MYREPARSE (@4, $1, SCM_ARG, m);
2117                         else
2118                                 MYREPARSE (@4, $1, SCM_ARG, $4);
2119                 }
2120         }
2121         | EXPECT_SCM function_arglist_optional '-' REAL
2122         {
2123                 $$ = $2;
2124                 SCM n = scm_difference ($4, SCM_UNDEFINED);
2125                 MYREPARSE (@4, $1, REAL, n);
2126         }
2127         ;
2128
2129 function_arglist_optional:
2130         function_arglist_backup
2131         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_backup DEFAULT
2132         {
2133                 $$ = scm_cons (loc_on_music (@4, $1), $3);
2134         }
2135         | function_arglist_skip_backup BACKUP
2136         ;
2137
2138 function_arglist_skip_backup:
2139         function_arglist_backup
2140         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_backup
2141         {
2142                 $$ = scm_cons (loc_on_music (@3, $1), $3);
2143         }
2144         ;
2145
2146 music_function_call:
2147         MUSIC_FUNCTION function_arglist {
2148                 $$ = MAKE_SYNTAX ("music-function", @$,
2149                                          $1, $2);
2150         }
2151         ;
2152
2153
2154 optional_id:
2155         /**/ { $$ = SCM_EOL; }
2156         | '=' simple_string {
2157                 $$ = $2;
2158         }
2159         ;
2160
2161 // We must not have lookahead tokens parsed in lyric mode.  In order
2162 // to save confusion, we take almost the same set as permitted with
2163 // \lyricmode and/or \lyrics.  However, music identifiers are also
2164 // allowed, and they obviously do not require switching into lyrics
2165 // mode for parsing.
2166
2167 lyric_mode_music:
2168         {
2169                 parser->lexer_->push_lyric_state ();
2170         } grouped_music_list
2171         {
2172                 parser->lexer_->pop_state ();
2173                 $$ = $2;
2174         }
2175         | MUSIC_IDENTIFIER
2176         ;
2177
2178 mode_changed_music:
2179         mode_changing_head grouped_music_list {
2180                 if ($1 == ly_symbol2scm ("chords"))
2181                 {
2182                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
2183                 }
2184                 else
2185                 {
2186                   $$ = $2;
2187                 }
2188                 parser->lexer_->pop_state ();
2189         }
2190         | mode_changing_head_with_context optional_context_mod grouped_music_list {
2191                 Context_mod *ctxmod = Context_mod::unsmob ($2);
2192                 SCM mods = SCM_EOL;
2193                 if (ctxmod)
2194                         mods = ctxmod->get_mods ();
2195                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, mods, SCM_BOOL_T, $3);
2196                 if ($1 == ly_symbol2scm ("ChordNames"))
2197                 {
2198                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
2199                 }
2200                 parser->lexer_->pop_state ();
2201         }
2202         ;
2203
2204 mode_changing_head:
2205         NOTEMODE {
2206                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
2207                 parser->lexer_->push_note_state (nn);
2208
2209                 $$ = ly_symbol2scm ("notes");
2210         }
2211         | DRUMMODE
2212                 {
2213                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
2214                 parser->lexer_->push_note_state (nn);
2215
2216                 $$ = ly_symbol2scm ("drums");
2217         }
2218         | FIGUREMODE {
2219                 parser->lexer_->push_figuredbass_state ();
2220
2221                 $$ = ly_symbol2scm ("figures");
2222         }
2223         | CHORDMODE {
2224                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
2225                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
2226                 nn = parser->lexer_->lookup_identifier ("pitchnames");
2227                 parser->lexer_->push_chord_state (nn);
2228                 $$ = ly_symbol2scm ("chords");
2229
2230         }
2231         | LYRICMODE
2232                 { parser->lexer_->push_lyric_state ();
2233                 $$ = ly_symbol2scm ("lyrics");
2234         }
2235         ;
2236
2237 mode_changing_head_with_context:
2238         DRUMS {
2239                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
2240                 parser->lexer_->push_note_state (nn);
2241
2242                 $$ = ly_symbol2scm ("DrumStaff");
2243         }
2244         | FIGURES {
2245                 parser->lexer_->push_figuredbass_state ();
2246
2247                 $$ = ly_symbol2scm ("FiguredBass");
2248         }
2249         | CHORDS {
2250                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
2251                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
2252                 nn = parser->lexer_->lookup_identifier ("pitchnames");
2253                 parser->lexer_->push_chord_state (nn);
2254                 $$ = ly_symbol2scm ("ChordNames");
2255         }
2256         | LYRICS
2257                 { parser->lexer_->push_lyric_state ();
2258                 $$ = ly_symbol2scm ("Lyrics");
2259         }
2260         ;
2261
2262 context_change:
2263         CHANGE symbol '=' simple_string  {
2264                 $$ = MAKE_SYNTAX ("context-change", @$, $2, $4);
2265         }
2266         ;
2267
2268
2269 property_path:
2270         symbol_list_rev  {
2271                 $$ = scm_reverse_x ($1, SCM_EOL);
2272         }
2273         | symbol_list_rev property_path {
2274                 $$ = scm_reverse_x ($1, $2);
2275         }
2276         ;
2277
2278 property_operation:
2279         symbol '=' scalar {
2280                 $$ = scm_list_3 (ly_symbol2scm ("assign"), $1, $3);
2281         }
2282         | UNSET symbol {
2283                 $$ = scm_list_2 (ly_symbol2scm ("unset"), $2);
2284         }
2285         | OVERRIDE property_path '=' scalar {
2286                 if (scm_ilength ($2) < 2) {
2287                         parser->parser_error (@2, _("bad grob property path"));
2288                         $$ = SCM_UNDEFINED;
2289                 } else {
2290                         $$ = scm_cons (ly_symbol2scm ("push"),
2291                                        scm_cons2 (scm_car ($2),
2292                                                   $4,
2293                                                   scm_cdr ($2)));
2294                 }
2295         }
2296         | REVERT revert_arg {
2297                 $$ = scm_cons (ly_symbol2scm ("pop"), $2);
2298         }
2299         ;
2300
2301 // This is all quite awkward for the sake of substantial backward
2302 // compatibility while at the same time allowing a more "natural" form
2303 // of specification not separating grob specification from grob
2304 // property path.  The purpose of this definition of revert_arg is to
2305 // allow the symbol list which specifies grob and property to revert
2306 // to be optionally be split into two parts after the grob (which in
2307 // this case is just the first element of the list).  symbol_list_part
2308 // is only one path component, but it can be parsed without lookahead,
2309 // so we can follow it with a synthetic BACKUP token when needed.  If
2310 // the first symbol_list_part already contains multiple elements (only
2311 // possible if a Scheme expression provides them), we just parse for
2312 // additional elements introduced by '.', which is what the
2313 // SYMBOL_LIST backup in connection with the immediately following
2314 // rule using symbol_list_arg does.
2315 //
2316 // As long as we don't have our coffers filled with both grob and at
2317 // least one grob property specification, the rest of the required
2318 // symbol list chain may be provided either with or without a leading
2319 // dot.  This is for both allowing the traditional
2320 // \revert Accidental #'color
2321 // as well as well as the "naive" form
2322 // \revert Accidental.color
2323
2324 revert_arg:
2325         revert_arg_backup BACKUP symbol_list_arg
2326         {
2327                 $$ = $3;
2328         }
2329         ;
2330
2331 revert_arg_backup:
2332         revert_arg_part
2333         {
2334                 if (scm_is_null ($1)
2335                     || scm_is_null (scm_cdr ($1)))
2336                         MYBACKUP (SCM_ARG, $1, @1);
2337                 else
2338                         MYBACKUP (SYMBOL_LIST, scm_reverse_x ($1, SCM_EOL), @1);
2339         }
2340         ;
2341
2342 // revert_arg_part delivers results in reverse
2343 revert_arg_part:
2344         symbol_list_part
2345         | revert_arg_backup BACKUP SCM_ARG '.' symbol_list_part
2346         {
2347                 $$ = scm_append_x (scm_list_2 ($5, $3));
2348         }
2349         | revert_arg_backup BACKUP SCM_ARG symbol_list_part
2350         {
2351                 $$ = scm_append_x (scm_list_2 ($4, $3));
2352         }
2353         ;
2354
2355 context_def_mod:
2356         CONSISTS { $$ = ly_symbol2scm ("consists"); }
2357         | REMOVE { $$ = ly_symbol2scm ("remove"); }
2358
2359         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
2360         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
2361         | DENIES { $$ = ly_symbol2scm ("denies"); }
2362
2363         | ALIAS { $$ = ly_symbol2scm ("alias"); }
2364         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
2365         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
2366         | NAME { $$ = ly_symbol2scm ("context-name"); }
2367         ;
2368
2369 context_mod:
2370         property_operation { $$ = $1; }
2371         | context_def_mod STRING {
2372                 $$ = scm_list_2 ($1, $2);
2373         }
2374         | context_def_mod embedded_scm
2375         {
2376                 if (!scm_is_string ($2)
2377                     && ly_symbol2scm ("consists") != $1
2378                     && ly_symbol2scm ("remove") != $1)
2379                 {
2380                         $$ = SCM_EOL;
2381                         parser->parser_error (@1, _ ("only \\consists and \\remove take non-string argument."));
2382                 }
2383                 else
2384                 {
2385                         $$ = scm_list_2 ($1, $2);
2386                 }
2387         }
2388         ;
2389
2390 // If defined, at least two members.
2391 grob_prop_spec:
2392         symbol_list_rev
2393         {
2394                 SCM l = scm_reverse_x ($1, SCM_EOL);
2395                 if (scm_is_pair (l)
2396                     && to_boolean
2397                     (scm_object_property (scm_car (l),
2398                                           ly_symbol2scm ("is-grob?"))))
2399                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2400                 if (scm_is_null (l) || scm_is_null (scm_cdr (l))) {
2401                         parser->parser_error (@1, _ ("bad grob property path"));
2402                         l = SCM_UNDEFINED;
2403                 }
2404                 $$ = l;
2405         }
2406         ;
2407
2408 // If defined, at least three members
2409 grob_prop_path:
2410         grob_prop_spec
2411         {
2412                 if (!SCM_UNBNDP ($1) && scm_is_null (scm_cddr ($1)))
2413                 {
2414                         parser->parser_error (@1, _ ("bad grob property path"));
2415                         $$ = SCM_UNDEFINED;
2416                 }
2417         }
2418         | grob_prop_spec property_path
2419         {
2420                 if (!SCM_UNBNDP ($1)) {
2421                         $$ = scm_append_x (scm_list_2 ($1, $2));
2422                         if (scm_is_null (scm_cddr ($$))) {
2423                                 parser->parser_error (@$, _ ("bad grob property path"));
2424                                 $$ = SCM_UNDEFINED;
2425                         }
2426                 }
2427
2428         }
2429         ;
2430
2431 // Exactly two elements or undefined
2432 context_prop_spec:
2433         symbol_list_rev
2434         {
2435                 SCM l = scm_reverse_x ($1, SCM_EOL);
2436                 switch (scm_ilength (l)) {
2437                 case 1:
2438                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2439                 case 2:
2440                         break;
2441                 default:
2442                         parser->parser_error (@1, _ ("bad context property path"));
2443                         l = SCM_UNDEFINED;
2444                 }
2445                 $$ = l;
2446         }
2447         ;
2448
2449 simple_music_property_def:
2450         OVERRIDE grob_prop_path '=' scalar {
2451                 if (SCM_UNBNDP ($2))
2452                         $$ = SCM_UNDEFINED;
2453                 else {
2454                         $$ = scm_list_5 (scm_car ($2),
2455                                          ly_symbol2scm ("OverrideProperty"),
2456                                          scm_cadr ($2),
2457                                          $4,
2458                                          scm_cddr ($2));
2459                 }
2460         }
2461         | REVERT simple_revert_context revert_arg {
2462                 $$ = scm_list_4 ($2,
2463                                  ly_symbol2scm ("RevertProperty"),
2464                                  scm_car ($3),
2465                                  scm_cdr ($3));
2466         }
2467         | SET context_prop_spec '=' scalar {
2468                 if (SCM_UNBNDP ($2))
2469                         $$ = SCM_UNDEFINED;
2470                 else
2471                         $$ = scm_list_4 (scm_car ($2),
2472                                          ly_symbol2scm ("PropertySet"),
2473                                          scm_cadr ($2),
2474                                          $4);
2475         }
2476         | UNSET context_prop_spec {
2477                 if (SCM_UNBNDP ($2))
2478                         $$ = SCM_UNDEFINED;
2479                 else
2480                         $$ = scm_list_3 (scm_car ($2),
2481                                          ly_symbol2scm ("PropertyUnset"),
2482                                          scm_cadr ($2));
2483         }
2484         ;
2485
2486
2487 // This is all quite awkward for the sake of substantial backward
2488 // compatibility while at the same time allowing a more "natural" form
2489 // of specification not separating grob specification from grob
2490 // property path.  The purpose of this definition of
2491 // simple_revert_context is to allow the symbol list which specifies
2492 // grob and property to revert to be optionally be split into two
2493 // parts after the grob (which may be preceded by a context
2494 // specification, a case which we distinguish by checking whether the
2495 // first symbol is a valid grob symbol instead).
2496 //
2497 // See revert_arg above for the main work horse of this arrangement.
2498 // simple_revert_context just caters for the context and delegates the
2499 // rest of the job to revert_arg.
2500
2501 simple_revert_context:
2502         symbol_list_part
2503         {
2504                 $1 = scm_reverse_x ($1, SCM_EOL);
2505                 if (scm_is_null ($1)
2506                     || to_boolean
2507                     (scm_object_property (scm_car ($1),
2508                                           ly_symbol2scm ("is-grob?")))) {
2509                         $$ = ly_symbol2scm ("Bottom");
2510                         parser->lexer_->push_extra_token (@1, SCM_IDENTIFIER, $1);
2511                 } else {
2512                         $$ = scm_car ($1);
2513                         parser->lexer_->push_extra_token (@1, SCM_IDENTIFIER,
2514                                                           scm_cdr ($1));
2515                 }
2516         }
2517         ;
2518
2519 music_property_def:
2520         simple_music_property_def {
2521                 if (SCM_UNBNDP ($1))
2522                         $$ = MAKE_SYNTAX ("void-music", @1);
2523                 else
2524                         $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons2 (parser->self_scm (), @$.smobbed_copy (), $1));
2525         }
2526         ;
2527
2528 string:
2529         STRING {
2530                 $$ = $1;
2531         }
2532         | full_markup
2533         ;
2534
2535 simple_string: STRING {
2536                 $$ = $1;
2537         }
2538         | embedded_scm_bare
2539         {
2540                 if (scm_is_string ($1)) {
2541                         $$ = $1;
2542                 } else {
2543                         parser->parser_error (@1, (_ ("simple string expected")));
2544                         $$ = scm_string (SCM_EOL);
2545                 }
2546         }
2547         ;
2548
2549 symbol:
2550         STRING {
2551                 $$ = scm_string_to_symbol ($1);
2552         }
2553         | embedded_scm_bare
2554         {
2555                 // This is a bit of overkill but makes the same
2556                 // routine responsible for all symbol interpretations.
2557                 $$ = try_string_variants (ly_lily_module_constant ("symbol?"),
2558                                           $1);
2559                 if (SCM_UNBNDP ($$))
2560                 {
2561                         parser->parser_error (@1, (_ ("symbol expected")));
2562                         // Generate a unique symbol in case it is used
2563                         // for an assignment or similar
2564                         $$ = scm_make_symbol (ly_string2scm ("undefined"));
2565                 }
2566         }
2567         ;
2568
2569 scalar:
2570         embedded_scm_arg
2571         | pitch_or_music
2572         | SCM_IDENTIFIER
2573         | bare_number
2574         // The following is a rather defensive variant of admitting
2575         // negative numbers: the grammar would permit number_factor or
2576         // even number_expression.  However, function arguments allow
2577         // only this simple kind of negative number, so to have things
2578         // like \tweak and \override behave reasonably similar, it
2579         // makes sense to rule out things like -- which are rather an
2580         // accent in function argument contexts.
2581         | '-' bare_number
2582         {
2583                 $$ = scm_difference ($2, SCM_UNDEFINED);
2584         }
2585         | string
2586         ;
2587
2588 event_chord:
2589         simple_element post_events {
2590                 // Let the rhythmic music iterator sort this mess out.
2591                 if (scm_is_pair ($2)) {
2592                         Music::unsmob ($$)->set_property ("articulations",
2593                                                          scm_reverse_x ($2, SCM_EOL));
2594                 }
2595         } %prec ':'
2596         | CHORD_REPETITION optional_notemode_duration post_events {
2597                 Input i;
2598                 i.set_location (@1, @3);
2599                 $$ = MAKE_SYNTAX ("repetition-chord", i,
2600                                   $2, scm_reverse_x ($3, SCM_EOL));
2601         } %prec ':'
2602         | MULTI_MEASURE_REST optional_notemode_duration post_events {
2603                 Input i;
2604                 i.set_location (@1, @3);
2605                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
2606                                   scm_reverse_x ($3, SCM_EOL));
2607         } %prec ':'
2608         | tempo_event
2609         | note_chord_element
2610         ;
2611
2612
2613 note_chord_element:
2614         chord_body optional_notemode_duration post_events
2615         {
2616                 Music *m = Music::unsmob ($1);
2617                 SCM dur = Duration::unsmob ($2)->smobbed_copy ();
2618                 SCM es = m->get_property ("elements");
2619                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
2620
2621                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
2622                   Music::unsmob (scm_car (s))->set_property ("duration", dur);
2623                 es = ly_append2 (es, postevs);
2624
2625                 m-> set_property ("elements", es);
2626                 m->set_spot (@$);
2627                 $$ = m->self_scm ();
2628         } %prec ':'
2629         ;
2630
2631 chord_body:
2632         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
2633         {
2634                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
2635         }
2636         | FIGURE_OPEN figure_list FIGURE_CLOSE
2637         {
2638                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
2639         }
2640         ;
2641
2642 chord_body_elements:
2643         /* empty */             { $$ = SCM_EOL; }
2644         | chord_body_elements chord_body_element {
2645                 if (!SCM_UNBNDP ($2))
2646                         $$ = scm_cons ($2, $1);
2647         }
2648         ;
2649
2650 chord_body_element:
2651         pitch_or_tonic_pitch exclamations questions octave_check post_events
2652         {
2653                 bool q = to_boolean ($3);
2654                 bool ex = to_boolean ($2);
2655                 SCM check = $4;
2656                 SCM post = $5;
2657
2658                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2659                 n->set_property ("pitch", $1);
2660                 if (q)
2661                         n->set_property ("cautionary", SCM_BOOL_T);
2662                 if (ex || q)
2663                         n->set_property ("force-accidental", SCM_BOOL_T);
2664
2665                 if (scm_is_pair (post)) {
2666                         SCM arts = scm_reverse_x (post, SCM_EOL);
2667                         n->set_property ("articulations", arts);
2668                 }
2669                 if (scm_is_number (check))
2670                 {
2671                         int q = scm_to_int (check);
2672                         n->set_property ("absolute-octave", scm_from_int (q-1));
2673                 }
2674
2675                 $$ = n->unprotect ();
2676         }
2677         | DRUM_PITCH post_events {
2678                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2679                 n->set_property ("drum-type", $1);
2680
2681                 if (scm_is_pair ($2)) {
2682                         SCM arts = scm_reverse_x ($2, SCM_EOL);
2683                         n->set_property ("articulations", arts);
2684                 }
2685                 $$ = n->unprotect ();
2686         }
2687         | music_function_chord_body
2688         {
2689                 Music *m = Music::unsmob ($1);
2690
2691                 while (m && m->is_mus_type ("music-wrapper-music")) {
2692                         $$ = m->get_property ("element");
2693                         m = Music::unsmob ($$);
2694                 }
2695
2696                 if (!(m && m->is_mus_type ("rhythmic-event"))) {
2697                         parser->parser_error (@$, _ ("not a rhythmic event"));
2698                         $$ = SCM_UNDEFINED;
2699                 }
2700         }
2701         ;
2702
2703 music_function_chord_body:
2704         music_function_call
2705         | MUSIC_IDENTIFIER
2706         | embedded_scm
2707         ;
2708
2709 event_function_event:
2710         EVENT_FUNCTION function_arglist {
2711                 $$ = MAKE_SYNTAX ("music-function", @$,
2712                                          $1, $2);
2713         }
2714         ;
2715
2716 post_events:
2717         /* empty */ {
2718                 $$ = SCM_EOL;
2719         }
2720         | post_events post_event {
2721                 $$ = $1;
2722                 if (Music *m = Music::unsmob ($2))
2723                 {
2724                         if (m->is_mus_type ("post-event-wrapper"))
2725                         {
2726                                 for (SCM p = m->get_property ("elements");
2727                                      scm_is_pair (p);
2728                                      p = scm_cdr (p))
2729                                 {
2730                                         $$ = scm_cons (scm_car (p), $$);
2731                                 }
2732                         } else {
2733                                 m->set_spot (@2);
2734                                 $$ = scm_cons ($2, $$);
2735                         }
2736                 }
2737         }
2738         ;
2739
2740 post_event_nofinger:
2741         direction_less_event {
2742                 $$ = $1;
2743         }
2744         | script_dir music_function_call {
2745                 $$ = $2;
2746                 if (!Music::unsmob ($2)->is_mus_type ("post-event")) {
2747                         parser->parser_error (@2, _ ("post-event expected"));
2748                         $$ = SCM_UNSPECIFIED;
2749                 } else if (!SCM_UNBNDP ($1))
2750                 {
2751                         Music::unsmob ($$)->set_property ("direction", $1);
2752                 }
2753         }
2754         | HYPHEN {
2755                 if (!parser->lexer_->is_lyric_state ())
2756                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2757                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
2758         }
2759         | EXTENDER {
2760                 if (!parser->lexer_->is_lyric_state ())
2761                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2762                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
2763         }
2764         | script_dir direction_reqd_event {
2765                 if (!SCM_UNBNDP ($1))
2766                 {
2767                         Music *m = Music::unsmob ($2);
2768                         m->set_property ("direction", $1);
2769                 }
2770                 $$ = $2;
2771         }
2772         | script_dir direction_less_event {
2773                 if (!SCM_UNBNDP ($1))
2774                 {
2775                         Music *m = Music::unsmob ($2);
2776                         m->set_property ("direction", $1);
2777                 }
2778                 $$ = $2;
2779         }
2780         | '^' fingering
2781         {
2782                 $$ = $2;
2783                 Music::unsmob ($$)->set_property ("direction", scm_from_int (UP));
2784         }
2785         | '_' fingering
2786         {
2787                 $$ = $2;
2788                 Music::unsmob ($$)->set_property ("direction", scm_from_int (DOWN));
2789         }
2790         ;
2791
2792 post_event:
2793         post_event_nofinger
2794         | '-' fingering {
2795                 $$ = $2;
2796         }
2797         ;
2798
2799 string_number_event:
2800         E_UNSIGNED {
2801                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
2802                 s->set_property ("string-number", $1);
2803                 $$ = s->unprotect ();
2804         }
2805         ;
2806
2807 direction_less_event:
2808         string_number_event
2809         | EVENT_IDENTIFIER      {
2810                 $$ = $1;
2811         }
2812         | tremolo_type  {
2813                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
2814                a->set_property ("tremolo-type", $1);
2815                $$ = a->unprotect ();
2816         }
2817         | event_function_event
2818         ;
2819
2820 direction_reqd_event:
2821         gen_text_def {
2822                 $$ = $1;
2823         }
2824         | script_abbreviation {
2825                 SCM s = parser->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
2826                 if (scm_is_string (s)) {
2827                         Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
2828                         a->set_property ("articulation-type", s);
2829                         $$ = a->unprotect ();
2830                 } else {
2831                         Music *original = Music::unsmob (s);
2832                         if (original && original->is_mus_type ("post-event")) {
2833                                 Music *a = original->clone ();
2834                                 a->set_spot (parser->lexer_->override_input (@$));
2835                                 $$ = a->unprotect ();
2836                         } else {
2837                                 parser->parser_error (@1, _ ("expecting string or post-event as script definition"));
2838                                 $$ = MY_MAKE_MUSIC ("PostEvents", @$)->unprotect ();
2839                         }
2840                 }
2841         }
2842         ;
2843
2844 octave_check:
2845         /**/ { $$ = SCM_EOL; }
2846         | '=' quotes { $$ = $2; }
2847         ;
2848
2849 quotes:
2850         /* empty */
2851         {
2852                 $$ = SCM_INUM0;
2853         }
2854         | sub_quotes
2855         | sup_quotes
2856         ;
2857
2858 sup_quotes:
2859         '\'' {
2860                 $$ = scm_from_int (1);
2861         }
2862         | sup_quotes '\'' {
2863                 $$ = scm_oneplus ($1);
2864         }
2865         ;
2866
2867 sub_quotes:
2868         ',' {
2869                 $$ = scm_from_int (-1);
2870         }
2871         | sub_quotes ',' {
2872                 $$ = scm_oneminus ($1);
2873         }
2874         ;
2875
2876 steno_pitch:
2877         NOTENAME_PITCH quotes {
2878                 if (!scm_is_eq (SCM_INUM0, $2))
2879                 {
2880                         Pitch p = *Pitch::unsmob ($1);
2881                         p = p.transposed (Pitch (scm_to_int ($2), 0));
2882                         $$ = p.smobbed_copy ();
2883                 }
2884         }
2885         ;
2886
2887 /*
2888 ugh. duplication
2889 */
2890
2891 steno_tonic_pitch:
2892         TONICNAME_PITCH quotes {
2893                 if (!scm_is_eq (SCM_INUM0, $2))
2894                 {
2895                         Pitch p = *Pitch::unsmob ($1);
2896                         p = p.transposed (Pitch (scm_to_int ($2), 0));
2897                         $$ = p.smobbed_copy ();
2898                 }
2899         }
2900         ;
2901
2902 pitch:
2903         steno_pitch
2904         | PITCH_IDENTIFIER quotes {
2905                 if (!scm_is_eq (SCM_INUM0, $2))
2906                 {
2907                         Pitch p = *Pitch::unsmob ($1);
2908                         p = p.transposed (Pitch (scm_to_int ($2), 0));
2909                         $$ = p.smobbed_copy ();
2910                 }
2911         }
2912         ;
2913
2914 pitch_or_tonic_pitch:
2915         pitch
2916         | steno_tonic_pitch
2917         ;
2918
2919 gen_text_def:
2920         full_markup {
2921                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2922                 t->set_property ("text", $1);
2923                 $$ = t->unprotect ();
2924         }
2925         | STRING {
2926                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2927                 t->set_property ("text",
2928                         make_simple_markup ($1));
2929                 $$ = t->unprotect ();
2930         }
2931         | embedded_scm
2932         {
2933                 Music *m = Music::unsmob ($1);
2934                 if (m && m->is_mus_type ("post-event"))
2935                         $$ = $1;
2936                 else if (Text_interface::is_markup ($1)) {
2937                         Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2938                         t->set_property ("text", $1);
2939                         $$ = t->unprotect ();
2940                 } else
2941                         parser->parser_error (@1, _ ("not an articulation"));
2942         }
2943         ;
2944
2945 fingering:
2946         UNSIGNED {
2947                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
2948                 t->set_property ("digit", $1);
2949                 $$ = t->unprotect ();
2950         }
2951         ;
2952
2953 script_abbreviation:
2954         '^'             {
2955                 $$ = scm_from_locale_string ("Hat");
2956         }
2957         | '+'           {
2958                 $$ = scm_from_locale_string ("Plus");
2959         }
2960         | '-'           {
2961                 $$ = scm_from_locale_string ("Dash");
2962         }
2963         | '!'           {
2964                 $$ = scm_from_locale_string ("Bang");
2965         }
2966         | ANGLE_CLOSE   {
2967                 $$ = scm_from_locale_string ("Larger");
2968         }
2969         | '.'           {
2970                 $$ = scm_from_locale_string ("Dot");
2971         }
2972         | '_' {
2973                 $$ = scm_from_locale_string ("Underscore");
2974         }
2975         ;
2976
2977 script_dir:
2978         '_'     { $$ = scm_from_int (DOWN); }
2979         | '^'   { $$ = scm_from_int (UP); }
2980         | '-'   { $$ = SCM_UNDEFINED; }
2981         ;
2982
2983 duration_length:
2984         multiplied_duration {
2985                 $$ = $1;
2986         }
2987         ;
2988
2989 maybe_notemode_duration:
2990         {
2991                 $$ = SCM_UNDEFINED;
2992         } %prec ':'
2993         | multiplied_duration   {
2994                 $$ = $1;
2995                 parser->default_duration_ = *Duration::unsmob ($$);
2996         }
2997 ;
2998
2999
3000 optional_notemode_duration:
3001         maybe_notemode_duration
3002         {
3003                 if (SCM_UNBNDP ($$))
3004                         $$ = parser->default_duration_.smobbed_copy ();
3005         }
3006         ;
3007
3008 steno_duration:
3009         UNSIGNED dots           {
3010                 $$ = make_duration ($1, scm_to_int ($2));
3011                 if (SCM_UNBNDP ($$))
3012                 {
3013                         parser->parser_error (@1, _ ("not a duration"));
3014                         $$ = Duration ().smobbed_copy ();
3015                 }
3016         }
3017         | DURATION_IDENTIFIER dots      {
3018                 Duration *d = Duration::unsmob ($1);
3019                 Duration k (d->duration_log (),
3020                             d->dot_count () + scm_to_int ($2));
3021                 k = k.compressed (d->factor ());
3022                 scm_remember_upto_here_1 ($1);
3023                 $$ = k.smobbed_copy ();
3024         }
3025         ;
3026
3027 multiplied_duration:
3028         steno_duration {
3029                 $$ = $1;
3030         }
3031         | multiplied_duration '*' UNSIGNED {
3032                 $$ = Duration::unsmob ($$)->compressed (scm_to_int ($3)).smobbed_copy ();
3033         }
3034         | multiplied_duration '*' FRACTION {
3035                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
3036
3037                 $$ = Duration::unsmob ($$)->compressed (m).smobbed_copy ();
3038         }
3039         ;
3040
3041 dots:
3042         /* empty */     {
3043                 $$ = SCM_INUM0;
3044         }
3045         | dots '.' {
3046                 $$ = scm_oneplus ($1);
3047         }
3048         ;
3049
3050 tremolo_type:
3051         ':'     {
3052                 $$ = scm_from_int (parser->default_tremolo_type_);
3053         }
3054         | ':' UNSIGNED {
3055                 if (SCM_UNBNDP (make_duration ($2))) {
3056                         parser->parser_error (@2, _ ("not a duration"));
3057                         $$ = scm_from_int (parser->default_tremolo_type_);
3058                 } else {
3059                         $$ = $2;
3060                         parser->default_tremolo_type_ = scm_to_int ($2);
3061                 }
3062         }
3063         ;
3064
3065 bass_number:
3066         UNSIGNED { $$ = $1; }
3067         | STRING { $$ = $1; }
3068         | full_markup { $$ = $1; }
3069         | embedded_scm_bare
3070         {
3071                 // as an integer, it needs to be non-negative, and otherwise
3072                 // it needs to be suitable as a markup.
3073                 if (scm_is_integer ($1)
3074                     ? scm_is_true (scm_negative_p ($1))
3075                     : !Text_interface::is_markup ($1))
3076                 {
3077                         parser->parser_error (@1, _ ("bass number expected"));
3078                         $$ = SCM_INUM0;
3079                 }
3080         }
3081         ;
3082
3083 figured_bass_alteration:
3084         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
3085         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
3086         | '!'   { $$ = scm_from_int (0); }
3087         ;
3088
3089 bass_figure:
3090         FIGURE_SPACE {
3091                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
3092                 $$ = bfr->unprotect ();
3093         }
3094         | bass_number  {
3095                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
3096                 $$ = bfr->self_scm ();
3097
3098                 if (scm_is_number ($1))
3099                         bfr->set_property ("figure", $1);
3100                 else if (Text_interface::is_markup ($1))
3101                         bfr->set_property ("text", $1);
3102
3103                 bfr->unprotect ();
3104         }
3105         | bass_figure ']' {
3106                 $$ = $1;
3107                 Music::unsmob ($1)->set_property ("bracket-stop", SCM_BOOL_T);
3108         }
3109         | bass_figure figured_bass_alteration {
3110                 Music *m = Music::unsmob ($1);
3111                 if (scm_to_double ($2)) {
3112                         SCM salter = m->get_property ("alteration");
3113                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
3114                         m->set_property ("alteration",
3115                                          scm_sum (alter, $2));
3116                 } else {
3117                         m->set_property ("alteration", scm_from_int (0));
3118                 }
3119         }
3120         | bass_figure figured_bass_modification  {
3121                 Music *m = Music::unsmob ($1);
3122                 m->set_property ($2, SCM_BOOL_T);
3123         }
3124         ;
3125
3126
3127 figured_bass_modification:
3128         E_PLUS          {
3129                 $$ = ly_symbol2scm ("augmented");
3130         }
3131         | E_EXCLAMATION {
3132                 $$ = ly_symbol2scm ("no-continuation");
3133         }
3134         | '/'           {
3135                 $$ = ly_symbol2scm ("diminished");
3136         }
3137         | E_BACKSLASH {
3138                 $$ = ly_symbol2scm ("augmented-slash");
3139         }
3140         ;
3141
3142 br_bass_figure:
3143         bass_figure {
3144                 $$ = $1;
3145         }
3146         | '[' bass_figure {
3147                 $$ = $2;
3148                 Music::unsmob ($$)->set_property ("bracket-start", SCM_BOOL_T);
3149         }
3150         ;
3151
3152 figure_list:
3153         /**/            {
3154                 $$ = SCM_EOL;
3155         }
3156         | figure_list br_bass_figure {
3157                 $$ = scm_cons ($2, $1);
3158         }
3159         ;
3160
3161 optional_rest:
3162         /**/   { $$ = SCM_BOOL_F; }
3163         | REST { $$ = SCM_BOOL_T; }
3164         ;
3165
3166 pitch_or_music:
3167         pitch exclamations questions octave_check maybe_notemode_duration optional_rest post_events {
3168                 if (!parser->lexer_->is_note_state ())
3169                         parser->parser_error (@1, _ ("have to be in Note mode for notes"));
3170                 if (!SCM_UNBNDP ($2)
3171                     || !SCM_UNBNDP ($3)
3172                     || scm_is_number ($4)
3173                     || !SCM_UNBNDP ($5)
3174                     || scm_is_true ($6)
3175                     || scm_is_pair ($7))
3176                 {
3177                         Music *n = 0;
3178                         if (scm_is_true ($6))
3179                                 n = MY_MAKE_MUSIC ("RestEvent", @$);
3180                         else
3181                                 n = MY_MAKE_MUSIC ("NoteEvent", @$);
3182
3183                         n->set_property ("pitch", $1);
3184                         if (SCM_UNBNDP ($5))
3185                                 n->set_property ("duration",
3186                                                  parser->default_duration_.smobbed_copy ());
3187                         else
3188                                 n->set_property ("duration", $5);
3189
3190                         if (scm_is_number ($4))
3191                         {
3192                                 int q = scm_to_int ($4);
3193                                 n->set_property ("absolute-octave", scm_from_int (q-1));
3194                         }
3195
3196                         if (to_boolean ($3))
3197                                 n->set_property ("cautionary", SCM_BOOL_T);
3198                         if (to_boolean ($2) || to_boolean ($3))
3199                                 n->set_property ("force-accidental", SCM_BOOL_T);
3200                         if (scm_is_pair ($7))
3201                                 n->set_property ("articulations",
3202                                                  scm_reverse_x ($7, SCM_EOL));
3203                         $$ = n->unprotect ();
3204                 }
3205         } %prec ':'
3206         | new_chord post_events {
3207                 if (!parser->lexer_->is_chord_state ())
3208                         parser->parser_error (@1, _ ("have to be in Chord mode for chords"));
3209                 if (scm_is_pair ($2)) {
3210                         if (Pitch::unsmob ($1))
3211                                 $1 = make_chord_elements (@1,
3212                                                           $1,
3213                                                           parser->default_duration_.smobbed_copy (),
3214                                                           SCM_EOL);
3215
3216                         SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
3217
3218                         $$ = MAKE_SYNTAX ("event-chord", @1, elts);
3219                 } else if (!Pitch::unsmob ($1))
3220                         $$ = MAKE_SYNTAX ("event-chord", @1, $1);
3221                 // A mere pitch drops through.
3222         } %prec ':'
3223         ;
3224
3225 simple_element:
3226         DRUM_PITCH optional_notemode_duration {
3227                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
3228                 n->set_property ("duration", $2);
3229                 n->set_property ("drum-type", $1);
3230
3231                 $$ = n->unprotect ();
3232         }
3233         | RESTNAME optional_notemode_duration           {
3234                 Music *ev = 0;
3235                 if (ly_scm2string ($1) == "s") {
3236                         /* Space */
3237                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
3238                   }
3239                 else {
3240                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
3241
3242                     }
3243                 ev->set_property ("duration", $2);
3244                 $$ = ev->unprotect ();
3245         }
3246         ;
3247
3248 lyric_element:
3249         full_markup {
3250                 if (!parser->lexer_->is_lyric_state ())
3251                         parser->parser_error (@1, _ ("markup outside of text script or \\lyricmode"));
3252                 $$ = $1;
3253         }
3254         | STRING {
3255                 if (!parser->lexer_->is_lyric_state ())
3256                         parser->parser_error (@1, _ ("unrecognized string, not in text script or \\lyricmode"));
3257                 $$ = $1;
3258         }
3259         | LYRIC_ELEMENT
3260         ;
3261
3262 lyric_element_music:
3263         lyric_element optional_notemode_duration post_events {
3264                 $$ = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
3265                 if (scm_is_pair ($3))
3266                         Music::unsmob ($$)->set_property
3267                                 ("articulations", scm_reverse_x ($3, SCM_EOL));
3268         } %prec ':'
3269         ;
3270
3271 // Can return a single pitch rather than a list.
3272 new_chord:
3273         steno_tonic_pitch maybe_notemode_duration   {
3274                 if (SCM_UNBNDP ($2))
3275                         $$ = $1;
3276                 else
3277                         $$ = make_chord_elements (@$, $1, $2, SCM_EOL);
3278         }
3279         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
3280                 SCM its = scm_reverse_x ($4, SCM_EOL);
3281                 $$ = make_chord_elements (@$, $1, $2, scm_cons ($3, its));
3282         } %prec ':'
3283         ;
3284
3285 chord_items:
3286         /**/ {
3287                 $$ = SCM_EOL;
3288         }
3289         | chord_items chord_item {
3290                 $$ = scm_cons ($2, $$);
3291         }
3292         ;
3293
3294 chord_separator:
3295         CHORD_COLON {
3296                 $$ = ly_symbol2scm ("chord-colon");
3297         }
3298         | CHORD_CARET {
3299                 $$ = ly_symbol2scm ("chord-caret");
3300         }
3301         | CHORD_SLASH steno_tonic_pitch {
3302                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
3303         }
3304         | CHORD_BASS steno_tonic_pitch {
3305                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
3306         }
3307         ;
3308
3309 chord_item:
3310         chord_separator {
3311                 $$ = $1;
3312         }
3313         | step_numbers {
3314                 $$ = scm_reverse_x ($1, SCM_EOL);
3315         }
3316         | CHORD_MODIFIER  {
3317                 $$ = $1;
3318         }
3319         ;
3320
3321 step_numbers:
3322         step_number { $$ = scm_cons ($1, SCM_EOL); }
3323         | step_numbers '.' step_number {
3324                 $$ = scm_cons ($3, $$);
3325         }
3326         ;
3327
3328 step_number:
3329         UNSIGNED {
3330                 $$ = make_chord_step ($1, 0);
3331         }
3332         | UNSIGNED '+' {
3333                 $$ = make_chord_step ($1, SHARP_ALTERATION);
3334         }
3335         | UNSIGNED CHORD_MINUS {
3336                 $$ = make_chord_step ($1, FLAT_ALTERATION);
3337         }
3338         ;
3339
3340 tempo_range:
3341         unsigned_number {
3342                 $$ = $1;
3343         } %prec ':'
3344         | unsigned_number '-' unsigned_number {
3345                 $$ = scm_cons ($1, $3);
3346         }
3347         ;
3348
3349 /*
3350         UTILITIES
3351
3352 TODO: should deprecate in favor of Scheme?
3353
3354  */
3355 number_expression:
3356         number_expression '+' number_term {
3357                 $$ = scm_sum ($1, $3);
3358         }
3359         | number_expression '-' number_term {
3360                 $$ = scm_difference ($1, $3);
3361         }
3362         | number_term
3363         ;
3364
3365 number_term:
3366         number_factor {
3367                 $$ = $1;
3368         }
3369         | number_factor '*' number_factor {
3370                 $$ = scm_product ($1, $3);
3371         }
3372         | number_factor '/' number_factor {
3373                 $$ = scm_divide ($1, $3);
3374         }
3375         ;
3376
3377 number_factor:
3378         '-'  number_factor { /* %prec UNARY_MINUS */
3379                 $$ = scm_difference ($2, SCM_UNDEFINED);
3380         }
3381         | bare_number
3382         ;
3383
3384 bare_number_common:
3385         REAL
3386         | NUMBER_IDENTIFIER
3387         | REAL NUMBER_IDENTIFIER
3388         {
3389                 $$ = scm_product ($1, $2);
3390         }
3391         ;
3392
3393 bare_number:
3394         bare_number_common
3395         | UNSIGNED
3396         | UNSIGNED NUMBER_IDENTIFIER    {
3397                 $$ = scm_product ($1, $2);
3398         }
3399         ;
3400
3401 unsigned_number:
3402         UNSIGNED
3403         | NUMBER_IDENTIFIER
3404         {
3405                 if (!scm_is_integer ($1)
3406                     || scm_is_true (scm_negative_p ($1)))
3407                 {
3408                         parser->parser_error (@1, _("not an unsigned integer"));
3409                         $$ = SCM_INUM0;
3410                 }
3411         }
3412         | embedded_scm
3413         {
3414                 if (!scm_is_integer ($1)
3415                     || scm_is_true (scm_negative_p ($1)))
3416                 {
3417                         parser->parser_error (@1, _("not an unsigned integer"));
3418                         $$ = SCM_INUM0;
3419                 }
3420         }
3421         ;
3422
3423 exclamations:
3424                 { $$ = SCM_UNDEFINED; }
3425         | exclamations '!'
3426         {
3427                 if (SCM_UNBNDP ($1))
3428                         $$ = SCM_BOOL_T;
3429                 else
3430                         $$ = scm_not ($1);
3431         }
3432         ;
3433
3434 questions:
3435 // This precedence rule is rather weird.  It triggers when '!' is
3436 // encountered after a pitch, and is used for deciding whether to save
3437 // this instead for a figure modification.  This should not actually
3438 // occur in practice as pitches and figures are generated in different
3439 // modes.  Using a greedy (%right) precedence makes sure that we don't
3440 // get stuck in a wrong interpretation.
3441         { $$ = SCM_UNDEFINED; } %prec ':'
3442         | questions '?'
3443         {
3444                 if (SCM_UNBNDP ($1))
3445                         $$ = SCM_BOOL_T;
3446                 else
3447                         $$ = scm_not ($1);
3448         }
3449         ;
3450
3451 full_markup_list:
3452         MARKUPLIST
3453                 { parser->lexer_->push_markup_state (); }
3454         markup_list {
3455                 $$ = $3;
3456                 parser->lexer_->pop_state ();
3457         }
3458         ;
3459
3460 full_markup:
3461         MARKUP
3462                 { parser->lexer_->push_markup_state (); }
3463         markup_top {
3464                 $$ = $3;
3465                 parser->lexer_->pop_state ();
3466         }
3467         ;
3468
3469 markup_top:
3470         markup_list {
3471                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
3472         }
3473         | markup_head_1_list simple_markup
3474         {
3475                 $$ = scm_car (MAKE_SYNTAX ("composed-markup-list",
3476                                            @2, $1, scm_list_1 ($2)));
3477         }
3478         | simple_markup {
3479                 $$ = $1;
3480         }
3481         ;
3482
3483 markup_scm:
3484         embedded_scm_bare
3485         {
3486                 if (Text_interface::is_markup ($1))
3487                         MYBACKUP (MARKUP_IDENTIFIER, $1, @1);
3488                 else if (Text_interface::is_markup_list ($1))
3489                         MYBACKUP (MARKUPLIST_IDENTIFIER, $1, @1);
3490                 else {
3491                         parser->parser_error (@1, _ ("not a markup"));
3492                         MYBACKUP (MARKUP_IDENTIFIER, scm_string (SCM_EOL), @1);
3493                 }
3494         } BACKUP
3495         ;
3496
3497
3498 markup_list:
3499         markup_composed_list {
3500                 $$ = $1;
3501         }
3502         | markup_uncomposed_list
3503         ;
3504
3505 markup_uncomposed_list:
3506         markup_braced_list {
3507                 $$ = $1;
3508         }
3509         | markup_command_list {
3510                 $$ = scm_list_1 ($1);
3511         }
3512         | markup_scm MARKUPLIST_IDENTIFIER
3513         {
3514                 $$ = $2;
3515         }
3516         | SCORELINES {
3517                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
3518                 parser->lexer_->push_note_state (nn);
3519         } '{' score_body '}' {
3520                 Score *sc = Score::unsmob ($4);
3521                 sc->origin ()->set_spot (@$);
3522                 if (sc->defs_.empty ()) {
3523                         Output_def *od = get_layout (parser);
3524                         sc->add_output_def (od);
3525                         od->unprotect ();
3526                 }
3527                 $$ = scm_list_1 (scm_list_2 (ly_lily_module_constant ("score-lines-markup-list"), $4));
3528                 parser->lexer_->pop_state ();
3529         }
3530         ;
3531
3532 markup_composed_list:
3533         markup_head_1_list markup_uncomposed_list {
3534                 $$ = MAKE_SYNTAX ("composed-markup-list",
3535                                   @2, $1, $2);
3536         }
3537         ;
3538
3539 markup_braced_list:
3540         '{' markup_braced_list_body '}' {
3541                 $$ = scm_reverse_x ($2, SCM_EOL);
3542         }
3543         ;
3544
3545 markup_braced_list_body:
3546         /* empty */     {  $$ = SCM_EOL; }
3547         | markup_braced_list_body markup {
3548                 $$ = scm_cons ($2, $1);
3549         }
3550         | markup_braced_list_body markup_list {
3551                 $$ = scm_reverse_x ($2, $1);
3552         }
3553         ;
3554
3555 markup_command_list:
3556         MARKUP_LIST_FUNCTION markup_command_list_arguments {
3557           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
3558         }
3559         ;
3560
3561 markup_command_basic_arguments:
3562         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
3563           $$ = scm_cons ($3, $2);
3564         }
3565         | EXPECT_SCM markup_command_list_arguments embedded_scm {
3566           $$ = check_scheme_arg (parser, @3, $3, $2, $1);
3567         }
3568         | EXPECT_NO_MORE_ARGS {
3569           $$ = SCM_EOL;
3570         }
3571         ;
3572
3573 markup_command_list_arguments:
3574         markup_command_basic_arguments { $$ = $1; }
3575         | EXPECT_MARKUP markup_command_list_arguments markup {
3576           $$ = scm_cons ($3, $2);
3577         }
3578         ;
3579
3580 markup_head_1_item:
3581         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
3582           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
3583         }
3584         ;
3585
3586 markup_head_1_list:
3587         markup_head_1_item      {
3588                 $$ = scm_list_1 ($1);
3589         }
3590         | markup_head_1_list markup_head_1_item {
3591                 $$ = scm_cons ($2, $1);
3592         }
3593         ;
3594
3595 simple_markup:
3596         STRING {
3597                 $$ = make_simple_markup ($1);
3598         }
3599         | SCORE {
3600                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
3601                 parser->lexer_->push_note_state (nn);
3602         } '{' score_body '}' {
3603                 Score *sc = Score::unsmob ($4);
3604                 sc->origin ()->set_spot (@$);
3605                 if (sc->defs_.empty ()) {
3606                         Output_def *od = get_layout (parser);
3607                         sc->add_output_def (od);
3608                         od->unprotect ();
3609                 }
3610                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), $4);
3611                 parser->lexer_->pop_state ();
3612         }
3613         | MARKUP_FUNCTION markup_command_basic_arguments {
3614                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
3615         }
3616         | markup_scm MARKUP_IDENTIFIER
3617         {
3618                 $$ = $2;
3619         }
3620         ;
3621
3622 markup:
3623         markup_head_1_list simple_markup
3624         {
3625                 $$ = scm_car (MAKE_SYNTAX ("composed-markup-list",
3626                                            @2, $1, scm_list_1 ($2)));
3627         }
3628         | simple_markup {
3629                 $$ = $1;
3630         }
3631         ;
3632
3633 %%
3634
3635 void
3636 Lily_parser::set_yydebug (bool x)
3637 {
3638         yydebug = x;
3639 }
3640
3641 SCM
3642 Lily_parser::do_yyparse ()
3643 {
3644         SCM retval = SCM_UNDEFINED;
3645         yyparse (this, &retval);
3646         return retval;
3647 }
3648
3649
3650
3651
3652
3653 /*
3654
3655 It is a little strange to have this function in this file, but
3656 otherwise, we have to import music classes into the lexer.
3657
3658 */
3659 int
3660 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
3661 {
3662         if (Book::unsmob (sid)) {
3663                 Book *book =  Book::unsmob (sid)->clone ();
3664                 *destination = book->self_scm ();
3665                 book->unprotect ();
3666
3667                 return BOOK_IDENTIFIER;
3668         } else if (scm_is_number (sid)) {
3669                 *destination = sid;
3670                 return NUMBER_IDENTIFIER;
3671         } else if (Context_def::unsmob (sid))
3672         {
3673                 *destination = Context_def::unsmob (sid)->clone ()->unprotect ();
3674                 return SCM_IDENTIFIER;
3675         } else if (Context_mod::unsmob (sid)) {
3676                 *destination = Context_mod::unsmob (sid)->smobbed_copy ();
3677                 return CONTEXT_MOD_IDENTIFIER;
3678         } else if (Music *mus = Music::unsmob (sid)) {
3679                 mus = mus->clone ();
3680                 *destination = mus->self_scm ();
3681                 bool is_event = mus->is_mus_type ("post-event");
3682                 mus->unprotect ();
3683                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
3684         } else if (Pitch::unsmob (sid)) {
3685                 *destination = Pitch::unsmob (sid)->smobbed_copy ();
3686                 return PITCH_IDENTIFIER;
3687         } else if (Duration::unsmob (sid)) {
3688                 *destination = Duration::unsmob (sid)->smobbed_copy ();
3689                 return DURATION_IDENTIFIER;
3690         } else if (Output_def::unsmob (sid)) {
3691                 *destination = Output_def::unsmob (sid)->clone ()->unprotect ();
3692                 return SCM_IDENTIFIER;
3693         } else if (Score::unsmob (sid)) {
3694                 *destination = Score::unsmob (sid)->clone ()->unprotect ();
3695                 return SCM_IDENTIFIER;
3696         }
3697
3698         return -1;
3699 }
3700
3701 SCM
3702 get_next_unique_context_id ()
3703 {
3704         return scm_from_locale_string ("$uniqueContextId");
3705 }
3706
3707
3708 SCM
3709 get_next_unique_lyrics_context_id ()
3710 {
3711         static int new_context_count;
3712         char s[128];
3713         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
3714         return scm_from_locale_string (s);
3715 }
3716
3717 // check_scheme_arg checks one argument with a given predicate for use
3718 // in an argument list and throws a syntax error if it is unusable.
3719 // The argument is prepended to the argument list in any case.  After
3720 // throwing a syntax error, the argument list is terminated with #f as
3721 // its last cdr in order to mark it as uncallable while not losing
3722 // track of its total length.
3723 //
3724 // There are a few special considerations: if optional argument disp
3725 // is given (otherwise it defaults to SCM_UNDEFINED), it will be used
3726 // instead of arg in a prospective error message.  This is useful if
3727 // arg is not the actual argument but rather a transformation of it.
3728 //
3729 // If arg itself is SCM_UNDEFINED, the predicate is considered false
3730 // and an error message using disp is produced unconditionally.
3731
3732 SCM check_scheme_arg (Lily_parser *parser, Input loc,
3733                       SCM arg, SCM args, SCM pred, SCM disp)
3734 {
3735         if (SCM_UNBNDP (arg))
3736                 args = scm_cons (disp, args);
3737         else {
3738                 args = scm_cons (arg, args);
3739                 if (scm_is_true (scm_call_1 (pred, arg)))
3740                         return args;
3741         }
3742         scm_set_cdr_x (scm_last_pair (args), SCM_EOL);
3743         MAKE_SYNTAX ("argument-error", loc, scm_length (args), pred,
3744                      SCM_UNBNDP (disp) ? arg : disp);
3745         scm_set_cdr_x (scm_last_pair (args), SCM_BOOL_F);
3746         return args;
3747 }
3748
3749 SCM loc_on_music (Input loc, SCM arg)
3750 {
3751         if (Music *m = Music::unsmob (arg))
3752         {
3753                 m = m->clone ();
3754                 m->set_spot (loc);
3755                 return m->unprotect ();
3756         }
3757         return arg;
3758 }
3759
3760 SCM
3761 try_string_variants (SCM pred, SCM str)
3762 {
3763         // a matching predicate is always ok
3764         if (scm_is_true (scm_call_1 (pred, str)))
3765                 return str;
3766         // a symbol may be interpreted as a list of symbols if it helps
3767         if (scm_is_symbol (str)) {
3768                 str = scm_list_1 (str);
3769                 if (scm_is_true (scm_call_1 (pred, str)))
3770                         return str;
3771                 return SCM_UNDEFINED;
3772         }
3773
3774         // If this cannot be a string representation of a symbol list,
3775         // we are through.
3776
3777         if (!is_regular_identifier (str, true))
3778                 return SCM_UNDEFINED;
3779
3780         str = scm_string_split (str, SCM_MAKE_CHAR ('.'));
3781         for (SCM p = str; scm_is_pair (p); p = scm_cdr (p))
3782                 scm_set_car_x (p, scm_string_to_symbol (scm_car (p)));
3783
3784         // Let's attempt the symbol list interpretation first.
3785
3786         if (scm_is_true (scm_call_1 (pred, str)))
3787                 return str;
3788
3789         // If there is just one symbol in the list, we might interpret
3790         // it as a single symbol
3791
3792         if (scm_is_null (scm_cdr (str)))
3793         {
3794                 str = scm_car (str);
3795                 if (scm_is_true (scm_call_1 (pred, str)))
3796                         return str;
3797         }
3798
3799         return SCM_UNDEFINED;
3800 }
3801
3802 bool
3803 is_regular_identifier (SCM id, bool multiple)
3804 {
3805   if (!scm_is_string (id))
3806           return false;
3807
3808   string str = ly_scm2string (id);
3809
3810   bool middle = false;
3811
3812   for (string::iterator it=str.begin(); it != str.end (); it++)
3813   {
3814           int c = *it & 0xff;
3815           if ((c >= 'a' && c <= 'z')
3816               || (c >= 'A' && c <= 'Z')
3817               || c > 0x7f)
3818                   middle = true;
3819           else if (middle && (c == '-' || c == '_' || (multiple && c == '.')))
3820                   middle = false;
3821           else
3822                   return false;
3823   }
3824   return middle;
3825 }
3826
3827 SCM
3828 make_music_from_simple (Lily_parser *parser, Input loc, SCM simple)
3829 {
3830         if (Music::unsmob (simple))
3831                 return simple;
3832         if (parser->lexer_->is_note_state ()) {
3833                 if (scm_is_symbol (simple)) {
3834                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
3835                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
3836                         n->set_property ("drum-type", simple);
3837                         return n->unprotect ();
3838                 }
3839                 if (Pitch::unsmob (simple)) {
3840                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
3841                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
3842                         n->set_property ("pitch", simple);
3843                         return n->unprotect ();
3844                 }
3845                 return simple;
3846         } else if (parser->lexer_->is_lyric_state ()) {
3847                 if (Text_interface::is_markup (simple))
3848                         return MAKE_SYNTAX ("lyric-event", loc, simple,
3849                                             parser->default_duration_.smobbed_copy ());
3850         } else if (parser->lexer_->is_chord_state ()) {
3851                 if (Pitch::unsmob (simple))
3852                         return MAKE_SYNTAX
3853                                 ("event-chord",
3854                                  loc,
3855                                  make_chord_elements (loc, simple,
3856                                                       parser->default_duration_.smobbed_copy (),
3857                                                       SCM_EOL));
3858         }
3859         return simple;
3860 }
3861
3862 Music *
3863 make_music_with_input (SCM name, Input where)
3864 {
3865        Music *m = make_music_by_name (name);
3866        m->set_spot (where);
3867        return m;
3868 }
3869
3870 SCM
3871 make_simple_markup (SCM a)
3872 {
3873         return a;
3874 }
3875
3876 SCM
3877 make_duration (SCM d, int dots)
3878 {
3879         int t = scm_to_int (d);
3880         if (t > 0 && (t & (t-1)) == 0)
3881                 return Duration (intlog2 (t), dots).smobbed_copy ();
3882         else
3883                 return SCM_UNDEFINED;
3884 }
3885
3886 SCM
3887 make_chord_step (SCM step_scm, Rational alter)
3888 {
3889         int step = scm_to_int (step_scm);
3890
3891         if (step == 7)
3892                 alter += FLAT_ALTERATION;
3893
3894         while (step < 0)
3895                 step += 7;
3896         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
3897         return m.smobbed_copy ();
3898 }
3899
3900
3901 SCM
3902 make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list)
3903 {
3904         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
3905         SCM res = scm_call_3 (chord_ctor, pitch, dur, modification_list);
3906         for (SCM s = res; scm_is_pair (s); s = scm_cdr (s))
3907         {
3908                 Music::unsmob (scm_car (s))->set_spot (loc);
3909         }
3910         return res;
3911 }
3912
3913 int
3914 yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser)
3915 {
3916         Lily_lexer *lex = parser->lexer_;
3917
3918         lex->lexval_ = s;
3919         lex->lexloc_ = loc;
3920         int tok = lex->pop_extra_token ();
3921         if (tok >= 0)
3922                 return tok;
3923         lex->prepare_for_next_token ();
3924         return lex->yylex ();
3925 }