configure.in

   1 dnl configure.in   -*-shell-script-*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 # Bootstrap the init proces.
   5 AC_INIT
   6
   7 # Bootstrap StepMake configure
   8 # For user package:
   9 AC_CONFIG_AUX_DIR([stepmake/bin])
  10
  11 # For stepmake package:
  12 # AC_CONFIG_AUX_DIR(bin)
  13
  14
  15 STEPMAKE_INIT
  16
  17 # List a file that identifies your package.
  18 AC_CONFIG_SRCDIR([lily/main.cc])
  19
  20 # Move to aclocal.m4?
  21 AC_CONFIG_HEADER([$CONFIGFILE.hh:config.hh.in])
  22
  23 # Uncomment the configuration options your package needs.
  24
  25 DOCUMENTATION=yes
  26 AC_ARG_ENABLE(documentation,
  27     [  --enable-documentation  build Documentation.  Default: on],
  28     [DOCUMENTATION=$enableval])
  29 AC_SUBST(DOCUMENTATION)
  30
  31 gui_b=no
  32 AC_ARG_ENABLE(gui,
  33     [  --enable-gui            compile with experimental GNOME output module.  Default: off],
  34     [gui_b=$enableval])
  35
  36 reloc_b=no
  37 AC_ARG_ENABLE(relocation,
  38     [  --enable-relocation     compile with dynamic relocation.  Default: off],
  39     [reloc_b=$enableval])
  40
  41 LINK_GXX_STATICALLY=no
  42 AC_ARG_ENABLE(static-gxx,
  43     [  --enable-static-gxx     link libstdc++.a statically. Default: off],
  44     [LINK_GXX_STATICALLY=$enableval])
  45 AC_SUBST(LINK_GXX_STATICALLY)
  46
  47 # must come before any header checks
  48 STEPMAKE_COMPILE
  49
  50 STEPMAKE_PYTHON(REQUIRED, 2.2)
  51 STEPMAKE_GCC(REQUIRED, 2.8)
  52 STEPMAKE_CXX(REQUIRED)
  53 STEPMAKE_GXX(REQUIRED, 3.0.5)
  54 STEPMAKE_CXXTEMPLATE
  55 STEPMAKE_LIB(REQUIRED)
  56 STEPMAKE_DLOPEN
  57 # Do not use bison 1.50 and 1.75.
  58 # 1.29 is required fr %locations, but I'm not sure it's enough --ns
  59 STEPMAKE_BISON(OPTIONAL, 1.29)
  60 STEPMAKE_FLEX(REQUIRED)
  61 STEPMAKE_FLEXLEXER(REQUIRED)
  62 STEPMAKE_FLEXLEXER_LOCATION
  63 AC_LANG_C
  64 STEPMAKE_LOCALE
  65 STEPMAKE_GETTEXT
  66 STEPMAKE_MSGFMT(REQUIRED)
  67 STEPMAKE_TEXMF(REQUIRED)
  68 STEPMAKE_TEXMF_DIRS
  69 STEPMAKE_GUILE_DEVEL(REQUIRED, 1.6.5)
  70 STEPMAKE_MAKEINFO(REQUIRED)
  71 STEPMAKE_PYTHON_DEVEL(REQUIRED)
  72
  73 STEPMAKE_PATH_PROG(GHOSTSCRIPT, gs, OPTIONAL, 8.15)
  74
  75 STEPMAKE_PROGS(MFTRACE, mftrace, REQUIRED, 1.1.9)
  76 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, REQUIRED, 20050624)
  77
  78 AC_CHECK_HEADERS([assert.h grp.h libio.h pwd.h sys/stat.h wchar.h])
  79 AC_LANG_PUSH(C++)
  80 AC_CHECK_HEADERS([sstream])
  81 AC_LANG_POP(C++)
  82 AC_HEADER_STAT
  83 AC_FUNC_MEMCMP
  84 AC_FUNC_VPRINTF
  85 AC_CHECK_FUNCS([chroot fopencookie funopen gettext isinf mbrtowc memmem snprintf vsnprintf wcrtomb])
  86 AC_CHECK_HEADERS([utf8/wchar.h], LIBS="$LIBS -lutf8")
  87 AC_SEARCH_LIBS(mbrtowc, [mingwex msvcp60])
  88
  89 STEPMAKE_PROGS(PKG_CONFIG, pkg-config, REQUIRED, 0.9.0)
  90
  91 if test "$gui_b" = "yes"; then
  92     STEPMAKE_GTK2(gtk+-2.0, REQUIRED, 2.4.0)
  93 fi
  94
  95 if test "$reloc_b" = "yes"; then
  96     AC_DEFINE(ARGV0_RELOCATION)
  97 fi
  98
  99 STEPMAKE_PANGO_FT2(pangoft2, REQUIRED, 1.6.0)
 100 #STEPMAKE_PANGO(pango, REQUIRED, 1.6.0)
 101 STEPMAKE_FONTCONFIG(fontconfig, REQUIRED, 2.2.0)
 102 STEPMAKE_FREETYPE2(freetype2, REQUIRED, 0)
 103
 104 STEPMAKE_WINDOWS
 105
 106 ## Optional tools for building documentation, website, extra fonts.
 107
 108 # guile executable for some scripts
 109 STEPMAKE_GUILE(OPTIONAL)
 110
 111 # perl for help2man.
 112 STEPMAKE_PERL(OPTIONAL)
 113
 114 # New makeinfo for multi-page website docs Simply always require new
 115 # makeinfo should avoid bug reports; if people want to build lily
 116 # without the docs, they can find this comment and use an older
 117 # makeinfo--but hopefully won't report makeinfo problems.
 118 STEPMAKE_PROGS(MAKEINFO, makeinfo, REQUIRED, 4.7)
 119
 120 if test "$optimise_b" = yes; then
 121     DEFINES="$DEFINES -DSTRING_UTILS_INLINED"
 122     AC_DEFINE(STRINGS_UTILS_INLINED)
 123 fi
 124
 125 AC_DEFINE_UNQUOTED(FLOWER_VERSION, "${FULL_FLOWER_VERSION}")
 126
 127 # Gather requirements and generate output.
 128 STEPMAKE_END
 129
 130 test -n "$CONFIGURATION" && mc=" conf=$CONFIGURATION" || mc=""
 131
 132 cat <<EOF
 133
 134 Type:
 135     make$mc all       to build LilyPond
 136     make$mc install   to install LilyPond
 137     make$mc help      to see all possible targets
 138
 139 EOF