aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4
   5 ### mostly interal macros
   6
   7 # Get full path of executable ($1)
   8 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
   9     ## which doesn't work in ash, if /usr/bin/which isn't installed
  10     ## type -p doesn't work in ash
  11     ## command -v doesn't work in zsh
  12     ## command -v "$1" 2>&1
  13     ## this test should work in ash, bash, pdksh (ksh), zsh
  14     type -p "$1" 2>/dev/null | tail -1 | awk '{print $NF}'
  15 ])
  16
  17
  18 # Get version string from executable ($1)
  19 AC_DEFUN(STEPMAKE_GET_VERSION, [
  20     ## "$1" --version 2>&1 | grep -v '^$' | head -1 | awk '{print $NF}'
  21     ##
  22     ## ARG.
  23     ## Workaround for broken Debian gcc version string:
  24     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  25     ##
  26     ## Assume, and hunt for, dotted version multiplet.
  27     changequote(<<, >>)dnl
  28     "$1" --version 2>&1 | grep '[0-9]\.[0-9]' | head -1 | \
  29         sed -e 's/.*[^-.0-9]\([0-9][0-9]*\.[0-9][.0-9]*\).*/\1/'
  30     changequote([, ])dnl
  31 ])
  32
  33 # Calculate simplistic numeric version from version string ($1)
  34 # As yet, we have no need for something more elaborate.
  35 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  36     echo "$1" | awk -F. '
  37     {
  38       if ([$]3) {three = [$]3}
  39       else {three = 0}
  40     }
  41     {printf "%d\n", [$]1*1000000 + [$]2*1000 + three}'
  42 ])
  43
  44
  45 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  46 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  47     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  48 ])
  49
  50 # Check if tested program ($2) was found ($1).
  51 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  52 # We could abort here if a 'REQUIRED' program is not found
  53 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  54     STEPMAKE_CHECK_SEARCH_RESULT($1)
  55     if test $? -ne 0; then
  56         STEPMAKE_ADD_ENTRY($3, $2)
  57         if test "$3" = "REQUIRED"; then
  58             command="echo ERROR: $2 not found"
  59             # abort configure process here?
  60         else
  61             command="- echo $2 not found"
  62         fi
  63         eval "$1"='$command'
  64         false
  65     else
  66         true
  67     fi
  68 ])
  69
  70
  71 # Return if tested proram ($1) was found (true) or not (false).
  72 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  73     r="`eval echo '$'"$1"`"
  74     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  75         true
  76     else
  77         ##STEPMAKE_WARN(cannot find $2. $3)
  78         false
  79     fi
  80 ])
  81
  82
  83 # Check version of program ($1)
  84 # If version is smaller than requested ($3),
  85 # add entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
  86 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
  87     r="`eval echo '$'"$1"`"
  88     AC_MSG_CHECKING([$r version])
  89     exe=`STEPMAKE_GET_EXECUTABLE($r)`
  90     ver=`STEPMAKE_GET_VERSION($exe)`
  91     num=`STEPMAKE_NUMERIC_VERSION($ver)`
  92     req=`STEPMAKE_NUMERIC_VERSION($3)`
  93     AC_MSG_RESULT([$ver])
  94     if test "$num" -lt "$req"; then
  95         STEPMAKE_ADD_ENTRY($2, ["$r $3 (installed: $ver)"])
  96     fi
  97 ])
  98
  99 ### Macros to build configure.in
 100
 101
 102 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 103     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 104     if test "$BIBTEX2HTML" = "bib2html"; then
 105         BIBTEX2HTML_FLAGS='$< $(@)'
 106     else
 107         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 108     fi
 109     AC_SUBST(BIBTEX2HTML)
 110     AC_SUBST(BIBTEX2HTML_FLAGS)
 111 ])
 112
 113
 114 AC_DEFUN(STEPMAKE_BISON, [
 115     # ugh, automake: we want (and check for) bison
 116     AC_PROG_YACC
 117
 118     STEPMAKE_PROGS(BISON, bison, $1)
 119
 120     # urg.  should test functionality rather than version.
 121     if test "$BISON" = "bison" -a -n "$2"; then
 122         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 123     fi
 124 ])
 125
 126
 127 AC_DEFUN(STEPMAKE_COMPILE, [
 128     # -O is necessary to get inlining
 129     CFLAGS=${CFLAGS-""}
 130     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 131     LDFLAGS=${LDFLAGS-""}
 132     checking_b=yes
 133     optimise_b=yes
 134     profile_b=no
 135     debug_b=yes
 136
 137     AC_ARG_ENABLE(checking,
 138     [  --enable-checking       set runtime checks (assert calls).  Default: on],
 139     [checking_b=$enableval] )
 140
 141     AC_ARG_ENABLE(debugging,
 142     [  --enable-debugging      compile with debugging info.  Default: on],
 143     [debug_b=$enableval])
 144
 145     AC_ARG_ENABLE(optimising,
 146     [  --enable-optimising     compile with optimising.  Default: on],
 147     [optimise_b=$enableval])
 148
 149     AC_ARG_ENABLE(profiling,
 150     [  --enable-profiling      compile with gprof support.  Default: off],
 151     [profile_b=$enableval])
 152
 153
 154     if test "$checking_b" = no; then
 155         # ugh
 156         AC_DEFINE(NDEBUG)
 157         DEFINES="$DEFINES -DNDEBUG"
 158     fi
 159
 160     if test "$optimise_b" = yes; then
 161         OPTIMIZE="-O2 -finline-functions"
 162     fi
 163
 164
 165     if test $profile_b = yes; then
 166         EXTRA_LIBES="-pg"
 167         OPTIMIZE="$OPTIMIZE -pg"
 168     fi
 169
 170     if test $debug_b = yes; then
 171         OPTIMIZE="$OPTIMIZE -g"
 172     fi
 173
 174
 175     AC_PROG_CC
 176     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 177     LD='$(CC)'
 178     AC_SUBST(LD)
 179
 180     CFLAGS="$CFLAGS $OPTIMIZE"
 181     CPPFLAGS=${CPPFLAGS-""}
 182
 183     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 184     save_cflags="$CFLAGS"
 185     case "$host" in
 186         alpha*-*-*)
 187             dnl should do compile test?
 188             AC_MSG_RESULT(-mieee)
 189             CFLAGS="-mieee $CFLAGS"
 190             ;;
 191         *)
 192             AC_MSG_RESULT([none])
 193             ;;
 194     esac
 195     AC_SUBST(cross_compiling)
 196     AC_SUBST(CFLAGS)
 197     AC_SUBST(CPPFLAGS)
 198     AC_SUBST(LDFLAGS)
 199     AC_SUBST(ICFLAGS)
 200     AC_SUBST(ILDFLAGS)
 201     AC_SUBST(DEFINES)
 202     AC_SUBST(EXTRA_LIBES)
 203 ])
 204
 205 AC_DEFUN(STEPMAKE_CXX, [
 206     AC_LANG([C++])
 207     AC_PROG_CXX
 208     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 209
 210     CPPFLAGS="$CPPFLAGS $DEFINES"
 211     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 212     LDFLAGS="$LDFLAGS $EXTRA_LIBES"
 213
 214     AC_SUBST(CXXFLAGS)
 215     AC_SUBST(CXX)
 216     LD='$(CXX)'
 217     AC_SUBST(LD)
 218 ])
 219
 220
 221 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 222     AC_CACHE_CHECK([whether explicit instantiation is needed],
 223         lily_cv_need_explicit_instantiation,
 224         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 225     template <class T> struct foo { static int baz; };
 226     template <class T> int foo<T>::baz = 1;
 227     ]], [[ return foo<int>::baz; ]])],[lily_cv_need_explicit_instantiation=no],[lily_cv_need_explicit_instantiation=yes]))
 228     if test x"$lily_cv_need_explicit_instantiation"x = x"yes"x; then
 229         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 230     fi
 231 ])
 232
 233
 234 AC_DEFUN(STEPMAKE_DATADIR, [
 235     if test "$datadir" = "\${prefix}/share"; then
 236             datadir='${prefix}/share'
 237     fi
 238     presome=${prefix}
 239     if test "$prefix" = "NONE"; then
 240         presome=${ac_default_prefix}
 241     fi
 242
 243     package_datadir=$datadir/$package
 244     local_package_datadir=$package_datadir/$FULL_VERSION
 245     build_package_datadir=$ugh_ugh_autoconf250_builddir/share/$package
 246
 247     DATADIR=`echo ${datadir} | sed "s!\\\${prefix}!$presome!"`
 248     PACKAGE_DATADIR=`echo ${package_datadir} | sed "s!\\\${prefix}!$presome!"`
 249     LOCAL_PACKAGE_DATADIR=`echo ${local_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 250     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 251
 252     AC_SUBST(datadir)
 253     AC_SUBST(package_datadir)
 254     AC_SUBST(local_package_datadir)
 255     AC_SUBST(build_package_datadir)
 256     AC_DEFINE_UNQUOTED(DATADIR, ["${DATADIR}"])
 257     AC_DEFINE_UNQUOTED(PACKAGE_DATADIR, ["${PACKAGE_DATADIR}"])
 258     AC_DEFINE_UNQUOTED(LOCAL_PACKAGE_DATADIR, ["${LOCAL_PACKAGE_DATADIR}"])
 259     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, ["${BUILD_PACKAGE_DATADIR}"])
 260 ])
 261
 262
 263 AC_DEFUN(STEPMAKE_END, [
 264     AC_SUBST(OPTIONAL)
 265     AC_SUBST(REQUIRED)
 266
 267     AC_CONFIG_FILES([$CONFIGFILE.make:config.make.in])
 268 AC_OUTPUT
 269
 270
 271     if test -n "$OPTIONAL"; then
 272         echo
 273         echo "WARNING: Please consider installing optional programs: $OPTIONAL"
 274     fi
 275
 276     if test -n "$REQUIRED"; then
 277         echo
 278         echo "ERROR: Please install required programs: $REQUIRED"
 279     fi
 280
 281     if test -n "$OPTIONAL$REQUIRED"; then
 282         echo
 283         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 284         echo "Remove config.cache before rerunning ./configure"
 285     fi
 286
 287     if test -n "$REQUIRED"; then
 288         rm -f $srcdir/GNUmakefile
 289         exit 1
 290     fi
 291
 292     # regular in-place build
 293     # test for srcdir_build = yes ?
 294     if test "$srcdir_build" = "yes"; then
 295         rm -f $srcdir/GNUmakefile
 296         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 297         chmod 444 $srcdir/GNUmakefile
 298     else # --srcdir build
 299         rm -f GNUmakefile
 300         cp $srcdir/make/srcdir.make.in GNUmakefile
 301         chmod 444 GNUmakefile
 302     fi
 303 ])
 304
 305
 306 AC_DEFUN(STEPMAKE_FLEX, [
 307     # ugh, automake: we want (and check for) flex
 308     # AC_PROG_LEX
 309     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 310
 311     # AC_PROG_LEX()
 312     # ugh, ugh
 313     ac_cv_prog_lex_root=lex.yy
 314     STEPMAKE_PROGS(FLEX, flex, $1)
 315 ])
 316
 317
 318 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 319     AC_CHECK_HEADERS([FlexLexer.h],[true],[false])
 320     if test $? -ne 0; then
 321         warn='FlexLexer.h (flex package)'
 322         STEPMAKE_ADD_ENTRY($1, $warn)
 323     fi
 324 ])
 325
 326
 327 AC_DEFUN(STEPMAKE_GCC, [
 328     if test "$GCC" = "yes"; then
 329         STEPMAKE_CHECK_VERSION(CC, $1, $2)
 330     else
 331         warn="$CC (Please install *GNU* cc)"
 332         STEPMAKE_ADD_ENTRY($1, $warn)
 333     fi
 334 ])
 335
 336
 337 AC_DEFUN(STEPMAKE_GETTEXT, [
 338     presome=${prefix}
 339     if test "$prefix" = "NONE"; then
 340             presome=${ac_default_prefix}
 341     fi
 342     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 343
 344     AC_SUBST(localedir)
 345     AC_DEFINE_UNQUOTED(LOCALEDIR, ["${LOCALEDIR}"])
 346     AC_CHECK_LIB(intl, gettext)
 347     AC_CHECK_FUNCS(gettext)
 348 ])
 349
 350
 351 AC_DEFUN(STEPMAKE_GUILE, [
 352     STEPMAKE_PATH_PROG(GUILE, guile, $1)
 353 ])
 354
 355
 356 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 357 #
 358 #   This macro runs the guile-config script, installed with Guile,
 359 #   to find out where Guile's header files and libraries are
 360 #   installed.  It sets two variables, marked for substitution, as
 361 #   by AC_SUBST.
 362 #
 363 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 364 #             code that uses Guile header files.  This is almost
 365 #             always just a -I flag.
 366 #
 367 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 368 #             program against Guile.  This includes -lguile for
 369 #             the Guile library itself, any libraries that Guile
 370 #             itself requires (like -lqthreads), and so on.  It may
 371 #             also include a -L flag to tell the compiler where to
 372 #             find the libraries.
 373
 374 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 375     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 376     if test -x $exe; then
 377         AC_MSG_CHECKING([guile compile flags])
 378         GUILE_CFLAGS="`$guile_config compile`"
 379         AC_MSG_RESULT($GUILE_CFLAGS)
 380         AC_MSG_CHECKING([guile link flags])
 381         GUILE_LDFLAGS="`$guile_config link`"
 382         AC_MSG_RESULT($GUILE_LDFLAGS)
 383     fi
 384     AC_SUBST(GUILE_CFLAGS)
 385     AC_SUBST(GUILE_LDFLAGS)
 386 ])
 387
 388
 389 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 390     ## First, let's just see if we can find Guile at all.
 391     AC_MSG_CHECKING([for guile-config])
 392     for guile_config in guile-config $target-guile-config $build-guile-config; do
 393         AC_MSG_RESULT([$guile_config])
 394         if ! $guile_config --version > /dev/null 2>&1 ; then
 395             AC_MSG_WARN([cannot execute $guile_config])
 396             AC_MSG_CHECKING([if we are cross compiling])
 397             GUILE_CONFIG='echo no guile-config'
 398         else
 399             GUILE_CONFIG=$guile_config
 400             break
 401         fi
 402     done
 403     STEPMAKE_OPTIONAL_REQUIRED(GUILE_CONFIG, $guile_config, $1)
 404     if test $? -ne 0; then
 405         STEPMAKE_ADD_ENTRY($1, 'guile-config (guile-devel, guile-dev or libguile-dev package)')
 406     fi
 407
 408     STEPMAKE_CHECK_SEARCH_RESULT(GUILE_CONFIG)
 409     # urg.  should test functionality rather than version.
 410     if test $? -eq 0 -a -n "$2"; then
 411         STEPMAKE_CHECK_VERSION(GUILE_CONFIG, $1, $2)
 412     fi
 413
 414     AC_SUBST(GUILE_CONFIG)
 415
 416     guile_version="$ver"
 417     changequote(<<, >>)dnl
 418     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 419     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 420     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 421     changequote([, ])dnl
 422     STEPMAKE_GUILE_FLAGS
 423     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 424     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 425     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 426 ])
 427
 428
 429 AC_DEFUN(STEPMAKE_GXX, [
 430     if test "$GXX" = "yes"; then
 431         STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 432     else
 433         warn="$CXX (Please install *GNU* c++)"
 434         STEPMAKE_ADD_ENTRY($1, $warn)
 435     fi
 436 ])
 437
 438
 439 AC_DEFUN(STEPMAKE_INIT, [
 440
 441     AC_PREREQ(2.50)
 442     . $srcdir/VERSION
 443     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 444     if test x$MY_PATCH_LEVEL != x; then
 445         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 446     fi
 447
 448     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 449     changequote(<<, >>)dnl
 450     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 451     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 452     changequote([, ])dnl
 453
 454     # No versioning on directory names of sub-packages
 455     # urg, urg
 456     stepmake=${datadir}/stepmake
 457     presome=${prefix}
 458     if test "$prefix" = "NONE"; then
 459             presome=${ac_default_prefix}
 460     fi
 461     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 462
 463     # urg, how is this supposed to work?
 464     if test "$program_prefix" = "NONE"; then
 465           program_prefix=
 466     fi
 467     if test "$program_suffix" = "NONE"; then
 468           program_suffix=
 469     fi
 470
 471     AC_MSG_CHECKING(Package)
 472     if test "$PACKAGE" = "STEPMAKE"; then
 473         AC_MSG_RESULT(Stepmake package!)
 474
 475         AC_MSG_CHECKING(builddir)
 476
 477         ugh_ugh_autoconf250_builddir="`pwd`"
 478
 479         if test "$srcdir" = "."; then
 480             srcdir_build=yes
 481         else
 482             srcdir_build=no
 483             package_builddir="`dirname $ugh_ugh_autoconf250_builddir`"
 484             package_srcdir="`dirname  $srcdir`"
 485         fi
 486         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 487
 488         (cd stepmake 2>/dev/null || mkdir stepmake)
 489         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 490 # only possible with autoconf < 2.50 -- hardcoded in configure.in
 491 #       AC_CONFIG_AUX_DIR(bin)
 492         stepmake=stepmake
 493     else
 494         AC_MSG_RESULT($PACKAGE)
 495
 496         AC_MSG_CHECKING(builddir)
 497         ugh_ugh_autoconf250_builddir="`pwd`"
 498         if test "$srcdir" = "."; then
 499             srcdir_build=yes
 500         else
 501             srcdir_build=no
 502         fi
 503         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 504
 505         AC_MSG_CHECKING(for stepmake)
 506         # Check for installed stepmake
 507         if test -d $stepmake; then
 508             AC_MSG_RESULT($stepmake)
 509         else
 510             stepmake="`cd $srcdir/stepmake; pwd`"
 511             AC_MSG_RESULT([$srcdir/stepmake  ($datadir/stepmake not found)])
 512         fi
 513
 514 # only possible with autoconf < 2.50 -- hardcoded in configure.in
 515 #       AC_CONFIG_AUX_DIR(\
 516 #         stepmake/bin\
 517 #         $srcdir/stepmake/bin\
 518 #       )
 519     fi
 520
 521     AC_SUBST(ugh_ugh_autoconf250_builddir)
 522     AC_SUBST(stepmake)
 523     AC_SUBST(package)
 524     AC_SUBST(PACKAGE)
 525     AC_SUBST(PACKAGE_NAME)
 526     AC_DEFINE_UNQUOTED(PACKAGE, ["${PACKAGE_NAME}"])
 527     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, ["${FULL_VERSION}"])
 528
 529     if test -z "$package_depth"; then
 530         package_depth="."
 531     else
 532         package_depth="../$package_depth"
 533     fi
 534     export package_depth
 535     AC_SUBST(package_depth)
 536
 537     AUTOGENERATE="This file was automatically generated by configure"
 538     AC_SUBST(AUTOGENERATE)
 539
 540     CONFIGSUFFIX=
 541     AC_ARG_ENABLE(config,
 542     [  --enable-config=CONF    put settings in config-CONF.make and config-CONF.h;
 543                             do \`make conf=CONF' to get output in ./out-CONF],
 544     [CONFIGURATION=$enableval])
 545
 546     ##'
 547
 548     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 549     CONFIGFILE=config$CONFIGSUFFIX
 550     AC_SUBST(CONFIGSUFFIX)
 551
 552     AC_CANONICAL_HOST
 553     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 554     STEPMAKE_PROGS(FIND, find, REQUIRED)
 555
 556     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 557
 558     if test "$(echo 2)" != "2" ||
 559         test "x`uname`" = "xHP-UX"; then
 560         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 561         AC_PATH_PROG(BASH, bash, $KSH)
 562         STEPMAKE_WARN(avoiding buggy /bin/sh)
 563         AC_PATH_PROG(SHELL, bash, $KSH)
 564     else
 565         SHELL=/bin/sh
 566         AC_PATH_PROG(BASH, bash, $SHELL)
 567     fi
 568     AC_SUBST(SHELL)
 569
 570     STEPMAKE_PATH_PROG(PYTHON, python, REQUIRED)
 571
 572     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 573         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 574         if test "$?" = 1; then
 575             warn='make (Please install *GNU* make)'
 576             # STEPMAKE_WARN($warn)
 577             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 578         fi
 579     fi
 580
 581     if test "$OSTYPE" = "cygwin" -o "$OSTYPE" = "cygwin32" -o "$OSTYPE" = "Windows_NT"; then
 582         LN=cp # hard link does not work under cygnus-nt
 583         LN_S='cp -r' # symbolic link does not work for native nt
 584         ZIP="zip -r -9" #
 585         program_suffix=.exe
 586         ROOTSEP=':'
 587         DIRSEP='/'
 588         PATHSEP=':'
 589         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
 590     else
 591         ROOTSEP=':'
 592         DIRSEP='/'
 593         PATHSEP=':'
 594         LN=ln
 595         LN_S='ln -s'
 596         ZIP="zip -r -9"
 597         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-sh -c"
 598     fi
 599     AC_SUBST(program_prefix)
 600     AC_SUBST(program_suffix)
 601     AC_SUBST(ZIP)
 602     AC_SUBST(LN)
 603     AC_SUBST(LN_S)
 604     AC_SUBST(INSTALL)
 605     AC_DEFINE_UNQUOTED(DIRSEP, ["${DIRSEP}"])
 606     AC_DEFINE_UNQUOTED(PATHSEP, ["${PATHSEP}"])
 607     AC_SUBST(DIRSEP)
 608     AC_SUBST(PATHSEP)
 609     AC_SUBST(ROOTSEP)
 610
 611     STEPMAKE_DATADIR
 612 ])
 613
 614
 615 AC_DEFUN(STEPMAKE_KPATHSEA, [
 616
 617     AC_ARG_WITH(kpathsea-include,
 618         [  --with-kpathsea-include=DIR
 619                           location of the kpathsea include dir],[
 620             if test "$withval" = "yes" -o "$withval" = "no"; then
 621                 AC_MSG_WARN(Usage: --with-kpathsea-include=includedir)
 622             else
 623                 CPPFLAGS="$CPPFLAGS -I${withval}"
 624             fi
 625             ])
 626
 627     AC_ARG_WITH(kpathsea-lib,
 628         [  --with-kpathsea-lib=DIR location of the kpathsea lib dir],[
 629             if test "$withval" = "yes" -o "$withval" = "no"; then
 630                 AC_MSG_WARN(Usage: --with-kpathsea-lib=libdir)
 631             else
 632                 LDFLAGS="$LDFLAGS -L${withval}"
 633             fi
 634             ])
 635
 636     kpathsea_b=yes
 637     #FIXME --with-xxx is meant for specifying a PATH too,
 638     # so this should read: --enable-kpathsea,
 639     # or --with-kpathsea-include=PATH --with-kpathsea-lib=PATH
 640     AC_ARG_WITH(kpathsea,
 641     [  --with-kpathsea         use kpathsea lib.  Default: on],
 642     [kpathsea_b=$with_kpathsea])
 643
 644     if test "$kpathsea_b" != "no"; then
 645         AC_CHECK_HEADERS([kpathsea/kpathsea.h])
 646         AC_CHECK_LIB(kpathsea, kpse_find_file)
 647         AC_CHECK_FUNCS(kpse_find_file,,kpathsea_b=no)
 648         if test "$kpathsea_b" = "no"; then
 649             warn='kpathsea (libkpathsea-dev or kpathsea-devel package)
 650    Else, please specify the location of your kpathsea using
 651    --with-kpathea-include and --with-kpathsea-lib options.  You should
 652    install kpathsea; see INSTALL.txt.  Rerun ./configure
 653    --without-kpathsea only if kpathsea is not available for your
 654    platform.'
 655             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 656         fi
 657     fi
 658     AC_MSG_CHECKING(whether to use kpathsea)
 659     if test "$kpathsea_b" != no; then
 660         AC_MSG_RESULT(yes)
 661         KPATHSEA=1
 662     else
 663         AC_MSG_RESULT(no)
 664         KPATHSEA=0
 665     fi
 666
 667     AC_SUBST(KPATHSEA)
 668     AC_DEFINE_UNQUOTED(KPATHSEA, $KPATHSEA)
 669 ])
 670
 671
 672 AC_DEFUN(STEPMAKE_LIB, [
 673     STEPMAKE_PROGS(AR, ar, $1)
 674     AC_PROG_RANLIB
 675     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 676 ])
 677
 678
 679 AC_DEFUN(STEPMAKE_LIBTOOL, [
 680     # libtool.info ...
 681     # **Never** try to set library version numbers so that they correspond
 682     # to the release number of your package.  This is an abuse that only
 683     # fosters misunderstanding of the purpose of library versions.
 684
 685     REVISION=$PATCH_LEVEL
 686     # CURRENT=$MINOR_VERSION
 687     CURRENT=`expr $MINOR_VERSION + 1`
 688     # AGE=`expr $MAJOR_VERSION + 1`
 689     AGE=$MAJOR_VERSION
 690     AC_SUBST(CURRENT)
 691     AC_SUBST(REVISION)
 692     AC_SUBST(AGE)
 693 ])
 694
 695
 696 AC_DEFUN(STEPMAKE_LOCALE, [
 697     lang=English
 698     ALL_LINGUAS="en nl"
 699
 700     # with/enable ??
 701     AC_ARG_WITH(localedir,
 702     [  --with-localedir=LOCALE use LOCALE as locale dir.  Default:
 703                             PREFIX/share/locale ],
 704     localedir=$with_localedir,
 705     localedir='${prefix}/share/locale')
 706
 707     AC_ARG_WITH(lang,
 708     [  --with-lang=LANG        use LANG as language to emit messages],
 709     language=$with_lang,
 710     language=English)
 711
 712     AC_MSG_CHECKING(language)
 713     case "$language" in
 714       En* | en* | Am* | am* | US* | us*)
 715             lang=English;;
 716       NL | nl | Du* | du* | Ned* | ned*)
 717             lang=Dutch;;
 718       "")
 719             lang=English;;
 720       *)
 721             lang=unknown;;
 722     esac
 723     AC_MSG_RESULT($lang)
 724
 725     if test "$lang" = "unknown" ; then
 726         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 727     fi
 728
 729 ])
 730
 731
 732 AC_DEFUN(STEPMAKE_MAKEINFO, [
 733     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 734     if test "$MAKEINFO" = "makeinfo"; then
 735         AC_MSG_CHECKING(whether makeinfo can split html by @node)
 736         mkdir -p out
 737         makeinfo --html --output=out/split <<EOF
 738 \input texinfo
 739 \input texinfo @c -*-texinfo-*-
 740 @setfilename split.info
 741 @settitle split.info
 742 @bye
 743 EOF
 744         if test -d out/split; then
 745             SPLITTING_MAKEINFO=yes
 746             AC_MSG_RESULT(yes)
 747             rm -rf out/split
 748         else
 749             AC_MSG_RESULT(no)
 750             STEPMAKE_WARN(your html documentation will be one large file)
 751             rm -rf out/split
 752         fi
 753     fi
 754     AC_SUBST(SPLITTING_MAKEINFO)
 755 ])
 756
 757
 758
 759 AC_DEFUN(STEPMAKE_MAN, [
 760     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 761     AC_SUBST(GROFF)
 762     STEPMAKE_PROGS(TROFF, troff, $1)
 763     AC_SUBST(TROFF)
 764     STEPMAKE_PROGS(TBL, tbl, $1)
 765     AC_SUBST(TBL)
 766 ])
 767
 768
 769 AC_DEFUN(STEPMAKE_MSGFMT, [
 770     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
 771 ])
 772
 773
 774 # Check for program ($2), set full path result to ($1).
 775 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 776 AC_DEFUN(STEPMAKE_PATH_PROG, [
 777     AC_CHECK_PROGS($1, $2, no)
 778     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 779     if test $? -eq 0; then
 780         AC_PATH_PROG($1, $2)
 781         if test -n "$4"; then
 782             STEPMAKE_CHECK_VERSION($1, $3, $4)
 783         fi
 784     fi
 785 ])
 786
 787
 788 # Check for program in set of names ($2), set result to ($1) .
 789 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 790 # If exists, and a minimal version ($4) is required
 791 AC_DEFUN(STEPMAKE_PROGS, [
 792     AC_CHECK_PROGS($1, $2, no)
 793     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 794     if test $? -eq 0 -a -n "$4"; then
 795         STEPMAKE_CHECK_VERSION($1, $3, $4)
 796     fi
 797 ])
 798
 799
 800 AC_DEFUN(STEPMAKE_PERL, [
 801     STEPMAKE_PATH_PROG(PERL, perl, $1)
 802 ])
 803
 804
 805 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
 806     AC_CHECK_HEADERS([python2.2/Python.h python2.1/Python.h python2.0/Python.h python2/Python.h python/Python.h python1.5/Python.h Python.h],[PYTHON_HEADER=yes])
 807     if test -z "$PYTHON_HEADER"; then
 808         warn='python.h (python-devel, python-dev or libpython-dev package)'
 809         STEPMAKE_ADD_ENTRY($1, $warn)
 810     fi
 811 ])
 812
 813
 814 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
 815     AC_ARG_ENABLE(tfm-path,
 816     [  --enable-tfm-path=PATH  set path of tex directories where tfm files live,
 817                             esp.: cmr10.tfm.  Default: use kpsewhich],
 818     [tfm_path=$enableval],
 819     [tfm_path=auto] )
 820
 821     # ugh
 822     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, OPTIONAL)
 823     AC_MSG_CHECKING(for tfm path)
 824
 825     TFM_FONTS="cmr msam"
 826
 827     if test "x$tfm_path" = xauto ; then
 828         if test "x$KPSEWHICH" != "xno" ; then
 829             for i in $TFM_FONTS; do
 830                 dir=`$KPSEWHICH tfm ${i}10.tfm`
 831                 TFM_PATH="$TFM_PATH `dirname $dir`"
 832             done
 833         else
 834             STEPMAKE_WARN(Please specify where cmr10.tfm lives:
 835     ./configure --enable-tfm-path=/usr/local/TeX/lib/tex/fonts)
 836         fi
 837     else
 838          TFM_PATH=$tfm_path
 839     fi
 840
 841     TFM_PATH=`echo $TFM_PATH | tr ':' ' '`
 842     AC_MSG_RESULT($TFM_PATH)
 843     AC_SUBST(TFM_PATH)
 844 ])
 845
 846
 847 AC_DEFUN(STEPMAKE_TEXMF, [
 848     # urg, never know what names these teTeX guys will think up
 849
 850     STEPMAKE_PROGS(METAFONT, mf mfont, $1)
 851     STEPMAKE_PROGS(INIMETAFONT, inimf inimfont, $1)
 852
 853     AC_MSG_CHECKING(for working metafont mode)
 854     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
 855     for MFMODE in $modelist; do
 856         $METAFONT "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
 857         if test -f mfput.tfm; then
 858             break;
 859         fi
 860     done
 861     AC_MSG_RESULT($MFMODE)
 862
 863     rm -f mfput.*
 864
 865     AC_SUBST(MFMODE)
 866 ])
 867
 868
 869 AC_DEFUN(STEPMAKE_WARN, [
 870     AC_MSG_WARN($1)
 871     warn_b=yes
 872 ])
 873
 874