lily/parser.yy

   1 /*
   2   parser.yy -- Bison/C++ parser for LilyPond
   3
   4   source file of the GNU LilyPond music typesetter
   5
   6   (c) 1997--2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7                  Jan Nieuwenhuizen <janneke@gnu.org>
   8 */
   9
  10 %{
  11
  12 #define YYERROR_VERBOSE 1
  13 #define YYPARSE_PARAM my_lily_parser
  14 #define YYLEX_PARAM my_lily_parser
  15 #define PARSER ((Lily_parser *) my_lily_parser)
  16
  17 #define yyerror PARSER->parser_error
  18
  19 /* We use custom location type: Input objects */
  20 #define YYLTYPE Input
  21 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  22         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  23
  24
  25 %}
  26
  27 /* We use SCMs to do strings, because it saves us the trouble of
  28 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  29 of the parse stack onto the heap. */
  30
  31 %left PREC_TOP
  32 %left ADDLYRICS
  33 %left PREC_BOT
  34
  35 %expect 1
  36
  37 /* One shift/reduce problem
  38
  39 1.  \repeat
  40         \repeat .. \alternative
  41
  42     \repeat { \repeat .. \alternative }
  43
  44 or
  45
  46     \repeat { \repeat } \alternative
  47 */
  48
  49
  50 %pure_parser
  51 %locations
  52
  53
  54
  55 %{ // -*-Fundamental-*-
  56
  57 /*
  58 FIXME:
  59
  60    * The rules for who is protecting what are very shady.  Uniformise
  61      this.
  62
  63    * There are too many lexical modes?
  64 */
  65
  66 #include "config.hh"
  67
  68 #include <cctype>
  69 #include <cstdlib>
  70 #include <cstdio>
  71 using namespace std;
  72
  73 #include "book.hh"
  74 #include "context-def.hh"
  75 #include "dimensions.hh"
  76 #include "file-path.hh"
  77 #include "input-smob.hh"
  78 #include "input.hh"
  79 #include "international.hh"
  80 #include "lily-guile.hh"
  81 #include "lily-lexer.hh"
  82 #include "lily-parser.hh"
  83 #include "lilypond-input-version.hh"
  84 #include "main.hh"
  85 #include "misc.hh"
  86 #include "music.hh"
  87 #include "music.hh"
  88 #include "output-def.hh"
  89 #include "paper-book.hh"
  90 #include "program-option.hh"
  91 #include "scm-hash.hh"
  92 #include "score.hh"
  93 #include "text-interface.hh"
  94 #include "warn.hh"
  95
  96 %}
  97
  98
  99 %union {
 100         Book *book;
 101         Output_def *outputdef;
 102         SCM scm;
 103         std::string *string;
 104         Music *music;
 105         Score *score;
 106         int i;
 107 }
 108
 109 %{
 110
 111 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
 112
 113 /* ES TODO:
 114 - Don't use lily module, create a new module instead.
 115 - delay application of the function
 116 */
 117 #define MAKE_SYNTAX(name, location, ...)        \
 118   scm_apply_0 (ly_lily_module_constant (name), scm_list_n (make_input (location), __VA_ARGS__, SCM_UNDEFINED));
 119
 120 Music *property_op_to_music (SCM op);
 121 SCM context_spec_music (SCM type, SCM id, SCM m, SCM ops, bool create_new);
 122 SCM get_next_unique_context_id ();
 123 SCM get_next_unique_lyrics_context_id ();
 124
 125 #undef _
 126 #if !HAVE_GETTEXT
 127 #define _(x) x
 128 #else
 129 #include <libintl.h>
 130 #define _(x) gettext (x)
 131 #endif
 132
 133
 134
 135 SCM make_lyric_combine_music (SCM name, SCM music);
 136 SCM make_music_relative (Pitch start, SCM music);
 137 Music *run_music_function (Lily_parser *, SCM expr);
 138 Music *set_property_music (SCM sym, SCM value);
 139 SCM get_first_context_id (SCM type, Music *m);
 140 SCM make_chord (SCM pitch, SCM dur, SCM modification_list);
 141 SCM make_chord_step (int step, int alter);
 142 SCM make_simple_markup (SCM a);
 143 bool is_duration (int t);
 144 bool is_regular_identifier (SCM id);
 145 bool ly_input_procedure_p (SCM x);
 146 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 147 void set_music_properties (Music *p, SCM a);
 148
 149 %}
 150
 151 /* The third option is an alias that will be used to display the
 152    syntax error.  Bison CVS now correctly handles backslash escapes.
 153
 154    FIXME: Bison needs to translate some of these, eg, STRING.
 155
 156 */
 157
 158 /* Keyword tokens with plain escaped name.  */
 159 %token ACCEPTS "\\accepts"
 160 %token ADDLYRICS "\\addlyrics"
 161 %token ADDQUOTE "\\addquote"
 162 %token ALIAS "\\alias"
 163 %token ALTERNATIVE "\\alternative"
 164 %token BOOK "\book"
 165 %token CHANGE "\\change"
 166 %token CHORDMODE "\\chordmode"
 167 %token CHORDS "\\chords"
 168 %token CONSISTS "\\consists"
 169 %token CONTEXT "\\context"
 170 %token DEFAULT "\\default"
 171 %token DEFAULTCHILD "\\defaultchild"
 172 %token DENIES "\\denies"
 173 %token DESCRIPTION "\\description"
 174 %token DRUMMODE "\\drummode"
 175 %token DRUMS "\\drums"
 176 %token FIGUREMODE "\\figuremode"
 177 %token FIGURES "\\figures"
 178 %token GROBDESCRIPTIONS "\\grobdescriptions"
 179 %token HEADER "\\header"
 180 %token INVALID "\\invalid"
 181 %token KEY "\\key"
 182 %token LAYOUT "\\layout"
 183 %token LYRICMODE "\\lyricmode"
 184 %token LYRICS "\\lyrics"
 185 %token LYRICSTO "\\lyricsto"
 186 %token MARK "\\mark"
 187 %token MARKUP "\\markup"
 188 %token MIDI "\\midi"
 189 %token NAME "\\name"
 190 %token NOTEMODE "\\notemode"
 191 %token OBJECTID "\\objectid"
 192 %token OCTAVE "\\octave"
 193 %token ONCE "\\once"
 194 %token OVERRIDE "\\override"
 195 %token PAPER "\\paper"
 196 %token PARTIAL "\\partial"
 197 %token RELATIVE "\\relative"
 198 %token REMOVE "\\remove"
 199 %token REPEAT "\\repeat"
 200 %token REST "\\rest"
 201 %token REVERT "\\revert"
 202 %token SCORE "\\score"
 203 %token SEQUENTIAL "\\sequential"
 204 %token SET "\\set"
 205 %token SIMULTANEOUS "\\simultaneous"
 206 %token SKIP "\\skip"
 207 %token TEMPO "\\tempo"
 208 %token TIMES "\\times"
 209 %token TRANSPOSE "\\transpose"
 210 %token TRANSPOSITION "\\transposition"
 211 %token TYPE "\\type"
 212 %token UNSET "\\unset"
 213 %token WITH "\\with"
 214
 215 /* Keyword token exceptions.  */
 216 %token TIME_T "\\time"
 217 %token NEWCONTEXT "\\new"
 218
 219
 220 /* Other string tokens.  */
 221
 222 %token CHORD_BASS "/+"
 223 %token CHORD_CARET "^"
 224 %token CHORD_COLON ":"
 225 %token CHORD_MINUS "-"
 226 %token CHORD_SLASH "/"
 227 %token DOUBLE_ANGLE_CLOSE ">>"
 228 %token DOUBLE_ANGLE_OPEN "<<"
 229 %token E_BACKSLASH "\\"
 230 %token E_ANGLE_CLOSE "\\>"
 231 %token E_CHAR "\\C[haracter]"
 232 %token E_CLOSE "\\)"
 233 %token E_EXCLAMATION "\\!"
 234 %token E_BRACKET_OPEN "\\["
 235 %token E_OPEN "\\("
 236 %token E_BRACKET_CLOSE "\\]"
 237 %token E_ANGLE_OPEN "\\<"
 238 %token E_PLUS "\\+"
 239 %token E_TILDE "\\~"
 240 %token EXTENDER "__"
 241
 242 /*
 243 If we give names, Bison complains.
 244 */
 245 %token FIGURE_CLOSE /* "\\>" */
 246 %token FIGURE_OPEN /* "\\<" */
 247 %token FIGURE_SPACE "_"
 248 %token HYPHEN "--"
 249
 250 %token CHORDMODIFIERS
 251 %token LYRIC_MARKUP
 252 %token MULTI_MEASURE_REST
 253 %token SCM_T
 254
 255
 256 %token <i> DIGIT
 257 %token <i> E_UNSIGNED
 258 %token <i> UNSIGNED
 259
 260 %token <scm> BOOK_IDENTIFIER
 261 %token <scm> CHORDMODIFIER_PITCH
 262 %token <scm> CHORD_MODIFIER
 263 %token <scm> CONTEXT_DEF_IDENTIFIER
 264 %token <scm> DRUM_PITCH
 265 %token <scm> DURATION_IDENTIFIER
 266 %token <scm> EVENT_IDENTIFIER
 267 %token <scm> FRACTION
 268 %token <scm> LYRICS_STRING
 269 %token <scm> LYRIC_MARKUP_IDENTIFIER
 270 %token <scm> MARKUP_HEAD_EMPTY
 271 %token <scm> MARKUP_HEAD_LIST0
 272 %token <scm> MARKUP_HEAD_MARKUP0
 273 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 274 %token <scm> MARKUP_HEAD_SCM0
 275 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 276 %token <scm> MARKUP_HEAD_SCM0_SCM1
 277 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 278 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 279 %token <scm> MARKUP_IDENTIFIER
 280 %token <scm> MUSIC_FUNCTION
 281 %token <scm> MUSIC_FUNCTION_MARKUP
 282 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 283 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 284 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 285 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 286 %token <scm> MUSIC_FUNCTION_MUSIC
 287 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 288 %token <scm> MUSIC_FUNCTION_SCM
 289 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 290 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 291 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC_MUSIC
 292 %token <scm> MUSIC_FUNCTION_SCM_SCM
 293 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 294 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM
 295 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM_MUSIC
 296 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM_SCM_MUSIC
 297 %token <scm> MUSIC_IDENTIFIER
 298 %token <scm> NOTENAME_PITCH
 299 %token <scm> NUMBER_IDENTIFIER
 300 %token <scm> OUTPUT_DEF_IDENTIFIER
 301 %token <scm> REAL
 302 %token <scm> RESTNAME
 303 %token <scm> SCM_IDENTIFIER
 304 %token <scm> SCM_T
 305 %token <scm> SCORE_IDENTIFIER
 306 %token <scm> STRING
 307 %token <scm> STRING_IDENTIFIER
 308 %token <scm> TONICNAME_PITCH
 309
 310
 311 %type <book> book_block
 312 %type <book> book_body
 313
 314 %type <i> bare_unsigned
 315 %type <i> figured_bass_alteration
 316 %type <i> dots
 317 %type <i> exclamations
 318 %type <i> optional_rest
 319 %type <i> questions
 320 %type <i> script_dir
 321 %type <i> sub_quotes
 322 %type <i> sup_quotes
 323 %type <i> tremolo_type
 324
 325 /* Music */
 326 %type <scm> Composite_music
 327 %type <scm> Grouped_music_list
 328 %type <scm> Music
 329 %type <scm> Prefix_composite_music
 330 %type <scm> Repeated_music
 331 %type <scm> Sequential_music
 332 %type <scm> Simple_music
 333 %type <scm> Simultaneous_music
 334 %type <scm> chord_body
 335 %type <scm> chord_body_element
 336 %type <scm> command_element
 337 %type <scm> command_event
 338 %type <scm> context_change
 339 %type <scm> direction_less_event
 340 %type <scm> direction_reqd_event
 341 %type <scm> event_chord
 342 %type <scm> gen_text_def
 343 %type <scm> music_property_def
 344 %type <scm> note_chord_element
 345 %type <scm> post_event
 346 %type <scm> re_rhythmed_music
 347 %type <scm> relative_music
 348 %type <scm> simple_element
 349 %type <scm> string_number_event
 350 %type <scm> tempo_event
 351 %type <scm> toplevel_music
 352
 353 %type <outputdef> output_def_body
 354 %type <outputdef> output_def_head
 355 %type <outputdef> output_def_head_with_mode_switch
 356 %type <outputdef> output_def
 357 %type <outputdef> paper_block
 358
 359 %type <scm> Alternative_music
 360 %type <scm> Generic_prefix_music_scm
 361 %type <scm> Music_list
 362 %type <scm> absolute_pitch
 363 %type <scm> assignment_id
 364 %type <scm> bare_number
 365 %type <scm> music_function_event
 366 %type <scm> music_function_chord_body
 367 %type <scm> music_function_musicless_prefix
 368 %type <scm> bass_figure
 369 %type <scm> figured_bass_modification
 370 %type <scm> br_bass_figure
 371 %type <scm> bass_number
 372 %type <scm> chord_body_elements
 373 %type <scm> chord_item
 374 %type <scm> chord_items
 375 %type <scm> chord_separator
 376 %type <scm> context_def_mod
 377 %type <scm> context_def_spec_block
 378 %type <scm> context_def_spec_body
 379 %type <scm> context_mod
 380 %type <scm> context_mod_list
 381 %type <scm> context_prop_spec
 382 %type <scm> direction_less_char
 383 %type <scm> duration_length
 384 %type <scm> embedded_scm
 385 %type <scm> figure_list
 386 %type <scm> figure_spec
 387 %type <scm> fraction
 388 %type <scm> full_markup
 389 %type <scm> identifier_init
 390 %type <scm> lilypond_header
 391 %type <scm> lilypond_header_body
 392 %type <scm> lyric_element
 393 %type <scm> lyric_markup
 394 %type <scm> markup
 395 %type <scm> markup_braced_list
 396 %type <scm> markup_braced_list_body
 397 %type <scm> markup_composed_list
 398 %type <scm> markup_head_1_item
 399 %type <scm> markup_head_1_list
 400 %type <scm> markup_list
 401 %type <scm> markup_top
 402 %type <scm> mode_changing_head
 403 %type <scm> mode_changing_head_with_context
 404 %type <scm> multiplied_duration
 405 %type <scm> new_chord
 406 %type <scm> new_lyrics
 407 %type <scm> number_expression
 408 %type <scm> number_factor
 409 %type <scm> number_term
 410 %type <scm> object_id_setting
 411 %type <scm> octave_check
 412 %type <scm> optional_context_mod
 413 %type <scm> optional_id
 414 %type <scm> optional_notemode_duration
 415 %type <scm> pitch
 416 %type <scm> pitch_also_in_chords
 417 %type <scm> post_events
 418 %type <scm> property_operation
 419 %type <scm> scalar
 420 %type <scm> script_abbreviation
 421 %type <scm> simple_markup
 422 %type <scm> simple_string
 423 %type <scm> steno_duration
 424 %type <scm> steno_pitch
 425 %type <scm> steno_tonic_pitch
 426 %type <scm> step_number
 427 %type <scm> step_numbers
 428 %type <scm> string
 429 %type <scm> function_scm_argument
 430
 431 %type <score> score_block
 432 %type <score> score_body
 433
 434
 435 %left '-' '+'
 436
 437 /* We don't assign precedence to / and *, because we might need varied
 438 prec levels in different prods */
 439
 440 %left UNARY_MINUS
 441
 442 %%
 443
 444 lilypond:       /* empty */
 445         | lilypond toplevel_expression {
 446         }
 447         | lilypond assignment {
 448         }
 449         | lilypond error {
 450                 PARSER->error_level_ = 1;
 451         }
 452         | lilypond INVALID      {
 453                 PARSER->error_level_ = 1;
 454         }
 455         ;
 456
 457
 458 object_id_setting:
 459         OBJECTID STRING { $$ = $2; }
 460         ;
 461
 462 toplevel_expression:
 463         lilypond_header {
 464                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 465         }
 466         | book_block {
 467                 Book *book = $1;
 468                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 469                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 470                 book->unprotect ();
 471         }
 472         | score_block {
 473                 Score *score = $1;
 474
 475                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 476                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 477                 score->unprotect ();
 478         }
 479         | toplevel_music {
 480                 Music *music = unsmob_music ($1);
 481                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 482                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 483         }
 484         | full_markup {
 485                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 486                 scm_call_2 (proc, PARSER->self_scm (), $1);
 487         }
 488         | output_def {
 489                 SCM id = SCM_EOL;
 490                 Output_def * od = $1;
 491
 492                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 493                         id = ly_symbol2scm ("$defaultpaper");
 494                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 495                         id = ly_symbol2scm ("$defaultmidi");
 496                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 497                         id = ly_symbol2scm ("$defaultlayout");
 498
 499                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 500                 od->unprotect();
 501         }
 502         ;
 503
 504 toplevel_music:
 505         Composite_music {
 506         }
 507         ;
 508
 509 embedded_scm:
 510         SCM_T
 511         | SCM_IDENTIFIER
 512         ;
 513
 514
 515 lilypond_header_body:
 516         {
 517                 $$ = get_header(PARSER);
 518                 PARSER->lexer_->add_scope ($$);
 519         }
 520         | lilypond_header_body assignment  {
 521
 522         }
 523         ;
 524
 525 lilypond_header:
 526         HEADER '{' lilypond_header_body '}'     {
 527                 $$ = PARSER->lexer_->remove_scope ();
 528         }
 529         ;
 530
 531 /*
 532         DECLARATIONS
 533 */
 534 assignment_id:
 535         STRING          { $$ = $1; }
 536         | LYRICS_STRING { $$ = $1; }
 537         ;
 538
 539 assignment:
 540         assignment_id '=' identifier_init  {
 541                 if (! is_regular_identifier ($1))
 542                 {
 543 #if 0
 544                         /* no longer valid with dashes in \paper{} block. */
 545                         @1.warning (_ ("identifier should have alphabetic characters only"));
 546 #endif
 547                 }
 548
 549
 550                 PARSER->lexer_->set_identifier ($1, $3);
 551
 552 /*
 553  TODO: devise standard for protection in parser.
 554
 555   The parser stack lives on the C-stack, which means that
 556 all objects can be unprotected as soon as they're here.
 557
 558 */
 559         }
 560         | embedded_scm { }
 561         ;
 562
 563
 564 identifier_init:
 565         score_block {
 566                 $$ = $1->self_scm ();
 567                 $1->unprotect ();
 568         }
 569         | book_block {
 570                 $$ = $1->self_scm ();
 571                 $1->unprotect ();
 572         }
 573         | output_def {
 574                 $$ = $1->self_scm ();
 575                 $1->unprotect ();
 576         }
 577         | context_def_spec_block {
 578                 $$ = $1;
 579         }
 580         | Music  {
 581                 $$ = $1;
 582         }
 583         | post_event {
 584                 $$ = $1;
 585         }
 586         | number_expression {
 587                 $$ = $1;
 588         }
 589         | string {
 590                 $$ = $1;
 591         }
 592         | embedded_scm {
 593                 $$ = $1;
 594         }
 595         | full_markup {
 596                 $$ = $1;
 597         }
 598         | DIGIT {
 599                 $$ = scm_from_int ($1);
 600         }
 601         ;
 602
 603 context_def_spec_block:
 604         CONTEXT '{' context_def_spec_body '}'
 605                 {
 606                 $$ = $3;
 607         }
 608         ;
 609
 610 context_def_spec_body:
 611         /**/ {
 612                 $$ = Context_def::make_scm ();
 613                 unsmob_context_def ($$)->set_spot (@$);
 614         }
 615         | CONTEXT_DEF_IDENTIFIER {
 616                 $$ = $1;
 617                 unsmob_context_def ($$)->set_spot (@$);
 618         }
 619         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 620                 Context_def*td = unsmob_context_def ($$);
 621
 622                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 623                         SCM tag = scm_caar (p);
 624
 625                         /* TODO: should make new tag "grob-definition" ? */
 626                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 627                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 628                 }
 629         }
 630         | context_def_spec_body context_mod {
 631                 unsmob_context_def ($$)->add_context_mod ($2);
 632         }
 633         ;
 634
 635
 636
 637 book_block:
 638         BOOK '{' book_body '}'  {
 639                 $$ = $3;
 640         }
 641         ;
 642
 643 /* FIXME:
 644    * Use 'handlers' like for toplevel-* stuff?
 645    * grok \layout and \midi?  */
 646 book_body:
 647         {
 648                 $$ = new Book;
 649                 $$->set_spot (@$);
 650                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 651                 $$->paper_->unprotect ();
 652                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 653         }
 654         | BOOK_IDENTIFIER {
 655                 $$ = unsmob_book ($1);
 656                 $$->set_spot (@$);
 657         }
 658         | book_body paper_block {
 659                 $$->paper_ = $2;
 660                 $2->unprotect ();
 661         }
 662         | book_body score_block {
 663                 SCM s = $2->self_scm ();
 664                 $$->add_score (s);
 665                 $2->unprotect();
 666         }
 667         | book_body full_markup {
 668                 $$->add_score ($2);
 669         }
 670         | book_body lilypond_header {
 671                 $$->header_ = $2;
 672         }
 673         | book_body error {
 674                 $$->paper_ = 0;
 675                 $$->scores_ = SCM_EOL;
 676         }
 677         | book_body object_id_setting {
 678                 $$->user_key_ = ly_scm2string ($2);
 679         }
 680         ;
 681
 682 score_block:
 683         SCORE '{' score_body '}'        {
 684                 $$ = $3;
 685         }
 686         ;
 687
 688 score_body:
 689         Music {
 690                 SCM m = $1;
 691                 SCM scorify = ly_lily_module_constant ("scorify-music");
 692                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 693
 694                 // pass ownernship to C++ again.
 695                 $$ = unsmob_score (score);
 696                 $$->protect ();
 697                 $$->set_spot (@$);
 698         }
 699         | SCORE_IDENTIFIER {
 700                 $$ = unsmob_score ($1);
 701                 $$->set_spot (@$);
 702         }
 703         | score_body object_id_setting {
 704                 $$->user_key_ = ly_scm2string ($2);
 705         }
 706         | score_body lilypond_header    {
 707                 $$->header_ = $2;
 708         }
 709         | score_body output_def {
 710                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 711                 {
 712                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 713
 714                 }
 715                 else
 716                 {
 717                         $$->add_output_def ($2);
 718                 }
 719                 $2->unprotect ();
 720         }
 721         | score_body error {
 722                 $$->error_found_ = true;
 723         }
 724         ;
 725
 726
 727 /*
 728         OUTPUT DEF
 729 */
 730
 731 paper_block:
 732         output_def {
 733                 $$ = $1;
 734                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 735                 {
 736                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
 737                         $$ = get_paper (PARSER);
 738                 }
 739         }
 740         ;
 741
 742
 743 output_def:
 744         output_def_body '}' {
 745                 $$ = $1;
 746
 747                 PARSER->lexer_->remove_scope ();
 748                 PARSER->lexer_->pop_state ();
 749         }
 750         ;
 751
 752 output_def_head:
 753         PAPER {
 754                 $$ = get_paper (PARSER);
 755                 $$->input_origin_ = @$;
 756                 PARSER->lexer_->add_scope ($$->scope_);
 757         }
 758         | MIDI    {
 759                 Output_def *p = get_midi (PARSER);
 760                 $$ = p;
 761                 PARSER->lexer_->add_scope (p->scope_);
 762         }
 763         | LAYOUT        {
 764                 Output_def *p = get_layout (PARSER);
 765
 766                 PARSER->lexer_->add_scope (p->scope_);
 767                 $$ = p;
 768         }
 769         ;
 770
 771 output_def_head_with_mode_switch:
 772         output_def_head {
 773                 PARSER->lexer_->push_initial_state ();
 774                 $$ = $1;
 775         }
 776         ;
 777
 778 output_def_body:
 779         output_def_head_with_mode_switch '{' {
 780                 $$ = $1;
 781                 $$->input_origin_.set_spot (@$);
 782         }
 783         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 784                 $1->unprotect ();
 785                 Output_def *o = unsmob_output_def ($3);
 786                 o->input_origin_.set_spot (@$);
 787                 $$ = o;
 788                 PARSER->lexer_->remove_scope ();
 789                 PARSER->lexer_->add_scope (o->scope_);
 790         }
 791         | output_def_body assignment  {
 792
 793         }
 794         | output_def_body context_def_spec_block        {
 795                 assign_context_def ($$, $2);
 796         }
 797         | output_def_body tempo_event  {
 798                 /*
 799                         junk this ? there already is tempo stuff in
 800                         music.
 801                 */
 802                 int m = scm_to_int (unsmob_music($2)->get_property ("metronome-count"));
 803                 Duration *d = unsmob_duration (unsmob_music($2)->get_property ("tempo-unit"));
 804                 set_tempo ($$, d->get_length (), m);
 805         }
 806         | output_def_body error {
 807
 808         }
 809         ;
 810
 811 tempo_event:
 812         TEMPO steno_duration '=' bare_unsigned  {
 813                 Music *m = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 814                 m->set_property ("tempo-unit", $2);
 815                 m->set_property ("metronome-count", scm_from_int ( $4));
 816                 $$ = m->unprotect ();
 817         }
 818         ;
 819
 820 /*
 821 The representation of a  list is the
 822
 823   (LIST . LAST-CONS)
 824
 825  to have efficient append.  */
 826
 827 Music_list:
 828         /* empty */ {
 829                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 830         }
 831         | Music_list Music {
 832                 SCM s = $$;
 833                 SCM c = scm_cons ($2, SCM_EOL);
 834
 835                 if (scm_is_pair (scm_cdr (s)))
 836                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 837                 else
 838                         scm_set_car_x (s, c); /* set first cons */
 839                 scm_set_cdr_x (s, c);  /* remember last cell */
 840         }
 841         | Music_list embedded_scm {
 842
 843         }
 844         | Music_list error {
 845                 Music *m = MY_MAKE_MUSIC("Music");
 846                 // ugh. code dup
 847                 m->set_property ("error-found", SCM_BOOL_T);
 848                 SCM s = $$;
 849                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 850                 m->unprotect (); /* UGH */
 851
 852                 if (scm_is_pair (scm_cdr (s)))
 853                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 854                 else
 855                         scm_set_car_x (s, c); /* set first cons */
 856                 scm_set_cdr_x (s, c);  /* remember last cell */
 857         }
 858         ;
 859
 860 Music:
 861         Simple_music
 862         | Composite_music
 863         ;
 864
 865 Alternative_music:
 866         /* empty */ {
 867                 $$ = SCM_EOL;
 868         }
 869         | ALTERNATIVE '{' Music_list '}' {
 870                 $$ = scm_car ($3);
 871         }
 872         ;
 873
 874
 875 Repeated_music:
 876         REPEAT simple_string bare_unsigned Music Alternative_music
 877         {
 878                 $$ = MAKE_SYNTAX ("repeat", @$, $2, scm_int2num ($3), $4, $5);
 879         }
 880         ;
 881
 882 Sequential_music:
 883         SEQUENTIAL '{' Music_list '}'           {
 884                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($3));
 885         }
 886         | '{' Music_list '}'            {
 887                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($2));
 888         }
 889         ;
 890
 891 Simultaneous_music:
 892         SIMULTANEOUS '{' Music_list '}'{
 893                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($3));
 894         }
 895         | simul_open Music_list simul_close     {
 896                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($2));
 897         }
 898         ;
 899
 900 Simple_music:
 901         event_chord
 902         | MUSIC_IDENTIFIER
 903         | music_property_def
 904         | context_change
 905         ;
 906
 907 optional_context_mod:
 908         /**/ { $$ = SCM_EOL; }
 909         | WITH { PARSER->lexer_->push_initial_state (); }
 910         '{' context_mod_list '}'
 911         {
 912                 PARSER->lexer_->pop_state ();
 913                 $$ = $4;
 914         }
 915         ;
 916
 917 context_mod_list:
 918         /* */  { $$ = SCM_EOL; }
 919         | context_mod_list context_mod  {
 920                  $$ = scm_cons ($2, $1);
 921         }
 922         ;
 923
 924 Composite_music:
 925         Prefix_composite_music { $$ = $1; }
 926         | Grouped_music_list { $$ = $1; }
 927         ;
 928
 929 Grouped_music_list:
 930         Simultaneous_music              { $$ = $1; }
 931         | Sequential_music              { $$ = $1; }
 932         ;
 933
 934 function_scm_argument:
 935         embedded_scm
 936         | simple_string
 937         ;
 938
 939 /*
 940 TODO: use code generation for this
 941 */
 942 Generic_prefix_music_scm:
 943         MUSIC_FUNCTION {
 944                 $$ = scm_list_2 ($1, make_input (@$));
 945         }
 946         | MUSIC_FUNCTION_SCM function_scm_argument {
 947                 $$ = scm_list_3 ($1, make_input (@$), $2);
 948         }
 949         | MUSIC_FUNCTION_MARKUP full_markup {
 950                 $$ = scm_list_3 ($1, make_input (@$), $2);
 951         }
 952         | music_function_musicless_prefix Music {
 953                 $$ = ly_append2 ($1, scm_list_1 ($2));
 954         }
 955         | MUSIC_FUNCTION_SCM_SCM function_scm_argument function_scm_argument {
 956                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
 957         }
 958         | MUSIC_FUNCTION_SCM_SCM_SCM function_scm_argument function_scm_argument function_scm_argument {
 959                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
 960         }
 961         | MUSIC_FUNCTION_MARKUP_MUSIC full_markup Music {
 962                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
 963         }
 964         | MUSIC_FUNCTION_MARKUP_MARKUP full_markup full_markup {
 965                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
 966         }
 967         | MUSIC_FUNCTION_MUSIC_MUSIC Music Music {
 968                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
 969         }
 970         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC function_scm_argument Music Music {
 971                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
 972         }
 973         | MUSIC_FUNCTION_SCM_SCM_MUSIC_MUSIC function_scm_argument function_scm_argument Music Music {
 974                 $$ = scm_list_n ($1, make_input (@$), $2, $3, $4, $5, SCM_UNDEFINED);
 975         }
 976         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC full_markup Music Music {
 977                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
 978         }
 979         ;
 980
 981 optional_id:
 982         /**/ { $$ = SCM_EOL; }
 983         | '=' simple_string {
 984                 $$ = $2;
 985         }
 986         ;
 987
 988
 989 Prefix_composite_music:
 990         Generic_prefix_music_scm {
 991                 $$ = run_music_function (PARSER, $1)->unprotect ();
 992         }
 993         | CONTEXT    simple_string optional_id optional_context_mod Music {
 994                 $$ = context_spec_music ($2, $3, $5, $4, false);
 995         }
 996         | NEWCONTEXT simple_string optional_id optional_context_mod Music {
 997                 $$ = context_spec_music ($2, $3, $5, $4, true);
 998         }
 999
1000         | TIMES fraction Music
1001         {
1002                 int n = scm_to_int (scm_car ($2));
1003                 int d = scm_to_int (scm_cdr ($2));
1004
1005                 Music *m = MY_MAKE_MUSIC ("TimeScaledMusic");
1006                 m->set_spot (@$);
1007
1008                 m->set_property ("element", $3);
1009                 m->set_property ("numerator", scm_from_int (n));
1010                 m->set_property ("denominator", scm_from_int (d));
1011                 m->compress (Moment (Rational (n,d)));
1012                 $$ = m->unprotect ();
1013         }
1014         | Repeated_music                { $$ = $1; }
1015         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1016                 Music *m = MY_MAKE_MUSIC ("TransposedMusic");
1017                 Pitch from = *unsmob_pitch ($2);
1018                 Pitch to = *unsmob_pitch ($3);
1019
1020                 Music *p = unsmob_music ($4);
1021                 p->transpose (pitch_interval (from, to));
1022                 m->set_property ("element", $4);
1023                 $$ = m->unprotect ();
1024         }
1025         | mode_changing_head Grouped_music_list {
1026                 if ($1 == ly_symbol2scm ("chords"))
1027                 {
1028                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1029                   chm->set_property ("element", $2);
1030                   $$ = chm->unprotect ();
1031                 }
1032                 else
1033                 {
1034                   $$ = $2;
1035                 }
1036                 PARSER->lexer_->pop_state ();
1037         }
1038         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1039                 $$ = context_spec_music ($1, SCM_UNDEFINED, $3, $2, true);
1040                 if ($1 == ly_symbol2scm ("ChordNames"))
1041                 {
1042                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1043                   chm->set_property ("element", $$);
1044                   $$ = chm->unprotect ();
1045                 }
1046                 PARSER->lexer_->pop_state ();
1047         }
1048         | relative_music        { $$ = $1; }
1049         | re_rhythmed_music     { $$ = $1; }
1050         ;
1051
1052 mode_changing_head:
1053         NOTEMODE {
1054                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1055                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1056
1057                 $$ = ly_symbol2scm ("notes");
1058         }
1059         | DRUMMODE
1060                 {
1061                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1062                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1063
1064                 $$ = ly_symbol2scm ("drums");
1065         }
1066         | FIGUREMODE {
1067                 PARSER->lexer_->push_figuredbass_state ();
1068
1069                 $$ = ly_symbol2scm ("figures");
1070         }
1071         | CHORDMODE {
1072                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1073                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1074                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1075                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1076                 $$ = ly_symbol2scm ("chords");
1077
1078         }
1079         | LYRICMODE
1080                 { PARSER->lexer_->push_lyric_state ();
1081                 $$ = ly_symbol2scm ("lyrics");
1082         }
1083         ;
1084
1085 mode_changing_head_with_context:
1086         DRUMS {
1087                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1088                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1089
1090                 $$ = ly_symbol2scm ("DrumStaff");
1091         }
1092         | FIGURES {
1093                 PARSER->lexer_->push_figuredbass_state ();
1094
1095                 $$ = ly_symbol2scm ("FiguredBass");
1096         }
1097         | CHORDS {
1098                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1099                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1100                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1101                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1102                 $$ = ly_symbol2scm ("ChordNames");
1103         }
1104         | LYRICS
1105                 { PARSER->lexer_->push_lyric_state ();
1106                 $$ = ly_symbol2scm ("Lyrics");
1107         }
1108         ;
1109
1110
1111 relative_music:
1112         RELATIVE absolute_pitch Music {
1113                 Pitch start = *unsmob_pitch ($2);
1114                 $$ = make_music_relative (start, $3);
1115         }
1116         | RELATIVE Composite_music {
1117                 Pitch middle_c (0, 0, 0);
1118                 $$ = make_music_relative (middle_c, $2);
1119         }
1120         ;
1121
1122 new_lyrics:
1123         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1124         /*cont */
1125         Grouped_music_list {
1126         /* Can also use Music at the expensive of two S/Rs similar to
1127            \repeat \alternative */
1128                 PARSER->lexer_->pop_state ();
1129
1130                 $$ = scm_cons ($3, SCM_EOL);
1131         }
1132         | new_lyrics ADDLYRICS {
1133                 PARSER->lexer_->push_lyric_state ();
1134         } Grouped_music_list {
1135                 PARSER->lexer_->pop_state ();
1136                 $$ = scm_cons ($4, $1);
1137         }
1138         ;
1139
1140 re_rhythmed_music:
1141         Grouped_music_list new_lyrics {
1142                 SCM voice = $1;
1143                 SCM name = get_first_context_id (scm_makfrom0str ("Voice"), unsmob_music (voice));
1144                 if (!scm_is_string (name))
1145                 {
1146                         name = get_next_unique_lyrics_context_id ();
1147                         voice = context_spec_music (scm_makfrom0str ("Voice"),
1148                                                     name,
1149                                                     voice, SCM_EOL, false);
1150                 }
1151
1152                 SCM context = scm_makfrom0str ("Lyrics");
1153                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1154
1155                 SCM lst = SCM_EOL;
1156                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1157                 {
1158                         SCM com = make_lyric_combine_music (name, scm_car (s));
1159                         SCM csm = context_spec_music (context,
1160                                 SCM_UNDEFINED, com, SCM_EOL, true);
1161                         lst = scm_cons (csm, lst);
1162                 }
1163                 all->set_property ("elements", scm_cons (voice,
1164                         lst));
1165                 $$ = all->unprotect ();
1166         }
1167         | LYRICSTO simple_string {
1168                 PARSER->lexer_->push_lyric_state ();
1169         } Music {
1170                 PARSER->lexer_->pop_state ();
1171                 SCM name = $2;
1172                 $$ = make_lyric_combine_music (name, $4);
1173         }
1174         ;
1175
1176 context_change:
1177         CHANGE STRING '=' STRING  {
1178                 Music *t = MY_MAKE_MUSIC ("ContextChange");
1179                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1180                 t-> set_property ("change-to-id", $4);
1181                 t->set_spot (@$);
1182
1183                 $$ = t->unprotect ();
1184         }
1185         ;
1186
1187 property_operation:
1188         STRING '=' scalar {
1189                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1190                         scm_string_to_symbol ($1), $3);
1191         }
1192         | UNSET simple_string {
1193                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1194                         scm_string_to_symbol ($2));
1195         }
1196         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1197                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1198                         scm_string_to_symbol ($2), $5, $3);
1199         }
1200         | OVERRIDE simple_string embedded_scm embedded_scm '=' embedded_scm {
1201                 $$ = scm_list_5 (ly_symbol2scm ("push"),
1202                                 scm_string_to_symbol ($2), $6, $4, $3);
1203         }
1204         | REVERT simple_string embedded_scm {
1205                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1206                         scm_string_to_symbol ($2), $3);
1207         }
1208         ;
1209
1210 context_def_mod:
1211         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1212         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1213
1214         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1215         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1216         | DENIES { $$ = ly_symbol2scm ("denies"); }
1217
1218         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1219         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1220         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1221         | NAME { $$ = ly_symbol2scm ("context-name"); }
1222         ;
1223
1224 context_mod:
1225         property_operation { $$ = $1; }
1226         | context_def_mod STRING {
1227                 $$ = scm_list_2 ($1, $2);
1228         }
1229         ;
1230
1231 context_prop_spec:
1232         simple_string {
1233                 if (!is_regular_identifier ($1))
1234                 {
1235                         @$.error (_("Grob name should be alphanumeric"));
1236                 }
1237
1238                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1239                         scm_string_to_symbol ($1));
1240         }
1241         | simple_string '.' simple_string {
1242                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1243                         scm_string_to_symbol ($3));
1244         }
1245         ;
1246
1247 music_property_def:
1248         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1249                 Music *m = property_op_to_music (scm_list_4 (
1250                         ly_symbol2scm ("push"),
1251                         scm_cadr ($2),
1252                         $5, $3));
1253                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, m->unprotect (), SCM_EOL, false);
1254         }
1255         | OVERRIDE context_prop_spec embedded_scm  embedded_scm '=' scalar {
1256                 Music *m = property_op_to_music (scm_list_5 (
1257                         ly_symbol2scm ("push"),
1258                         scm_cadr ($2),
1259                         $6, $4, $3));
1260                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, m->unprotect (), SCM_EOL, false);
1261         }
1262         | REVERT context_prop_spec embedded_scm {
1263                 Music *m = property_op_to_music (scm_list_3 (
1264                         ly_symbol2scm ("pop"),
1265                         scm_cadr ($2),
1266                         $3));
1267
1268                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, m->unprotect (), SCM_EOL, false);
1269         }
1270         | SET context_prop_spec '=' scalar {
1271                 Music *m = property_op_to_music (scm_list_3 (
1272                         ly_symbol2scm ("assign"),
1273                         scm_cadr ($2),
1274                         $4));
1275                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, m->unprotect (), SCM_EOL, false);
1276         }
1277         | UNSET context_prop_spec {
1278                 Music *m = property_op_to_music (scm_list_2 (
1279                         ly_symbol2scm ("unset"),
1280                         scm_cadr ($2)));
1281                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, m->unprotect (), SCM_EOL, false);
1282         }
1283         | ONCE music_property_def {
1284                 Music *m = unsmob_music ($2);
1285                 SCM e = m->get_property ("element");
1286                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1287                 $$ = $2;
1288         }
1289         ;
1290
1291
1292 string:
1293         STRING {
1294                 $$ = $1;
1295         }
1296         | STRING_IDENTIFIER {
1297                 $$ = $1;
1298         }
1299         | string '+' string {
1300                 $$ = scm_string_append (scm_list_2 ($1, $3));
1301         }
1302         ;
1303
1304 simple_string: STRING {
1305                 $$ = $1;
1306         }
1307         | LYRICS_STRING {
1308                 $$ = $1;
1309         }
1310         | STRING_IDENTIFIER {
1311                 $$ = $1;
1312         }
1313         ;
1314
1315 scalar: string {
1316                 $$ = $1;
1317         }
1318         | LYRICS_STRING {
1319                 $$ = $1;
1320         }
1321         | bare_number {
1322                 $$ = $1;
1323         }
1324         | embedded_scm {
1325                 $$ = $1;
1326         }
1327         | full_markup {
1328                 $$ = $1;
1329         }
1330         | DIGIT {
1331                 $$ = scm_from_int ($1);
1332         }
1333         ;
1334
1335 /*
1336
1337 pre_events doesn't contain anything. It is a trick:
1338
1339 Adding pre_events to the simple_element
1340 makes the choice between
1341
1342   string:  STRING
1343
1344 and
1345
1346   simple_element: STRING
1347
1348 a single shift/reduction conflict.
1349
1350 nevertheless, this is not very clean, and we should find a different
1351 solution.
1352
1353 */
1354 pre_events: /* empty */
1355         ;
1356
1357 event_chord:
1358         pre_events simple_element post_events   {
1359                 Music *m = unsmob_music ($2);
1360                 m->protect ();
1361                 SCM elts = m->get_property ("elements");
1362
1363                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1364
1365                 m->set_property ("elements", elts);
1366                 /* why is this giving wrong start location? -ns
1367                  * $2->set_spot (@$); */
1368                 Input i;
1369                 i.set_location (@2, @3);
1370                 m->set_spot (i);
1371                 $$ = m->unprotect ();
1372         }
1373         | command_element { $$ = $1; }
1374         | note_chord_element
1375         ;
1376
1377
1378 note_chord_element:
1379         chord_body optional_notemode_duration post_events
1380         {
1381                 Music *m = unsmob_music ($1);
1382                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1383                 SCM es = m->get_property ("elements");
1384                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1385
1386                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1387                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1388                 es = ly_append2 (es, postevs);
1389
1390                 m-> set_property ("elements", es);
1391                 m->set_spot (@$);
1392                 $$ = m->self_scm ();
1393         }
1394         ;
1395
1396 chord_open: '<'
1397         ;
1398
1399 chord_close: '>'
1400         ;
1401
1402 simul_open: DOUBLE_ANGLE_OPEN
1403         ;
1404
1405 simul_close: DOUBLE_ANGLE_CLOSE
1406         ;
1407
1408 chord_body:
1409         chord_open chord_body_elements chord_close
1410         {
1411                 Music *m = MY_MAKE_MUSIC ("EventChord");
1412                 m->set_spot (@$);
1413                 m->set_property ("elements",
1414                         scm_reverse_x ($2, SCM_EOL));
1415                 $$ = m->unprotect ();
1416         }
1417         ;
1418
1419 chord_body_elements:
1420         /* empty */             { $$ = SCM_EOL; }
1421         | chord_body_elements chord_body_element {
1422                 $$ = scm_cons ($2, $1);
1423         }
1424         ;
1425
1426 chord_body_element:
1427         pitch exclamations questions octave_check post_events
1428         {
1429                 int q = $3;
1430                 int ex = $2;
1431                 SCM check = $4;
1432                 SCM post = $5;
1433
1434                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1435                 n->set_property ("pitch", $1);
1436                 n->set_spot (@$);
1437                 if (q % 2)
1438                         n->set_property ("cautionary", SCM_BOOL_T);
1439                 if (ex % 2 || q % 2)
1440                         n->set_property ("force-accidental", SCM_BOOL_T);
1441
1442                 if (scm_is_pair (post)) {
1443                         SCM arts = scm_reverse_x (post, SCM_EOL);
1444                         n->set_property ("articulations", arts);
1445                 }
1446                 if (scm_is_number (check))
1447                 {
1448                         int q = scm_to_int (check);
1449                         n->set_property ("absolute-octave", scm_from_int (q-1));
1450                 }
1451
1452                 $$ = n->unprotect ();
1453         }
1454         | DRUM_PITCH post_events {
1455                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1456                 n->set_property ("duration", $2);
1457                 n->set_property ("drum-type", $1);
1458                 n->set_spot (@$);
1459
1460                 if (scm_is_pair ($2)) {
1461                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1462                         n->set_property ("articulations", arts);
1463                 }
1464                 $$ = n->unprotect ();
1465         }
1466         | music_function_chord_body {
1467                 Music *m = run_music_function (PARSER, $1);
1468                 m->set_spot (@$);
1469                 $$ = m->unprotect ();
1470         }
1471         ;
1472
1473 music_function_chord_body:
1474         MUSIC_FUNCTION {
1475                 $$ = scm_list_2 ($1, make_input (@$));
1476         }
1477         | music_function_musicless_prefix chord_body_element {
1478                 $$ = ly_append2 ($1, scm_list_1 ($2));
1479         }
1480         ;
1481
1482 music_function_event:
1483         music_function_musicless_prefix post_event {
1484                 $$ = ly_append2 ($1, scm_list_1 ($2));
1485         }
1486         ;
1487
1488 /*
1489 TODO: use code generation for this
1490 */
1491 music_function_musicless_prefix:
1492         MUSIC_FUNCTION_MUSIC {
1493                 $$ = scm_list_2 ($1, make_input (@$));
1494         }
1495         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument {
1496                 $$ = scm_list_3 ($1, make_input (@$), $2);
1497         }
1498         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument {
1499                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1500         }
1501         | MUSIC_FUNCTION_SCM_SCM_SCM_MUSIC function_scm_argument function_scm_argument function_scm_argument {
1502                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
1503         }
1504         | MUSIC_FUNCTION_SCM_SCM_SCM_SCM_MUSIC function_scm_argument function_scm_argument function_scm_argument function_scm_argument {
1505                 $$ = scm_list_n ($1, make_input (@$), $2, $3, $4, $5, SCM_UNDEFINED);
1506         }
1507         ;
1508
1509
1510 command_element:
1511         command_event {
1512                 Music *m = MY_MAKE_MUSIC ("EventChord");
1513                 m->set_property ("elements", scm_cons ($1, SCM_EOL));
1514                 Music *e = unsmob_music ($1);
1515                 e-> set_spot (@$);
1516                 m-> set_spot (@$);
1517                 $$ = m->unprotect ();
1518         }
1519         | SKIP duration_length {
1520                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1521                 skip->set_property ("duration", $2);
1522                 skip->set_spot (@$);
1523                 $$ = skip->unprotect ();
1524         }
1525         | E_BRACKET_OPEN {
1526                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1527                 m->set_property ("span-direction", scm_from_int (START));
1528                 m->set_spot (@$);
1529
1530                 Music *chord = MY_MAKE_MUSIC ("EventChord");
1531                 chord->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1532                 m->unprotect();
1533                 chord->set_spot (@$);
1534                 $$ = chord->unprotect ();
1535         }
1536         | E_BRACKET_CLOSE {
1537                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1538                 m->set_property ("span-direction", scm_from_int (STOP));
1539                 m->set_spot (@$);
1540
1541                 Music *chord = MY_MAKE_MUSIC ("EventChord");
1542                 chord->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1543                 chord->set_spot (@$);
1544                 m->unprotect ();
1545                 $$ = chord->unprotect ();
1546         }
1547         | E_BACKSLASH {
1548                 Music *m = MY_MAKE_MUSIC ("VoiceSeparator");
1549                 m->set_spot (@$);
1550                 $$ = m->unprotect ();
1551         }
1552         | '|'      {
1553                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
1554
1555                 Music *m = unsmob_music (pipe);
1556                 if (m)
1557                         m = m->clone ();
1558                 else
1559                         m = MY_MAKE_MUSIC ("BarCheck");
1560
1561                 m->set_spot (@$);
1562                 $$ = m->unprotect ();
1563         }
1564         | TRANSPOSITION pitch {
1565                 Pitch middle_c;
1566                 Pitch sounds_as_c = pitch_interval (*unsmob_pitch ($2), middle_c);
1567                 Music *m = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1568                                          sounds_as_c.smobbed_copy());
1569                 m->set_spot (@$);
1570                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1571                         m->unprotect (), SCM_EOL, false);
1572         }
1573         | PARTIAL duration_length       {
1574                 Moment m = - unsmob_duration ($2)->get_length ();
1575                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1576                 p->set_spot (@$);
1577                 SCM ps = p->unprotect ();
1578                 ps = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1579                                         ps, SCM_EOL, false);
1580                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1581                                         ps, SCM_EOL, false);
1582         }
1583
1584         | TIME_T fraction  {
1585                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1586
1587                 $$ = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1588         }
1589         | MARK scalar {
1590                 SCM proc = ly_lily_module_constant ("make-mark-set");
1591
1592                 $$ = scm_call_1 (proc, $2);
1593         }
1594         ;
1595
1596 command_event:
1597         E_TILDE {
1598                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent")->unprotect ();
1599         }
1600         | MARK DEFAULT  {
1601                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1602                 $$ = m->unprotect ();
1603         }
1604         | tempo_event {
1605                 $$ = $1;
1606         }
1607         | KEY DEFAULT {
1608                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1609                 $$ = key->unprotect ();
1610         }
1611         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1612
1613                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1614                 if (scm_ilength ($3) > 0)
1615                 {
1616                         key->set_property ("pitch-alist", $3);
1617                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1618                         key->transpose (* unsmob_pitch ($2));
1619                 } else {
1620                         PARSER->parser_error (@3, _ ("second argument must be pitch list"));
1621                 }
1622
1623                 $$ = key->unprotect ();
1624         }
1625         ;
1626
1627
1628 post_events:
1629         /* empty */ {
1630                 $$ = SCM_EOL;
1631         }
1632         | post_events post_event {
1633                 unsmob_music ($2)->set_spot (@2);
1634                 $$ = scm_cons ($2, $$);
1635         }
1636         ;
1637
1638 post_event:
1639         direction_less_event {
1640                 $$ = $1;
1641         }
1642         | '-' music_function_event {
1643                 Music *mus = run_music_function (PARSER, $2);
1644                 mus->set_spot (@1);
1645                 $$ = mus->unprotect ();
1646         }
1647         | HYPHEN {
1648                 if (!PARSER->lexer_->is_lyric_state ())
1649                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1650                 $$ = MY_MAKE_MUSIC ("HyphenEvent")->unprotect ();
1651         }
1652         | EXTENDER {
1653                 if (!PARSER->lexer_->is_lyric_state ())
1654                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1655                 $$ = MY_MAKE_MUSIC ("ExtenderEvent")->unprotect ();
1656         }
1657         | script_dir direction_reqd_event {
1658                 if ($1)
1659                 {
1660                         Music *m = unsmob_music ($2);
1661                         m->set_property ("direction", scm_from_int ($1));
1662                 }
1663                 $$ = $2;
1664         }
1665         | script_dir direction_less_event {
1666                 if ($1)
1667                 {
1668                         Music *m = unsmob_music ($2);
1669                         m->set_property ("direction", scm_from_int ($1));
1670                 }
1671                 $$ = $2;
1672         }
1673         | string_number_event
1674         ;
1675
1676 string_number_event:
1677         E_UNSIGNED {
1678                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1679                 s->set_property ("string-number", scm_from_int ($1));
1680                 s->set_spot (@$);
1681                 $$ = s->unprotect ();
1682         }
1683         ;
1684
1685 direction_less_char:
1686         '['  {
1687                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1688         }
1689         | ']'  {
1690                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1691         }
1692         | '~'  {
1693                 $$ = ly_symbol2scm ("tildeSymbol");
1694         }
1695         | '('  {
1696                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1697         }
1698         | ')'  {
1699                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1700         }
1701         | E_EXCLAMATION  {
1702                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1703         }
1704         | E_OPEN  {
1705                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1706         }
1707         | E_CLOSE  {
1708                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1709         }
1710         | E_ANGLE_CLOSE  {
1711                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1712         }
1713         | E_ANGLE_OPEN  {
1714                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1715         }
1716         ;
1717
1718 direction_less_event:
1719         direction_less_char {
1720                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
1721                 Music *m = 0;
1722                 if (unsmob_music (predefd))
1723                 {
1724                         m = unsmob_music (predefd)->clone ();
1725                 }
1726                 else
1727                 {
1728                         m = MY_MAKE_MUSIC ("Music");
1729                 }
1730                 m->set_spot (@$);
1731                 $$ = m->unprotect ();
1732         }
1733         | EVENT_IDENTIFIER      {
1734                 $$ = $1;
1735         }
1736         | tremolo_type  {
1737                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1738                a->set_spot (@$);
1739                a->set_property ("tremolo-type", scm_from_int ($1));
1740                $$ = a->unprotect ();
1741         }
1742         ;
1743
1744 direction_reqd_event:
1745         gen_text_def {
1746                 $$ = $1;
1747         }
1748         | script_abbreviation {
1749                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1750                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1751                 if (scm_is_string (s))
1752                         a->set_property ("articulation-type", s);
1753                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
1754                 $$ = a->unprotect ();
1755         }
1756         ;
1757
1758 octave_check:
1759         /**/ { $$ = SCM_EOL; }
1760         | '='  { $$ = scm_from_int (0); }
1761         | '=' sub_quotes { $$ = scm_from_int ($2); }
1762         | '=' sup_quotes { $$ = scm_from_int ($2); }
1763         ;
1764
1765 sup_quotes:
1766         '\'' {
1767                 $$ = 1;
1768         }
1769         | sup_quotes '\'' {
1770                 $$ ++;
1771         }
1772         ;
1773
1774 sub_quotes:
1775         ',' {
1776                 $$ = 1;
1777         }
1778         | sub_quotes ',' {
1779                 $$++;
1780         }
1781         ;
1782
1783 steno_pitch:
1784         NOTENAME_PITCH  {
1785                 $$ = $1;
1786         }
1787         | NOTENAME_PITCH sup_quotes     {
1788                 Pitch p = *unsmob_pitch ($1);
1789                 p = p.transposed (Pitch ($2,0,0));
1790                 $$ = p.smobbed_copy ();
1791         }
1792         | NOTENAME_PITCH sub_quotes      {
1793                 Pitch p =* unsmob_pitch ($1);
1794                 p = p.transposed (Pitch (-$2,0,0));
1795                 $$ = p.smobbed_copy ();
1796         }
1797         ;
1798
1799 /*
1800 ugh. duplication
1801 */
1802
1803 steno_tonic_pitch:
1804         TONICNAME_PITCH {
1805                 $$ = $1;
1806         }
1807         | TONICNAME_PITCH sup_quotes    {
1808                 Pitch p = *unsmob_pitch ($1);
1809                 p = p.transposed (Pitch ($2,0,0));
1810                 $$ = p.smobbed_copy ();
1811         }
1812         | TONICNAME_PITCH sub_quotes     {
1813                 Pitch p =* unsmob_pitch ($1);
1814
1815                 p = p.transposed (Pitch (-$2,0,0));
1816                 $$ = p.smobbed_copy ();
1817         }
1818         ;
1819
1820 pitch:
1821         steno_pitch {
1822                 $$ = $1;
1823         }
1824         ;
1825
1826 pitch_also_in_chords:
1827         pitch
1828         | steno_tonic_pitch
1829         ;
1830
1831 gen_text_def:
1832         full_markup {
1833                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1834                 t->set_property ("text", $1);
1835                 t->set_spot (@$);
1836                 $$ = t->unprotect ();
1837         }
1838         | string {
1839                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1840                 t->set_property ("text",
1841                         make_simple_markup ($1));
1842                 t->set_spot (@$);
1843                 $$ = t->unprotect ();
1844         }
1845         | DIGIT {
1846                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1847                 t->set_property ("digit", scm_from_int ($1));
1848                 t->set_spot (@$);
1849                 $$ = t->unprotect ();
1850         }
1851         ;
1852
1853 script_abbreviation:
1854         '^'             {
1855                 $$ = scm_makfrom0str ("Hat");
1856         }
1857         | '+'           {
1858                 $$ = scm_makfrom0str ("Plus");
1859         }
1860         | '-'           {
1861                 $$ = scm_makfrom0str ("Dash");
1862         }
1863         | '|'           {
1864                 $$ = scm_makfrom0str ("Bar");
1865         }
1866         | '>'           {
1867                 $$ = scm_makfrom0str ("Larger");
1868         }
1869         | '.'           {
1870                 $$ = scm_makfrom0str ("Dot");
1871         }
1872         | '_' {
1873                 $$ = scm_makfrom0str ("Underscore");
1874         }
1875         ;
1876
1877 script_dir:
1878         '_'     { $$ = DOWN; }
1879         | '^'   { $$ = UP; }
1880         | '-'   { $$ = CENTER; }
1881         ;
1882
1883
1884 absolute_pitch:
1885         steno_pitch     {
1886                 $$ = $1;
1887         }
1888         ;
1889
1890 duration_length:
1891         multiplied_duration {
1892                 $$ = $1;
1893         }
1894         ;
1895
1896 optional_notemode_duration:
1897         {
1898                 Duration dd = PARSER->default_duration_;
1899                 $$ = dd.smobbed_copy ();
1900         }
1901         | multiplied_duration   {
1902                 $$ = $1;
1903                 PARSER->default_duration_ = *unsmob_duration ($$);
1904         }
1905         ;
1906
1907 steno_duration:
1908         bare_unsigned dots              {
1909                 int len = 0;
1910                 if (!is_duration ($1))
1911                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
1912                 else
1913                         len = intlog2 ($1);
1914
1915                 $$ = Duration (len, $2).smobbed_copy ();
1916         }
1917         | DURATION_IDENTIFIER dots      {
1918                 Duration *d = unsmob_duration ($1);
1919                 Duration k (d->duration_log (), d->dot_count () + $2);
1920                 *d = k;
1921                 $$ = $1;
1922         }
1923         ;
1924
1925 multiplied_duration:
1926         steno_duration {
1927                 $$ = $1;
1928         }
1929         | multiplied_duration '*' bare_unsigned {
1930                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1931         }
1932         | multiplied_duration '*' FRACTION {
1933                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
1934
1935                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1936         }
1937         ;
1938
1939 fraction:
1940         FRACTION { $$ = $1; }
1941         | UNSIGNED '/' UNSIGNED {
1942                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
1943         }
1944         ;
1945
1946 dots:
1947         /* empty */     {
1948                 $$ = 0;
1949         }
1950         | dots '.' {
1951                 $$ ++;
1952         }
1953         ;
1954
1955 tremolo_type:
1956         ':'     {
1957                 $$ = 0;
1958         }
1959         | ':' bare_unsigned {
1960                 if (!is_duration ($2))
1961                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
1962                 $$ = $2;
1963         }
1964         ;
1965
1966 bass_number:
1967         DIGIT   {
1968                 $$ = scm_from_int ($1);
1969         }
1970         | UNSIGNED {
1971                 $$ = scm_from_int ($1);
1972         }
1973         | STRING { $$ = $1; }
1974         | full_markup { $$ = $1; }
1975         ;
1976
1977 figured_bass_alteration:
1978         '-'     { $$ = -2; }
1979         | '+'   { $$ = 2; }
1980         | '!'   { $$ = 0; }
1981         ;
1982
1983 bass_figure:
1984         FIGURE_SPACE {
1985                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1986                 $$ = bfr->self_scm ();
1987                 bfr->unprotect ();
1988                 bfr->set_spot (@1);
1989         }
1990         | bass_number  {
1991                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1992                 $$ = bfr->self_scm ();
1993
1994                 if (scm_is_number ($1))
1995                         bfr->set_property ("figure", $1);
1996                 else if (Text_interface::is_markup ($1))
1997                         bfr->set_property ("text", $1);
1998
1999                 bfr->unprotect ();
2000                 bfr->set_spot (@1);
2001         }
2002         | bass_figure ']' {
2003                 $$ = $1;
2004                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2005         }
2006         | bass_figure figured_bass_alteration {
2007                 Music *m = unsmob_music ($1);
2008                 if ($2) {
2009                         SCM salter = m->get_property ("alteration");
2010                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2011                         m->set_property ("alteration",
2012                                 scm_from_int (alter + $2));
2013                 } else {
2014                         m->set_property ("alteration", scm_from_int (0));
2015                 }
2016         }
2017         | bass_figure figured_bass_modification  {
2018                 Music *m = unsmob_music ($1);
2019                 if ($2 == ly_symbol2scm ("plus"))
2020                         {
2021                         m->set_property ("augmented", SCM_BOOL_T);
2022                         }
2023                 else if ($2 == ly_symbol2scm ("slash"))
2024                         {
2025                         m->set_property ("diminished", SCM_BOOL_T);
2026                         }
2027                 else if ($2 == ly_symbol2scm ("exclamation"))
2028                         {
2029                         m->set_property ("no-continuation", SCM_BOOL_T);
2030                         }
2031         }
2032         ;
2033
2034
2035 figured_bass_modification:
2036         E_PLUS          {
2037                 $$ = ly_symbol2scm ("plus");
2038         }
2039         | E_EXCLAMATION {
2040                 $$ = ly_symbol2scm ("exclamation");
2041         }
2042         | '/'           {
2043                 $$ = ly_symbol2scm ("slash");
2044         }
2045         ;
2046
2047 br_bass_figure:
2048         bass_figure {
2049                 $$ = $1;
2050         }
2051         | '[' bass_figure {
2052                 $$ = $2;
2053                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2054         }
2055         ;
2056
2057 figure_list:
2058         /**/            {
2059                 $$ = SCM_EOL;
2060         }
2061         | figure_list br_bass_figure {
2062                 $$ = scm_cons ($2, $1);
2063         }
2064         ;
2065
2066 figure_spec:
2067         FIGURE_OPEN figure_list FIGURE_CLOSE {
2068                 Music *m = MY_MAKE_MUSIC ("EventChord");
2069                 $2 = scm_reverse_x ($2, SCM_EOL);
2070                 m->set_property ("elements", $2);
2071                 $$ = m->self_scm ();
2072         }
2073         ;
2074
2075
2076 optional_rest:
2077         /**/   { $$ = 0; }
2078         | REST { $$ = 1; }
2079         ;
2080
2081 simple_element:
2082         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2083                 if (!PARSER->lexer_->is_note_state ())
2084                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
2085
2086                 Music *n = 0;
2087                 if ($6)
2088                         n = MY_MAKE_MUSIC ("RestEvent");
2089                 else
2090                         n = MY_MAKE_MUSIC ("NoteEvent");
2091
2092                 n->set_property ("pitch", $1);
2093                 n->set_property ("duration", $5);
2094
2095                 if (scm_is_number ($4))
2096                 {
2097                         int q = scm_to_int ($4);
2098                         n->set_property ("absolute-octave", scm_from_int (q-1));
2099                 }
2100
2101                 if ($3 % 2)
2102                         n->set_property ("cautionary", SCM_BOOL_T);
2103                 if ($2 % 2 || $3 % 2)
2104                         n->set_property ("force-accidental", SCM_BOOL_T);
2105
2106                 Music *v = MY_MAKE_MUSIC ("EventChord");
2107                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2108                 n->unprotect ();
2109
2110                 v->set_spot (@$);
2111                 n->set_spot (@$);
2112                 $$ = v->unprotect ();
2113         }
2114         | DRUM_PITCH optional_notemode_duration {
2115                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2116                 n->set_property ("duration", $2);
2117                 n->set_property ("drum-type", $1);
2118
2119                 Music *v = MY_MAKE_MUSIC ("EventChord");
2120                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2121                 n->unprotect ();
2122                 v->set_spot (@$);
2123                 n->set_spot (@$);
2124                 $$ = v->unprotect ();
2125
2126         }
2127         | figure_spec optional_notemode_duration {
2128                 Music *m = unsmob_music ($1);
2129                 m->set_spot (@$);
2130                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2131                 {
2132                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2133                 }
2134                 $$ = m->unprotect ();
2135         }
2136         | RESTNAME optional_notemode_duration           {
2137                 Music *ev = 0;
2138                 if (ly_scm2string ($1) == "s") {
2139                         /* Space */
2140                         ev = MY_MAKE_MUSIC ("SkipEvent");
2141                   }
2142                 else {
2143                         ev = MY_MAKE_MUSIC ("RestEvent");
2144
2145                     }
2146                 ev->set_property ("duration", $2);
2147                 ev->set_spot (@$);
2148                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2149                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2150                 velt->set_spot (@$);
2151
2152                 ev->unprotect();
2153
2154                 $$ = velt->unprotect ();
2155         }
2156         | MULTI_MEASURE_REST optional_notemode_duration         {
2157                 SCM proc = ly_lily_module_constant ("make-multi-measure-rest");
2158                 $$ = scm_call_2 (proc, $2, make_input (@$));
2159         }
2160         | lyric_element optional_notemode_duration      {
2161                 if (!PARSER->lexer_->is_lyric_state ())
2162                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2163
2164                 Music *levent = MY_MAKE_MUSIC ("LyricEvent");
2165                 levent->set_property ("text", $1);
2166                 levent->set_property ("duration",$2);
2167                 levent->set_spot (@$);
2168                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2169                 velt->set_property ("elements", scm_list_1 (levent->self_scm ()));
2170
2171                 $$= velt->unprotect ();
2172         }
2173         | new_chord {
2174                 if (!PARSER->lexer_->is_chord_state ())
2175                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
2176                 $$ = $1;
2177         }
2178         ;
2179
2180 lyric_element:
2181         lyric_markup {
2182                 $$ = $1;
2183         }
2184         | LYRICS_STRING {
2185                 $$ = $1;
2186         }
2187         ;
2188
2189 new_chord:
2190         steno_tonic_pitch optional_notemode_duration   {
2191                 $$ = make_chord ($1, $2, SCM_EOL);
2192         }
2193         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2194                 SCM its = scm_reverse_x ($4, SCM_EOL);
2195                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2196         }
2197         ;
2198
2199 chord_items:
2200         /**/ {
2201                 $$ = SCM_EOL;
2202         }
2203         | chord_items chord_item {
2204                 $$ = scm_cons ($2, $$);
2205         }
2206         ;
2207
2208 chord_separator:
2209         CHORD_COLON {
2210                 $$ = ly_symbol2scm ("chord-colon");
2211         }
2212         | CHORD_CARET {
2213                 $$ = ly_symbol2scm ("chord-caret");
2214         }
2215         | CHORD_SLASH steno_tonic_pitch {
2216                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2217         }
2218         | CHORD_BASS steno_tonic_pitch {
2219                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2220         }
2221         ;
2222
2223 chord_item:
2224         chord_separator {
2225                 $$ = $1;
2226         }
2227         | step_numbers {
2228                 $$ = scm_reverse_x ($1, SCM_EOL);
2229         }
2230         | CHORD_MODIFIER  {
2231                 $$ = $1;
2232         }
2233         ;
2234
2235 step_numbers:
2236         step_number { $$ = scm_cons ($1, SCM_EOL); }
2237         | step_numbers '.' step_number {
2238                 $$ = scm_cons ($3, $$);
2239         }
2240         ;
2241
2242 step_number:
2243         bare_unsigned {
2244                 $$ = make_chord_step ($1, 0);
2245         }
2246         | bare_unsigned '+' {
2247                 $$ = make_chord_step ($1, SHARP);
2248         }
2249         | bare_unsigned CHORD_MINUS {
2250                 $$ = make_chord_step ($1, FLAT);
2251         }
2252         ;
2253
2254 /*
2255         UTILITIES
2256
2257 TODO: should deprecate in favor of Scheme?
2258
2259  */
2260 number_expression:
2261         number_expression '+' number_term {
2262                 $$ = scm_sum ($1, $3);
2263         }
2264         | number_expression '-' number_term {
2265                 $$ = scm_difference ($1, $3);
2266         }
2267         | number_term
2268         ;
2269
2270 number_term:
2271         number_factor {
2272                 $$ = $1;
2273         }
2274         | number_factor '*' number_factor {
2275                 $$ = scm_product ($1, $3);
2276         }
2277         | number_factor '/' number_factor {
2278                 $$ = scm_divide ($1, $3);
2279         }
2280         ;
2281
2282 number_factor:
2283         '-'  number_factor { /* %prec UNARY_MINUS */
2284                 $$ = scm_difference ($2, SCM_UNDEFINED);
2285         }
2286         | bare_number
2287         ;
2288
2289
2290 bare_number:
2291         UNSIGNED        {
2292                 $$ = scm_from_int ($1);
2293         }
2294         | REAL          {
2295                 $$ = $1;
2296         }
2297         | NUMBER_IDENTIFIER             {
2298                 $$ = $1;
2299         }
2300         | REAL NUMBER_IDENTIFIER        {
2301                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2302         }
2303         | UNSIGNED NUMBER_IDENTIFIER    {
2304                 $$ = scm_from_double ($1 *scm_to_double ($2));
2305         }
2306         ;
2307
2308
2309 bare_unsigned:
2310         UNSIGNED {
2311                         $$ = $1;
2312         }
2313         | DIGIT {
2314                 $$ = $1;
2315         }
2316         ;
2317
2318 exclamations:
2319                 { $$ = 0; }
2320         | exclamations '!'      { $$ ++; }
2321         ;
2322
2323 questions:
2324                 { $$ = 0; }
2325         | questions '?' { $$ ++; }
2326         ;
2327
2328 /*
2329 This should be done more dynamically if possible.
2330 */
2331
2332 lyric_markup:
2333         LYRIC_MARKUP_IDENTIFIER {
2334                 $$ = $1;
2335         }
2336         | LYRIC_MARKUP
2337                 { PARSER->lexer_->push_markup_state (); }
2338         markup_top {
2339                 $$ = $3;
2340                 PARSER->lexer_->pop_state ();
2341         }
2342         ;
2343
2344 full_markup:
2345         MARKUP_IDENTIFIER {
2346                 $$ = $1;
2347         }
2348         | MARKUP
2349                 { PARSER->lexer_->push_markup_state (); }
2350         markup_top {
2351                 $$ = $3;
2352                 PARSER->lexer_->pop_state ();
2353         }
2354         ;
2355
2356 markup_top:
2357         markup_list {
2358                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2359         }
2360         | markup_head_1_list simple_markup      {
2361                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2362         }
2363         | simple_markup {
2364                 $$ = $1;
2365         }
2366         ;
2367
2368 markup_list:
2369         markup_composed_list {
2370                 $$ = $1;
2371         }
2372         | markup_braced_list {
2373                 $$ = $1;
2374         }
2375         ;
2376
2377 markup_composed_list:
2378         markup_head_1_list markup_braced_list {
2379                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2380
2381         }
2382         ;
2383
2384 markup_braced_list:
2385         '{' markup_braced_list_body '}' {
2386                 $$ = scm_reverse_x ($2, SCM_EOL);
2387         }
2388         ;
2389
2390 markup_braced_list_body:
2391         /* empty */     {  $$ = SCM_EOL; }
2392         | markup_braced_list_body markup {
2393                 $$ = scm_cons ($2, $1);
2394         }
2395         | markup_braced_list_body markup_list {
2396                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2397         }
2398         ;
2399
2400 markup_head_1_item:
2401         MARKUP_HEAD_MARKUP0     {
2402                 $$ = scm_list_1 ($1);
2403         }
2404         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2405                 $$ = scm_list_2 ($1, $2);
2406         }
2407         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2408                 $$ = scm_list_3 ($1, $2, $3);
2409         }
2410         ;
2411
2412 markup_head_1_list:
2413         markup_head_1_item      {
2414                 $$ = scm_list_1 ($1);
2415         }
2416         | markup_head_1_list markup_head_1_item {
2417                 $$ = scm_cons ($2, $1);
2418         }
2419         ;
2420
2421 simple_markup:
2422         STRING {
2423                 $$ = make_simple_markup ($1);
2424         }
2425         | MARKUP_IDENTIFIER {
2426                 $$ = $1;
2427         }
2428         | LYRIC_MARKUP_IDENTIFIER {
2429                 $$ = $1;
2430         }
2431         | STRING_IDENTIFIER {
2432                 $$ = $1;
2433         }
2434         | SCORE {
2435                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2436                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2437         } '{' score_body '}' {
2438                 Score * sc = $4;
2439                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2440                 sc->unprotect ();
2441                 PARSER->lexer_->pop_state ();
2442         }
2443         | MARKUP_HEAD_SCM0 embedded_scm {
2444                 $$ = scm_list_2 ($1, $2);
2445         }
2446         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2447                 $$ = scm_list_4 ($1, $2, $3, $4);
2448         }
2449         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2450                 $$ = scm_list_3 ($1, $2, $3);
2451         }
2452         | MARKUP_HEAD_EMPTY {
2453                 $$ = scm_list_1 ($1);
2454         }
2455         | MARKUP_HEAD_LIST0 markup_list {
2456                 $$ = scm_list_2 ($1,$2);
2457         }
2458         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2459                 $$ = scm_list_3 ($1, $2, $3);
2460         }
2461         ;
2462
2463 markup:
2464         markup_head_1_list simple_markup        {
2465                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2466                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2467         }
2468         | simple_markup {
2469                 $$ = $1;
2470         }
2471         ;
2472
2473 %%
2474
2475 void
2476 Lily_parser::set_yydebug (bool )
2477 {
2478 #if 0
2479         yydebug = 1;
2480 #endif
2481 }
2482
2483 void
2484 Lily_parser::do_yyparse ()
2485 {
2486         yyparse ((void*)this);
2487 }
2488
2489
2490
2491
2492
2493 /*
2494
2495 It is a little strange to have this function in this file, but
2496 otherwise, we have to import music classes into the lexer.
2497
2498 */
2499 int
2500 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2501 {
2502         if (scm_is_string (sid)) {
2503                 *destination = sid;
2504                 return STRING_IDENTIFIER;
2505         } else if (unsmob_book (sid)) {
2506                 *destination = unsmob_book (sid)->clone ()->self_scm ();
2507                 return BOOK_IDENTIFIER;
2508         } else if (scm_is_number (sid)) {
2509                 *destination = sid;
2510                 return NUMBER_IDENTIFIER;
2511         } else if (unsmob_context_def (sid)) {
2512                 *destination = unsmob_context_def (sid)->clone_scm ();
2513                 return CONTEXT_DEF_IDENTIFIER;
2514         } else if (unsmob_score (sid)) {
2515                 Score *score = new Score (*unsmob_score (sid));
2516                 *destination = score->self_scm ();
2517                 return SCORE_IDENTIFIER;
2518         } else if (Music *mus = unsmob_music (sid)) {
2519                 mus = mus->clone ();
2520                 *destination = mus->self_scm ();
2521                 unsmob_music (*destination)->
2522                         set_property ("origin", make_input (last_input_));
2523
2524                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2525                         != SCM_BOOL_F;
2526
2527                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2528         } else if (unsmob_duration (sid)) {
2529                 *destination = unsmob_duration (sid)->smobbed_copy ();
2530                 return DURATION_IDENTIFIER;
2531         } else if (unsmob_output_def (sid)) {
2532                 Output_def *p = unsmob_output_def (sid);
2533                 p = p->clone ();
2534
2535                 *destination = p->self_scm ();
2536                 return OUTPUT_DEF_IDENTIFIER;
2537         } else if (Text_interface::is_markup (sid)) {
2538                 *destination = sid;
2539                 if (is_lyric_state ())
2540                         return LYRIC_MARKUP_IDENTIFIER;
2541                 return MARKUP_IDENTIFIER;
2542         }
2543
2544         return -1;
2545 }
2546
2547 Music *
2548 property_op_to_music (SCM op)
2549 {
2550         Music *m = 0;
2551         SCM tag = scm_car (op);
2552         SCM symbol = scm_cadr (op);
2553         SCM args = scm_cddr (op);
2554         SCM grob_val = SCM_UNDEFINED;
2555         SCM grob_path = SCM_UNDEFINED;
2556         SCM val = SCM_UNDEFINED;
2557
2558         if (tag == ly_symbol2scm ("assign"))
2559                 {
2560                 m = MY_MAKE_MUSIC ("PropertySet");
2561                 val = scm_car (args);
2562                 }
2563         else if (tag == ly_symbol2scm ("unset"))
2564                 m = MY_MAKE_MUSIC ("PropertyUnset");
2565         else if (tag == ly_symbol2scm ("push"))
2566                 {
2567                 m = MY_MAKE_MUSIC ("OverrideProperty");
2568                 grob_val = scm_car (args);
2569                 grob_path = scm_cdr (args);
2570                 m->set_property ("pop-first", SCM_BOOL_T);
2571                 }
2572         else if (tag == ly_symbol2scm ("pop")) {
2573                 m = MY_MAKE_MUSIC ("RevertProperty");
2574                 grob_path = args;
2575                 }
2576
2577         m->set_property ("symbol", symbol);
2578
2579         if (val != SCM_UNDEFINED)
2580                 m->set_property ("value", val);
2581         if (grob_val != SCM_UNDEFINED)
2582                 m->set_property ("grob-value", grob_val);
2583         if (grob_path != SCM_UNDEFINED)
2584                 m->set_property ("grob-property-path", grob_path);
2585
2586         return m;
2587 }
2588
2589 SCM
2590 context_spec_music (SCM type, SCM id, SCM m, SCM ops, bool create_new)
2591 {
2592         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2593
2594         csm->set_property ("element", m);
2595
2596         csm->set_property ("context-type",
2597                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2598         csm->set_property ("property-operations", ops);
2599         if (create_new)
2600                 csm->set_property ("create-new", SCM_BOOL_T);
2601
2602         if (scm_is_string (id))
2603                 csm->set_property ("context-id", id);
2604         return csm->unprotect ();
2605 }
2606
2607 SCM
2608 get_next_unique_context_id ()
2609 {
2610         return scm_makfrom0str ("$uniqueContextId");
2611 }
2612
2613
2614 SCM
2615 get_next_unique_lyrics_context_id ()
2616 {
2617         static int new_context_count;
2618         char s[128];
2619         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2620         return scm_makfrom0str (s);
2621 }
2622
2623
2624 Music *
2625 run_music_function (Lily_parser *parser, SCM expr)
2626 {
2627         SCM func = scm_car (expr);
2628         Input *loc = unsmob_input (scm_cadr (expr));
2629         SCM args = scm_cddr (expr);
2630         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2631
2632         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2633         bool ok  = true;
2634
2635         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2636         {
2637                 parser->error_level_ = 1;
2638                 ok = false;
2639         }
2640
2641         SCM m = SCM_EOL;
2642         if (ok)
2643                 m = scm_apply_0 (func, scm_cons (parser->self_scm(),
2644                                                  scm_cdr (expr)));
2645
2646
2647         Music* retval = 0;
2648         if (unsmob_music (m))
2649                 {
2650                 retval = unsmob_music (m);
2651                 retval->protect ();
2652                 }
2653         else
2654                 {
2655                 if (ok)
2656                         loc->error (_ ("music head function must return Music object"));
2657                 retval = MY_MAKE_MUSIC ("Music");
2658                 }
2659         retval->set_spot (*loc);
2660         return retval;
2661 }
2662
2663 bool
2664 is_regular_identifier (SCM id)
2665 {
2666   string str = ly_scm2string (id);
2667   char const *s = str.c_str ();
2668
2669   bool v = true;
2670 #if 0
2671   isalpha (*s);
2672   s++;
2673 #endif
2674   while (*s && v)
2675    {
2676         v = v && isalnum (*s);
2677         s++;
2678    }
2679   return v;
2680 }
2681
2682
2683 SCM
2684 get_first_context_id (SCM type, Music *m)
2685 {
2686         SCM id = m->get_property ("context-id");
2687         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2688             && scm_is_string (m->get_property ("context-id"))
2689             && scm_c_string_length (id) > 0)
2690         {
2691                 return id;
2692         }
2693         return SCM_EOL;
2694 }
2695
2696 SCM
2697 make_simple_markup (SCM a)
2698 {
2699         return a;
2700 }
2701
2702 bool
2703 is_duration (int t)
2704 {
2705   return t && t == 1 << intlog2 (t);
2706 }
2707
2708 void
2709 set_music_properties (Music *p, SCM a)
2710 {
2711   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2712         p->internal_set_property (scm_caar (k), scm_cdar (k));
2713 }
2714
2715
2716 SCM
2717 make_chord_step (int step, int alter)
2718 {
2719         if (step == 7)
2720                 alter += FLAT;
2721
2722         while (step < 0)
2723                 step += 7;
2724         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2725         return m.smobbed_copy ();
2726 }
2727
2728
2729 SCM
2730 make_chord (SCM pitch, SCM dur, SCM modification_list)
2731 {
2732         SCM chord_ctor = ly_lily_module_constant ("construct-chord");
2733         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
2734
2735         unsmob_music (ch)->protect();
2736         return ch;
2737 }
2738
2739
2740 /* Todo: actually also use apply iso. call too ...  */
2741 bool
2742 ly_input_procedure_p (SCM x)
2743 {
2744         return ly_is_procedure (x)
2745                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2746 }
2747
2748 Music*
2749 set_property_music (SCM sym, SCM value)
2750 {
2751         Music *p = MY_MAKE_MUSIC ("PropertySet");
2752         p->set_property ("symbol", sym);
2753         p->set_property ("value", value);
2754         return p;
2755 }
2756
2757 SCM
2758 make_music_relative (Pitch start, SCM music)
2759 {
2760         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
2761         relative->set_property ("element", music);
2762
2763         Music *m = unsmob_music (music);
2764         Pitch last = m->to_relative_octave (start);
2765         if (lily_1_8_relative)
2766                 m->set_property ("last-pitch", last.smobbed_copy ());
2767         return relative->unprotect ();
2768 }
2769
2770 SCM
2771 make_lyric_combine_music (SCM name, SCM music)
2772 {
2773         Music *combine = MY_MAKE_MUSIC ("LyricCombineMusic");
2774         combine->set_property ("element", music);
2775         combine->set_property ("associated-context", name);
2776         return combine->unprotect ();
2777 }
2778
2779
2780 int
2781 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2782 {
2783         Lily_parser *pars = (Lily_parser*) v;
2784         Lily_lexer *lex = pars->lexer_;
2785
2786         lex->lexval = (void*) s;
2787         lex->lexloc = loc;
2788         lex->prepare_for_next_token ();
2789         return lex->yylex ();
2790 }