configure.ac

   1 dnl configure.ac   -*-shell-script-*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.60)
   5
   6 # Bootstrap the init process.
   7 AC_INIT
   8
   9 # Bootstrap StepMake configure
  10 AC_CONFIG_AUX_DIR([config])
  11
  12 STEPMAKE_INIT
  13
  14 # List a file that identifies your package.
  15 AC_CONFIG_SRCDIR([lily/main.cc])
  16
  17 # Move to aclocal.m4?
  18 AC_CONFIG_HEADERS([$CONFIGFILE.hh:config.hh.in])
  19
  20 # Uncomment the configuration options your package needs.
  21
  22 DOCUMENTATION=yes
  23 AC_ARG_ENABLE(documentation,
  24     [AS_HELP_STRING([--enable-documentation],
  25                     [build Documentation.  Default: on])],
  26     [DOCUMENTATION=$enableval])
  27 AC_SUBST(DOCUMENTATION)
  28
  29 GUILEv2=no
  30 AC_ARG_ENABLE(guile2,
  31     [AS_HELP_STRING([--enable-guile2],
  32                     [highly experimental GUILE 2 support.  Default: off])],
  33     [GUILEv2=$enableval])
  34
  35 AC_ARG_WITH(fonts-dir,
  36     [AS_HELP_STRING([--with-fonts-dir=DIR],
  37                     [location of URW++ fonts.])],
  38     [NCSB_DIR=$withval],
  39     [NCSB_DIR=""])
  40
  41 reloc_b=no
  42 AC_ARG_ENABLE(relocation,
  43     [AS_HELP_STRING([--enable-relocation],
  44                     [compile with dynamic relocation.  Default: off])],
  45     [reloc_b=$enableval])
  46
  47 rpath_b=no
  48 AC_ARG_ENABLE(rpath,
  49     [AS_HELP_STRING([--enable-rpath],
  50                     [hardcode runtime library path.  Default: off])],
  51     [rpath_b=$enableval])
  52
  53 LINK_GXX_STATICALLY=no
  54 AC_ARG_ENABLE(static-gxx,
  55     [AS_HELP_STRING([--enable-static-gxx],
  56                     [link libstdc++.a statically.  Default: off])],
  57     [LINK_GXX_STATICALLY=$enableval])
  58 AC_SUBST(LINK_GXX_STATICALLY)
  59
  60 # must come before any header checks
  61 STEPMAKE_COMPILE
  62
  63 AC_CHECK_PROG(FCLIST, fc-list, fc-list)
  64 AC_MSG_CHECKING([for Century Schoolbook L PFB files])
  65 AC_SUBST(NCSB_SOURCE_FILES)
  66 AC_SUBST(NCSB_DIR)
  67 if test "$NCSB_DIR" = ""; then
  68   if test "$FCLIST" != ""; then
  69     NCSB_FILE=`$FCLIST "Century Schoolbook L:foundry=urw:fontformat=Type 1:lang=ru" file \
  70               | head -n 1`
  71     if test "$NCSB_FILE" != ""; then
  72       NCSB_FILE=`echo $NCSB_FILE | sed 's/\(:.*\)$//g'`
  73       NCSB_FILE=`$PYTHON "$srcdir/scripts/auxiliar/readlink.py" $NCSB_FILE`
  74       NCSB_DIR=`AS_DIRNAME($NCSB_FILE)`
  75     fi
  76   fi
  77 fi
  78 if test "$NCSB_DIR" != "" ;  then
  79   for f in c059013l.pfb c059016l.pfb c059033l.pfb c059036l.pfb; do
  80     if test ! -f "$NCSB_DIR/$f"; then
  81       MISSING_NCSB_SOURCE_FILES="$f $MISSING_NCSB_SOURCE_FILES"
  82     else
  83       if test "`grep Cyrillic "$NCSB_DIR/$f"`" = ""; then
  84         INCOMPLETE_NCSB_SOURCE_FILES="$f $INCOMPLETE_NCSB_SOURCE_FILES"
  85       else
  86         NCSB_SOURCE_FILES="$NCSB_DIR/$f $NCSB_SOURCE_FILES"
  87       fi
  88     fi
  89   done
  90 fi
  91 if test "$NCSB_DIR" = "" -o "$MISSING_NCSB_SOURCE_FILES" != "$INCOMPLETE_NCSB_SOURCE_FILES"; then
  92   AC_MSG_RESULT(no)
  93   STEPMAKE_ADD_ENTRY(REQUIRED,International Century Schoolbook L fonts)
  94   if test "$NCSB_DIR" = ""; then
  95     if test "$FCLIST" = ""; then
  96       STEPMAKE_ADD_ENTRY(REQUIRED,'(install the fc-list utility from FontConfig, or use --with-fonts-dir)')
  97     else
  98       STEPMAKE_ADD_ENTRY(REQUIRED,'(make sure the fc-list utility can see them, or use --with-fonts-dir)')
  99     fi
 100   fi
 101   if test "$MISSING_NCSB_SOURCE_FILES" != ""; then
 102     STEPMAKE_ADD_ENTRY(REQUIRED,'(these files are missing: $MISSING_NCSB_SOURCE_FILES)')
 103   fi
 104   if test "$INCOMPLETE_NCSB_SOURCE_FILES" != ""; then
 105     STEPMAKE_ADD_ENTRY(REQUIRED,'(these files do not contain Cyrillic characters: $INCOMPLETE_NCSB_SOURCE_FILES)')
 106   fi
 107 else
 108   AC_MSG_RESULT(yes)
 109 fi
 110
 111 AC_MSG_CHECKING([for Nimbus Sans L (Helvetica) PFB files])
 112 AC_SUBST(HELV_SOURCE_FILES)
 113 if test "$NCSB_DIR" != "" ;  then
 114   for f in n019003l.pfb n019004l.pfb n019023l.pfb n019024l.pfb; do
 115     if test ! -f "$NCSB_DIR/$f"; then
 116       MISSING_HELV_SOURCE_FILES="$f $MISSING_HELV_SOURCE_FILES"
 117     else
 118       if test "`grep Cyrillic "$NCSB_DIR/$f"`" = ""; then
 119         INCOMPLETE_HELV_SOURCE_FILES="$f $INCOMPLETE_HELV_SOURCE_FILES"
 120       else
 121         HELV_SOURCE_FILES="$NCSB_DIR/$f $HELV_SOURCE_FILES"
 122       fi
 123     fi
 124   done
 125 fi
 126 if test "$NCSB_DIR" = "" -o "$MISSING_HELV_SOURCE_FILES" != "$INCOMPLETE_HELV_SOURCE_FILES"; then
 127   AC_MSG_RESULT(no)
 128   STEPMAKE_ADD_ENTRY(REQUIRED,International Nimbus Sans L fonts)
 129   if test "$MISSING_HELV_SOURCE_FILES" != ""; then
 130     STEPMAKE_ADD_ENTRY(REQUIRED,'(these files are missing: $MISSING_HELV_SOURCE_FILES)')
 131   fi
 132   if test "$INCOMPLETE_HELV_SOURCE_FILES" != ""; then
 133     STEPMAKE_ADD_ENTRY(REQUIRED,'(these files do not contain Cyrillic characters: $INCOMPLETE_HELV_SOURCE_FILES)')
 134   fi
 135 else
 136   AC_MSG_RESULT(yes)
 137 fi
 138
 139 AC_MSG_CHECKING([for Nimbus Mono L (Courier) PFB files])
 140 AC_SUBST(COUR_SOURCE_FILES)
 141 if test "$NCSB_DIR" != "" ;  then
 142   for f in n022003l.pfb n022004l.pfb n022023l.pfb n022024l.pfb; do
 143     if test ! -f "$NCSB_DIR/$f"; then
 144       MISSING_COUR_SOURCE_FILES="$f $MISSING_COUR_SOURCE_FILES"
 145     else
 146       if test "`grep Cyrillic "$NCSB_DIR/$f"`" = ""; then
 147         INCOMPLETE_COUR_SOURCE_FILES="$f $INCOMPLETE_COUR_SOURCE_FILES"
 148       else
 149         COUR_SOURCE_FILES="$NCSB_DIR/$f $COUR_SOURCE_FILES"
 150       fi
 151     fi
 152   done
 153 fi
 154 if test "$NCSB_DIR" = "" -o "$MISSING_COUR_SOURCE_FILES" != "$INCOMPLETE_COUR_SOURCE_FILES"; then
 155   AC_MSG_RESULT(no)
 156   STEPMAKE_ADD_ENTRY(REQUIRED,International Nimbus Mono L fonts)
 157   if test "$MISSING_COUR_SOURCE_FILES" != ""; then
 158     STEPMAKE_ADD_ENTRY(REQUIRED,'(these files are missing: $MISSING_COUR_SOURCE_FILES)')
 159   fi
 160   if test "$INCOMPLETE_COUR_SOURCE_FILES" != ""; then
 161     STEPMAKE_ADD_ENTRY(REQUIRED,'(these files do not contain Cyrillic characters: $INCOMPLETE_COUR_SOURCE_FILES)')
 162   fi
 163 else
 164   AC_MSG_RESULT(yes)
 165 fi
 166
 167 AC_LANG([C++])
 168
 169 STEPMAKE_PYTHON(REQUIRED, 2.4, 3.0)
 170 # this checks if we have GNU C by compiling a program with
 171 # __GNUC__, but that macro now unofficially means "the compiler
 172 # supports the GNU C extensions" -- the intel C compiler and clang
 173 # both support __GNUC__!
 174 STEPMAKE_GCC_OR_CLANG(REQUIRED, 3.4)
 175
 176 STEPMAKE_CXX(REQUIRED)
 177 STEPMAKE_GXX_OR_CLANG(REQUIRED, 3.4)
 178 STEPMAKE_GXXCODEGENBUG
 179 STEPMAKE_CXXTEMPLATE
 180 STEPMAKE_STL_DATA_METHOD
 181 STEPMAKE_LIB(REQUIRED)
 182 STEPMAKE_DLOPEN
 183 # Do not use bison 1.50 and 1.75.
 184 # 1.29 is required fr %locations, but I'm not sure it's enough --ns
 185 STEPMAKE_BISON(REQUIRED, 1.29)
 186 STEPMAKE_FLEX(REQUIRED)
 187 STEPMAKE_FLEXLEXER(REQUIRED)
 188 STEPMAKE_FLEXLEXER_LOCATION
 189 STEPMAKE_LOCALE
 190 STEPMAKE_GETTEXT
 191 STEPMAKE_MSGFMT(REQUIRED)
 192 STEPMAKE_TEXMF(REQUIRED)
 193 STEPMAKE_TEXMF_DIRS(REQUIRED)
 194 if test "$GUILEv2" = "yes"
 195 then
 196     STEPMAKE_GUILE_DEVEL(REQUIRED, 2.0.7, 2.2.0)
 197 else
 198     STEPMAKE_GUILE_DEVEL(REQUIRED, 1.8.2, 1.9.0)
 199 fi
 200
 201 # check for 3 typedefs added in Guile 1.9
 202 save_CXXFLAGS="$CXXFLAGS"
 203 CXXFLAGS="$GUILE_CFLAGS $CXXFLAGS"
 204 AC_CHECK_TYPES([scm_t_hash_fold_fn, scm_t_hash_handle_fn],
 205                [AC_DEFINE(HAVE_GUILE_HASH_FUNC)], [],
 206                [#include <libguile.h>])
 207 AC_CHECK_TYPES([scm_t_subr],
 208                [AC_DEFINE(HAVE_GUILE_SUBR_TYPE)], [],
 209                [#include <libguile.h>])
 210 CXXFLAGS="$save_CXXFLAGS"
 211
 212 ## Check for usable cxxabi
 213 save_LIBS="$LIBS"
 214 LIBS="$LIBS $CXXABI_LIBS"
 215 AC_MSG_CHECKING(for usable C++ demangler)
 216 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cxxabi.h>],
 217             [abi::__cxa_demangle ("", 0, 0, 0)])],
 218     [AC_DEFINE(HAVE_CXA_DEMANGLE)
 219         AC_MSG_RESULT(yes)],[
 220         LIBS="$LIBS -lsupc++"
 221         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cxxabi.h>],
 222                     [abi::__cxa_demangle ("", 0, 0, 0)])],
 223             [AC_DEFINE(HAVE_CXA_DEMANGLE)
 224                 AC_MSG_RESULT([yes, using -lsupc++])
 225                 CXXABI_LIBS="$CXXABI_LIBS -lsupc++"],
 226             [AC_MSG_RESULT([no, use c++filt -t for manual demangling])])])
 227 LIBS="$save_LIBS"
 228 AC_SUBST(CXXABI_LIBS)
 229
 230 ## check rational bugfix.
 231 save_CPPFLAGS="$CPPFLAGS"
 232 CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 233 AC_MSG_CHECKING(GUILE rational bugfix)
 234 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <libguile.h>
 235 #ifdef SCM_FRACTION_REDUCED_BIT
 236 #error
 237 #endif
 238 ]])],[AC_MSG_RESULT(ok)],[REQUIRED="$REQUIRED GUILE-with-rational-bugfix"
 239 AC_MSG_RESULT(Must have patched GUILE rational support. See INSTALL.txt)])
 240 CPPFLAGS="$save_CPPFLAGS"
 241
 242
 243 STEPMAKE_PYTHON_DEVEL(REQUIRED, 2.4, 3.0)
 244
 245 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, REQUIRED, 20110222)
 246
 247 STEPMAKE_PATH_PROG(T1ASM, t1asm, REQUIRED)
 248
 249 AC_CHECK_HEADERS([assert.h grp.h libio.h pwd.h sys/stat.h wchar.h fpu_control.h])
 250 AC_CHECK_HEADERS([sstream])
 251 AC_HEADER_STAT
 252 AC_FUNC_MEMCMP
 253 AC_FUNC_VPRINTF
 254 AC_CHECK_FUNCS([chroot fopencookie gettext isinf memmem snprintf vsnprintf])
 255
 256 STEPMAKE_PROGS(PKG_CONFIG, pkg-config, REQUIRED, 0.9.0)
 257
 258 AC_MSG_CHECKING(whether to enable dynamic relocation)
 259 if test "$reloc_b" = "yes"; then
 260     AC_DEFINE(ARGV0_RELOCATION)
 261 fi
 262 AC_MSG_RESULT($reloc_b)
 263
 264 AC_MSG_CHECKING(for rpath linkage)
 265 if test "$rpath_b" = "yes"; then
 266     LDFLAGS="$LDFLAGS -Wl,-rpath -Wl,\\\$\$ORIGIN/../lib"
 267 elif test "$rpath_b" != "no"; then
 268     LDFLAGS="$LDFLAGS -Wl,-rpath -Wl,$rpath_b"
 269 fi
 270 AC_MSG_RESULT($rpath_b)
 271
 272 HOST_ARCH=`$CC -dumpmachine`
 273 AC_SUBST(HOST_ARCH)
 274
 275 STEPMAKE_PANGO_FT2(pangoft2, REQUIRED, 1.6.0)
 276 STEPMAKE_FONTCONFIG(fontconfig, REQUIRED, 2.4.0)
 277 STEPMAKE_FREETYPE2(freetype2, REQUIRED, 2.1.10)
 278
 279 STEPMAKE_WINDOWS
 280
 281 # guile executable for some scripts
 282 STEPMAKE_GUILE(OPTIONAL, 1.8.2, 1.9.0)
 283
 284 # perl for help2man and for mf2pt1.pl
 285 STEPMAKE_PERL(REQUIRED)
 286
 287 ## Optional tools for building documentation, website, extra fonts.
 288 if test "$DOCUMENTATION" = "yes"; then
 289   DOCUMENTATION_REQUIRED=REQUIRED
 290 else
 291   DOCUMENTATION_REQUIRED=OPTIONAL
 292 fi
 293
 294 STEPMAKE_PATH_PROG(GHOSTSCRIPT, gs, $DOCUMENTATION_REQUIRED, 8.60)
 295
 296 STEPMAKE_PROGS(MAKEINFO, makeinfo, REQUIRED, 4.11)
 297 STEPMAKE_PROGS(TEXI2HTML, texi2html, $DOCUMENTATION_REQUIRED, 1.82)
 298 STEPMAKE_PROGS(DBLATEX, dblatex, $DOCUMENTATION_REQUIRED, 0.1.4)
 299 STEPMAKE_PROGS(BIBTEX, bibtex, $DOCUMENTATION_REQUIRED)
 300 STEPMAKE_PROGS(PDFLATEX, pdflatex, $DOCUMENTATION_REQUIRED)
 301 STEPMAKE_PROGS(PDFTEX, pdfetex pdftex etex, $DOCUMENTATION_REQUIRED)
 302 STEPMAKE_PROGS(TEXI2PDF, texi2pdf, $DOCUMENTATION_REQUIRED)
 303 STEPMAKE_PROGS(TEXINDEX, texindex, $DOCUMENTATION_REQUIRED)
 304 AC_MSG_CHECKING(for epsf.tex)
 305 TEX_EPSF=`kpsewhich tex epsf`
 306 if test "$TEX_EPSF" = ""; then
 307     AC_MSG_RESULT(not found)
 308     STEPMAKE_ADD_ENTRY($DOCUMENTATION_REQUIRED,epsf.tex)
 309 else
 310     AC_MSG_RESULT($TEX_EPSF)
 311 fi
 312 AC_MSG_CHECKING(for Cyrillic characters support in TeX)
 313 TEX_FIKPARM=`kpsewhich -format=mf fikparm`
 314 if test "$TEX_FIKPARM" = ""; then
 315     AC_MSG_RESULT(not found)
 316     STEPMAKE_ADD_ENTRY($DOCUMENTATION_REQUIRED,
 317 ['lh CTAN package (texlive-lang-cyrillic or texlive-texmf-fonts)'])
 318 else
 319     AC_MSG_RESULT(yes)
 320 fi
 321 STEPMAKE_PROGS(NETPBM, pngtopnm, $DOCUMENTATION_REQUIRED)
 322 STEPMAKE_PROGS(IMAGEMAGICK, convert, $DOCUMENTATION_REQUIRED)
 323 # this name avoids a conflict with ZIP in stepmake/aclocal.m4
 324 STEPMAKE_PROGS(ZIPDOC, zip, $DOCUMENTATION_REQUIRED)
 325 STEPMAKE_PROGS(RSYNC, rsync, $DOCUMENTATION_REQUIRED)
 326
 327 AC_DEFINE_UNQUOTED(FLOWER_VERSION, "${FULL_FLOWER_VERSION}")
 328
 329 # must also have local.make if configure fails.
 330 touch local.make
 331
 332 if test "$reloc_b$rpath_b" = "yesno"; then
 333     STEPMAKE_WARN([Using --enable-relocation without --enable-rpath.  LilyPond may have trouble finding libraries.])
 334 fi
 335
 336 # Gather requirements and generate output.
 337 STEPMAKE_END
 338
 339 test -n "$CONFIGURATION" && mc=" conf=$CONFIGURATION" || mc=""
 340
 341 if make top-doc 1>/dev/null 2>&1; then
 342     rm -f INSTALL.txt && ln Documentation/topdocs/out/INSTALL.txt .
 343     rm -f README.txt && ln Documentation/topdocs/out/README.txt .
 344 fi
 345
 346 cat <<EOF
 347
 348 Type:
 349     make$mc all       to build LilyPond
 350     make$mc install   to install LilyPond
 351     make$mc help      to see all possible targets
 352
 353 Edit local.make for local Makefile overrides.
 354
 355
 356 EOF