configure.in

   1 dnl configure.in   -*-shell-script-*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 # Bootstrap the init proces.
   5 AC_INIT
   6
   7 # Bootstrap StepMake configure
   8 # For user package:
   9 AC_CONFIG_AUX_DIR([stepmake/bin])
  10
  11 # For stepmake package:
  12 # AC_CONFIG_AUX_DIR(bin)
  13
  14
  15 STEPMAKE_INIT
  16
  17 # List a file that identifies your package.
  18 AC_CONFIG_SRCDIR([lily/main.cc])
  19
  20 # Move to aclocal.m4?
  21 AC_CONFIG_HEADER([$CONFIGFILE.hh:config.hh.in])
  22
  23 # Uncomment the configuration options your package needs.
  24
  25 DOCUMENTATION=yes
  26 AC_ARG_ENABLE(documentation,
  27     [  --enable-documentation  build Documentation.  Default: on],
  28     [DOCUMENTATION=$enableval])
  29 AC_SUBST(DOCUMENTATION)
  30
  31 gui_b=no
  32 AC_ARG_ENABLE(gui,
  33     [  --enable-gui            compile with experimental GNOME output.  Default: off],
  34     [gui_b=$enableval])
  35
  36
  37 AC_ARG_WITH(ncsb-dir,
  38     [  --with-ncsb-dir=DIR     location of Century Schoolbook fonts.],
  39     [NCSB_DIR=$withval],
  40     [NCSB_DIR=""])
  41
  42 reloc_b=no
  43 AC_ARG_ENABLE(relocation,
  44     [  --enable-relocation     compile with dynamic relocation.  Default: off],
  45     [reloc_b=$enableval])
  46
  47 LINK_GXX_STATICALLY=no
  48 AC_ARG_ENABLE(static-gxx,
  49     [  --enable-static-gxx     link libstdc++.a statically. Default: off],
  50     [LINK_GXX_STATICALLY=$enableval])
  51 AC_SUBST(LINK_GXX_STATICALLY)
  52
  53 # must come before any header checks
  54 STEPMAKE_COMPILE
  55
  56 AC_CHECK_PROG(FCMATCH, fc-match, fc-match)
  57 AC_MSG_CHECKING([New Century Schoolbook PFB files])
  58 AC_SUBST(NCSB_SOURCE_FILES)
  59 if test "$NCSB_DIR" != "" ;  then
  60   NCSB_SOURCE_FILES=""
  61   for f in c059013l c059016l c059033l c059036l; do
  62     if test ! -f "$NCSB_DIR/$f.pfb"; then
  63       AC_MSG_WARN($NCSB_DIR does not contain $f.pfb.)
  64     else
  65       NCSB_SOURCE_FILES="$NCSB_DIR/$f.pfb $NCSB_SOURCE_FILES"
  66     fi
  67   done
  68 else
  69   if test "$FCMATCH" != ""; then
  70     for style in Roman Italic "Bold Italic" Bold; do
  71       NCSB_FILE=`$FCMATCH --verbose "Century Schoolbook L:style=$style" | grep 'file:' | grep -v "\.ttf"`
  72
  73       NCSB_FILE=`echo $NCSB_FILE | sed 's/^.*"\(.*\)".*$/\1/g'`
  74       NCSB_FILE=`$PYTHON "$srcdir/buildscripts/readlink.py" $NCSB_FILE`
  75       NCSB_SOURCE_FILES="$NCSB_FILE $NCSB_SOURCE_FILES"
  76     done
  77   else
  78     AC_MSG_RESULT(not found)
  79     echo "Can't find Century Schoolbook files. Install FontConfig's fc-match,"
  80     echo "or use --with-ncsb-dir"
  81   fi
  82 fi
  83 AC_MSG_RESULT($NCSB_SOURCE_FILES)
  84
  85
  86
  87 STEPMAKE_PYTHON(REQUIRED, 2.4)
  88 STEPMAKE_GCC(REQUIRED, 3.4)
  89
  90 STEPMAKE_CXX(REQUIRED)
  91 STEPMAKE_GXX(REQUIRED, 3.4)
  92 STEPMAKE_CXXTEMPLATE
  93 STEPMAKE_STL_DATA_METHOD
  94 STEPMAKE_LIB(REQUIRED)
  95 STEPMAKE_DLOPEN
  96 # Do not use bison 1.50 and 1.75.
  97 # 1.29 is required fr %locations, but I'm not sure it's enough --ns
  98 STEPMAKE_BISON(OPTIONAL, 1.29)
  99 STEPMAKE_FLEX(REQUIRED)
 100 STEPMAKE_FLEXLEXER(REQUIRED)
 101 STEPMAKE_FLEXLEXER_LOCATION
 102 AC_LANG_C
 103 STEPMAKE_LOCALE
 104 STEPMAKE_GETTEXT
 105 STEPMAKE_MSGFMT(REQUIRED)
 106 STEPMAKE_TEXMF(REQUIRED)
 107 STEPMAKE_TEXMF_DIRS
 108
 109 ## should check for 1.8.2 ?
 110 STEPMAKE_GUILE_DEVEL(REQUIRED, 1.8.0)
 111
 112
 113 ## check rational bugfix.
 114 save_CPPFLAGS="$CPPFLAGS"
 115 CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 116 AC_MSG_CHECKING(GUILE rational bugfix)
 117 AC_TRY_CPP(
 118 #include <libguile.h>
 119 #ifdef SCM_FRACTION_REDUCED_BIT
 120 #error
 121 #endif
 122 ,
 123 AC_MSG_RESULT(ok),
 124 REQUIRED="$REQUIRED GUILE-with-rational-bugfix"
 125 AC_MSG_RESULT(Must have patched GUILE rational support. See INSTALL.txt))
 126 CPPFLAGS="$save_CPPFLAGS"
 127
 128
 129 # We check for makeinfo below, too. Really duplicate that check?
 130 ## STEPMAKE_MAKEINFO(REQUIRED, 4.11)
 131 STEPMAKE_PYTHON_DEVEL(REQUIRED)
 132
 133 STEPMAKE_PATH_PROG(GHOSTSCRIPT, gs, OPTIONAL, 8.15)
 134
 135 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, REQUIRED, 20050624)
 136
 137 AC_CHECK_HEADERS([assert.h grp.h libio.h pwd.h sys/stat.h wchar.h fpu_control.h])
 138 AC_LANG_PUSH(C++)
 139 AC_CHECK_HEADERS([sstream boost/lambda/lambda.hpp])
 140 AC_LANG_POP(C++)
 141 AC_HEADER_STAT
 142 AC_FUNC_MEMCMP
 143 AC_FUNC_VPRINTF
 144 AC_CHECK_FUNCS([chroot fopencookie funopen gettext isinf mbrtowc memmem snprintf vsnprintf wcrtomb])
 145 AC_CHECK_HEADERS([utf8/wchar.h], LIBS="$LIBS -lutf8")
 146 AC_SEARCH_LIBS(mbrtowc, [mingwex msvcp60])
 147
 148 STEPMAKE_PROGS(PKG_CONFIG, pkg-config, REQUIRED, 0.9.0)
 149
 150 if test "$gui_b" = "yes"; then
 151     STEPMAKE_GTK2(gtk+-2.0, REQUIRED, 2.4.0)
 152 fi
 153
 154 if test "$reloc_b" = "yes"; then
 155     AC_DEFINE(ARGV0_RELOCATION)
 156 fi
 157
 158
 159 HOST_ARCH=`$CC -dumpmachine`
 160 AC_SUBST(HOST_ARCH)
 161
 162 STEPMAKE_PANGO_FT2(pangoft2, REQUIRED, 1.6.0)
 163 #STEPMAKE_PANGO(pango, REQUIRED, 1.6.0)
 164 STEPMAKE_FONTCONFIG(fontconfig, REQUIRED, 2.2.0)
 165 STEPMAKE_FREETYPE2(freetype2, REQUIRED, 2.1.10)
 166
 167 STEPMAKE_WINDOWS
 168
 169 ## Optional tools for building documentation, website, extra fonts.
 170
 171 # guile executable for some scripts
 172 STEPMAKE_GUILE(OPTIONAL)
 173
 174 # perl for help2man.
 175 STEPMAKE_PERL(OPTIONAL)
 176
 177 STEPMAKE_PROGS(MAKEINFO, makeinfo, REQUIRED, 4.11)
 178 STEPMAKE_PROGS(TEXI2HTML, texi2html, REQUIRED, 1.79)
 179
 180 AC_DEFINE_UNQUOTED(FLOWER_VERSION, "${FULL_FLOWER_VERSION}")
 181
 182
 183 # must also have local.make if configure fails.
 184 touch local.make
 185
 186 # Gather requirements and generate output.
 187 STEPMAKE_END
 188
 189 test -n "$CONFIGURATION" && mc=" conf=$CONFIGURATION" || mc=""
 190
 191 cat <<EOF
 192
 193 Type:
 194     make$mc all       to build LilyPond
 195     make$mc install   to install LilyPond
 196     make$mc help      to see all possible targets
 197
 198 Edit local.make for local Makefile overrides.
 199
 200
 201 EOF