configure.ac

   1 dnl configure.ac   -*-shell-script-*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.60)
   5
   6 # Bootstrap the init process.
   7 AC_INIT
   8
   9 # Bootstrap StepMake configure
  10 AC_CONFIG_AUX_DIR([config])
  11
  12 STEPMAKE_INIT
  13
  14 # List a file that identifies your package.
  15 AC_CONFIG_SRCDIR([lily/main.cc])
  16
  17 # Move to aclocal.m4?
  18 AC_CONFIG_HEADERS([$CONFIGFILE.hh:config.hh.in])
  19
  20 # Uncomment the configuration options your package needs.
  21
  22 DOCUMENTATION=yes
  23 AC_ARG_ENABLE(documentation,
  24     [AS_HELP_STRING([--enable-documentation],
  25                     [build Documentation.  Default: on])],
  26     [DOCUMENTATION=$enableval])
  27 AC_SUBST(DOCUMENTATION)
  28
  29 AC_ARG_WITH(ncsb-dir,
  30     [AS_HELP_STRING([--with-ncsb-dir=DIR],
  31                     [location of Century Schoolbook fonts.])],
  32     [NCSB_DIR=$withval],
  33     [NCSB_DIR=""])
  34
  35 reloc_b=no
  36 AC_ARG_ENABLE(relocation,
  37     [AS_HELP_STRING([--enable-relocation],
  38                     [compile with dynamic relocation.  Default: off])],
  39     [reloc_b=$enableval])
  40
  41 rpath_b=no
  42 AC_ARG_ENABLE(rpath,
  43     [AS_HELP_STRING([--enable-rpath],
  44                     [hardcode runtime library path.  Default: off])],
  45     [rpath_b=$enableval])
  46
  47 LINK_GXX_STATICALLY=no
  48 AC_ARG_ENABLE(static-gxx,
  49     [AS_HELP_STRING([--enable-static-gxx],
  50                     [link libstdc++.a statically.  Default: off])],
  51     [LINK_GXX_STATICALLY=$enableval])
  52 AC_SUBST(LINK_GXX_STATICALLY)
  53
  54 # must come before any header checks
  55 STEPMAKE_COMPILE
  56
  57 AC_CHECK_PROG(FCLIST, fc-list, fc-list)
  58 AC_MSG_CHECKING([New Century Schoolbook PFB files])
  59 AC_SUBST(NCSB_SOURCE_FILES)
  60 AC_SUBST(NCSB_DIR)
  61 UNCHECKED_NCSB_SOURCE_FILES=""
  62 if test "$NCSB_DIR" != "" ;  then
  63   for f in c059013l c059016l c059033l c059036l; do
  64     if test ! -f "$NCSB_DIR/$f.pfb"; then
  65       STEPMAKE_WARN($NCSB_DIR does not contain $f.pfb.)
  66     else
  67       UNCHECKED_NCSB_SOURCE_FILES="$NCSB_DIR/$f.pfb $UNCHECKED_NCSB_SOURCE_FILES"
  68     fi
  69   done
  70 else
  71   if test "$FCLIST" != ""; then
  72     for style in Roman Italic "Bold Italic" Bold; do
  73       NCSB_FILE=`$FCLIST "Century Schoolbook L:style=$style:foundry=urw:fontformat=Type 1" file \
  74                 | head -n 1`
  75       NCSB_FILE=`echo $NCSB_FILE | sed 's/\(:.*\)$//g'`
  76       NCSB_FILE=`$PYTHON "$srcdir/scripts/auxiliar/readlink.py" $NCSB_FILE`
  77       UNCHECKED_NCSB_SOURCE_FILES="$NCSB_FILE $UNCHECKED_NCSB_SOURCE_FILES"
  78     done
  79     NCSB_DIR=`AS_DIRNAME($NCSB_FILE)`
  80   else
  81     AC_MSG_RESULT(not found)
  82     echo "Can't find Century Schoolbook files. Install FontConfig's fc-list,"
  83     echo "or use --with-ncsb-dir"
  84     STEPMAKE_ADD_ENTRY(REQUIRED,International New Century Schoolbook fonts)
  85   fi
  86 fi
  87 NCSB_SOURCE_FILES=""
  88 for f in $UNCHECKED_NCSB_SOURCE_FILES; do
  89   if test "`grep Cyrillic "$f"`" = ""; then
  90     STEPMAKE_WARN($f does not have Cyrillic characters.)
  91     STEPMAKE_ADD_ENTRY(REQUIRED,International New Century Schoolbook fonts)
  92   else
  93     NCSB_SOURCE_FILES="$f $NCSB_SOURCE_FILES"
  94   fi
  95 done
  96 AC_MSG_RESULT($NCSB_SOURCE_FILES)
  97
  98 AC_LANG([C++])
  99
 100 STEPMAKE_PYTHON(REQUIRED, 2.4)
 101 # this checks if we have GNU C by compiling a program with
 102 # __GNUC__, but that macro now unofficially means "the compiler
 103 # supports the GNU C extensions" -- the intel C compiler and clang
 104 # both support __GNUC__!
 105 STEPMAKE_GCC_OR_CLANG(REQUIRED, 3.4)
 106
 107 STEPMAKE_CXX(REQUIRED)
 108 STEPMAKE_GXX_OR_CLANG(REQUIRED, 3.4)
 109 STEPMAKE_GXXCODEGENBUG
 110 STEPMAKE_CXXTEMPLATE
 111 STEPMAKE_STL_DATA_METHOD
 112 STEPMAKE_LIB(REQUIRED)
 113 STEPMAKE_DLOPEN
 114 # Do not use bison 1.50 and 1.75.
 115 # 1.29 is required fr %locations, but I'm not sure it's enough --ns
 116 STEPMAKE_BISON(OPTIONAL, 1.29)
 117 STEPMAKE_FLEX(REQUIRED)
 118 STEPMAKE_FLEXLEXER(REQUIRED)
 119 STEPMAKE_FLEXLEXER_LOCATION
 120 STEPMAKE_LOCALE
 121 STEPMAKE_GETTEXT
 122 STEPMAKE_MSGFMT(REQUIRED)
 123 STEPMAKE_TEXMF(REQUIRED)
 124 STEPMAKE_TEXMF_DIRS(REQUIRED)
 125 STEPMAKE_GUILE_DEVEL(REQUIRED, 1.8.2)
 126
 127 # check for 3 typedefs added in Guile 1.9
 128 save_CXXFLAGS="$CXXFLAGS"
 129 CXXFLAGS="$GUILE_CFLAGS $CXXFLAGS"
 130 AC_CHECK_TYPES([scm_t_hash_fold_fn, scm_t_hash_handle_fn],
 131                [AC_DEFINE(HAVE_GUILE_HASH_FUNC)], [],
 132                [#include <libguile.h>])
 133 AC_CHECK_TYPES([scm_t_subr],
 134                [AC_DEFINE(HAVE_GUILE_SUBR_TYPE)], [],
 135                [#include <libguile.h>])
 136 CXXFLAGS="$save_CXXFLAGS"
 137
 138 ## Check for usable cxxabi
 139 save_LIBS="$LIBS"
 140 LIBS="$LIBS $CXXABI_LIBS"
 141 AC_MSG_CHECKING(for usable C++ demangler)
 142 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cxxabi.h>],
 143             [abi::__cxa_demangle ("", 0, 0, 0)])],
 144     [AC_DEFINE(HAVE_CXA_DEMANGLE)
 145         AC_MSG_RESULT(yes)],[
 146         LIBS="$LIBS -lsupc++"
 147         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cxxabi.h>],
 148                     [abi::__cxa_demangle ("", 0, 0, 0)])],
 149             [AC_DEFINE(HAVE_CXA_DEMANGLE)
 150                 AC_MSG_RESULT([yes, using -lsupc++])
 151                 CXXABI_LIBS="$CXXABI_LIBS -lsupc++"],
 152             [AC_MSG_RESULT([no, use c++filt -t for manual demangling])])])
 153 LIBS="$save_LIBS"
 154 AC_SUBST(CXXABI_LIBS)
 155
 156 ## check rational bugfix.
 157 save_CPPFLAGS="$CPPFLAGS"
 158 CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 159 AC_MSG_CHECKING(GUILE rational bugfix)
 160 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <libguile.h>
 161 #ifdef SCM_FRACTION_REDUCED_BIT
 162 #error
 163 #endif
 164 ]])],[AC_MSG_RESULT(ok)],[REQUIRED="$REQUIRED GUILE-with-rational-bugfix"
 165 AC_MSG_RESULT(Must have patched GUILE rational support. See INSTALL.txt)])
 166 CPPFLAGS="$save_CPPFLAGS"
 167
 168
 169 STEPMAKE_PYTHON_DEVEL(REQUIRED)
 170
 171 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, REQUIRED, 20110222)
 172
 173 STEPMAKE_PATH_PROG(T1ASM, t1asm, REQUIRED)
 174
 175 AC_CHECK_HEADERS([assert.h grp.h libio.h pwd.h sys/stat.h wchar.h fpu_control.h])
 176 AC_CHECK_HEADERS([sstream])
 177 AC_HEADER_STAT
 178 AC_FUNC_MEMCMP
 179 AC_FUNC_VPRINTF
 180 AC_CHECK_FUNCS([chroot fopencookie gettext isinf memmem snprintf vsnprintf])
 181
 182 STEPMAKE_PROGS(PKG_CONFIG, pkg-config, REQUIRED, 0.9.0)
 183
 184 AC_MSG_CHECKING(whether to enable dynamic relocation)
 185 if test "$reloc_b" = "yes"; then
 186     AC_DEFINE(ARGV0_RELOCATION)
 187 fi
 188 AC_MSG_RESULT($reloc_b)
 189
 190 AC_MSG_CHECKING(for rpath linkage)
 191 if test "$rpath_b" = "yes"; then
 192     LDFLAGS="$LDFLAGS -Wl,-rpath -Wl,\\\$\$ORIGIN/../lib"
 193 elif test "$rpath_b" != "no"; then
 194     LDFLAGS="$LDFLAGS -Wl,-rpath -Wl,$rpath_b"
 195 fi
 196 AC_MSG_RESULT($rpath_b)
 197
 198 HOST_ARCH=`$CC -dumpmachine`
 199 AC_SUBST(HOST_ARCH)
 200
 201 STEPMAKE_PANGO_FT2(pangoft2, REQUIRED, 1.6.0)
 202 STEPMAKE_FONTCONFIG(fontconfig, REQUIRED, 2.4.0)
 203 STEPMAKE_FREETYPE2(freetype2, REQUIRED, 2.1.10)
 204
 205 STEPMAKE_WINDOWS
 206
 207 # guile executable for some scripts
 208 STEPMAKE_GUILE(OPTIONAL)
 209
 210 # perl for help2man.
 211 STEPMAKE_PERL(OPTIONAL)
 212
 213 ## Optional tools for building documentation, website, extra fonts.
 214 if test "$DOCUMENTATION" = "yes"; then
 215   DOCUMENTATION_REQUIRED=REQUIRED
 216 else
 217   DOCUMENTATION_REQUIRED=OPTIONAL
 218 fi
 219
 220 STEPMAKE_PATH_PROG(GHOSTSCRIPT, gs, $DOCUMENTATION_REQUIRED, 8.60)
 221
 222 STEPMAKE_PROGS(MAKEINFO, makeinfo, REQUIRED, 4.11)
 223 STEPMAKE_PROGS(TEXI2HTML, texi2html, $DOCUMENTATION_REQUIRED, 1.82)
 224 STEPMAKE_PROGS(DBLATEX, dblatex, $DOCUMENTATION_REQUIRED, 0.1.4)
 225 STEPMAKE_PROGS(BIBTEX, bibtex, $DOCUMENTATION_REQUIRED)
 226 STEPMAKE_PROGS(PDFLATEX, pdflatex, $DOCUMENTATION_REQUIRED)
 227 STEPMAKE_PROGS(PDFTEX, pdfetex pdftex etex, $DOCUMENTATION_REQUIRED)
 228 STEPMAKE_PROGS(TEXI2PDF, texi2pdf, $DOCUMENTATION_REQUIRED)
 229 STEPMAKE_PROGS(TEXINDEX, texindex, $DOCUMENTATION_REQUIRED)
 230 AC_MSG_CHECKING(for epsf.tex)
 231 TEX_EPSF=`kpsewhich tex epsf`
 232 if test "$TEX_EPSF" = ""; then
 233     AC_MSG_RESULT(not found)
 234     STEPMAKE_ADD_ENTRY($DOCUMENTATION_REQUIRED,epsf.tex)
 235 else
 236     AC_MSG_RESULT($TEX_EPSF)
 237 fi
 238 AC_MSG_CHECKING(for Cyrillic characters support in TeX)
 239 TEX_FIKPARM=`kpsewhich -format=mf fikparm`
 240 if test "$TEX_FIKPARM" = ""; then
 241     AC_MSG_RESULT(not found)
 242     STEPMAKE_ADD_ENTRY($DOCUMENTATION_REQUIRED,
 243 ['lh CTAN package (texlive-lang-cyrillic or texlive-texmf-fonts)'])
 244 else
 245     AC_MSG_RESULT(yes)
 246 fi
 247 STEPMAKE_PROGS(NETPBM, pngtopnm, $DOCUMENTATION_REQUIRED)
 248 STEPMAKE_PROGS(IMAGEMAGICK, convert, $DOCUMENTATION_REQUIRED)
 249 # this name avoids a conflict with ZIP in stepmake/aclocal.m4
 250 STEPMAKE_PROGS(ZIPDOC, zip, $DOCUMENTATION_REQUIRED)
 251 STEPMAKE_PROGS(RSYNC, rsync, $DOCUMENTATION_REQUIRED)
 252
 253 AC_DEFINE_UNQUOTED(FLOWER_VERSION, "${FULL_FLOWER_VERSION}")
 254
 255 # must also have local.make if configure fails.
 256 touch local.make
 257
 258 if test "$reloc_b$rpath_b" = "yesno"; then
 259     STEPMAKE_WARN([Using --enable-relocation without --enable-rpath.  LilyPond may have trouble finding libraries.])
 260 fi
 261
 262 # Gather requirements and generate output.
 263 STEPMAKE_END
 264
 265 test -n "$CONFIGURATION" && mc=" conf=$CONFIGURATION" || mc=""
 266
 267 if make top-doc 1>/dev/null 2>&1; then
 268     rm -f INSTALL.txt && ln Documentation/topdocs/out/INSTALL.txt .
 269     rm -f README.txt && ln Documentation/topdocs/out/README.txt .
 270 fi
 271
 272 cat <<EOF
 273
 274 Type:
 275     make$mc all       to build LilyPond
 276     make$mc install   to install LilyPond
 277     make$mc help      to see all possible targets
 278
 279 Edit local.make for local Makefile overrides.
 280
 281
 282 EOF