aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl WARNING WARNING WARNING
   3 dnl do not edit! this is aclocal.m4, generated from /users/hanwen/usr/src/lilypond/stepmake/aclocal.m4
   4 dnl aclocal.m4   -*-shell-script-*-
   5 dnl StepMake subroutines for configure.in
   6
   7
   8 ### mostly interal macros
   9
  10 # Get full path of executable ($1)
  11 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
  12     ## which doesn't work in ash, if /usr/bin/which isn't installed
  13     ## type -p doesn't work in ash
  14     ## command -v doesn't work in zsh
  15     ## command -v "$1" 2>&1
  16     ## this test should work in ash, bash, pdksh (ksh), zsh
  17     type -p "$1" 2>/dev/null | tail -1 | awk '{print $NF}'
  18 ])
  19
  20
  21 # Get version string from executable ($1)
  22 AC_DEFUN(STEPMAKE_GET_VERSION, [
  23     ## "$1" --version 2>&1 | grep -v '^$' | head -1 | awk '{print $NF}'
  24     ##
  25     ## ARG.
  26     ## Workaround for broken Debian gcc version string:
  27     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  28     ##
  29     ## Assume, and hunt for, dotted version multiplet.
  30     changequote(<<, >>)dnl
  31     "$1" --version 2>&1 | grep '[0-9]\.[0-9]' | head -1 | \
  32         sed -e 's/.*[^-.0-9]\([0-9][0-9]*\.[0-9][.0-9]*\).*/\1/'
  33     changequote([, ])dnl
  34 ])
  35
  36 # Calculate simplistic numeric version from version string ($1)
  37 # As yet, we have no need for something more elaborate.
  38 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  39     echo "$1" | awk -F. '
  40     {
  41       if ([$]3) {three = [$]3}
  42       else {three = 0}
  43     }
  44     {printf "%d\n", [$]1*1000000 + [$]2*1000 + three}'
  45 ])
  46
  47
  48 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  49 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  50     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  51 ])
  52
  53 # Check if tested program ($2) was found ($1).
  54 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  55 # We could abort here if a 'REQUIRED' program is not found
  56 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  57     STEPMAKE_CHECK_SEARCH_RESULT($1)
  58     if test $? -ne 0; then
  59         STEPMAKE_ADD_ENTRY($3, $2)
  60         if test "$3" = "REQUIRED"; then
  61             command="echo ERROR: $2 not found"
  62             # abort configure process here?
  63         else
  64             command="- echo $2 not found"
  65         fi
  66         eval "$1"='$command'
  67         false
  68     else
  69         true
  70     fi
  71 ])
  72
  73
  74 # Return if tested proram ($1) was found (true) or not (false).
  75 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  76     r="`eval echo '$'"$1"`"
  77     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  78         true
  79     else
  80         ##STEPMAKE_WARN(cannot find $2. $3)
  81         false
  82     fi
  83 ])
  84
  85
  86 # Check version of program ($1)
  87 # If version is smaller than requested ($3),
  88 # add entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
  89 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
  90     r="`eval echo '$'"$1"`"
  91     AC_MSG_CHECKING("$r version")
  92     #exe=`STEPMAKE_GET_EXECUTABLE($r)`
  93     exe=`STEPMAKE_GET_EXECUTABLE($r)`
  94     ver=`STEPMAKE_GET_VERSION($exe)`
  95     num=`STEPMAKE_NUMERIC_VERSION($ver)`
  96     req=`STEPMAKE_NUMERIC_VERSION($3)`
  97     AC_MSG_RESULT("$ver")
  98     if test "$num" -lt "$req"; then
  99         STEPMAKE_ADD_ENTRY($2, "$r $3 (installed: $ver)")
 100     fi
 101 ])
 102
 103 ### Macros to build configure.in
 104
 105
 106 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 107     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 108     if test "$BIBTEX2HTML" = "bib2html"; then
 109         BIBTEX2HTML_FLAGS='$< $(@)'
 110     else
 111         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 112     fi
 113     AC_SUBST(BIBTEX2HTML)
 114     AC_SUBST(BIBTEX2HTML_FLAGS)
 115 ])
 116
 117
 118 AC_DEFUN(STEPMAKE_BISON, [
 119     # ugh, automake: we want (and check for) bison
 120     AC_PROG_YACC
 121
 122     STEPMAKE_PROGS(BISON, bison, $1)
 123
 124     # urg.  should test functionality rather than version.
 125     if test "$BISON" = "bison" -a -n "$2"; then
 126         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 127     fi
 128 ])
 129
 130
 131 AC_DEFUN(STEPMAKE_COMPILE, [
 132     # -O is necessary to get inlining
 133     CFLAGS=${CFLAGS-""}
 134     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 135     LDFLAGS=${LDFLAGS-""}
 136     checking_b=yes
 137     optimise_b=yes
 138     profile_b=no
 139     debug_b=yes
 140
 141     AC_ARG_ENABLE(checking,
 142     [  --enable-checking       set runtime checks (assert calls).  Default: on],
 143     [checking_b=$enableval] )
 144
 145     AC_ARG_ENABLE(debugging,
 146     [  --enable-debugging      compile with debugging info.  Default: on],
 147     [debug_b=$enableval])
 148
 149     AC_ARG_ENABLE(optimising,
 150     [  --enable-optimising     compile with optimising.  Default: on],
 151     [optimise_b=$enableval])
 152
 153     AC_ARG_ENABLE(profiling,
 154     [  --enable-profiling      compile with gprof support.  Default: off],
 155     [profile_b=$enableval])
 156
 157
 158     if test "$checking_b" = no; then
 159         # ugh
 160         AC_DEFINE(NDEBUG)
 161         DEFINES="$DEFINES -DNDEBUG"
 162     fi
 163
 164     if test "$optimise_b" = yes; then
 165         OPTIMIZE="-O2 -finline-functions"
 166     fi
 167
 168
 169     if test $profile_b = yes; then
 170         EXTRA_LIBES="-pg"
 171         OPTIMIZE="$OPTIMIZE -pg"
 172     fi
 173
 174     if test $debug_b = yes; then
 175         OPTIMIZE="$OPTIMIZE -g"
 176     fi
 177
 178
 179     AC_PROG_CC
 180     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 181     LD='$(CC)'
 182     AC_SUBST(LD)
 183
 184     CFLAGS="$CFLAGS $OPTIMIZE"
 185     CPPFLAGS=${CPPFLAGS-""}
 186
 187     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 188     save_cflags="$CFLAGS"
 189     case "$host" in
 190         alpha*-*-*)
 191             dnl should do compile test?
 192             AC_MSG_RESULT(-mieee)
 193             CFLAGS="-mieee $CFLAGS"
 194             ;;
 195         *)
 196             AC_MSG_RESULT([none])
 197             ;;
 198     esac
 199     AC_SUBST(cross_compiling)
 200     AC_SUBST(CFLAGS)
 201     AC_SUBST(CPPFLAGS)
 202     AC_SUBST(LDFLAGS)
 203     AC_SUBST(ICFLAGS)
 204     AC_SUBST(ILDFLAGS)
 205     AC_SUBST(DEFINES)
 206     AC_SUBST(EXTRA_LIBES)
 207 ])
 208
 209 AC_DEFUN(STEPMAKE_CXX, [
 210     AC_LANG_CPLUSPLUS
 211     AC_PROG_CXX
 212     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 213
 214     CPPFLAGS="$CPPFLAGS $DEFINES"
 215     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 216     LDFLAGS="$LDFLAGS $EXTRA_LIBES"
 217
 218     AC_SUBST(CXXFLAGS)
 219     AC_SUBST(CXX)
 220     LD='$(CXX)'
 221     AC_SUBST(LD)
 222 ])
 223
 224
 225 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 226     AC_CACHE_CHECK([whether explicit instantiation is needed],
 227         lily_cv_need_explicit_instantiation,
 228         AC_TRY_LINK([
 229     template <class T> struct foo { static int baz; };
 230     template <class T> int foo<T>::baz = 1;
 231     ], [ return foo<int>::baz; ],
 232             lily_cv_need_explicit_instantiation=no,
 233             lily_cv_need_explicit_instantiation=yes))
 234     if test x"$lily_cv_need_explicit_instantiation"x = x"yes"x; then
 235         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 236     fi
 237 ])
 238
 239
 240 AC_DEFUN(STEPMAKE_DATADIR, [
 241     if test "$datadir" = "\${prefix}/share"; then
 242             datadir='${prefix}/share'
 243     fi
 244     presome=${prefix}
 245     if test "$prefix" = "NONE"; then
 246         presome=${ac_default_prefix}
 247     fi
 248
 249     package_datadir=$datadir/$package
 250     local_package_datadir=$package_datadir/$FULL_VERSION
 251     build_package_datadir=$builddir/share/$package
 252
 253     DATADIR=`echo ${datadir} | sed "s!\\\${prefix}!$presome!"`
 254     PACKAGE_DATADIR=`echo ${package_datadir} | sed "s!\\\${prefix}!$presome!"`
 255     LOCAL_PACKAGE_DATADIR=`echo ${local_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 256     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 257
 258     AC_SUBST(datadir)
 259     AC_SUBST(package_datadir)
 260     AC_SUBST(local_package_datadir)
 261     AC_SUBST(build_package_datadir)
 262     AC_DEFINE_UNQUOTED(DATADIR, "${DATADIR}")
 263     AC_DEFINE_UNQUOTED(PACKAGE_DATADIR, "${PACKAGE_DATADIR}")
 264     AC_DEFINE_UNQUOTED(LOCAL_PACKAGE_DATADIR, "${LOCAL_PACKAGE_DATADIR}")
 265     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, "${BUILD_PACKAGE_DATADIR}")
 266 ])
 267
 268
 269 AC_DEFUN(STEPMAKE_END, [
 270     AC_SUBST(OPTIONAL)
 271     AC_SUBST(REQUIRED)
 272
 273     AC_OUTPUT($CONFIGFILE.make:config.make.in)
 274
 275
 276     if test -n "$OPTIONAL"; then
 277         echo
 278         echo "WARNING: Please consider installing optional programs: $OPTIONAL"
 279     fi
 280
 281     if test -n "$REQUIRED"; then
 282         echo
 283         echo "ERROR: Please install required programs: $REQUIRED"
 284     fi
 285
 286     if test -n "$OPTIONAL$REQUIRED"; then
 287         echo
 288         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 289         echo "Remove config.cache before rerunning ./configure"
 290     fi
 291
 292     if test -n "$REQUIRED"; then
 293         rm -f $srcdir/GNUmakefile
 294         exit 1
 295     fi
 296
 297     # regular in-place build
 298     # test for srcdir_build = yes ?
 299     if test "$srcdir_build" = "yes"; then
 300         rm -f $srcdir/GNUmakefile
 301         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 302         chmod 444 $srcdir/GNUmakefile
 303     else # --srcdir build
 304         rm -f GNUmakefile
 305         cp $srcdir/make/srcdir.make.in GNUmakefile
 306         chmod 444 GNUmakefile
 307     fi
 308 ])
 309
 310
 311 AC_DEFUN(STEPMAKE_FLEX, [
 312     # ugh, automake: we want (and check for) flex
 313     # AC_PROG_LEX
 314     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 315
 316     # AC_DECL_YYTEXT
 317     # ugh, ugh
 318     ac_cv_prog_lex_root=lex.yy
 319     STEPMAKE_PROGS(FLEX, flex, $1)
 320 ])
 321
 322
 323 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 324     AC_HAVE_HEADERS(FlexLexer.h, true, false)
 325     if test $? -ne 0; then
 326         warn='FlexLexer.h (flex package)'
 327         STEPMAKE_ADD_ENTRY($1, $warn)
 328     fi
 329 ])
 330
 331
 332 AC_DEFUN(STEPMAKE_GCC, [
 333     if test "$GCC" = "yes"; then
 334         STEPMAKE_CHECK_VERSION(CC, $1, $2)
 335     else
 336         warn="$CC (Please install *GNU* cc)"
 337         STEPMAKE_ADD_ENTRY($1, $warn)
 338     fi
 339 ])
 340
 341
 342 AC_DEFUN(STEPMAKE_GETTEXT, [
 343     presome=${prefix}
 344     if test "$prefix" = "NONE"; then
 345             presome=${ac_default_prefix}
 346     fi
 347     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 348
 349     AC_SUBST(localedir)
 350     AC_DEFINE_UNQUOTED(LOCALEDIR, "${LOCALEDIR}")
 351     AC_CHECK_LIB(intl, gettext)
 352     AC_CHECK_FUNCS(gettext)
 353 ])
 354
 355
 356 AC_DEFUN(STEPMAKE_GUILE, [
 357     STEPMAKE_PATH_PROG(GUILE, guile, $1)
 358 ])
 359
 360
 361 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 362 #
 363 #   This macro runs the guile-config script, installed with Guile,
 364 #   to find out where Guile's header files and libraries are
 365 #   installed.  It sets two variables, marked for substitution, as
 366 #   by AC_SUBST.
 367 #
 368 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 369 #             code that uses Guile header files.  This is almost
 370 #             always just a -I flag.
 371 #
 372 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 373 #             program against Guile.  This includes -lguile for
 374 #             the Guile library itself, any libraries that Guile
 375 #             itself requires (like -lqthreads), and so on.  It may
 376 #             also include a -L flag to tell the compiler where to
 377 #             find the libraries.
 378
 379 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 380     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 381     if test -x $exe; then
 382         AC_MSG_CHECKING("guile compile flags")
 383         GUILE_CFLAGS="`$guile_config compile`"
 384         AC_MSG_RESULT($GUILE_CFLAGS)
 385         AC_MSG_CHECKING("guile link flags")
 386         GUILE_LDFLAGS="`$guile_config link`"
 387         AC_MSG_RESULT($GUILE_LDFLAGS)
 388     fi
 389     AC_SUBST(GUILE_CFLAGS)
 390     AC_SUBST(GUILE_LDFLAGS)
 391 ])
 392
 393
 394 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 395     ## First, let's just see if we can find Guile at all.
 396     AC_MSG_CHECKING("for guile-config")
 397     for guile_config in guile-config $target-guile-config $build-guile-config; do
 398         AC_MSG_RESULT("$guile_config")
 399         if ! $guile_config --version > /dev/null 2>&1 ; then
 400             AC_MSG_WARN("cannot execute $guile_config")
 401             AC_MSG_CHECKING("if we are cross compiling")
 402             GUILE_CONFIG='echo no guile-config'
 403         else
 404             GUILE_CONFIG=$guile_config
 405             break
 406         fi
 407     done
 408     STEPMAKE_OPTIONAL_REQUIRED(GUILE_CONFIG, $guile_config, $1)
 409     if test $? -ne 0; then
 410         STEPMAKE_ADD_ENTRY($1, 'guile-config (guile-devel, guile-dev or libguile-dev package)')
 411     fi
 412
 413     STEPMAKE_CHECK_SEARCH_RESULT(GUILE_CONFIG)
 414     # urg.  should test functionality rather than version.
 415     if test $? -eq 0 -a -n "$2"; then
 416         STEPMAKE_CHECK_VERSION(GUILE_CONFIG, $1, $2)
 417     fi
 418
 419     AC_SUBST(GUILE_CONFIG)
 420
 421     guile_version="$ver"
 422     changequote(<<, >>)dnl
 423     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 424     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 425     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 426     changequote([, ])dnl
 427     STEPMAKE_GUILE_FLAGS
 428     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 429     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 430     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 431 ])
 432
 433
 434 AC_DEFUN(STEPMAKE_GXX, [
 435     if test "$GXX" = "yes"; then
 436         STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 437     else
 438         warn="$CXX (Please install *GNU* c++)"
 439         STEPMAKE_ADD_ENTRY($1, $warn)
 440     fi
 441 ])
 442
 443
 444 AC_DEFUN(STEPMAKE_INIT, [
 445
 446     . $srcdir/VERSION
 447     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 448     if test x$MY_PATCH_LEVEL != x; then
 449         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 450     fi
 451
 452     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 453     changequote(<<, >>)dnl
 454     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 455     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 456     changequote([, ])dnl
 457
 458     # No versioning on directory names of sub-packages
 459     # urg, urg
 460     stepmake=${datadir}/stepmake
 461     presome=${prefix}
 462     if test "$prefix" = "NONE"; then
 463             presome=${ac_default_prefix}
 464     fi
 465     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 466
 467     # urg, how is this supposed to work?
 468     if test "$program_prefix" = "NONE"; then
 469           program_prefix=
 470     fi
 471     if test "$program_suffix" = "NONE"; then
 472           program_suffix=
 473     fi
 474
 475     AC_MSG_CHECKING(Package)
 476     if test "$PACKAGE" = "STEPMAKE"; then
 477         AC_MSG_RESULT(Stepmake package!)
 478
 479         AC_MSG_CHECKING(builddir)
 480
 481         builddir="`pwd`"
 482
 483         if test "$srcdir" = "."; then
 484             srcdir_build=yes
 485         else
 486             srcdir_build=no
 487             package_builddir="`dirname $builddir`"
 488             package_srcdir="`dirname  $srcdir`"
 489         fi
 490         AC_MSG_RESULT($builddir)
 491
 492         (cd stepmake 2>/dev/null || mkdir stepmake)
 493         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 494         AC_CONFIG_AUX_DIR(bin)
 495         stepmake=stepmake
 496     else
 497         AC_MSG_RESULT($PACKAGE)
 498
 499         AC_MSG_CHECKING(builddir)
 500         builddir="`pwd`"
 501         if test "$srcdir" = "."; then
 502             srcdir_build=yes
 503         else
 504             srcdir_build=no
 505         fi
 506         AC_MSG_RESULT($builddir)
 507
 508         AC_MSG_CHECKING(for stepmake)
 509         # Check for installed stepmake
 510         if test -d $stepmake; then
 511             AC_MSG_RESULT($stepmake)
 512         else
 513             stepmake="`cd $srcdir/stepmake; pwd`"
 514             AC_MSG_RESULT($srcdir/stepmake  ($datadir/stepmake not found))
 515         fi
 516
 517         AC_CONFIG_AUX_DIR(\
 518           $HOME/usr/local/share/stepmake/bin\
 519           $HOME/usr/local/lib/stepmake/bin\
 520           $HOME/usr/share/stepmake/bin\
 521           $HOME/usr/lib/stepmake/bin\
 522           /usr/local/share/stepmake/bin\
 523           /usr/local/lib/stepmake/bin\
 524           /usr/share/stepmake/bin\
 525           /usr/lib/stepmake/bin\
 526           stepmake/bin\
 527           $srcdir/stepmake/bin\
 528         )
 529     fi
 530
 531     AC_SUBST(builddir)
 532     AC_SUBST(stepmake)
 533     AC_SUBST(package)
 534     AC_SUBST(PACKAGE)
 535     AC_SUBST(PACKAGE_NAME)
 536     AC_DEFINE_UNQUOTED(PACKAGE, "${PACKAGE_NAME}")
 537     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, "${FULL_VERSION}")
 538
 539     if test -z "$package_depth"; then
 540         package_depth="."
 541     else
 542         package_depth="../$package_depth"
 543     fi
 544     export package_depth
 545     AC_SUBST(package_depth)
 546
 547     AUTOGENERATE="This file was automatically generated by configure"
 548     AC_SUBST(AUTOGENERATE)
 549
 550     CONFIGSUFFIX=
 551     AC_ARG_ENABLE(config,
 552     [  --enable-config=CONF    put settings in config-CONF.make and config-CONF.h;
 553                             do \`make conf=CONF' to get output in ./out-CONF],
 554     [CONFIGURATION=$enableval])
 555
 556     ##'
 557
 558     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 559     CONFIGFILE=config$CONFIGSUFFIX
 560     AC_SUBST(CONFIGSUFFIX)
 561
 562     AC_CANONICAL_HOST
 563     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 564     STEPMAKE_PROGS(FIND, find, REQUIRED)
 565
 566     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 567
 568     if test "$(echo 2)" != "2" ||
 569         test "x`uname`" = "xHP-UX"; then
 570         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 571         AC_PATH_PROG(BASH, bash, $KSH)
 572         STEPMAKE_WARN(avoiding buggy /bin/sh)
 573         AC_PATH_PROG(SHELL, bash, $KSH)
 574     else
 575         SHELL=/bin/sh
 576         AC_PATH_PROG(BASH, bash, $SHELL)
 577     fi
 578     AC_SUBST(SHELL)
 579
 580     STEPMAKE_PATH_PROG(PYTHON, python, REQUIRED)
 581
 582     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 583         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 584         if test "$?" = 1; then
 585             warn='make (Please install *GNU* make)'
 586             # STEPMAKE_WARN($warn)
 587             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 588         fi
 589     fi
 590
 591     if test "$OSTYPE" = "cygwin" -o "$OSTYPE" = "cygwin32" -o "$OSTYPE" = "Windows_NT"; then
 592         LN=cp # hard link does not work under cygnus-nt
 593         LN_S='cp -r' # symbolic link does not work for native nt
 594         ZIP="zip -r -9" #
 595         program_suffix=.exe
 596         ROOTSEP=':'
 597         DIRSEP='/'
 598         PATHSEP=':'
 599         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
 600     else
 601         ROOTSEP=':'
 602         DIRSEP='/'
 603         PATHSEP=':'
 604         LN=ln
 605         LN_S='ln -s'
 606         ZIP="zip -r -9"
 607         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-sh -c"
 608     fi
 609     AC_SUBST(program_prefix)
 610     AC_SUBST(program_suffix)
 611     AC_SUBST(ZIP)
 612     AC_SUBST(LN)
 613     AC_SUBST(LN_S)
 614     AC_SUBST(INSTALL)
 615     AC_DEFINE_UNQUOTED(DIRSEP, '${DIRSEP}')
 616     AC_DEFINE_UNQUOTED(PATHSEP, '${PATHSEP}')
 617     AC_SUBST(DIRSEP)
 618     AC_SUBST(PATHSEP)
 619     AC_SUBST(ROOTSEP)
 620
 621     STEPMAKE_DATADIR
 622 ])
 623
 624
 625 AC_DEFUN(STEPMAKE_KPATHSEA, [
 626
 627     AC_ARG_WITH(kpathsea-include,
 628         [  --with-kpathsea-include=DIR
 629                           location of the kpathsea include dir],[
 630             if test "$withval" = "yes" -o "$withval" = "no"; then
 631                 AC_MSG_WARN(Usage: --with-kpathsea-include=includedir)
 632             else
 633                 CPPFLAGS="$CPPFLAGS -I${withval}"
 634             fi
 635             ])
 636
 637     AC_ARG_WITH(kpathsea-lib,
 638         [  --with-kpathsea-lib=DIR location of the kpathsea lib dir],[
 639             if test "$withval" = "yes" -o "$withval" = "no"; then
 640                 AC_MSG_WARN(Usage: --with-kpathsea-lib=libdir)
 641             else
 642                 LDFLAGS="$LDFLAGS -L${withval}"
 643             fi
 644             ])
 645
 646     kpathsea_b=yes
 647     #FIXME --with-xxx is meant for specifying a PATH too,
 648     # so this should read: --enable-kpathsea,
 649     # or --with-kpathsea-include=PATH --with-kpathsea-lib=PATH
 650     AC_ARG_WITH(kpathsea,
 651     [  --with-kpathsea         use kpathsea lib.  Default: on],
 652     [kpathsea_b=$with_kpathsea])
 653
 654     if test "$kpathsea_b" != "no"; then
 655         AC_HAVE_HEADERS(kpathsea/kpathsea.h)
 656         AC_CHECK_LIB(kpathsea, kpse_find_file)
 657         AC_CHECK_FUNCS(kpse_find_file,,kpathsea_b=no)
 658         if test "$kpathsea_b" = "no"; then
 659             warn='kpathsea (libkpathsea-dev or kpathsea-devel package)
 660    Else, please specify the location of your kpathsea using
 661    --with-kpathea-include and --with-kpathsea-lib options.  You should
 662    install kpathsea; see INSTALL.txt.  Rerun ./configure
 663    --without-kpathsea only if kpathsea is not available for your
 664    platform.'
 665             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 666         fi
 667     fi
 668     AC_MSG_CHECKING(whether to use kpathsea)
 669     if test "$kpathsea_b" != no; then
 670         AC_MSG_RESULT(yes)
 671         KPATHSEA=1
 672     else
 673         AC_MSG_RESULT(no)
 674         KPATHSEA=0
 675     fi
 676
 677     AC_SUBST(KPATHSEA)
 678     AC_DEFINE_UNQUOTED(KPATHSEA, $KPATHSEA)
 679 ])
 680
 681
 682 AC_DEFUN(STEPMAKE_LIB, [
 683     STEPMAKE_PROGS(AR, ar, $1)
 684     AC_PROG_RANLIB
 685     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 686 ])
 687
 688
 689 AC_DEFUN(STEPMAKE_LIBTOOL, [
 690     # libtool.info ...
 691     # **Never** try to set library version numbers so that they correspond
 692     # to the release number of your package.  This is an abuse that only
 693     # fosters misunderstanding of the purpose of library versions.
 694
 695     REVISION=$PATCH_LEVEL
 696     # CURRENT=$MINOR_VERSION
 697     CURRENT=`expr $MINOR_VERSION + 1`
 698     # AGE=`expr $MAJOR_VERSION + 1`
 699     AGE=$MAJOR_VERSION
 700     AC_SUBST(CURRENT)
 701     AC_SUBST(REVISION)
 702     AC_SUBST(AGE)
 703 ])
 704
 705
 706 AC_DEFUN(STEPMAKE_LOCALE, [
 707     lang=English
 708     ALL_LINGUAS="en nl"
 709
 710     # with/enable ??
 711     AC_ARG_WITH(localedir,
 712     [  --with-localedir=LOCALE use LOCALE as locale dir.  Default:
 713                             PREFIX/share/locale ],
 714     localedir=$with_localedir,
 715     localedir='${prefix}/share/locale')
 716
 717     AC_ARG_WITH(lang,
 718     [  --with-lang=LANG        use LANG as language to emit messages],
 719     language=$with_lang,
 720     language=English)
 721
 722     AC_MSG_CHECKING(language)
 723     case "$language" in
 724       En* | en* | Am* | am* | US* | us*)
 725             lang=English;;
 726       NL | nl | Du* | du* | Ned* | ned*)
 727             lang=Dutch;;
 728       "")
 729             lang=English;;
 730       *)
 731             lang=unknown;;
 732     esac
 733     AC_MSG_RESULT($lang)
 734
 735     if test "$lang" = "unknown" ; then
 736         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 737     fi
 738
 739 ])
 740
 741
 742 AC_DEFUN(STEPMAKE_MAKEINFO, [
 743     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 744     if test "$MAKEINFO" = "makeinfo"; then
 745         AC_MSG_CHECKING(whether makeinfo can split html by @node)
 746         mkdir -p out
 747         makeinfo --html --output=out/split <<EOF
 748 \input texinfo
 749 \input texinfo @c -*-texinfo-*-
 750 @setfilename split.info
 751 @settitle split.info
 752 @bye
 753 EOF
 754         if test -d out/split; then
 755             SPLITTING_MAKEINFO=yes
 756             AC_MSG_RESULT(yes)
 757             rm -rf out/split
 758         else
 759             AC_MSG_RESULT(no)
 760             STEPMAKE_WARN(your html documentation will be one large file)
 761             rm -rf out/split
 762         fi
 763     fi
 764     AC_SUBST(SPLITTING_MAKEINFO)
 765 ])
 766
 767
 768
 769 AC_DEFUN(STEPMAKE_MAN, [
 770     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 771     AC_SUBST(GROFF)
 772     STEPMAKE_PROGS(TROFF, troff, $1)
 773     AC_SUBST(TROFF)
 774     STEPMAKE_PROGS(TBL, tbl, $1)
 775     AC_SUBST(TBL)
 776 ])
 777
 778
 779 AC_DEFUN(STEPMAKE_MSGFMT, [
 780     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
 781 ])
 782
 783
 784 # Check for program ($2), set full path result to ($1).
 785 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 786 AC_DEFUN(STEPMAKE_PATH_PROG, [
 787     AC_CHECK_PROGS($1, $2, no)
 788     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 789     if test $? -eq 0; then
 790         AC_PATH_PROG($1, $2)
 791         if test -n "$4"; then
 792             STEPMAKE_CHECK_VERSION($1, $3, $4)
 793         fi
 794     fi
 795 ])
 796
 797
 798 # Check for program in set of names ($2), set result to ($1) .
 799 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 800 # If exists, and a minimal version ($4) is required
 801 AC_DEFUN(STEPMAKE_PROGS, [
 802     AC_CHECK_PROGS($1, $2, no)
 803     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 804     if test $? -eq 0 -a -n "$4"; then
 805         STEPMAKE_CHECK_VERSION($1, $3, $4)
 806     fi
 807 ])
 808
 809
 810 AC_DEFUN(STEPMAKE_PERL, [
 811     STEPMAKE_PATH_PROG(PERL, perl, $1)
 812 ])
 813
 814
 815 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
 816     AC_HAVE_HEADERS(python2.2/Python.h python2.1/Python.h python2.0/Python.h python2/Python.h python/Python.h python1.5/Python.h Python.h, PYTHON_HEADER=yes)
 817     if test -z "$PYTHON_HEADER"; then
 818         warn='python.h (python-devel, python-dev or libpython-dev package)'
 819         STEPMAKE_ADD_ENTRY($1, $warn)
 820     fi
 821 ])
 822
 823
 824 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
 825     AC_ARG_ENABLE(tfm-path,
 826     [  --enable-tfm-path=PATH  set path of tex directories where tfm files live,
 827                             esp.: cmr10.tfm.  Default: use kpsewhich],
 828     [tfm_path=$enableval],
 829     [tfm_path=auto] )
 830
 831     # ugh
 832     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, OPTIONAL)
 833     AC_MSG_CHECKING(for tfm path)
 834
 835     TFM_FONTS="cmr msam"
 836
 837     if test "x$tfm_path" = xauto ; then
 838         if test "x$KPSEWHICH" != "xno" ; then
 839             for i in $TFM_FONTS; do
 840                 dir=`$KPSEWHICH tfm ${i}10.tfm`
 841                 TFM_PATH="$TFM_PATH `dirname $dir`"
 842             done
 843         else
 844             STEPMAKE_WARN(Please specify where cmr10.tfm lives:
 845     ./configure --enable-tfm-path=/usr/local/TeX/lib/tex/fonts)
 846         fi
 847     else
 848          TFM_PATH=$tfm_path
 849     fi
 850
 851     TFM_PATH=`echo $TFM_PATH | tr ':' ' '`
 852     AC_MSG_RESULT($TFM_PATH)
 853     AC_SUBST(TFM_PATH)
 854 ])
 855
 856
 857 AC_DEFUN(STEPMAKE_TEXMF, [
 858     # urg, never know what names these teTeX guys will think up
 859
 860     STEPMAKE_PROGS(METAFONT, mf mfont, $1)
 861     STEPMAKE_PROGS(INIMETAFONT, inimf inimfont, $1)
 862
 863     AC_MSG_CHECKING(for working metafont mode)
 864     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
 865     for MFMODE in $modelist; do
 866         $METAFONT "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
 867         if test -f mfput.tfm; then
 868             break;
 869         fi
 870     done
 871     AC_MSG_RESULT($MFMODE)
 872
 873     rm -f mfput.*
 874
 875     AC_SUBST(MFMODE)
 876 ])
 877
 878
 879 AC_DEFUN(STEPMAKE_WARN, [
 880     AC_MSG_WARN($1)
 881     warn_b=yes
 882 ])
 883
 884