scm/output-lib.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2010 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;; Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19
  20 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21 ;; general
  22
  23 (define-public (grob::has-interface grob iface)
  24   (memq iface (ly:grob-interfaces grob)))
  25
  26 (define-public (grob::is-live? grob)
  27   (pair? (ly:grob-basic-properties grob)))
  28
  29 (define-public (make-stencil-boxer thickness padding callback)
  30
  31   "Return function that adds a box around the grob passed as argument."
  32   (lambda (grob)
  33     (box-stencil (callback grob) thickness padding)))
  34
  35 (define-public (make-stencil-circler thickness padding callback)
  36   "Return function that adds a circle around the grob passed as argument."
  37
  38   (lambda (grob) (circle-stencil (callback grob) thickness padding)))
  39
  40 (define-public (print-circled-text-callback grob)
  41   (grob-interpret-markup grob (make-circle-markup
  42                                (ly:grob-property grob 'text))))
  43
  44 (define-public (event-cause grob)
  45   (let ((cause (ly:grob-property  grob 'cause)))
  46
  47     (cond
  48      ((ly:stream-event? cause) cause)
  49      ((ly:grob? cause) (event-cause cause))
  50      (else #f))))
  51
  52 (define-public (grob-interpret-markup grob text)
  53   (let* ((layout (ly:grob-layout grob))
  54          (defs (ly:output-def-lookup layout 'text-font-defaults))
  55          (props (ly:grob-alist-chain grob defs)))
  56
  57     (ly:text-interface::interpret-markup layout props text)))
  58
  59
  60 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  61 ;; note heads
  62
  63 (define-public (stem::calc-duration-log grob)
  64   (ly:duration-log
  65    (ly:event-property (event-cause grob) 'duration)))
  66
  67 (define-public (note-head::calc-duration-log grob)
  68   (min 2
  69        (ly:duration-log
  70         (ly:event-property (event-cause grob) 'duration))))
  71
  72 (define-public (dots::calc-dot-count grob)
  73   (ly:duration-dot-count
  74    (ly:event-property (event-cause grob) 'duration)))
  75
  76 (define-public (dots::calc-staff-position grob)
  77   (let* ((head (ly:grob-parent grob Y))
  78          (log (ly:grob-property head 'duration-log)))
  79
  80     (cond
  81      ((or (not (grob::has-interface head 'rest-interface))
  82           (not (integer? log))) 0)
  83      ((= log 7) 4)
  84      ((> log 4) 3)
  85      ((= log 0) -1)
  86      ((= log 1) 1)
  87      ((= log -1) 1)
  88      (else 0))))
  89
  90 ;; Kept separate from note-head::calc-glyph-name to allow use by
  91 ;; markup commands \note and \note-by-number
  92 (define-public (select-head-glyph style log)
  93   "Select a note head glyph string based on note head style @var{style}
  94 and duration-log @var{log}."
  95   (case style
  96     ;; "default" style is directly handled in note-head.cc as a
  97     ;; special case (HW says, mainly for performance reasons).
  98     ;; Therefore, style "default" does not appear in this case
  99     ;; statement.  -- jr
 100     ((xcircle) "2xcircle")
 101     ((harmonic) "0harmonic")
 102     ((harmonic-black) "2harmonic")
 103     ((harmonic-mixed) (if (<= log 1) "0harmonic"
 104                           "2harmonic"))
 105     ((baroque)
 106      ;; Oops, I actually would not call this "baroque", but, for
 107      ;; backwards compatibility to 1.4, this is supposed to take
 108      ;; brevis, longa and maxima from the neo-mensural font and all
 109      ;; other note heads from the default font.  -- jr
 110      (if (< log 0)
 111          (string-append (number->string log) "neomensural")
 112          (number->string log)))
 113     ((altdefault)
 114      ;; Like default, but brevis is drawn with double vertical lines
 115      (if (= log -1)
 116          (string-append (number->string log) "double")
 117          (number->string log)))
 118     ((mensural)
 119      (string-append (number->string log) (symbol->string style)))
 120     ((petrucci)
 121      (if (< log 0)
 122          (string-append (number->string log) "mensural")
 123          (string-append (number->string log) (symbol->string style))))
 124     ((neomensural)
 125      (string-append (number->string log) (symbol->string style)))
 126     (else
 127      (if (string-match "vaticana*|hufnagel*|medicaea*" (symbol->string style))
 128          (symbol->string style)
 129          (string-append (number->string (max 0 log))
 130                         (symbol->string style))))))
 131
 132 (define-public (note-head::calc-glyph-name grob)
 133   (let ((style (ly:grob-property grob 'style))
 134         (log (min 2 (ly:grob-property grob 'duration-log))))
 135
 136     (select-head-glyph style log)))
 137
 138 (define-public (note-head::brew-ez-stencil grob)
 139   (let* ((log (ly:grob-property grob 'duration-log))
 140          (pitch (ly:event-property (event-cause grob) 'pitch))
 141          (pitch-index (ly:pitch-notename pitch))
 142          (note-names (ly:grob-property grob 'note-names))
 143          (pitch-string (if (and (vector? note-names)
 144                                 (> (vector-length note-names) pitch-index))
 145                            (vector-ref note-names pitch-index)
 146                            (string
 147                             (integer->char
 148                              (+ (modulo (+ pitch-index 2) 7)
 149                                 (char->integer #\A))))))
 150          (staff-space (ly:staff-symbol-staff-space grob))
 151          (line-thickness (ly:staff-symbol-line-thickness grob))
 152          (stem (ly:grob-object grob 'stem))
 153          (stem-thickness (* (if (ly:grob? stem)
 154                                 (ly:grob-property stem 'thickness)
 155                                 1.3)
 156                             line-thickness))
 157          (radius (/ (+ staff-space line-thickness) 2))
 158          (letter (markup #:center-align #:vcenter pitch-string))
 159          (filled-circle (markup #:draw-circle radius 0 #t)))
 160
 161     (ly:stencil-translate-axis
 162      (grob-interpret-markup
 163       grob
 164       (if (>= log 2)
 165           (make-combine-markup
 166            filled-circle
 167            (make-with-color-markup white letter))
 168           (make-combine-markup
 169            (make-combine-markup
 170             filled-circle
 171             (make-with-color-markup white (make-draw-circle-markup
 172                                            (- radius stem-thickness) 0 #t)))
 173            letter)))
 174      radius X)))
 175
 176
 177 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 178 ;; break visibility
 179
 180 (define-public all-visible             #(#t #t #t))
 181 (define-public begin-of-line-invisible #(#t #t #f))
 182 (define-public center-invisible        #(#t #f #t))
 183 (define-public end-of-line-invisible   #(#f #t #t))
 184 (define-public begin-of-line-visible   #(#f #f #t))
 185 (define-public center-visible          #(#f #t #f))
 186 (define-public end-of-line-visible     #(#t #f #f))
 187 (define-public all-invisible           #(#f #f #f))
 188
 189 (define-public spanbar-begin-of-line-invisible #(#t #f #f))
 190
 191
 192 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 193 ;; Bar lines.
 194
 195 ;;
 196 ;; How should a  bar line behave at a break?
 197 (define bar-glyph-alist
 198   '((":|:" . (":|" . "|:"))
 199     (":|.|:" . (":|" . "|:"))
 200     (":|.:" . (":|" . "|:"))
 201     ("||:" . ("||" . "|:"))
 202     ("dashed" . ("dashed" . '()))
 203     ("|" . ("|" . ()))
 204     ("||:" . ("||" . "|:"))
 205     ("|s" . (() . "|"))
 206     ("|:" . ("|" . "|:"))
 207     ("|." . ("|." . ()))
 208
 209     ;; hmm... should we end with a bar line here?
 210     (".|" . ("|" . ".|"))
 211     (":|" . (":|" . ()))
 212     ("||" . ("||" . ()))
 213     (".|." . (".|." . ()))
 214     ("|.|" . ("|.|" . ()))
 215     ("" . ("" . ""))
 216     (":" . (":" . ""))
 217     ("." . ("." . ()))
 218     ("'" . ("'" . ()))
 219     ("empty" . (() . ()))
 220     ("brace" . (() . "brace"))
 221     ("bracket" . (() . "bracket"))
 222
 223     ;; segno bar lines
 224     ("S" . ("||" . "S"))
 225     ("|S" . ("|" . "S"))
 226     ("S|" . ("S" . ()))
 227     (":|S" . (":|" . "S"))
 228     (":|S." . (":|S" . ()))
 229     ("S|:" . ("S" . "|:"))
 230     (".S|:" . ("|" . "S|:"))
 231     (":|S|:" . (":|" . "S|:"))
 232     (":|S.|:" . (":|S" . "|:"))))
 233
 234 (define-public (bar-line::calc-glyph-name grob)
 235   (let* ((glyph (ly:grob-property grob 'glyph))
 236          (dir (ly:item-break-dir grob))
 237          (result (assoc-get glyph bar-glyph-alist))
 238          (glyph-name (if (= dir CENTER)
 239                          glyph
 240                          (if (and result
 241                                   (string? (index-cell result dir)))
 242                              (index-cell result dir)
 243                              #f))))
 244     glyph-name))
 245
 246 (define-public (bar-line::calc-break-visibility grob)
 247   (let* ((glyph (ly:grob-property grob 'glyph))
 248          (result (assoc-get glyph bar-glyph-alist)))
 249
 250     (if result
 251         (vector (string? (car result)) #t (string? (cdr result)))
 252         all-invisible)))
 253
 254 (define-public (shift-right-at-line-begin g)
 255   "Shift an item to the right, but only at the start of the line."
 256   (if (and (ly:item? g)
 257            (equal? (ly:item-break-dir g) RIGHT))
 258       (ly:grob-translate-axis! g 3.5 X)))
 259
 260
 261 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 262 ;; Tuplets
 263
 264 (define-public (tuplet-number::calc-denominator-text grob)
 265   (number->string (ly:event-property (event-cause grob) 'denominator)))
 266
 267 (define-public (tuplet-number::calc-fraction-text grob)
 268   (let ((ev (event-cause grob)))
 269
 270     (format "~a:~a"
 271             (ly:event-property ev 'denominator)
 272             (ly:event-property ev 'numerator))))
 273
 274 ;; a formatter function, which is simply a wrapper around an existing
 275 ;; tuplet formatter function. It takes the value returned by the given
 276 ;; function and appends a note of given length.
 277 (define-public ((tuplet-number::append-note-wrapper function note) grob)
 278   (let ((txt (if function (function grob) #f)))
 279
 280     (if txt
 281         (markup txt #:fontsize -5 #:note note UP)
 282         (markup #:fontsize -5 #:note note UP))))
 283
 284 ;; Print a tuplet denominator with a different number than the one derived from
 285 ;; the actual tuplet fraction
 286 (define-public ((tuplet-number::non-default-tuplet-denominator-text denominator)
 287                 grob)
 288   (number->string (if denominator
 289                       denominator
 290                       (ly:event-property (event-cause grob) 'denominator))))
 291
 292 ;; Print a tuplet fraction with different numbers than the ones derived from
 293 ;; the actual tuplet fraction
 294 (define-public ((tuplet-number::non-default-tuplet-fraction-text
 295                  denominator numerator) grob)
 296   (let* ((ev (event-cause grob))
 297          (den (if denominator denominator (ly:event-property ev 'denominator)))
 298          (num (if numerator numerator (ly:event-property ev 'numerator))))
 299
 300     (format "~a:~a" den num)))
 301
 302 ;; Print a tuplet fraction with note durations appended to the numerator and the
 303 ;; denominator
 304 (define-public ((tuplet-number::fraction-with-notes
 305                  denominatornote numeratornote) grob)
 306   (let* ((ev (event-cause grob))
 307          (denominator (ly:event-property ev 'denominator))
 308          (numerator (ly:event-property ev 'numerator)))
 309
 310     ((tuplet-number::non-default-fraction-with-notes
 311       denominator denominatornote numerator numeratornote) grob)))
 312
 313 ;; Print a tuplet fraction with note durations appended to the numerator and the
 314 ;; denominator
 315 (define-public ((tuplet-number::non-default-fraction-with-notes
 316                  denominator denominatornote numerator numeratornote) grob)
 317   (let* ((ev (event-cause grob))
 318          (den (if denominator denominator (ly:event-property ev 'denominator)))
 319          (num (if numerator numerator (ly:event-property ev 'numerator))))
 320
 321     (make-concat-markup (list
 322                          (make-simple-markup (format "~a" den))
 323                          (markup #:fontsize -5 #:note denominatornote UP)
 324                          (make-simple-markup " : ")
 325                          (make-simple-markup (format "~a" num))
 326                          (markup #:fontsize -5 #:note numeratornote UP)))))
 327
 328
 329 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 330 ;; Color
 331
 332 (define-public color? list?)
 333 (define-public (rgb-color r g b) (list r g b))
 334
 335 ; predefined colors
 336 (define-public black       '(0.0 0.0 0.0))
 337 (define-public white       '(1.0 1.0 1.0))
 338 (define-public red         '(1.0 0.0 0.0))
 339 (define-public green       '(0.0 1.0 0.0))
 340 (define-public blue        '(0.0 0.0 1.0))
 341 (define-public cyan        '(0.0 1.0 1.0))
 342 (define-public magenta     '(1.0 0.0 1.0))
 343 (define-public yellow      '(1.0 1.0 0.0))
 344
 345 (define-public grey        '(0.5 0.5 0.5))
 346 (define-public darkred     '(0.5 0.0 0.0))
 347 (define-public darkgreen   '(0.0 0.5 0.0))
 348 (define-public darkblue    '(0.0 0.0 0.5))
 349 (define-public darkcyan    '(0.0 0.5 0.5))
 350 (define-public darkmagenta '(0.5 0.0 0.5))
 351 (define-public darkyellow  '(0.5 0.5 0.0))
 352
 353
 354 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 355 ;; key signature
 356
 357 (define-public (key-signature-interface::alteration-position step alter
 358                                                              c0-position)
 359   ;; TODO: memoize - this is mostly constant.
 360
 361   ;; fes, ges, as and bes typeset in lower octave
 362   (define FLAT_TOP_PITCH 2)
 363
 364   ;; ais and bis typeset in lower octave
 365   (define SHARP_TOP_PITCH 4)
 366
 367   (if (pair? step)
 368       (+ (cdr step) (* (car step) 7) c0-position)
 369       (let* ((from-bottom-pos (modulo (+ 4 49 c0-position) 7))
 370              (p step)
 371              (c0 (- from-bottom-pos 4)))
 372
 373         (if
 374          (or (and (< alter 0)
 375                   (or (> p FLAT_TOP_PITCH) (> (+ p c0) 4)) (> (+ p c0) 1))
 376              (and (> alter 0)
 377                   (or (> p SHARP_TOP_PITCH) (> (+ p c0) 5)) (> (+ p c0) 2)))
 378
 379          ;; Typeset below c_position
 380          (set! p (- p 7)))
 381
 382         ;; Provide for the four cases in which there's a glitch
 383         ;; it's a hack, but probably not worth
 384         ;; the effort of finding a nicer solution.
 385         ;; --dl.
 386         (cond
 387          ((and (= c0 2) (= p 3) (> alter 0))
 388           (set! p (- p 7)))
 389          ((and (= c0 -3) (= p -1) (> alter 0))
 390           (set! p (+ p 7)))
 391          ((and (= c0 -4) (= p -1) (< alter 0))
 392           (set! p (+ p 7)))
 393          ((and (= c0 -2) (= p -3) (< alter 0))
 394           (set! p (+ p 7))))
 395
 396         (+ c0 p))))
 397
 398
 399 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 400 ;; accidentals
 401
 402 (define-public (accidental-interface::calc-alteration grob)
 403   (ly:pitch-alteration (ly:event-property (event-cause grob) 'pitch)))
 404
 405 (define-public cancellation-glyph-name-alist
 406   '((0 . "accidentals.natural")))
 407
 408 (define-public standard-alteration-glyph-name-alist
 409   '(
 410     ;; ordered for optimal performance.
 411     (0 . "accidentals.natural")
 412     (-1/2 . "accidentals.flat")
 413     (1/2 . "accidentals.sharp")
 414
 415     (1 . "accidentals.doublesharp")
 416     (-1 . "accidentals.flatflat")
 417
 418     (3/4 . "accidentals.sharp.slashslash.stemstemstem")
 419     (1/4 . "accidentals.sharp.slashslash.stem")
 420     (-1/4 . "accidentals.mirroredflat")
 421     (-3/4 . "accidentals.mirroredflat.flat")))
 422
 423 ;; FIXME: standard vs default, alteration-FOO vs FOO-alteration
 424 (define-public alteration-default-glyph-name-alist
 425   standard-alteration-glyph-name-alist)
 426
 427 (define-public makam-alteration-glyph-name-alist
 428   '((1 . "accidentals.doublesharp")
 429     (8/9 . "accidentals.sharp.slashslashslash.stemstem")
 430     (5/9 . "accidentals.sharp.slashslashslash.stem")
 431     (4/9 . "accidentals.sharp")
 432     (1/9 . "accidentals.sharp.slashslash.stem")
 433     (0 . "accidentals.natural")
 434     (-1/9 . "accidentals.mirroredflat")
 435     (-4/9 . "accidentals.flat.slash")
 436     (-5/9 . "accidentals.flat")
 437     (-8/9 . "accidentals.flat.slashslash")
 438     (-1 . "accidentals.flatflat")))
 439
 440 (define-public alteration-hufnagel-glyph-name-alist
 441   '((-1/2 . "accidentals.hufnagelM1")
 442     (0 . "accidentals.vaticana0")
 443     (1/2 . "accidentals.mensural1")))
 444
 445 (define-public alteration-medicaea-glyph-name-alist
 446   '((-1/2 . "accidentals.medicaeaM1")
 447     (0 . "accidentals.vaticana0")
 448     (1/2 . "accidentals.mensural1")))
 449
 450 (define-public alteration-vaticana-glyph-name-alist
 451   '((-1/2 . "accidentals.vaticanaM1")
 452     (0 . "accidentals.vaticana0")
 453     (1/2 . "accidentals.mensural1")))
 454
 455 (define-public alteration-mensural-glyph-name-alist
 456   '((-1/2 . "accidentals.mensuralM1")
 457     (0 . "accidentals.vaticana0")
 458     (1/2 . "accidentals.mensural1")))
 459
 460
 461 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 462 ;; * Pitch Trill Heads
 463 ;; * Parentheses
 464
 465 (define-public (parentheses-item::calc-parenthesis-stencils grob)
 466   (let* ((font (ly:grob-default-font grob))
 467          (lp (ly:font-get-glyph font "accidentals.leftparen"))
 468          (rp (ly:font-get-glyph font "accidentals.rightparen")))
 469
 470     (list lp rp)))
 471
 472 (define-public (parentheses-item::calc-angled-bracket-stencils grob)
 473   (let* ((parent (ly:grob-parent grob Y))
 474          (y-extent (ly:grob-extent parent parent Y))
 475          (half-thickness 0.05) ; should it be a property?
 476          (width 0.5) ; should it be a property?
 477          (angularity 1.5)  ; makes angle brackets
 478          (white-padding 0.1) ; should it be a property?
 479          (lp (ly:stencil-aligned-to
 480                  (ly:stencil-aligned-to
 481                    (make-parenthesis-stencil y-extent
 482                                              half-thickness
 483                                              (- width)
 484                                              angularity)
 485                    Y CENTER)
 486                  X RIGHT))
 487          (lp-x-extent
 488            (interval-widen (ly:stencil-extent lp X) white-padding))
 489          (rp (ly:stencil-aligned-to
 490                  (ly:stencil-aligned-to
 491                    (make-parenthesis-stencil y-extent
 492                                              half-thickness
 493                                              width
 494                                              angularity)
 495                    Y CENTER)
 496                  X LEFT))
 497           (rp-x-extent
 498             (interval-widen (ly:stencil-extent rp X) white-padding)))
 499     (set! lp (ly:make-stencil (ly:stencil-expr lp)
 500                               lp-x-extent
 501                               (ly:stencil-extent lp Y)))
 502     (set! rp (ly:make-stencil (ly:stencil-expr rp)
 503                               rp-x-extent
 504                               (ly:stencil-extent rp Y)))
 505     (list (stencil-whiteout lp)
 506           (stencil-whiteout rp))))
 507
 508 (define (parenthesize-elements grob . rest)
 509   (let* ((refp (if (null? rest)
 510                    grob
 511                    (car rest)))
 512          (elts (ly:grob-object grob 'elements))
 513          (x-ext (ly:relative-group-extent elts refp X))
 514          (stencils (ly:grob-property grob 'stencils))
 515          (lp (car stencils))
 516          (rp (cadr stencils))
 517          (padding (ly:grob-property grob 'padding 0.1)))
 518
 519     (ly:stencil-add
 520      (ly:stencil-translate-axis lp (- (car x-ext) padding) X)
 521      (ly:stencil-translate-axis rp (+ (cdr x-ext) padding) X))))
 522
 523
 524 (define (parentheses-item::print me)
 525   (let* ((elts (ly:grob-object me 'elements))
 526          (y-ref (ly:grob-common-refpoint-of-array me elts Y))
 527          (x-ref (ly:grob-common-refpoint-of-array me elts X))
 528          (stencil (parenthesize-elements me x-ref))
 529          (elt-y-ext (ly:relative-group-extent elts y-ref Y))
 530          (y-center (interval-center elt-y-ext)))
 531
 532     (ly:stencil-translate
 533      stencil
 534      (cons
 535       (- (ly:grob-relative-coordinate me x-ref X))
 536       (- y-center (ly:grob-relative-coordinate me y-ref Y))))))
 537
 538
 539
 540 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 541 ;;
 542
 543 (define-public (chain-grob-member-functions grob value . funcs)
 544   (for-each
 545    (lambda (func)
 546      (set! value (func grob value)))
 547    funcs)
 548
 549   value)
 550
 551
 552 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 553 ;; falls/doits
 554
 555 (define-public (bend::print spanner)
 556   (define (close  a b)
 557     (< (abs (- a b)) 0.01))
 558
 559   (let* ((delta-y (* 0.5 (ly:grob-property spanner 'delta-position)))
 560          (left-span (ly:spanner-bound spanner LEFT))
 561          (dots (if (and (grob::has-interface left-span 'note-head-interface)
 562                         (ly:grob? (ly:grob-object left-span 'dot)))
 563                    (ly:grob-object left-span 'dot) #f))
 564
 565          (right-span (ly:spanner-bound spanner RIGHT))
 566          (thickness (* (ly:grob-property spanner 'thickness)
 567                        (ly:output-def-lookup (ly:grob-layout spanner)
 568                                              'line-thickness)))
 569          (padding (ly:grob-property spanner 'padding 0.5))
 570          (common (ly:grob-common-refpoint right-span
 571                                           (ly:grob-common-refpoint spanner
 572                                                                    left-span X)
 573                                           X))
 574          (common-y (ly:grob-common-refpoint spanner left-span Y))
 575          (minimum-length (ly:grob-property spanner 'minimum-length 0.5))
 576
 577          (left-x (+ padding
 578                     (max
 579                      (interval-end (ly:grob-robust-relative-extent
 580                                     left-span common X))
 581                      (if
 582                       (and dots
 583                            (close
 584                             (ly:grob-relative-coordinate dots common-y Y)
 585                             (ly:grob-relative-coordinate spanner common-y Y)))
 586                       (interval-end
 587                        (ly:grob-robust-relative-extent dots common X))
 588                       ;; TODO: use real infinity constant.
 589                       -10000))))
 590          (right-x (max (- (interval-start
 591                            (ly:grob-robust-relative-extent right-span common X))
 592                           padding)
 593                        (+ left-x minimum-length)))
 594          (self-x (ly:grob-relative-coordinate spanner common X))
 595          (dx (- right-x left-x))
 596          (exp (list 'path thickness
 597                     `(quote
 598                       (rmoveto
 599                        ,(- left-x self-x) 0
 600
 601                        rcurveto
 602                        ,(/ dx 3)
 603                        0
 604                        ,dx ,(* 0.66 delta-y)
 605                        ,dx ,delta-y)))))
 606
 607     (ly:make-stencil
 608      exp
 609      (cons (- left-x self-x) (- right-x self-x))
 610      (cons (min 0 delta-y)
 611            (max 0 delta-y)))))
 612
 613
 614 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 615 ;; grace spacing
 616
 617 (define-public (grace-spacing::calc-shortest-duration grob)
 618   (let* ((cols (ly:grob-object grob 'columns))
 619          (get-difference
 620           (lambda (idx)
 621             (ly:moment-sub (ly:grob-property
 622                             (ly:grob-array-ref cols (1+ idx)) 'when)
 623                            (ly:grob-property
 624                             (ly:grob-array-ref cols idx) 'when))))
 625
 626          (moment-min (lambda (x y)
 627                        (cond
 628                         ((and x y)
 629                          (if (ly:moment<? x y)
 630                              x
 631                              y))
 632                         (x x)
 633                         (y y)))))
 634
 635     (fold moment-min #f (map get-difference
 636                              (iota (1- (ly:grob-array-length cols)))))))
 637
 638
 639 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 640 ;; fingering
 641
 642 (define-public (fingering::calc-text grob)
 643   (let* ((event (event-cause grob))
 644          (digit (ly:event-property event 'digit)))
 645
 646     (if (> digit 5)
 647         (ly:input-message (ly:event-property event 'origin)
 648                           "Warning: Fingering notation for finger number ~a"
 649                           digit))
 650
 651     (number->string digit 10)))
 652
 653 (define-public (string-number::calc-text grob)
 654   (let ((digit (ly:event-property (event-cause grob) 'string-number)))
 655
 656     (number->string digit 10)))
 657
 658 (define-public (stroke-finger::calc-text grob)
 659   (let* ((digit (ly:event-property (event-cause grob) 'digit))
 660          (text (ly:event-property (event-cause grob) 'text)))
 661
 662     (if (string? text)
 663         text
 664         (vector-ref (ly:grob-property grob 'digit-names)
 665                     (1- (max (min 5 digit) 1))))))
 666
 667
 668 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 669 ;; dynamics
 670
 671 (define-public (hairpin::calc-grow-direction grob)
 672   (if (eq? (ly:event-property (event-cause grob) 'class) 'decrescendo-event)
 673       START
 674       STOP))
 675
 676 (define-public (dynamic-text-spanner::before-line-breaking grob)
 677   "Monitor left bound of @code{DynamicTextSpanner} for absolute dynamics.
 678 If found, ensure @code{DynamicText} does not collide with spanner text by
 679 changing @code{'attach-dir} and @code{'padding}.  Reads the
 680 @code{'right-padding} property of @code{DynamicText} to fine tune space
 681 between the two text elements."
 682   (let ((left-bound (ly:spanner-bound grob LEFT)))
 683     (if (grob::has-interface left-bound 'dynamic-text-interface)
 684         (let* ((details (ly:grob-property grob 'bound-details))
 685                (left-details (ly:assoc-get 'left details))
 686                (my-padding (ly:assoc-get 'padding left-details))
 687                (script-padding (ly:grob-property left-bound 'right-padding 0)))
 688
 689           (and (number? my-padding)
 690                (ly:grob-set-nested-property! grob
 691                                              '(bound-details left attach-dir)
 692                                              RIGHT)
 693                (ly:grob-set-nested-property! grob
 694                                              '(bound-details left padding)
 695                                              (+ my-padding script-padding)))))))
 696
 697
 698 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 699 ;; lyrics
 700
 701 (define-public (lyric-text::print grob)
 702   "Allow interpretation of tildes as lyric tieing marks."
 703
 704   (let ((text (ly:grob-property grob 'text)))
 705
 706     (grob-interpret-markup grob (if (string? text)
 707                                     (make-tied-lyric-markup text)
 708                                     text))))
 709
 710 (define-public ((grob::calc-property-by-copy prop) grob)
 711   (ly:event-property (event-cause grob) prop))
 712
 713
 714 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 715 ;; fret boards
 716
 717 (define-public (fret-board::calc-stencil grob)
 718   (grob-interpret-markup
 719    grob
 720    (make-fret-diagram-verbose-markup
 721     (ly:grob-property grob 'dot-placement-list))))
 722
 723
 724 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 725 ;; scripts
 726
 727 (define-public (script-interface::calc-x-offset grob)
 728   (ly:grob-property grob 'positioning-done)
 729   (let* ((shift (ly:grob-property grob 'toward-stem-shift 0.0))
 730          (note-head-location
 731           (ly:self-alignment-interface::centered-on-x-parent grob))
 732          (note-head-grob (ly:grob-parent grob X))
 733          (stem-grob (ly:grob-object note-head-grob 'stem)))
 734
 735     (+ note-head-location
 736        ;; If the property 'toward-stem-shift is defined and the script
 737        ;; has the same direction as the stem, move the script accordingly.
 738        ;; Since scripts can also be over skips, we need to check whether
 739        ;; the grob has a stem at all.
 740        (if (ly:grob? stem-grob)
 741            (let ((dir1 (ly:grob-property grob 'direction))
 742                  (dir2 (ly:grob-property stem-grob 'direction)))
 743              (if (equal? dir1 dir2)
 744                  (let* ((common-refp (ly:grob-common-refpoint grob stem-grob X))
 745                         (stem-location
 746                          (ly:grob-relative-coordinate stem-grob common-refp X)))
 747                    (* shift (- stem-location note-head-location)))
 748                  0.0))
 749            0.0))))
 750
 751
 752 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 753 ;; instrument names
 754
 755 (define-public (system-start-text::print grob)
 756   (let* ((left-bound (ly:spanner-bound grob LEFT))
 757          (left-mom (ly:grob-property left-bound 'when))
 758          (name (if (moment<=? left-mom ZERO-MOMENT)
 759                    (ly:grob-property grob 'long-text)
 760                    (ly:grob-property grob 'text))))
 761
 762     (if (and (markup? name)
 763              (!= (ly:item-break-dir left-bound) CENTER))
 764
 765         (grob-interpret-markup grob name)
 766         (ly:grob-suicide! grob))))
 767
 768 (define-public (system-start-text::calc-x-offset grob)
 769   (let* ((left-bound (ly:spanner-bound grob LEFT))
 770          (left-mom (ly:grob-property left-bound 'when))
 771          (layout (ly:grob-layout grob))
 772          (indent (ly:output-def-lookup layout
 773                                        (if (moment<=? left-mom ZERO-MOMENT)
 774                                            'indent
 775                                            'short-indent)
 776                                        0.0))
 777          (system (ly:grob-system grob))
 778          (my-extent (ly:grob-extent grob system X))
 779          (elements (ly:grob-object system 'elements))
 780          (common (ly:grob-common-refpoint-of-array system elements X))
 781          (total-ext empty-interval)
 782          (align-x (ly:grob-property grob 'self-alignment-X 0))
 783          (padding (min 0 (- (interval-length my-extent) indent)))
 784          (right-padding (- padding
 785                            (/ (* padding (1+ align-x)) 2))))
 786
 787     ;; compensate for the variation in delimiter extents by
 788     ;; calculating an X-offset correction based on united extents
 789     ;; of all delimiters in this system
 790     (let unite-delims ((l (ly:grob-array-length elements)))
 791       (if (> l 0)
 792           (let ((elt (ly:grob-array-ref elements (1- l))))
 793
 794             (if (grob::has-interface elt 'system-start-delimiter-interface)
 795                 (let ((dims (ly:grob-extent elt common X)))
 796                   (if (interval-sane? dims)
 797                       (set! total-ext (interval-union total-ext dims)))))
 798             (unite-delims (1- l)))))
 799
 800     (+
 801      (ly:side-position-interface::x-aligned-side grob)
 802      right-padding
 803      (- (interval-length total-ext)))))
 804
 805 (define-public (system-start-text::calc-y-offset grob)
 806
 807   (define (live-elements-list me)
 808     (let* ((elements (ly:grob-object me 'elements))
 809            (elts-length (ly:grob-array-length elements))
 810            (live-elements '()))
 811
 812       (let get-live ((len elts-length))
 813         (if (> len 0)
 814             (let ((elt (ly:grob-array-ref elements (1- len))))
 815
 816               (if (grob::is-live? elt)
 817                   (set! live-elements (cons elt live-elements)))
 818               (get-live (1- len)))))
 819       live-elements))
 820
 821   (let* ((left-bound (ly:spanner-bound grob LEFT))
 822          (live-elts (live-elements-list grob))
 823          (system (ly:grob-system grob))
 824          (extent empty-interval))
 825
 826     (if (and (pair? live-elts)
 827              (interval-sane? (ly:grob-extent grob system Y)))
 828         (let get-extent ((lst live-elts))
 829           (if (pair? lst)
 830               (let ((axis-group (car lst)))
 831
 832                 (if (and (ly:spanner? axis-group)
 833                          (equal? (ly:spanner-bound axis-group LEFT)
 834                                  left-bound))
 835                     (set! extent (add-point extent
 836                                             (ly:grob-relative-coordinate
 837                                              axis-group system Y))))
 838                 (get-extent (cdr lst)))))
 839         ;; no live axis group(s) for this instrument name -> remove from system
 840         (ly:grob-suicide! grob))
 841
 842     (+
 843      (ly:self-alignment-interface::y-aligned-on-self grob)
 844      (interval-center extent))))
 845
 846
 847 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 848 ;; ambitus
 849
 850 (define-public (ambitus::print grob)
 851   (let ((heads (ly:grob-object grob 'note-heads)))
 852
 853     (if (and (ly:grob-array? heads)
 854              (= (ly:grob-array-length heads) 2))
 855         (let* ((common (ly:grob-common-refpoint-of-array grob heads Y))
 856                (head-down (ly:grob-array-ref heads 0))
 857                (head-up (ly:grob-array-ref heads 1))
 858                (gap (ly:grob-property grob 'gap 0.35))
 859                (point-min (+ (interval-end (ly:grob-extent head-down common Y))
 860                              gap))
 861                (point-max (- (interval-start (ly:grob-extent head-up common Y))
 862                              gap)))
 863
 864           (if (< point-min point-max)
 865               (let* ((layout (ly:grob-layout grob))
 866                      (line-thick (ly:output-def-lookup layout 'line-thickness))
 867                      (blot (ly:output-def-lookup layout 'blot-diameter))
 868                      (grob-thick (ly:grob-property grob 'thickness 2))
 869                      (width (* line-thick grob-thick))
 870                      (x-ext (symmetric-interval (/ width 2)))
 871                      (y-ext (cons point-min point-max))
 872                      (line (ly:round-filled-box x-ext y-ext blot))
 873                      (y-coord (ly:grob-relative-coordinate grob common Y)))
 874
 875                 (ly:stencil-translate-axis line (- y-coord) Y))
 876               empty-stencil))
 877         (begin
 878           (ly:grob-suicide! grob)
 879           (list)))))