configure.in

   1 dnl configure.in   -*-shell-script-*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 # Bootstrap the init proces.
   5 AC_INIT
   6
   7 # Bootstrap StepMake configure
   8 # For user package:
   9 AC_CONFIG_AUX_DIR([stepmake/bin])
  10
  11 # For stepmake package:
  12 # AC_CONFIG_AUX_DIR(bin)
  13
  14
  15 STEPMAKE_INIT
  16
  17 # List a file that identifies your package.
  18 AC_CONFIG_SRCDIR([lily/main.cc])
  19
  20 # Move to aclocal.m4?
  21 AC_CONFIG_HEADER([$CONFIGFILE.hh:config.hh.in])
  22
  23 # Uncomment the configuration options your package needs.
  24
  25 DOCUMENTATION=yes
  26 AC_ARG_ENABLE(documentation,
  27     [  --enable-documentation  build Documentation.  Default: on],
  28     [DOCUMENTATION=$enableval])
  29 AC_SUBST(DOCUMENTATION)
  30
  31 gui_b=no
  32 AC_ARG_ENABLE(gui,
  33     [  --enable-gui            compile with experimental GNOME output module.  Default: off],
  34     [gui_b=$enableval])
  35
  36 reloc_b=no
  37 AC_ARG_ENABLE(relocation,
  38     [  --enable-relocation     compile with dynamic relocation.  Default: off],
  39     [reloc_b=$enableval])
  40
  41 FRAMEWORKDIR=".."
  42 AC_ARG_WITH(framework-dir,
  43     [  --with-framework-dir=DIR
  44         relative the optional framework directory],[
  45         if test "$withval" = "yes" -o "$withval" = "no"; then
  46             AC_MSG_WARN(Usage: --with-framework-dir=../lib/FRAMEWORK/DIR)
  47         else
  48             FRAMEWORKDIR="${withval}"
  49             LDFLAGS="$LDFLAGS -Wl,--rpath,'\$\${ORIGIN}/$FRAMEWORKDIR/lib'"
  50         fi
  51         ])
  52 AC_DEFINE_UNQUOTED(FRAMEWORKDIR, ["${FRAMEWORKDIR}"])
  53
  54 LINK_GXX_STATICALLY=no
  55 AC_ARG_ENABLE(static-gxx,
  56     [  --enable-static-gxx     link libstdc++.a statically. Default: off],
  57     [LINK_GXX_STATICALLY=$enableval])
  58 AC_SUBST(LINK_GXX_STATICALLY)
  59
  60 # must come before any header checks
  61 STEPMAKE_COMPILE
  62
  63 STEPMAKE_PYTHON(REQUIRED, 2.2)
  64 STEPMAKE_GCC(REQUIRED, 2.8)
  65 STEPMAKE_CXX(REQUIRED)
  66 STEPMAKE_GXX(REQUIRED, 3.0.5)
  67 STEPMAKE_CXXTEMPLATE
  68 STEPMAKE_LIB(REQUIRED)
  69 STEPMAKE_DLOPEN
  70 # Do not use bison 1.50 and 1.75.
  71 # 1.29 is required fr %locations, but I'm not sure it's enough --ns
  72 STEPMAKE_BISON(OPTIONAL, 1.29)
  73 STEPMAKE_FLEX(REQUIRED)
  74 STEPMAKE_FLEXLEXER(REQUIRED)
  75 STEPMAKE_FLEXLEXER_LOCATION
  76 AC_LANG_C
  77 STEPMAKE_LOCALE
  78 STEPMAKE_GETTEXT
  79 STEPMAKE_MSGFMT(REQUIRED)
  80 STEPMAKE_TEXMF(REQUIRED)
  81 STEPMAKE_TEXMF_DIRS
  82 STEPMAKE_GUILE_DEVEL(REQUIRED, 1.6.5)
  83 STEPMAKE_MAKEINFO(REQUIRED)
  84 STEPMAKE_PYTHON_DEVEL(REQUIRED)
  85
  86 STEPMAKE_PATH_PROG(GHOSTSCRIPT, gs, OPTIONAL, 8.15)
  87
  88 STEPMAKE_PROGS(MFTRACE, mftrace, REQUIRED, 1.1.9)
  89 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, REQUIRED, 20050624)
  90
  91 AC_CHECK_HEADERS([assert.h grp.h libio.h pwd.h sys/stat.h wchar.h])
  92 AC_LANG_PUSH(C++)
  93 AC_CHECK_HEADERS([sstream])
  94 AC_LANG_POP(C++)
  95 AC_HEADER_STAT
  96 AC_FUNC_MEMCMP
  97 AC_FUNC_VPRINTF
  98 AC_CHECK_FUNCS([chroot fopencookie funopen gettext isinf mbrtowc memmem snprintf vsnprintf wcrtomb])
  99 AC_CHECK_HEADERS([utf8/wchar.h], LIBS="$LIBS -lutf8")
 100 AC_SEARCH_LIBS(mbrtowc, [mingwex msvcp60])
 101
 102 STEPMAKE_PROGS(PKG_CONFIG, pkg-config, REQUIRED, 0.9.0)
 103
 104 if test "$gui_b" = "yes"; then
 105     STEPMAKE_GTK2(gtk+-2.0, REQUIRED, 2.4.0)
 106 fi
 107
 108 if test "$reloc_b" = "yes"; then
 109     AC_DEFINE(ARGV0_RELOCATION)
 110 fi
 111
 112 STEPMAKE_PANGO_FT2(pangoft2, REQUIRED, 1.6.0)
 113 #STEPMAKE_PANGO(pango, REQUIRED, 1.6.0)
 114 STEPMAKE_FONTCONFIG(fontconfig, REQUIRED, 2.2.0)
 115 STEPMAKE_FREETYPE2(freetype2, REQUIRED, 0)
 116
 117 STEPMAKE_WINDOWS
 118
 119 ## Optional tools for building documentation, website, extra fonts.
 120
 121 # guile executable for some scripts
 122 STEPMAKE_GUILE(OPTIONAL)
 123
 124 # perl for help2man.
 125 STEPMAKE_PERL(OPTIONAL)
 126
 127 # New makeinfo for multi-page website docs Simply always require new
 128 # makeinfo should avoid bug reports; if people want to build lily
 129 # without the docs, they can find this comment and use an older
 130 # makeinfo--but hopefully won't report makeinfo problems.
 131 STEPMAKE_PROGS(MAKEINFO, makeinfo, REQUIRED, 4.7)
 132
 133 if test "$optimise_b" = yes; then
 134     DEFINES="$DEFINES -DSTRING_UTILS_INLINED"
 135     AC_DEFINE(STRINGS_UTILS_INLINED)
 136 fi
 137
 138 AC_DEFINE_UNQUOTED(FLOWER_VERSION, "${FULL_FLOWER_VERSION}")
 139
 140 # Gather requirements and generate output.
 141 STEPMAKE_END
 142
 143 test -n "$CONFIGURATION" && mc=" conf=$CONFIGURATION" || mc=""
 144
 145 cat <<EOF
 146
 147 Type:
 148     make$mc all       to build LilyPond
 149     make$mc install   to install LilyPond
 150     make$mc help      to see all possible targets
 151
 152 EOF