configure.in

   1 dnl configure.in   -*-shell-script-*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 # Bootstrap the init proces.
   5 AC_INIT
   6
   7 # Bootstrap StepMake configure
   8 # For user package:
   9 AC_CONFIG_AUX_DIR([stepmake/bin])
  10
  11 # For stepmake package:
  12 # AC_CONFIG_AUX_DIR(bin)
  13
  14
  15 STEPMAKE_INIT
  16
  17 # List a file that identifies your package.
  18 AC_CONFIG_SRCDIR([lily/main.cc])
  19
  20 # Move to aclocal.m4?
  21 AC_CONFIG_HEADER([$CONFIGFILE.hh:config.hh.in])
  22
  23 # Uncomment the configuration options your package needs.
  24
  25 DOCUMENTATION=yes
  26 AC_ARG_ENABLE(documentation,
  27     [  --enable-documentation  build Documentation.  Default: on],
  28     [DOCUMENTATION=$enableval])
  29 AC_SUBST(DOCUMENTATION)
  30
  31 gui_b=no
  32 AC_ARG_ENABLE(gui,
  33     [  --enable-gui            compile with experimental GNOME output.  Default: off],
  34     [gui_b=$enableval])
  35
  36
  37 AC_ARG_WITH(ncsb-dir,
  38     [  --with-ncsb-dir=DIR     location of Century Schoolbook fonts.],
  39     [NCSB_DIR=$withval],
  40     [NCSB_DIR=/usr/share/fonts/default/Type1])
  41
  42 reloc_b=no
  43 AC_ARG_ENABLE(relocation,
  44     [  --enable-relocation     compile with dynamic relocation.  Default: off],
  45     [reloc_b=$enableval])
  46
  47 LINK_GXX_STATICALLY=no
  48 AC_ARG_ENABLE(static-gxx,
  49     [  --enable-static-gxx     link libstdc++.a statically. Default: off],
  50     [LINK_GXX_STATICALLY=$enableval])
  51 AC_SUBST(LINK_GXX_STATICALLY)
  52
  53 # must come before any header checks
  54 STEPMAKE_COMPILE
  55
  56 STEPMAKE_PYTHON(REQUIRED, 2.3)
  57 STEPMAKE_GCC(REQUIRED, 4.0)
  58 STEPMAKE_CXX(REQUIRED)
  59 STEPMAKE_GXX(REQUIRED, 4.0)
  60 STEPMAKE_CXXTEMPLATE
  61 STEPMAKE_STL_DATA_METHOD
  62 STEPMAKE_LIB(REQUIRED)
  63 STEPMAKE_DLOPEN
  64 # Do not use bison 1.50 and 1.75.
  65 # 1.29 is required fr %locations, but I'm not sure it's enough --ns
  66 STEPMAKE_BISON(OPTIONAL, 1.29)
  67 STEPMAKE_FLEX(REQUIRED)
  68 STEPMAKE_FLEXLEXER(REQUIRED)
  69 STEPMAKE_FLEXLEXER_LOCATION
  70 AC_LANG_C
  71 STEPMAKE_LOCALE
  72 STEPMAKE_GETTEXT
  73 STEPMAKE_MSGFMT(REQUIRED)
  74 STEPMAKE_TEXMF(REQUIRED)
  75 STEPMAKE_TEXMF_DIRS
  76 STEPMAKE_GUILE_DEVEL(REQUIRED, 1.6.7)
  77 STEPMAKE_MAKEINFO(REQUIRED, 4.8)
  78 STEPMAKE_PYTHON_DEVEL(REQUIRED)
  79
  80 STEPMAKE_PATH_PROG(GHOSTSCRIPT, gs, OPTIONAL, 8.15)
  81
  82 STEPMAKE_PROGS(MFTRACE, mftrace, REQUIRED, 1.1.19)
  83 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, REQUIRED, 20050624)
  84
  85 AC_CHECK_HEADERS([assert.h grp.h libio.h pwd.h sys/stat.h wchar.h])
  86 AC_LANG_PUSH(C++)
  87 AC_CHECK_HEADERS([sstream])
  88 AC_LANG_POP(C++)
  89 AC_HEADER_STAT
  90 AC_FUNC_MEMCMP
  91 AC_FUNC_VPRINTF
  92 AC_CHECK_FUNCS([chroot fopencookie funopen gettext isinf mbrtowc memmem snprintf vsnprintf wcrtomb])
  93 AC_CHECK_HEADERS([utf8/wchar.h], LIBS="$LIBS -lutf8")
  94 AC_SEARCH_LIBS(mbrtowc, [mingwex msvcp60])
  95
  96 STEPMAKE_PROGS(PKG_CONFIG, pkg-config, REQUIRED, 0.9.0)
  97
  98 if test "$gui_b" = "yes"; then
  99     STEPMAKE_GTK2(gtk+-2.0, REQUIRED, 2.4.0)
 100 fi
 101
 102 if test "$reloc_b" = "yes"; then
 103     AC_DEFINE(ARGV0_RELOCATION)
 104 fi
 105
 106 AC_MSG_CHECKING([New Century Schoolbook PFB files])
 107 if  test ! -f "$NCSB_DIR/c059016l.pfb"; then
 108     AC_MSG_WARN($NCSB_DIR does not contain c059033l.pfb. Use --with-ncsb-dir)
 109 fi
 110
 111 AC_MSG_RESULT($NCSB_DIR)
 112 AC_SUBST(NCSB_DIR)
 113
 114 HOST_ARCH=`$CC -dumpmachine`
 115 AC_SUBST(HOST_ARCH)
 116
 117 STEPMAKE_PANGO_FT2(pangoft2, REQUIRED, 1.6.0)
 118 #STEPMAKE_PANGO(pango, REQUIRED, 1.6.0)
 119 STEPMAKE_FONTCONFIG(fontconfig, REQUIRED, 2.2.0)
 120 STEPMAKE_FREETYPE2(freetype2, REQUIRED, 0)
 121
 122 STEPMAKE_WINDOWS
 123
 124 ## Optional tools for building documentation, website, extra fonts.
 125
 126 # guile executable for some scripts
 127 STEPMAKE_GUILE(OPTIONAL)
 128
 129 # perl for help2man.
 130 STEPMAKE_PERL(OPTIONAL)
 131
 132 # New makeinfo for multi-page website docs Simply always require new
 133 # makeinfo should avoid bug reports; if people want to build lily
 134 # without the docs, they can find this comment and use an older
 135 # makeinfo--but hopefully won't report makeinfo problems.
 136 STEPMAKE_PROGS(MAKEINFO, makeinfo, REQUIRED, 4.7)
 137
 138 AC_DEFINE_UNQUOTED(FLOWER_VERSION, "${FULL_FLOWER_VERSION}")
 139
 140 # Gather requirements and generate output.
 141 STEPMAKE_END
 142
 143 test -n "$CONFIGURATION" && mc=" conf=$CONFIGURATION" || mc=""
 144
 145 cat <<EOF
 146
 147 Type:
 148     make$mc all       to build LilyPond
 149     make$mc install   to install LilyPond
 150     make$mc help      to see all possible targets
 151
 152 EOF