lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2003 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdio.h>
  57 #include <stdlib.h>
  58 #include <stdio.h>
  59
  60
  61 #include "scm-option.hh"
  62 #include "translator-def.hh"
  63 #include "lily-guile.hh"
  64 #include "misc.hh"
  65 #include "my-lily-lexer.hh"
  66 #include "paper-def.hh"
  67 #include "midi-def.hh"
  68 #include "main.hh"
  69 #include "file-path.hh"
  70 #include "warn.hh"
  71 #include "dimensions.hh"
  72 #include "my-lily-parser.hh"
  73 #include "score.hh"
  74 #include "input-file-results.hh"
  75 #include "input.hh"
  76 #include "lilypond-input-version.hh"
  77 #include "scm-hash.hh"
  78 #include "auto-change-iterator.hh"
  79 #include "ly-modules.hh"
  80 #include "music-sequence.hh"
  81 #include "input-smob.hh"
  82 #include "event.hh"
  83 #include "text-item.hh"
  84 #include "music-list.hh"
  85
  86
  87 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  88
  89
  90
  91 #define YYERROR_VERBOSE 1
  92
  93 My_lily_parser* my_lily_parser;
  94 #define YYPARSE_PARAM my_lily_parser
  95 #define YYLEX_PARAM my_lily_parser
  96 #define THIS\
  97         ((My_lily_parser *) my_lily_parser)
  98
  99 #define yyerror THIS->parser_error
 100
 101 /*
 102   Add symbols to the  TAGS field of a music object.
 103 */
 104
 105 void
 106 tag_music (Music*m,  SCM tag, Input ip)
 107 {
 108         SCM tags = m->get_mus_property ("tags");
 109         if (gh_symbol_p (tag))
 110                 tags = scm_cons (tag, tags);
 111         else if (gh_list_p (tag))
 112                 tags = gh_append2 (tag, tags);
 113         else
 114                 ip.warning (_("Tag must be symbol or list of symbols."));
 115
 116         m->set_mus_property ("tags", tags);
 117 }
 118
 119
 120
 121 bool
 122 regular_identifier_b (SCM id)
 123 {
 124   String str = ly_scm2string (id);
 125   char const *s = str.to_str0 () ;
 126
 127   bool v = true;
 128   while (*s && v)
 129    {
 130         v = v && isalpha (*s);
 131         s++;
 132    }
 133   return v;
 134 }
 135
 136 SCM
 137 make_simple_markup (SCM a)
 138 {
 139         static SCM simple;
 140         if (!simple)
 141         simple = scm_c_eval_string ("simple-markup");
 142
 143         return scm_list_n (simple, a, SCM_UNDEFINED);
 144 }
 145
 146
 147 bool
 148 is_duration_b (int t)
 149 {
 150   return t && t == 1 << intlog2 (t);
 151 }
 152
 153 void
 154 set_music_properties (Music *p, SCM a)
 155 {
 156   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 157         {
 158         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 159         }
 160 }
 161
 162 SCM
 163 make_chord_step (int step, int alter)
 164 {
 165         if (step == 7)
 166                 alter--;
 167
 168         /* ugh: fucks up above 13 */
 169         Pitch m(step > 7 ? 1 : 0,(step - 1) % 7, alter);
 170         return m.smobbed_copy ();
 171 }
 172
 173
 174 SCM
 175 make_chord (SCM pitch, SCM dur, SCM modification_list)
 176 {
 177         static SCM chord_ctor;
 178         if (!chord_ctor)
 179                 chord_ctor= scm_c_eval_string ("construct-chord");
 180         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 181         scm_gc_protect_object (ch);
 182         return ch;
 183 }
 184
 185 /*
 186   Todo: actually also use apply iso. call too ...
 187 */
 188 bool
 189 ly_input_procedure_p (SCM x)
 190 {
 191         return gh_procedure_p (x)
 192                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 193 }
 194
 195 Music*
 196 set_property_music (SCM sym, SCM value)
 197 {
 198         Music * p = MY_MAKE_MUSIC("PropertySet");
 199         p->set_mus_property ("symbol", sym);
 200         p->set_mus_property ("value", value);
 201         return p;
 202 }
 203
 204 %}
 205
 206 /* We use SCMs to do strings, because it saves us the trouble of
 207 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 208 of the parse stack onto the heap. */
 209
 210
 211 %union {
 212         String * string;
 213     Music *music;
 214     Score *score;
 215     Music_output_def * outputdef;
 216     SCM scm;
 217     int i;
 218 }
 219 %{
 220
 221 int
 222 yylex (YYSTYPE *s,  void * v)
 223 {
 224         My_lily_parser   *pars = (My_lily_parser*) v;
 225         My_lily_lexer * lex = pars->lexer_;
 226
 227         lex->lexval = (void*) s;
 228         lex->prepare_for_next_token();
 229         return lex->yylex ();
 230 }
 231
 232
 233 %}
 234
 235 %pure_parser
 236
 237
 238 %token ACCEPTS
 239 %token ADDLYRICS
 240 %token ALIAS
 241 %token ALTERNATIVE
 242 %token APPLY
 243 %token APPLYCONTEXT
 244 %token APPLYOUTPUT
 245 %token AUTOCHANGE
 246 %token BAR
 247 %token BREATHE
 248 %token CHORDMODIFIERS
 249 %token CHORDS
 250 %token LESSLESS
 251 %token MOREMORE
 252 %token CLEF
 253 %token COMMANDSPANREQUEST
 254 %token CONSISTS
 255 %token CONSISTSEND
 256 %token CONTEXT
 257 %token DEFAULT
 258 %token DENIES
 259 %token DESCRIPTION
 260 %token EXTENDER
 261 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 262 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 263 %token GRACE
 264 %token ACCIACCATURA
 265 %token APPOGGIATURA
 266 %token GROBDESCRIPTIONS
 267 %token HEADER
 268 %token HYPHEN
 269 %token INVALID
 270 %token KEY
 271 %token LYRICS
 272 %token MARK
 273 %token MIDI
 274 %token MULTI_MEASURE_REST
 275 %token NAME
 276 %token NEWCONTEXT
 277 %token NOTES
 278 %token OCTAVE
 279 %token ONCE
 280 %token OVERRIDE SET REVERT
 281 %token PAPER
 282 %token PARTCOMBINE
 283 %token PARTIAL
 284 %token PITCHNAMES
 285 %token PROPERTY
 286 %token RELATIVE
 287 %token REMOVE
 288 %token REPEAT
 289 %token REST
 290 %token SCM_T
 291 %token SCORE
 292 %token SEQUENTIAL
 293 %token SIMULTANEOUS
 294 %token SKIP
 295 %token SPANREQUEST
 296 %token TAG
 297 %token TEMPO
 298 %token TIMES
 299 %token TIME_T
 300 %token TRANSLATOR
 301 %token TRANSPOSE
 302 %token TYPE
 303 %token UNSET
 304
 305
 306 /* escaped */
 307 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 308 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 309 %token E_BACKSLASH
 310 %token <i> E_UNSIGNED
 311 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 312 %token FIGURE_SPACE
 313
 314 %type <i>       exclamations questions dots optional_rest
 315 %type <i>        bass_mod
 316 %type <scm>     grace_head
 317 %type <scm>     lyric_element
 318 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 319 %token <i>      DIGIT
 320 %token <scm>    NOTENAME_PITCH
 321 %token <scm>    TONICNAME_PITCH
 322 %token <scm>    CHORDMODIFIER_PITCH
 323 %token <scm>    DURATION_IDENTIFIER
 324 %token <scm>    FRACTION
 325 %token <id>     IDENTIFIER
 326 %token <scm>    CHORDNAMES
 327
 328 %token <scm> CHORD_MODIFIER
 329
 330 %token <scm>    SCORE_IDENTIFIER
 331 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 332 %token <scm>    NUMBER_IDENTIFIER
 333 %token <scm>    EVENT_IDENTIFIER
 334 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 335 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 336 %token <scm>    RESTNAME
 337 %token <scm>    STRING
 338 %token <scm>    SCM_T
 339 %token <i>      UNSIGNED
 340 %token <scm>   REAL
 341
 342 %token MARKUP
 343 %token <scm> MARKUP_HEAD_MARKUP0
 344 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 345 %token <scm> MARKUP_HEAD_SCM0
 346 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 347 %token <scm> MARKUP_HEAD_SCM0_SCM1
 348 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 349 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 350
 351 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 352 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 353
 354 %type <outputdef> output_def
 355 %type <scm>     lilypond_header lilypond_header_body
 356 %type <music>   open_event close_event
 357 %type <i>       sub_quotes sup_quotes
 358 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 359 %type <music>   Repeated_music
 360 %type <scm>     Alternative_music
 361 %type <i>       tremolo_type
 362 %type <i>       bare_int  bare_unsigned
 363 %type <i>       script_dir
 364 %type <scm>     identifier_init
 365
 366 %type <music> note_chord_element chord_body chord_body_element
 367 %type <scm>  chord_body_elements
 368 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 369
 370 %type <scm>   post_events
 371 %type <music> gen_text_def direction_less_event direction_reqd_event
 372 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 373 %type <scm>    steno_tonic_pitch
 374 %type <scm>     duration_length fraction
 375
 376 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 377
 378 %type <scm>  embedded_scm scalar
 379 %type <music>   Music Sequential_music Simultaneous_music
 380 %type <music>   relative_music re_rhythmed_music part_combined_music
 381 %type <music>   property_def translator_change  simple_property_def
 382 %type <scm> Music_list
 383 %type <outputdef>  music_output_def_body
 384 %type <music> shorthand_command_req
 385 %type <music>   post_event tagged_post_event
 386 %type <music> command_req verbose_command_req
 387 %type <music>   extender_req
 388 %type <music> hyphen_req
 389 %type <music> string_number_event
 390 %type <scm>     string bare_number number_expression number_term number_factor
 391 %type <score>   score_block score_body
 392
 393 %type <scm>     translator_spec_block translator_spec_body
 394 %type <music>   tempo_event
 395 %type <scm> notenames_body notenames_block chordmodifiers_block
 396 %type <scm>     script_abbreviation
 397
 398
 399
 400 %left '-' '+'
 401
 402 /* We don't assign precedence to / and *, because we might need varied
 403 prec levels in different prods */
 404
 405 %left UNARY_MINUS
 406
 407 %%
 408
 409 lilypond:       /* empty */
 410         | lilypond toplevel_expression {}
 411         | lilypond assignment  { }
 412         | lilypond error {
 413                 THIS->error_level_  = 1;
 414         }
 415         | lilypond INVALID      {
 416                 THIS->error_level_  = 1;
 417         }
 418         ;
 419
 420 toplevel_expression:
 421         notenames_block                 {
 422                 THIS->lexer_->pitchname_tab_ =  $1;
 423         }
 424         | chordmodifiers_block                  {
 425                 THIS->lexer_->chordmodifier_tab_  = $1;
 426         }
 427         | lilypond_header {
 428                 THIS->input_file_->header_ = $1;
 429         }
 430         | score_block {
 431                 THIS->input_file_->scores_.push ($1);
 432         }
 433         | output_def {
 434                 if (dynamic_cast<Paper_def*> ($1))
 435                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultpaper"), $1->self_scm ());
 436                 else if (dynamic_cast<Midi_def*> ($1))
 437                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultmidi"), $1->self_scm ());
 438         }
 439         ;
 440
 441 embedded_scm:
 442         SCM_T
 443         | SCM_IDENTIFIER
 444         ;
 445
 446
 447 chordmodifiers_block:
 448         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 449         ;
 450
 451 notenames_block:
 452         PITCHNAMES notenames_body   {  $$ = $2; }
 453         ;
 454
 455 notenames_body:
 456         embedded_scm    {
 457           int i = scm_ilength ($1);
 458
 459           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 460           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 461                 SCM pt = ly_cdar (s);
 462                 scm_hashq_set_x (tab, ly_caar (s), pt);
 463           }
 464           $$ = tab;
 465         }
 466         ;
 467
 468 lilypond_header_body:
 469         {
 470                 $$ = ly_make_anonymous_module ();
 471                 THIS->lexer_->add_scope ($$);
 472         }
 473         | lilypond_header_body assignment  {
 474
 475         }
 476         ;
 477
 478 lilypond_header:
 479         HEADER '{' lilypond_header_body '}'     {
 480                 $$ = THIS->lexer_-> remove_scope();
 481         }
 482         ;
 483
 484
 485 /*
 486         DECLARATIONS
 487 */
 488 assignment:
 489         STRING {
 490                 THIS->push_spot ();
 491         }
 492         /* cont */ '=' identifier_init  {
 493
 494         /*
 495                 Should find generic way of associating input with objects.
 496         */
 497                 Input ip = THIS->pop_spot ();
 498
 499                 if (! regular_identifier_b ($1))
 500                 {
 501                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 502                 }
 503
 504                 THIS->lexer_->set_identifier ($1, $4);
 505
 506 /*
 507  TODO: devise standard for protection in parser.
 508
 509   The parser stack lives on the C-stack, which means that
 510 all objects can be unprotected as soon as they're here.
 511
 512 */
 513         }
 514         | embedded_scm { }
 515         ;
 516
 517
 518
 519 identifier_init:
 520         score_block {
 521                 $$ = $1->self_scm ();
 522                 scm_gc_unprotect_object ($$);
 523         }
 524         | full_markup {
 525                 $$ = $1;
 526         }
 527         | output_def {
 528                 $$ = $1->self_scm ();
 529                 scm_gc_unprotect_object ($$);
 530         }
 531         | translator_spec_block {
 532                 $$ = $1;
 533         }
 534         | Music  {
 535                 $$ = $1->self_scm ();
 536                 scm_gc_unprotect_object ($$);
 537         }
 538         | post_event {
 539                 $$ = $1->self_scm ();
 540                 scm_gc_unprotect_object ($$);
 541         }
 542         | number_expression {
 543                 $$ = $1;
 544         }
 545         | string {
 546                 $$ = $1;
 547         }
 548         | embedded_scm  {
 549                 $$ = $1;
 550         }
 551         ;
 552
 553 translator_spec_block:
 554         TRANSLATOR '{' translator_spec_body '}'
 555                 {
 556                 $$ = $3;
 557         }
 558         ;
 559
 560 translator_spec_body:
 561         TRANSLATOR_IDENTIFIER   {
 562                 $$ = $1;
 563                 unsmob_translator_def ($$)-> set_spot (THIS->here_input ());
 564         }
 565         | TYPE STRING   {
 566                 $$ = Translator_def::make_scm ();
 567                 Translator_def*td =  unsmob_translator_def ($$);
 568                 td->translator_group_type_ = $2;
 569                 td->set_spot (THIS->here_input ());
 570         }
 571         | translator_spec_body DESCRIPTION string  {
 572                 unsmob_translator_def ($$)->description_ = $3;
 573         }
 574         | translator_spec_body STRING '=' embedded_scm                  {
 575                 unsmob_translator_def ($$)->add_property_assign ($2, $4);
 576         }
 577         | translator_spec_body STRING OVERRIDE embedded_scm '=' embedded_scm {
 578                 unsmob_translator_def ($$)
 579                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 580         }
 581         | translator_spec_body STRING SET embedded_scm '=' embedded_scm {
 582                 unsmob_translator_def ($$)
 583                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 584         }
 585         | translator_spec_body STRING REVERT embedded_scm  {
 586           unsmob_translator_def ($$)->add_pop_property (
 587                 scm_string_to_symbol ($2), $4);
 588         }
 589         | translator_spec_body NAME STRING  {
 590                 unsmob_translator_def ($$)->type_name_ = scm_string_to_symbol ($3);
 591         }
 592         | translator_spec_body CONSISTS STRING  {
 593                 unsmob_translator_def ($$)->add_element ($3);
 594         }
 595         | translator_spec_body ALIAS STRING  {
 596                 Translator_def*td = unsmob_translator_def ($$);
 597                 td->type_aliases_ = scm_cons (scm_string_to_symbol ($3), td->type_aliases_);
 598         }
 599         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 600                 Translator_def*td = unsmob_translator_def($$);
 601                 // td->add_property_assign (ly_symbol2scm ("allGrobDescriptions"), $3);
 602                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p))
 603                         td->add_property_assign (scm_symbol_to_string (ly_caar (p)), ly_cdar (p));
 604         }
 605         | translator_spec_body CONSISTSEND STRING  {
 606                 unsmob_translator_def ($$)->add_last_element ( $3);
 607         }
 608         | translator_spec_body ACCEPTS STRING  {
 609                 unsmob_translator_def ($$)->set_acceptor (scm_string_to_symbol ($3), true);
 610         }
 611         | translator_spec_body DENIES STRING  {
 612                 unsmob_translator_def ($$)->set_acceptor (scm_string_to_symbol ($3), false);
 613         }
 614         | translator_spec_body REMOVE STRING  {
 615                 unsmob_translator_def ($$)->remove_element ($3);
 616         }
 617         ;
 618
 619 /*
 620         SCORE
 621 */
 622 score_block:
 623         SCORE {
 624                 THIS->push_spot ();
 625         }
 626         /*cont*/ '{' score_body '}'     {
 627                 THIS->pop_spot ();
 628                 $$ = $4;
 629                 if (!$$->defs_.size ())
 630                 {
 631                   Music_output_def *id =
 632                         unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 633                   $$->add_output (id ? id->clone () :  new Paper_def );
 634                 }
 635         }
 636         ;
 637
 638 score_body:
 639         Music   {
 640                 $$ = new Score;
 641
 642                 $$->set_spot (THIS->here_input ());
 643                 SCM m = $1->self_scm ();
 644                 scm_gc_unprotect_object (m);
 645
 646                 /*
 647                         guh.
 648                 */
 649                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 650                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 651                         m = gh_call1 (gh_car (check_funcs), m);
 652                 $$->music_ = m;
 653
 654         }
 655         | SCORE_IDENTIFIER {
 656                 $$ = unsmob_score ($1);
 657                 $$->set_spot (THIS->here_input ());
 658         }
 659         | score_body lilypond_header    {
 660                 $$->header_ = $2;
 661         }
 662         | score_body output_def {
 663                 $$->add_output ($2);
 664         }
 665         | score_body error {
 666
 667         }
 668         ;
 669
 670
 671 /*
 672         MIDI
 673 */
 674 output_def:
 675         music_output_def_body '}' {
 676                 $$ = $1;
 677                 THIS-> lexer_-> remove_scope ();
 678         }
 679         ;
 680
 681 music_output_def_body:
 682         MIDI '{'    {
 683                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 684
 685
 686                 Midi_def* p =0;
 687                 if (id)
 688                         p = dynamic_cast<Midi_def*> (id->clone ());
 689                 else
 690                         p = new Midi_def;
 691
 692                 $$ = p;
 693                 THIS->lexer_->add_scope (p->scope_);
 694         }
 695         | PAPER '{'     {
 696                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 697                   Paper_def *p = 0;
 698                 if (id)
 699                         p = dynamic_cast<Paper_def*> (id->clone ());
 700                 else
 701                         p = new Paper_def;
 702
 703                 THIS->lexer_->add_scope (p->scope_);
 704                 $$ = p;
 705         }
 706         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 707                 Music_output_def * o =  unsmob_music_output_def ($3);
 708                 $$ =o;
 709
 710                 THIS->lexer_->add_scope (o->scope_);
 711         }
 712         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 713                 Music_output_def * o =  unsmob_music_output_def ($3);
 714                 $$ = o;
 715
 716                 THIS->lexer_->add_scope (o->scope_);
 717         }
 718         | music_output_def_body assignment  {
 719
 720         }
 721         | music_output_def_body translator_spec_block   {
 722                 $$->assign_translator ($2);
 723         }
 724         | music_output_def_body tempo_event  {
 725                 /*
 726                         junk this ? there already is tempo stuff in
 727                         music.
 728                 */
 729                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 730                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 731                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 732                 if (md)
 733                         md->set_tempo (d->get_length (), m);
 734         }
 735         | music_output_def_body error {
 736
 737         }
 738         ;
 739
 740 tempo_event:
 741         TEMPO steno_duration '=' bare_unsigned  {
 742                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 743                 $$->set_mus_property ("tempo-unit", $2);
 744                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 745         }
 746         ;
 747
 748 /*
 749 The representation of a  list is the
 750
 751   (LIST . LAST-CONS)
 752
 753  to have  efficient append.
 754 */
 755 Music_list:
 756         /* empty */ {
 757                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 758         }
 759         | Music_list Music {
 760                 SCM s = $$;
 761                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 762                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 763                 if (gh_pair_p (ly_cdr (s)))
 764                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 765                 else
 766                         gh_set_car_x (s, c); /* set first cons */
 767                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 768         }
 769         | Music_list error {
 770         }
 771         ;
 772
 773
 774 Music:
 775         Simple_music
 776         | Composite_music
 777         ;
 778
 779 Alternative_music:
 780         /* empty */ {
 781                 $$ = SCM_EOL;
 782         }
 783         | ALTERNATIVE '{' Music_list '}' {
 784                 $$ = $3;
 785         }
 786         ;
 787
 788 Repeated_music:
 789         REPEAT string bare_unsigned Music Alternative_music
 790         {
 791                 Music *beg = $4;
 792                 int times = $3;
 793                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 794                 if (times < scm_ilength (alts)) {
 795                   unsmob_music (gh_car (alts))
 796                     ->origin ()->warning (
 797                     _("More alternatives than repeats.  Junking excess alternatives."));
 798                   alts = ly_truncate_list (times, alts);
 799                 }
 800
 801
 802                 static SCM proc;
 803                 if (!proc)
 804                         proc = scm_c_eval_string ("make-repeated-music");
 805
 806                 SCM mus = scm_call_1 (proc, $2);
 807                 scm_gc_protect_object (mus); // UGH.
 808                 Music *r =unsmob_music (mus);
 809                 if (beg)
 810                         {
 811                         r-> set_mus_property ("element", beg->self_scm ());
 812                         scm_gc_unprotect_object (beg->self_scm ());
 813                         }
 814                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 815
 816                 r-> set_mus_property ("elements",alts);
 817                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 818                         /*
 819                         we can not get durations and other stuff correct down the line, so we have to
 820                         add to the duration log here.
 821                         */
 822                         static SCM func;
 823
 824                         if (!func)
 825                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 826
 827                         int dots = ($3 % 3) ? 0 : 1;
 828                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 829
 830                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 831
 832                         if (seq) {
 833                                 int list_len =scm_ilength (seq->music_list ());
 834                                 if (list_len != 2)
 835                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 836                                 shift -= 1;
 837                                 r->compress (Moment (Rational (1,list_len)));
 838                                 }
 839                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 840
 841                 }
 842                 r->set_spot (*$4->origin ());
 843
 844                 $$ = r;
 845         }
 846         ;
 847
 848 Sequential_music:
 849         SEQUENTIAL '{' Music_list '}'           {
 850                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 851                 $$->set_mus_property ("elements", ly_car ($3));
 852                 $$->set_spot(THIS->here_input());
 853         }
 854         | '{' Music_list '}'            {
 855                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 856                 $$->set_mus_property ("elements", ly_car ($2));
 857                 $$->set_spot(THIS->here_input());
 858         }
 859         ;
 860
 861 Simultaneous_music:
 862         SIMULTANEOUS '{' Music_list '}'{
 863                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 864                 $$->set_mus_property ("elements", ly_car ($3));
 865                 $$->set_spot(THIS->here_input());
 866
 867         }
 868         | simul_open Music_list simul_close     {
 869                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 870                 $$->set_mus_property ("elements", ly_car ($2));
 871                 $$->set_spot(THIS->here_input());
 872         }
 873         ;
 874
 875 Simple_music:
 876         event_chord             { $$ = $1; }
 877         | APPLYOUTPUT embedded_scm {
 878                 if (!ly_input_procedure_p ($2))
 879                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 880                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 881                 $$->set_mus_property ("procedure", $2);
 882                 $$->set_spot (THIS->here_input());
 883         }
 884         | APPLYCONTEXT embedded_scm {
 885                 if (!ly_input_procedure_p ($2))
 886                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 887                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 888                 $$->set_mus_property ("procedure", $2);
 889                 $$->set_spot (THIS->here_input());
 890         }
 891         | MUSIC_IDENTIFIER {
 892                 $$ = unsmob_music ($1);
 893         }
 894         | property_def
 895         | translator_change
 896         ;
 897
 898
 899 grace_head:
 900         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 901         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 902         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 903         ;
 904
 905
 906 Composite_music:
 907         CONTEXT STRING Music    {
 908                 Music*csm =MY_MAKE_MUSIC("ContextSpeccedMusic");
 909
 910                 csm->set_mus_property ("element", $3->self_scm ());
 911                 scm_gc_unprotect_object ($3->self_scm ());
 912
 913                 csm->set_mus_property ("context-type", scm_string_to_symbol ($2));
 914                 csm->set_mus_property ("context-id", scm_makfrom0str (""));
 915
 916                 $$ = csm;
 917         }
 918         | AUTOCHANGE STRING Music       {
 919         Music*chm = MY_MAKE_MUSIC("AutoChangeMusic");
 920                 chm->set_mus_property ("element", $3->self_scm ());
 921                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_proc);
 922
 923                 scm_gc_unprotect_object ($3->self_scm ());
 924                 chm->set_mus_property ("what", scm_string_to_symbol ($2));
 925
 926                 $$ = chm;
 927                 chm->set_spot (*$3->origin ());
 928         }
 929         | grace_head Music {
 930 #if 1
 931         /*
 932                 The other version is for easier debugging  of
 933                 Sequential_music_iterator in combination with grace notes.
 934         */
 935
 936 /*
 937
 938 TODO: should distinguish between both grace types in the
 939 basic music objects too, since the meaning is different.
 940
 941 */
 942
 943                 String start_str = "start" + ly_scm2string ($1) + "Music";
 944                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 945
 946                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 947                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 948
 949                 Music *startm = unsmob_music (start);
 950                 Music *stopm = unsmob_music (stop);
 951
 952                 SCM ms = SCM_EOL;
 953                 if (stopm) {
 954                         stopm = stopm->clone ();
 955                         ms = scm_cons (stopm->self_scm (), ms);
 956                         scm_gc_unprotect_object (stopm->self_scm ());
 957                 }
 958                 ms = scm_cons ($2->self_scm (), ms);
 959                 scm_gc_unprotect_object ($2->self_scm());
 960                 if (startm) {
 961                         startm = startm->clone ();
 962                         ms = scm_cons (startm->self_scm () , ms);
 963                         scm_gc_unprotect_object (startm->self_scm ());
 964                 }
 965
 966
 967                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 968                 seq->set_mus_property ("elements", ms);
 969
 970
 971                 $$ = MY_MAKE_MUSIC("GraceMusic");
 972                 $$->set_mus_property ("element", seq->self_scm ());
 973                 scm_gc_unprotect_object (seq->self_scm ());
 974 #else
 975                 $$ = MY_MAKE_MUSIC("GraceMusic");
 976                 $$->set_mus_property ("element", $2->self_scm ());
 977                 scm_gc_unprotect_object ($2->self_scm ());
 978 #endif
 979         }
 980         | CONTEXT string '=' string Music {
 981                 Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
 982
 983                 csm->set_mus_property ("element", $5->self_scm ());
 984                 scm_gc_unprotect_object ($5->self_scm ());
 985
 986                 csm->set_mus_property ("context-type", scm_string_to_symbol ($2));
 987                 csm->set_mus_property ("context-id", $4);
 988
 989                 $$ = csm;
 990         }
 991         | NEWCONTEXT string Music {
 992                 static int new_context_count;
 993
 994                 Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
 995
 996                 csm->set_mus_property ("element", $3->self_scm ());
 997                 scm_gc_unprotect_object ($3->self_scm ());
 998
 999                 csm->set_mus_property ("context-type", scm_string_to_symbol ($2));
1000
1001                 char s[1024];
1002                 snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
1003
1004                 SCM new_id = scm_makfrom0str (s);
1005                 csm->set_mus_property ("context-id", new_id);
1006                 $$ = csm;
1007         }
1008         | TIMES {
1009                 THIS->push_spot ();
1010         }
1011         /* CONTINUED */
1012                 fraction Music
1013
1014         {
1015                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
1016                 Music *mp = $4;
1017
1018                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
1019                 $$->set_spot (THIS->pop_spot ());
1020
1021                 $$->set_mus_property ("element", mp->self_scm ());
1022                 scm_gc_unprotect_object (mp->self_scm ());
1023                 $$->set_mus_property ("numerator", gh_int2scm (n));
1024                 $$->set_mus_property ("denominator", gh_int2scm (d));
1025                 $$->compress (Moment (Rational (n,d)));
1026
1027         }
1028         | Repeated_music                { $$ = $1; }
1029         | Simultaneous_music            { $$ = $1; }
1030         | Sequential_music              { $$ = $1; }
1031         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1032                 $$ = MY_MAKE_MUSIC("TransposedMusic");
1033                 Music *p = $4;
1034                 Pitch from = *unsmob_pitch ($2);
1035                 Pitch to = *unsmob_pitch ($3);
1036
1037                 p->transpose (interval (from, to));
1038                 $$->set_mus_property ("element", p->self_scm ());
1039                 scm_gc_unprotect_object (p->self_scm ());
1040         }
1041         | APPLY embedded_scm Music  {
1042                 if (!ly_input_procedure_p ($2))
1043                         {
1044                         THIS->parser_error (_ ("\\apply takes function argument"));
1045                         $$ = $3;
1046                         }
1047                 else
1048                         {
1049                         SCM ret = gh_call1 ($2, $3->self_scm ());
1050                         Music *m = unsmob_music (ret);
1051                         if (!m) {
1052                                 THIS->parser_error ("\\apply must return a Music");
1053                                 m = MY_MAKE_MUSIC("Music");
1054                                 }
1055                         $$ = m;
1056                         }
1057         }
1058         | NOTES
1059                 { THIS->lexer_->push_note_state (); }
1060         Music
1061                 { $$ = $3;
1062                   THIS->lexer_->pop_state ();
1063                 }
1064         | FIGURES
1065                 { THIS->lexer_->push_figuredbass_state (); }
1066         Music
1067                 {
1068                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1069                   chm->set_mus_property ("element", $3->self_scm ());
1070                   $$ = chm;
1071                   scm_gc_unprotect_object ($3->self_scm());
1072
1073                   THIS->lexer_->pop_state ();
1074         }
1075         | CHORDS
1076                 { THIS->lexer_->push_chord_state (); }
1077         Music
1078                 {
1079                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1080                   chm->set_mus_property ("element", $3->self_scm ());
1081                   scm_gc_unprotect_object ($3->self_scm());
1082                   $$ = chm;
1083
1084                   THIS->lexer_->pop_state ();
1085         }
1086         | LYRICS
1087                 { THIS->lexer_->push_lyric_state (); }
1088         Music
1089                 {
1090                   $$ = $3;
1091                   THIS->lexer_->pop_state ();
1092         }
1093         | relative_music        { $$ = $1; }
1094         | re_rhythmed_music     { $$ = $1; }
1095         | part_combined_music   { $$ = $1; }
1096         | TAG embedded_scm Music {
1097                 tag_music ($3, $2, THIS->here_input ());
1098                 $$ = $3;
1099         }
1100         ;
1101
1102 relative_music:
1103         RELATIVE absolute_pitch Music {
1104                 Music * p = $3;
1105                 Pitch pit = *unsmob_pitch ($2);
1106                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1107
1108                 $$->set_mus_property ("element", p->self_scm ());
1109                 scm_gc_unprotect_object (p->self_scm ());
1110
1111
1112                 Pitch retpitch = p->to_relative_octave (pit);
1113                 if (lily_1_8_relative)
1114                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1115         }
1116         ;
1117
1118 re_rhythmed_music:
1119         ADDLYRICS Music Music {
1120         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1121           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1122           scm_gc_unprotect_object ($3->self_scm ());
1123           scm_gc_unprotect_object ($2->self_scm ());
1124           $$ = l;
1125         }
1126         ;
1127
1128 part_combined_music:
1129         PARTCOMBINE STRING Music Music {
1130                 Music * p= MY_MAKE_MUSIC("PartCombineMusic");
1131                 p->set_mus_property ("what", scm_string_to_symbol ($2));
1132                 p->set_mus_property ("elements", gh_list ($3->self_scm (),$4->self_scm (), SCM_UNDEFINED));
1133
1134                 scm_gc_unprotect_object ($3->self_scm ());
1135                 scm_gc_unprotect_object ($4->self_scm ());
1136
1137                 $$ = p;
1138         }
1139         ;
1140
1141 translator_change:
1142         TRANSLATOR STRING '=' STRING  {
1143                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1144                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1145                 t-> set_mus_property ("change-to-id", $4);
1146
1147                 $$ = t;
1148                 $$->set_spot (THIS->here_input ());
1149         }
1150         ;
1151
1152 property_def:
1153         simple_property_def
1154         | ONCE simple_property_def {
1155                 $$ = $2;
1156                 SCM e = $2->get_mus_property ("element");
1157                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1158         }
1159         ;
1160
1161 simple_property_def:
1162         PROPERTY STRING '.' STRING '='  scalar {
1163                 Music *t = set_property_music (scm_string_to_symbol ($4), $6);
1164                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1165
1166                 csm->set_mus_property ("element", t->self_scm ());
1167                 scm_gc_unprotect_object (t->self_scm ());
1168
1169                 $$ = csm;
1170                 $$->set_spot (THIS->here_input ());
1171
1172                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1173         }
1174         | PROPERTY STRING '.' STRING UNSET {
1175
1176                 Music *t = MY_MAKE_MUSIC("PropertyUnset");
1177                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1178
1179                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1180                 csm->set_mus_property ("element", t->self_scm ());
1181                 scm_gc_unprotect_object (t->self_scm ());
1182
1183                 $$ = csm;
1184                 $$->set_spot (THIS->here_input ());
1185
1186                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1187         }
1188         | PROPERTY STRING '.' STRING SET embedded_scm '=' embedded_scm {
1189                 bool autobeam
1190                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1191                 bool itc = internal_type_checking_global_b;
1192                 Music *t = MY_MAKE_MUSIC("OverrideProperty");
1193                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1194                 t->set_mus_property ("pop-first", SCM_BOOL_T);
1195                 if (autobeam)
1196                         internal_type_checking_global_b = false;
1197                 t->set_mus_property ("grob-property", $6);
1198                 if (autobeam)
1199                         internal_type_checking_global_b = itc;
1200                 t->set_mus_property ("grob-value", $8);
1201
1202                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1203                 csm->set_mus_property ("element", t->self_scm ());
1204                 scm_gc_unprotect_object (t->self_scm ());
1205                 $$ = csm;
1206                 $$->set_spot (THIS->here_input ());
1207
1208                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1209         }
1210         | PROPERTY STRING '.' STRING OVERRIDE
1211                 embedded_scm '=' embedded_scm
1212         {
1213                 /*
1214                         UGH UGH UGH UGH.
1215                 */
1216                 bool autobeam
1217                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1218                 bool itc = internal_type_checking_global_b;
1219
1220                 Music *t = MY_MAKE_MUSIC("OverrideProperty");
1221                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1222                 if (autobeam)
1223                         internal_type_checking_global_b = false;
1224                 t->set_mus_property ("grob-property", $6);
1225                 t->set_mus_property ("grob-value", $8);
1226                 if (autobeam)
1227                         internal_type_checking_global_b = itc;
1228
1229                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1230                 csm->set_mus_property ("element", t->self_scm ());
1231                 scm_gc_unprotect_object (t->self_scm ());
1232
1233                 $$ = csm;
1234                 $$->set_spot (THIS->here_input ());
1235
1236                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1237
1238         }
1239         | PROPERTY STRING '.' STRING REVERT embedded_scm {
1240                 Music *t = MY_MAKE_MUSIC("RevertProperty");
1241                 bool autobeam
1242                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1243                 bool itc = internal_type_checking_global_b;
1244
1245                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1246                 if (autobeam)
1247                         internal_type_checking_global_b = false;
1248                 t->set_mus_property ("grob-property", $6);
1249                 if (autobeam)
1250                         internal_type_checking_global_b = itc;
1251
1252                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1253                 csm->set_mus_property ("element", t->self_scm ());
1254                 scm_gc_unprotect_object (t->self_scm ());
1255
1256                 $$ = csm;
1257                 $$->set_spot (THIS->here_input ());
1258
1259                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1260         }
1261         ;
1262
1263
1264 scalar:
1265         string          { $$ = $1; }
1266         | bare_int      { $$ = gh_int2scm ($1); }
1267         | embedded_scm  { $$ = $1; }
1268         | full_markup {  $$ = $1; }
1269         | DIGIT { $$ = gh_int2scm ($1); }
1270         ;
1271
1272
1273
1274 /*
1275 This is a trick:
1276
1277 Adding pre_events to the simple_element
1278 makes the choice between
1279
1280   string:  STRING
1281
1282 and
1283
1284   simple_element: STRING
1285
1286 a single shift/reduction conflict.
1287
1288 nevertheless, this is not very clean, and we should find a different
1289 solution.
1290
1291 */
1292 pre_events: {
1293                 THIS->push_spot ();
1294         }
1295         ;
1296
1297 event_chord:
1298         pre_events simple_element post_events   {
1299                 SCM elts = $2-> get_mus_property ("elements");
1300
1301                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1302
1303                 $2->set_mus_property ("elements", elts);
1304                 $$ = $2;
1305         }
1306         | command_element
1307         | note_chord_element
1308         ;
1309
1310
1311 note_chord_element:
1312         chord_body optional_notemode_duration post_events
1313         {
1314                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1315                 SCM es = $1->get_mus_property ("elements");
1316                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1317
1318                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1319                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1320                 es = gh_append2 (es, postevs);
1321
1322                 $1-> set_mus_property ("elements", es);
1323                 $$ = $1;
1324         }
1325         ;
1326
1327 chord_open: '<'
1328         ;
1329
1330 chord_close: '>'
1331         ;
1332
1333 simul_open: LESSLESS
1334         ;
1335
1336 simul_close: MOREMORE
1337         ;
1338
1339 chord_body:
1340         chord_open chord_body_elements chord_close
1341         {
1342                 $$ = MY_MAKE_MUSIC("EventChord");
1343                 $$->set_mus_property ("elements",
1344                         scm_reverse_x ($2, SCM_EOL));
1345         }
1346         ;
1347
1348 chord_body_elements:
1349         /* empty */             { $$ = SCM_EOL; }
1350         | chord_body_elements chord_body_element {
1351                 $$ = gh_cons ($2->self_scm(), $1);
1352                 scm_gc_unprotect_object ($2->self_scm());
1353         }
1354         ;
1355
1356 chord_body_element:
1357         pitch exclamations questions post_events
1358         {
1359                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1360                 n->set_mus_property ("pitch", $1);
1361                 if ($3 % 2)
1362                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1363                 if ($2 % 2 || $3 % 2)
1364                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1365
1366                 SCM arts = scm_reverse_x ($4, SCM_EOL);
1367                 n->set_mus_property ("articulations", arts);
1368
1369                 $$ = n;
1370         }
1371         ;
1372
1373 command_element:
1374         command_req {
1375                 $$ = MY_MAKE_MUSIC("EventChord");
1376                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1377                 scm_gc_unprotect_object ($1->self_scm());
1378
1379                 $$-> set_spot (THIS->here_input ());
1380                 $1-> set_spot (THIS->here_input ());
1381         }
1382         | OCTAVE { THIS->push_spot (); }
1383           pitch {
1384                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1385                 $$ = l;
1386                 $$->set_spot (THIS->pop_spot ());
1387                 $$->set_mus_property ("pitch", $3);
1388         }
1389         | E_LEFTSQUARE {
1390                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1391                 l->set_mus_property ("span-direction", gh_int2scm (START));
1392                 l->set_spot (THIS->here_input ());
1393
1394                 $$ = MY_MAKE_MUSIC("EventChord");
1395                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1396                 scm_gc_unprotect_object (l->self_scm());
1397                 $$->set_spot (THIS->here_input ());
1398         }
1399         | E_RIGHTSQUARE {
1400                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1401                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1402                 l->set_spot (THIS->here_input ());
1403
1404                 $$ = MY_MAKE_MUSIC("EventChord");
1405                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1406                 $$->set_spot (THIS->here_input ());
1407                 scm_gc_unprotect_object (l->self_scm());
1408         }
1409         | E_BACKSLASH {
1410                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1411                 $$->set_spot (THIS->here_input ());
1412         }
1413         | '|'      {
1414
1415                 $$ = MY_MAKE_MUSIC("BarCheck");
1416                 $$->set_spot (THIS->here_input ());
1417         }
1418         | BAR STRING                    {
1419                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1420
1421                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1422                 csm->set_mus_property ("element", t->self_scm ());
1423                 scm_gc_unprotect_object (t->self_scm ());
1424
1425                 $$ = csm;
1426                 $$->set_spot (THIS->here_input ());
1427
1428                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1429         }
1430         | PARTIAL duration_length       {
1431                 Moment m = - unsmob_duration ($2)->get_length ();
1432                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1433
1434                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1435                 sp->set_mus_property ("element", p->self_scm ());
1436                 scm_gc_unprotect_object (p->self_scm ());
1437
1438                 $$ =sp ;
1439                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1440         }
1441         | CLEF STRING  {
1442                 static SCM proc ;
1443                 if (!proc)
1444                         proc = scm_c_eval_string ("make-clef-set");
1445
1446                 SCM result = scm_call_1 (proc, $2);
1447                 scm_gc_protect_object (result);
1448                 $$ = unsmob_music (result);
1449         }
1450         | TIME_T fraction  {
1451                 static SCM proc;
1452                 if (!proc)
1453                         proc = scm_c_eval_string ("make-time-signature-set");
1454
1455                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1456                 scm_gc_protect_object (result);
1457                 $$ = unsmob_music (result);
1458         }
1459         ;
1460
1461 command_req:
1462         shorthand_command_req   { $$ = $1; }
1463         | verbose_command_req   { $$ = $1; }
1464         ;
1465
1466 shorthand_command_req:
1467         extender_req {
1468                 $$ = $1;
1469         }
1470         | hyphen_req {
1471                 $$ = $1;
1472         }
1473         | BREATHE {
1474                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1475         }
1476         | E_TILDE {
1477                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1478         }
1479         ;
1480
1481 verbose_command_req:
1482         MARK DEFAULT  {
1483                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1484                 $$ = m;
1485         }
1486         | MARK scalar {
1487                 Music *m = MY_MAKE_MUSIC("MarkEvent");
1488                 m->set_mus_property ("label", $2);
1489                 $$ = m;
1490         }
1491         | SKIP duration_length {
1492                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1493                 skip->set_mus_property ("duration", $2);
1494
1495                 $$ = skip;
1496         }
1497         | tempo_event {
1498                 $$ = $1;
1499         }
1500         | KEY DEFAULT {
1501                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1502                 $$ = key;
1503         }
1504         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1505
1506                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1507                 if (scm_ilength ($3) > 0)
1508                 {
1509                         key->set_mus_property ("pitch-alist", $3);
1510                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1511                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1512                 } else {
1513                         THIS->parser_error (_("Second argument must be pitch list."));
1514                 }
1515
1516                 $$ = key;
1517         }
1518         ;
1519
1520 post_events:
1521         /* empty */ {
1522                 $$ = SCM_EOL;
1523         }
1524         | post_events post_event {
1525                 $2->set_spot (THIS->here_input ());
1526                 $$ = gh_cons ($2->self_scm(), $$);
1527                 scm_gc_unprotect_object ($2->self_scm());
1528         }
1529         | post_events tagged_post_event {
1530                 $2 -> set_spot (THIS->here_input ());
1531                 $$ = scm_cons ($2->self_scm(), $$);
1532                 scm_gc_unprotect_object ($2->self_scm());
1533         }
1534         ;
1535
1536
1537 tagged_post_event:
1538         '-' TAG embedded_scm post_event {
1539                 tag_music ($4, $3, THIS->here_input ());
1540                 $$ = $4;
1541         }
1542         ;
1543
1544 post_event:
1545         direction_less_event {
1546                 $$ = $1;
1547         }
1548         | script_dir direction_reqd_event {
1549                 if ($1)
1550                         $2->set_mus_property ("direction", gh_int2scm ($1));
1551                 $$ = $2;
1552         }
1553         | script_dir direction_less_event {
1554                 if ($1)
1555                         $2->set_mus_property ("direction", gh_int2scm ($1));
1556                 $$ = $2;
1557         }
1558         | string_number_event
1559         ;
1560
1561 string_number_event:
1562         E_UNSIGNED {
1563                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1564                 s->set_mus_property ("string-number",  gh_int2scm($1));
1565                 s->set_spot (THIS->here_input ());
1566                 $$ = s;
1567         }
1568         ;
1569
1570
1571 direction_less_event:
1572         '['  {
1573
1574
1575 /*
1576
1577 TODO: should take all these defs out of the parser, adn make use
1578 configurable, i.e.
1579
1580
1581 (set-articulation '~ "trill")
1582
1583 */
1584                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1585                 m->set_spot (THIS->here_input());
1586                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1587                 $$ = m;
1588         }
1589         | ']'  {
1590                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1591                 m->set_spot (THIS->here_input());
1592                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1593                 $$ = m;
1594         }
1595         | '~' {
1596                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1597                 m->set_spot (THIS->here_input());
1598                 $$ = m;
1599         }
1600         | close_event {
1601                 $$ = $1;
1602                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction", gh_int2scm (START));
1603         }
1604         | open_event {
1605                 $$ = $1;
1606                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction", gh_int2scm (STOP));
1607         }
1608         | EVENT_IDENTIFIER      {
1609                 $$ = unsmob_music ($1);
1610         }
1611         | tremolo_type  {
1612                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1613                a->set_spot (THIS->here_input ());
1614                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1615                $$ = a;
1616         }
1617         ;
1618
1619 direction_reqd_event:
1620         gen_text_def {
1621                 $$ = $1;
1622         }
1623         | script_abbreviation {
1624                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1625                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1626                 if (gh_string_p (s))
1627                         a->set_mus_property ("articulation-type", s);
1628                 else THIS->parser_error (_ ("Expecting string as script definition"));
1629                 $$ = a;
1630         }
1631         ;
1632
1633 sup_quotes:
1634         '\'' {
1635                 $$ = 1;
1636         }
1637         | sup_quotes '\'' {
1638                 $$ ++;
1639         }
1640         ;
1641
1642 sub_quotes:
1643         ',' {
1644                 $$ = 1;
1645         }
1646         | sub_quotes ',' {
1647                 $$ ++ ;
1648         }
1649         ;
1650
1651 steno_pitch:
1652         NOTENAME_PITCH  {
1653                 $$ = $1;
1654         }
1655         | NOTENAME_PITCH sup_quotes     {
1656                 Pitch p = *unsmob_pitch ($1);
1657                 p = p.transposed (Pitch ($2,0,0));
1658                 $$ = p.smobbed_copy ();
1659         }
1660         | NOTENAME_PITCH sub_quotes      {
1661                 Pitch p =* unsmob_pitch ($1);
1662                 p = p.transposed (Pitch (-$2,0,0));
1663                 $$ = p.smobbed_copy ();
1664         }
1665         ;
1666
1667 /*
1668 ugh. duplication
1669 */
1670
1671 steno_tonic_pitch:
1672         TONICNAME_PITCH {
1673                 $$ = $1;
1674         }
1675         | TONICNAME_PITCH sup_quotes    {
1676                 Pitch p = *unsmob_pitch ($1);
1677                 p = p.transposed (Pitch ($2,0,0));
1678                 $$ = p.smobbed_copy ();
1679         }
1680         | TONICNAME_PITCH sub_quotes     {
1681                 Pitch p =* unsmob_pitch ($1);
1682
1683                 p = p.transposed (Pitch (-$2,0,0));
1684                 $$ = p.smobbed_copy ();
1685         }
1686         ;
1687
1688 pitch:
1689         steno_pitch {
1690                 $$ = $1;
1691         }
1692         ;
1693
1694 pitch_also_in_chords:
1695         pitch
1696         | steno_tonic_pitch
1697         ;
1698
1699
1700
1701
1702
1703 extender_req:
1704         EXTENDER {
1705                 if (!THIS->lexer_->lyric_state_b ())
1706                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1707                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1708         }
1709         ;
1710
1711 hyphen_req:
1712         HYPHEN {
1713                 if (!THIS->lexer_->lyric_state_b ())
1714                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1715                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1716         }
1717         ;
1718
1719 close_event:
1720         '('     {
1721                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1722                 $$ = s;
1723                 s->set_spot (THIS->here_input());
1724         }
1725         | E_OPEN        {
1726                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1727                 $$ = s;
1728                 s->set_spot (THIS->here_input());
1729         }
1730         | E_SMALLER {
1731                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1732                 $$ = s;
1733                 s->set_spot (THIS->here_input());
1734         }
1735         | E_BIGGER {
1736                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1737                 $$ = s;
1738                 s->set_spot (THIS->here_input());
1739         }
1740         ;
1741
1742
1743 open_event:
1744         E_EXCLAMATION   {
1745                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1746                 s->set_spot (THIS->here_input());
1747
1748                 $$ = s;
1749         }
1750         | ')'   {
1751                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1752                 $$ = s;
1753                 s->set_spot (THIS->here_input());
1754
1755         }
1756         | E_CLOSE       {
1757                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1758                 $$ = s;
1759                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1760                 s->set_spot (THIS->here_input());
1761         }
1762         ;
1763
1764 gen_text_def:
1765         full_markup {
1766                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1767                 t->set_mus_property ("text", $1);
1768                 t->set_spot (THIS->here_input ());
1769                 $$ = t;
1770         }
1771         | string {
1772                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1773                 t->set_mus_property ("text", make_simple_markup ($1));
1774                 t->set_spot (THIS->here_input ());
1775                 $$ = t;
1776
1777         }
1778         | DIGIT {
1779                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1780                 t->set_mus_property ("digit",  gh_int2scm ($1));
1781                 t->set_spot (THIS->here_input ());
1782                 $$ = t;
1783         }
1784         ;
1785
1786 script_abbreviation:
1787         '^'             {
1788                 $$ = scm_makfrom0str ("Hat");
1789         }
1790         | '+'           {
1791                 $$ = scm_makfrom0str ("Plus");
1792         }
1793         | '-'           {
1794                 $$ = scm_makfrom0str ("Dash");
1795         }
1796         | '|'           {
1797                 $$ = scm_makfrom0str ("Bar");
1798         }
1799         | '>'           {
1800                 $$ = scm_makfrom0str ("Larger");
1801         }
1802         | '.'           {
1803                 $$ = scm_makfrom0str ("Dot");
1804         }
1805         | '_' {
1806                 $$ = scm_makfrom0str ("Underscore");
1807         }
1808         ;
1809
1810 script_dir:
1811         '_'     { $$ = DOWN; }
1812         | '^'   { $$ = UP; }
1813         | '-'   { $$ = CENTER; }
1814         ;
1815
1816
1817 absolute_pitch:
1818         steno_pitch     {
1819                 $$ = $1;
1820         }
1821         ;
1822
1823 duration_length:
1824         multiplied_duration {
1825                 $$ = $1;
1826         }
1827         ;
1828
1829 optional_notemode_duration:
1830         {
1831                 Duration dd = THIS->default_duration_;
1832                 $$ = dd.smobbed_copy ();
1833
1834                 THIS->beam_check ($$);
1835         }
1836         | multiplied_duration   {
1837                 $$ = $1;
1838                 THIS->default_duration_ = *unsmob_duration ($$);
1839
1840                 THIS->beam_check ($$);
1841         }
1842         ;
1843
1844 steno_duration:
1845         bare_unsigned dots              {
1846                 int l = 0;
1847                 if (!is_duration_b ($1))
1848                         THIS->parser_error (_f ("not a duration: %d", $1));
1849                 else
1850                         l =  intlog2 ($1);
1851
1852                 $$ = Duration (l, $2).smobbed_copy ();
1853         }
1854         | DURATION_IDENTIFIER dots      {
1855                 Duration *d =unsmob_duration ($1);
1856                 Duration k (d->duration_log (),d->dot_count () + $2);
1857
1858                 *d = k;
1859                 $$ = $1;
1860         }
1861         ;
1862
1863
1864
1865
1866 multiplied_duration:
1867         steno_duration {
1868                 $$ = $1;
1869         }
1870         | multiplied_duration '*' bare_unsigned {
1871                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1872         }
1873         | multiplied_duration '*' FRACTION {
1874                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1875
1876                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1877         }
1878         ;
1879
1880 fraction:
1881         FRACTION { $$ = $1; }
1882         | UNSIGNED '/' UNSIGNED {
1883                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1884         }
1885         ;
1886
1887 dots:
1888         /* empty */     {
1889                 $$ = 0;
1890         }
1891         | dots '.' {
1892                 $$ ++;
1893         }
1894         ;
1895
1896
1897 tremolo_type:
1898         ':'     {
1899                 $$ =0;
1900         }
1901         | ':' bare_unsigned {
1902                 if (!is_duration_b ($2))
1903                         THIS->parser_error (_f ("not a duration: %d", $2));
1904                 $$ = $2;
1905         }
1906         ;
1907
1908
1909
1910 /*****************************************************************
1911                 BASS FIGURES
1912 *****************************************************************/
1913 bass_number:
1914         DIGIT   {
1915                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1916         }
1917         | UNSIGNED {
1918                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1919         }
1920         | STRING { $$ =  $1; }
1921         ;
1922
1923 bass_mod:
1924         '-'     { $$ = -1; }
1925         | '+'   { $$ = 1; }
1926         | '!'   { $$ = 0; }
1927         ;
1928
1929 bass_figure:
1930         FIGURE_SPACE {
1931                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1932                 $$ = bfr->self_scm();
1933                 scm_gc_unprotect_object ($$);
1934         }
1935         | bass_number  {
1936                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1937                 $$ = bfr->self_scm();
1938
1939                 bfr->set_mus_property ("figure", $1);
1940
1941                 scm_gc_unprotect_object ($$);
1942         }
1943         | bass_figure bass_mod {
1944                 Music *m = unsmob_music ($1);
1945                 if ($2) {
1946                         SCM salter =m->get_mus_property ("alteration");
1947                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1948                         m->set_mus_property ("alteration",
1949                                 gh_int2scm (alter + $2));
1950                 } else {
1951                         m->set_mus_property ("alteration", gh_int2scm (0));
1952                 }
1953         }
1954         ;
1955
1956 br_bass_figure:
1957         '[' bass_figure {
1958                 $$ = $2;
1959                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1960         }
1961         | bass_figure   {
1962                 $$ = $1;
1963         }
1964         | br_bass_figure ']' {
1965                 $$ = $1;
1966                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1967         }
1968         ;
1969
1970 figure_list:
1971         /**/            {
1972                 $$ = SCM_EOL;
1973         }
1974         | figure_list br_bass_figure {
1975                 $$ = scm_cons ($2, $1);
1976         }
1977         ;
1978
1979 figure_spec:
1980         FIGURE_OPEN figure_list FIGURE_CLOSE {
1981                 Music * m = MY_MAKE_MUSIC("EventChord");
1982                 $2 = scm_reverse_x ($2, SCM_EOL);
1983                 m->set_mus_property ("elements",  $2);
1984                 $$ = m->self_scm ();
1985         }
1986         ;
1987
1988
1989 optional_rest:
1990         /**/   { $$ = 0; }
1991         | REST { $$ = 1; }
1992         ;
1993
1994 simple_element:
1995         pitch exclamations questions optional_notemode_duration optional_rest {
1996
1997                 Input i = THIS->pop_spot ();
1998                 if (!THIS->lexer_->note_state_b ())
1999                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2000
2001                 Music *n = 0;
2002                 if ($5)
2003                         n =  MY_MAKE_MUSIC("RestEvent");
2004                 else
2005                         n =  MY_MAKE_MUSIC("NoteEvent");
2006
2007                 n->set_mus_property ("pitch", $1);
2008                 n->set_mus_property ("duration", $4);
2009
2010
2011                 if ($3 % 2)
2012                         n->set_mus_property ("cautionary", SCM_BOOL_T);
2013                 if ($2 % 2 || $3 % 2)
2014                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
2015
2016                 Music *v = MY_MAKE_MUSIC("EventChord");
2017                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
2018                 scm_gc_unprotect_object (n->self_scm());
2019
2020                 v->set_spot (i);
2021                 n->set_spot (i);
2022                 $$ = v;
2023         }
2024         | figure_spec optional_notemode_duration {
2025                 Music * m = unsmob_music ($1);
2026                 Input i = THIS->pop_spot ();
2027                 m->set_spot (i);
2028                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
2029                 {
2030                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
2031                 }
2032                 $$ = m;
2033         }
2034         | RESTNAME optional_notemode_duration           {
2035
2036                 Input i = THIS->pop_spot ();
2037                 Music * ev = 0;
2038                 if (ly_scm2string ($1) =="s") {
2039                         /* Space */
2040                         ev = MY_MAKE_MUSIC("SkipEvent");
2041                   }
2042                 else {
2043                         ev = MY_MAKE_MUSIC("RestEvent");
2044
2045                     }
2046                 ev->set_mus_property ("duration" ,$2);
2047                 ev->set_spot (i);
2048                 Music * velt = MY_MAKE_MUSIC("EventChord");
2049                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
2050                 velt->set_spot (i);
2051
2052                 $$ = velt;
2053         }
2054         | MULTI_MEASURE_REST optional_notemode_duration         {
2055                 THIS->pop_spot ();
2056
2057                 static SCM proc ;
2058                 if (!proc)
2059                         proc = scm_c_eval_string ("make-multi-measure-rest");
2060
2061                 SCM mus = scm_call_2 (proc, $2,
2062                         make_input (THIS->here_input()));
2063                 scm_gc_protect_object (mus);
2064                 $$ = unsmob_music (mus);
2065         }
2066
2067         | lyric_element optional_notemode_duration      {
2068                 Input i = THIS->pop_spot ();
2069                 if (!THIS->lexer_->lyric_state_b ())
2070                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2071
2072                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2073                 lreq->set_mus_property ("text", $1);
2074                 lreq->set_mus_property ("duration",$2);
2075                 lreq->set_spot (i);
2076                 Music * velt = MY_MAKE_MUSIC("EventChord");
2077                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2078
2079                 $$= velt;
2080         }
2081         | new_chord {
2082                 THIS->pop_spot ();
2083
2084                 if (!THIS->lexer_->chord_state_b ())
2085                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2086                 $$ = unsmob_music ($1);
2087         }
2088         ;
2089
2090 lyric_element:
2091         full_markup { $$ = $1; }
2092         | STRING {  $$ = $1 ; }
2093         ;
2094
2095 new_chord:
2096         steno_tonic_pitch optional_notemode_duration   {
2097                 $$ = make_chord ($1, $2, SCM_EOL);
2098         }
2099         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2100                 SCM its = scm_reverse_x ($4, SCM_EOL);
2101                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2102         }
2103         ;
2104
2105 chord_items:
2106         /**/ {
2107                 $$ = SCM_EOL;
2108         }
2109         | chord_items chord_item {
2110                 $$ = gh_cons ($2, $$);
2111         }
2112         ;
2113
2114 chord_separator:
2115         CHORD_COLON {
2116                 $$ = ly_symbol2scm ("chord-colon");
2117         }
2118         | CHORD_CARET {
2119                 $$ = ly_symbol2scm ("chord-caret");
2120         }
2121         | CHORD_SLASH steno_tonic_pitch {
2122                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2123         }
2124         | CHORD_BASS steno_tonic_pitch {
2125                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2126         }
2127         ;
2128
2129 chord_item:
2130         chord_separator {
2131                 $$ = $1;
2132         }
2133         | step_numbers {
2134                 $$ = scm_reverse_x ($1, SCM_EOL);
2135         }
2136         | CHORD_MODIFIER  {
2137                 $$ = $1;
2138         }
2139         ;
2140
2141 step_numbers:
2142         step_number { $$ = gh_cons ($1, SCM_EOL); }
2143         | step_numbers '.' step_number {
2144                 $$ = gh_cons ($3, $$);
2145         }
2146         ;
2147
2148 step_number:
2149         bare_unsigned {
2150                 $$ = make_chord_step ($1, 0);
2151         }
2152         | bare_unsigned '+' {
2153                 $$ = make_chord_step ($1, 1);
2154         }
2155         | bare_unsigned CHORD_MINUS {
2156                 $$ = make_chord_step ($1,-1);
2157         }
2158         ;
2159
2160 /*
2161         UTILITIES
2162
2163 TODO: should deprecate in favor of Scheme?
2164
2165  */
2166 number_expression:
2167         number_expression '+' number_term {
2168                 $$ = scm_sum ($1, $3);
2169         }
2170         | number_expression '-' number_term {
2171                 $$ = scm_difference ($1, $3);
2172         }
2173         | number_term
2174         ;
2175
2176 number_term:
2177         number_factor {
2178                 $$ = $1;
2179         }
2180         | number_factor '*' number_factor {
2181                 $$ = scm_product ($1, $3);
2182         }
2183         | number_factor '/' number_factor {
2184                 $$ = scm_divide ($1, $3);
2185         }
2186         ;
2187
2188 number_factor:
2189         '-'  number_factor { /* %prec UNARY_MINUS */
2190                 $$ = scm_difference ($2, SCM_UNDEFINED);
2191         }
2192         | bare_number
2193         ;
2194
2195
2196 bare_number:
2197         UNSIGNED        {
2198                 $$ = gh_int2scm ($1);
2199         }
2200         | REAL          {
2201                 $$ = $1;
2202         }
2203         | NUMBER_IDENTIFIER             {
2204                 $$ = $1;
2205         }
2206         | REAL NUMBER_IDENTIFIER        {
2207                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2208         }
2209         | UNSIGNED NUMBER_IDENTIFIER    {
2210                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2211         }
2212         ;
2213
2214
2215 bare_unsigned:
2216         UNSIGNED {
2217                         $$ = $1;
2218         }
2219         | DIGIT {
2220                 $$ = $1;
2221         }
2222         ;
2223
2224 bare_int:
2225         bare_number {
2226                 if (scm_integer_p ($1) == SCM_BOOL_T)
2227                 {
2228                         int k = gh_scm2int ($1);
2229                         $$ = k;
2230                 } else
2231                 {
2232                         THIS->parser_error (_ ("need integer number arg"));
2233                         $$ = 0;
2234                 }
2235         }
2236         | '-' bare_int {
2237                 $$ = -$2;
2238         }
2239         ;
2240
2241
2242 string:
2243         STRING          {
2244                 $$ = $1;
2245         }
2246         | STRING_IDENTIFIER     {
2247                 $$ = $1;
2248         }
2249         | string '+' string {
2250                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2251         }
2252         ;
2253
2254
2255 exclamations:
2256                 { $$ = 0; }
2257         | exclamations '!'      { $$ ++; }
2258         ;
2259
2260 questions:
2261                 { $$ = 0; }
2262         | questions '?' { $$ ++; }
2263         ;
2264
2265
2266
2267 full_markup:
2268         MARKUP_IDENTIFIER {
2269                 $$ = $1;
2270         }
2271         | MARKUP
2272                 { THIS->lexer_->push_markup_state (); }
2273         markup
2274                 { $$ = $3;
2275                   THIS->lexer_->pop_state ();
2276                 }
2277         ;
2278
2279
2280 /*
2281 This should be done more dynamically if possible.
2282 */
2283 markup:
2284         STRING {
2285                 $$ = make_simple_markup ($1);
2286         }
2287         | MARKUP_HEAD_MARKUP0 markup {
2288                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2289         }
2290         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2291                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2292         }
2293         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2294                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2295         }
2296         | markup_line {
2297                 $$ = $1;
2298         }
2299         | MARKUP_HEAD_LIST0 markup_list {
2300                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2301         }
2302         | MARKUP_HEAD_SCM0 embedded_scm {
2303                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2304         }
2305         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2306                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2307         }
2308         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2309                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2310         }
2311         | MARKUP_IDENTIFIER {
2312                 $$ = $1;
2313         }
2314
2315         ;
2316
2317 markup_list:
2318         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2319         ;
2320
2321 markup_line:
2322         '{' markup_list_body '}' {
2323                 static SCM line ;
2324                 if (!line)
2325                         line = scm_c_eval_string ("line-markup");
2326
2327                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2328         }
2329         ;
2330
2331 markup_list_body:
2332         /**/ {  $$ = SCM_EOL; }
2333         | markup_list_body markup {
2334                 $$ = gh_cons ($2, $1) ;
2335         }
2336         ;
2337
2338
2339 %%
2340
2341 void
2342 My_lily_parser::set_yydebug (bool )
2343 {
2344 #if 0
2345         yydebug = 1;
2346 #endif
2347 }
2348
2349 extern My_lily_parser * current_parser;
2350
2351 void
2352 My_lily_parser::do_yyparse ()
2353 {
2354         current_parser = this;;
2355         yyparse ((void*)this);
2356 }
2357
2358
2359 /*
2360 Should make this optional?    It will also complain when you do
2361
2362         [s4]
2363
2364 which is entirely legitimate.
2365
2366 Or we can scrap it. Barchecks should detect wrong durations, and
2367 skipTypesetting speeds it up a lot.
2368 */
2369
2370 void
2371 My_lily_parser::beam_check (SCM dur)
2372 {
2373   Duration *d = unsmob_duration (dur);
2374   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2375     {
2376       Music * m = unsmob_music (last_beam_start_);
2377       m->origin ()->warning (_("Suspect duration found following this beam"));
2378     }
2379   last_beam_start_ = SCM_EOL;
2380 }
2381
2382
2383
2384
2385 /*
2386
2387 It is a little strange to have this function in this file, but
2388 otherwise, we have to import music classes into the lexer.
2389
2390 */
2391 int
2392 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2393 {
2394         if (gh_string_p (sid)) {
2395                 *destination = sid;
2396                 return STRING_IDENTIFIER;
2397         } else if (gh_number_p (sid)) {
2398                 *destination = sid;
2399                 return NUMBER_IDENTIFIER;
2400         } else if (unsmob_translator_def (sid)) {
2401                 *destination = unsmob_translator_def (sid)->clone_scm();
2402                 return TRANSLATOR_IDENTIFIER;
2403         } else if (unsmob_score (sid)) {
2404                 Score *sc =  new Score (*unsmob_score (sid));
2405                 *destination =sc->self_scm ();
2406                 return SCORE_IDENTIFIER;
2407         } else if (Music * mus =unsmob_music (sid)) {
2408                 *destination = unsmob_music (sid)->clone ()->self_scm();
2409                 unsmob_music (*destination)->
2410                         set_mus_property ("origin", make_input (last_input_));
2411                 return dynamic_cast<Event*> (mus)
2412                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2413         } else if (unsmob_duration (sid)) {
2414                 *destination = unsmob_duration (sid)->smobbed_copy();
2415                 return DURATION_IDENTIFIER;
2416         } else if (unsmob_music_output_def (sid)) {
2417                 Music_output_def *p = unsmob_music_output_def (sid);
2418                 p = p->clone ();
2419
2420                 *destination = p->self_scm();
2421                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2422         } else if (Text_item::markup_p (sid)) {
2423                 *destination = sid;
2424                 return MARKUP_IDENTIFIER;
2425         }
2426
2427         return -1;
2428 }