configure.in

   1 dnl configure.in   -*-shell-script-*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.60)
   5
   6 # Bootstrap the init process.
   7 AC_INIT
   8
   9 # Bootstrap StepMake configure
  10 AC_CONFIG_AUX_DIR([config])
  11
  12 STEPMAKE_INIT
  13
  14 # List a file that identifies your package.
  15 AC_CONFIG_SRCDIR([lily/main.cc])
  16
  17 # Move to aclocal.m4?
  18 AC_CONFIG_HEADERS([$CONFIGFILE.hh:config.hh.in])
  19
  20 # Uncomment the configuration options your package needs.
  21
  22 DOCUMENTATION=yes
  23 AC_ARG_ENABLE(documentation,
  24     [AS_HELP_STRING([--enable-documentation],
  25                     [build Documentation.  Default: on])],
  26     [DOCUMENTATION=$enableval])
  27 AC_SUBST(DOCUMENTATION)
  28
  29 AC_ARG_WITH(ncsb-dir,
  30     [AS_HELP_STRING([--with-ncsb-dir=DIR],
  31                     [location of Century Schoolbook fonts.])],
  32     [NCSB_DIR=$withval],
  33     [NCSB_DIR=""])
  34
  35 reloc_b=no
  36 AC_ARG_ENABLE(relocation,
  37     [AS_HELP_STRING([--enable-relocation],
  38                     [compile with dynamic relocation.  Default: off])],
  39     [reloc_b=$enableval])
  40
  41 rpath_b=no
  42 AC_ARG_ENABLE(rpath,
  43     [AS_HELP_STRING([--enable-rpath],
  44                     [hardcode runtime library path.  Default: off])],
  45     [rpath_b=$enableval])
  46
  47 LINK_GXX_STATICALLY=no
  48 AC_ARG_ENABLE(static-gxx,
  49     [AS_HELP_STRING([--enable-static-gxx],
  50                     [link libstdc++.a statically.  Default: off])],
  51     [LINK_GXX_STATICALLY=$enableval])
  52 AC_SUBST(LINK_GXX_STATICALLY)
  53
  54 # must come before any header checks
  55 STEPMAKE_COMPILE
  56
  57 AC_CHECK_PROG(FCLIST, fc-list, fc-list)
  58 AC_MSG_CHECKING([New Century Schoolbook PFB files])
  59 AC_SUBST(NCSB_SOURCE_FILES)
  60 AC_SUBST(NCSB_DIR)
  61 UNCHECKED_NCSB_SOURCE_FILES=""
  62 if test "$NCSB_DIR" != "" ;  then
  63   for f in c059013l c059016l c059033l c059036l; do
  64     if test ! -f "$NCSB_DIR/$f.pfb"; then
  65       STEPMAKE_WARN($NCSB_DIR does not contain $f.pfb.)
  66     else
  67       UNCHECKED_NCSB_SOURCE_FILES="$NCSB_DIR/$f.pfb $UNCHECKED_NCSB_SOURCE_FILES"
  68     fi
  69   done
  70 else
  71   if test "$FCLIST" != ""; then
  72     for style in Roman Italic "Bold Italic" Bold; do
  73       NCSB_FILE=`$FCLIST "Century Schoolbook L:style=$style:foundry=urw:fontformat=Type 1" file \
  74                 | head -n 1`
  75       NCSB_FILE=`echo $NCSB_FILE | sed 's/\(:.*\)$//g'`
  76       NCSB_FILE=`$PYTHON "$srcdir/scripts/auxiliar/readlink.py" $NCSB_FILE`
  77       UNCHECKED_NCSB_SOURCE_FILES="$NCSB_FILE $UNCHECKED_NCSB_SOURCE_FILES"
  78     done
  79     NCSB_DIR=`AS_DIRNAME($NCSB_FILE)`
  80   else
  81     AC_MSG_RESULT(not found)
  82     echo "Can't find Century Schoolbook files. Install FontConfig's fc-list,"
  83     echo "or use --with-ncsb-dir"
  84   fi
  85 fi
  86 NCSB_SOURCE_FILES=""
  87 for f in $UNCHECKED_NCSB_SOURCE_FILES; do
  88   if test "`grep Cyrillic "$f"`" = ""; then
  89     STEPMAKE_WARN($f does not have Cyrillic characters.)
  90   else
  91     NCSB_SOURCE_FILES="$f $NCSB_SOURCE_FILES"
  92   fi
  93 done
  94 AC_MSG_RESULT($NCSB_SOURCE_FILES)
  95
  96 AC_LANG([C++])
  97
  98 STEPMAKE_PYTHON(REQUIRED, 2.4)
  99 # this checks if we have GNU C by compiling a program with
 100 # __GNUC__, but that macro now unofficially means "the compiler
 101 # supports the GNU C extensions" -- the intel C compiler and clang
 102 # both support __GNUC__!
 103 STEPMAKE_GCC_OR_CLANG(REQUIRED, 3.4)
 104
 105 STEPMAKE_CXX(REQUIRED)
 106 STEPMAKE_GXX_OR_CLANG(REQUIRED, 3.4)
 107 STEPMAKE_GXXCODEGENBUG
 108 STEPMAKE_CXXTEMPLATE
 109 STEPMAKE_STL_DATA_METHOD
 110 STEPMAKE_LIB(REQUIRED)
 111 STEPMAKE_DLOPEN
 112 # Do not use bison 1.50 and 1.75.
 113 # 1.29 is required fr %locations, but I'm not sure it's enough --ns
 114 STEPMAKE_BISON(OPTIONAL, 1.29)
 115 STEPMAKE_FLEX(REQUIRED)
 116 STEPMAKE_FLEXLEXER(REQUIRED)
 117 STEPMAKE_FLEXLEXER_LOCATION
 118 STEPMAKE_LOCALE
 119 STEPMAKE_GETTEXT
 120 STEPMAKE_MSGFMT(REQUIRED)
 121 STEPMAKE_TEXMF(REQUIRED)
 122 STEPMAKE_TEXMF_DIRS
 123 STEPMAKE_GUILE_DEVEL(REQUIRED, 1.8.2)
 124
 125 # check for 3 typedefs added in Guile 1.9
 126 save_CXXFLAGS="$CXXFLAGS"
 127 CXXFLAGS="$GUILE_CFLAGS $CXXFLAGS"
 128 AC_CHECK_TYPES([scm_t_hash_fold_fn, scm_t_hash_handle_fn],
 129                [AC_DEFINE(HAVE_GUILE_HASH_FUNC)], [],
 130                [#include <libguile.h>])
 131 AC_CHECK_TYPES([scm_t_subr],
 132                [AC_DEFINE(HAVE_GUILE_SUBR_TYPE)], [],
 133                [#include <libguile.h>])
 134 CXXFLAGS="$save_CXXFLAGS"
 135
 136 ## Check for usable cxxabi
 137 save_LIBS="$LIBS"
 138 LIBS="$LIBS $CXXABI_LIBS"
 139 AC_MSG_CHECKING(for usable C++ demangler)
 140 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cxxabi.h>],
 141             [abi::__cxa_demangle ("", 0, 0, 0)])],
 142     [AC_DEFINE(HAVE_CXA_DEMANGLE)
 143         AC_MSG_RESULT(yes)],[
 144         LIBS="$LIBS -lsupc++"
 145         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cxxabi.h>],
 146                     [abi::__cxa_demangle ("", 0, 0, 0)])],
 147             [AC_DEFINE(HAVE_CXA_DEMANGLE)
 148                 AC_MSG_RESULT([yes, using -lsupc++])
 149                 CXXABI_LIBS="$CXXABI_LIBS -lsupc++"],
 150             [AC_MSG_RESULT([no, use c++filt -t for manual demangling])])])
 151 LIBS="$save_LIBS"
 152 AC_SUBST(CXXABI_LIBS)
 153
 154 ## check rational bugfix.
 155 save_CPPFLAGS="$CPPFLAGS"
 156 CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 157 AC_MSG_CHECKING(GUILE rational bugfix)
 158 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <libguile.h>
 159 #ifdef SCM_FRACTION_REDUCED_BIT
 160 #error
 161 #endif
 162 ]])],[AC_MSG_RESULT(ok)],[REQUIRED="$REQUIRED GUILE-with-rational-bugfix"
 163 AC_MSG_RESULT(Must have patched GUILE rational support. See INSTALL.txt)])
 164 CPPFLAGS="$save_CPPFLAGS"
 165
 166
 167 STEPMAKE_PYTHON_DEVEL(REQUIRED)
 168
 169 STEPMAKE_PATH_PROG(GHOSTSCRIPT, gs, OPTIONAL, 8.60)
 170
 171 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, REQUIRED, 20100501)
 172 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, OPTIONAL, 20110222)
 173
 174 STEPMAKE_PATH_PROG(T1ASM, t1asm, REQUIRED)
 175
 176 AC_CHECK_HEADERS([assert.h grp.h libio.h pwd.h sys/stat.h wchar.h fpu_control.h])
 177 AC_CHECK_HEADERS([sstream])
 178 AC_HEADER_STAT
 179 AC_FUNC_MEMCMP
 180 AC_FUNC_VPRINTF
 181 AC_CHECK_FUNCS([chroot fopencookie gettext isinf memmem snprintf vsnprintf])
 182
 183 STEPMAKE_PROGS(PKG_CONFIG, pkg-config, REQUIRED, 0.9.0)
 184
 185 AC_MSG_CHECKING(whether to enable dynamic relocation)
 186 if test "$reloc_b" = "yes"; then
 187     AC_DEFINE(ARGV0_RELOCATION)
 188 fi
 189 AC_MSG_RESULT($reloc_b)
 190
 191 AC_MSG_CHECKING(for rpath linkage)
 192 if test "$rpath_b" = "yes"; then
 193     LDFLAGS="$LDFLAGS -Wl,-rpath -Wl,\\\$\$ORIGIN/../lib"
 194 elif test "$rpath_b" != "no"; then
 195     LDFLAGS="$LDFLAGS -Wl,-rpath -Wl,$rpath_b"
 196 fi
 197 AC_MSG_RESULT($rpath_b)
 198
 199 HOST_ARCH=`$CC -dumpmachine`
 200 AC_SUBST(HOST_ARCH)
 201
 202 STEPMAKE_PANGO_FT2(pangoft2, REQUIRED, 1.6.0)
 203 STEPMAKE_FONTCONFIG(fontconfig, REQUIRED, 2.4.0)
 204 STEPMAKE_FREETYPE2(freetype2, REQUIRED, 2.1.10)
 205
 206 STEPMAKE_WINDOWS
 207
 208 ## Optional tools for building documentation, website, extra fonts.
 209
 210 # guile executable for some scripts
 211 STEPMAKE_GUILE(OPTIONAL)
 212
 213 # perl for help2man.
 214 STEPMAKE_PERL(OPTIONAL)
 215
 216 STEPMAKE_PROGS(MAKEINFO, makeinfo, REQUIRED, 4.11)
 217 STEPMAKE_PROGS(TEXI2HTML, texi2html, OPTIONAL, 1.82)
 218 STEPMAKE_PROGS(DBLATEX, dblatex, OPTIONAL, 0.1.4)
 219 STEPMAKE_PROGS(PDFLATEX, pdflatex, OPTIONAL)
 220 STEPMAKE_PROGS(NETPBM, pngtopnm, OPTIONAL)
 221 STEPMAKE_PROGS(IMAGEMAGICK, convert, OPTIONAL)
 222 # this name avoids a conflict with ZIP in stepmake/aclocal.m4
 223 STEPMAKE_PROGS(ZIPDOC, zip, OPTIONAL)
 224 STEPMAKE_PROGS(RSYNC, rsync, OPTIONAL)
 225
 226
 227 AC_DEFINE_UNQUOTED(FLOWER_VERSION, "${FULL_FLOWER_VERSION}")
 228
 229 # must also have local.make if configure fails.
 230 touch local.make
 231
 232 if test "$reloc_b$rpath_b" = "yesno"; then
 233     STEPMAKE_WARN([Using --enable-relocation without --enable-rpath.  LilyPond may have trouble finding libraries.])
 234 fi
 235
 236 # Gather requirements and generate output.
 237 STEPMAKE_END
 238
 239 test -n "$CONFIGURATION" && mc=" conf=$CONFIGURATION" || mc=""
 240
 241 if make top-doc 1>/dev/null 2>&1; then
 242     rm -f INSTALL.txt && ln Documentation/topdocs/out/INSTALL.txt .
 243     rm -f README.txt && ln Documentation/topdocs/out/README.txt .
 244 fi
 245
 246 cat <<EOF
 247
 248 Type:
 249     make$mc all       to build LilyPond
 250     make$mc install   to install LilyPond
 251     make$mc help      to see all possible targets
 252
 253 Edit local.make for local Makefile overrides.
 254
 255
 256 EOF