aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl WARNING WARNING WARNING
   3 dnl do not edit! this is aclocal.m4, generated from /home/fred/lily/stepmake/aclocal.m4
   4 dnl aclocal.m4   -*-shell-script-*-
   5 dnl StepMake subroutines for configure.in
   6
   7
   8 ### mostly interal macros
   9
  10 # Get full path of executable ($1)
  11 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
  12     ## which doesn't work in ash, if /usr/bin/which isn't installed
  13     ## type -p doesn't work in ash
  14     ## command -v doesn't work in zsh
  15     ## command -v "$1" 2>&1
  16     ## this test should work in ash, bash, pdksh (ksh), zsh
  17     type -p "$1" 2>/dev/null | tail -1 | awk '{print $NF}'
  18 ])
  19
  20
  21 # Get version string from executable ($1)
  22 AC_DEFUN(STEPMAKE_GET_VERSION, [
  23     ## "$1" --version 2>&1 | grep -v '^$' | head -1 | awk '{print $NF}'
  24     ##
  25     ## ARG.
  26     ## Workaround for broken Debian gcc version string:
  27     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  28     ##
  29     ## Assume, and hunt for, dotted version multiplet.
  30     changequote(<<, >>)dnl
  31     "$1" --version 2>&1 | grep '[0-9]\.[0-9]' | head -1 | \
  32         sed -e 's/.*[^-.0-9]\([0-9][0-9]*\.[0-9][.0-9]*\).*/\1/'
  33     changequote([, ])dnl
  34 ])
  35
  36 # Calculate simplistic numeric version from version string ($1)
  37 # As yet, we have no need for something more elaborate.
  38 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  39     echo "$1" | awk -F. '
  40     {
  41       if ([$]3) {three = [$]3}
  42       else {three = 0}
  43     }
  44     {printf "%d\n", [$]1*1000000 + [$]2*1000 + three}'
  45 ])
  46
  47
  48 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  49 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  50     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  51 ])
  52
  53 # Check if tested program ($2) was found ($1).
  54 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  55 # We could abort here if a 'REQUIRED' program is not found
  56 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  57     STEPMAKE_CHECK_SEARCH_RESULT($1)
  58     if test $? -ne 0; then
  59         STEPMAKE_ADD_ENTRY($3, $2)
  60         if test "$3" = "REQUIRED"; then
  61             command="echo ERROR: $2 not found"
  62             # abort configure process here?
  63         else
  64             command="- echo $2 not found"
  65         fi
  66         eval "$1"='$command'
  67         false
  68     else
  69         true
  70     fi
  71 ])
  72
  73
  74 # Return if tested proram ($1) was found (true) or not (false).
  75 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  76     r="`eval echo '$'"$1"`"
  77     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  78         true
  79     else
  80         ##STEPMAKE_WARN(cannot find $2. $3)
  81         false
  82     fi
  83 ])
  84
  85
  86 # Check version of program ($1)
  87 # If version is smaller than requested ($3),
  88 # add entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
  89 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
  90     r="`eval echo '$'"$1"`"
  91     AC_MSG_CHECKING([$r version])
  92     exe=`STEPMAKE_GET_EXECUTABLE($r)`
  93     ver=`STEPMAKE_GET_VERSION($exe)`
  94     num=`STEPMAKE_NUMERIC_VERSION($ver)`
  95     req=`STEPMAKE_NUMERIC_VERSION($3)`
  96     AC_MSG_RESULT([$ver])
  97     if test "$num" -lt "$req"; then
  98         STEPMAKE_ADD_ENTRY($2, ["$r $3 (installed: $ver)"])
  99     fi
 100 ])
 101
 102 ### Macros to build configure.in
 103
 104
 105 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 106     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 107     if test "$BIBTEX2HTML" = "bib2html"; then
 108         BIBTEX2HTML_FLAGS='$< $(@)'
 109     else
 110         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 111     fi
 112     AC_SUBST(BIBTEX2HTML)
 113     AC_SUBST(BIBTEX2HTML_FLAGS)
 114 ])
 115
 116
 117 AC_DEFUN(STEPMAKE_BISON, [
 118     # ugh, automake: we want (and check for) bison
 119     AC_PROG_YACC
 120
 121     STEPMAKE_PROGS(BISON, bison, $1)
 122
 123     # urg.  should test functionality rather than version.
 124     if test "$BISON" = "bison" -a -n "$2"; then
 125         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 126     fi
 127 ])
 128
 129
 130 AC_DEFUN(STEPMAKE_COMPILE, [
 131     # -O is necessary to get inlining
 132     CFLAGS=${CFLAGS-""}
 133     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 134     LDFLAGS=${LDFLAGS-""}
 135     checking_b=yes
 136     optimise_b=yes
 137     profile_b=no
 138     debug_b=yes
 139
 140     AC_ARG_ENABLE(checking,
 141     [  --enable-checking       set runtime checks (assert calls).  Default: on],
 142     [checking_b=$enableval] )
 143
 144     AC_ARG_ENABLE(debugging,
 145     [  --enable-debugging      compile with debugging info.  Default: on],
 146     [debug_b=$enableval])
 147
 148     AC_ARG_ENABLE(optimising,
 149     [  --enable-optimising     compile with optimising.  Default: on],
 150     [optimise_b=$enableval])
 151
 152     AC_ARG_ENABLE(profiling,
 153     [  --enable-profiling      compile with gprof support.  Default: off],
 154     [profile_b=$enableval])
 155
 156
 157     if test "$checking_b" = no; then
 158         # ugh
 159         AC_DEFINE(NDEBUG)
 160         DEFINES="$DEFINES -DNDEBUG"
 161     fi
 162
 163     if test "$optimise_b" = yes; then
 164         OPTIMIZE="-O2 -finline-functions"
 165     fi
 166
 167
 168     if test $profile_b = yes; then
 169         EXTRA_LIBES="-pg"
 170         OPTIMIZE="$OPTIMIZE -pg"
 171     fi
 172
 173     if test $debug_b = yes; then
 174         OPTIMIZE="$OPTIMIZE -g"
 175     fi
 176
 177
 178     AC_PROG_CC
 179     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 180     LD='$(CC)'
 181     AC_SUBST(LD)
 182
 183     CFLAGS="$CFLAGS $OPTIMIZE"
 184     CPPFLAGS=${CPPFLAGS-""}
 185
 186     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 187     save_cflags="$CFLAGS"
 188     case "$host" in
 189         alpha*-*-*)
 190             dnl should do compile test?
 191             AC_MSG_RESULT(-mieee)
 192             CFLAGS="-mieee $CFLAGS"
 193             ;;
 194         *)
 195             AC_MSG_RESULT([none])
 196             ;;
 197     esac
 198     AC_SUBST(cross_compiling)
 199     AC_SUBST(CFLAGS)
 200     AC_SUBST(CPPFLAGS)
 201     AC_SUBST(LDFLAGS)
 202     AC_SUBST(ICFLAGS)
 203     AC_SUBST(ILDFLAGS)
 204     AC_SUBST(DEFINES)
 205     AC_SUBST(EXTRA_LIBES)
 206 ])
 207
 208 AC_DEFUN(STEPMAKE_CXX, [
 209     AC_LANG([C++])
 210     AC_PROG_CXX
 211     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 212
 213     CPPFLAGS="$CPPFLAGS $DEFINES"
 214     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 215     LDFLAGS="$LDFLAGS $EXTRA_LIBES"
 216
 217     AC_SUBST(CXXFLAGS)
 218     AC_SUBST(CXX)
 219     LD='$(CXX)'
 220     AC_SUBST(LD)
 221 ])
 222
 223
 224 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 225     AC_CACHE_CHECK([whether explicit instantiation is needed],
 226         lily_cv_need_explicit_instantiation,
 227         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 228     template <class T> struct foo { static int baz; };
 229     template <class T> int foo<T>::baz = 1;
 230     ]], [[ return foo<int>::baz; ]])],[lily_cv_need_explicit_instantiation=no],[lily_cv_need_explicit_instantiation=yes]))
 231     if test x"$lily_cv_need_explicit_instantiation"x = x"yes"x; then
 232         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 233     fi
 234 ])
 235
 236
 237 AC_DEFUN(STEPMAKE_DATADIR, [
 238     if test "$datadir" = "\${prefix}/share"; then
 239             datadir='${prefix}/share'
 240     fi
 241     presome=${prefix}
 242     if test "$prefix" = "NONE"; then
 243         presome=${ac_default_prefix}
 244     fi
 245
 246     package_datadir=$datadir/$package
 247     local_package_datadir=$package_datadir/$FULL_VERSION
 248     build_package_datadir=$ugh_ugh_autoconf250_builddir/share/$package
 249
 250     DATADIR=`echo ${datadir} | sed "s!\\\${prefix}!$presome!"`
 251     PACKAGE_DATADIR=`echo ${package_datadir} | sed "s!\\\${prefix}!$presome!"`
 252     LOCAL_PACKAGE_DATADIR=`echo ${local_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 253     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 254
 255     AC_SUBST(datadir)
 256     AC_SUBST(package_datadir)
 257     AC_SUBST(local_package_datadir)
 258     AC_SUBST(build_package_datadir)
 259     AC_DEFINE_UNQUOTED(DATADIR, ["${DATADIR}"])
 260     AC_DEFINE_UNQUOTED(PACKAGE_DATADIR, ["${PACKAGE_DATADIR}"])
 261     AC_DEFINE_UNQUOTED(LOCAL_PACKAGE_DATADIR, ["${LOCAL_PACKAGE_DATADIR}"])
 262     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, ["${BUILD_PACKAGE_DATADIR}"])
 263 ])
 264
 265
 266 AC_DEFUN(STEPMAKE_END, [
 267     AC_SUBST(OPTIONAL)
 268     AC_SUBST(REQUIRED)
 269
 270     AC_CONFIG_FILES([$CONFIGFILE.make:config.make.in])
 271 AC_OUTPUT
 272
 273
 274     if test -n "$OPTIONAL"; then
 275         echo
 276         echo "WARNING: Please consider installing optional programs: $OPTIONAL"
 277     fi
 278
 279     if test -n "$REQUIRED"; then
 280         echo
 281         echo "ERROR: Please install required programs: $REQUIRED"
 282     fi
 283
 284     if test -n "$OPTIONAL$REQUIRED"; then
 285         echo
 286         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 287         echo "Remove config.cache before rerunning ./configure"
 288     fi
 289
 290     if test -n "$REQUIRED"; then
 291         rm -f $srcdir/GNUmakefile
 292         exit 1
 293     fi
 294
 295     # regular in-place build
 296     # test for srcdir_build = yes ?
 297     if test "$srcdir_build" = "yes"; then
 298         rm -f $srcdir/GNUmakefile
 299         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 300         chmod 444 $srcdir/GNUmakefile
 301     else # --srcdir build
 302         rm -f GNUmakefile
 303         cp $srcdir/make/srcdir.make.in GNUmakefile
 304         chmod 444 GNUmakefile
 305     fi
 306 ])
 307
 308
 309 AC_DEFUN(STEPMAKE_FLEX, [
 310     # ugh, automake: we want (and check for) flex
 311     # AC_PROG_LEX
 312     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 313
 314     # AC_PROG_LEX()
 315     # ugh, ugh
 316     ac_cv_prog_lex_root=lex.yy
 317     STEPMAKE_PROGS(FLEX, flex, $1)
 318 ])
 319
 320
 321 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 322     AC_CHECK_HEADERS([FlexLexer.h],[true],[false])
 323     if test $? -ne 0; then
 324         warn='FlexLexer.h (flex package)'
 325         STEPMAKE_ADD_ENTRY($1, $warn)
 326     fi
 327 ])
 328
 329
 330 AC_DEFUN(STEPMAKE_GCC, [
 331     if test "$GCC" = "yes"; then
 332         STEPMAKE_CHECK_VERSION(CC, $1, $2)
 333     else
 334         warn="$CC (Please install *GNU* cc)"
 335         STEPMAKE_ADD_ENTRY($1, $warn)
 336     fi
 337 ])
 338
 339
 340 AC_DEFUN(STEPMAKE_GETTEXT, [
 341     presome=${prefix}
 342     if test "$prefix" = "NONE"; then
 343             presome=${ac_default_prefix}
 344     fi
 345     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 346
 347     AC_SUBST(localedir)
 348     AC_DEFINE_UNQUOTED(LOCALEDIR, ["${LOCALEDIR}"])
 349     AC_CHECK_LIB(intl, gettext)
 350     AC_CHECK_FUNCS(gettext)
 351 ])
 352
 353
 354 AC_DEFUN(STEPMAKE_GUILE, [
 355     STEPMAKE_PATH_PROG(GUILE, guile, $1)
 356 ])
 357
 358
 359 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 360 #
 361 #   This macro runs the guile-config script, installed with Guile,
 362 #   to find out where Guile's header files and libraries are
 363 #   installed.  It sets two variables, marked for substitution, as
 364 #   by AC_SUBST.
 365 #
 366 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 367 #             code that uses Guile header files.  This is almost
 368 #             always just a -I flag.
 369 #
 370 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 371 #             program against Guile.  This includes -lguile for
 372 #             the Guile library itself, any libraries that Guile
 373 #             itself requires (like -lqthreads), and so on.  It may
 374 #             also include a -L flag to tell the compiler where to
 375 #             find the libraries.
 376
 377 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 378     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 379     if test -x $exe; then
 380         AC_MSG_CHECKING([guile compile flags])
 381         GUILE_CFLAGS="`$guile_config compile`"
 382         AC_MSG_RESULT($GUILE_CFLAGS)
 383         AC_MSG_CHECKING([guile link flags])
 384         GUILE_LDFLAGS="`$guile_config link`"
 385         AC_MSG_RESULT($GUILE_LDFLAGS)
 386     fi
 387     AC_SUBST(GUILE_CFLAGS)
 388     AC_SUBST(GUILE_LDFLAGS)
 389 ])
 390
 391
 392 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 393     ## First, let's just see if we can find Guile at all.
 394     AC_MSG_CHECKING([for guile-config])
 395     for guile_config in guile-config $target-guile-config $build-guile-config; do
 396         AC_MSG_RESULT([$guile_config])
 397         if ! $guile_config --version > /dev/null 2>&1 ; then
 398             AC_MSG_WARN([cannot execute $guile_config])
 399             AC_MSG_CHECKING([if we are cross compiling])
 400             GUILE_CONFIG='echo no guile-config'
 401         else
 402             GUILE_CONFIG=$guile_config
 403             break
 404         fi
 405     done
 406     STEPMAKE_OPTIONAL_REQUIRED(GUILE_CONFIG, $guile_config, $1)
 407     if test $? -ne 0; then
 408         STEPMAKE_ADD_ENTRY($1, 'guile-config (guile-devel, guile-dev or libguile-dev package)')
 409     fi
 410
 411     STEPMAKE_CHECK_SEARCH_RESULT(GUILE_CONFIG)
 412     # urg.  should test functionality rather than version.
 413     if test $? -eq 0 -a -n "$2"; then
 414         STEPMAKE_CHECK_VERSION(GUILE_CONFIG, $1, $2)
 415     fi
 416
 417     AC_SUBST(GUILE_CONFIG)
 418
 419     guile_version="$ver"
 420     changequote(<<, >>)dnl
 421     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 422     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 423     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 424     changequote([, ])dnl
 425     STEPMAKE_GUILE_FLAGS
 426     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 427     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 428     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 429 ])
 430
 431
 432 AC_DEFUN(STEPMAKE_GXX, [
 433     if test "$GXX" = "yes"; then
 434         STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 435     else
 436         warn="$CXX (Please install *GNU* c++)"
 437         STEPMAKE_ADD_ENTRY($1, $warn)
 438     fi
 439 ])
 440
 441
 442 AC_DEFUN(STEPMAKE_INIT, [
 443
 444     AC_PREREQ(2.50)
 445     . $srcdir/VERSION
 446     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 447     if test x$MY_PATCH_LEVEL != x; then
 448         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 449     fi
 450
 451     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 452     changequote(<<, >>)dnl
 453     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 454     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 455     changequote([, ])dnl
 456
 457     # No versioning on directory names of sub-packages
 458     # urg, urg
 459     stepmake=${datadir}/stepmake
 460     presome=${prefix}
 461     if test "$prefix" = "NONE"; then
 462             presome=${ac_default_prefix}
 463     fi
 464     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 465
 466     # urg, how is this supposed to work?
 467     if test "$program_prefix" = "NONE"; then
 468           program_prefix=
 469     fi
 470     if test "$program_suffix" = "NONE"; then
 471           program_suffix=
 472     fi
 473
 474     AC_MSG_CHECKING(Package)
 475     if test "$PACKAGE" = "STEPMAKE"; then
 476         AC_MSG_RESULT(Stepmake package!)
 477
 478         AC_MSG_CHECKING(builddir)
 479
 480         ugh_ugh_autoconf250_builddir="`pwd`"
 481
 482         if test "$srcdir" = "."; then
 483             srcdir_build=yes
 484         else
 485             srcdir_build=no
 486             package_builddir="`dirname $ugh_ugh_autoconf250_builddir`"
 487             package_srcdir="`dirname  $srcdir`"
 488         fi
 489         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 490
 491         (cd stepmake 2>/dev/null || mkdir stepmake)
 492         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 493 # only possible with autoconf < 2.50 -- hardcoded in configure.in
 494 #       AC_CONFIG_AUX_DIR(bin)
 495         stepmake=stepmake
 496     else
 497         AC_MSG_RESULT($PACKAGE)
 498
 499         AC_MSG_CHECKING(builddir)
 500         ugh_ugh_autoconf250_builddir="`pwd`"
 501         if test "$srcdir" = "."; then
 502             srcdir_build=yes
 503         else
 504             srcdir_build=no
 505         fi
 506         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 507
 508         AC_MSG_CHECKING(for stepmake)
 509         # Check for installed stepmake
 510         if test -d $stepmake; then
 511             AC_MSG_RESULT($stepmake)
 512         else
 513             stepmake="`cd $srcdir/stepmake; pwd`"
 514             AC_MSG_RESULT([$srcdir/stepmake  ($datadir/stepmake not found)])
 515         fi
 516
 517 # only possible with autoconf < 2.50 -- hardcoded in configure.in
 518 #       AC_CONFIG_AUX_DIR(\
 519 #         stepmake/bin\
 520 #         $srcdir/stepmake/bin\
 521 #       )
 522     fi
 523
 524     AC_SUBST(ugh_ugh_autoconf250_builddir)
 525     AC_SUBST(stepmake)
 526     AC_SUBST(package)
 527     AC_SUBST(PACKAGE)
 528     AC_SUBST(PACKAGE_NAME)
 529     AC_DEFINE_UNQUOTED(PACKAGE, ["${PACKAGE_NAME}"])
 530     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, ["${FULL_VERSION}"])
 531
 532     if test -z "$package_depth"; then
 533         package_depth="."
 534     else
 535         package_depth="../$package_depth"
 536     fi
 537     export package_depth
 538     AC_SUBST(package_depth)
 539
 540     AUTOGENERATE="This file was automatically generated by configure"
 541     AC_SUBST(AUTOGENERATE)
 542
 543     CONFIGSUFFIX=
 544     AC_ARG_ENABLE(config,
 545     [  --enable-config=CONF    put settings in config-CONF.make and config-CONF.h;
 546                             do \`make conf=CONF' to get output in ./out-CONF],
 547     [CONFIGURATION=$enableval])
 548
 549     ##'
 550
 551     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 552     CONFIGFILE=config$CONFIGSUFFIX
 553     AC_SUBST(CONFIGSUFFIX)
 554
 555     AC_CANONICAL_HOST
 556     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 557     STEPMAKE_PROGS(FIND, find, REQUIRED)
 558
 559     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 560
 561     if test "$(echo 2)" != "2" ||
 562         test "x`uname`" = "xHP-UX"; then
 563         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 564         AC_PATH_PROG(BASH, bash, $KSH)
 565         STEPMAKE_WARN(avoiding buggy /bin/sh)
 566         AC_PATH_PROG(SHELL, bash, $KSH)
 567     else
 568         SHELL=/bin/sh
 569         AC_PATH_PROG(BASH, bash, $SHELL)
 570     fi
 571     AC_SUBST(SHELL)
 572
 573     STEPMAKE_PATH_PROG(PYTHON, python, REQUIRED)
 574
 575     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 576         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 577         if test "$?" = 1; then
 578             warn='make (Please install *GNU* make)'
 579             # STEPMAKE_WARN($warn)
 580             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 581         fi
 582     fi
 583
 584     if test "$OSTYPE" = "cygwin" -o "$OSTYPE" = "cygwin32" -o "$OSTYPE" = "Windows_NT"; then
 585         LN=cp # hard link does not work under cygnus-nt
 586         LN_S='cp -r' # symbolic link does not work for native nt
 587         ZIP="zip -r -9" #
 588         program_suffix=.exe
 589         ROOTSEP=':'
 590         DIRSEP='/'
 591         PATHSEP=':'
 592         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
 593     else
 594         ROOTSEP=':'
 595         DIRSEP='/'
 596         PATHSEP=':'
 597         LN=ln
 598         LN_S='ln -s'
 599         ZIP="zip -r -9"
 600         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-sh -c"
 601     fi
 602     AC_SUBST(program_prefix)
 603     AC_SUBST(program_suffix)
 604     AC_SUBST(ZIP)
 605     AC_SUBST(LN)
 606     AC_SUBST(LN_S)
 607     AC_SUBST(INSTALL)
 608     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
 609     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
 610     AC_SUBST(DIRSEP)
 611     AC_SUBST(PATHSEP)
 612     AC_SUBST(ROOTSEP)
 613
 614     STEPMAKE_DATADIR
 615 ])
 616
 617
 618 AC_DEFUN(STEPMAKE_KPATHSEA, [
 619
 620     AC_ARG_WITH(kpathsea-include,
 621         [  --with-kpathsea-include=DIR
 622                           location of the kpathsea include dir],[
 623             if test "$withval" = "yes" -o "$withval" = "no"; then
 624                 AC_MSG_WARN(Usage: --with-kpathsea-include=includedir)
 625             else
 626                 CPPFLAGS="$CPPFLAGS -I${withval}"
 627             fi
 628             ])
 629
 630     AC_ARG_WITH(kpathsea-lib,
 631         [  --with-kpathsea-lib=DIR location of the kpathsea lib dir],[
 632             if test "$withval" = "yes" -o "$withval" = "no"; then
 633                 AC_MSG_WARN(Usage: --with-kpathsea-lib=libdir)
 634             else
 635                 LDFLAGS="$LDFLAGS -L${withval}"
 636             fi
 637             ])
 638
 639     kpathsea_b=yes
 640     #FIXME --with-xxx is meant for specifying a PATH too,
 641     # so this should read: --enable-kpathsea,
 642     # or --with-kpathsea-include=PATH --with-kpathsea-lib=PATH
 643     AC_ARG_WITH(kpathsea,
 644     [  --with-kpathsea         use kpathsea lib.  Default: on],
 645     [kpathsea_b=$with_kpathsea])
 646
 647     if test "$kpathsea_b" != "no"; then
 648         AC_CHECK_HEADERS([kpathsea/kpathsea.h])
 649         AC_CHECK_LIB(kpathsea, kpse_find_file)
 650         AC_CHECK_FUNCS(kpse_find_file,,kpathsea_b=no)
 651         if test "$kpathsea_b" = "no"; then
 652             warn='kpathsea (libkpathsea-dev or kpathsea-devel package)
 653    Else, please specify the location of your kpathsea using
 654    --with-kpathea-include and --with-kpathsea-lib options.  You should
 655    install kpathsea; see INSTALL.txt.  Rerun ./configure
 656    --without-kpathsea only if kpathsea is not available for your
 657    platform.'
 658             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 659         fi
 660     fi
 661     AC_MSG_CHECKING(whether to use kpathsea)
 662     if test "$kpathsea_b" != no; then
 663         AC_MSG_RESULT(yes)
 664         KPATHSEA=1
 665     else
 666         AC_MSG_RESULT(no)
 667         KPATHSEA=0
 668     fi
 669
 670     AC_SUBST(KPATHSEA)
 671     AC_DEFINE_UNQUOTED(KPATHSEA, $KPATHSEA)
 672 ])
 673
 674
 675 AC_DEFUN(STEPMAKE_LIB, [
 676     STEPMAKE_PROGS(AR, ar, $1)
 677     AC_PROG_RANLIB
 678     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 679 ])
 680
 681
 682 AC_DEFUN(STEPMAKE_LIBTOOL, [
 683     # libtool.info ...
 684     # **Never** try to set library version numbers so that they correspond
 685     # to the release number of your package.  This is an abuse that only
 686     # fosters misunderstanding of the purpose of library versions.
 687
 688     REVISION=$PATCH_LEVEL
 689     # CURRENT=$MINOR_VERSION
 690     CURRENT=`expr $MINOR_VERSION + 1`
 691     # AGE=`expr $MAJOR_VERSION + 1`
 692     AGE=$MAJOR_VERSION
 693     AC_SUBST(CURRENT)
 694     AC_SUBST(REVISION)
 695     AC_SUBST(AGE)
 696 ])
 697
 698
 699 AC_DEFUN(STEPMAKE_LOCALE, [
 700     lang=English
 701     ALL_LINGUAS="en nl"
 702
 703     # with/enable ??
 704     AC_ARG_WITH(localedir,
 705     [  --with-localedir=LOCALE use LOCALE as locale dir.  Default:
 706                             PREFIX/share/locale ],
 707     localedir=$with_localedir,
 708     localedir='${prefix}/share/locale')
 709
 710     AC_ARG_WITH(lang,
 711     [  --with-lang=LANG        use LANG as language to emit messages],
 712     language=$with_lang,
 713     language=English)
 714
 715     AC_MSG_CHECKING(language)
 716     case "$language" in
 717       En* | en* | Am* | am* | US* | us*)
 718             lang=English;;
 719       NL | nl | Du* | du* | Ned* | ned*)
 720             lang=Dutch;;
 721       "")
 722             lang=English;;
 723       *)
 724             lang=unknown;;
 725     esac
 726     AC_MSG_RESULT($lang)
 727
 728     if test "$lang" = "unknown" ; then
 729         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 730     fi
 731
 732 ])
 733
 734
 735 AC_DEFUN(STEPMAKE_MAKEINFO, [
 736     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 737     if test "$MAKEINFO" = "makeinfo"; then
 738         AC_MSG_CHECKING(whether makeinfo can split html by @node)
 739         mkdir -p out
 740         makeinfo --html --output=out/split <<EOF
 741 \input texinfo
 742 \input texinfo @c -*-texinfo-*-
 743 @setfilename split.info
 744 @settitle split.info
 745 @bye
 746 EOF
 747         if test -d out/split; then
 748             SPLITTING_MAKEINFO=yes
 749             AC_MSG_RESULT(yes)
 750             rm -rf out/split
 751         else
 752             AC_MSG_RESULT(no)
 753             STEPMAKE_WARN(your html documentation will be one large file)
 754             rm -rf out/split
 755         fi
 756     fi
 757     AC_SUBST(SPLITTING_MAKEINFO)
 758 ])
 759
 760
 761
 762 AC_DEFUN(STEPMAKE_MAN, [
 763     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 764     AC_SUBST(GROFF)
 765     STEPMAKE_PROGS(TROFF, troff, $1)
 766     AC_SUBST(TROFF)
 767     STEPMAKE_PROGS(TBL, tbl, $1)
 768     AC_SUBST(TBL)
 769 ])
 770
 771
 772 AC_DEFUN(STEPMAKE_MSGFMT, [
 773     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
 774 ])
 775
 776
 777 # Check for program ($2), set full path result to ($1).
 778 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 779 AC_DEFUN(STEPMAKE_PATH_PROG, [
 780     AC_CHECK_PROGS($1, $2, no)
 781     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 782     if test $? -eq 0; then
 783         AC_PATH_PROG($1, $2)
 784         if test -n "$4"; then
 785             STEPMAKE_CHECK_VERSION($1, $3, $4)
 786         fi
 787     fi
 788 ])
 789
 790
 791 # Check for program in set of names ($2), set result to ($1) .
 792 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 793 # If exists, and a minimal version ($4) is required
 794 AC_DEFUN(STEPMAKE_PROGS, [
 795     AC_CHECK_PROGS($1, $2, no)
 796     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 797     if test $? -eq 0 -a -n "$4"; then
 798         STEPMAKE_CHECK_VERSION($1, $3, $4)
 799     fi
 800 ])
 801
 802
 803 AC_DEFUN(STEPMAKE_PERL, [
 804     STEPMAKE_PATH_PROG(PERL, perl, $1)
 805 ])
 806
 807
 808 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
 809     AC_CHECK_HEADERS([python2.2/Python.h python2.1/Python.h python2.0/Python.h python2/Python.h python/Python.h python1.5/Python.h Python.h],[PYTHON_HEADER=yes])
 810     if test -z "$PYTHON_HEADER"; then
 811         warn='python.h (python-devel, python-dev or libpython-dev package)'
 812         STEPMAKE_ADD_ENTRY($1, $warn)
 813     fi
 814 ])
 815
 816
 817 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
 818     AC_ARG_ENABLE(tfm-path,
 819     [  --enable-tfm-path=PATH  set path of tex directories where tfm files live,
 820                             esp.: cmr10.tfm.  Default: use kpsewhich],
 821     [tfm_path=$enableval],
 822     [tfm_path=auto] )
 823
 824     # ugh
 825     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, OPTIONAL)
 826     AC_MSG_CHECKING(for tfm path)
 827
 828     TFM_FONTS="cmr msam"
 829
 830     if test "x$tfm_path" = xauto ; then
 831         if test "x$KPSEWHICH" != "xno" ; then
 832             for i in $TFM_FONTS; do
 833                 dir=`$KPSEWHICH tfm ${i}10.tfm`
 834                 TFM_PATH="$TFM_PATH `dirname $dir`"
 835             done
 836         else
 837             STEPMAKE_WARN(Please specify where cmr10.tfm lives:
 838     ./configure --enable-tfm-path=/usr/local/TeX/lib/tex/fonts)
 839         fi
 840     else
 841          TFM_PATH=$tfm_path
 842     fi
 843
 844     TFM_PATH=`echo $TFM_PATH | tr ':' ' '`
 845     AC_MSG_RESULT($TFM_PATH)
 846     AC_SUBST(TFM_PATH)
 847 ])
 848
 849
 850 AC_DEFUN(STEPMAKE_TEXMF, [
 851     # urg, never know what names these teTeX guys will think up
 852
 853     STEPMAKE_PROGS(METAFONT, mf mfont, $1)
 854     STEPMAKE_PROGS(INIMETAFONT, inimf inimfont, $1)
 855
 856     AC_MSG_CHECKING(for working metafont mode)
 857     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
 858     for MFMODE in $modelist; do
 859         $METAFONT "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
 860         if test -f mfput.tfm; then
 861             break;
 862         fi
 863     done
 864     AC_MSG_RESULT($MFMODE)
 865
 866     rm -f mfput.*
 867
 868     AC_SUBST(MFMODE)
 869 ])
 870
 871
 872 AC_DEFUN(STEPMAKE_WARN, [
 873     AC_MSG_WARN($1)
 874     warn_b=yes
 875 ])
 876
 877