configure.ac

   1 dnl configure.ac   -*-shell-script-*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.60)
   5
   6 # Bootstrap the init process.
   7 AC_INIT
   8
   9 # Bootstrap StepMake configure
  10 AC_CONFIG_AUX_DIR([config])
  11
  12 STEPMAKE_INIT
  13
  14 # List a file that identifies your package.
  15 AC_CONFIG_SRCDIR([lily/main.cc])
  16
  17 # Move to aclocal.m4?
  18 AC_CONFIG_HEADERS([$CONFIGFILE.hh:config.hh.in])
  19
  20 # Uncomment the configuration options your package needs.
  21
  22 DOCUMENTATION=yes
  23 AC_ARG_ENABLE(documentation,
  24     [AS_HELP_STRING([--enable-documentation],
  25                     [build Documentation.  Default: on])],
  26     [DOCUMENTATION=$enableval])
  27 AC_SUBST(DOCUMENTATION)
  28
  29 GUILEv2=no
  30 AC_ARG_ENABLE(guile2,
  31     [AS_HELP_STRING([--enable-guile2],
  32                     [highly experimental GUILE 2 support.  Default: off])],
  33     [GUILEv2=$enableval])
  34
  35 AC_ARG_WITH(ncsb-dir,
  36     [AS_HELP_STRING([--with-ncsb-dir=DIR],
  37                     [location of Century Schoolbook fonts.])],
  38     [NCSB_DIR=$withval],
  39     [NCSB_DIR=""])
  40
  41 reloc_b=no
  42 AC_ARG_ENABLE(relocation,
  43     [AS_HELP_STRING([--enable-relocation],
  44                     [compile with dynamic relocation.  Default: off])],
  45     [reloc_b=$enableval])
  46
  47 rpath_b=no
  48 AC_ARG_ENABLE(rpath,
  49     [AS_HELP_STRING([--enable-rpath],
  50                     [hardcode runtime library path.  Default: off])],
  51     [rpath_b=$enableval])
  52
  53 LINK_GXX_STATICALLY=no
  54 AC_ARG_ENABLE(static-gxx,
  55     [AS_HELP_STRING([--enable-static-gxx],
  56                     [link libstdc++.a statically.  Default: off])],
  57     [LINK_GXX_STATICALLY=$enableval])
  58 AC_SUBST(LINK_GXX_STATICALLY)
  59
  60 # must come before any header checks
  61 STEPMAKE_COMPILE
  62
  63 AC_CHECK_PROG(FCLIST, fc-list, fc-list)
  64 AC_MSG_CHECKING([for New Century Schoolbook PFB files])
  65 AC_SUBST(NCSB_SOURCE_FILES)
  66 AC_SUBST(NCSB_DIR)
  67 if test "$NCSB_DIR" = ""; then
  68   if test "$FCLIST" != ""; then
  69     NCSB_FILE=`$FCLIST "Century Schoolbook L:foundry=urw:fontformat=Type 1:lang=ru" file \
  70               | head -n 1`
  71     if test "$NCSB_FILE" != ""; then
  72       NCSB_FILE=`echo $NCSB_FILE | sed 's/\(:.*\)$//g'`
  73       NCSB_FILE=`$PYTHON "$srcdir/scripts/auxiliar/readlink.py" $NCSB_FILE`
  74       NCSB_DIR=`AS_DIRNAME($NCSB_FILE)`
  75     fi
  76   fi
  77 fi
  78 if test "$NCSB_DIR" != "" ;  then
  79   for f in c059013l.pfb c059016l.pfb c059033l.pfb c059036l.pfb; do
  80     if test ! -f "$NCSB_DIR/$f"; then
  81       MISSING_NCSB_SOURCE_FILES="$f $MISSING_NCSB_SOURCE_FILES"
  82     else
  83       if test "`grep Cyrillic "$NCSB_DIR/$f"`" = ""; then
  84         INCOMPLETE_NCSB_SOURCE_FILES="$f $INCOMPLETE_NCSB_SOURCE_FILES"
  85       else
  86         NCSB_SOURCE_FILES="$NCSB_DIR/$f $NCSB_SOURCE_FILES"
  87       fi
  88     fi
  89   done
  90 fi
  91 if test "$NCSB_DIR" = "" -o "$MISSING_NCSB_SOURCE_FILES" != "$INCOMPLETE_NCSB_SOURCE_FILES"; then
  92   AC_MSG_RESULT(no)
  93   STEPMAKE_ADD_ENTRY(REQUIRED,International New Century Schoolbook fonts)
  94   if test "$NCSB_DIR" = ""; then
  95     if test "$FCLIST" = ""; then
  96       STEPMAKE_ADD_ENTRY(REQUIRED,'(install the fc-list utility from FontConfig, or use --with-ncsb-dir)')
  97     else
  98       STEPMAKE_ADD_ENTRY(REQUIRED,'(make sure the fc-list utility can see them, or use --with-ncsb-dir)')
  99     fi
 100   fi
 101   if test "$MISSING_NCSB_SOURCE_FILES" != ""; then
 102     STEPMAKE_ADD_ENTRY(REQUIRED,'(these files are missing: $MISSING_NCSB_SOURCE_FILES)')
 103   fi
 104   if test "$INCOMPLETE_NCSB_SOURCE_FILES" != ""; then
 105     STEPMAKE_ADD_ENTRY(REQUIRED,'(these files do not contain Cyrillic characters: $INCOMPLETE_NCSB_SOURCE_FILES)')
 106   fi
 107 else
 108   AC_MSG_RESULT(yes)
 109 fi
 110
 111 AC_LANG([C++])
 112
 113 STEPMAKE_PYTHON(REQUIRED, 2.4, 3.0)
 114 # this checks if we have GNU C by compiling a program with
 115 # __GNUC__, but that macro now unofficially means "the compiler
 116 # supports the GNU C extensions" -- the intel C compiler and clang
 117 # both support __GNUC__!
 118 STEPMAKE_GCC_OR_CLANG(REQUIRED, 3.4)
 119
 120 STEPMAKE_CXX(REQUIRED)
 121 STEPMAKE_GXX_OR_CLANG(REQUIRED, 3.4)
 122 STEPMAKE_GXXCODEGENBUG
 123 STEPMAKE_CXXTEMPLATE
 124 STEPMAKE_STL_DATA_METHOD
 125 STEPMAKE_LIB(REQUIRED)
 126 STEPMAKE_DLOPEN
 127 # Do not use bison 1.50 and 1.75.
 128 # 1.29 is required fr %locations, but I'm not sure it's enough --ns
 129 STEPMAKE_BISON(REQUIRED, 1.29)
 130 STEPMAKE_FLEX(REQUIRED)
 131 STEPMAKE_FLEXLEXER(REQUIRED)
 132 STEPMAKE_FLEXLEXER_LOCATION
 133 STEPMAKE_LOCALE
 134 STEPMAKE_GETTEXT
 135 STEPMAKE_MSGFMT(REQUIRED)
 136 STEPMAKE_TEXMF(REQUIRED)
 137 STEPMAKE_TEXMF_DIRS(REQUIRED)
 138 if test "$GUILEv2" = "yes"
 139 then
 140     STEPMAKE_GUILE_DEVEL(REQUIRED, 2.0.7, 2.2.0)
 141 else
 142     STEPMAKE_GUILE_DEVEL(REQUIRED, 1.8.2, 1.9.0)
 143 fi
 144
 145 # check for 3 typedefs added in Guile 1.9
 146 save_CXXFLAGS="$CXXFLAGS"
 147 CXXFLAGS="$GUILE_CFLAGS $CXXFLAGS"
 148 AC_CHECK_TYPES([scm_t_hash_fold_fn, scm_t_hash_handle_fn],
 149                [AC_DEFINE(HAVE_GUILE_HASH_FUNC)], [],
 150                [#include <libguile.h>])
 151 AC_CHECK_TYPES([scm_t_subr],
 152                [AC_DEFINE(HAVE_GUILE_SUBR_TYPE)], [],
 153                [#include <libguile.h>])
 154 CXXFLAGS="$save_CXXFLAGS"
 155
 156 ## Check for usable cxxabi
 157 save_LIBS="$LIBS"
 158 LIBS="$LIBS $CXXABI_LIBS"
 159 AC_MSG_CHECKING(for usable C++ demangler)
 160 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cxxabi.h>],
 161             [abi::__cxa_demangle ("", 0, 0, 0)])],
 162     [AC_DEFINE(HAVE_CXA_DEMANGLE)
 163         AC_MSG_RESULT(yes)],[
 164         LIBS="$LIBS -lsupc++"
 165         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cxxabi.h>],
 166                     [abi::__cxa_demangle ("", 0, 0, 0)])],
 167             [AC_DEFINE(HAVE_CXA_DEMANGLE)
 168                 AC_MSG_RESULT([yes, using -lsupc++])
 169                 CXXABI_LIBS="$CXXABI_LIBS -lsupc++"],
 170             [AC_MSG_RESULT([no, use c++filt -t for manual demangling])])])
 171 LIBS="$save_LIBS"
 172 AC_SUBST(CXXABI_LIBS)
 173
 174 ## check rational bugfix.
 175 save_CPPFLAGS="$CPPFLAGS"
 176 CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 177 AC_MSG_CHECKING(GUILE rational bugfix)
 178 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <libguile.h>
 179 #ifdef SCM_FRACTION_REDUCED_BIT
 180 #error
 181 #endif
 182 ]])],[AC_MSG_RESULT(ok)],[REQUIRED="$REQUIRED GUILE-with-rational-bugfix"
 183 AC_MSG_RESULT(Must have patched GUILE rational support. See INSTALL.txt)])
 184 CPPFLAGS="$save_CPPFLAGS"
 185
 186
 187 STEPMAKE_PYTHON_DEVEL(REQUIRED, 2.4, 3.0)
 188
 189 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, REQUIRED, 20110222)
 190
 191 STEPMAKE_PATH_PROG(T1ASM, t1asm, REQUIRED)
 192
 193 AC_CHECK_HEADERS([assert.h grp.h libio.h pwd.h sys/stat.h wchar.h fpu_control.h])
 194 AC_CHECK_HEADERS([sstream])
 195 AC_HEADER_STAT
 196 AC_FUNC_MEMCMP
 197 AC_FUNC_VPRINTF
 198 AC_CHECK_FUNCS([chroot fopencookie gettext isinf memmem snprintf vsnprintf])
 199
 200 STEPMAKE_PROGS(PKG_CONFIG, pkg-config, REQUIRED, 0.9.0)
 201
 202 AC_MSG_CHECKING(whether to enable dynamic relocation)
 203 if test "$reloc_b" = "yes"; then
 204     AC_DEFINE(ARGV0_RELOCATION)
 205 fi
 206 AC_MSG_RESULT($reloc_b)
 207
 208 AC_MSG_CHECKING(for rpath linkage)
 209 if test "$rpath_b" = "yes"; then
 210     LDFLAGS="$LDFLAGS -Wl,-rpath -Wl,\\\$\$ORIGIN/../lib"
 211 elif test "$rpath_b" != "no"; then
 212     LDFLAGS="$LDFLAGS -Wl,-rpath -Wl,$rpath_b"
 213 fi
 214 AC_MSG_RESULT($rpath_b)
 215
 216 HOST_ARCH=`$CC -dumpmachine`
 217 AC_SUBST(HOST_ARCH)
 218
 219 STEPMAKE_PANGO_FT2(pangoft2, REQUIRED, 1.6.0)
 220 STEPMAKE_FONTCONFIG(fontconfig, REQUIRED, 2.4.0)
 221 STEPMAKE_FREETYPE2(freetype2, REQUIRED, 2.1.10)
 222
 223 STEPMAKE_WINDOWS
 224
 225 # guile executable for some scripts
 226 STEPMAKE_GUILE(OPTIONAL, 1.8.2, 1.9.0)
 227
 228 # perl for help2man and for mf2pt1.pl
 229 STEPMAKE_PERL(REQUIRED)
 230
 231 ## Optional tools for building documentation, website, extra fonts.
 232 if test "$DOCUMENTATION" = "yes"; then
 233   DOCUMENTATION_REQUIRED=REQUIRED
 234 else
 235   DOCUMENTATION_REQUIRED=OPTIONAL
 236 fi
 237
 238 STEPMAKE_PATH_PROG(GHOSTSCRIPT, gs, $DOCUMENTATION_REQUIRED, 8.60)
 239
 240 STEPMAKE_PROGS(MAKEINFO, makeinfo, REQUIRED, 4.11)
 241 STEPMAKE_PROGS(TEXI2HTML, texi2html, $DOCUMENTATION_REQUIRED, 1.82)
 242 STEPMAKE_PROGS(DBLATEX, dblatex, $DOCUMENTATION_REQUIRED, 0.1.4)
 243 STEPMAKE_PROGS(BIBTEX, bibtex, $DOCUMENTATION_REQUIRED)
 244 STEPMAKE_PROGS(PDFLATEX, pdflatex, $DOCUMENTATION_REQUIRED)
 245 STEPMAKE_PROGS(PDFTEX, pdfetex pdftex etex, $DOCUMENTATION_REQUIRED)
 246 STEPMAKE_PROGS(TEXI2PDF, texi2pdf, $DOCUMENTATION_REQUIRED)
 247 STEPMAKE_PROGS(TEXINDEX, texindex, $DOCUMENTATION_REQUIRED)
 248 AC_MSG_CHECKING(for epsf.tex)
 249 TEX_EPSF=`kpsewhich tex epsf`
 250 if test "$TEX_EPSF" = ""; then
 251     AC_MSG_RESULT(not found)
 252     STEPMAKE_ADD_ENTRY($DOCUMENTATION_REQUIRED,epsf.tex)
 253 else
 254     AC_MSG_RESULT($TEX_EPSF)
 255 fi
 256 AC_MSG_CHECKING(for Cyrillic characters support in TeX)
 257 TEX_FIKPARM=`kpsewhich -format=mf fikparm`
 258 if test "$TEX_FIKPARM" = ""; then
 259     AC_MSG_RESULT(not found)
 260     STEPMAKE_ADD_ENTRY($DOCUMENTATION_REQUIRED,
 261 ['lh CTAN package (texlive-lang-cyrillic or texlive-texmf-fonts)'])
 262 else
 263     AC_MSG_RESULT(yes)
 264 fi
 265 STEPMAKE_PROGS(NETPBM, pngtopnm, $DOCUMENTATION_REQUIRED)
 266 STEPMAKE_PROGS(IMAGEMAGICK, convert, $DOCUMENTATION_REQUIRED)
 267 # this name avoids a conflict with ZIP in stepmake/aclocal.m4
 268 STEPMAKE_PROGS(ZIPDOC, zip, $DOCUMENTATION_REQUIRED)
 269 STEPMAKE_PROGS(RSYNC, rsync, $DOCUMENTATION_REQUIRED)
 270
 271 AC_DEFINE_UNQUOTED(FLOWER_VERSION, "${FULL_FLOWER_VERSION}")
 272
 273 # must also have local.make if configure fails.
 274 touch local.make
 275
 276 if test "$reloc_b$rpath_b" = "yesno"; then
 277     STEPMAKE_WARN([Using --enable-relocation without --enable-rpath.  LilyPond may have trouble finding libraries.])
 278 fi
 279
 280 # Gather requirements and generate output.
 281 STEPMAKE_END
 282
 283 test -n "$CONFIGURATION" && mc=" conf=$CONFIGURATION" || mc=""
 284
 285 if make top-doc 1>/dev/null 2>&1; then
 286     rm -f INSTALL.txt && ln Documentation/topdocs/out/INSTALL.txt .
 287     rm -f README.txt && ln Documentation/topdocs/out/README.txt .
 288 fi
 289
 290 cat <<EOF
 291
 292 Type:
 293     make$mc all       to build LilyPond
 294     make$mc install   to install LilyPond
 295     make$mc help      to see all possible targets
 296
 297 Edit local.make for local Makefile overrides.
 298
 299
 300 EOF