aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl WARNING WARNING WARNING
   3 dnl do not edit! this is aclocal.m4, generated from /home/rz/lilypond/lilypond/stepmake/aclocal.m4
   4 dnl aclocal.m4   -*-shell-script-*-
   5 dnl StepMake subroutines for configure.in
   6
   7
   8 ### mostly interal macros
   9
  10 # Get full path of executable ($1)
  11 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
  12     ## which doesn't work in ash, if /usr/bin/which isn't installed
  13     ## type -p doesn't work in ash
  14     ## command -v doesn't work in zsh
  15     ## command -v "$1" 2>&1
  16     ## this test should work in ash, bash, pdksh (ksh), zsh
  17     type -p "$1" 2>/dev/null | tail -1 | awk '{print $NF}'
  18 ])
  19
  20
  21 # Get version string from executable ($1)
  22 AC_DEFUN(STEPMAKE_GET_VERSION, [
  23     ## "$1" --version 2>&1 | grep -v '^$' | head -1 | awk '{print $NF}'
  24     ##
  25     ## ARG.
  26     ## Workaround for broken Debian gcc version string:
  27     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  28     ##
  29     ## Assume, and hunt for, dotted version multiplet.
  30     changequote(<<, >>)dnl
  31     "$1" --version 2>&1 | grep '[0-9]\.[0-9]' | head -1 | \
  32         sed -e 's/.*[^-.0-9]\([0-9][0-9]*\.[0-9][.0-9]*\).*/\1/'
  33     changequote([, ])dnl
  34 ])
  35
  36 # Calculate simplistic numeric version from version string ($1)
  37 # As yet, we have no need for something more elaborate.
  38 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  39     echo "$1" | awk -F. '
  40     {
  41       if ([$]3) {three = [$]3}
  42       else {three = 0}
  43     }
  44     {printf "%d\n", [$]1*1000000 + [$]2*1000 + three}'
  45 ])
  46
  47
  48 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  49 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  50     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  51 ])
  52
  53 # Check if tested program ($2) was found ($1).
  54 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  55 # We could abort here if a 'REQUIRED' program is not found
  56 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  57     STEPMAKE_CHECK_SEARCH_RESULT($1)
  58     if test $? -ne 0; then
  59         STEPMAKE_ADD_ENTRY($3, $2)
  60         if test "$3" = "REQUIRED"; then
  61             command="echo ERROR: $2 not found"
  62             # abort configure process here?
  63         else
  64             command="- echo $2 not found"
  65         fi
  66         eval "$1"='$command'
  67         false
  68     else
  69         true
  70     fi
  71 ])
  72
  73
  74 # Return if tested proram ($1) was found (true) or not (false).
  75 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  76     r="`eval echo '$'"$1"`"
  77     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  78         true
  79     else
  80         ##STEPMAKE_WARN(cannot find $2. $3)
  81         false
  82     fi
  83 ])
  84
  85
  86 # Check version of program ($1)
  87 # If version is smaller than requested ($3),
  88 # add entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
  89 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
  90     r="`eval echo '$'"$1"`"
  91     AC_MSG_CHECKING([$r version])
  92     exe=`STEPMAKE_GET_EXECUTABLE($r)`
  93     ver=`STEPMAKE_GET_VERSION($exe)`
  94     num=`STEPMAKE_NUMERIC_VERSION($ver)`
  95     req=`STEPMAKE_NUMERIC_VERSION($3)`
  96     AC_MSG_RESULT([$ver])
  97     if test "$num" -lt "$req"; then
  98         STEPMAKE_ADD_ENTRY($2, ["$r $3 (installed: $ver)"])
  99     fi
 100 ])
 101
 102 ### Macros to build configure.in
 103
 104
 105 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 106     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 107     if test "$BIBTEX2HTML" = "bib2html"; then
 108         BIBTEX2HTML_FLAGS='$< $(@)'
 109     else
 110         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 111     fi
 112     AC_SUBST(BIBTEX2HTML)
 113     AC_SUBST(BIBTEX2HTML_FLAGS)
 114 ])
 115
 116
 117 AC_DEFUN(STEPMAKE_BISON, [
 118     # ugh, automake: we want (and check for) bison
 119     AC_PROG_YACC
 120
 121     STEPMAKE_PROGS(BISON, bison, $1)
 122
 123     # urg.  should test functionality rather than version.
 124     if test "$BISON" = "bison" -a -n "$2"; then
 125         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 126     fi
 127 ])
 128
 129
 130 AC_DEFUN(STEPMAKE_COMPILE, [
 131     # -O is necessary to get inlining
 132     CFLAGS=${CFLAGS-""}
 133     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 134     LDFLAGS=${LDFLAGS-""}
 135     checking_b=yes
 136     optimise_b=yes
 137     profile_b=no
 138     debug_b=yes
 139
 140     AC_ARG_ENABLE(checking,
 141     [  --enable-checking       set runtime checks (assert calls).  Default: on],
 142     [checking_b=$enableval] )
 143
 144     AC_ARG_ENABLE(debugging,
 145     [  --enable-debugging      compile with debugging info.  Default: on],
 146     [debug_b=$enableval])
 147
 148     AC_ARG_ENABLE(optimising,
 149     [  --enable-optimising     compile with optimising.  Default: on],
 150     [optimise_b=$enableval])
 151
 152     AC_ARG_ENABLE(profiling,
 153     [  --enable-profiling      compile with gprof support.  Default: off],
 154     [profile_b=$enableval])
 155
 156
 157     if test "$checking_b" = no; then
 158         # ugh
 159         AC_DEFINE(NDEBUG)
 160         DEFINES="$DEFINES -DNDEBUG"
 161     fi
 162
 163     if test "$optimise_b" = yes; then
 164         OPTIMIZE="-O2 -finline-functions"
 165     fi
 166
 167
 168     if test $profile_b = yes; then
 169         EXTRA_LIBES="-pg"
 170         OPTIMIZE="$OPTIMIZE -pg"
 171     fi
 172
 173     if test $debug_b = yes; then
 174         OPTIMIZE="$OPTIMIZE -g"
 175     fi
 176
 177
 178     AC_PROG_CC
 179     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 180     LD='$(CC)'
 181     AC_SUBST(LD)
 182
 183     CFLAGS="$CFLAGS $OPTIMIZE"
 184     CPPFLAGS=${CPPFLAGS-""}
 185
 186     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 187     save_cflags="$CFLAGS"
 188     case "$host" in
 189         alpha*-*-*)
 190             dnl should do compile test?
 191             AC_MSG_RESULT(-mieee)
 192             CFLAGS="-mieee $CFLAGS"
 193             ;;
 194         *)
 195             AC_MSG_RESULT([none])
 196             ;;
 197     esac
 198     AC_SUBST(cross_compiling)
 199     AC_SUBST(CFLAGS)
 200     AC_SUBST(CPPFLAGS)
 201     AC_SUBST(LDFLAGS)
 202     AC_SUBST(ICFLAGS)
 203     AC_SUBST(ILDFLAGS)
 204     AC_SUBST(DEFINES)
 205     AC_SUBST(EXTRA_LIBES)
 206 ])
 207
 208 AC_DEFUN(STEPMAKE_CXX, [
 209     AC_LANG([C++])
 210     AC_PROG_CXX
 211     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 212
 213     CPPFLAGS="$CPPFLAGS $DEFINES"
 214     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 215     LDFLAGS="$LDFLAGS $EXTRA_LIBES"
 216
 217     AC_SUBST(CXXFLAGS)
 218     AC_SUBST(CXX)
 219     LD='$(CXX)'
 220     AC_SUBST(LD)
 221 ])
 222
 223
 224 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 225     AC_CACHE_CHECK([whether explicit instantiation is needed],
 226         lily_cv_need_explicit_instantiation,
 227         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 228     template <class T> struct foo { static int baz; };
 229     template <class T> int foo<T>::baz = 1;
 230     ]], [[ return foo<int>::baz; ]])],[lily_cv_need_explicit_instantiation=no],[lily_cv_need_explicit_instantiation=yes]))
 231     if test x"$lily_cv_need_explicit_instantiation"x = x"yes"x; then
 232         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 233     fi
 234 ])
 235
 236
 237 AC_DEFUN(STEPMAKE_DATADIR, [
 238     if test "$datadir" = "\${prefix}/share"; then
 239             datadir='${prefix}/share'
 240     fi
 241     presome=${prefix}
 242     if test "$prefix" = "NONE"; then
 243         presome=${ac_default_prefix}
 244     fi
 245
 246     package_datadir=$datadir/$package
 247     local_package_datadir=$package_datadir/$FULL_VERSION
 248     build_package_datadir=$ugh_ugh_autoconf250_builddir/share/$package
 249
 250     DATADIR=`echo ${datadir} | sed "s!\\\${prefix}!$presome!"`
 251     PACKAGE_DATADIR=`echo ${package_datadir} | sed "s!\\\${prefix}!$presome!"`
 252     LOCAL_PACKAGE_DATADIR=`echo ${local_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 253     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 254
 255     AC_SUBST(datadir)
 256     AC_SUBST(package_datadir)
 257     AC_SUBST(local_package_datadir)
 258     AC_SUBST(build_package_datadir)
 259     AC_DEFINE_UNQUOTED(DATADIR, ["${DATADIR}"])
 260     AC_DEFINE_UNQUOTED(PACKAGE_DATADIR, ["${PACKAGE_DATADIR}"])
 261     AC_DEFINE_UNQUOTED(LOCAL_PACKAGE_DATADIR, ["${LOCAL_PACKAGE_DATADIR}"])
 262     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, ["${BUILD_PACKAGE_DATADIR}"])
 263 ])
 264
 265 ## ugh: cut & paste programming from datadir.
 266 AC_DEFUN(STEPMAKE_LIBDIR, [
 267     if test "$datadir" = "\${prefix}/lib"; then
 268             datadir='${prefix}/lib'
 269     fi
 270     presome=${prefix}
 271     if test "$prefix" = "NONE"; then
 272         presome=${ac_default_prefix}
 273     fi
 274
 275     package_libdir=$libdir/$package
 276
 277     local_package_libdir=$package_libdir/$FULL_VERSION
 278     build_package_libdir=$ugh_ugh_autoconf250_builddir/lib/$package
 279
 280     DATADIR=`echo ${libdir} | sed "s!\\\${prefix}!$presome!"`
 281     PACKAGE_LIBDIR=`echo ${package_libdir} | sed "s!\\\${prefix}!$presome!"`
 282     LOCAL_PACKAGE_LIBDIR=`echo ${local_package_libdir} | sed "s!\\\${prefix}!$presome!"`
 283     BUILD_PACKAGE_LIBDIR=`echo ${build_package_libdir} | sed "s!\\\${prefix}!$presome!"`
 284
 285     AC_SUBST(libdir)
 286     AC_SUBST(package_libdir)
 287     AC_SUBST(local_package_libdir)
 288     AC_SUBST(build_package_libdir)
 289     AC_DEFINE_UNQUOTED(LIBDIR, ["${LIBDIR}"])
 290     AC_DEFINE_UNQUOTED(PACKAGE_LIBDIR, ["${PACKAGE_LIBDIR}"])
 291     AC_DEFINE_UNQUOTED(LOCAL_PACKAGE_LIBDIR, ["${LOCAL_PACKAGE_LIBDIR}"])
 292     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_LIBDIR, ["${BUILD_PACKAGE_LIBDIR}"])
 293 ])
 294
 295
 296 AC_DEFUN(STEPMAKE_END, [
 297     AC_SUBST(OPTIONAL)
 298     AC_SUBST(REQUIRED)
 299
 300     AC_CONFIG_FILES([$CONFIGFILE.make:config.make.in])
 301 AC_OUTPUT
 302
 303
 304     if test -n "$OPTIONAL"; then
 305         echo
 306         echo "WARNING: Please consider installing optional programs: $OPTIONAL"
 307     fi
 308
 309     if test -n "$REQUIRED"; then
 310         echo
 311         echo "ERROR: Please install required programs: $REQUIRED"
 312     fi
 313
 314     if test -n "$OPTIONAL$REQUIRED"; then
 315         echo
 316         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 317         echo "Remove config.cache before rerunning ./configure"
 318     fi
 319
 320     if test -n "$REQUIRED"; then
 321         rm -f $srcdir/GNUmakefile
 322         exit 1
 323     fi
 324
 325     # regular in-place build
 326     # test for srcdir_build = yes ?
 327     if test "$srcdir_build" = "yes"; then
 328         rm -f $srcdir/GNUmakefile
 329         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 330         chmod 444 $srcdir/GNUmakefile
 331     else # --srcdir build
 332         rm -f GNUmakefile
 333         cp $srcdir/make/srcdir.make.in GNUmakefile
 334         chmod 444 GNUmakefile
 335     fi
 336 ])
 337
 338
 339 AC_DEFUN(STEPMAKE_FLEX, [
 340     # ugh, automake: we want (and check for) flex
 341     # AC_PROG_LEX
 342     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 343
 344     # AC_PROG_LEX()
 345     # ugh, ugh
 346     ac_cv_prog_lex_root=lex.yy
 347     STEPMAKE_PROGS(FLEX, flex, $1)
 348 ])
 349
 350
 351 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 352     AC_CHECK_HEADERS([FlexLexer.h],[true],[false])
 353     if test $? -ne 0; then
 354         warn='FlexLexer.h (flex package)'
 355         STEPMAKE_ADD_ENTRY($1, $warn)
 356     fi
 357 ])
 358
 359
 360 AC_DEFUN(STEPMAKE_GCC, [
 361     if test "$GCC" = "yes"; then
 362         STEPMAKE_CHECK_VERSION(CC, $1, $2)
 363     else
 364         warn="$CC (Please install *GNU* cc)"
 365         STEPMAKE_ADD_ENTRY($1, $warn)
 366     fi
 367 ])
 368
 369
 370 AC_DEFUN(STEPMAKE_GETTEXT, [
 371     presome=${prefix}
 372     if test "$prefix" = "NONE"; then
 373             presome=${ac_default_prefix}
 374     fi
 375     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 376
 377     AC_SUBST(localedir)
 378     AC_DEFINE_UNQUOTED(LOCALEDIR, ["${LOCALEDIR}"])
 379     AC_CHECK_LIB(intl, gettext)
 380     AC_CHECK_FUNCS(gettext)
 381 ])
 382
 383
 384 AC_DEFUN(STEPMAKE_GUILE, [
 385     STEPMAKE_PATH_PROG(GUILE, guile, $1)
 386 ])
 387
 388
 389 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 390 #
 391 #   This macro runs the guile-config script, installed with Guile,
 392 #   to find out where Guile's header files and libraries are
 393 #   installed.  It sets two variables, marked for substitution, as
 394 #   by AC_SUBST.
 395 #
 396 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 397 #             code that uses Guile header files.  This is almost
 398 #             always just a -I flag.
 399 #
 400 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 401 #             program against Guile.  This includes -lguile for
 402 #             the Guile library itself, any libraries that Guile
 403 #             itself requires (like -lqthreads), and so on.  It may
 404 #             also include a -L flag to tell the compiler where to
 405 #             find the libraries.
 406
 407 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 408     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 409     if test -x $exe; then
 410         AC_MSG_CHECKING([guile compile flags])
 411         GUILE_CFLAGS="`$guile_config compile`"
 412         AC_MSG_RESULT($GUILE_CFLAGS)
 413         AC_MSG_CHECKING([guile link flags])
 414         GUILE_LDFLAGS="`$guile_config link`"
 415         AC_MSG_RESULT($GUILE_LDFLAGS)
 416     fi
 417     AC_SUBST(GUILE_CFLAGS)
 418     AC_SUBST(GUILE_LDFLAGS)
 419 ])
 420
 421
 422 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 423     ## First, let's just see if we can find Guile at all.
 424     AC_MSG_CHECKING([for guile-config])
 425     for guile_config in guile-config $target-guile-config $build-guile-config; do
 426         AC_MSG_RESULT([$guile_config])
 427         if ! $guile_config --version > /dev/null 2>&1 ; then
 428             AC_MSG_WARN([cannot execute $guile_config])
 429             AC_MSG_CHECKING([if we are cross compiling])
 430             GUILE_CONFIG='echo no guile-config'
 431         else
 432             GUILE_CONFIG=$guile_config
 433             break
 434         fi
 435     done
 436     STEPMAKE_OPTIONAL_REQUIRED(GUILE_CONFIG, $guile_config, $1)
 437     if test $? -ne 0; then
 438         STEPMAKE_ADD_ENTRY($1, 'guile-config (guile-devel, guile-dev or libguile-dev package)')
 439     fi
 440
 441     STEPMAKE_CHECK_SEARCH_RESULT(GUILE_CONFIG)
 442     # urg.  should test functionality rather than version.
 443     if test $? -eq 0 -a -n "$2"; then
 444         STEPMAKE_CHECK_VERSION(GUILE_CONFIG, $1, $2)
 445     fi
 446
 447     AC_SUBST(GUILE_CONFIG)
 448
 449     guile_version="$ver"
 450     changequote(<<, >>)dnl
 451     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 452     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 453     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 454     changequote([, ])dnl
 455     STEPMAKE_GUILE_FLAGS
 456     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 457     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 458     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 459 ])
 460
 461
 462 AC_DEFUN(STEPMAKE_GXX, [
 463     if test "$GXX" = "yes"; then
 464         STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 465     else
 466         warn="$CXX (Please install *GNU* c++)"
 467         STEPMAKE_ADD_ENTRY($1, $warn)
 468     fi
 469 ])
 470
 471
 472 AC_DEFUN(STEPMAKE_INIT, [
 473
 474     AC_PREREQ(2.50)
 475     . $srcdir/VERSION
 476     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 477     if test x$MY_PATCH_LEVEL != x; then
 478         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 479     fi
 480
 481     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 482     changequote(<<, >>)dnl
 483     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 484     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 485     changequote([, ])dnl
 486
 487     # No versioning on directory names of sub-packages
 488     # urg, urg
 489     stepmake=${datadir}/stepmake
 490     presome=${prefix}
 491     if test "$prefix" = "NONE"; then
 492             presome=${ac_default_prefix}
 493     fi
 494     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 495
 496     # urg, how is this supposed to work?
 497     if test "$program_prefix" = "NONE"; then
 498           program_prefix=
 499     fi
 500     if test "$program_suffix" = "NONE"; then
 501           program_suffix=
 502     fi
 503
 504     AC_MSG_CHECKING(Package)
 505     if test "$PACKAGE" = "STEPMAKE"; then
 506         AC_MSG_RESULT(Stepmake package!)
 507
 508         AC_MSG_CHECKING(builddir)
 509
 510         ugh_ugh_autoconf250_builddir="`pwd`"
 511
 512         if test "$srcdir" = "."; then
 513             srcdir_build=yes
 514         else
 515             srcdir_build=no
 516             package_builddir="`dirname $ugh_ugh_autoconf250_builddir`"
 517             package_srcdir="`dirname  $srcdir`"
 518         fi
 519         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 520
 521         (cd stepmake 2>/dev/null || mkdir stepmake)
 522         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 523 # only possible with autoconf < 2.50 -- hardcoded in configure.in
 524 #       AC_CONFIG_AUX_DIR(bin)
 525         stepmake=stepmake
 526     else
 527         AC_MSG_RESULT($PACKAGE)
 528
 529         AC_MSG_CHECKING(builddir)
 530         ugh_ugh_autoconf250_builddir="`pwd`"
 531         if test "$srcdir" = "."; then
 532             srcdir_build=yes
 533         else
 534             srcdir_build=no
 535         fi
 536         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 537
 538         AC_MSG_CHECKING(for stepmake)
 539         # Check for installed stepmake
 540         if test -d $stepmake; then
 541             AC_MSG_RESULT($stepmake)
 542         else
 543             stepmake="`cd $srcdir/stepmake; pwd`"
 544             AC_MSG_RESULT([$srcdir/stepmake  ($datadir/stepmake not found)])
 545         fi
 546
 547 # only possible with autoconf < 2.50 -- hardcoded in configure.in
 548 #       AC_CONFIG_AUX_DIR(\
 549 #         stepmake/bin\
 550 #         $srcdir/stepmake/bin\
 551 #       )
 552     fi
 553
 554     AC_SUBST(ugh_ugh_autoconf250_builddir)
 555     AC_SUBST(stepmake)
 556     AC_SUBST(package)
 557     AC_SUBST(PACKAGE)
 558     AC_SUBST(PACKAGE_NAME)
 559     AC_DEFINE_UNQUOTED(PACKAGE, ["${PACKAGE_NAME}"])
 560     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, ["${FULL_VERSION}"])
 561
 562     if test -z "$package_depth"; then
 563         package_depth="."
 564     else
 565         package_depth="../$package_depth"
 566     fi
 567     export package_depth
 568     AC_SUBST(package_depth)
 569
 570     AUTOGENERATE="This file was automatically generated by configure"
 571     AC_SUBST(AUTOGENERATE)
 572
 573     CONFIGSUFFIX=
 574     AC_ARG_ENABLE(config,
 575     [  --enable-config=CONF    put settings in config-CONF.make and config-CONF.h;
 576                             do \`make conf=CONF' to get output in ./out-CONF],
 577     [CONFIGURATION=$enableval])
 578
 579     ##'
 580
 581     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 582     CONFIGFILE=config$CONFIGSUFFIX
 583     AC_SUBST(CONFIGSUFFIX)
 584
 585     AC_CANONICAL_HOST
 586     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 587     STEPMAKE_PROGS(FIND, find, REQUIRED)
 588
 589     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 590
 591     if test "$(echo 2)" != "2" ||
 592         test "x`uname`" = "xHP-UX"; then
 593         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 594         AC_PATH_PROG(BASH, bash, $KSH)
 595         STEPMAKE_WARN(avoiding buggy /bin/sh)
 596         AC_PATH_PROG(SHELL, bash, $KSH)
 597     else
 598         SHELL=/bin/sh
 599         AC_PATH_PROG(BASH, bash, $SHELL)
 600     fi
 601     AC_SUBST(SHELL)
 602
 603     STEPMAKE_PATH_PROG(PYTHON, python, REQUIRED)
 604
 605     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 606         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 607         if test "$?" = 1; then
 608             warn='make (Please install *GNU* make)'
 609             # STEPMAKE_WARN($warn)
 610             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 611         fi
 612     fi
 613
 614     if test "$OSTYPE" = "cygwin" -o "$OSTYPE" = "cygwin32" -o "$OSTYPE" = "Windows_NT"; then
 615         LN=cp # hard link does not work under cygnus-nt
 616         LN_S='cp -r' # symbolic link does not work for native nt
 617         ZIP="zip -r -9" #
 618         program_suffix=.exe
 619         ROOTSEP=':'
 620         DIRSEP='/'
 621         PATHSEP=':'
 622         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
 623     else
 624         ROOTSEP=':'
 625         DIRSEP='/'
 626         PATHSEP=':'
 627         LN=ln
 628         LN_S='ln -s'
 629         ZIP="zip -r -9"
 630         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-sh -c"
 631     fi
 632     AC_SUBST(program_prefix)
 633     AC_SUBST(program_suffix)
 634     AC_SUBST(ZIP)
 635     AC_SUBST(LN)
 636     AC_SUBST(LN_S)
 637     AC_SUBST(INSTALL)
 638     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
 639     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
 640     AC_SUBST(DIRSEP)
 641     AC_SUBST(PATHSEP)
 642     AC_SUBST(ROOTSEP)
 643
 644     STEPMAKE_DATADIR
 645     STEPMAKE_LIBDIR
 646 ])
 647
 648
 649 AC_DEFUN(STEPMAKE_KPATHSEA, [
 650
 651     AC_ARG_WITH(kpathsea-include,
 652         [  --with-kpathsea-include=DIR
 653                           location of the kpathsea include dir],[
 654             if test "$withval" = "yes" -o "$withval" = "no"; then
 655                 AC_MSG_WARN(Usage: --with-kpathsea-include=includedir)
 656             else
 657                 CPPFLAGS="$CPPFLAGS -I${withval}"
 658             fi
 659             ])
 660
 661     AC_ARG_WITH(kpathsea-lib,
 662         [  --with-kpathsea-lib=DIR location of the kpathsea lib dir],[
 663             if test "$withval" = "yes" -o "$withval" = "no"; then
 664                 AC_MSG_WARN(Usage: --with-kpathsea-lib=libdir)
 665             else
 666                 LDFLAGS="$LDFLAGS -L${withval}"
 667             fi
 668             ])
 669
 670     kpathsea_b=yes
 671     #FIXME --with-xxx is meant for specifying a PATH too,
 672     # so this should read: --enable-kpathsea,
 673     # or --with-kpathsea-include=PATH --with-kpathsea-lib=PATH
 674     AC_ARG_WITH(kpathsea,
 675     [  --with-kpathsea         use kpathsea lib.  Default: on],
 676     [kpathsea_b=$with_kpathsea])
 677
 678     if test "$kpathsea_b" != "no"; then
 679         AC_CHECK_HEADERS([kpathsea/kpathsea.h])
 680         AC_CHECK_LIB(kpathsea, kpse_find_file)
 681         AC_CHECK_FUNCS(kpse_find_file,,kpathsea_b=no)
 682         if test "$kpathsea_b" = "no"; then
 683             warn='kpathsea (libkpathsea-dev or kpathsea-devel package)
 684    Else, please specify the location of your kpathsea using
 685    --with-kpathea-include and --with-kpathsea-lib options.  You should
 686    install kpathsea; see INSTALL.txt.  Rerun ./configure
 687    --without-kpathsea only if kpathsea is not available for your
 688    platform.'
 689             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 690         fi
 691     fi
 692     AC_MSG_CHECKING(whether to use kpathsea)
 693     if test "$kpathsea_b" != no; then
 694         AC_MSG_RESULT(yes)
 695         KPATHSEA=1
 696     else
 697         AC_MSG_RESULT(no)
 698         KPATHSEA=0
 699     fi
 700
 701     AC_SUBST(KPATHSEA)
 702     AC_DEFINE_UNQUOTED(KPATHSEA, $KPATHSEA)
 703 ])
 704
 705
 706 AC_DEFUN(STEPMAKE_LIB, [
 707     STEPMAKE_PROGS(AR, ar, $1)
 708     AC_PROG_RANLIB
 709     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 710 ])
 711
 712
 713 AC_DEFUN(STEPMAKE_LIBTOOL, [
 714     # libtool.info ...
 715     # **Never** try to set library version numbers so that they correspond
 716     # to the release number of your package.  This is an abuse that only
 717     # fosters misunderstanding of the purpose of library versions.
 718
 719     REVISION=$PATCH_LEVEL
 720     # CURRENT=$MINOR_VERSION
 721     CURRENT=`expr $MINOR_VERSION + 1`
 722     # AGE=`expr $MAJOR_VERSION + 1`
 723     AGE=$MAJOR_VERSION
 724     AC_SUBST(CURRENT)
 725     AC_SUBST(REVISION)
 726     AC_SUBST(AGE)
 727 ])
 728
 729
 730 AC_DEFUN(STEPMAKE_LOCALE, [
 731     lang=English
 732     ALL_LINGUAS="en nl"
 733
 734     # with/enable ??
 735     AC_ARG_WITH(localedir,
 736     [  --with-localedir=LOCALE use LOCALE as locale dir.  Default:
 737                             PREFIX/share/locale ],
 738     localedir=$with_localedir,
 739     localedir='${prefix}/share/locale')
 740
 741     AC_ARG_WITH(lang,
 742     [  --with-lang=LANG        use LANG as language to emit messages],
 743     language=$with_lang,
 744     language=English)
 745
 746     AC_MSG_CHECKING(language)
 747     case "$language" in
 748       En* | en* | Am* | am* | US* | us*)
 749             lang=English;;
 750       NL | nl | Du* | du* | Ned* | ned*)
 751             lang=Dutch;;
 752       "")
 753             lang=English;;
 754       *)
 755             lang=unknown;;
 756     esac
 757     AC_MSG_RESULT($lang)
 758
 759     if test "$lang" = "unknown" ; then
 760         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 761     fi
 762
 763 ])
 764
 765
 766 AC_DEFUN(STEPMAKE_MAKEINFO, [
 767     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 768     if test "$MAKEINFO" = "makeinfo"; then
 769         AC_MSG_CHECKING(whether makeinfo can split html by @node)
 770         mkdir -p out
 771         makeinfo --html --output=out/split <<EOF
 772 \input texinfo
 773 \input texinfo @c -*-texinfo-*-
 774 @setfilename split.info
 775 @settitle split.info
 776 @bye
 777 EOF
 778         if test -d out/split; then
 779             SPLITTING_MAKEINFO=yes
 780             AC_MSG_RESULT(yes)
 781             rm -rf out/split
 782         else
 783             AC_MSG_RESULT(no)
 784             STEPMAKE_WARN(your html documentation will be one large file)
 785             rm -rf out/split
 786         fi
 787     fi
 788     AC_SUBST(SPLITTING_MAKEINFO)
 789 ])
 790
 791
 792
 793 AC_DEFUN(STEPMAKE_MAN, [
 794     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 795     AC_SUBST(GROFF)
 796     STEPMAKE_PROGS(TROFF, troff, $1)
 797     AC_SUBST(TROFF)
 798     STEPMAKE_PROGS(TBL, tbl, $1)
 799     AC_SUBST(TBL)
 800 ])
 801
 802
 803 AC_DEFUN(STEPMAKE_MSGFMT, [
 804     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
 805 ])
 806
 807
 808 # Check for program ($2), set full path result to ($1).
 809 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 810 AC_DEFUN(STEPMAKE_PATH_PROG, [
 811     AC_CHECK_PROGS($1, $2, no)
 812     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 813     if test $? -eq 0; then
 814         AC_PATH_PROG($1, $2)
 815         if test -n "$4"; then
 816             STEPMAKE_CHECK_VERSION($1, $3, $4)
 817         fi
 818     fi
 819 ])
 820
 821
 822 # Check for program in set of names ($2), set result to ($1) .
 823 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 824 # If exists, and a minimal version ($4) is required
 825 AC_DEFUN(STEPMAKE_PROGS, [
 826     AC_CHECK_PROGS($1, $2, no)
 827     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 828     if test $? -eq 0 -a -n "$4"; then
 829         STEPMAKE_CHECK_VERSION($1, $3, $4)
 830     fi
 831 ])
 832
 833
 834 AC_DEFUN(STEPMAKE_PERL, [
 835     STEPMAKE_PATH_PROG(PERL, perl, $1)
 836 ])
 837
 838
 839 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
 840     AC_CHECK_HEADERS([python2.2/Python.h python2.1/Python.h python2.0/Python.h python2/Python.h python/Python.h python1.5/Python.h Python.h],[PYTHON_HEADER=yes])
 841     if test -z "$PYTHON_HEADER"; then
 842         warn='python.h (python-devel, python-dev or libpython-dev package)'
 843         STEPMAKE_ADD_ENTRY($1, $warn)
 844     fi
 845 ])
 846
 847
 848 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
 849     AC_ARG_ENABLE(tfm-path,
 850     [  --enable-tfm-path=PATH  set path of tex directories where tfm files live,
 851                             esp.: cmr10.tfm.  Default: use kpsewhich],
 852     [tfm_path=$enableval],
 853     [tfm_path=auto] )
 854
 855     # ugh
 856     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, OPTIONAL)
 857     AC_MSG_CHECKING(for tfm path)
 858
 859     TFM_FONTS="cmr msam"
 860
 861     if test "x$tfm_path" = xauto ; then
 862         if test "x$KPSEWHICH" != "xno" ; then
 863             for i in $TFM_FONTS; do
 864                 dir=`$KPSEWHICH tfm ${i}10.tfm`
 865                 TFM_PATH="$TFM_PATH `dirname $dir`"
 866             done
 867         else
 868             STEPMAKE_WARN(Please specify where cmr10.tfm lives:
 869     ./configure --enable-tfm-path=/usr/local/TeX/lib/tex/fonts)
 870         fi
 871     else
 872          TFM_PATH=$tfm_path
 873     fi
 874
 875     TFM_PATH=`echo $TFM_PATH | tr ':' ' '`
 876     AC_MSG_RESULT($TFM_PATH)
 877     AC_SUBST(TFM_PATH)
 878 ])
 879
 880
 881 AC_DEFUN(STEPMAKE_TEXMF, [
 882     # urg, never know what names these teTeX guys will think up
 883
 884     STEPMAKE_PROGS(METAFONT, mf mfont, $1)
 885     STEPMAKE_PROGS(INIMETAFONT, inimf inimfont, $1)
 886
 887     AC_MSG_CHECKING(for working metafont mode)
 888     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
 889     for MFMODE in $modelist; do
 890         $METAFONT "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
 891         if test -f mfput.tfm; then
 892             break;
 893         fi
 894     done
 895     AC_MSG_RESULT($MFMODE)
 896
 897     rm -f mfput.*
 898
 899     AC_SUBST(MFMODE)
 900 ])
 901
 902
 903 AC_DEFUN(STEPMAKE_WARN, [
 904     AC_MSG_WARN($1)
 905     warn_b=yes
 906 ])
 907
 908