lily/parser.yy

   1 /* -*- mode: c++; c-file-style: "linux" -*- */
   2 /*
   3   This file is part of LilyPond, the GNU music typesetter.
   4
   5   Copyright (C) 1997--2012 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6                  Jan Nieuwenhuizen <janneke@gnu.org>
   7
   8   LilyPond is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   LilyPond is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  20 */
  21
  22 /* Mode and indentation are at best a rough approximation based on TAB
  23  * formatting (reasonable for compatibility with unspecific editor
  24  * modes as Bison modes are hard to find) and need manual correction
  25  * frequently.  Without a reasonably dependable way of formatting a
  26  * Bison file sensibly, there is little point in trying to fix the
  27  * inconsistent state of indentation.
  28  */
  29
  30 %{
  31
  32 #define YYDEBUG 1
  33 #define YYERROR_VERBOSE 1
  34
  35 #define yyerror Lily_parser::parser_error
  36
  37 /* We use custom location type: Input objects */
  38 #define YYLTYPE Input
  39 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  40         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  41
  42
  43 %}
  44
  45 %parse-param {Lily_parser *parser}
  46 %lex-param {Lily_parser *parser}
  47
  48 /* We use SCMs to do strings, because it saves us the trouble of
  49 deleting them.  Let's hope that a stack overflow doesn't trigger a move
  50 of the parse stack onto the heap. */
  51
  52 %left PREC_BOT
  53 %nonassoc REPEAT
  54 %nonassoc ALTERNATIVE
  55
  56 /* The above precedences tackle the shift/reduce problem
  57
  58 1.  \repeat
  59         \repeat .. \alternative
  60
  61     \repeat { \repeat .. \alternative }
  62
  63 or
  64
  65     \repeat { \repeat } \alternative
  66 */
  67
  68 %nonassoc COMPOSITE
  69 %left ADDLYRICS
  70
  71  /* ADDLYRICS needs to have lower precedence than argument scanning,
  72   * or we won't be able to tell music apart from closed_music without
  73   * lookahead in the context of function calls.
  74   */
  75
  76 %nonassoc DEFAULT
  77
  78  /* \default is only applied after exhausting function arguments */
  79
  80 %nonassoc FUNCTION_ARGLIST
  81
  82  /* expressions with units are permitted into argument lists */
  83
  84 %right PITCH_IDENTIFIER NOTENAME_PITCH TONICNAME_PITCH
  85       UNSIGNED REAL DURATION_IDENTIFIER ':'
  86
  87  /* The above are the symbols that can start optional function arguments
  88     that are recognized in the grammar rather than by predicate
  89  */
  90
  91 %nonassoc NUMBER_IDENTIFIER '/'
  92
  93  /* Number-unit expressions, where permitted, are concatenated into
  94   * function arguments, just like fractions and tremoli.  Tremoli must
  95   * not have higher precedence than UNSIGNED, or Lilypond will not
  96   * join ':' with a following optional number.
  97   */
  98
  99 %left PREC_TOP
 100
 101
 102
 103
 104 %pure_parser
 105 %locations
 106
 107
 108
 109 %{ // -*-Fundamental-*-
 110
 111 /*
 112 FIXME:
 113
 114    * The rules for who is protecting what are very shady.  Uniformise
 115      this.
 116
 117    * There are too many lexical modes?
 118 */
 119
 120 #include "config.hh"
 121
 122 #include <cctype>
 123 #include <cstdlib>
 124 #include <cstdio>
 125 using namespace std;
 126
 127 #include "book.hh"
 128 #include "context-def.hh"
 129 #include "context-mod.hh"
 130 #include "dimensions.hh"
 131 #include "file-path.hh"
 132 #include "input.hh"
 133 #include "international.hh"
 134 #include "lily-guile.hh"
 135 #include "lily-lexer.hh"
 136 #include "lily-parser.hh"
 137 #include "main.hh"
 138 #include "misc.hh"
 139 #include "music.hh"
 140 #include "output-def.hh"
 141 #include "paper-book.hh"
 142 #include "scm-hash.hh"
 143 #include "score.hh"
 144 #include "text-interface.hh"
 145 #include "warn.hh"
 146
 147 void
 148 Lily_parser::parser_error (Input const *i, Lily_parser *parser, string s)
 149 {
 150         parser->parser_error (*i, s);
 151 }
 152
 153 #define MYBACKUP(Token, Value, Location)                                \
 154 do                                                                      \
 155         if (yychar == YYEMPTY)                                          \
 156         {                                                               \
 157                 if (Token)                                              \
 158                         parser->lexer_->push_extra_token (Token, Value); \
 159                 parser->lexer_->push_extra_token (BACKUP);              \
 160         } else {                                                        \
 161                 parser->parser_error                                    \
 162                         (Location, _("Too much lookahead"));            \
 163         }                                                               \
 164 while (0)
 165
 166
 167 #define MYREPARSE(Location, Pred, Token, Value)                         \
 168 do                                                                      \
 169         if (yychar == YYEMPTY)                                          \
 170         {                                                               \
 171                 parser->lexer_->push_extra_token (Token, Value);        \
 172                 parser->lexer_->push_extra_token (REPARSE,              \
 173                                                   Pred);                \
 174         } else {                                                        \
 175                 parser->parser_error                                    \
 176                         (Location, _("Too much lookahead"));            \
 177         }                                                               \
 178 while (0)
 179
 180 %}
 181
 182
 183 %union {
 184         Book *book;
 185         Output_def *outputdef;
 186         SCM scm;
 187         std::string *string;
 188         Score *score;
 189         int i;
 190 }
 191
 192 %{
 193
 194 #define MY_MAKE_MUSIC(x, spot)  make_music_with_input (ly_symbol2scm (x), spot)
 195
 196 /* ES TODO:
 197 - Don't use lily module, create a new module instead.
 198 - delay application of the function
 199 */
 200 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 201   scm_apply_0 (proc, args)
 202 /* Syntactic Sugar. */
 203 #define MAKE_SYNTAX(name, location, ...)        \
 204   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (parser->self_scm (), make_input (location) , ##__VA_ARGS__, SCM_UNDEFINED))
 205 #define START_MAKE_SYNTAX(name, ...)                                    \
 206         scm_list_n (ly_lily_module_constant (name) , ##__VA_ARGS__, SCM_UNDEFINED)
 207 #define FINISH_MAKE_SYNTAX(start, location, ...)                        \
 208         LOWLEVEL_MAKE_SYNTAX (scm_car (start), scm_cons2 (parser->self_scm (), make_input (location), scm_append_x (scm_list_2 (scm_cdr (start), scm_list_n (__VA_ARGS__, SCM_UNDEFINED)))))
 209
 210 SCM get_next_unique_context_id ();
 211 SCM get_next_unique_lyrics_context_id ();
 212
 213 #undef _
 214 #if !HAVE_GETTEXT
 215 #define _(x) x
 216 #else
 217 #include <libintl.h>
 218 #define _(x) gettext (x)
 219 #endif
 220
 221
 222 static Music *make_music_with_input (SCM name, Input where);
 223 SCM check_scheme_arg (Lily_parser *parser, Input loc,
 224                       SCM arg, SCM args, SCM pred);
 225 SCM loc_on_music (Input loc, SCM arg);
 226 SCM make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list);
 227 SCM make_chord_step (int step, Rational alter);
 228 SCM make_simple_markup (SCM a);
 229 bool is_duration (int t);
 230 bool is_regular_identifier (SCM id);
 231 int yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser);
 232 void set_music_properties (Music *p, SCM a);
 233
 234 %}
 235
 236 /* The third option is an alias that will be used to display the
 237    syntax error.  Bison CVS now correctly handles backslash escapes.
 238
 239    FIXME: Bison needs to translate some of these, eg, STRING.
 240
 241 */
 242
 243 /* Keyword tokens with plain escaped name.  */
 244 %token ACCEPTS "\\accepts"
 245 %token ADDLYRICS "\\addlyrics"
 246 %token ALIAS "\\alias"
 247 %token ALTERNATIVE "\\alternative"
 248 %token BOOK "\\book"
 249 %token BOOKPART "\\bookpart"
 250 %token CHANGE "\\change"
 251 %token CHORDMODE "\\chordmode"
 252 %token CHORDS "\\chords"
 253 %token CONSISTS "\\consists"
 254 %token CONTEXT "\\context"
 255 %token DEFAULT "\\default"
 256 %token DEFAULTCHILD "\\defaultchild"
 257 %token DENIES "\\denies"
 258 %token DESCRIPTION "\\description"
 259 %token DRUMMODE "\\drummode"
 260 %token DRUMS "\\drums"
 261 %token FIGUREMODE "\\figuremode"
 262 %token FIGURES "\\figures"
 263 %token HEADER "\\header"
 264 %token INVALID "\\version-error"
 265 %token LAYOUT "\\layout"
 266 %token LYRICMODE "\\lyricmode"
 267 %token LYRICS "\\lyrics"
 268 %token LYRICSTO "\\lyricsto"
 269 %token MARKUP "\\markup"
 270 %token MARKUPLIST "\\markuplist"
 271 %token MIDI "\\midi"
 272 %token NAME "\\name"
 273 %token NOTEMODE "\\notemode"
 274 %token OVERRIDE "\\override"
 275 %token PAPER "\\paper"
 276 %token REMOVE "\\remove"
 277 %token REPEAT "\\repeat"
 278 %token REST "\\rest"
 279 %token REVERT "\\revert"
 280 %token SCORE "\\score"
 281 %token SEQUENTIAL "\\sequential"
 282 %token SET "\\set"
 283 %token SIMULTANEOUS "\\simultaneous"
 284 %token TEMPO "\\tempo"
 285 %token TYPE "\\type"
 286 %token UNSET "\\unset"
 287 %token WITH "\\with"
 288
 289 /* Keyword token exceptions.  */
 290 %token NEWCONTEXT "\\new"
 291
 292
 293 /* Other string tokens.  */
 294
 295 %token CHORD_BASS "/+"
 296 %token CHORD_CARET "^"
 297 %token CHORD_COLON ":"
 298 %token CHORD_MINUS "-"
 299 %token CHORD_SLASH "/"
 300 %token ANGLE_OPEN "<"
 301 %token ANGLE_CLOSE ">"
 302 %token DOUBLE_ANGLE_OPEN "<<"
 303 %token DOUBLE_ANGLE_CLOSE ">>"
 304 %token E_BACKSLASH "\\"
 305 %token E_ANGLE_CLOSE "\\>"
 306 %token E_CHAR "\\C[haracter]"
 307 %token E_CLOSE "\\)"
 308 %token E_EXCLAMATION "\\!"
 309 %token E_BRACKET_OPEN "\\["
 310 %token E_OPEN "\\("
 311 %token E_BRACKET_CLOSE "\\]"
 312 %token E_ANGLE_OPEN "\\<"
 313 %token E_PLUS "\\+"
 314 %token E_TILDE "\\~"
 315 %token EXTENDER "__"
 316
 317 /*
 318 If we give names, Bison complains.
 319 */
 320 %token FIGURE_CLOSE /* "\\>" */
 321 %token FIGURE_OPEN /* "\\<" */
 322 %token FIGURE_SPACE "_"
 323 %token HYPHEN "--"
 324
 325 %token CHORDMODIFIERS
 326 %token LYRIC_MARKUP
 327 %token MULTI_MEASURE_REST
 328
 329
 330 %token <i> E_UNSIGNED
 331 %token <scm> UNSIGNED
 332
 333 /* Artificial tokens, for more generic function syntax */
 334 %token <i> EXPECT_MARKUP "markup?"
 335 %token <i> EXPECT_PITCH "ly:pitch?"
 336 %token <i> EXPECT_DURATION "ly:duration?"
 337 %token <scm> EXPECT_SCM "scheme?"
 338 %token <scm> BACKUP "(backed-up?)"
 339 %token <scm> REPARSE "(reparsed?)"
 340 %token <i> EXPECT_MARKUP_LIST "markup-list?"
 341 %token <scm> EXPECT_OPTIONAL "optional?"
 342 /* After the last argument. */
 343 %token <i> EXPECT_NO_MORE_ARGS;
 344
 345 /* An artificial token for parsing embedded Lilypond */
 346 %token <i> EMBEDDED_LILY "#{"
 347
 348 %token <scm> BOOK_IDENTIFIER
 349 %token <scm> CHORDMODIFIER_PITCH
 350 %token <scm> CHORD_MODIFIER
 351 %token <scm> CHORD_REPETITION
 352 %token <scm> CONTEXT_DEF_IDENTIFIER
 353 %token <scm> CONTEXT_MOD_IDENTIFIER
 354 %token <scm> DRUM_PITCH
 355 %token <scm> PITCH_IDENTIFIER
 356 %token <scm> DURATION_IDENTIFIER
 357 %token <scm> EVENT_IDENTIFIER
 358 %token <scm> EVENT_FUNCTION
 359 %token <scm> FRACTION
 360 %token <scm> LYRICS_STRING
 361 %token <scm> LYRIC_ELEMENT
 362 %token <scm> LYRIC_MARKUP_IDENTIFIER
 363 %token <scm> MARKUP_FUNCTION
 364 %token <scm> MARKUP_LIST_FUNCTION
 365 %token <scm> MARKUP_IDENTIFIER
 366 %token <scm> MARKUPLIST_IDENTIFIER
 367 %token <scm> MUSIC_FUNCTION
 368 %token <scm> MUSIC_IDENTIFIER
 369 %token <scm> NOTENAME_PITCH
 370 %token <scm> NUMBER_IDENTIFIER
 371 %token <scm> OUTPUT_DEF_IDENTIFIER
 372 %token <scm> REAL
 373 %token <scm> RESTNAME
 374 %token <scm> SCM_FUNCTION
 375 %token <scm> SCM_IDENTIFIER
 376 %token <scm> SCM_TOKEN
 377 %token <scm> SCORE_IDENTIFIER
 378 %token <scm> STRING
 379 %token <scm> STRING_IDENTIFIER
 380 %token <scm> TONICNAME_PITCH
 381
 382
 383 %type <book> book_block
 384 %type <book> book_body
 385 %type <book> bookpart_block
 386 %type <book> bookpart_body
 387
 388 %type <i> bare_unsigned
 389 %type <scm> figured_bass_alteration
 390 %type <i> dots
 391 %type <i> exclamations
 392 %type <i> optional_rest
 393 %type <i> questions
 394 %type <i> script_dir
 395 %type <i> sub_quotes
 396 %type <i> sup_quotes
 397 %type <i> tremolo_type
 398
 399 /* Music */
 400 %type <scm> composite_music
 401 %type <scm> grouped_music_list
 402 %type <scm> braced_music_list
 403 %type <scm> closed_music
 404 %type <scm> music
 405 %type <scm> music_bare
 406 %type <scm> music_arg
 407 %type <scm> music_assign
 408 %type <scm> complex_music
 409 %type <scm> complex_music_prefix
 410 %type <scm> mode_changed_music
 411 %type <scm> repeated_music
 412 %type <scm> sequential_music
 413 %type <scm> simple_music
 414 %type <scm> simultaneous_music
 415 %type <scm> chord_body
 416 %type <scm> chord_body_element
 417 %type <scm> command_element
 418 %type <scm> command_event
 419 %type <scm> context_modification
 420 %type <scm> context_change
 421 %type <scm> direction_less_event
 422 %type <scm> direction_reqd_event
 423 %type <scm> embedded_lilypond
 424 %type <scm> event_chord
 425 %type <scm> fingering
 426 %type <scm> gen_text_def
 427 %type <scm> music_property_def
 428 %type <scm> note_chord_element
 429 %type <scm> post_event
 430 %type <scm> post_event_nofinger
 431 %type <scm> re_rhythmed_music
 432 %type <scm> simple_element
 433 %type <scm> simple_music_property_def
 434 %type <scm> start_symbol
 435 %type <scm> string_number_event
 436 %type <scm> tempo_event
 437
 438 %type <outputdef> output_def_body
 439 %type <outputdef> output_def_head
 440 %type <outputdef> output_def_head_with_mode_switch
 441 %type <outputdef> output_def
 442 %type <outputdef> paper_block
 443
 444 %type <scm> music_function_call
 445 %type <scm> music_list
 446 %type <scm> assignment_id
 447 %type <scm> bare_number
 448 %type <scm> bare_number_closed
 449 %type <scm> unsigned_number
 450 %type <scm> bass_figure
 451 %type <scm> figured_bass_modification
 452 %type <scm> br_bass_figure
 453 %type <scm> bass_number
 454 %type <scm> chord_body_elements
 455 %type <scm> chord_item
 456 %type <scm> chord_items
 457 %type <scm> chord_separator
 458 %type <scm> context_def_mod
 459 %type <scm> context_def_spec_block
 460 %type <scm> context_def_spec_body
 461 %type <scm> context_mod
 462 %type <scm> context_mod_list
 463 %type <scm> context_prop_spec
 464 %type <scm> direction_less_char
 465 %type <scm> duration_length
 466 %type <scm> embedded_scm
 467 %type <scm> embedded_scm_arg
 468 %type <scm> embedded_scm_arg_closed
 469 %type <scm> embedded_scm_bare
 470 %type <scm> embedded_scm_bare_arg
 471 %type <scm> embedded_scm_closed
 472 %type <scm> event_function_event
 473 %type <scm> figure_list
 474 %type <scm> figure_spec
 475 %type <scm> fraction
 476 %type <scm> full_markup
 477 %type <scm> full_markup_list
 478 %type <scm> function_arglist
 479 %type <scm> function_arglist_optional
 480 %type <scm> function_arglist_backup
 481 %type <scm> function_arglist_nonbackup
 482 %type <scm> function_arglist_skip
 483 %type <scm> function_arglist_bare
 484 %type <scm> function_arglist_closed
 485 %type <scm> function_arglist_closed_optional
 486 %type <scm> function_arglist_common
 487 %type <scm> function_arglist_common_lyric
 488 %type <scm> function_arglist_common_minus
 489 %type <scm> function_arglist_closed_common
 490 %type <scm> function_arglist_keep
 491 %type <scm> function_arglist_closed_keep
 492 %type <scm> identifier_init
 493 %type <scm> lilypond
 494 %type <scm> lilypond_header
 495 %type <scm> lilypond_header_body
 496 %type <scm> lyric_element
 497 %type <scm> lyric_element_arg
 498 %type <scm> lyric_element_music
 499 %type <scm> lyric_markup
 500 %type <scm> markup
 501 %type <scm> markup_braced_list
 502 %type <scm> markup_braced_list_body
 503 %type <scm> markup_composed_list
 504 %type <scm> markup_command_list
 505 %type <scm> markup_command_list_arguments
 506 %type <scm> markup_command_basic_arguments
 507 %type <scm> markup_head_1_item
 508 %type <scm> markup_head_1_list
 509 %type <scm> markup_list
 510 %type <scm> markup_top
 511 %type <scm> maybe_notemode_duration
 512 %type <scm> mode_changing_head
 513 %type <scm> mode_changing_head_with_context
 514 %type <scm> multiplied_duration
 515 %type <scm> music_function_event
 516 %type <scm> music_function_chord_body
 517 %type <scm> new_chord
 518 %type <scm> new_lyrics
 519 %type <scm> number_expression
 520 %type <scm> number_factor
 521 %type <scm> number_term
 522 %type <scm> octave_check
 523 %type <scm> optional_context_mod
 524 %type <scm> optional_id
 525 %type <scm> optional_notemode_duration
 526 %type <scm> pitch
 527 %type <scm> pitch_also_in_chords
 528 %type <scm> post_events
 529 %type <scm> property_operation
 530 %type <scm> property_path property_path_revved
 531 %type <scm> scalar
 532 %type <scm> scalar_closed
 533 %type <scm> scm_function_call
 534 %type <scm> scm_function_call_closed
 535 %type <scm> script_abbreviation
 536 %type <scm> simple_chord_elements
 537 %type <scm> simple_markup
 538 %type <scm> simple_string
 539 %type <scm> steno_duration
 540 %type <scm> steno_pitch
 541 %type <scm> steno_tonic_pitch
 542 %type <scm> step_number
 543 %type <scm> step_numbers
 544 %type <scm> string
 545 %type <scm> tempo_range
 546
 547 %type <score> score_block
 548 %type <score> score_body
 549
 550
 551 %left '-' '+'
 552
 553 /* We don't assign precedence to / and *, because we might need varied
 554 prec levels in different prods */
 555
 556 %left UNARY_MINUS
 557
 558 %%
 559
 560 start_symbol:
 561         lilypond
 562         | EMBEDDED_LILY {
 563                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 564                 parser->lexer_->push_note_state (alist_to_hashq (nn));
 565         } embedded_lilypond {
 566                 parser->lexer_->pop_state ();
 567                 parser->lexer_->set_identifier (ly_symbol2scm ("parseStringResult"), $3);
 568         }
 569         ;
 570
 571 lilypond:       /* empty */ { }
 572         | lilypond toplevel_expression {
 573         }
 574         | lilypond assignment {
 575         }
 576         | lilypond error {
 577                 parser->error_level_ = 1;
 578         }
 579         | lilypond INVALID      {
 580                 parser->error_level_ = 1;
 581         }
 582         ;
 583
 584
 585 toplevel_expression:
 586         lilypond_header {
 587                 parser->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 588         }
 589         | book_block {
 590                 Book *book = $1;
 591                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-book-handler");
 592                 scm_call_2 (proc, parser->self_scm (), book->self_scm ());
 593                 book->unprotect ();
 594         }
 595         | bookpart_block {
 596                 Book *bookpart = $1;
 597                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 598                 scm_call_2 (proc, parser->self_scm (), bookpart->self_scm ());
 599                 bookpart->unprotect ();
 600         }
 601         | score_block {
 602                 Score *score = $1;
 603
 604                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-score-handler");
 605                 scm_call_2 (proc, parser->self_scm (), score->self_scm ());
 606                 score->unprotect ();
 607         }
 608         | composite_music {
 609                 Music *music = unsmob_music ($1);
 610                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-music-handler");
 611                 scm_call_2 (proc, parser->self_scm (), music->self_scm ());
 612         }
 613         | full_markup {
 614                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 615                 scm_call_2 (proc, parser->self_scm (), scm_list_1 ($1));
 616         }
 617         | full_markup_list {
 618                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 619                 scm_call_2 (proc, parser->self_scm (), $1);
 620         }
 621         | output_def {
 622                 SCM id = SCM_EOL;
 623                 Output_def * od = $1;
 624
 625                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 626                         id = ly_symbol2scm ("$defaultpaper");
 627                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 628                         id = ly_symbol2scm ("$defaultmidi");
 629                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 630                         id = ly_symbol2scm ("$defaultlayout");
 631
 632                 parser->lexer_->set_identifier (id, od->self_scm ());
 633                 od->unprotect();
 634         }
 635         ;
 636
 637 embedded_scm_bare:
 638         SCM_TOKEN
 639         {
 640                 $$ = parser->lexer_->eval_scm ($1);
 641         }
 642         | SCM_IDENTIFIER
 643         ;
 644
 645 embedded_scm_bare_arg:
 646         embedded_scm_bare
 647         | STRING
 648         | STRING_IDENTIFIER
 649         | full_markup
 650         | full_markup_list
 651         | context_modification
 652         | score_block
 653         {
 654                 $$ = $1->self_scm ();
 655                 $1->unprotect ();
 656         }
 657         | context_def_spec_block
 658         | book_block
 659         {
 660                 $$ = $1->self_scm ();
 661                 $1->unprotect ();
 662         }
 663         | bookpart_block
 664         {
 665                 $$ = $1->self_scm ();
 666                 $1->unprotect ();
 667         }
 668         | output_def
 669         {
 670                 $$ = $1->self_scm ();
 671                 $1->unprotect ();
 672         }
 673         ;
 674
 675 /* The generic version may end in music, or not */
 676
 677 embedded_scm:
 678         embedded_scm_bare
 679         | scm_function_call
 680         ;
 681
 682 embedded_scm_arg:
 683         embedded_scm_bare_arg
 684         | scm_function_call
 685         | music_arg
 686         ;
 687
 688 scm_function_call:
 689         SCM_FUNCTION function_arglist {
 690                 $$ = MAKE_SYNTAX ("music-function", @$,
 691                                          $1, $2);
 692         }
 693         ;
 694
 695 embedded_lilypond:
 696         /* empty */
 697         {
 698                 $$ = MAKE_SYNTAX ("void-music", @$);
 699         }
 700         | identifier_init
 701         | music music music_list {
 702                 $$ = MAKE_SYNTAX ("sequential-music", @$,
 703                                   scm_cons2 ($1, $2, scm_reverse_x ($3, SCM_EOL)));
 704         }
 705         | error {
 706                 parser->error_level_ = 1;
 707         }
 708         | INVALID embedded_lilypond {
 709                 parser->error_level_ = 1;
 710         }
 711         ;
 712
 713
 714 lilypond_header_body:
 715         {
 716                 $$ = get_header (parser);
 717                 parser->lexer_->add_scope ($$);
 718         }
 719         | lilypond_header_body assignment  {
 720
 721         }
 722         ;
 723
 724 lilypond_header:
 725         HEADER '{' lilypond_header_body '}'     {
 726                 $$ = parser->lexer_->remove_scope ();
 727         }
 728         ;
 729
 730 /*
 731         DECLARATIONS
 732 */
 733 assignment_id:
 734         STRING          { $$ = $1; }
 735         | LYRICS_STRING { $$ = $1; }
 736         ;
 737
 738 assignment:
 739         assignment_id '=' identifier_init  {
 740                 parser->lexer_->set_identifier ($1, $3);
 741         }
 742         | assignment_id property_path '=' identifier_init {
 743                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 744                 parser->lexer_->set_identifier (path, $4);
 745         ;
 746 /*
 747  TODO: devise standard for protection in parser.
 748
 749   The parser stack lives on the C-stack, which means that
 750 all objects can be unprotected as soon as they're here.
 751
 752 */
 753         }
 754         | embedded_scm { }
 755         ;
 756
 757
 758 identifier_init:
 759         score_block {
 760                 $$ = $1->self_scm ();
 761                 $1->unprotect ();
 762         }
 763         | book_block {
 764                 $$ = $1->self_scm ();
 765                 $1->unprotect ();
 766         }
 767         | bookpart_block {
 768                 $$ = $1->self_scm ();
 769                 $1->unprotect ();
 770         }
 771         | output_def {
 772                 $$ = $1->self_scm ();
 773                 $1->unprotect ();
 774         }
 775         | context_def_spec_block {
 776                 $$ = $1;
 777         }
 778         | music_assign  {
 779                 $$ = $1;
 780         }
 781         | post_event_nofinger {
 782                 $$ = $1;
 783         }
 784         | number_expression {
 785                 $$ = $1;
 786         }
 787         | string {
 788                 $$ = $1;
 789         }
 790         | embedded_scm {
 791                 $$ = $1;
 792         }
 793         | full_markup {
 794                 $$ = $1;
 795         }
 796         | full_markup_list {
 797                 $$ = $1;
 798         }
 799         | context_modification {
 800                 $$ = $1;
 801         }
 802         ;
 803
 804 context_def_spec_block:
 805         CONTEXT '{' context_def_spec_body '}'
 806                 {
 807                 $$ = $3;
 808         }
 809         ;
 810
 811 context_def_spec_body:
 812         /**/ {
 813                 $$ = Context_def::make_scm ();
 814                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 815         }
 816         | CONTEXT_DEF_IDENTIFIER {
 817                 $$ = $1;
 818                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 819         }
 820         | context_def_spec_body embedded_scm {
 821                 if (Context_mod *cm = unsmob_context_mod ($2)) {
 822                         SCM p = cm->get_mods ();
 823                         Context_def*td = unsmob_context_def ($$);
 824
 825                         for (; scm_is_pair (p); p = scm_cdr (p)) {
 826                                 td->add_context_mod (scm_car (p));
 827                         }
 828                 } else {
 829                         parser->parser_error (@2, _ ("not a context mod"));
 830                 }
 831         }
 832         | context_def_spec_body context_mod {
 833                 unsmob_context_def ($$)->add_context_mod ($2);
 834         }
 835         | context_def_spec_body context_modification {
 836                 Context_def *td = unsmob_context_def ($$);
 837                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 838                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 839                     td->add_context_mod (scm_car (m));
 840                 }
 841         }
 842         ;
 843
 844
 845
 846 book_block:
 847         BOOK '{' book_body '}'  {
 848                 $$ = $3;
 849                 pop_paper (parser);
 850                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 851         }
 852         ;
 853
 854 /* FIXME:
 855    * Use 'handlers' like for toplevel-* stuff?
 856    * grok \layout and \midi?  */
 857 book_body:
 858         {
 859                 $$ = new Book;
 860                 init_papers (parser);
 861                 $$->origin ()->set_spot (@$);
 862                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (parser->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 863                 $$->paper_->unprotect ();
 864                 push_paper (parser, $$->paper_);
 865                 $$->header_ = parser->lexer_->lookup_identifier ("$defaultheader");
 866                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$->self_scm ());
 867         }
 868         | BOOK_IDENTIFIER {
 869                 $$ = unsmob_book ($1);
 870                 $$->protect ();
 871                 $$->origin ()->set_spot (@$);
 872                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 873         }
 874         | book_body paper_block {
 875                 $$->paper_ = $2;
 876                 $2->unprotect ();
 877                 set_paper (parser, $2);
 878         }
 879         | book_body bookpart_block {
 880                 Book *bookpart = $2;
 881                 SCM proc = parser->lexer_->lookup_identifier ("book-bookpart-handler");
 882                 scm_call_2 (proc, $$->self_scm (), bookpart->self_scm ());
 883                 bookpart->unprotect ();
 884         }
 885         | book_body score_block {
 886                 Score *score = $2;
 887                 SCM proc = parser->lexer_->lookup_identifier ("book-score-handler");
 888                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 889                 score->unprotect ();
 890         }
 891         | book_body composite_music {
 892                 Music *music = unsmob_music ($2);
 893                 SCM proc = parser->lexer_->lookup_identifier ("book-music-handler");
 894                 scm_call_3 (proc, parser->self_scm (), $$->self_scm (), music->self_scm ());
 895         }
 896         | book_body full_markup {
 897                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 898                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 899         }
 900         | book_body full_markup_list {
 901                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 902                 scm_call_2 (proc, $$->self_scm (), $2);
 903         }
 904         | book_body lilypond_header {
 905                 $$->header_ = $2;
 906         }
 907         | book_body embedded_scm { }
 908         | book_body error {
 909                 $$->paper_ = 0;
 910                 $$->scores_ = SCM_EOL;
 911                 $$->bookparts_ = SCM_EOL;
 912         }
 913         ;
 914
 915 bookpart_block:
 916         BOOKPART '{' bookpart_body '}' {
 917                 $$ = $3;
 918                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 919         }
 920         ;
 921
 922 bookpart_body:
 923         {
 924                 $$ = new Book;
 925                 $$->origin ()->set_spot (@$);
 926                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$->self_scm ());
 927         }
 928         | BOOK_IDENTIFIER {
 929                 $$ = unsmob_book ($1);
 930                 $$->protect ();
 931                 $$->origin ()->set_spot (@$);
 932                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 933         }
 934         | bookpart_body paper_block {
 935                 $$->paper_ = $2;
 936                 $2->unprotect ();
 937         }
 938         | bookpart_body score_block {
 939                 Score *score = $2;
 940                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-score-handler");
 941                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 942                 score->unprotect ();
 943         }
 944         | bookpart_body composite_music {
 945                 Music *music = unsmob_music ($2);
 946                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-music-handler");
 947                 scm_call_3 (proc, parser->self_scm (), $$->self_scm (), music->self_scm ());
 948         }
 949         | bookpart_body full_markup {
 950                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 951                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 952         }
 953         | bookpart_body full_markup_list {
 954                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 955                 scm_call_2 (proc, $$->self_scm (), $2);
 956         }
 957         | bookpart_body lilypond_header {
 958                 $$->header_ = $2;
 959         }
 960         | bookpart_body embedded_scm { }
 961         | bookpart_body error {
 962                 $$->paper_ = 0;
 963                 $$->scores_ = SCM_EOL;
 964         }
 965         ;
 966
 967 score_block:
 968         SCORE '{' score_body '}'        {
 969                 $$ = $3;
 970         }
 971         ;
 972
 973 score_body:
 974         music {
 975                 SCM m = $1;
 976                 SCM scorify = ly_lily_module_constant ("scorify-music");
 977                 SCM score = scm_call_2 (scorify, m, parser->self_scm ());
 978
 979                 // pass ownernship to C++ again.
 980                 $$ = unsmob_score (score);
 981                 $$->protect ();
 982                 $$->origin ()->set_spot (@$);
 983         }
 984         | SCORE_IDENTIFIER {
 985                 $$ = unsmob_score ($1);
 986                 $$->protect ();
 987                 $$->origin ()->set_spot (@$);
 988         }
 989         | score_body lilypond_header    {
 990                 $$->set_header ($2);
 991         }
 992         | score_body output_def {
 993                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 994                 {
 995                         parser->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 996
 997                 }
 998                 else
 999                 {
1000                         $$->add_output_def ($2);
1001                 }
1002                 $2->unprotect ();
1003         }
1004         | score_body error {
1005                 $$->error_found_ = true;
1006         }
1007         ;
1008
1009
1010 /*
1011         OUTPUT DEF
1012 */
1013
1014 paper_block:
1015         output_def {
1016                 $$ = $1;
1017                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
1018                 {
1019                         parser->parser_error (@1, _ ("need \\paper for paper block"));
1020                         $1->unprotect ();
1021                         $$ = get_paper (parser);
1022                 }
1023         }
1024         ;
1025
1026
1027 output_def:
1028         output_def_body '}' {
1029                 $$ = $1;
1030
1031                 parser->lexer_->remove_scope ();
1032                 parser->lexer_->pop_state ();
1033         }
1034         ;
1035
1036 output_def_head:
1037         PAPER {
1038                 $$ = get_paper (parser);
1039                 $$->input_origin_ = @$;
1040                 parser->lexer_->add_scope ($$->scope_);
1041         }
1042         | MIDI    {
1043                 Output_def *p = get_midi (parser);
1044                 $$ = p;
1045                 parser->lexer_->add_scope (p->scope_);
1046         }
1047         | LAYOUT        {
1048                 Output_def *p = get_layout (parser);
1049
1050                 parser->lexer_->add_scope (p->scope_);
1051                 $$ = p;
1052         }
1053         ;
1054
1055 output_def_head_with_mode_switch:
1056         output_def_head {
1057                 parser->lexer_->push_initial_state ();
1058                 $$ = $1;
1059         }
1060         ;
1061
1062 output_def_body:
1063         output_def_head_with_mode_switch '{' {
1064                 $$ = $1;
1065                 $$->input_origin_.set_spot (@$);
1066         }
1067         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
1068                 $1->unprotect ();
1069
1070                 Output_def *o = unsmob_output_def ($3);
1071                 o->input_origin_.set_spot (@$);
1072                 $$ = o;
1073                 $$->protect ();
1074                 parser->lexer_->remove_scope ();
1075                 parser->lexer_->add_scope (o->scope_);
1076         }
1077         | output_def_body assignment  {
1078
1079         }
1080         | output_def_body context_def_spec_block        {
1081                 assign_context_def ($$, $2);
1082         }
1083         | output_def_body error {
1084
1085         }
1086         ;
1087
1088 tempo_event:
1089         TEMPO steno_duration '=' tempo_range    {
1090                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_EOL, $2, $4);
1091         }
1092         | TEMPO scalar_closed steno_duration '=' tempo_range    {
1093                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
1094         }
1095         | TEMPO scalar {
1096                 $$ = MAKE_SYNTAX ("tempo", @$, $2);
1097         }
1098         ;
1099
1100 /*
1101 The representation of a  list is reversed to have efficient append.  */
1102
1103 music_list:
1104         /* empty */ {
1105                 $$ = SCM_EOL;
1106         }
1107         | music_list music {
1108                 $$ = scm_cons ($2, $1);
1109         }
1110         | music_list embedded_scm {
1111
1112         }
1113         | music_list error {
1114                 Music *m = MY_MAKE_MUSIC("Music", @$);
1115                 // ugh. code dup
1116                 m->set_property ("error-found", SCM_BOOL_T);
1117                 $$ = scm_cons (m->self_scm (), $1);
1118                 m->unprotect (); /* UGH */
1119         }
1120         ;
1121
1122 braced_music_list:
1123         '{' music_list '}'
1124         {
1125                 $$ = scm_reverse_x ($2, SCM_EOL);
1126         }
1127         ;
1128
1129 music:  music_arg
1130         | lyric_element_music
1131         ;
1132
1133 music_arg:
1134         simple_music
1135         {
1136                 if (unsmob_pitch ($1)) {
1137                         Music *n = MY_MAKE_MUSIC ("NoteEvent", @1);
1138                         n->set_property ("pitch", $1);
1139                         n->set_property ("duration",
1140                                          parser->default_duration_.smobbed_copy ());
1141                         $$ = n->unprotect ();
1142                 }
1143         }
1144         | composite_music %prec COMPOSITE
1145         ;
1146
1147 music_assign:
1148         simple_music
1149         | composite_music %prec COMPOSITE
1150         | lyric_element_music
1151         ;
1152
1153 repeated_music:
1154         REPEAT simple_string unsigned_number music
1155         {
1156                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, SCM_EOL);
1157         }
1158         | REPEAT simple_string unsigned_number music ALTERNATIVE braced_music_list
1159         {
1160                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $6);
1161         }
1162         ;
1163
1164 sequential_music:
1165         SEQUENTIAL braced_music_list {
1166                 $$ = MAKE_SYNTAX ("sequential-music", @$, $2);
1167         }
1168         | braced_music_list {
1169                 $$ = MAKE_SYNTAX ("sequential-music", @$, $1);
1170         }
1171         ;
1172
1173 simultaneous_music:
1174         SIMULTANEOUS braced_music_list {
1175                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, $2);
1176         }
1177         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1178                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($2, SCM_EOL));
1179         }
1180         ;
1181
1182 simple_music:
1183         event_chord
1184         | music_property_def
1185         | context_change
1186         ;
1187
1188 context_modification:
1189         WITH { parser->lexer_->push_initial_state (); } '{' context_mod_list '}'
1190         {
1191                 parser->lexer_->pop_state ();
1192                 $$ = $4;
1193         }
1194         | WITH CONTEXT_MOD_IDENTIFIER
1195         {
1196                 $$ = $2;
1197         }
1198         | CONTEXT_MOD_IDENTIFIER
1199         {
1200                 $$ = $1;
1201         }
1202         | WITH embedded_scm_closed
1203         {
1204                 if (unsmob_context_mod ($2))
1205                         $$ = $2;
1206                 else {
1207                         parser->parser_error (@2, _ ("not a context mod"));
1208                         $$ = Context_mod ().smobbed_copy ();
1209                 }
1210         }
1211         ;
1212
1213 optional_context_mod:
1214         /**/ {
1215             $$ = SCM_EOL;
1216         }
1217         | context_modification
1218         {
1219               $$ = $1;
1220         }
1221         ;
1222
1223 context_mod_list:
1224         /**/ {
1225             $$ = Context_mod ().smobbed_copy ();
1226         }
1227         | context_mod_list context_mod  {
1228                  unsmob_context_mod ($1)->add_context_mod ($2);
1229         }
1230         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1231                  Context_mod *md = unsmob_context_mod ($2);
1232                  if (md)
1233                      unsmob_context_mod ($1)->add_context_mods (md->get_mods ());
1234         }
1235         | context_mod_list embedded_scm {
1236                 Context_mod *md = unsmob_context_mod ($2);
1237                 if (md)
1238                         unsmob_context_mod ($1)->add_context_mods (md->get_mods ());
1239                 else
1240                         parser->parser_error (@2, _ ("not a context mod"));
1241         }
1242         ;
1243
1244 composite_music:
1245         complex_music
1246         | music_bare
1247         ;
1248
1249 /* Music that can be parsed without lookahead */
1250 closed_music:
1251         music_bare
1252         | complex_music_prefix closed_music
1253         {
1254                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1255         }
1256         ;
1257
1258 music_bare:
1259         mode_changed_music
1260         | MUSIC_IDENTIFIER
1261         | grouped_music_list
1262         ;
1263
1264 grouped_music_list:
1265         simultaneous_music              { $$ = $1; }
1266         | sequential_music              { $$ = $1; }
1267         ;
1268
1269 /* An argument list. If a function \foo expects scm scm pitch, then the lexer expands \foo into the token sequence:
1270  MUSIC_FUNCTION EXPECT_PITCH EXPECT_SCM EXPECT_SCM EXPECT_NO_MORE_ARGS
1271 and this rule returns the reversed list of arguments. */
1272
1273 function_arglist_skip:
1274         function_arglist_common
1275         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_skip
1276         {
1277                 $$ = scm_cons ($1, $3);
1278         } %prec FUNCTION_ARGLIST
1279         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_skip
1280         {
1281                 $$ = scm_cons ($1, $3);
1282         } %prec FUNCTION_ARGLIST
1283         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip
1284         {
1285                 $$ = scm_cons ($1, $3);
1286         } %prec FUNCTION_ARGLIST
1287         ;
1288
1289
1290 function_arglist_nonbackup:
1291         EXPECT_OPTIONAL EXPECT_PITCH function_arglist pitch_also_in_chords {
1292                 $$ = scm_cons ($4, $3);
1293         }
1294         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed duration_length {
1295                 $$ = scm_cons ($4, $3);
1296         }
1297         | EXPECT_OPTIONAL EXPECT_SCM function_arglist embedded_scm_arg_closed
1298         {
1299                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1300         }
1301         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed bare_number_closed
1302         {
1303                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1304         }
1305         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed FRACTION
1306         {
1307                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1308         }
1309         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed post_event_nofinger
1310         {
1311                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1312         }
1313         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed '-' UNSIGNED
1314         {
1315                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1316                 if (scm_is_true (scm_call_1 ($2, n)))
1317                         $$ = scm_cons (n, $3);
1318                 else {
1319                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1320                         t->set_property ("digit", $5);
1321                         $$ = t->unprotect ();
1322                         if (scm_is_true (scm_call_1 ($2, $$)))
1323                                 $$ = scm_cons ($$, $3);
1324                         else
1325                                 $$ = check_scheme_arg (parser, @4, n, $3, $2);
1326                 }
1327
1328         }
1329         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed '-' REAL
1330         {
1331                 $$ = check_scheme_arg (parser, @4,
1332                                        scm_difference ($5, SCM_UNDEFINED),
1333                                        $3, $2);
1334         }
1335         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed '-' NUMBER_IDENTIFIER
1336         {
1337                 $$ = check_scheme_arg (parser, @4,
1338                                        scm_difference ($5, SCM_UNDEFINED),
1339                                        $3, $2);
1340         }
1341         ;
1342
1343
1344 function_arglist_keep:
1345         function_arglist_common
1346         | function_arglist_backup
1347         ;
1348
1349 function_arglist_closed_keep:
1350         function_arglist_closed_common
1351         | function_arglist_backup
1352         ;
1353
1354 function_arglist_backup:
1355         EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep embedded_scm_arg_closed
1356         {
1357                 if (scm_is_true (scm_call_1 ($2, $4)))
1358                 {
1359                         $$ = scm_cons ($4, $3);
1360                 } else {
1361                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1362                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
1363                 }
1364         }
1365         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep post_event_nofinger
1366         {
1367                 if (scm_is_true (scm_call_1 ($2, $4)))
1368                 {
1369                         $$ = scm_cons ($4, $3);
1370                 } else {
1371                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1372                         MYBACKUP (EVENT_IDENTIFIER, $4, @4);
1373                 }
1374         }
1375         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep lyric_element
1376         {
1377                 // There is no point interpreting a lyrics string as
1378                 // an event, since we don't allow music possibly
1379                 // followed by durations or postevent into closed
1380                 // music, and we only accept closed music in optional
1381                 // arguments at the moment.  If this changes, more
1382                 // complex schemes might become interesting here as
1383                 // well: see how we do this at the mandatory argument
1384                 // point.
1385                 if (scm_is_true (scm_call_1 ($2, $4)))
1386                         $$ = scm_cons ($4, $3);
1387                 else {
1388                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1389                         MYBACKUP (LYRICS_STRING, $4, @4);
1390                 }
1391         }
1392         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep UNSIGNED
1393         {
1394                 if (scm_is_true (scm_call_1 ($2, $4)))
1395                 {
1396                         $$ = $3;
1397                         MYREPARSE (@4, $2, UNSIGNED, $4);
1398                 } else {
1399                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1400                         MYBACKUP (UNSIGNED, $4, @4);
1401                 }
1402         }
1403         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep REAL
1404         {
1405                 if (scm_is_true (scm_call_1 ($2, $4)))
1406                 {
1407                         $$ = $3;
1408                         MYREPARSE (@4, $2, REAL, $4);
1409                 } else {
1410                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1411                         MYBACKUP (REAL, $4, @4);
1412                 }
1413         }
1414         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep NUMBER_IDENTIFIER
1415         {
1416                 if (scm_is_true (scm_call_1 ($2, $4)))
1417                 {
1418                         $$ = scm_cons ($4, $3);
1419                 } else {
1420                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1421                         MYBACKUP (NUMBER_IDENTIFIER, $4, @4);
1422                 }
1423         }
1424         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep FRACTION
1425         {
1426                 if (scm_is_true (scm_call_1 ($2, $4)))
1427                 {
1428                         $$ = scm_cons ($4, $3);
1429                 } else {
1430                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1431                         MYBACKUP (FRACTION, $4, @4);
1432                 }
1433         }
1434         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep '-' UNSIGNED
1435         {
1436                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1437                 if (scm_is_true (scm_call_1 ($2, n))) {
1438                         $$ = $3;
1439                         MYREPARSE (@5, $2, REAL, n);
1440                 } else {
1441                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1442                         t->set_property ("digit", $5);
1443                         $$ = t->unprotect ();
1444                         if (scm_is_true (scm_call_1 ($2, $$)))
1445                                 $$ = scm_cons ($$, $3);
1446                         else {
1447                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1448                                 MYBACKUP (UNSIGNED, $5, @5);
1449                                 parser->lexer_->push_extra_token ('-');
1450                         }
1451                 }
1452
1453         }
1454         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep '-' REAL
1455         {
1456                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1457                 if (scm_is_true (scm_call_1 ($2, n))) {
1458                         MYREPARSE (@5, $2, REAL, n);
1459                         $$ = $3;
1460                 } else {
1461                         MYBACKUP (REAL, n, @5);
1462                 }
1463         }
1464         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep '-' NUMBER_IDENTIFIER
1465         {
1466                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1467                 if (scm_is_true (scm_call_1 ($2, n))) {
1468                         $$ = scm_cons (n, $3);
1469                 } else {
1470                         MYBACKUP (NUMBER_IDENTIFIER, n, @5);
1471                 }
1472         }
1473         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_keep pitch_also_in_chords
1474         {
1475                 $$ = scm_cons ($4, $3);
1476         }
1477         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_keep duration_length
1478         {
1479                 $$ = scm_cons ($4, $3);
1480         }
1481         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup BACKUP
1482         {
1483                 $$ = scm_cons ($1, $3);
1484                 MYBACKUP(0, SCM_UNDEFINED, @3);
1485         }
1486         | function_arglist_backup REPARSE embedded_scm_arg_closed
1487         {
1488                 $$ = check_scheme_arg (parser, @3,
1489                                        $3, $1, $2);
1490         }
1491         | function_arglist_backup REPARSE bare_number
1492         {
1493                 $$ = check_scheme_arg (parser, @3,
1494                                        $3, $1, $2);
1495         }
1496         | function_arglist_backup REPARSE fraction
1497         {
1498                 $$ = check_scheme_arg (parser, @3,
1499                                        $3, $1, $2);
1500         }
1501         ;
1502
1503 function_arglist:
1504         function_arglist_common
1505         | function_arglist_nonbackup
1506         ;
1507
1508 function_arglist_common:
1509         function_arglist_bare
1510         | EXPECT_SCM function_arglist_optional embedded_scm_arg
1511         {
1512                 $$ = check_scheme_arg (parser, @3,
1513                                        $3, $2, $1);
1514         }
1515         | EXPECT_SCM function_arglist_closed_optional bare_number
1516         {
1517                 $$ = check_scheme_arg (parser, @3,
1518                                        $3, $2, $1);
1519         }
1520         | EXPECT_SCM function_arglist_closed_optional fraction
1521         {
1522                 $$ = check_scheme_arg (parser, @3,
1523                                        $3, $2, $1);
1524         }
1525         | EXPECT_SCM function_arglist_closed_optional post_event_nofinger
1526         {
1527                 $$ = check_scheme_arg (parser, @3,
1528                                        $3, $2, $1);
1529         }
1530         | function_arglist_common_minus
1531         | function_arglist_common_lyric
1532         ;
1533
1534 function_arglist_common_lyric:
1535         EXPECT_SCM function_arglist_optional lyric_element
1536         {
1537                 // We check how the predicate thinks about a lyrics
1538                 // event or about a markup.  If it accepts neither, we
1539                 // backup the original token.  Otherwise we commit to
1540                 // taking the token.  Depending on what the predicate
1541                 // is willing to accept, we interpret as a string, as
1542                 // a lyric event, or ambiguously (meaning that if
1543                 // something looking like a duration or post event
1544                 // follows, we take the event, otherwise the string).
1545                 SCM lyric_event = MAKE_SYNTAX ("lyric-event", @3, $3,
1546                                                parser->default_duration_.smobbed_copy ());
1547                 if (scm_is_true (scm_call_1 ($1, $3)))
1548                         if (scm_is_true (scm_call_1 ($1, lyric_event)))
1549                         {
1550                                 $$ = $2;
1551                                 MYREPARSE (@3, $1, LYRICS_STRING, $3);
1552                         } else {
1553                                 $$ = scm_cons ($3, $2);
1554                         }
1555                 else if (scm_is_true (scm_call_1 ($1, lyric_event)))
1556                 {
1557                         $$ = $2;
1558                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
1559                 } else {
1560                         // This is going to flag a syntax error, we
1561                         // know the predicate to be false.
1562                         check_scheme_arg (parser, @3,
1563                                           $3, $2, $1);
1564                 }
1565         }
1566         | function_arglist_common_lyric REPARSE lyric_element_arg
1567         {
1568                 // This should never be false
1569                 $$ = check_scheme_arg (parser, @3,
1570                                        $3, $1, $2);
1571         }
1572         ;
1573
1574 function_arglist_common_minus:
1575         EXPECT_SCM function_arglist_closed_optional '-' UNSIGNED
1576         {
1577                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1578                 if (scm_is_true (scm_call_1 ($1, n))) {
1579                         $$ = $2;
1580                         MYREPARSE (@4, $1, REAL, n);
1581                 } else {
1582                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @4);
1583                         t->set_property ("digit", $4);
1584                         $$ = t->unprotect ();
1585                         if (scm_is_true (scm_call_1 ($1, $$)))
1586                                 $$ = scm_cons ($$, $2);
1587                         else
1588                                 $$ = check_scheme_arg (parser, @3, n, $2, $1);
1589                 }
1590
1591         }
1592         | EXPECT_SCM function_arglist_closed_optional '-' REAL
1593         {
1594                 $$ = $2;
1595                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1596                 MYREPARSE (@4, $1, REAL, n);
1597         }
1598         | EXPECT_SCM function_arglist_closed_optional '-' NUMBER_IDENTIFIER
1599         {
1600                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1601                 $$ = check_scheme_arg (parser, @4, n, $2, $1);
1602         }
1603         | function_arglist_common_minus REPARSE bare_number
1604         {
1605                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1606         }
1607         ;
1608
1609 function_arglist_closed:
1610         function_arglist_closed_common
1611         | function_arglist_nonbackup
1612         ;
1613
1614 function_arglist_closed_common:
1615         function_arglist_bare
1616         | EXPECT_SCM function_arglist_optional embedded_scm_arg_closed
1617         {
1618                 $$ = check_scheme_arg (parser, @3,
1619                                        $3, $2, $1);
1620         }
1621         | EXPECT_SCM function_arglist_closed_optional bare_number
1622         {
1623                 $$ = check_scheme_arg (parser, @3,
1624                                        $3, $2, $1);
1625         }
1626         | EXPECT_SCM function_arglist_closed_optional '-' UNSIGNED
1627         {
1628                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1629                 if (scm_is_true (scm_call_1 ($1, n))) {
1630                         $$ = scm_cons (n, $2);
1631                 } else {
1632                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @4);
1633                         t->set_property ("digit", $4);
1634                         $$ = t->unprotect ();
1635                         if (scm_is_true (scm_call_1 ($1, $$)))
1636                                 $$ = scm_cons ($$, $2);
1637                         else
1638                                 $$ = check_scheme_arg (parser, @3, n, $2, $1);
1639                 }
1640
1641         }
1642         | EXPECT_SCM function_arglist_closed_optional '-' REAL
1643         {
1644                 $$ = check_scheme_arg (parser, @3,
1645                                        scm_difference ($4, SCM_UNDEFINED),
1646                                        $2, $1);
1647         }
1648         | EXPECT_SCM function_arglist_closed_optional '-' NUMBER_IDENTIFIER
1649         {
1650                 $$ = check_scheme_arg (parser, @3,
1651                                        scm_difference ($4, SCM_UNDEFINED),
1652                                        $2, $1);
1653         }
1654         | EXPECT_SCM function_arglist_closed_optional post_event_nofinger
1655         {
1656                 $$ = check_scheme_arg (parser, @3,
1657                                        $3, $2, $1);
1658         }
1659         | EXPECT_SCM function_arglist_closed_optional fraction
1660         {
1661                 $$ = check_scheme_arg (parser, @3,
1662                                        $3, $2, $1);
1663         }
1664         | EXPECT_SCM function_arglist_optional lyric_element
1665         {
1666                 $$ = check_scheme_arg (parser, @3,
1667                                        $3, $2, $1);
1668         }
1669         ;
1670
1671 function_arglist_optional:
1672         function_arglist_keep %prec FUNCTION_ARGLIST
1673         | function_arglist_backup BACKUP
1674         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_optional
1675         {
1676                 $$ = scm_cons ($1, $3);
1677         }
1678         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_optional
1679         {
1680                 $$ = scm_cons ($1, $3);
1681         }
1682         ;
1683
1684 function_arglist_closed_optional:
1685         function_arglist_closed_keep %prec FUNCTION_ARGLIST
1686         | function_arglist_backup BACKUP
1687         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_closed_optional
1688         {
1689                 $$ = scm_cons ($1, $3);
1690         }
1691         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_optional
1692         {
1693                 $$ = scm_cons ($1, $3);
1694         }
1695         ;
1696
1697 embedded_scm_closed:
1698         embedded_scm_bare
1699         | scm_function_call_closed
1700         ;
1701
1702 embedded_scm_arg_closed:
1703         embedded_scm_bare_arg
1704         | scm_function_call_closed
1705         | closed_music
1706         ;
1707
1708 scm_function_call_closed:
1709         SCM_FUNCTION function_arglist_closed {
1710                 $$ = MAKE_SYNTAX ("music-function", @$,
1711                                          $1, $2);
1712         } %prec FUNCTION_ARGLIST
1713         ;
1714
1715 function_arglist_bare:
1716         EXPECT_NO_MORE_ARGS {
1717                 $$ = SCM_EOL;
1718         }
1719         | EXPECT_PITCH function_arglist_optional pitch_also_in_chords {
1720                 $$ = scm_cons ($3, $2);
1721         }
1722         | EXPECT_DURATION function_arglist_closed_optional duration_length {
1723                 $$ = scm_cons ($3, $2);
1724         }
1725         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_skip DEFAULT {
1726                 $$ = scm_cons ($1, $3);
1727         }
1728         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_skip DEFAULT {
1729                 $$ = scm_cons ($1, $3);
1730         }
1731         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip DEFAULT {
1732                 $$ = scm_cons ($1, $3);
1733         }
1734         ;
1735
1736 music_function_call:
1737         MUSIC_FUNCTION function_arglist {
1738                 $$ = MAKE_SYNTAX ("music-function", @$,
1739                                          $1, $2);
1740         }
1741         ;
1742
1743
1744 optional_id:
1745         /**/ { $$ = SCM_EOL; }
1746         | '=' simple_string {
1747                 $$ = $2;
1748         }
1749         ;
1750
1751 complex_music:
1752         music_function_call
1753         | repeated_music                { $$ = $1; }
1754         | re_rhythmed_music     { $$ = $1; }
1755         | complex_music_prefix music
1756         {
1757                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1758         }
1759         ;
1760
1761 complex_music_prefix:
1762         CONTEXT simple_string optional_id optional_context_mod {
1763                 Context_mod *ctxmod = unsmob_context_mod ($4);
1764                 SCM mods = SCM_EOL;
1765                 if (ctxmod)
1766                         mods = ctxmod->get_mods ();
1767                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_F);
1768         }
1769         | NEWCONTEXT simple_string optional_id optional_context_mod {
1770                 Context_mod *ctxmod = unsmob_context_mod ($4);
1771                 SCM mods = SCM_EOL;
1772                 if (ctxmod)
1773                         mods = ctxmod->get_mods ();
1774                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_T);
1775         }
1776         ;
1777
1778 mode_changed_music:
1779         mode_changing_head grouped_music_list {
1780                 if ($1 == ly_symbol2scm ("chords"))
1781                 {
1782                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1783                 }
1784                 else
1785                 {
1786                   $$ = $2;
1787                 }
1788                 parser->lexer_->pop_state ();
1789         }
1790         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1791                 Context_mod *ctxmod = unsmob_context_mod ($2);
1792                 SCM mods = SCM_EOL;
1793                 if (ctxmod)
1794                         mods = ctxmod->get_mods ();
1795                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, mods, SCM_BOOL_T, $3);
1796                 if ($1 == ly_symbol2scm ("ChordNames"))
1797                 {
1798                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1799                 }
1800                 parser->lexer_->pop_state ();
1801         }
1802         ;
1803
1804 mode_changing_head:
1805         NOTEMODE {
1806                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
1807                 parser->lexer_->push_note_state (alist_to_hashq (nn));
1808
1809                 $$ = ly_symbol2scm ("notes");
1810         }
1811         | DRUMMODE
1812                 {
1813                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
1814                 parser->lexer_->push_note_state (alist_to_hashq (nn));
1815
1816                 $$ = ly_symbol2scm ("drums");
1817         }
1818         | FIGUREMODE {
1819                 parser->lexer_->push_figuredbass_state ();
1820
1821                 $$ = ly_symbol2scm ("figures");
1822         }
1823         | CHORDMODE {
1824                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
1825                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1826                 nn = parser->lexer_->lookup_identifier ("pitchnames");
1827                 parser->lexer_->push_chord_state (alist_to_hashq (nn));
1828                 $$ = ly_symbol2scm ("chords");
1829
1830         }
1831         | LYRICMODE
1832                 { parser->lexer_->push_lyric_state ();
1833                 $$ = ly_symbol2scm ("lyrics");
1834         }
1835         ;
1836
1837 mode_changing_head_with_context:
1838         DRUMS {
1839                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
1840                 parser->lexer_->push_note_state (alist_to_hashq (nn));
1841
1842                 $$ = ly_symbol2scm ("DrumStaff");
1843         }
1844         | FIGURES {
1845                 parser->lexer_->push_figuredbass_state ();
1846
1847                 $$ = ly_symbol2scm ("FiguredBass");
1848         }
1849         | CHORDS {
1850                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
1851                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1852                 nn = parser->lexer_->lookup_identifier ("pitchnames");
1853                 parser->lexer_->push_chord_state (alist_to_hashq (nn));
1854                 $$ = ly_symbol2scm ("ChordNames");
1855         }
1856         | LYRICS
1857                 { parser->lexer_->push_lyric_state ();
1858                 $$ = ly_symbol2scm ("Lyrics");
1859         }
1860         ;
1861
1862 new_lyrics:
1863         ADDLYRICS { parser->lexer_->push_lyric_state (); }
1864         /*cont */
1865         composite_music {
1866         /* Can also use music at the expensive of two S/Rs similar to
1867            \repeat \alternative */
1868                 parser->lexer_->pop_state ();
1869
1870                 $$ = scm_cons ($3, SCM_EOL);
1871         }
1872         | new_lyrics ADDLYRICS {
1873                 parser->lexer_->push_lyric_state ();
1874         } composite_music {
1875                 parser->lexer_->pop_state ();
1876                 $$ = scm_cons ($4, $1);
1877         }
1878         ;
1879
1880 re_rhythmed_music:
1881         composite_music new_lyrics {
1882                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1883         } %prec COMPOSITE
1884         | LYRICSTO simple_string {
1885                 parser->lexer_->push_lyric_state ();
1886         } music {
1887                 parser->lexer_->pop_state ();
1888                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1889         }
1890         ;
1891
1892 context_change:
1893         CHANGE STRING '=' STRING  {
1894                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1895         }
1896         ;
1897
1898
1899 property_path_revved:
1900         embedded_scm_closed {
1901                 $$ = scm_cons ($1, SCM_EOL);
1902         }
1903         | property_path_revved embedded_scm_closed {
1904                 $$ = scm_cons ($2, $1);
1905         }
1906         ;
1907
1908 property_path:
1909         property_path_revved  {
1910                 $$ = scm_reverse_x ($1, SCM_EOL);
1911         }
1912         ;
1913
1914 property_operation:
1915         STRING '=' scalar {
1916                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1917                         scm_string_to_symbol ($1), $3);
1918         }
1919         | UNSET simple_string {
1920                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1921                         scm_string_to_symbol ($2));
1922         }
1923         | OVERRIDE simple_string property_path '=' scalar {
1924                 $$ = scm_append (scm_list_2 (scm_list_3 (ly_symbol2scm ("push"),
1925                                                         scm_string_to_symbol ($2), $5),
1926                                              $3));
1927         }
1928         | REVERT simple_string embedded_scm {
1929                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1930                         scm_string_to_symbol ($2), $3);
1931         }
1932         ;
1933
1934 context_def_mod:
1935         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1936         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1937
1938         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1939         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1940         | DENIES { $$ = ly_symbol2scm ("denies"); }
1941
1942         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1943         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1944         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1945         | NAME { $$ = ly_symbol2scm ("context-name"); }
1946         ;
1947
1948 context_mod:
1949         property_operation { $$ = $1; }
1950         | context_def_mod STRING {
1951                 $$ = scm_list_2 ($1, $2);
1952         }
1953         | context_def_mod embedded_scm
1954         {
1955                 if (!scm_is_string ($2)
1956                     && ly_symbol2scm ("consists") != $1
1957                     && ly_symbol2scm ("remove") != $1)
1958                 {
1959                         $$ = SCM_EOL;
1960                         parser->parser_error (@1, _ ("only \\consists and \\remove take non-string argument."));
1961                 }
1962                 else
1963                 {
1964                         $$ = scm_list_2 ($1, $2);
1965                 }
1966         }
1967         ;
1968
1969 context_prop_spec:
1970         simple_string {
1971                 if (!is_regular_identifier ($1))
1972                 {
1973                         @$.error (_("Grob name should be alphanumeric"));
1974                 }
1975
1976                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1977                         scm_string_to_symbol ($1));
1978         }
1979         | simple_string '.' simple_string {
1980                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1981                         scm_string_to_symbol ($3));
1982         }
1983         ;
1984
1985 simple_music_property_def:
1986         OVERRIDE context_prop_spec property_path '=' scalar {
1987                 $$ = scm_append (scm_list_2 (scm_list_n (scm_car ($2),
1988                                 ly_symbol2scm ("OverrideProperty"),
1989                                 scm_cadr ($2),
1990                                 $5, SCM_UNDEFINED),
1991                                 $3));
1992         }
1993         | REVERT context_prop_spec embedded_scm {
1994                 $$ = scm_list_4 (scm_car ($2),
1995                         ly_symbol2scm ("RevertProperty"),
1996                         scm_cadr ($2),
1997                         $3);
1998         }
1999         | SET context_prop_spec '=' scalar {
2000                 $$ = scm_list_4 (scm_car ($2),
2001                         ly_symbol2scm ("PropertySet"),
2002                         scm_cadr ($2),
2003                         $4);
2004         }
2005         | UNSET context_prop_spec {
2006                 $$ = scm_list_3 (scm_car ($2),
2007                         ly_symbol2scm ("PropertyUnset"),
2008                         scm_cadr ($2));
2009         }
2010         ;
2011
2012 music_property_def:
2013         simple_music_property_def {
2014                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons2 (parser->self_scm (), make_input (@$), $1));
2015         }
2016         ;
2017
2018 string:
2019         STRING {
2020                 $$ = $1;
2021         }
2022         | STRING_IDENTIFIER {
2023                 $$ = $1;
2024         }
2025         | string '+' string {
2026                 $$ = scm_string_append (scm_list_2 ($1, $3));
2027         }
2028         ;
2029
2030 simple_string: STRING {
2031                 $$ = $1;
2032         }
2033         | LYRICS_STRING {
2034                 $$ = $1;
2035         }
2036         | STRING_IDENTIFIER {
2037                 $$ = $1;
2038         }
2039         ;
2040
2041 scalar:
2042         embedded_scm_arg
2043         | bare_number
2044         | lyric_element
2045         ;
2046
2047 scalar_closed:
2048         embedded_scm_arg_closed
2049         | bare_number
2050         | lyric_element
2051         ;
2052
2053
2054 event_chord:
2055         simple_element post_events {
2056                 // Let the rhythmic music iterator sort this mess out.
2057                 if (scm_is_pair ($2)) {
2058                         if (unsmob_pitch ($1)) {
2059                                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @1);
2060                                 n->set_property ("pitch", $1);
2061                                 n->set_property ("duration",
2062                                                  parser->default_duration_.smobbed_copy ());
2063                                 $$ = n->unprotect ();
2064                         }
2065                         unsmob_music ($$)->set_property ("articulations",
2066                                                          scm_reverse_x ($2, SCM_EOL));
2067                 }
2068         }
2069         | simple_chord_elements post_events     {
2070                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
2071
2072                 Input i;
2073                 /* why is this giving wrong start location? -ns
2074                  * i = @$; */
2075                 i.set_location (@1, @2);
2076                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
2077         }
2078         | CHORD_REPETITION optional_notemode_duration post_events {
2079                 Input i;
2080                 i.set_location (@1, @3);
2081                 $$ = MAKE_SYNTAX ("repetition-chord", i,
2082                                   $2, scm_reverse_x ($3, SCM_EOL));
2083         }
2084         | MULTI_MEASURE_REST optional_notemode_duration post_events {
2085                 Input i;
2086                 i.set_location (@1, @3);
2087                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
2088                                   scm_reverse_x ($3, SCM_EOL));
2089         }
2090         | command_element
2091         | note_chord_element
2092         ;
2093
2094
2095 note_chord_element:
2096         chord_body optional_notemode_duration post_events
2097         {
2098                 Music *m = unsmob_music ($1);
2099                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
2100                 SCM es = m->get_property ("elements");
2101                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
2102
2103                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
2104                   unsmob_music (scm_car (s))->set_property ("duration", dur);
2105                 es = ly_append2 (es, postevs);
2106
2107                 m-> set_property ("elements", es);
2108                 m->set_spot (@$);
2109                 $$ = m->self_scm ();
2110         }
2111         ;
2112
2113 chord_body:
2114         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
2115         {
2116                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
2117         }
2118         ;
2119
2120 chord_body_elements:
2121         /* empty */             { $$ = SCM_EOL; }
2122         | chord_body_elements chord_body_element {
2123                 if (!SCM_UNBNDP ($2))
2124                         $$ = scm_cons ($2, $1);
2125         }
2126         ;
2127
2128 chord_body_element:
2129         pitch exclamations questions octave_check post_events
2130         {
2131                 int q = $3;
2132                 int ex = $2;
2133                 SCM check = $4;
2134                 SCM post = $5;
2135
2136                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2137                 n->set_property ("pitch", $1);
2138                 if (q % 2)
2139                         n->set_property ("cautionary", SCM_BOOL_T);
2140                 if (ex % 2 || q % 2)
2141                         n->set_property ("force-accidental", SCM_BOOL_T);
2142
2143                 if (scm_is_pair (post)) {
2144                         SCM arts = scm_reverse_x (post, SCM_EOL);
2145                         n->set_property ("articulations", arts);
2146                 }
2147                 if (scm_is_number (check))
2148                 {
2149                         int q = scm_to_int (check);
2150                         n->set_property ("absolute-octave", scm_from_int (q-1));
2151                 }
2152
2153                 $$ = n->unprotect ();
2154         }
2155         | DRUM_PITCH post_events {
2156                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2157                 n->set_property ("drum-type", $1);
2158
2159                 if (scm_is_pair ($2)) {
2160                         SCM arts = scm_reverse_x ($2, SCM_EOL);
2161                         n->set_property ("articulations", arts);
2162                 }
2163                 $$ = n->unprotect ();
2164         }
2165         | music_function_chord_body
2166         {
2167                 Music *m = unsmob_music ($1);
2168
2169                 while (m && m->is_mus_type ("music-wrapper-music")) {
2170                         $$ = m->get_property ("element");
2171                         m = unsmob_music ($$);
2172                 }
2173
2174                 if (!(m && m->is_mus_type ("rhythmic-event"))) {
2175                         parser->parser_error (@$, _ ("not a rhythmic event"));
2176                         $$ = SCM_UNDEFINED;
2177                 }
2178         }
2179         ;
2180
2181 music_function_chord_body:
2182         music_function_call
2183         | MUSIC_IDENTIFIER
2184         ;
2185
2186 // Event functions may only take closed arglists, otherwise it would
2187 // not be clear whether a following postevent should be associated
2188 // with the last argument of the event function or with the expression
2189 // for which the function call acts itself as event.
2190
2191 music_function_event:
2192         MUSIC_FUNCTION function_arglist_closed {
2193                 $$ = MAKE_SYNTAX ("music-function", @$,
2194                                          $1, $2);
2195         }
2196         ;
2197
2198 event_function_event:
2199         EVENT_FUNCTION function_arglist_closed {
2200                 $$ = MAKE_SYNTAX ("music-function", @$,
2201                                          $1, $2);
2202         }
2203         ;
2204
2205 command_element:
2206         command_event {
2207                 $$ = $1;
2208         }
2209         | E_BRACKET_OPEN {
2210                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
2211                 m->set_property ("span-direction", scm_from_int (START));
2212                 $$ = m->unprotect();
2213         }
2214         | E_BRACKET_CLOSE {
2215                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
2216                 m->set_property ("span-direction", scm_from_int (STOP));
2217                 $$ = m->unprotect ();
2218         }
2219         | E_BACKSLASH {
2220                 $$ = MAKE_SYNTAX ("voice-separator", @$);
2221         }
2222         | '|'      {
2223                 SCM pipe = parser->lexer_->lookup_identifier ("pipeSymbol");
2224
2225                 Music *m = unsmob_music (pipe);
2226                 if (m)
2227                 {
2228                         m = m->clone ();
2229                         m->set_spot (@$);
2230                         $$ = m->unprotect ();
2231                 }
2232                 else
2233                         $$ = MAKE_SYNTAX ("bar-check", @$);
2234
2235         }
2236         ;
2237
2238 command_event:
2239         E_TILDE {
2240                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent", @$)->unprotect ();
2241         }
2242         | tempo_event {
2243                 $$ = $1;
2244         }
2245         ;
2246
2247
2248 post_events:
2249         /* empty */ {
2250                 $$ = SCM_EOL;
2251         }
2252         | post_events post_event {
2253                 unsmob_music ($2)->set_spot (@2);
2254                 $$ = scm_cons ($2, $$);
2255         }
2256         ;
2257
2258 post_event_nofinger:
2259         direction_less_event {
2260                 $$ = $1;
2261         }
2262         | script_dir music_function_event {
2263                 $$ = $2;
2264                 if ($1)
2265                 {
2266                         unsmob_music ($$)->set_property ("direction", scm_from_int ($1));
2267                 }
2268         }
2269         | HYPHEN {
2270                 if (!parser->lexer_->is_lyric_state ())
2271                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2272                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
2273         }
2274         | EXTENDER {
2275                 if (!parser->lexer_->is_lyric_state ())
2276                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2277                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
2278         }
2279         | script_dir direction_reqd_event {
2280                 if ($1)
2281                 {
2282                         Music *m = unsmob_music ($2);
2283                         m->set_property ("direction", scm_from_int ($1));
2284                 }
2285                 $$ = $2;
2286         }
2287         | script_dir direction_less_event {
2288                 if ($1)
2289                 {
2290                         Music *m = unsmob_music ($2);
2291                         m->set_property ("direction", scm_from_int ($1));
2292                 }
2293                 $$ = $2;
2294         }
2295         | string_number_event
2296         | '^' fingering
2297         {
2298                 $$ = $2;
2299                 unsmob_music ($$)->set_property ("direction", scm_from_int (UP));
2300         }
2301         | '_' fingering
2302         {
2303                 $$ = $2;
2304                 unsmob_music ($$)->set_property ("direction", scm_from_int (DOWN));
2305         }
2306         ;
2307
2308 post_event:
2309         post_event_nofinger
2310         | '-' fingering {
2311                 $$ = $2;
2312         }
2313         ;
2314
2315 string_number_event:
2316         E_UNSIGNED {
2317                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
2318                 s->set_property ("string-number", scm_from_int ($1));
2319                 $$ = s->unprotect ();
2320         }
2321         ;
2322
2323 direction_less_char:
2324         '['  {
2325                 $$ = ly_symbol2scm ("bracketOpenSymbol");
2326         }
2327         | ']'  {
2328                 $$ = ly_symbol2scm ("bracketCloseSymbol");
2329         }
2330         | '~'  {
2331                 $$ = ly_symbol2scm ("tildeSymbol");
2332         }
2333         | '('  {
2334                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
2335         }
2336         | ')'  {
2337                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
2338         }
2339         | E_EXCLAMATION  {
2340                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
2341         }
2342         | E_OPEN  {
2343                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
2344         }
2345         | E_CLOSE  {
2346                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
2347         }
2348         | E_ANGLE_CLOSE  {
2349                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
2350         }
2351         | E_ANGLE_OPEN  {
2352                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
2353         }
2354         ;
2355
2356 direction_less_event:
2357         direction_less_char {
2358                 SCM predefd = parser->lexer_->lookup_identifier_symbol ($1);
2359                 Music *m = 0;
2360                 if (unsmob_music (predefd))
2361                 {
2362                         m = unsmob_music (predefd)->clone ();
2363                         m->set_spot (@$);
2364                 }
2365                 else
2366                 {
2367                         m = MY_MAKE_MUSIC ("Music", @$);
2368                 }
2369                 $$ = m->unprotect ();
2370         }
2371         | EVENT_IDENTIFIER      {
2372                 $$ = $1;
2373         }
2374         | tremolo_type  {
2375                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
2376                a->set_property ("tremolo-type", scm_from_int ($1));
2377                $$ = a->unprotect ();
2378         }
2379         | event_function_event
2380         ;
2381
2382 direction_reqd_event:
2383         gen_text_def {
2384                 $$ = $1;
2385         }
2386         | script_abbreviation {
2387                 SCM s = parser->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
2388                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
2389                 if (scm_is_string (s))
2390                         a->set_property ("articulation-type", s);
2391                 else parser->parser_error (@1, _ ("expecting string as script definition"));
2392                 $$ = a->unprotect ();
2393         }
2394         ;
2395
2396 octave_check:
2397         /**/ { $$ = SCM_EOL; }
2398         | '='  { $$ = scm_from_int (0); }
2399         | '=' sub_quotes { $$ = scm_from_int (-$2); }
2400         | '=' sup_quotes { $$ = scm_from_int ($2); }
2401         ;
2402
2403 sup_quotes:
2404         '\'' {
2405                 $$ = 1;
2406         }
2407         | sup_quotes '\'' {
2408                 $$ ++;
2409         }
2410         ;
2411
2412 sub_quotes:
2413         ',' {
2414                 $$ = 1;
2415         }
2416         | sub_quotes ',' {
2417                 $$++;
2418         }
2419         ;
2420
2421 steno_pitch:
2422         NOTENAME_PITCH  {
2423                 $$ = $1;
2424         }
2425         | NOTENAME_PITCH sup_quotes     {
2426                 Pitch p = *unsmob_pitch ($1);
2427                 p = p.transposed (Pitch ($2,0,0));
2428                 $$ = p.smobbed_copy ();
2429         }
2430         | NOTENAME_PITCH sub_quotes      {
2431                 Pitch p =* unsmob_pitch ($1);
2432                 p = p.transposed (Pitch (-$2,0,0));
2433                 $$ = p.smobbed_copy ();
2434         }
2435         ;
2436
2437 /*
2438 ugh. duplication
2439 */
2440
2441 steno_tonic_pitch:
2442         TONICNAME_PITCH {
2443                 $$ = $1;
2444         }
2445         | TONICNAME_PITCH sup_quotes    {
2446                 Pitch p = *unsmob_pitch ($1);
2447                 p = p.transposed (Pitch ($2,0,0));
2448                 $$ = p.smobbed_copy ();
2449         }
2450         | TONICNAME_PITCH sub_quotes     {
2451                 Pitch p = *unsmob_pitch ($1);
2452
2453                 p = p.transposed (Pitch (-$2,0,0));
2454                 $$ = p.smobbed_copy ();
2455         }
2456         ;
2457
2458 pitch:
2459         steno_pitch {
2460                 $$ = $1;
2461         }
2462         | PITCH_IDENTIFIER
2463         ;
2464
2465 pitch_also_in_chords:
2466         pitch
2467         | steno_tonic_pitch
2468         ;
2469
2470 gen_text_def:
2471         full_markup {
2472                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2473                 t->set_property ("text", $1);
2474                 $$ = t->unprotect ();
2475         }
2476         | simple_string {
2477                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2478                 t->set_property ("text",
2479                         make_simple_markup ($1));
2480                 $$ = t->unprotect ();
2481         }
2482         ;
2483
2484 fingering:
2485         UNSIGNED {
2486                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
2487                 t->set_property ("digit", $1);
2488                 $$ = t->unprotect ();
2489         }
2490         ;
2491
2492 script_abbreviation:
2493         '^'             {
2494                 $$ = scm_from_locale_string ("Hat");
2495         }
2496         | '+'           {
2497                 $$ = scm_from_locale_string ("Plus");
2498         }
2499         | '-'           {
2500                 $$ = scm_from_locale_string ("Dash");
2501         }
2502         | '|'           {
2503                 $$ = scm_from_locale_string ("Bar");
2504         }
2505         | ANGLE_CLOSE   {
2506                 $$ = scm_from_locale_string ("Larger");
2507         }
2508         | '.'           {
2509                 $$ = scm_from_locale_string ("Dot");
2510         }
2511         | '_' {
2512                 $$ = scm_from_locale_string ("Underscore");
2513         }
2514         ;
2515
2516 script_dir:
2517         '_'     { $$ = DOWN; }
2518         | '^'   { $$ = UP; }
2519         | '-'   { $$ = CENTER; }
2520         ;
2521
2522 duration_length:
2523         multiplied_duration {
2524                 $$ = $1;
2525         }
2526         ;
2527
2528 maybe_notemode_duration:
2529         {
2530                 $$ = SCM_UNDEFINED;
2531         }
2532         | multiplied_duration   {
2533                 $$ = $1;
2534                 parser->default_duration_ = *unsmob_duration ($$);
2535         }
2536 ;
2537
2538
2539 optional_notemode_duration:
2540         maybe_notemode_duration
2541         {
2542                 if (SCM_UNBNDP ($$))
2543                         $$ = parser->default_duration_.smobbed_copy ();
2544         }
2545         ;
2546
2547 steno_duration:
2548         bare_unsigned dots              {
2549                 int len = 0;
2550                 if (!is_duration ($1))
2551                         parser->parser_error (@1, _f ("not a duration: %d", $1));
2552                 else
2553                         len = intlog2 ($1);
2554
2555                 $$ = Duration (len, $2).smobbed_copy ();
2556         }
2557         | DURATION_IDENTIFIER dots      {
2558                 Duration *d = unsmob_duration ($1);
2559                 Duration k (d->duration_log (), d->dot_count () + $2);
2560                 k = k.compressed (d->factor ());
2561                 *d = k;
2562                 $$ = $1;
2563         }
2564         ;
2565
2566 multiplied_duration:
2567         steno_duration {
2568                 $$ = $1;
2569         }
2570         | multiplied_duration '*' bare_unsigned {
2571                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2572         }
2573         | multiplied_duration '*' FRACTION {
2574                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2575
2576                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2577         }
2578         ;
2579
2580 fraction:
2581         FRACTION { $$ = $1; }
2582         | UNSIGNED '/' UNSIGNED {
2583                 $$ = scm_cons ($1, $3);
2584         }
2585         ;
2586
2587 dots:
2588         /* empty */     {
2589                 $$ = 0;
2590         }
2591         | dots '.' {
2592                 $$ ++;
2593         }
2594         ;
2595
2596 tremolo_type:
2597         ':'     {
2598                 $$ = 0;
2599         }
2600         | ':' bare_unsigned {
2601                 if (!is_duration ($2))
2602                         parser->parser_error (@2, _f ("not a duration: %d", $2));
2603                 $$ = $2;
2604         }
2605         ;
2606
2607 bass_number:
2608         UNSIGNED { $$ = $1; }
2609         | STRING { $$ = $1; }
2610         | full_markup { $$ = $1; }
2611         ;
2612
2613 figured_bass_alteration:
2614         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
2615         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
2616         | '!'   { $$ = scm_from_int (0); }
2617         ;
2618
2619 bass_figure:
2620         FIGURE_SPACE {
2621                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2622                 $$ = bfr->unprotect ();
2623         }
2624         | bass_number  {
2625                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2626                 $$ = bfr->self_scm ();
2627
2628                 if (scm_is_number ($1))
2629                         bfr->set_property ("figure", $1);
2630                 else if (Text_interface::is_markup ($1))
2631                         bfr->set_property ("text", $1);
2632
2633                 bfr->unprotect ();
2634         }
2635         | bass_figure ']' {
2636                 $$ = $1;
2637                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2638         }
2639         | bass_figure figured_bass_alteration {
2640                 Music *m = unsmob_music ($1);
2641                 if (scm_to_double ($2)) {
2642                         SCM salter = m->get_property ("alteration");
2643                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
2644                         m->set_property ("alteration",
2645                                          scm_sum (alter, $2));
2646                 } else {
2647                         m->set_property ("alteration", scm_from_int (0));
2648                 }
2649         }
2650         | bass_figure figured_bass_modification  {
2651                 Music *m = unsmob_music ($1);
2652                 if ($2 == ly_symbol2scm ("plus"))
2653                         {
2654                         m->set_property ("augmented", SCM_BOOL_T);
2655                         }
2656                 else if ($2 == ly_symbol2scm ("slash"))
2657                         {
2658                         m->set_property ("diminished", SCM_BOOL_T);
2659                         }
2660                 else if ($2 == ly_symbol2scm ("exclamation"))
2661                         {
2662                         m->set_property ("no-continuation", SCM_BOOL_T);
2663                         }
2664                 else if ($2 == ly_symbol2scm ("backslash"))
2665                         {
2666                         m->set_property ("augmented-slash", SCM_BOOL_T);
2667                         }
2668         }
2669         ;
2670
2671
2672 figured_bass_modification:
2673         E_PLUS          {
2674                 $$ = ly_symbol2scm ("plus");
2675         }
2676         | E_EXCLAMATION {
2677                 $$ = ly_symbol2scm ("exclamation");
2678         }
2679         | '/'           {
2680                 $$ = ly_symbol2scm ("slash");
2681         }
2682         | E_BACKSLASH {
2683                 $$ = ly_symbol2scm ("backslash");
2684         }
2685         ;
2686
2687 br_bass_figure:
2688         bass_figure {
2689                 $$ = $1;
2690         }
2691         | '[' bass_figure {
2692                 $$ = $2;
2693                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2694         }
2695         ;
2696
2697 figure_list:
2698         /**/            {
2699                 $$ = SCM_EOL;
2700         }
2701         | figure_list br_bass_figure {
2702                 $$ = scm_cons ($2, $1);
2703         }
2704         ;
2705
2706 figure_spec:
2707         FIGURE_OPEN figure_list FIGURE_CLOSE {
2708                 $$ = scm_reverse_x ($2, SCM_EOL);
2709         }
2710         ;
2711
2712
2713 optional_rest:
2714         /**/   { $$ = 0; }
2715         | REST { $$ = 1; }
2716         ;
2717
2718 simple_element:
2719         pitch exclamations questions octave_check maybe_notemode_duration optional_rest {
2720                 if (!parser->lexer_->is_note_state ())
2721                         parser->parser_error (@1, _ ("have to be in Note mode for notes"));
2722                 if ($2 || $3 || scm_is_number ($4) || !SCM_UNBNDP ($5) || $6)
2723                 {
2724                         Music *n = 0;
2725                         if ($6)
2726                                 n = MY_MAKE_MUSIC ("RestEvent", @$);
2727                         else
2728                                 n = MY_MAKE_MUSIC ("NoteEvent", @$);
2729
2730                         n->set_property ("pitch", $1);
2731                         if (SCM_UNBNDP ($5))
2732                                 n->set_property ("duration",
2733                                                  parser->default_duration_.smobbed_copy ());
2734                         else
2735                                 n->set_property ("duration", $5);
2736
2737                         if (scm_is_number ($4))
2738                         {
2739                                 int q = scm_to_int ($4);
2740                                 n->set_property ("absolute-octave", scm_from_int (q-1));
2741                         }
2742
2743                         if ($3 % 2)
2744                                 n->set_property ("cautionary", SCM_BOOL_T);
2745                         if ($2 % 2 || $3 % 2)
2746                                 n->set_property ("force-accidental", SCM_BOOL_T);
2747
2748                         $$ = n->unprotect ();
2749                 }
2750         }
2751         | DRUM_PITCH optional_notemode_duration {
2752                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2753                 n->set_property ("duration", $2);
2754                 n->set_property ("drum-type", $1);
2755
2756                 $$ = n->unprotect ();
2757         }
2758         | RESTNAME optional_notemode_duration           {
2759                 Music *ev = 0;
2760                 if (ly_scm2string ($1) == "s") {
2761                         /* Space */
2762                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
2763                   }
2764                 else {
2765                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
2766
2767                     }
2768                 ev->set_property ("duration", $2);
2769                 $$ = ev->unprotect ();
2770         }
2771         ;
2772
2773 simple_chord_elements:
2774         new_chord {
2775                 if (!parser->lexer_->is_chord_state ())
2776                         parser->parser_error (@1, _ ("have to be in Chord mode for chords"));
2777                 $$ = $1;
2778         }
2779         | figure_spec optional_notemode_duration {
2780                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2781                 {
2782                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2783                 }
2784                 $$ = $1;
2785         }
2786         ;
2787
2788 lyric_element:
2789         lyric_markup {
2790                 $$ = $1;
2791         }
2792         | LYRICS_STRING {
2793                 $$ = $1;
2794         }
2795         ;
2796
2797 lyric_element_arg:
2798         lyric_element
2799         | lyric_element multiplied_duration post_events {
2800                 $$ = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
2801                 if (scm_is_pair ($3))
2802                         unsmob_music ($$)->set_property
2803                                 ("articulations", scm_reverse_x ($3, SCM_EOL));
2804         }
2805         | lyric_element post_event post_events {
2806                 $$ = MAKE_SYNTAX ("lyric-event", @$, $1,
2807                                   parser->default_duration_.smobbed_copy ());
2808                 unsmob_music ($$)->set_property
2809                         ("articulations", scm_cons ($2, scm_reverse_x ($3, SCM_EOL)));
2810         }
2811         | LYRIC_ELEMENT optional_notemode_duration post_events {
2812                 $$ = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
2813                 if (scm_is_pair ($3))
2814                         unsmob_music ($$)->set_property
2815                                 ("articulations", scm_reverse_x ($3, SCM_EOL));
2816         }
2817         ;
2818
2819
2820 lyric_element_music:
2821         lyric_element optional_notemode_duration post_events {
2822                 $$ = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
2823                 if (scm_is_pair ($3))
2824                         unsmob_music ($$)->set_property
2825                                 ("articulations", scm_reverse_x ($3, SCM_EOL));
2826         }
2827         ;
2828
2829 new_chord:
2830         steno_tonic_pitch optional_notemode_duration   {
2831                 $$ = make_chord_elements (@$, $1, $2, SCM_EOL);
2832         }
2833         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2834                 SCM its = scm_reverse_x ($4, SCM_EOL);
2835                 $$ = make_chord_elements (@$, $1, $2, scm_cons ($3, its));
2836         }
2837         ;
2838
2839 chord_items:
2840         /**/ {
2841                 $$ = SCM_EOL;
2842         }
2843         | chord_items chord_item {
2844                 $$ = scm_cons ($2, $$);
2845         }
2846         ;
2847
2848 chord_separator:
2849         CHORD_COLON {
2850                 $$ = ly_symbol2scm ("chord-colon");
2851         }
2852         | CHORD_CARET {
2853                 $$ = ly_symbol2scm ("chord-caret");
2854         }
2855         | CHORD_SLASH steno_tonic_pitch {
2856                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2857         }
2858         | CHORD_BASS steno_tonic_pitch {
2859                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2860         }
2861         ;
2862
2863 chord_item:
2864         chord_separator {
2865                 $$ = $1;
2866         }
2867         | step_numbers {
2868                 $$ = scm_reverse_x ($1, SCM_EOL);
2869         }
2870         | CHORD_MODIFIER  {
2871                 $$ = $1;
2872         }
2873         ;
2874
2875 step_numbers:
2876         step_number { $$ = scm_cons ($1, SCM_EOL); }
2877         | step_numbers '.' step_number {
2878                 $$ = scm_cons ($3, $$);
2879         }
2880         ;
2881
2882 step_number:
2883         bare_unsigned {
2884                 $$ = make_chord_step ($1, 0);
2885         }
2886         | bare_unsigned '+' {
2887                 $$ = make_chord_step ($1, SHARP_ALTERATION);
2888         }
2889         | bare_unsigned CHORD_MINUS {
2890                 $$ = make_chord_step ($1, FLAT_ALTERATION);
2891         }
2892         ;
2893
2894 tempo_range:
2895         bare_unsigned {
2896                 $$ = scm_from_int ($1);
2897         }
2898         | bare_unsigned '~' bare_unsigned {
2899                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2900         }
2901         ;
2902
2903 /*
2904         UTILITIES
2905
2906 TODO: should deprecate in favor of Scheme?
2907
2908  */
2909 number_expression:
2910         number_expression '+' number_term {
2911                 $$ = scm_sum ($1, $3);
2912         }
2913         | number_expression '-' number_term {
2914                 $$ = scm_difference ($1, $3);
2915         }
2916         | number_term
2917         ;
2918
2919 number_term:
2920         number_factor {
2921                 $$ = $1;
2922         }
2923         | number_factor '*' number_factor {
2924                 $$ = scm_product ($1, $3);
2925         }
2926         | number_factor '/' number_factor {
2927                 $$ = scm_divide ($1, $3);
2928         }
2929         ;
2930
2931 number_factor:
2932         '-'  number_factor { /* %prec UNARY_MINUS */
2933                 $$ = scm_difference ($2, SCM_UNDEFINED);
2934         }
2935         | bare_number
2936         ;
2937
2938
2939 bare_number:
2940         bare_number_closed
2941         | UNSIGNED NUMBER_IDENTIFIER    {
2942                 $$ = scm_product ($1, $2);
2943         }
2944         | REAL NUMBER_IDENTIFIER        {
2945                 $$ = scm_product ($1, $2);
2946         }
2947         ;
2948
2949 bare_number_closed:
2950         UNSIGNED
2951         | REAL
2952         | NUMBER_IDENTIFIER
2953         ;
2954
2955 bare_unsigned:
2956         UNSIGNED {
2957                 $$ = scm_to_int ($1);
2958         }
2959         ;
2960
2961 unsigned_number:
2962         UNSIGNED
2963         | NUMBER_IDENTIFIER
2964         ;
2965
2966 exclamations:
2967                 { $$ = 0; }
2968         | exclamations '!'      { $$ ++; }
2969         ;
2970
2971 questions:
2972                 { $$ = 0; }
2973         | questions '?' { $$ ++; }
2974         ;
2975
2976 /*
2977 This should be done more dynamically if possible.
2978 */
2979
2980 lyric_markup:
2981         LYRIC_MARKUP_IDENTIFIER {
2982                 $$ = $1;
2983         }
2984         | LYRIC_MARKUP
2985                 { parser->lexer_->push_markup_state (); }
2986         markup_top {
2987                 $$ = $3;
2988                 parser->lexer_->pop_state ();
2989         }
2990         ;
2991
2992 full_markup_list:
2993         MARKUPLIST_IDENTIFIER {
2994                 $$ = $1;
2995         }
2996         | MARKUPLIST
2997                 { parser->lexer_->push_markup_state (); }
2998         markup_list {
2999                 $$ = $3;
3000                 parser->lexer_->pop_state ();
3001         }
3002         ;
3003
3004 full_markup:
3005         MARKUP_IDENTIFIER {
3006                 $$ = $1;
3007         }
3008         | MARKUP
3009                 { parser->lexer_->push_markup_state (); }
3010         markup_top {
3011                 $$ = $3;
3012                 parser->lexer_->pop_state ();
3013         }
3014         ;
3015
3016 markup_top:
3017         markup_list {
3018                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
3019         }
3020         | markup_head_1_list simple_markup      {
3021                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
3022         }
3023         | simple_markup {
3024                 $$ = $1;
3025         }
3026         ;
3027
3028 markup_scm:
3029         embedded_scm_bare
3030         {
3031                 if (Text_interface::is_markup ($1))
3032                         MYBACKUP (MARKUP_IDENTIFIER, $1, @1);
3033                 else if (Text_interface::is_markup_list ($1))
3034                         MYBACKUP (MARKUPLIST_IDENTIFIER, $1, @1);
3035                 else {
3036                         parser->parser_error (@1, _ ("not a markup"));
3037                         MYBACKUP (MARKUP_IDENTIFIER, scm_string (SCM_EOL), @1);
3038                 }
3039         } BACKUP
3040         ;
3041
3042
3043 markup_list:
3044         MARKUPLIST_IDENTIFIER {
3045                 $$ = $1;
3046         }
3047         | markup_composed_list {
3048                 $$ = $1;
3049         }
3050         | markup_braced_list {
3051                 $$ = $1;
3052         }
3053         | markup_command_list {
3054                 $$ = scm_list_1 ($1);
3055         }
3056         | markup_scm MARKUPLIST_IDENTIFIER
3057         {
3058                 $$ = $2;
3059         }
3060         ;
3061
3062 markup_composed_list:
3063         markup_head_1_list markup_braced_list {
3064                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
3065
3066         }
3067         ;
3068
3069 markup_braced_list:
3070         '{' markup_braced_list_body '}' {
3071                 $$ = scm_reverse_x ($2, SCM_EOL);
3072         }
3073         ;
3074
3075 markup_braced_list_body:
3076         /* empty */     {  $$ = SCM_EOL; }
3077         | markup_braced_list_body markup {
3078                 $$ = scm_cons ($2, $1);
3079         }
3080         | markup_braced_list_body markup_list {
3081                 $$ = scm_reverse_x ($2, $1);
3082         }
3083         ;
3084
3085 markup_command_list:
3086         MARKUP_LIST_FUNCTION markup_command_list_arguments {
3087           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
3088         }
3089         ;
3090
3091 markup_command_basic_arguments:
3092         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
3093           $$ = scm_cons ($3, $2);
3094         }
3095         | EXPECT_SCM markup_command_list_arguments embedded_scm_closed {
3096           $$ = check_scheme_arg (parser, @3, $3, $2, $1);
3097         }
3098         | EXPECT_NO_MORE_ARGS {
3099           $$ = SCM_EOL;
3100         }
3101         ;
3102
3103 markup_command_list_arguments:
3104         markup_command_basic_arguments { $$ = $1; }
3105         | EXPECT_MARKUP markup_command_list_arguments markup {
3106           $$ = scm_cons ($3, $2);
3107         }
3108         ;
3109
3110 markup_head_1_item:
3111         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
3112           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
3113         }
3114         ;
3115
3116 markup_head_1_list:
3117         markup_head_1_item      {
3118                 $$ = scm_list_1 ($1);
3119         }
3120         | markup_head_1_list markup_head_1_item {
3121                 $$ = scm_cons ($2, $1);
3122         }
3123         ;
3124
3125 simple_markup:
3126         STRING {
3127                 $$ = make_simple_markup ($1);
3128         }
3129         | MARKUP_IDENTIFIER {
3130                 $$ = $1;
3131         }
3132         | LYRIC_MARKUP_IDENTIFIER {
3133                 $$ = $1;
3134         }
3135         | STRING_IDENTIFIER {
3136                 $$ = $1;
3137         }
3138         | SCORE {
3139                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
3140                 parser->lexer_->push_note_state (alist_to_hashq (nn));
3141         } '{' score_body '}' {
3142                 Score * sc = $4;
3143                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
3144                 sc->unprotect ();
3145                 parser->lexer_->pop_state ();
3146         }
3147         | MARKUP_FUNCTION markup_command_basic_arguments {
3148                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
3149         }
3150         | markup_scm MARKUP_IDENTIFIER
3151         {
3152                 $$ = $2;
3153         }
3154         ;
3155
3156 markup:
3157         markup_head_1_list simple_markup        {
3158                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
3159                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
3160         }
3161         | simple_markup {
3162                 $$ = $1;
3163         }
3164         ;
3165
3166 %%
3167
3168 void
3169 Lily_parser::set_yydebug (bool x)
3170 {
3171         yydebug = x;
3172 }
3173
3174 void
3175 Lily_parser::do_yyparse ()
3176 {
3177         yyparse (this);
3178 }
3179
3180
3181
3182
3183
3184 /*
3185
3186 It is a little strange to have this function in this file, but
3187 otherwise, we have to import music classes into the lexer.
3188
3189 */
3190 int
3191 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
3192 {
3193         if (scm_is_string (sid)) {
3194                 *destination = sid;
3195                 return STRING_IDENTIFIER;
3196         } else if (unsmob_book (sid)) {
3197                 Book *book =  unsmob_book (sid)->clone ();
3198                 *destination = book->self_scm ();
3199                 book->unprotect ();
3200
3201                 return BOOK_IDENTIFIER;
3202         } else if (scm_is_number (sid)) {
3203                 *destination = sid;
3204                 return NUMBER_IDENTIFIER;
3205         } else if (unsmob_context_def (sid)) {
3206                 Context_def *def= unsmob_context_def (sid)->clone ();
3207
3208                 *destination = def->self_scm ();
3209                 def->unprotect ();
3210
3211                 return CONTEXT_DEF_IDENTIFIER;
3212         } else if (unsmob_context_mod (sid)) {
3213                 *destination = unsmob_context_mod (sid)->smobbed_copy ();
3214
3215                 return CONTEXT_MOD_IDENTIFIER;
3216         } else if (unsmob_score (sid)) {
3217                 Score *score = new Score (*unsmob_score (sid));
3218                 *destination = score->self_scm ();
3219
3220                 score->unprotect ();
3221                 return SCORE_IDENTIFIER;
3222         } else if (Music *mus = unsmob_music (sid)) {
3223                 mus = mus->clone ();
3224                 *destination = mus->self_scm ();
3225                 unsmob_music (*destination)->
3226                         set_property ("origin", make_input (last_input_));
3227
3228                 bool is_event = mus->is_mus_type ("post-event");
3229                 mus->unprotect ();
3230                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
3231         } else if (unsmob_pitch (sid)) {
3232                 *destination = unsmob_pitch (sid)->smobbed_copy ();
3233                 return PITCH_IDENTIFIER;
3234         } else if (unsmob_duration (sid)) {
3235                 *destination = unsmob_duration (sid)->smobbed_copy ();
3236                 return DURATION_IDENTIFIER;
3237         } else if (unsmob_output_def (sid)) {
3238                 Output_def *p = unsmob_output_def (sid);
3239                 p = p->clone ();
3240
3241                 *destination = p->self_scm ();
3242                 p->unprotect ();
3243                 return OUTPUT_DEF_IDENTIFIER;
3244         } else if (Text_interface::is_markup (sid)) {
3245                 *destination = sid;
3246                 if (is_lyric_state ())
3247                         return LYRIC_MARKUP_IDENTIFIER;
3248                 return MARKUP_IDENTIFIER;
3249         } else if (Text_interface::is_markup_list (sid)) {
3250                 *destination = sid;
3251                 return MARKUPLIST_IDENTIFIER;
3252         }
3253
3254         return -1;
3255 }
3256
3257 SCM
3258 get_next_unique_context_id ()
3259 {
3260         return scm_from_locale_string ("$uniqueContextId");
3261 }
3262
3263
3264 SCM
3265 get_next_unique_lyrics_context_id ()
3266 {
3267         static int new_context_count;
3268         char s[128];
3269         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
3270         return scm_from_locale_string (s);
3271 }
3272
3273 SCM check_scheme_arg (Lily_parser *parser, Input loc,
3274                       SCM arg, SCM args, SCM pred)
3275 {
3276         args = scm_cons (arg, args);
3277         if (scm_is_true (scm_call_1 (pred, arg)))
3278                 return args;
3279         scm_set_cdr_x (scm_last_pair (args), SCM_EOL);
3280         MAKE_SYNTAX ("argument-error", loc, scm_length (args), pred, arg);
3281         scm_set_cdr_x (scm_last_pair (args), SCM_BOOL_F);
3282         return args;
3283 }
3284
3285 SCM loc_on_music (Input loc, SCM arg)
3286 {
3287         if (Music *m = unsmob_music (arg))
3288         {
3289                 m = m->clone ();
3290                 m->set_spot (loc);
3291                 return m->unprotect ();
3292         }
3293         return arg;
3294 }
3295
3296 bool
3297 is_regular_identifier (SCM id)
3298 {
3299   string str = ly_scm2string (id);
3300   char const *s = str.c_str ();
3301
3302   bool v = true;
3303 #if 0
3304   isalpha (*s);
3305   s++;
3306 #endif
3307   while (*s && v)
3308    {
3309         v = v && isalnum (*s);
3310         s++;
3311    }
3312   return v;
3313 }
3314
3315 Music *
3316 make_music_with_input (SCM name, Input where)
3317 {
3318        Music *m = make_music_by_name (name);
3319        m->set_spot (where);
3320        return m;
3321 }
3322
3323 SCM
3324 make_simple_markup (SCM a)
3325 {
3326         return a;
3327 }
3328
3329 bool
3330 is_duration (int t)
3331 {
3332   return t && t == 1 << intlog2 (t);
3333 }
3334
3335 void
3336 set_music_properties (Music *p, SCM a)
3337 {
3338   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
3339         p->set_property (scm_caar (k), scm_cdar (k));
3340 }
3341
3342
3343 SCM
3344 make_chord_step (int step, Rational alter)
3345 {
3346         if (step == 7)
3347                 alter += FLAT_ALTERATION;
3348
3349         while (step < 0)
3350                 step += 7;
3351         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
3352         return m.smobbed_copy ();
3353 }
3354
3355
3356 SCM
3357 make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list)
3358 {
3359         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
3360         SCM res = scm_call_3 (chord_ctor, pitch, dur, modification_list);
3361         for (SCM s = res; scm_is_pair (s); s = scm_cdr (s))
3362         {
3363                 unsmob_music (scm_car (s))->set_spot (loc);
3364         }
3365         return res;
3366 }
3367
3368 int
3369 yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser)
3370 {
3371         Lily_lexer *lex = parser->lexer_;
3372
3373         lex->lexval_ = s;
3374         lex->lexloc_ = loc;
3375         lex->prepare_for_next_token ();
3376         return lex->yylex ();
3377 }