configure.ac

   1 dnl configure.ac   -*-shell-script-*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.60)
   5
   6 # Bootstrap the init process.
   7 AC_INIT
   8
   9 # Bootstrap StepMake configure
  10 AC_CONFIG_AUX_DIR([config])
  11
  12 STEPMAKE_INIT
  13
  14 # List a file that identifies your package.
  15 AC_CONFIG_SRCDIR([lily/main.cc])
  16
  17 # Move to aclocal.m4?
  18 AC_CONFIG_HEADERS([$CONFIGFILE.hh:config.hh.in])
  19
  20 # Uncomment the configuration options your package needs.
  21
  22 DOCUMENTATION=yes
  23 AC_ARG_ENABLE(documentation,
  24     [AS_HELP_STRING([--enable-documentation],
  25                     [build Documentation.  Default: on])],
  26     [DOCUMENTATION=$enableval])
  27 AC_SUBST(DOCUMENTATION)
  28
  29 GUILEv2=no
  30 AC_ARG_ENABLE(guile2,
  31     [AS_HELP_STRING([--enable-guile2],
  32                     [highly experimental GUILE 2 support.  Default: off])],
  33     [GUILEv2=$enableval])
  34
  35 AC_ARG_WITH(texgyre-dir,
  36     [AS_HELP_STRING([--with-texgyre-dir=DIR],
  37                     [location of TeX Gyre fonts.])],
  38     [TEXGYRE_DIR=$withval],
  39     [TEXGYRE_DIR=""])
  40
  41 AC_ARG_WITH(urwotf-dir,
  42     [AS_HELP_STRING([--with-urwotf-dir=DIR],
  43                     [location of URW++ OTF fonts.])],
  44     [URWOTF_DIR=$withval],
  45     [URWOTF_DIR=""])
  46
  47 reloc_b=no
  48 AC_ARG_ENABLE(relocation,
  49     [AS_HELP_STRING([--enable-relocation],
  50                     [compile with dynamic relocation.  Default: off])],
  51     [reloc_b=$enableval])
  52
  53 rpath_b=no
  54 AC_ARG_ENABLE(rpath,
  55     [AS_HELP_STRING([--enable-rpath],
  56                     [hardcode runtime library path.  Default: off])],
  57     [rpath_b=$enableval])
  58
  59 LINK_GXX_STATICALLY=no
  60 AC_ARG_ENABLE(static-gxx,
  61     [AS_HELP_STRING([--enable-static-gxx],
  62                     [link libstdc++.a statically.  Default: off])],
  63     [LINK_GXX_STATICALLY=$enableval])
  64 AC_SUBST(LINK_GXX_STATICALLY)
  65
  66 # must come before any header checks
  67 STEPMAKE_COMPILE
  68
  69 AC_CHECK_PROG(FCLIST, fc-list, fc-list)
  70 AC_MSG_CHECKING([for TeX Gyre fonts OTF files])
  71 AC_SUBST(TEXGYRE_DIR)
  72 AC_SUBST(TEXGYRE_FILES)
  73 if test "$TEXGYRE_DIR" = ""; then
  74   if test "$FCLIST" != ""; then
  75     TEXGYRE_FILE=`$FCLIST "TeX Gyre Schola:fontformat=CFF" file | head -n 1`
  76     if test "$TEXGYRE_FILE" != ""; then
  77       TEXGYRE_FILE=`echo $TEXGYRE_FILE | sed 's/\(:.*\)$//g'`
  78       TEXGYRE_FILE=`$PYTHON "$srcdir/scripts/auxiliar/readlink.py" $TEXGYRE_FILE`
  79       TEXGYRE_DIR=`AS_DIRNAME($TEXGYRE_FILE)`
  80     fi
  81   fi
  82 fi
  83 if test "$TEXGYRE_DIR" != "" ;  then
  84   for f in texgyreschola-regular.otf texgyreschola-italic.otf \
  85            texgyreschola-bold.otf texgyreschola-bolditalic.otf \
  86            texgyreheros-regular.otf texgyreheros-italic.otf \
  87            texgyreheros-bold.otf texgyreheros-bolditalic.otf \
  88            texgyrecursor-regular.otf texgyrecursor-italic.otf \
  89            texgyrecursor-bold.otf texgyrecursor-bolditalic.otf; do
  90     if test ! -f "$TEXGYRE_DIR/$f"; then
  91       MISSING_TEXGYRE_FILES="$MISSING_TEXGYRE_FILES $f"
  92     else
  93       TEXGYRE_FILES="$TEXGYRE_FILES $f"
  94     fi
  95   done
  96 fi
  97 if test "$TEXGYRE_DIR" = "" -o "$MISSING_TEXGYRE_FILES" != ""; then
  98   AC_MSG_RESULT(no)
  99   STEPMAKE_ADD_ENTRY(REQUIRED,TeX Gyre fonts OTF)
 100   if test "$TEXGYRE_DIR" = ""; then
 101     if test "$FCLIST" = ""; then
 102       STEPMAKE_ADD_ENTRY(REQUIRED,'(install the fc-list utility from FontConfig, or use --with-texgyre-dir)')
 103     else
 104       STEPMAKE_ADD_ENTRY(REQUIRED,"(make sure the fc-list utility can see them, e.g. 'sudo apt-get install fonts-texgyre', or use --with-texgyre-dir)")
 105     fi
 106   else
 107     STEPMAKE_ADD_ENTRY(REQUIRED,'(these files are missing: $MISSING_TEXGYRE_FILES)')
 108   fi
 109 else
 110   AC_MSG_RESULT(yes)
 111 fi
 112 AC_MSG_CHECKING([for URW++ OTF files])
 113 AC_SUBST(URWOTF_DIR)
 114 AC_SUBST(URWOTF_FILES)
 115 if test "$URWOTF_DIR" = ""; then
 116   if test "$FCLIST" != ""; then
 117     URWOTF_FILE=`$FCLIST "C059:fontformat=CFF" file | head -n 1`
 118     if test "$URWOTF_FILE" != ""; then
 119       URWOTF_FILE=`echo $URWOTF_FILE | sed 's/\(:.*\)$//g'`
 120       URWOTF_FILE=`$PYTHON "$srcdir/scripts/auxiliar/readlink.py" $URWOTF_FILE`
 121       URWOTF_DIR=`AS_DIRNAME($URWOTF_FILE)`
 122     fi
 123   fi
 124 fi
 125 if test "$URWOTF_DIR" != "" ;  then
 126   for f in C059-BdIta.otf C059-Bold.otf \
 127            C059-Italic.otf C059-Roman.otf \
 128            NimbusMonoPS-Bold.otf NimbusMonoPS-BoldItalic.otf \
 129            NimbusMonoPS-Italic.otf NimbusMonoPS-Regular.otf \
 130            NimbusSans-Bold.otf NimbusSans-BoldItalic.otf \
 131            NimbusSans-Italic.otf NimbusSans-Regular.otf; do
 132     if test ! -f "$URWOTF_DIR/$f"; then
 133       MISSING_URWOTF_FILES="$MISSING_URWOTF_FILES $f"
 134     else
 135       URWOTF_FILES="$URWOTF_FILES $f"
 136     fi
 137   done
 138 fi
 139 if test "$MISSING_URWOTF_FILES"="NimbusSans-BoldItalic.otf NimbusSans-Italic.otf" && \
 140    test -f "$URWOTF_DIR/NimbusSans-BoldOblique.otf" && \
 141    test -f "$URWOTF_DIR/NimbusSans-Oblique.otf"; then
 142   MISSING_URWOTF_FILES=""
 143   URWOTF_FILES="$URWOTF_FILES NimbusSans-BoldOblique.otf NimbusSans-Oblique.otf"
 144 fi
 145 if test "$URWOTF_DIR" = "" -o "$MISSING_URWOTF_FILES" != ""; then
 146   AC_MSG_RESULT(no)
 147   STEPMAKE_ADD_ENTRY(OPTIONAL,URW++ OTF fonts)
 148   if test "$URWOTF_DIR" = ""; then
 149     if test "$FCLIST" = ""; then
 150       STEPMAKE_ADD_ENTRY(OPTIONAL,'(install the fc-list utility from FontConfig, or use --with-urwotf-dir)')
 151     else
 152       STEPMAKE_ADD_ENTRY(OPTIONAL,"(download OTF files from 'http://git.ghostscript.com/?p=urw-core35-fonts.git;a=tree;hb=1f28a6fcd2176256a995db907d9ffe6e1b9b83e9' and put them under '~/.local/share/fonts' etc., or use --with-urwotf-dir)")
 153     fi
 154   else
 155     STEPMAKE_ADD_ENTRY(OPTIONAL,'(these files are missing: $MISSING_URWOTF_FILES)')
 156   fi
 157 else
 158   AC_MSG_RESULT(yes)
 159 fi
 160
 161 AC_LANG([C++])
 162
 163 STEPMAKE_PYTHON(REQUIRED, 2.4, 3.0)
 164 # this checks if we have GNU C by compiling a program with
 165 # __GNUC__, but that macro now unofficially means "the compiler
 166 # supports the GNU C extensions" -- the intel C compiler and clang
 167 # both support __GNUC__!
 168 STEPMAKE_GCC_OR_CLANG(REQUIRED, 3.4)
 169
 170 STEPMAKE_CXX(REQUIRED)
 171 STEPMAKE_GXX_OR_CLANG(REQUIRED, 3.4)
 172 STEPMAKE_GXXCODEGENBUG
 173 STEPMAKE_CXXTEMPLATE
 174 STEPMAKE_STL_DATA_METHOD
 175 STEPMAKE_LIB(REQUIRED)
 176 STEPMAKE_DLOPEN
 177 # Do not use bison 1.50 and 1.75.
 178 # 1.29 is required fr %locations, but I'm not sure it's enough --ns
 179 STEPMAKE_BISON(REQUIRED, 1.29)
 180 STEPMAKE_FLEX(REQUIRED)
 181 STEPMAKE_FLEXLEXER(REQUIRED)
 182 STEPMAKE_FLEXLEXER_LOCATION
 183 STEPMAKE_LOCALE
 184 STEPMAKE_GETTEXT
 185 STEPMAKE_MSGFMT(REQUIRED)
 186 STEPMAKE_TEXMF(REQUIRED)
 187 STEPMAKE_TEXMF_DIRS(REQUIRED)
 188 if test "$GUILEv2" = "yes"
 189 then
 190     STEPMAKE_GUILE_DEVEL(REQUIRED, 2.0.7, 2.3.0)
 191 else
 192     STEPMAKE_GUILE_DEVEL(REQUIRED, 1.8.2, 1.9.0)
 193 fi
 194
 195 # check for 3 typedefs added in Guile 1.9
 196 save_CXXFLAGS="$CXXFLAGS"
 197 CXXFLAGS="$GUILE_CFLAGS $CXXFLAGS"
 198 AC_CHECK_TYPES([scm_t_hash_fold_fn, scm_t_hash_handle_fn],
 199                [AC_DEFINE(HAVE_GUILE_HASH_FUNC)], [],
 200                [#include <libguile.h>])
 201 AC_CHECK_TYPES([scm_t_subr],
 202                [AC_DEFINE(HAVE_GUILE_SUBR_TYPE)], [],
 203                [#include <libguile.h>])
 204 CXXFLAGS="$save_CXXFLAGS"
 205
 206 ## Check for usable cxxabi
 207 save_LIBS="$LIBS"
 208 LIBS="$LIBS $CXXABI_LIBS"
 209 AC_MSG_CHECKING(for usable C++ demangler)
 210 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cxxabi.h>],
 211             [abi::__cxa_demangle ("", 0, 0, 0)])],
 212     [AC_DEFINE(HAVE_CXA_DEMANGLE)
 213         AC_MSG_RESULT(yes)],[
 214         LIBS="$LIBS -lsupc++"
 215         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cxxabi.h>],
 216                     [abi::__cxa_demangle ("", 0, 0, 0)])],
 217             [AC_DEFINE(HAVE_CXA_DEMANGLE)
 218                 AC_MSG_RESULT([yes, using -lsupc++])
 219                 CXXABI_LIBS="$CXXABI_LIBS -lsupc++"],
 220             [AC_MSG_RESULT([no, use c++filt -t for manual demangling])])])
 221 LIBS="$save_LIBS"
 222 AC_SUBST(CXXABI_LIBS)
 223
 224 ## check rational bugfix.
 225 save_CPPFLAGS="$CPPFLAGS"
 226 CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 227 AC_MSG_CHECKING(GUILE rational bugfix)
 228 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <libguile.h>
 229 #ifdef SCM_FRACTION_REDUCED_BIT
 230 #error
 231 #endif
 232 ]])],[AC_MSG_RESULT(ok)],[REQUIRED="$REQUIRED GUILE-with-rational-bugfix"
 233 AC_MSG_RESULT(Must have patched GUILE rational support. See INSTALL.txt)])
 234 CPPFLAGS="$save_CPPFLAGS"
 235
 236
 237 STEPMAKE_PYTHON_DEVEL(REQUIRED, 2.4, 3.0)
 238
 239 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, REQUIRED, 20110222)
 240
 241 STEPMAKE_PATH_PROG(T1ASM, t1asm, REQUIRED)
 242
 243 AC_CHECK_HEADERS([assert.h grp.h libio.h pwd.h sys/stat.h wchar.h fpu_control.h])
 244 AC_CHECK_HEADERS([sstream])
 245 AC_HEADER_STAT
 246 AC_FUNC_MEMCMP
 247 AC_FUNC_VPRINTF
 248 AC_CHECK_FUNCS([chroot fopencookie gettext isinf memmem snprintf vsnprintf])
 249
 250 STEPMAKE_PROGS(PKG_CONFIG, pkg-config, REQUIRED, 0.9.0)
 251
 252 AC_MSG_CHECKING(whether to enable dynamic relocation)
 253 if test "$reloc_b" = "yes"; then
 254     AC_DEFINE(ARGV0_RELOCATION)
 255 fi
 256 AC_MSG_RESULT($reloc_b)
 257
 258 AC_MSG_CHECKING(for rpath linkage)
 259 if test "$rpath_b" = "yes"; then
 260     LDFLAGS="$LDFLAGS -Wl,-rpath -Wl,\\\$\$ORIGIN/../lib"
 261 elif test "$rpath_b" != "no"; then
 262     LDFLAGS="$LDFLAGS -Wl,-rpath -Wl,$rpath_b"
 263 fi
 264 AC_MSG_RESULT($rpath_b)
 265
 266 HOST_ARCH=`$CC -dumpmachine`
 267 AC_SUBST(HOST_ARCH)
 268
 269 STEPMAKE_PANGO_FT2_WITH_OTF_FEATURE(pangoft2, OPTIONAL, 1.38.0)
 270 if test "$have_pangoft2_with_otf_feature" != yes ; then
 271     STEPMAKE_PANGO_FT2(pangoft2, REQUIRED, 1.6.0)
 272 fi
 273 STEPMAKE_FONTCONFIG(fontconfig, REQUIRED, 2.4.0)
 274 STEPMAKE_FREETYPE2(freetype2, REQUIRED, 2.1.10)
 275
 276 STEPMAKE_WINDOWS
 277
 278 # guile executable for some scripts
 279 if test "$GUILEv2" = "yes"
 280 then
 281     STEPMAKE_GUILE(OPTIONAL, 2.0.7, 2.3.0)
 282 else
 283     STEPMAKE_GUILE(OPTIONAL, 1.8.2, 1.9.0)
 284 fi
 285
 286 # perl for help2man and for mf2pt1.pl
 287 STEPMAKE_PERL(REQUIRED)
 288
 289 ## Optional tools for building documentation, website, extra fonts.
 290 if test "$DOCUMENTATION" = "yes"; then
 291   DOCUMENTATION_REQUIRED=REQUIRED
 292 else
 293   DOCUMENTATION_REQUIRED=OPTIONAL
 294 fi
 295
 296 STEPMAKE_PATH_PROG(GHOSTSCRIPT, gs, $DOCUMENTATION_REQUIRED, 8.60)
 297
 298 AC_SUBST(GS920)
 299 AC_SUBST(EXTRACTPDFMARK)
 300 AC_SUBST(USE_EXTRACTPDFMARK)
 301 STEPMAKE_PROGS(GS920, gs, OPTIONAL, 9.20)
 302 STEPMAKE_PROGS(EXTRACTPDFMARK, extractpdfmark, OPTIONAL)
 303 req=`STEPMAKE_NUMERIC_VERSION(9.20)`
 304 USE_EXTRACTPDFMARK=yes
 305 if test "$GS920_VERSION" -lt "$req"; then
 306     GS920=
 307     USE_EXTRACTPDFMARK=no
 308 fi
 309 if test "$EXTRACTPDFMARK" != "extractpdfmark"; then
 310     EXTRACTPDFMARK=
 311     USE_EXTRACTPDFMARK=no
 312 fi
 313 if test "$USE_EXTRACTPDFMARK" != "yes"; then
 314     STEPMAKE_ADD_ENTRY(OPTIONAL,
 315         ["(Optionally using Ghostscript >= 9.20 together with"])
 316     STEPMAKE_ADD_ENTRY(OPTIONAL,
 317         [" Extract PDFmark can significantly reduce the disk space required"])
 318     STEPMAKE_ADD_ENTRY(OPTIONAL,
 319         [" for building the documentation and the final PDF files.)"])
 320 fi
 321
 322 STEPMAKE_PROGS(MAKEINFO, makeinfo, REQUIRED, 4.11)
 323 STEPMAKE_PROGS(TEXI2HTML, texi2html, $DOCUMENTATION_REQUIRED, 1.82)
 324 STEPMAKE_PROGS(DBLATEX, dblatex, $DOCUMENTATION_REQUIRED, 0.1.4)
 325 STEPMAKE_PROGS(BIBTEX, bibtex, $DOCUMENTATION_REQUIRED)
 326 STEPMAKE_PROGS(PDFLATEX, xelatex pdflatex, $DOCUMENTATION_REQUIRED)
 327 if test "$PDFLATEX" = "xelatex"; then
 328     STEPMAKE_PROGS(PDFTEX, xetex, $DOCUMENTATION_REQUIRED)
 329     if test "$PDFTEX" = "xetex"; then
 330         # For avoiding PDF destination name replacement.
 331         PDFTEX=$ugh_ugh_autoconf250_builddir/scripts/build/out$CONFIGSUFFIX/xetex-with-options
 332         PDFLATEX=$ugh_ugh_autoconf250_builddir/scripts/build/out$CONFIGSUFFIX/xelatex-with-options
 333     fi
 334 else
 335     STEPMAKE_PROGS(PDFTEX, pdfetex pdftex etex, $DOCUMENTATION_REQUIRED)
 336 fi
 337 STEPMAKE_PROGS(TEXI2PDF, texi2pdf, $DOCUMENTATION_REQUIRED)
 338 STEPMAKE_PROGS(TEXINDEX, texindex, $DOCUMENTATION_REQUIRED)
 339 AC_MSG_CHECKING(for epsf.tex)
 340 TEX_EPSF=`kpsewhich tex epsf`
 341 if test "$TEX_EPSF" = ""; then
 342     AC_MSG_RESULT(not found)
 343     STEPMAKE_ADD_ENTRY($DOCUMENTATION_REQUIRED,epsf.tex)
 344 else
 345     AC_MSG_RESULT($TEX_EPSF)
 346 fi
 347 AC_MSG_CHECKING(for Cyrillic characters support in TeX)
 348 TEX_FIKPARM=`kpsewhich -format=mf fikparm`
 349 if test "$TEX_FIKPARM" = ""; then
 350     AC_MSG_RESULT(not found)
 351     STEPMAKE_ADD_ENTRY($DOCUMENTATION_REQUIRED,
 352 ['lh CTAN package (texlive-lang-cyrillic or texlive-texmf-fonts)'])
 353 else
 354     AC_MSG_RESULT(yes)
 355 fi
 356 STEPMAKE_PROGS(NETPBM, pngtopnm, $DOCUMENTATION_REQUIRED)
 357 STEPMAKE_PROGS(IMAGEMAGICK, convert, $DOCUMENTATION_REQUIRED)
 358 # this name avoids a conflict with ZIP in stepmake/aclocal.m4
 359 STEPMAKE_PROGS(ZIPDOC, zip, $DOCUMENTATION_REQUIRED)
 360 STEPMAKE_PROGS(RSYNC, rsync, $DOCUMENTATION_REQUIRED)
 361
 362 AC_DEFINE_UNQUOTED(FLOWER_VERSION, "${FULL_FLOWER_VERSION}")
 363
 364 # must also have local.make if configure fails.
 365 touch local.make
 366
 367 if test "$reloc_b$rpath_b" = "yesno"; then
 368     STEPMAKE_WARN([Using --enable-relocation without --enable-rpath.  LilyPond may have trouble finding libraries.])
 369 fi
 370
 371 # Gather requirements and generate output.
 372 STEPMAKE_END
 373
 374 test -n "$CONFIGURATION" && mc=" conf=$CONFIGURATION" || mc=""
 375
 376 if make top-doc 1>/dev/null 2>&1; then
 377     rm -f INSTALL.txt && ln Documentation/topdocs/out/INSTALL.txt .
 378     rm -f README.txt && ln Documentation/topdocs/out/README.txt .
 379 fi
 380
 381 cat <<EOF
 382
 383 Type:
 384     make$mc all       to build LilyPond
 385     make$mc install   to install LilyPond
 386     make$mc help      to see all possible targets
 387
 388 Edit local.make for local Makefile overrides.
 389
 390
 391 EOF