aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4
   5 ### mostly interal macros
   6
   7 # Get full path of executable ($1)
   8 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
   9     ## which doesn't work in ash, if /usr/bin/which isn't installed
  10     ## type -p doesn't work in ash
  11     ## command -v doesn't work in zsh
  12     ## command -v "$1" 2>&1
  13     ## this test should work in ash, bash, pdksh (ksh), zsh
  14     type -p $1 2>/dev/null | tail -n 1 | awk '{print $NF}'
  15 ])
  16
  17
  18 # Get version string from executable ($1)
  19 AC_DEFUN(STEPMAKE_GET_VERSION, [
  20     ## "$1" --version 2>&1 | grep -v '^$' | head -n 1 | awk '{print $NF}'
  21     ##
  22     ## ARG.
  23     ## Workaround for broken Debian gcc version string:
  24     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  25     ##
  26     ## -V: Workaround for python
  27
  28     changequote(<<, >>)#dnl
  29
  30     ## Assume and hunt for dotted version multiplet.
  31     ## use eval trickery, because we cannot use multi-level $() instead of ``
  32     ## for compatibility reasons.
  33
  34     ## grab the first version number in  --version output.
  35     eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 |
  36                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  37                 head -n 1 |
  38                 tr ' ' '\n' |
  39                 sed 's/\([0-9][0-9]*\.[0-9][0-9.]*\).*/\1/g' |
  40                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  41                 head -n 1\`\"
  42
  43     if test -z "$_ver"; then
  44         ## If empty, try date [fontforge]
  45         eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '[0-9]\{6,8\}' \
  46             | head -n 1 \
  47             | sed -e 's/^[^.0-9]*//' -e 's/[^.0-9]*$//'\`\"
  48     fi
  49     echo "$_ver"
  50     changequote([, ])#dnl
  51 ])
  52
  53 # Calculate simplistic numeric version from version string ($1)
  54 # As yet, we have no need for something more elaborate.
  55 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  56     echo "$1" | awk -F. '
  57     {
  58       if ([$]3) {three = [$]3}
  59       else {three = 0}
  60     }
  61     {printf "%.0f\n", [$]1*1000000 + [$]2*1000 + three}'
  62 ])
  63
  64
  65 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  66 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  67     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  68 ])
  69
  70 # Check if tested program ($2) was found ($1).
  71 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  72 # We could abort here if a 'REQUIRED' program is not found
  73 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  74     STEPMAKE_CHECK_SEARCH_RESULT($1)
  75     if test $? -ne 0; then
  76         STEPMAKE_ADD_ENTRY($3, $2)
  77         if test "$3" = "REQUIRED"; then
  78             command="echo ERROR: $2 not found"
  79             # abort configure process here?
  80         else
  81             command="- echo $2 not found"
  82         fi
  83         eval "$1"='$command'
  84         false
  85     else
  86         true
  87     fi
  88 ])
  89
  90
  91 # Return if tested proram ($1) was found (true) or not (false).
  92 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  93     r="`eval echo '$'"$1"`"
  94     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  95         true
  96     else
  97         ##STEPMAKE_WARN(cannot find $2. $3)
  98         false
  99     fi
 100 ])
 101
 102
 103 # Check version of program ($1)
 104 # If version ($4: optional argument, supply if version cannot be
 105 # parsed using --version or -V ) is smaller than requested ($3), add
 106 # entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
 107 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
 108     r="`eval echo '$'"$1"`"
 109     AC_MSG_CHECKING([$r version])
 110     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 111     if test -n "$4"; then
 112         ver="$4"
 113     else
 114         ver=`STEPMAKE_GET_VERSION($exe)`
 115     fi
 116     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 117     req=`STEPMAKE_NUMERIC_VERSION($3)`
 118     AC_MSG_RESULT([$ver])
 119     if test "$num" -lt "$req"; then
 120         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
 121     fi
 122     vervar="`echo $1 | tr '[a-z]' '[A-Z]'`_VERSION"
 123     eval `echo $vervar=$num`
 124 ##    AC_SUBST(`eval echo $vervar`)
 125 ])
 126
 127 # Check version of program ($1)
 128 # If version is greater than or equals unsupported ($3),
 129 # add entry to unsupported list ($2, 'UNSUPPORTED')
 130 AC_DEFUN(STEPMAKE_CHECK_VERSION_UNSUPPORTED, [
 131     r="`eval echo '$'"$1"`"
 132     AC_MSG_CHECKING([$r version])
 133     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 134     ver=`STEPMAKE_GET_VERSION($exe)`
 135     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 136     sup=`STEPMAKE_NUMERIC_VERSION($3)`
 137     AC_MSG_RESULT([$ver])
 138     if test "$num" -ge "$sup"; then
 139         STEPMAKE_ADD_ENTRY($2, ["$r < $3 (installed: $ver)"])
 140     fi
 141 ])
 142
 143 ### Macros to build configure.in
 144
 145
 146 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 147     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 148     if test "$BIBTEX2HTML" = "bib2html"; then
 149         BIBTEX2HTML_FLAGS='$< $(@)'
 150     else
 151         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 152     fi
 153     AC_SUBST(BIBTEX2HTML)
 154     AC_SUBST(BIBTEX2HTML_FLAGS)
 155 ])
 156
 157
 158 AC_DEFUN(STEPMAKE_BISON, [
 159     # ugh, automake: we want (and check for) bison
 160     AC_PROG_YACC
 161
 162     STEPMAKE_PROGS(BISON, bison, $1)
 163
 164     # urg.  should test functionality rather than version.
 165     if test "$BISON" = "bison" -a -n "$2"; then
 166         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 167     fi
 168 ])
 169
 170 AC_DEFUN(STEPMAKE_COMPILE_BEFORE, [
 171     # -O is necessary to get inlining
 172     CFLAGS=${CFLAGS-""}
 173     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 174     LDFLAGS=${LDFLAGS-""}
 175     optimise_b=yes
 176     profile_b=no
 177     debug_b=yes
 178     pipe_b=yes
 179
 180     AC_ARG_ENABLE(debugging,
 181     [AS_HELP_STRING([--enable-debugging],
 182                     [compile with debugging info.  Default: on])],
 183     [debug_b=$enableval])
 184
 185     AC_ARG_ENABLE(optimising,
 186     [AS_HELP_STRING([--enable-optimising],
 187                     [compile with optimising.  Default: on])],
 188     [optimise_b=$enableval])
 189
 190     AC_ARG_ENABLE(profiling,
 191     [AS_HELP_STRING([--enable-profiling],
 192                     [compile with gprof support.  Default: off])],
 193     [profile_b=$enableval])
 194
 195     AC_ARG_ENABLE(pipe,
 196     [AS_HELP_STRING([--enable-pipe],
 197                     [compile with -pipe.  Default: on])],
 198     [pipe_b=$enableval])
 199
 200     if test "$optimise_b" = yes; then
 201         AC_DEFINE(NDEBUG)
 202         DEFINES="$DEFINES -DNDEBUG"
 203         OPTIMIZE=" -O2 -finline-functions"
 204     fi
 205
 206     if test $profile_b = yes; then
 207         EXTRA_LIBS="-pg"
 208         OPTIMIZE="$OPTIMIZE -pg"
 209     fi
 210
 211     if test $debug_b = yes; then
 212         OPTIMIZE="$OPTIMIZE -g"
 213     fi
 214 ])
 215
 216 AC_DEFUN(STEPMAKE_COMPILE, [
 217
 218     AC_REQUIRE([STEPMAKE_COMPILE_BEFORE])
 219     AC_REQUIRE([AC_PROG_CC])
 220
 221     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 222     LD='$(CC)'
 223     AC_SUBST(LD)
 224
 225     # If -pipe requested, test if it works and add to CFLAGS.
 226     if test "$pipe_b" = yes; then
 227         save_cflags="$CFLAGS"
 228         CFLAGS=" -pipe $CFLAGS";
 229         AC_CACHE_CHECK([whether compiler understands -pipe],
 230             [stepmake_cv_cflags_pipe],
 231             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[/* -pipe test */]])],
 232                 [stepmake_cv_cflags_pipe=yes],
 233                 [stepmake_cv_cflags_pipe=no]))
 234         CFLAGS=$save_cflags
 235         if test $stepmake_cv_cflags_pipe = yes; then
 236             OPTIMIZE="$OPTIMIZE -pipe"
 237         fi
 238     fi
 239
 240     CFLAGS="$CFLAGS $OPTIMIZE"
 241     CPPFLAGS=${CPPFLAGS-""}
 242
 243     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 244     save_cflags="$CFLAGS"
 245     case "$host" in
 246         alpha*-*-*)
 247             dnl should do compile test?
 248             AC_MSG_RESULT(-mieee)
 249             CFLAGS=" -mieee $CFLAGS"
 250             ;;
 251         *)
 252             AC_MSG_RESULT([none])
 253             ;;
 254     esac
 255
 256     AC_SUBST(cross_compiling)
 257     AC_SUBST(CFLAGS)
 258     AC_SUBST(CPPFLAGS)
 259     AC_SUBST(LDFLAGS)
 260     AC_SUBST(DEFINES)
 261     AC_SUBST(EXTRA_LIBS)
 262 ])
 263
 264 AC_DEFUN(STEPMAKE_CXX, [
 265     AC_PROG_CXX
 266     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 267
 268     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 269     LD='$(CXX)'
 270
 271     AC_SUBST(CXX)
 272     AC_SUBST(CXXFLAGS)
 273     AC_SUBST(LD)
 274 ])
 275
 276
 277 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 278     AC_CACHE_CHECK([whether explicit instantiation is needed],
 279         stepmake_cv_need_explicit_instantiation,
 280         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 281     template <class T> struct foo { static int baz; };
 282     template <class T> int foo<T>::baz = 1;
 283     ]], [[ return foo<int>::baz; ]])],[stepmake_cv_need_explicit_instantiation=no],[stepmake_cv_need_explicit_instantiation=yes]))
 284     if test x"$stepmake_cv_need_explicit_instantiation"x = x"yes"x; then
 285         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 286     fi
 287 ])
 288
 289 AC_DEFUN(STEPMAKE_GXXCODEGENBUG, [
 290     AC_MSG_CHECKING([options for known g++ bugs])
 291     case "$GXX:$CXX_VERSION" in
 292         yes:400600[[0-2]])
 293             AC_MSG_RESULT([-fno-optimize-sibling-calls (tail call bug)])
 294             CXXFLAGS="$CXXFLAGS -fno-optimize-sibling-calls"
 295             ;;
 296         yes:400700?)
 297             AC_MSG_RESULT([-fno-tree-vrp (comparison bug)])
 298             CXXFLAGS="$CXXFLAGS -fno-tree-vrp"
 299             ;;
 300         *) AC_MSG_RESULT([none])
 301     esac
 302     AC_SUBST(CXXFLAGS)
 303 ])
 304
 305
 306 AC_DEFUN(STEPMAKE_DATADIR, [
 307     if test "$datadir" = "\${prefix}/share"; then
 308             datadir='${prefix}/share'
 309     fi
 310     presome=${prefix}
 311     if test "$prefix" = "NONE"; then
 312         presome=${ac_default_prefix}
 313     fi
 314
 315     build_package_datadir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/share/$package
 316
 317     DATADIR=`echo ${datadir} | sed "s!\\\${datarootdir}!${prefix}/share!"`
 318     DATADIR=`echo ${DATADIR} | sed "s!\\\${prefix}!$presome!"`
 319     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 320
 321     AC_SUBST(datadir)
 322     AC_SUBST(datarootdir)
 323     AC_SUBST(build_package_datadir)
 324     AC_DEFINE_UNQUOTED(DATADIR, ["${DATADIR}"])
 325     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, ["${BUILD_PACKAGE_DATADIR}"])
 326 ])
 327
 328 ## ugh: cut & paste programming from datadir.
 329 AC_DEFUN(STEPMAKE_LIBDIR, [
 330
 331     if test "$libdir" = "\${exec_prefix}/lib"; then
 332         libdir='${exec_prefix}/lib'
 333     fi
 334     presome=$exec_prefix
 335     build_package_libdir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/lib/$package
 336
 337     LIBDIR=`echo ${libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 338     BUILD_PACKAGE_LIBDIR=`echo ${build_package_libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 339
 340     AC_SUBST(libdir)
 341     AC_SUBST(build_package_libdir)
 342     AC_DEFINE_UNQUOTED(LIBDIR, ["${LIBDIR}"])
 343     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_LIBDIR, ["${BUILD_PACKAGE_LIBDIR}"])
 344 ])
 345
 346
 347 AC_DEFUN(STEPMAKE_PREFIX_EXPAND_FIXUP, [
 348     # undo expanding of explicit --infodir=/usr/share
 349     # to ease install-time override with prefix=...
 350     strip=`echo $includedir | eval sed s@^$prefix@@`
 351     if test "$includedir" = "`eval echo $prefix$strip`"; then
 352             includedir='${prefix}'$strip''
 353     fi
 354     strip=`echo $libdir | eval sed s@^$exec_prefix@@`
 355     if test "$libdir" = "`eval echo $exec_prefix$strip`"; then
 356             libdir='${exec_prefix}'$strip''
 357     fi
 358     strip=`echo $infodir | eval sed s@^$datarootdir@@`
 359     if test "$infodir" = "`eval echo $datarootdir$strip`"; then
 360             infodir='${datarootdir}'$strip''
 361     fi
 362     strip=`echo $mandir | eval sed s@^$datarootdir@@`
 363     if test "$mandir" = "`eval echo $datarootdir$strip`"; then
 364             mandir='${datarootdir}'$strip''
 365     fi
 366 ])
 367
 368
 369 AC_DEFUN(STEPMAKE_END, [
 370     STEPMAKE_PREFIX_EXPAND_FIXUP
 371
 372     AC_SUBST(OPTIONAL)
 373     AC_SUBST(REQUIRED)
 374
 375     AC_CONFIG_FILES([$CONFIGFILE.make:config.make.in])
 376     AC_OUTPUT
 377
 378     if test -n "$OPTIONAL"; then
 379         echo
 380         echo "WARNING: Please consider installing optional programs or files: $OPTIONAL"
 381     fi
 382
 383     if test -n "$REQUIRED"; then
 384         echo
 385         echo "ERROR: Please install required programs: $REQUIRED"
 386     fi
 387
 388     if test -n "$UNSUPPORTED"; then
 389         echo
 390         echo "ERROR: Please use older version of programs: $UNSUPPORTED"
 391     fi
 392
 393     if test -n "$OPTIONAL$REQUIRED$UNSUPPORTED"; then
 394         echo
 395         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 396         if test -f config.cache ; then
 397             echo "Remove config.cache before rerunning ./configure"
 398         fi
 399     fi
 400
 401     if test -n "$REQUIRED$UNSUPPORTED"; then
 402         rm -f $srcdir/GNUmakefile
 403         exit 1
 404     fi
 405
 406     # regular in-place build
 407     # test for srcdir_build = yes ?
 408     if test "$srcdir_build" = "yes"; then
 409         rm -f $srcdir/GNUmakefile
 410         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 411         chmod 444 $srcdir/GNUmakefile
 412     else
 413         if test -f $srcdir/GNUmakefile; then
 414             cat <<EOF
 415 Source directory already configured.  Please clean the source directory
 416
 417      make -C $srcdir distclean
 418
 419 and rerun configure.
 420 EOF
 421             exit 2
 422         fi
 423
 424         abssrcdir="`cd $srcdir; pwd`"
 425         absbuilddir="`pwd`"
 426         for d in 2 3 4 5 ; do
 427             for mf in `cd $srcdir ; find . -maxdepth $d -mindepth $d -name GNUmakefile`; do
 428                 case "$abssrcdir" in
 429                     "$absbuilddir"/*)
 430 # source is below build directory, always copy
 431                         ;;
 432                     *)
 433                         case "$abssrcdir/${mf#./}" in
 434                             "$absbuilddir"/*)
 435 # find descended into build directory, don't copy
 436                                 continue
 437                         esac
 438                 esac
 439                 mkdir -p ${mf%/*}
 440                 cat <<EOF | $PYTHON -  > $mf
 441 print 'depth=' + ('../' * ( $d-1 ) )
 442 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 443 print 'include \$(configure-srcdir)/$mf'
 444 print 'MODULE_INCLUDES += \$(src-dir)/\$(outbase)'
 445 EOF
 446             done
 447             for mf in `cd $srcdir ; find . -maxdepth $d -mindepth $d -name '*.make' | grep -v config.make `; do
 448                 case "$abssrcdir" in
 449                     "$absbuilddir"/*)
 450 # source is below build directory, always copy
 451                         ;;
 452                     *)
 453                         case "$abssrcdir/${mf#./}" in
 454                             "$absbuilddir"/*)
 455 # find descended into build directory, don't copy
 456                                 continue
 457                         esac
 458                 esac
 459                 mkdir -p ${mf%/*}
 460                 cat <<EOF | $PYTHON -  > $mf
 461 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 462 print 'include \$(configure-srcdir)/$mf'
 463 EOF
 464             done
 465         done
 466
 467         rm -f GNUmakefile
 468         cat <<EOF > GNUmakefile
 469 depth = .
 470 include config\$(if \$(conf),-\$(conf),).make
 471 include \$(configure-srcdir)/GNUmakefile.in
 472 EOF
 473         chmod 444 GNUmakefile
 474         AC_SUBST(VPATH)
 475     fi
 476 ])
 477
 478
 479 AC_DEFUN(STEPMAKE_FLEX, [
 480     # ugh, automake: we want (and check for) flex
 481     # AC_PROG_LEX
 482     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 483
 484     # AC_PROG_LEX()
 485     # ugh, ugh
 486     ac_cv_prog_lex_root=lex.yy
 487     STEPMAKE_PROGS(FLEX, flex, $1)
 488 ])
 489
 490
 491 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 492     AC_CHECK_HEADERS([FlexLexer.h],[true],[false])
 493     if test $? -ne 0; then
 494         warn='FlexLexer.h (flex package)'
 495         STEPMAKE_ADD_ENTRY($1, $warn)
 496     fi
 497     # check for yyFlexLexer.yy_current_buffer,
 498     # in 2.5.4 <= flex < 2.5.29
 499     AC_CACHE_CHECK([for yyFlexLexer.yy_current_buffer],
 500         [stepmake_cv_flexlexer_yy_current_buffer],
 501         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 502 using namespace std;
 503 #include <FlexLexer.h>
 504 class yy_flex_lexer: public yyFlexLexer
 505 {
 506   public:
 507     yy_flex_lexer ()
 508     {
 509       yy_current_buffer = 0;
 510     }
 511 };
 512 ]])],
 513             [stepmake_cv_flexlexer_yy_current_buffer=yes],
 514             [stepmake_cv_flexlexer_yy_current_buffer=no]))
 515     if test $stepmake_cv_flexlexer_yy_current_buffer = yes; then
 516         AC_DEFINE(HAVE_FLEXLEXER_YY_CURRENT_BUFFER, 1, [Define to 1 if yyFlexLexer has yy_current_buffer.])
 517     fi
 518 ])
 519
 520
 521
 522 AC_DEFUN(STEPMAKE_FLEXLEXER_LOCATION, [
 523         AC_MSG_CHECKING([FlexLexer.h location])
 524
 525         # ugh.
 526         cat <<EOF > conftest.cc
 527 using namespace std;
 528 #include <FlexLexer.h>
 529 EOF
 530         FLEXLEXER_FILE=`eval $ac_cpp conftest.cc | \
 531           sed 's!# 1 "\(.*FlexLexer.h\)"!@FLEXLEXER@\1@@!g' | grep '@@' | \
 532           sed 's!.*@FLEXLEXER@\(.*\)@@.*$!\1!g' ` 1> /dev/null 2> /dev/null
 533         rm conftest.cc
 534         AC_SUBST(FLEXLEXER_FILE)
 535         AC_MSG_RESULT($FLEXLEXER_FILE)
 536 ])
 537
 538 AC_DEFUN(STEPMAKE_GCC_OR_CLANG, [
 539     STEPMAKE_HAS_CLANG()
 540     if test "$HAS_CLANG" = "no"; then
 541         if test "$GCC" = "yes"; then
 542             STEPMAKE_CHECK_VERSION(CC, $1, $2)
 543         else
 544             warn="$CC (Please install *GNU* cc)"
 545             STEPMAKE_ADD_ENTRY($1, $warn)
 546         fi
 547     fi
 548     # no else, we're fine with any clang
 549 ])
 550
 551 AC_DEFUN(STEPMAKE_GETTEXT, [
 552     presome=${prefix}
 553     if test "$prefix" = "NONE"; then
 554             presome=${ac_default_prefix}
 555     fi
 556     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 557
 558     AC_SUBST(localedir)
 559     AC_DEFINE_UNQUOTED(LOCALEDIR, ["${LOCALEDIR}"])
 560     AC_CHECK_LIB(intl, gettext)
 561     AC_CHECK_FUNCS(gettext)
 562 ])
 563
 564
 565 AC_DEFUN(STEPMAKE_GUILE, [
 566     STEPMAKE_PATH_PROG(GUILE, guile guile1, $1)
 567 ])
 568
 569
 570 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 571 #
 572 #   This macro runs the guile-config script, installed with Guile,
 573 #   to find out where Guile's header files and libraries are
 574 #   installed.  It sets two variables, marked for substitution, as
 575 #   by AC_SUBST.
 576 #
 577 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 578 #             code that uses Guile header files.  This is almost
 579 #             always just a -I flag.
 580 #
 581 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 582 #             program against Guile.  This includes -lguile for
 583 #             the Guile library itself, any libraries that Guile
 584 #             itself requires (like -lqthreads), and so on.  It may
 585 #             also include a -L flag to tell the compiler where to
 586 #             find the libraries.
 587
 588 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 589     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 590     if test -x $exe; then
 591         AC_MSG_CHECKING([guile compile flags])
 592         GUILE_CFLAGS="`$guile_config compile`"
 593         AC_MSG_RESULT($GUILE_CFLAGS)
 594         AC_MSG_CHECKING([guile link flags])
 595         GUILE_LDFLAGS="`$guile_config link`"
 596         AC_MSG_RESULT($GUILE_LDFLAGS)
 597     fi
 598     AC_SUBST(GUILE_CFLAGS)
 599     AC_SUBST(GUILE_LDFLAGS)
 600 ])
 601
 602
 603 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 604     ## First, let's just see if we can find Guile at all.
 605     test -n "$target_alias" && target_guile_config=$target_alias-guile-config
 606     test -n "$host_alias" && host_guile_config=$host_alias-guile-config
 607     AC_MSG_CHECKING([for guile-config])
 608     for guile_config in $GUILE_CONFIG $target_guile_config $host_guile_config $build_guile_config guile-config guile1-config; do
 609         AC_MSG_RESULT([$guile_config])
 610         if ! $guile_config --version > /dev/null 2>&1 ; then
 611             AC_MSG_WARN([cannot execute $guile_config])
 612             AC_MSG_CHECKING([if we are cross compiling])
 613             GUILE_CONFIG='echo no guile-config'
 614         else
 615             GUILE_CONFIG=$guile_config
 616             break
 617         fi
 618     done
 619     STEPMAKE_OPTIONAL_REQUIRED(GUILE_CONFIG, $guile_config, $1)
 620     if test $? -ne 0; then
 621         STEPMAKE_ADD_ENTRY($1, 'guile-config (guile-devel, guile-dev or libguile-dev package) or guile1-config (guile1-devel package)')
 622     fi
 623
 624     STEPMAKE_CHECK_SEARCH_RESULT(GUILE_CONFIG)
 625     # urg.  should test functionality rather than version.
 626     if test $? -eq 0 -a -n "$2"; then
 627         STEPMAKE_CHECK_VERSION(GUILE_CONFIG, $1, $2)
 628     fi
 629
 630     AC_SUBST(GUILE_CONFIG)
 631
 632     guile_version="$ver"
 633     changequote(<<, >>)#dnl
 634     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 635     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 636     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 637     changequote([, ])#dnl
 638     STEPMAKE_GUILE_FLAGS
 639     save_CPPFLAGS="$CPPFLAGS"
 640     save_LIBS="$LIBS"
 641     CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 642     LIBS="$GUILE_LDFLAGS $LIBS"
 643     AC_CHECK_HEADERS([libguile.h])
 644     AC_CHECK_LIB(guile, scm_boot_guile)
 645     AC_CHECK_FUNCS(scm_boot_guile,,libguile_b=no)
 646     if test "$libguile_b" = "no"; then
 647             warn='libguile (libguile-dev, guile-devel or guile-dev
 648    package).'
 649             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 650     fi
 651     CPPFLAGS="$save_CPPFLAGS"
 652     LIBS="$save_LIBS"
 653     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 654     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 655     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 656 ])
 657
 658
 659 AC_DEFUN(STEPMAKE_DLOPEN, [
 660     AC_CHECK_LIB(dl, dlopen)
 661     AC_CHECK_FUNCS(dlopen)
 662 ])
 663
 664 AC_DEFUN(STEPMAKE_HAS_CLANG, [
 665     AC_EGREP_CPP(yes,
 666       [#ifdef __clang__
 667        yes
 668        #endif
 669       ], HAS_CLANG=yes, HAS_CLANG=no)
 670 ])
 671
 672 AC_DEFUN(STEPMAKE_GXX_OR_CLANG, [
 673     STEPMAKE_HAS_CLANG()
 674     if test "$HAS_CLANG" = "no"; then
 675         if test "$GXX" = "yes"; then
 676             STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 677         else
 678             warn="$CXX (Please install *GNU* c++)"
 679             STEPMAKE_ADD_ENTRY($1, $warn)
 680         fi
 681     fi
 682     # no else, we're fine with any clang
 683 ])
 684
 685
 686 AC_DEFUN(STEPMAKE_INIT, [
 687
 688     . $srcdir/VERSION
 689     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 690     MICRO_VERSION=$PATCH_LEVEL
 691     TOPLEVEL_VERSION=$FULL_VERSION
 692     if test x$MY_PATCH_LEVEL != x; then
 693         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 694     fi
 695     VERSION=$FULL_VERSION
 696     export MAJOR_VERSION MINOR_VERSION PATCH_LEVEL
 697     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 698     changequote(<<, >>)#dnl
 699     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 700     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 701     changequote([, ])#dnl
 702
 703     # No versioning on directory names of sub-packages
 704     # urg, urg
 705     stepmake=${datadir}/stepmake
 706     presome=${prefix}
 707     if test "$prefix" = "NONE"; then
 708             presome=${ac_default_prefix}
 709     fi
 710     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 711
 712     # urg, how is this supposed to work?
 713     if test "$program_prefix" = "NONE"; then
 714           program_prefix=
 715     fi
 716     if test "$program_suffix" = "NONE"; then
 717           program_suffix=
 718     fi
 719
 720     AC_MSG_CHECKING(Package)
 721     if test "$PACKAGE" = "STEPMAKE"; then
 722         AC_MSG_RESULT(Stepmake package!)
 723
 724         AC_MSG_CHECKING(builddir)
 725
 726         ugh_ugh_autoconf250_builddir="`pwd`"
 727
 728         if test "$srcdir" = "."; then
 729             srcdir_build=yes
 730         else
 731             srcdir_build=no
 732             package_builddir="`dirname $ugh_ugh_autoconf250_builddir`"
 733             package_srcdir="`dirname  $srcdir`"
 734         fi
 735         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 736
 737         (cd stepmake 2>/dev/null || mkdir stepmake)
 738         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 739         stepmake=stepmake
 740     else
 741         AC_MSG_RESULT($PACKAGE)
 742
 743         AC_MSG_CHECKING(builddir)
 744         ugh_ugh_autoconf250_builddir="`pwd`"
 745
 746         here_dir=$(cd . && pwd)
 747         full_src_dir=$(cd $srcdir && pwd)
 748
 749         if test "$full_src_dir" = "$here_dir"; then
 750             srcdir_build=yes
 751         else
 752             srcdir_build=no
 753         fi
 754         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 755
 756         AC_MSG_CHECKING(for stepmake)
 757         # Check for installed stepmake
 758         if test -d $stepmake; then
 759             AC_MSG_RESULT($stepmake)
 760         else
 761             stepmake="`cd $srcdir/stepmake; pwd`"
 762             AC_MSG_RESULT([$srcdir/stepmake  ($datadir/stepmake not found)])
 763         fi
 764     fi
 765
 766     AC_SUBST(ugh_ugh_autoconf250_builddir)
 767
 768     # Use absolute directory for non-srcdir builds, so that build
 769     # dir can be moved.
 770     if test "$srcdir_build" = "no" ;  then
 771         srcdir="`cd $srcdir; pwd`"
 772     fi
 773
 774     AC_SUBST(srcdir)
 775     AC_SUBST(stepmake)
 776     AC_SUBST(package)
 777     AC_SUBST(PACKAGE)
 778     AC_SUBST(PACKAGE_NAME)
 779     AC_SUBST(VERSION)
 780     AC_SUBST(MAJOR_VERSION)
 781     AC_SUBST(MINOR_VERSION)
 782     AC_SUBST(MICRO_VERSION)
 783
 784     # stepmake nonstandard names
 785     AC_SUBST(PATCH_LEVEL)
 786     AC_SUBST(TOPLEVEL_VERSION)
 787
 788     # We don't need the upper case variant,
 789     # so stick to macros are uppercase convention.
 790     # AC_DEFINE_UNQUOTED(package, ["${package}"])
 791     # AC_DEFINE_UNQUOTED(PACKAGE, ["${PACKAGE}"])
 792     AC_DEFINE_UNQUOTED(PACKAGE, ["${package}"])
 793     AC_DEFINE_UNQUOTED(PACKAGE_NAME, ["${PACKAGE_NAME}"])
 794     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, ["${FULL_VERSION}"])
 795
 796     if test -z "$package_depth"; then
 797         package_depth="."
 798     else
 799         package_depth="../$package_depth"
 800     fi
 801     export package_depth
 802     AC_SUBST(package_depth)
 803
 804     AUTOGENERATE="This file was automatically generated by configure"
 805     AC_SUBST(AUTOGENERATE)
 806
 807     CONFIGSUFFIX=
 808     AC_ARG_ENABLE(config,
 809     [AS_HELP_STRING([--enable-config=CONF],
 810                     [put settings in config-CONF.make and config-CONF.h;
 811                     do `make conf=CONF' to get output in ./out-CONF])],
 812     [CONFIGURATION=$enableval])
 813
 814     ##'`#
 815
 816     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 817     CONFIGFILE=config$CONFIGSUFFIX
 818     AC_SUBST(CONFIGSUFFIX)
 819
 820     AC_CANONICAL_HOST
 821     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 822     STEPMAKE_PROGS(FIND, find, REQUIRED)
 823
 824     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 825
 826     if test "$(echo 2)" != "2" ||
 827         test "x`uname`" = "xHP-UX"; then
 828         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 829         AC_PATH_PROG(BASH, bash, $KSH)
 830         STEPMAKE_WARN(avoiding buggy /bin/sh)
 831         AC_PATH_PROG(SHELL, bash, $KSH)
 832     else
 833         SHELL=/bin/sh
 834         AC_PATH_PROG(BASH, bash, $SHELL)
 835     fi
 836     AC_SUBST(SHELL)
 837
 838     STEPMAKE_PYTHON(REQUIRED, 1.5)
 839
 840     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 841         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 842         if test "$?" = 1; then
 843             warn='make (Please install *GNU* make)'
 844             # STEPMAKE_WARN($warn)
 845             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 846         fi
 847     fi
 848
 849     ROOTSEP=':'
 850     DIRSEP='/'
 851     PATHSEP=':'
 852     LN=ln
 853     LN_S='ln -s'
 854     ZIP="zip -r -9"
 855
 856     AC_SUBST(program_prefix)
 857     AC_SUBST(program_suffix)
 858     AC_SUBST(ZIP)
 859     AC_SUBST(LN)
 860     AC_SUBST(LN_S)
 861     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
 862     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
 863     AC_SUBST(DIRSEP)
 864     AC_SUBST(PATHSEP)
 865     AC_SUBST(ROOTSEP)
 866
 867     STEPMAKE_DATADIR
 868     STEPMAKE_LIBDIR
 869 ])
 870
 871
 872 AC_DEFUN(STEPMAKE_LIB, [
 873     STEPMAKE_PROGS(AR, ar, $1)
 874     AC_PROG_RANLIB
 875     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 876 ])
 877
 878
 879 AC_DEFUN(STEPMAKE_LIBTOOL, [
 880     # libtool.info ...
 881     # **Never** try to set library version numbers so that they correspond
 882     # to the release number of your package.  This is an abuse that only
 883     # fosters misunderstanding of the purpose of library versions.
 884
 885     REVISION=$PATCH_LEVEL
 886     # CURRENT=$MINOR_VERSION
 887     CURRENT=`expr $MINOR_VERSION + 1`
 888     # AGE=`expr $MAJOR_VERSION + 1`
 889     AGE=$MAJOR_VERSION
 890     AC_SUBST(CURRENT)
 891     AC_SUBST(REVISION)
 892     AC_SUBST(AGE)
 893 ])
 894
 895
 896 AC_DEFUN(STEPMAKE_LOCALE, [
 897     lang=English
 898     ALL_LINGUAS="en nl"
 899
 900     # with/enable ??
 901     AC_ARG_WITH(localedir,
 902     [AS_HELP_STRING([--with-localedir=DIR],
 903                     [location of locales.  Default: PREFIX/share/locale])],
 904     localedir=$with_localedir,
 905     localedir='${prefix}/share/locale')
 906
 907     AC_ARG_WITH(lang,
 908     [AS_HELP_STRING([--with-lang=LANG],
 909                     [use LANG as language to emit messages])],
 910     language=$with_lang,
 911     language=English)
 912
 913     AC_MSG_CHECKING(language)
 914     case "$language" in
 915       En* | en* | Am* | am* | US* | us*)
 916             lang=English;;
 917       NL | nl | Du* | du* | Ned* | ned*)
 918             lang=Dutch;;
 919       "")
 920             lang=English;;
 921       *)
 922             lang=unknown;;
 923     esac
 924     AC_MSG_RESULT($lang)
 925
 926     if test "$lang" = "unknown" ; then
 927         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 928     fi
 929
 930 ])
 931
 932
 933 AC_DEFUN(STEPMAKE_MAKEINFO, [
 934     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 935 ])
 936
 937
 938 AC_DEFUN(STEPMAKE_MAN, [
 939     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 940     AC_SUBST(GROFF)
 941     STEPMAKE_PROGS(TROFF, troff, $1)
 942     AC_SUBST(TROFF)
 943     STEPMAKE_PROGS(TBL, tbl, $1)
 944     AC_SUBST(TBL)
 945 ])
 946
 947
 948 AC_DEFUN(STEPMAKE_MSGFMT, [
 949     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
 950 ])
 951
 952
 953 # Check for program ($2), set full path result to ($1).
 954 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 955 AC_DEFUN(STEPMAKE_PATH_PROG, [
 956     AC_CHECK_PROGS($1, $2, no)
 957     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 958     if test $? -eq 0; then
 959         AC_PATH_PROGS($1, $2)
 960         if test -n "$4"; then
 961             STEPMAKE_CHECK_VERSION($1, $3, $4)
 962         fi
 963     fi
 964 ])
 965
 966
 967 # Check for program in set of names ($2), set result to ($1) .
 968 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 969 # If exists, and a minimal version ($4) is required
 970 AC_DEFUN(STEPMAKE_PROGS, [
 971     AC_CHECK_PROGS($1, $2, no)
 972     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 973     if test $? -eq 0 -a -n "$4"; then
 974         STEPMAKE_CHECK_VERSION($1, $3, $4)
 975     fi
 976 ])
 977
 978
 979 AC_DEFUN(STEPMAKE_PERL, [
 980     STEPMAKE_PATH_PROG(PERL, perl, $1)
 981 ])
 982
 983
 984 AC_DEFUN(STEPMAKE_PYTHON, [
 985     unset pv
 986     AC_MSG_CHECKING([for python])
 987     for python in $PYTHON python python2 python2.4 python2.3 python2.2 python2.1 python2.0; do
 988         AC_MSG_RESULT([$python])
 989         if ! $python -V > /dev/null 2>&1 ; then
 990             #AC_MSG_WARN([cannot execute $python])
 991             PYTHON='echo no python'
 992         else
 993             unset pv
 994             STEPMAKE_CHECK_VERSION(python, pv, $2)
 995             if test -z "$pv"; then
 996                 PYTHON=$python
 997                 break
 998             fi
 999         fi
1000     done
1001     if test -n "$pv"; then
1002         STEPMAKE_ADD_ENTRY($1, $pv)
1003     fi
1004     # clear cached value since arg 2 might point us to a new binary
1005     unset ac_cv_path_PYTHON
1006
1007     AC_PATH_PROG(PYTHON, $PYTHON)
1008     AC_SUBST(PYTHON)
1009 ])
1010
1011 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
1012     AC_ARG_WITH(python-include,
1013         [AS_HELP_STRING([--with-python-include=DIR],
1014                         [location of the python include dir])],[
1015         if test "$withval" = "yes" -o "$withval" = "no"; then
1016             AC_MSG_WARN(Usage: --with-python-include=includedir)
1017         else
1018             PYTHON_CFLAGS="-I${withval}"
1019         fi
1020     ])
1021
1022     AC_ARG_WITH(python-lib,
1023         [AS_HELP_STRING([--with-python-lib=NAME],
1024                         [name of the python lib])],[
1025         if test "$withval" = "yes" -o "$withval" = "no"; then
1026             AC_MSG_WARN(Usage: --with-python-lib=name)
1027         else
1028             LDFLAGS="$LDFLAGS -l${withval}"
1029         fi
1030     ])
1031
1032     AC_CHECK_PROGS(PYTHON_CONFIG, python-config, no)
1033
1034     if test -z "$PYTHON_CFLAGS" -a "$PYTHON_CONFIG" != "no"; then
1035         # Clean out junk: http://bugs.python.org/issue3290
1036         # Python headers may need some -f* flags, leave them in.
1037         # We want the sed commands to look like 's/-[WDOm][[:alnum:][:punct:]][[:alnum:][:punct:]]*//g' and 's/-arch [^[:space:]]*//g', but automake eats brackets.
1038          #PYTHON_CFLAGS=`$PYTHON_CONFIG --cflags | sed -e 's/-[[WDOm]][[[:alnum:][:punct:]]][[[:alnum:][:punct:]]]*//g' | sed -e 's/-arch @<:@^@<:@:space:@:>@@:>@*//g'`
1039          # The above sed BRE matches parts of legal options, stipping down part of that option, resulting in invalid gcc arguments. Gentoo Bug #415793
1040          # For instance, '-floop-stip-mime' becomes '-floop-strip', and '-fvect-cost-model' becomes '-fvect-cost'.
1041          # Tentative fix to require a non alphanumeric character before the initial hyphen of the BRE or the hyphen being the first character in the string.
1042          PYTHON_CFLAGS=`$PYTHON_CONFIG --cflags | sed -e 's/\(^\|[[^[:alnum:]]]\)-[[WDOm]][[[:alnum:][:punct:]]][[[:alnum:][:punct:]]]*//g' | sed -e 's/-arch @<:@^@<:@:space:@:>@@:>@*//g'`
1043         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
1044     fi
1045
1046     if test -z "$PYTHON_CFLAGS" -a "$cross_compiling" = "no"; then
1047         changequote(<<, >>)#dnl
1048         # alternatively, for python >= 2.0
1049         # 'import sys, distutils.sysconfig; sys.stdout.write (distutils.sysconfig.get_python_inc ())'
1050         PYTHON_INCLUDE=`$PYTHON -c 'import sys; sys.stdout.write ("%s/include/python%s" % (sys.prefix, sys.version[:3]))'`
1051         PYTHON_CFLAGS="-I$PYTHON_INCLUDE"
1052         changequote([, ])#dnl
1053     fi
1054
1055     if test -z "$PYTHON_HEADER"; then
1056         CPPFLAGS="$PYTHON_CFLAGS $CPPFLAGS"
1057         AC_CHECK_HEADERS([Python.h],[PYTHON_HEADER=yes])
1058     fi
1059
1060     if test -z "$PYTHON_HEADER"; then
1061         warn="Python.h (python-devel, python-dev or libpython-dev package)"
1062         STEPMAKE_ADD_ENTRY($1, $warn)
1063     fi
1064 ])
1065
1066
1067
1068 AC_DEFUN(STEPMAKE_STL_DATA_METHOD, [
1069     AC_CACHE_CHECK([for stl.data () method],
1070         [stepmake_cv_stl_data_method],
1071         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1072 #include <vector>
1073 using namespace std;
1074 vector <int> v;
1075 void *p = v.data ();
1076 ]])],
1077             [stepmake_cv_stl_data_method=yes],
1078             [stepmake_cv_stl_data_method=no]))
1079     if test $stepmake_cv_stl_data_method = yes; then
1080         AC_DEFINE(HAVE_STL_DATA_METHOD, 1, [define if stl classes have data () method])
1081     fi
1082 ])
1083
1084
1085 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
1086     # ugh
1087     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, OPTIONAL)
1088 ])
1089
1090 AC_DEFUN(STEPMAKE_TEXMF, [
1091     STEPMAKE_PROGS(METAFONT, mf-nowin mf mfw mfont, $1)
1092     STEPMAKE_PROGS(METAPOST, mpost, $1)
1093
1094     AC_MSG_CHECKING(for working metafont mode)
1095     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
1096     for MFMODE in $modelist; do
1097         $METAFONT -progname=mf "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
1098         if test -f mfput.tfm; then
1099             break;
1100         fi
1101     done
1102     AC_MSG_RESULT($MFMODE)
1103
1104     rm -f mfput.*
1105
1106     AC_SUBST(MFMODE)
1107 ])
1108
1109
1110 AC_DEFUN(STEPMAKE_WARN, [
1111     AC_MSG_WARN($1)
1112     warn_b=yes
1113 ])
1114
1115
1116 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1117 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1118 dnl also defines GSTUFF_PKG_ERRORS on error
1119 AC_DEFUN(PKG_CHECK_MODULES, [
1120   succeeded=no
1121
1122   if test -z "$PKG_CONFIG"; then
1123     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1124   fi
1125
1126   if test "$PKG_CONFIG" = "no" ; then
1127      echo "*** The pkg-config script could not be found. Make sure it is"
1128      echo "*** in your path, or set the PKG_CONFIG environment variable"
1129      echo "*** to the full path to pkg-config."
1130      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1131   else
1132      PKG_CONFIG_MIN_VERSION=0.9.0
1133      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1134         AC_MSG_CHECKING(for $2)
1135
1136         if $PKG_CONFIG --exists "$2" ; then
1137             AC_MSG_RESULT(yes)
1138             succeeded=yes
1139
1140             AC_MSG_CHECKING($1_CFLAGS)
1141             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1142             AC_MSG_RESULT($$1_CFLAGS)
1143
1144             AC_MSG_CHECKING($1_LIBS)
1145             $1_LIBS=`$PKG_CONFIG --libs "$2"`
1146             AC_MSG_RESULT($$1_LIBS)
1147         else
1148             $1_CFLAGS=""
1149             $1_LIBS=""
1150             ## If we have a custom action on failure, don't print errors, but
1151             ## do set a variable so people can do so.
1152             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1153             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1154         fi
1155
1156         AC_SUBST($1_CFLAGS)
1157         AC_SUBST($1_LIBS)
1158      fi
1159   fi
1160
1161   if test $succeeded = yes; then
1162      ifelse([$3], , :, [$3])
1163   else
1164      ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
1165   fi
1166 ])
1167
1168 AC_DEFUN(STEPMAKE_FREETYPE2, [
1169     PKG_CHECK_MODULES(FREETYPE2, $1 >= $3, have_freetype2=yes, true)
1170     if test "$have_freetype2" = yes; then
1171         AC_DEFINE(HAVE_FREETYPE2)
1172         save_CPPFLAGS="$CPPFLAGS"
1173         save_LIBS="$LIBS"
1174         CPPFLAGS="$FREETYPE2_CFLAGS $CPPFLAGS"
1175         LIBS="$FREETYPE2_LIBS $LIBS"
1176         AC_SUBST(FREETYPE2_CFLAGS)
1177         AC_SUBST(FREETYPE2_LIBS)
1178         CPPFLAGS="$save_CPPFLAGS"
1179         LIBS="$save_LIBS"
1180     else
1181         # UGR
1182         #r="lib$1-dev or $1-devel"
1183         r="libfreetype6-dev or freetype?-devel"
1184         ver="`pkg-config --modversion $1`"
1185         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1186     fi
1187 ])
1188
1189 AC_DEFUN(STEPMAKE_PANGO, [
1190     PKG_CHECK_MODULES(PANGO, $1 >= $3, have_pango16=yes, true)
1191     if test "$have_pango16" = yes ; then
1192         AC_DEFINE(HAVE_PANGO16)
1193         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1194         save_CPPFLAGS="$CPPFLAGS"
1195         save_LIBS="$LIBS"
1196         CPPFLAGS="$PANGO_CFLAGS $CPPFLAGS"
1197         LIBS="$PANGO_LIBS $LIBS"
1198         AC_CHECK_HEADERS([pango/pangofc-fontmap.h])
1199         AC_CHECK_FUNCS([pango_fc_font_map_add_decoder_find_func])
1200         AC_SUBST(PANGO_CFLAGS)
1201         AC_SUBST(PANGO_LIBS)
1202         CPPFLAGS="$save_CPPFLAGS"
1203         LIBS="$save_LIBS"
1204     else
1205         # UGR
1206         #r="lib$1-dev or $1-devel"
1207         r="libpango1.0-dev or pango1.0-devel"
1208         ver="`pkg-config --modversion $1`"
1209         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1210     fi
1211 ])
1212
1213 AC_DEFUN(STEPMAKE_PANGO_FT2, [
1214     PKG_CHECK_MODULES(PANGO_FT2, $1 >= $3, have_pangoft2=yes, true)
1215     if test "$have_pangoft2" = yes ; then
1216         AC_DEFINE(HAVE_PANGO16)
1217         AC_DEFINE(HAVE_PANGO_FT2)
1218         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1219         save_CPPFLAGS="$CPPFLAGS"
1220         save_LIBS="$LIBS"
1221         CPPFLAGS="$CPPFLAGS $PANGO_FT2_CFLAGS"
1222         LIBS="$PANGO_FT2_LIBS $LIBS"
1223         AC_CHECK_HEADERS([pango/pangoft2.h])
1224         AC_CHECK_FUNCS([pango_ft2_font_map_create_context])
1225         AC_SUBST(PANGO_FT2_CFLAGS)
1226         AC_SUBST(PANGO_FT2_LIBS)
1227         CPPFLAGS="$save_CPPFLAGS"
1228         LIBS="$save_LIBS"
1229     else
1230         # UGR
1231         #r="lib$1-dev or $1-devel"e
1232         r="libpango1.0-dev or pango?-devel"
1233         ver="`pkg-config --modversion $1`"
1234         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1235     fi
1236 ])
1237
1238 AC_DEFUN(STEPMAKE_FONTCONFIG, [
1239     PKG_CHECK_MODULES(FONTCONFIG, $1 >= $3, have_fontconfig=yes, true)
1240     if test "$have_fontconfig" = yes ; then
1241         AC_DEFINE(HAVE_FONTCONFIG)
1242         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1243         save_CPPFLAGS="$CPPFLAGS"
1244         save_LIBS="$LIBS"
1245         CPPFLAGS="$FONTCONFIG_CFLAGS $CPPFLAGS"
1246         LIBS="$FONTCONFIG_LIBS $LIBS"
1247         AC_SUBST(FONTCONFIG_CFLAGS)
1248         AC_SUBST(FONTCONFIG_LIBS)
1249         CPPFLAGS="$save_CPPFLAGS"
1250         LIBS="$save_LIBS"
1251     else
1252         r="lib$1-dev or $1-devel"
1253         ver="`pkg-config --modversion $1`"
1254         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1255     fi
1256 ])
1257
1258 AC_DEFUN(STEPMAKE_WINDOWS, [
1259     AC_CYGWIN
1260     AC_MINGW32
1261
1262     if test "$CYGWIN" = "yes"; then
1263         LN_S='cp -r' # Cygwin symbolic links do not work for native apps.
1264         program_suffix=.exe
1265         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1266     elif test "$MINGW32" = "yes"; then
1267         LN='cp -r'
1268         LN_S='cp -r'
1269         program_suffix=.exe
1270         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1271         PATHSEP=';'
1272     fi
1273
1274     AC_SUBST(LN)
1275     AC_SUBST(LN_S)
1276     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
1277     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
1278     AC_SUBST(DIRSEP)
1279     AC_SUBST(PATHSEP)
1280     AC_SUBST(program_suffix)
1281
1282     AC_MSG_CHECKING([for some flavor of Windows])
1283     if test "$CYGWIN$MINGW32" = "nono"; then
1284         PLATFORM_WINDOWS=no
1285     else
1286         PLATFORM_WINDOWS=yes
1287     fi
1288     AC_MSG_RESULT([$PLATFORM_WINDOWS])
1289     AC_SUBST(PLATFORM_WINDOWS)
1290     STEPMAKE_PROGS(WINDRES, $target-windres windres, x)
1291     AC_SUBST(WINDRES)
1292 ])