lily/parser.yy

   1 /* -*- mode: c++; c-file-style: "linux"; indent-tabs-mode: t -*- */
   2 /*
   3   This file is part of LilyPond, the GNU music typesetter.
   4
   5   Copyright (C) 1997--2014 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6                  Jan Nieuwenhuizen <janneke@gnu.org>
   7
   8   LilyPond is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   LilyPond is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  20 */
  21
  22 /* Mode and indentation are at best a rough approximation based on TAB
  23  * formatting (reasonable for compatibility with unspecific editor
  24  * modes as Bison modes are hard to find) and need manual correction
  25  * frequently.  Without a reasonably dependable way of formatting a
  26  * Bison file sensibly, there is little point in trying to fix the
  27  * inconsistent state of indentation.
  28  */
  29
  30 %{
  31
  32 #define yyerror Lily_parser::parser_error
  33
  34 /* We use custom location type: Input objects */
  35 #define YYLTYPE Input
  36 #define YYSTYPE SCM
  37 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  38         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  39
  40 #define YYPRINT(file, type, value)                                      \
  41         do {                                                            \
  42                 if (scm_is_eq (value, SCM_UNSPECIFIED))                 \
  43                         break;                                          \
  44                 SCM s = scm_call_2 (ly_lily_module_constant ("value->lily-string"), \
  45                                     value,                              \
  46                                     parser->self_scm ());               \
  47                 char *p = scm_to_locale_string (s);                     \
  48                 fputs (p, file);                                        \
  49                 free (p);                                               \
  50         } while (0)
  51
  52 %}
  53
  54 %parse-param {Lily_parser *parser}
  55 %parse-param {SCM *retval}
  56 %lex-param {Lily_parser *parser}
  57 %error-verbose
  58 %debug
  59
  60 /* We use SCMs to do strings, because it saves us the trouble of
  61 deleting them.  Let's hope that a stack overflow doesn't trigger a move
  62 of the parse stack onto the heap. */
  63
  64 %left PREC_BOT
  65 %nonassoc REPEAT
  66 %nonassoc ALTERNATIVE
  67
  68 /* The above precedences tackle the shift/reduce problem
  69
  70 1.  \repeat
  71         \repeat .. \alternative
  72
  73     \repeat { \repeat .. \alternative }
  74
  75 or
  76
  77     \repeat { \repeat } \alternative
  78 */
  79
  80 %nonassoc COMPOSITE
  81 %left ADDLYRICS
  82
  83 %right ':' UNSIGNED REAL E_UNSIGNED EVENT_IDENTIFIER EVENT_FUNCTION '^' '_'
  84        HYPHEN EXTENDER DURATION_IDENTIFIER '!'
  85
  86  /* The above are needed for collecting tremoli and other items (that
  87     could otherwise be interpreted as belonging to the next function
  88     argument) greedily, and together with the next rule will serve to
  89     join numbers and units greedily instead of allowing them into
  90     separate function arguments
  91  */
  92
  93 %nonassoc NUMBER_IDENTIFIER
  94
  95 %left PREC_TOP
  96
  97
  98
  99
 100 %pure-parser
 101 %locations
 102
 103
 104
 105 %{ // -*-Fundamental-*-
 106
 107 /*
 108 FIXME:
 109
 110    * The rules for who is protecting what are very shady.  Uniformise
 111      this.
 112
 113    * There are too many lexical modes?
 114 */
 115
 116 #include "config.hh"
 117
 118 #include <cctype>
 119 #include <cstdlib>
 120 #include <cstdio>
 121 using namespace std;
 122
 123 #include "book.hh"
 124 #include "context-def.hh"
 125 #include "context-mod.hh"
 126 #include "dimensions.hh"
 127 #include "file-path.hh"
 128 #include "input.hh"
 129 #include "international.hh"
 130 #include "lily-guile.hh"
 131 #include "lily-lexer.hh"
 132 #include "lily-parser.hh"
 133 #include "main.hh"
 134 #include "misc.hh"
 135 #include "music.hh"
 136 #include "output-def.hh"
 137 #include "paper-book.hh"
 138 #include "scm-hash.hh"
 139 #include "score.hh"
 140 #include "text-interface.hh"
 141 #include "warn.hh"
 142
 143 void
 144 Lily_parser::parser_error (Input const *i, Lily_parser *parser, SCM *, const string &s)
 145 {
 146         parser->parser_error (*i, s);
 147 }
 148
 149 // The following are somewhat precarious constructs as they may change
 150 // the value of the lookahead token.  That implies that the lookahead
 151 // token must not yet have made an impact on the state stack other
 152 // than causing the reduction of the current rule, or switching the
 153 // lookahead token while Bison is mulling it over will cause trouble.
 154
 155 #define MYBACKUP(Token, Value, Location)                                \
 156         do {                                                            \
 157                 if (yychar != YYEMPTY)                                  \
 158                         parser->lexer_->push_extra_token                \
 159                                 (yylloc, yychar, yylval);               \
 160                 if (Token)                                              \
 161                         parser->lexer_->push_extra_token                \
 162                                 (Location, Token, Value);               \
 163                 parser->lexer_->push_extra_token (Location, BACKUP);    \
 164                 yychar = YYEMPTY;                                       \
 165         } while (0)
 166
 167
 168 #define MYREPARSE(Location, Pred, Token, Value)                         \
 169         do {                                                            \
 170                 if (yychar != YYEMPTY)                                  \
 171                         parser->lexer_->push_extra_token                \
 172                                 (yylloc, yychar, yylval);               \
 173                 parser->lexer_->push_extra_token                        \
 174                         (Location, Token, Value);                       \
 175                 parser->lexer_->push_extra_token                        \
 176                         (Location, REPARSE, Pred);                      \
 177                 yychar = YYEMPTY;                                       \
 178         } while (0)
 179
 180 %}
 181
 182
 183 %{
 184
 185 #define MY_MAKE_MUSIC(x, spot) \
 186         make_music_with_input (ly_symbol2scm (x), \
 187                                parser->lexer_->override_input (spot))
 188
 189 /* ES TODO:
 190 - Don't use lily module, create a new module instead.
 191 - delay application of the function
 192 */
 193 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 194   scm_apply_0 (proc, args)
 195 /* Syntactic Sugar. */
 196 #define MAKE_SYNTAX(name, location, ...)                                \
 197         LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (parser->self_scm (), parser->lexer_->override_input (location).smobbed_copy (), ##__VA_ARGS__, SCM_UNDEFINED))
 198 #define START_MAKE_SYNTAX(name, ...)                                    \
 199         scm_list_n (ly_lily_module_constant (name) , ##__VA_ARGS__, SCM_UNDEFINED)
 200 #define FINISH_MAKE_SYNTAX(start, location, ...)                        \
 201         LOWLEVEL_MAKE_SYNTAX (scm_car (start), scm_cons2 (parser->self_scm (), parser->lexer_->override_input (location).smobbed_copy (), scm_append_x (scm_list_2 (scm_cdr (start), scm_list_n (__VA_ARGS__, SCM_UNDEFINED)))))
 202
 203 SCM get_next_unique_context_id ();
 204 SCM get_next_unique_lyrics_context_id ();
 205
 206 #undef _
 207 #if !HAVE_GETTEXT
 208 #define _(x) x
 209 #else
 210 #include <libintl.h>
 211 #define _(x) gettext (x)
 212 #endif
 213
 214
 215 static Music *make_music_with_input (SCM name, Input where);
 216 SCM check_scheme_arg (Lily_parser *parser, Input loc,
 217                       SCM arg, SCM args, SCM pred, SCM disp = SCM_UNDEFINED);
 218 SCM make_music_from_simple (Lily_parser *parser, Input loc, SCM pitch);
 219 SCM loc_on_music (Input loc, SCM arg);
 220 SCM make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list);
 221 SCM make_chord_step (SCM step, Rational alter);
 222 SCM make_simple_markup (SCM a);
 223 SCM make_duration (SCM t, int dots = 0);
 224 bool is_regular_identifier (SCM id, bool multiple=false);
 225 SCM try_string_variants (SCM pred, SCM str);
 226 int yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser);
 227
 228 %}
 229
 230 /* The third option is an alias that will be used to display the
 231    syntax error.  Bison CVS now correctly handles backslash escapes.
 232
 233    FIXME: Bison needs to translate some of these, eg, STRING.
 234
 235 */
 236
 237 /* Keyword tokens with plain escaped name.  */
 238 %token END_OF_FILE 0 "end of input"
 239 %token ACCEPTS "\\accepts"
 240 %token ADDLYRICS "\\addlyrics"
 241 %token ALIAS "\\alias"
 242 %token ALTERNATIVE "\\alternative"
 243 %token BOOK "\\book"
 244 %token BOOKPART "\\bookpart"
 245 %token CHANGE "\\change"
 246 %token CHORDMODE "\\chordmode"
 247 %token CHORDS "\\chords"
 248 %token CONSISTS "\\consists"
 249 %token CONTEXT "\\context"
 250 %token DEFAULT "\\default"
 251 %token DEFAULTCHILD "\\defaultchild"
 252 %token DENIES "\\denies"
 253 %token DESCRIPTION "\\description"
 254 %token DRUMMODE "\\drummode"
 255 %token DRUMS "\\drums"
 256 %token FIGUREMODE "\\figuremode"
 257 %token FIGURES "\\figures"
 258 %token HEADER "\\header"
 259 %token INVALID "\\version-error"
 260 %token LAYOUT "\\layout"
 261 %token LYRICMODE "\\lyricmode"
 262 %token LYRICS "\\lyrics"
 263 %token LYRICSTO "\\lyricsto"
 264 %token MARKUP "\\markup"
 265 %token MARKUPLIST "\\markuplist"
 266 %token MIDI "\\midi"
 267 %token NAME "\\name"
 268 %token NOTEMODE "\\notemode"
 269 %token OVERRIDE "\\override"
 270 %token PAPER "\\paper"
 271 %token REMOVE "\\remove"
 272 %token REPEAT "\\repeat"
 273 %token REST "\\rest"
 274 %token REVERT "\\revert"
 275 %token SCORE "\\score"
 276 %token SCORELINES "\\score-lines"
 277 %token SEQUENTIAL "\\sequential"
 278 %token SET "\\set"
 279 %token SIMULTANEOUS "\\simultaneous"
 280 %token TEMPO "\\tempo"
 281 %token TYPE "\\type"
 282 %token UNSET "\\unset"
 283 %token WITH "\\with"
 284
 285 /* Keyword token exceptions.  */
 286 %token NEWCONTEXT "\\new"
 287
 288
 289 /* Other string tokens.  */
 290
 291 %token CHORD_BASS "/+"
 292 %token CHORD_CARET "^"
 293 %token CHORD_COLON ":"
 294 %token CHORD_MINUS "-"
 295 %token CHORD_SLASH "/"
 296 %token ANGLE_OPEN "<"
 297 %token ANGLE_CLOSE ">"
 298 %token DOUBLE_ANGLE_OPEN "<<"
 299 %token DOUBLE_ANGLE_CLOSE ">>"
 300 %token E_BACKSLASH "\\"
 301 %token E_EXCLAMATION "\\!"
 302 %token E_PLUS "\\+"
 303 %token EXTENDER "__"
 304
 305 /*
 306 If we give names, Bison complains.
 307 */
 308 %token FIGURE_CLOSE /* "\\>" */
 309 %token FIGURE_OPEN /* "\\<" */
 310 %token FIGURE_SPACE "_"
 311 %token HYPHEN "--"
 312
 313 %token MULTI_MEASURE_REST
 314
 315
 316 %token E_UNSIGNED
 317 %token UNSIGNED
 318
 319 /* Artificial tokens, for more generic function syntax */
 320 %token EXPECT_MARKUP "markup?"
 321 %token EXPECT_SCM "scheme?"
 322 %token BACKUP "(backed-up?)"
 323 %token REPARSE "(reparsed?)"
 324 %token EXPECT_MARKUP_LIST "markup-list?"
 325 %token EXPECT_OPTIONAL "optional?"
 326 /* After the last argument. */
 327 %token EXPECT_NO_MORE_ARGS;
 328
 329 /* An artificial token for parsing embedded Lilypond */
 330 %token EMBEDDED_LILY "#{"
 331
 332 %token BOOK_IDENTIFIER
 333 %token CHORD_MODIFIER
 334 %token CHORD_REPETITION
 335 %token CONTEXT_MOD_IDENTIFIER
 336 %token DRUM_PITCH
 337 %token PITCH_IDENTIFIER
 338 %token DURATION_IDENTIFIER
 339 %token EVENT_IDENTIFIER
 340 %token EVENT_FUNCTION
 341 %token FRACTION
 342 %token LYRIC_ELEMENT
 343 %token MARKUP_FUNCTION
 344 %token MARKUP_LIST_FUNCTION
 345 %token MARKUP_IDENTIFIER
 346 %token MARKUPLIST_IDENTIFIER
 347 %token MUSIC_FUNCTION
 348 %token MUSIC_IDENTIFIER
 349 %token NOTENAME_PITCH
 350 %token NUMBER_IDENTIFIER
 351 %token REAL
 352 %token RESTNAME
 353 %token SCM_ARG
 354 %token SCM_FUNCTION
 355 %token SCM_IDENTIFIER
 356 %token SCM_TOKEN
 357 %token STRING
 358 %token SYMBOL_LIST
 359 %token TONICNAME_PITCH
 360
 361 %left '-' '+'
 362
 363 /* We don't assign precedence to / and *, because we might need varied
 364 prec levels in different prods */
 365
 366 %left UNARY_MINUS
 367
 368 %%
 369
 370 start_symbol:
 371         lilypond
 372         | EMBEDDED_LILY {
 373                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 374                 parser->lexer_->push_note_state (nn);
 375         } embedded_lilypond {
 376                 parser->lexer_->pop_state ();
 377                 *retval = $3;
 378         }
 379         ;
 380
 381 lilypond:       /* empty */ { $$ = SCM_UNSPECIFIED; }
 382         | lilypond toplevel_expression {
 383         }
 384         | lilypond assignment {
 385         }
 386         | lilypond error {
 387                 parser->error_level_ = 1;
 388         }
 389         | lilypond INVALID      {
 390                 parser->error_level_ = 1;
 391         }
 392         ;
 393
 394
 395 toplevel_expression:
 396         {
 397                 parser->lexer_->add_scope (get_header (parser));
 398         } lilypond_header {
 399                 parser->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $2);
 400         }
 401         | book_block {
 402                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-book-handler");
 403                 scm_call_2 (proc, parser->self_scm (), $1);
 404         }
 405         | bookpart_block {
 406                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 407                 scm_call_2 (proc, parser->self_scm (), $1);
 408         }
 409         | BOOK_IDENTIFIER {
 410                 SCM proc = parser->lexer_->lookup_identifier
 411                         (Book::unsmob($1)->paper_
 412                          ? "toplevel-book-handler"
 413                          : "toplevel-bookpart-handler");
 414                 scm_call_2 (proc, parser->self_scm (), $1);
 415         }
 416         | score_block {
 417                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-score-handler");
 418                 scm_call_2 (proc, parser->self_scm (), $1);
 419         }
 420         | composite_music {
 421                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-music-handler");
 422                 scm_call_2 (proc, parser->self_scm (), $1);
 423         }
 424         | full_markup {
 425                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 426                 scm_call_2 (proc, parser->self_scm (), scm_list_1 ($1));
 427         }
 428         | full_markup_list {
 429                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 430                 scm_call_2 (proc, parser->self_scm (), $1);
 431         }
 432         | SCM_TOKEN {
 433                 // Evaluate and ignore #xxx, as opposed to \xxx
 434                 parser->lexer_->eval_scm_token ($1, @1);
 435         }
 436         | embedded_scm_active
 437         {
 438                 SCM out = SCM_UNDEFINED;
 439                 if (Text_interface::is_markup ($1))
 440                         out = scm_list_1 ($1);
 441                 else if (Text_interface::is_markup_list ($1))
 442                         out = $1;
 443                 if (scm_is_pair (out))
 444                 {
 445                         SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 446                         scm_call_2 (proc, parser->self_scm (), out);
 447                 } else if (Score::is_smob ($1))
 448                 {
 449                         SCM proc = parser->lexer_->lookup_identifier ("toplevel-score-handler");
 450                         scm_call_2 (proc, parser->self_scm (), $1);
 451                 } else if (Output_def * od = Output_def::unsmob ($1)) {
 452                         SCM id = SCM_EOL;
 453
 454                         if (od->c_variable ("is-paper") == SCM_BOOL_T)
 455                                 id = ly_symbol2scm ("$defaultpaper");
 456                         else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 457                                 id = ly_symbol2scm ("$defaultmidi");
 458                         else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 459                                 id = ly_symbol2scm ("$defaultlayout");
 460
 461                         parser->lexer_->set_identifier (id, $1);
 462                 } else if (!scm_is_eq ($1, SCM_UNSPECIFIED))
 463                         parser->parser_error (@1, _("bad expression type"));
 464         }
 465         | output_def {
 466                 SCM id = SCM_EOL;
 467                 Output_def * od = Output_def::unsmob ($1);
 468
 469                 if (od->c_variable ("is-paper") == SCM_BOOL_T)
 470                         id = ly_symbol2scm ("$defaultpaper");
 471                 else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 472                         id = ly_symbol2scm ("$defaultmidi");
 473                 else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 474                         id = ly_symbol2scm ("$defaultlayout");
 475
 476                 parser->lexer_->set_identifier (id, $1);
 477         }
 478         ;
 479
 480 embedded_scm_bare:
 481         SCM_TOKEN
 482         {
 483                 $$ = parser->lexer_->eval_scm_token ($1, @1);
 484         }
 485         | SCM_IDENTIFIER
 486         ;
 487
 488 embedded_scm_active:
 489         SCM_IDENTIFIER
 490         | scm_function_call
 491         ;
 492
 493 embedded_scm_bare_arg:
 494         SCM_ARG
 495         | SCM_TOKEN
 496         {
 497                 $$ = parser->lexer_->eval_scm_token ($1, @1);
 498         }
 499         | FRACTION
 500         | full_markup_list
 501         | context_modification
 502         | score_block
 503         | context_def_spec_block
 504         | book_block
 505         | bookpart_block
 506         | output_def
 507         ;
 508
 509 /* The generic version may end in music, or not */
 510
 511 embedded_scm:
 512         embedded_scm_bare
 513         | scm_function_call
 514         ;
 515
 516 /* embedded_scm_arg is _not_ casting pitches to music by default, this
 517  * has to be done by the function itself.  Note that this may cause
 518  * the results of scm_function_call or embedded_scm_bare_arg to be
 519  * turned into music from pitches as well.  Note that this creates a
 520  * distinctly awkward situation for calculated drum pitches.  Those
 521  * are at the current point of time rejected as music constituents as
 522  * they can't be distinguished from "proper" symbols.
 523  */
 524
 525 embedded_scm_arg:
 526         embedded_scm_bare_arg
 527         | scm_function_call
 528         | music_assign
 529         ;
 530
 531 scm_function_call:
 532         SCM_FUNCTION function_arglist {
 533                 $$ = MAKE_SYNTAX ("music-function", @$,
 534                                          $1, $2);
 535         }
 536         ;
 537
 538 embedded_lilypond_number:
 539         '-' embedded_lilypond_number
 540         {
 541                 $$ = scm_difference ($2, SCM_UNDEFINED);
 542         }
 543         | bare_number_common
 544         | UNSIGNED NUMBER_IDENTIFIER
 545         {
 546                 $$ = scm_product ($1, $2);
 547         }
 548         ;
 549
 550 embedded_lilypond:
 551         /* empty */
 552         {
 553                 // FIXME: @$ does not contain a useful source location
 554                 // for empty rules, and the only token in the whole
 555                 // production, EMBEDDED_LILY, is synthetic and also
 556                 // contains no source location.
 557                 $$ = MAKE_SYNTAX ("void-music", @$);
 558         }
 559         | identifier_init_nonumber
 560         | embedded_lilypond_number
 561         | post_event post_events
 562         {
 563                 $$ = scm_reverse_x ($2, SCM_EOL);
 564                 if (Music *m = Music::unsmob ($1))
 565                 {
 566                         if (m->is_mus_type ("post-event-wrapper"))
 567                                 $$ = scm_append
 568                                         (scm_list_2 (m->get_property ("elements"),
 569                                                      $$));
 570                         else
 571                                 $$ = scm_cons ($1, $$);
 572                 }
 573                 if (scm_is_pair ($$)
 574                     && scm_is_null (scm_cdr ($$)))
 575                         $$ = scm_car ($$);
 576                 else
 577                 {
 578                         Music * m = MY_MAKE_MUSIC ("PostEvents", @$);
 579                         m->set_property ("elements", $$);
 580                         $$ = m->unprotect ();
 581                 }
 582         }
 583         | multiplied_duration
 584         | music_embedded music_embedded music_list {
 585                 $3 = scm_reverse_x ($3, SCM_EOL);
 586                 if (Music::is_smob ($2))
 587                         $3 = scm_cons ($2, $3);
 588                 if (Music::is_smob ($1))
 589                         $3 = scm_cons ($1, $3);
 590                 $$ = MAKE_SYNTAX ("sequential-music", @$, $3);
 591         }
 592         | error {
 593                 parser->error_level_ = 1;
 594                 $$ = SCM_UNSPECIFIED;
 595         }
 596         | INVALID embedded_lilypond {
 597                 parser->error_level_ = 1;
 598                 $$ = $2;
 599         }
 600         ;
 601
 602
 603 lilypond_header_body:
 604         /* empty */ { $$ = SCM_UNSPECIFIED; }
 605         | lilypond_header_body assignment  {
 606
 607         }
 608         | lilypond_header_body embedded_scm  {
 609
 610         }
 611         ;
 612
 613 lilypond_header:
 614         HEADER '{' lilypond_header_body '}'     {
 615                 $$ = parser->lexer_->remove_scope ();
 616         }
 617         ;
 618
 619 /*
 620         DECLARATIONS
 621 */
 622 assignment_id:
 623         STRING          { $$ = $1; }
 624         ;
 625
 626 assignment:
 627         assignment_id '=' identifier_init  {
 628                 parser->lexer_->set_identifier ($1, $3);
 629                 $$ = SCM_UNSPECIFIED;
 630         }
 631         | assignment_id property_path '=' identifier_init {
 632                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 633                 parser->lexer_->set_identifier (path, $4);
 634                 $$ = SCM_UNSPECIFIED;
 635         }
 636         | assignment_id '.' property_path '=' identifier_init {
 637                 SCM path = scm_cons (scm_string_to_symbol ($1), $3);
 638                 parser->lexer_->set_identifier (path, $5);
 639                 $$ = SCM_UNSPECIFIED;
 640         }
 641         ;
 642
 643
 644 identifier_init:
 645         identifier_init_nonumber
 646         | number_expression
 647         | post_event_nofinger post_events
 648         {
 649                 $$ = scm_reverse_x ($2, SCM_EOL);
 650                 if (Music *m = Music::unsmob ($1))
 651                 {
 652                         if (m->is_mus_type ("post-event-wrapper"))
 653                                 $$ = scm_append
 654                                         (scm_list_2 (m->get_property ("elements"),
 655                                                      $$));
 656                         else
 657                                 $$ = scm_cons ($1, $$);
 658                 }
 659                 if (scm_is_pair ($$)
 660                     && scm_is_null (scm_cdr ($$)))
 661                         $$ = scm_car ($$);
 662                 else
 663                 {
 664                         Music * m = MY_MAKE_MUSIC ("PostEvents", @$);
 665                         m->set_property ("elements", $$);
 666                         $$ = m->unprotect ();
 667                 }
 668         }
 669         ;
 670
 671 identifier_init_nonumber:
 672         score_block
 673         | book_block
 674         | bookpart_block
 675         | output_def
 676         | context_def_spec_block
 677         | music_assign
 678         | pitch_or_music
 679         | FRACTION
 680         | string
 681         | embedded_scm
 682         | full_markup_list
 683         | context_modification
 684         ;
 685
 686 context_def_spec_block:
 687         CONTEXT '{' context_def_spec_body '}'
 688         {
 689                 $$ = $3;
 690                 Context_def *td = Context_def::unsmob ($$);
 691                 if (!td) {
 692                         $$ = Context_def::make_scm ();
 693                         td = Context_def::unsmob ($$);
 694                 }
 695                 td->origin ()->set_spot (@$);
 696         }
 697         ;
 698
 699 context_mod_arg:
 700         embedded_scm
 701         |
 702         {
 703                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 704                 parser->lexer_->push_note_state (nn);
 705         }
 706         composite_music
 707         {
 708                 parser->lexer_->pop_state ();
 709                 $$ = $2;
 710         }
 711         ;
 712
 713
 714 context_def_spec_body:
 715         /**/ {
 716                 $$ = SCM_UNSPECIFIED;
 717         }
 718         | context_def_spec_body context_mod {
 719                 if (!SCM_UNBNDP ($2)) {
 720                         Context_def *td = Context_def::unsmob ($$);
 721                         if (!td) {
 722                                 $$ = Context_def::make_scm ();
 723                                 td = Context_def::unsmob ($$);
 724                         }
 725                         Context_def::unsmob ($$)->add_context_mod ($2);
 726                 }
 727         }
 728         | context_def_spec_body context_modification {
 729                 Context_def *td = Context_def::unsmob ($$);
 730                 if (!td) {
 731                         $$ = Context_def::make_scm ();
 732                         td = Context_def::unsmob ($$);
 733                 }
 734                 SCM new_mods = Context_mod::unsmob ($2)->get_mods ();
 735                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 736                     td->add_context_mod (scm_car (m));
 737                 }
 738         }
 739         | context_def_spec_body context_mod_arg {
 740                 Context_def *td = Context_def::unsmob ($1);
 741                 if (scm_is_eq ($2, SCM_UNSPECIFIED))
 742                         ;
 743                 else if (!td && Context_def::unsmob ($2))
 744                         $$ = $2;
 745                 else {
 746                         if (!td) {
 747                                 $$ = Context_def::make_scm ();
 748                                 td = Context_def::unsmob ($$);
 749                         }
 750                         if (Music::is_smob ($2)) {
 751                                 SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
 752                                 $2 = scm_call_2 (proc, parser->self_scm (), $2);
 753                         }
 754                         if (Context_mod *cm = Context_mod::unsmob ($2)) {
 755                                 for (SCM m = cm->get_mods (); scm_is_pair (m); m = scm_cdr (m)) {
 756                                         td->add_context_mod (scm_car (m));
 757                                 }
 758                         } else
 759                                 parser->parser_error (@2, _ ("not a context mod"));
 760                 }
 761         }
 762         ;
 763
 764
 765
 766 book_block:
 767         BOOK '{' book_body '}'  {
 768                 $$ = $3;
 769                 Book::unsmob ($$)->origin ()->set_spot (@$);
 770                 pop_paper (parser);
 771                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 772         }
 773         ;
 774
 775 /* FIXME:
 776    * Use 'handlers' like for toplevel-* stuff?
 777    * grok \layout and \midi?  */
 778 book_body:
 779         {
 780                 Book *book = new Book;
 781                 init_papers (parser);
 782                 book->paper_ = dynamic_cast<Output_def*> (Output_def::unsmob (parser->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 783                 book->paper_->unprotect ();
 784                 push_paper (parser, book->paper_);
 785                 book->header_ = get_header (parser);
 786                 $$ = book->unprotect ();
 787                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$);
 788         }
 789         | BOOK_IDENTIFIER {
 790                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 791         }
 792         | book_body paper_block {
 793                 Book::unsmob ($1)->paper_ = Output_def::unsmob ($2);
 794                 set_paper (parser, Output_def::unsmob ($2));
 795         }
 796         | book_body bookpart_block {
 797                 SCM proc = parser->lexer_->lookup_identifier ("book-bookpart-handler");
 798                 scm_call_2 (proc, $1, $2);
 799         }
 800         | book_body score_block {
 801                 SCM proc = parser->lexer_->lookup_identifier ("book-score-handler");
 802                 scm_call_2 (proc, $1, $2);
 803         }
 804         | book_body composite_music {
 805                 SCM proc = parser->lexer_->lookup_identifier ("book-music-handler");
 806                 scm_call_3 (proc, parser->self_scm (), $1, $2);
 807         }
 808         | book_body full_markup {
 809                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 810                 scm_call_2 (proc, $1, scm_list_1 ($2));
 811         }
 812         | book_body full_markup_list {
 813                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 814                 scm_call_2 (proc, $1, $2);
 815         }
 816         | book_body SCM_TOKEN {
 817                 // Evaluate and ignore #xxx, as opposed to \xxx
 818                 parser->lexer_->eval_scm_token ($2, @2);
 819         }
 820         | book_body embedded_scm_active
 821         {
 822                 SCM out = SCM_UNDEFINED;
 823                 if (Text_interface::is_markup ($2))
 824                         out = scm_list_1 ($2);
 825                 else if (Text_interface::is_markup_list ($2))
 826                         out = $2;
 827                 if (scm_is_pair (out))
 828                 {
 829                         SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 830                         scm_call_2 (proc, $1, out);
 831                 } else if (Score::is_smob ($2))
 832                 {
 833                         SCM proc = parser->lexer_->lookup_identifier ("book-score-handler");
 834                         scm_call_2 (proc, $1, $2);
 835                 } else if (Output_def *od = Output_def::unsmob ($2)) {
 836                         SCM id = SCM_EOL;
 837
 838                         if (od->c_variable ("is-paper") == SCM_BOOL_T)
 839                                 id = ly_symbol2scm ("$defaultpaper");
 840                         else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 841                                 id = ly_symbol2scm ("$defaultmidi");
 842                         else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 843                                 id = ly_symbol2scm ("$defaultlayout");
 844
 845                         parser->lexer_->set_identifier (id, $2);
 846                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
 847                         parser->parser_error (@2, _("bad expression type"));
 848         }
 849         | book_body
 850         {
 851                 parser->lexer_->add_scope (Book::unsmob ($1)->header_);
 852         } lilypond_header
 853         | book_body error {
 854                 Book *book = Book::unsmob ($1);
 855                 book->paper_ = 0;
 856                 book->scores_ = SCM_EOL;
 857                 book->bookparts_ = SCM_EOL;
 858         }
 859         ;
 860
 861 bookpart_block:
 862         BOOKPART '{' bookpart_body '}' {
 863                 $$ = $3;
 864                 Book::unsmob ($$)->origin ()->set_spot (@$);
 865                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 866         }
 867         ;
 868
 869 bookpart_body:
 870         {
 871                 Book *book = new Book;
 872                 $$ = book->unprotect ();
 873                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$);
 874         }
 875         | BOOK_IDENTIFIER {
 876                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 877         }
 878         | bookpart_body paper_block {
 879                 Book::unsmob ($$)->paper_ = Output_def::unsmob ($2);
 880         }
 881         | bookpart_body score_block {
 882                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-score-handler");
 883                 scm_call_2 (proc, $1, $2);
 884         }
 885         | bookpart_body composite_music {
 886                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-music-handler");
 887                 scm_call_3 (proc, parser->self_scm (), $1, $2);
 888         }
 889         | bookpart_body full_markup {
 890                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 891                 scm_call_2 (proc, $1, scm_list_1 ($2));
 892         }
 893         | bookpart_body full_markup_list {
 894                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 895                 scm_call_2 (proc, $1, $2);
 896         }
 897         | bookpart_body SCM_TOKEN {
 898                 // Evaluate and ignore #xxx, as opposed to \xxx
 899                 parser->lexer_->eval_scm_token ($2, @2);
 900         }
 901         | bookpart_body embedded_scm_active
 902         {
 903                 SCM out = SCM_UNDEFINED;
 904                 if (Text_interface::is_markup ($2))
 905                         out = scm_list_1 ($2);
 906                 else if (Text_interface::is_markup_list ($2))
 907                         out = $2;
 908                 if (scm_is_pair (out))
 909                 {
 910                         SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 911                         scm_call_2 (proc, $1, out);
 912                 } else if (Score::is_smob ($2))
 913                 {
 914                         SCM proc = parser->lexer_->lookup_identifier ("bookpart-score-handler");
 915                         scm_call_2 (proc, $1, $2);
 916                 } else if (Output_def *od = Output_def::unsmob ($2)) {
 917                         SCM id = SCM_EOL;
 918
 919                         if (od->c_variable ("is-paper") == SCM_BOOL_T)
 920                                 id = ly_symbol2scm ("$defaultpaper");
 921                         else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 922                                 id = ly_symbol2scm ("$defaultmidi");
 923                         else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 924                                 id = ly_symbol2scm ("$defaultlayout");
 925
 926                         parser->lexer_->set_identifier (id, $2);
 927                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
 928                         parser->parser_error (@2, _("bad expression type"));
 929         }
 930         | bookpart_body
 931         {
 932                 Book *book = Book::unsmob ($1);
 933                 if (!ly_is_module (book->header_))
 934                         book->header_ = ly_make_module (false);
 935                 parser->lexer_->add_scope (book->header_);
 936         } lilypond_header
 937         | bookpart_body error {
 938                 Book *book = Book::unsmob ($1);
 939                 book->paper_ = 0;
 940                 book->scores_ = SCM_EOL;
 941         }
 942         ;
 943
 944 score_block:
 945         SCORE '{' score_body '}'        {
 946                 Score::unsmob ($3)->origin ()->set_spot (@$);
 947                 $$ = $3;
 948         }
 949         ;
 950
 951 score_body:
 952         score_items {
 953                 if (!Score::is_smob ($1)) {
 954                         parser->parser_error (@1, _("Missing music in \\score"));
 955                         $$ = (new Score)->unprotect ();
 956                         if (scm_is_pair ($1) && ly_is_module (scm_car ($1)))
 957                         {
 958                                 Score::unsmob ($$)->set_header (scm_car ($1));
 959                                 $1 = scm_cdr ($1);
 960                         }
 961                         for (SCM p = scm_reverse_x ($1, SCM_EOL);
 962                              scm_is_pair (p); p = scm_cdr (p))
 963                         {
 964                                 Score::unsmob ($$)->
 965                                         add_output_def (Output_def::unsmob (scm_car (p)));
 966                         }
 967                 }
 968         }
 969         | score_body error {
 970                 Score::unsmob ($$)->error_found_ = true;
 971         }
 972         ;
 973
 974 score_item:
 975         embedded_scm
 976         | music
 977         | output_def
 978         ;
 979
 980 score_items:
 981         /* empty */
 982         {
 983                 $$ = SCM_EOL;
 984         }
 985         | score_items score_item
 986         {
 987                 Output_def *od = Output_def::unsmob ($2);
 988                 if (od) {
 989                         if (od->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 990                         {
 991                                 parser->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 992                                 od = 0;
 993                                 $2 = SCM_UNSPECIFIED;
 994                         }
 995                 } else if (!Score::is_smob ($$)) {
 996                         if (Music::is_smob ($2)) {
 997                                 SCM scorify = ly_lily_module_constant ("scorify-music");
 998                                 $2 = scm_call_2 (scorify, $2, parser->self_scm ());
 999                         }
1000                         if (Score::is_smob ($2))
1001                         {
1002                                 $$ = $2;
1003                                 $2 = SCM_UNSPECIFIED;
1004                         }
1005                 }
1006                 Score *score = Score::unsmob ($$);
1007                 if (score && scm_is_pair ($1)) {
1008                         if (ly_is_module (scm_car ($1)))
1009                         {
1010                                 score->set_header (scm_car ($1));
1011                                 $1 = scm_cdr ($1);
1012                         }
1013                         for (SCM p = scm_reverse_x ($1, SCM_EOL);
1014                              scm_is_pair (p); p = scm_cdr (p))
1015                         {
1016                                 score->add_output_def (Output_def::unsmob (scm_car (p)));
1017                         }
1018                 }
1019                 if (od) {
1020                         if (score)
1021                                 score->add_output_def (od);
1022                         else if (scm_is_pair ($$) && ly_is_module (scm_car ($$)))
1023                                 scm_set_cdr_x ($$, scm_cons ($2, scm_cdr ($$)));
1024                         else
1025                                 $$ = scm_cons ($2, $$);
1026                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
1027                         parser->parser_error (@2, _("Spurious expression in \\score"));
1028         }
1029         | score_items
1030         {
1031                 if (Score *score = Score::unsmob ($1)) {
1032                         if (!ly_is_module (score->get_header ()))
1033                                 score->set_header (ly_make_module (false));
1034                         parser->lexer_->add_scope (score->get_header ());
1035                 } else {
1036                         if (!scm_is_pair ($1) || !ly_is_module (scm_car ($1)))
1037                                 $1 = scm_cons (ly_make_module (false), $1);
1038                         parser->lexer_->add_scope (scm_car ($1));
1039                 }
1040         } lilypond_header
1041         {
1042                 $$ = $1;
1043         }
1044         ;
1045
1046
1047 /*
1048         OUTPUT DEF
1049 */
1050
1051 paper_block:
1052         output_def {
1053                 Output_def *od = Output_def::unsmob ($1);
1054
1055                 if (od->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
1056                 {
1057                         parser->parser_error (@1, _ ("need \\paper for paper block"));
1058                         $$ = get_paper (parser)->unprotect ();
1059                 }
1060         }
1061         ;
1062
1063
1064 output_def:
1065         output_def_body '}' {
1066                 if (scm_is_pair ($1))
1067                         $$ = scm_car ($1);
1068
1069                 parser->lexer_->remove_scope ();
1070                 parser->lexer_->pop_state ();
1071         }
1072         ;
1073
1074 output_def_head:
1075         PAPER {
1076                 Output_def *p = get_paper (parser);
1077                 p->input_origin_ = @$;
1078                 parser->lexer_->add_scope (p->scope_);
1079                 $$ = p->unprotect ();
1080         }
1081         | MIDI    {
1082                 Output_def *p = get_midi (parser);
1083                 $$ = p->unprotect ();
1084                 parser->lexer_->add_scope (p->scope_);
1085         }
1086         | LAYOUT        {
1087                 Output_def *p = get_layout (parser);
1088
1089                 parser->lexer_->add_scope (p->scope_);
1090                 $$ = p->unprotect ();
1091         }
1092         ;
1093
1094 output_def_head_with_mode_switch:
1095         output_def_head {
1096                 parser->lexer_->push_initial_state ();
1097                 $$ = $1;
1098         }
1099         ;
1100
1101 // We need this weird nonterminal because both music as well as a
1102 // context definition can start with \context and the difference is
1103 // only apparent after looking at the next token.  If it is '{', there
1104 // is still time to escape from notes mode.
1105
1106 music_or_context_def:
1107         music_assign
1108         | context_def_spec_block
1109         ;
1110
1111 output_def_body:
1112         output_def_head_with_mode_switch '{' {
1113                 Output_def::unsmob ($1)->input_origin_.set_spot (@$);
1114                 // This is a stupid trick to mark the beginning of the
1115                 // body for deciding whether to allow
1116                 // embedded_scm_active to have an output definition
1117                 $$ = scm_list_1 ($1);
1118         }
1119         | output_def_body assignment  {
1120                 if (scm_is_pair ($1))
1121                         $$ = scm_car ($1);
1122         }
1123         | output_def_body embedded_scm_active
1124         {
1125                 // We don't switch into note mode for Scheme functions
1126                 // here.  Does not seem warranted/required in output
1127                 // definitions.
1128                 if (scm_is_pair ($1))
1129                 {
1130                         Output_def *o = Output_def::unsmob ($2);
1131                         if (o) {
1132                                 o->input_origin_.set_spot (@$);
1133                                 $1 = o->self_scm ();
1134                                 parser->lexer_->remove_scope ();
1135                                 parser->lexer_->add_scope (o->scope_);
1136                                 $2 = SCM_UNSPECIFIED;
1137                         } else
1138                                 $1 = scm_car ($1);
1139                 }
1140                 if (Context_def::is_smob ($2))
1141                         assign_context_def (Output_def::unsmob ($1), $2);
1142                 // Seems unlikely, but let's be complete:
1143                 else if (Music::is_smob ($2))
1144                 {
1145                         SCM proc = parser->lexer_->lookup_identifier
1146                                 ("output-def-music-handler");
1147                         scm_call_3 (proc, parser->self_scm (),
1148                                     $1, $2);
1149                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
1150                         parser->parser_error (@2, _("bad expression type"));
1151                 $$ = $1;
1152         }
1153         | output_def_body SCM_TOKEN {
1154                 if (scm_is_pair ($1))
1155                         $$ = scm_car ($1);
1156                 // Evaluate and ignore #xxx, as opposed to \xxx
1157                 parser->lexer_->eval_scm_token ($2, @2);
1158         }
1159         | output_def_body
1160         {
1161                 if (scm_is_pair ($1))
1162                         $1 = scm_car ($1);
1163                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
1164                 parser->lexer_->push_note_state (nn);
1165         } music_or_context_def
1166         {
1167                 parser->lexer_->pop_state ();
1168                 if (Context_def::is_smob ($3))
1169                         assign_context_def (Output_def::unsmob ($1), $3);
1170                 else {
1171
1172                         SCM proc = parser->lexer_->lookup_identifier
1173                                      ("output-def-music-handler");
1174                         scm_call_3 (proc, parser->self_scm (),
1175                                     $1, $3);
1176                 }
1177                 $$ = $1;
1178         }
1179         | output_def_body error {
1180
1181         }
1182         ;
1183
1184 tempo_event:
1185         TEMPO steno_duration '=' tempo_range    {
1186                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_EOL, $2, $4);
1187         }
1188         | TEMPO scalar steno_duration '=' tempo_range   {
1189                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
1190         }
1191         | TEMPO scalar {
1192                 $$ = MAKE_SYNTAX ("tempo", @$, $2);
1193         } %prec ':'
1194         ;
1195
1196 /*
1197 The representation of a  list is reversed to have efficient append.  */
1198
1199 music_list:
1200         /* empty */ {
1201                 $$ = SCM_EOL;
1202         }
1203         | music_list music_embedded {
1204                 if (Music::is_smob ($2))
1205                         $$ = scm_cons ($2, $1);
1206         }
1207         | music_list error {
1208                 Music *m = MY_MAKE_MUSIC("Music", @$);
1209                 // ugh. code dup
1210                 m->set_property ("error-found", SCM_BOOL_T);
1211                 $$ = scm_cons (m->self_scm (), $1);
1212                 m->unprotect (); /* UGH */
1213         }
1214         ;
1215
1216 braced_music_list:
1217         '{' music_list '}'
1218         {
1219                 $$ = scm_reverse_x ($2, SCM_EOL);
1220         }
1221         ;
1222
1223 music:  music_assign
1224         | lyric_element_music
1225         | pitch_as_music
1226         ;
1227
1228 pitch_as_music:
1229         pitch_or_music
1230         {
1231                 $$ = make_music_from_simple (parser, @1, $1);
1232                 if (!Music::is_smob ($$))
1233                 {
1234                         parser->parser_error (@1, _ ("music expected"));
1235                         $$ = MAKE_SYNTAX ("void-music", @$);
1236                 }
1237         }
1238         ;
1239
1240 music_embedded:
1241         music
1242         {
1243                 if (Music::unsmob ($1)->is_mus_type ("post-event")) {
1244                         parser->parser_error (@1, _ ("unexpected post-event"));
1245                         $$ = SCM_UNSPECIFIED;
1246                 }
1247         }
1248         | music_embedded_backup
1249         {
1250                 $$ = $1;
1251         }
1252         | music_embedded_backup BACKUP lyric_element_music
1253         {
1254                 $$ = $3;
1255         }
1256         | multiplied_duration post_events
1257         {
1258                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1259
1260                 parser->default_duration_ = *Duration::unsmob ($1);
1261                 n->set_property ("duration", $1);
1262
1263                 if (scm_is_pair ($2))
1264                         n->set_property ("articulations",
1265                                          scm_reverse_x ($2, SCM_EOL));
1266                 $$ = n->unprotect ();
1267         }
1268         ;
1269
1270 music_embedded_backup:
1271         embedded_scm
1272         {
1273                 if (scm_is_eq ($1, SCM_UNSPECIFIED))
1274                         $$ = $1;
1275                 else if (Music *m = Music::unsmob ($1)) {
1276                         if (m->is_mus_type ("post-event")) {
1277                                 parser->parser_error
1278                                         (@1, _ ("unexpected post-event"));
1279                                 $$ = SCM_UNSPECIFIED;
1280                         } else
1281                                 $$ = $1;
1282                 } else if (parser->lexer_->is_lyric_state ()
1283                            && Text_interface::is_markup ($1))
1284                         MYBACKUP (LYRIC_ELEMENT, $1, @1);
1285                 else {
1286                         @$.warning (_ ("Ignoring non-music expression"));
1287                         $$ = $1;
1288                 }
1289         }
1290         ;
1291
1292 // music_assign does not need to contain lyrics: there are no
1293 // assignments in lyricmode.
1294 music_assign:
1295         simple_music
1296         | composite_music %prec COMPOSITE
1297         ;
1298
1299 repeated_music:
1300         REPEAT simple_string unsigned_number music
1301         {
1302                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, SCM_EOL);
1303         }
1304         | REPEAT simple_string unsigned_number music ALTERNATIVE braced_music_list
1305         {
1306                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $6);
1307         }
1308         ;
1309
1310 sequential_music:
1311         SEQUENTIAL braced_music_list {
1312                 $$ = MAKE_SYNTAX ("sequential-music", @$, $2);
1313         }
1314         | braced_music_list {
1315                 $$ = MAKE_SYNTAX ("sequential-music", @$, $1);
1316         }
1317         ;
1318
1319 simultaneous_music:
1320         SIMULTANEOUS braced_music_list {
1321                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, $2);
1322         }
1323         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1324                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($2, SCM_EOL));
1325         }
1326         ;
1327
1328 simple_music:
1329         event_chord
1330         | music_property_def
1331         | context_change
1332         ;
1333
1334 context_modification:
1335         WITH
1336         {
1337                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
1338                 parser->lexer_->push_note_state (nn);
1339         } '{' context_mod_list '}'
1340         {
1341                 parser->lexer_->pop_state ();
1342                 $$ = $4;
1343         }
1344         | WITH CONTEXT_MOD_IDENTIFIER
1345         {
1346                 $$ = $2;
1347         }
1348         | CONTEXT_MOD_IDENTIFIER
1349         {
1350                 $$ = $1;
1351         }
1352         | WITH context_modification_arg
1353         {
1354                 if (Music::is_smob ($2)) {
1355                         SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
1356                         $2 = scm_call_2 (proc, parser->self_scm (), $2);
1357                 }
1358                 if (Context_mod::is_smob ($2))
1359                         $$ = $2;
1360                 else {
1361                         parser->parser_error (@2, _ ("not a context mod"));
1362                         $$ = Context_mod ().smobbed_copy ();
1363                 }
1364         }
1365         ;
1366
1367 context_modification_arg:
1368         embedded_scm
1369         | MUSIC_IDENTIFIER
1370         ;
1371
1372 optional_context_mod:
1373         /**/ {
1374             $$ = SCM_EOL;
1375         }
1376         | context_modification
1377         {
1378               $$ = $1;
1379         }
1380         ;
1381
1382 context_mod_list:
1383         /**/ {
1384             $$ = Context_mod ().smobbed_copy ();
1385         }
1386         | context_mod_list context_mod  {
1387                 if (!SCM_UNBNDP ($2))
1388                         Context_mod::unsmob ($1)->add_context_mod ($2);
1389         }
1390         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1391                  Context_mod *md = Context_mod::unsmob ($2);
1392                  if (md)
1393                      Context_mod::unsmob ($1)->add_context_mods (md->get_mods ());
1394         }
1395         | context_mod_list context_mod_arg {
1396                 if (scm_is_eq ($2, SCM_UNSPECIFIED))
1397                         ;
1398                 else if (Music::is_smob ($2)) {
1399                         SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
1400                         $2 = scm_call_2 (proc, parser->self_scm (), $2);
1401                 }
1402                 if (Context_mod::is_smob ($2))
1403                         Context_mod::unsmob ($$)->add_context_mods
1404                                 (Context_mod::unsmob ($2)->get_mods ());
1405                 else {
1406                         parser->parser_error (@2, _ ("not a context mod"));
1407                 }
1408         }
1409         ;
1410
1411 context_prefix:
1412         CONTEXT symbol optional_id optional_context_mod {
1413                 Context_mod *ctxmod = Context_mod::unsmob ($4);
1414                 SCM mods = SCM_EOL;
1415                 if (ctxmod)
1416                         mods = ctxmod->get_mods ();
1417                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_F);
1418         }
1419         | NEWCONTEXT symbol optional_id optional_context_mod {
1420                 Context_mod *ctxmod = Context_mod::unsmob ($4);
1421                 SCM mods = SCM_EOL;
1422                 if (ctxmod)
1423                         mods = ctxmod->get_mods ();
1424                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_T);
1425         }
1426         ;
1427
1428 new_lyrics:
1429         ADDLYRICS lyric_mode_music {
1430                 $$ = scm_list_1 ($2);
1431         }
1432         | new_lyrics ADDLYRICS lyric_mode_music {
1433                 $$ = scm_cons ($3, $1);
1434         }
1435         ;
1436
1437 /* basic_music is basically the same as composite_music but with
1438  * context-prefixed music and lyricized music explicitly removed.  The
1439  * reason is that in a sequence
1440  *
1441  *   \new Staff \new Voice { ... } \addlyrics { ... } \addlyrics { ... }
1442  *
1443  * we need to group both \addlyrics together (as they go with the same
1444  * voice) but then combine them with \new Voice { ... }, meaning that
1445  * combining \new Voice { ... } needs higher priority than
1446  * { ... } \addlyrics, and *not* have \new Staff \new Voice { ... }
1447  * combine before combining \new Voice { ... } \addlyrics: only one
1448  * layer of context-prefixed music should assemble before \addlyrics
1449  * is integrated.  Total mess, and we sort this mess out with explicit
1450  * rules preferring a single context-prefix.
1451  */
1452
1453 basic_music:
1454         music_function_call
1455         | repeated_music
1456         | music_bare
1457         | LYRICSTO simple_string lyric_mode_music {
1458                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, SCM_EOL, $3);
1459         }
1460         | LYRICSTO symbol '=' simple_string lyric_mode_music
1461         {
1462                 $$ = MAKE_SYNTAX ("lyric_combine", @$, $3, $2, $4);
1463         }
1464         ;
1465
1466 contextable_music:
1467         basic_music
1468         | pitch_as_music
1469         | event_chord
1470         ;
1471
1472 contexted_basic_music:
1473         context_prefix contextable_music new_lyrics
1474         {
1475                 Input i;
1476                 i.set_location (@1, @2);
1477                 $$ = FINISH_MAKE_SYNTAX ($1, i, $2);
1478                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $$, scm_reverse_x ($3, SCM_EOL));
1479         } %prec COMPOSITE
1480         | context_prefix contextable_music
1481         {
1482                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1483         } %prec COMPOSITE
1484         | context_prefix contexted_basic_music
1485         {
1486                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1487         }
1488         ;
1489
1490 composite_music:
1491         basic_music %prec COMPOSITE
1492         | contexted_basic_music
1493         | basic_music new_lyrics
1494         {
1495                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1496         } %prec COMPOSITE
1497         ;
1498
1499 music_bare:
1500         mode_changed_music
1501         | MUSIC_IDENTIFIER
1502         | grouped_music_list
1503         ;
1504
1505 grouped_music_list:
1506         simultaneous_music              { $$ = $1; }
1507         | sequential_music              { $$ = $1; }
1508         ;
1509
1510 /* Function argument lists are arguably the most complex part in the
1511  * parser.  They are pretty tricky to understand because of the way
1512  * they are processed, and because of optional arguments that can be
1513  * omitted.  When there are several optional arguments in a row,
1514  * omitting one automatically omits all following arguments.  Optional
1515  * arguments can only be omitted when either
1516  *
1517  * a) the omission is explicitly started with \default
1518  * b) the omission is implicitly started by an argument not matching
1519  *    its predicate, and there is a mandatory argument later that can
1520  *    "catch" the argument that does not fit.
1521  *
1522  * When argument parsing starts, the lexer pushes EXPECT_SCM tokens
1523  * (corresponding to mandatory arguments and having a predicate
1524  * function as semantic value) or EXPECT_OPTIONAL EXPECT_SCM (where
1525  * the semantic value of the EXPECT_OPTIONAL token is the default to
1526  * use when the optional argument is omitted, and EXPECT_SCM again has
1527  * the argument predicate as semantic value) in reverse order to the
1528  * parser, followed by EXPECT_NO_MORE_ARGS.  The argument list is then
1529  * processed inside-out while actual tokens are consumed.
1530  *
1531  * This means that the argument list tokens determine the actions
1532  * taken as they arrive.  The structure of the argument list is known
1533  * to the parser and stored in its parse stack when the first argument
1534  * is being parsed.  What the parser does not know is which predicates
1535  * will match and whether or not \default will be appearing in the
1536  * argument list, and where.
1537  *
1538  * Sequences of 0 or more optional arguments are scanned using either
1539  * function_arglist_backup or function_arglist_nonbackup.  The first
1540  * is used when optional arguments are followed by at least one
1541  * mandatory argument: in that case optional arguments may be skipped
1542  * by either a false predicate (in which case the expression will be
1543  * pushed back as one or more tokens, preceded by a BACKUP token) or
1544  * by using \default.
1545  *
1546  * If optional arguments are at the end of the argument list, they are
1547  * instead scanned using function_arglist_nonbackup: here the only
1548  * manner to enter into skipping of optional arguments is the use of
1549  * \default.
1550  *
1551  * The argument list of a normal function call is parsed using
1552  * function_arglist.  The part of an argument list before a mandatory
1553  * argument is parsed using function_arglist_optional.
1554  *
1555  * The difference is that leading optional arguments are scanned using
1556  * function_arglist_nonbackup and function_arglist_backup,
1557  * respectively.
1558  *
1559  * Most other details are obvious in the rules themselves.
1560  *
1561  */
1562
1563 symbol_list_arg:
1564         SYMBOL_LIST
1565         | SYMBOL_LIST '.' symbol_list_rev
1566         {
1567                 $$ = scm_append (scm_list_2 ($1, scm_reverse_x ($3, SCM_EOL)));
1568         }
1569         ;
1570
1571 symbol_list_rev:
1572         symbol_list_part
1573         | symbol_list_rev '.' symbol_list_part
1574         {
1575                 $$ = scm_append_x (scm_list_2 ($3, $1));
1576         }
1577         ;
1578
1579 // symbol_list_part delivers elements in reverse copy.
1580
1581 symbol_list_part:
1582         symbol_list_element
1583         {
1584                 SCM sym_l_p = ly_lily_module_constant ("symbol-list?");
1585                 $$ = try_string_variants (sym_l_p, $1);
1586                 if (SCM_UNBNDP ($$)) {
1587                         parser->parser_error (@1, _("not a symbol"));
1588                         $$ = SCM_EOL;
1589                 } else
1590                         $$ = scm_reverse ($$);
1591         }
1592         ;
1593
1594
1595 symbol_list_element:
1596         STRING
1597         | embedded_scm_bare
1598         ;
1599
1600
1601 function_arglist_nonbackup:
1602         function_arglist_common
1603         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup post_event_nofinger
1604         {
1605                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1606         }
1607         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' UNSIGNED
1608         {
1609                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1610                 if (scm_is_true (scm_call_1 ($2, n)))
1611                         $$ = scm_cons (n, $3);
1612                 else {
1613                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1614                         t->set_property ("digit", $5);
1615                         $$ = check_scheme_arg (parser, @4, t->unprotect (),
1616                                                $3, $2, n);
1617                 }
1618         }
1619         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' REAL
1620         {
1621                 $$ = check_scheme_arg (parser, @4,
1622                                        scm_difference ($5, SCM_UNDEFINED),
1623                                        $3, $2);
1624         }
1625         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' NUMBER_IDENTIFIER
1626         {
1627                 $$ = check_scheme_arg (parser, @4,
1628                                        scm_difference ($5, SCM_UNDEFINED),
1629                                        $3, $2);
1630         }
1631         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup embedded_scm_arg
1632         {
1633                 if (scm_is_true (scm_call_1 ($2, $4)))
1634                         $$ = scm_cons ($4, $3);
1635                 else
1636                         $$ = check_scheme_arg (parser, @4,
1637                                                make_music_from_simple
1638                                                (parser, @4, $4),
1639                                                $3, $2);
1640         }
1641         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup bare_number_common
1642         {
1643                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1644         }
1645         | function_arglist_nonbackup_reparse REPARSE pitch_or_music
1646         {
1647                 if (scm_is_true (scm_call_1 ($2, $3)))
1648                         $$ = scm_cons ($3, $1);
1649                 else
1650                         $$ = check_scheme_arg (parser, @3,
1651                                                make_music_from_simple
1652                                                (parser, @3, $3),
1653                                                $1, $2);
1654         }
1655         | function_arglist_nonbackup_reparse REPARSE duration_length
1656         {
1657                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1658         }
1659         | function_arglist_nonbackup_reparse REPARSE bare_number_common
1660         {
1661                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1662         }
1663         | function_arglist_nonbackup_reparse REPARSE SCM_ARG
1664         {
1665                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1666         }
1667         | function_arglist_nonbackup_reparse REPARSE lyric_element_music
1668         {
1669                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1670         }
1671         | function_arglist_nonbackup_reparse REPARSE symbol_list_arg
1672         {
1673                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1674         }
1675         ;
1676
1677 function_arglist_nonbackup_reparse:
1678         EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup SCM_IDENTIFIER
1679         {
1680                 $$ = $3;
1681                 SCM res = try_string_variants ($2, $4);
1682                 if (!SCM_UNBNDP (res))
1683                         if (scm_is_pair (res))
1684                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1685                         else
1686                                 MYREPARSE (@4, $2, SCM_ARG, res);
1687                 else if (scm_is_true
1688                          (scm_call_1
1689                           ($2, make_music_from_simple
1690                            (parser, @4, $4))))
1691                         MYREPARSE (@4, $2, STRING, $4);
1692                 else
1693                         MYREPARSE (@4, $2, SCM_ARG, $4);
1694         }
1695         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup pitch
1696         {
1697                 $$ = $3;
1698                 if (scm_is_true
1699                     (scm_call_1
1700                      ($2, make_music_from_simple
1701                       (parser, @4, $4))))
1702                         MYREPARSE (@4, $2, PITCH_IDENTIFIER, $4);
1703                 else
1704                         MYREPARSE (@4, $2, SCM_ARG, $4);
1705         }
1706         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup steno_tonic_pitch
1707         {
1708                 $$ = $3;
1709                 if (scm_is_true
1710                     (scm_call_1
1711                      ($2, make_music_from_simple
1712                       (parser, @4, $4))))
1713                         MYREPARSE (@4, $2, TONICNAME_PITCH, $4);
1714                 else
1715                         MYREPARSE (@4, $2, SCM_ARG, $4);
1716         }
1717         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup STRING
1718         {
1719                 $$ = $3;
1720                 SCM res = try_string_variants ($2, $4);
1721                 if (!SCM_UNBNDP (res))
1722                         if (scm_is_pair (res))
1723                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1724                         else
1725                                 MYREPARSE (@4, $2, SCM_ARG, res);
1726                 else if (scm_is_true
1727                          (scm_call_1
1728                           ($2, make_music_from_simple
1729                            (parser, @4, $4))))
1730                         MYREPARSE (@4, $2, STRING, $4);
1731                 else
1732                         MYREPARSE (@4, $2, SCM_ARG, $4);
1733         }
1734         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup full_markup
1735         {
1736                 $$ = $3;
1737                 if (scm_is_true (scm_call_1 ($2, $4)))
1738                         MYREPARSE (@4, $2, SCM_ARG, $4);
1739                 else if (scm_is_true
1740                          (scm_call_1
1741                           ($2, make_music_from_simple
1742                            (parser, @4, $4))))
1743                         MYREPARSE (@4, $2, STRING, $4);
1744                 else
1745                         MYREPARSE (@4, $2, SCM_ARG, $4);
1746         }
1747         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup UNSIGNED
1748         {
1749                 $$ = $3;
1750                 if (scm_is_true (scm_call_1 ($2, $4)))
1751                         MYREPARSE (@4, $2, REAL, $4);
1752                 else {
1753                         SCM d = make_duration ($4);
1754                         if (SCM_UNBNDP (d) || scm_is_false (scm_call_1 ($2, d)))
1755                                 MYREPARSE (@4, $2, REAL, $4); // trigger error
1756                         else
1757                                 MYREPARSE (@4, $2, DURATION_IDENTIFIER, d);
1758                 }
1759         }
1760         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup DURATION_IDENTIFIER {
1761                 $$ = $3;
1762                 MYREPARSE (@4, $2, DURATION_IDENTIFIER, $4);
1763         }
1764         ;
1765
1766
1767 // function_arglist_backup can't occur at the end of an argument
1768 // list.
1769 function_arglist_backup:
1770         function_arglist_common
1771         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup embedded_scm_arg
1772         {
1773                 if (scm_is_true (scm_call_1 ($2, $4)))
1774                         $$ = scm_cons ($4, $3);
1775                 else {
1776                         $$ = make_music_from_simple (parser, @4, $4);
1777                         if (scm_is_true (scm_call_1 ($2, $$)))
1778                                 $$ = scm_cons ($$, $3);
1779                         else
1780                         {
1781                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1782                                 MYBACKUP (SCM_ARG, $4, @4);
1783                         }
1784                 }
1785         }
1786         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup post_event_nofinger
1787         {
1788                 if (scm_is_true (scm_call_1 ($2, $4)))
1789                 {
1790                         $$ = scm_cons ($4, $3);
1791                 } else {
1792                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1793                         MYBACKUP (EVENT_IDENTIFIER, $4, @4);
1794                 }
1795         }
1796         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup pitch
1797         {
1798                 if (scm_is_true
1799                     (scm_call_1
1800                      ($2, make_music_from_simple
1801                       (parser, @4, $4))))
1802                 {
1803                         $$ = $3;
1804                         MYREPARSE (@4, $2, PITCH_IDENTIFIER, $4);
1805                 } else if (scm_is_true (scm_call_1 ($2, $4)))
1806                         $$ = scm_cons ($4, $3);
1807                 else {
1808                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1809                         MYBACKUP (PITCH_IDENTIFIER, $4, @4);
1810                 }
1811         }
1812         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup steno_tonic_pitch
1813         {
1814                 if (scm_is_true
1815                     (scm_call_1
1816                      ($2, make_music_from_simple
1817                       (parser, @4, $4))))
1818                 {
1819                         $$ = $3;
1820                         MYREPARSE (@4, $2, TONICNAME_PITCH, $4);
1821                 } else if (scm_is_true (scm_call_1 ($2, $4)))
1822                         $$ = scm_cons ($4, $3);
1823                 else {
1824                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1825                         MYBACKUP (TONICNAME_PITCH, $4, @4);
1826                 }
1827         }
1828         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup full_markup
1829         {
1830                 if (scm_is_true (scm_call_1 ($2, $4)))
1831                         $$ = scm_cons ($4, $3);
1832                 else {
1833                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1834                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
1835                 }
1836         }
1837         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup UNSIGNED
1838         {
1839                 if (scm_is_true (scm_call_1 ($2, $4)))
1840                 {
1841                         MYREPARSE (@4, $2, REAL, $4);
1842                         $$ = $3;
1843                 } else {
1844                         SCM d = make_duration ($4);
1845                         if (SCM_UNBNDP (d) || scm_is_false (scm_call_1 ($2, d)))
1846                         {
1847                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1848                                 MYBACKUP (UNSIGNED, $4, @4);
1849                         } else {
1850                                 MYREPARSE (@4, $2, DURATION_IDENTIFIER, d);
1851                                 $$ = $3;
1852                         }
1853                 }
1854         }
1855         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup REAL
1856         {
1857                 if (scm_is_true (scm_call_1 ($2, $4)))
1858                 {
1859                         $$ = $3;
1860                         MYREPARSE (@4, $2, REAL, $4);
1861                 } else {
1862                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1863                         MYBACKUP (REAL, $4, @4);
1864                 }
1865         }
1866         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup NUMBER_IDENTIFIER
1867         {
1868                 if (scm_is_true (scm_call_1 ($2, $4)))
1869                 {
1870                         $$ = scm_cons ($4, $3);
1871                 } else {
1872                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1873                         MYBACKUP (NUMBER_IDENTIFIER, $4, @4);
1874                 }
1875         }
1876         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' UNSIGNED
1877         {
1878                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1879                 if (scm_is_true (scm_call_1 ($2, n))) {
1880                         $$ = $3;
1881                         MYREPARSE (@5, $2, REAL, n);
1882                 } else {
1883                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1884                         t->set_property ("digit", $5);
1885                         $$ = t->unprotect ();
1886                         if (scm_is_true (scm_call_1 ($2, $$)))
1887                                 $$ = scm_cons ($$, $3);
1888                         else {
1889                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1890                                 MYBACKUP (UNSIGNED, $5, @5);
1891                                 parser->lexer_->push_extra_token (@4, '-');
1892                         }
1893                 }
1894         }
1895         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' REAL
1896         {
1897                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1898                 if (scm_is_true (scm_call_1 ($2, n))) {
1899                         MYREPARSE (@5, $2, REAL, n);
1900                         $$ = $3;
1901                 } else {
1902                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1903                         MYBACKUP (REAL, n, @5);
1904                 }
1905         }
1906         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' NUMBER_IDENTIFIER
1907         {
1908                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1909                 if (scm_is_true (scm_call_1 ($2, n))) {
1910                         $$ = scm_cons (n, $3);
1911                 } else {
1912                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1913                         MYBACKUP (NUMBER_IDENTIFIER, n, @5);
1914                 }
1915         }
1916         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup DURATION_IDENTIFIER
1917         {
1918                 if (scm_is_true (scm_call_1 ($2, $4)))
1919                 {
1920                         MYREPARSE (@4, $2, DURATION_IDENTIFIER, $4);
1921                         $$ = $3;
1922                 } else {
1923                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1924                         MYBACKUP (DURATION_IDENTIFIER, $4, @4);
1925                 }
1926         }
1927         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup SCM_IDENTIFIER
1928         {
1929                 SCM res = try_string_variants ($2, $4);
1930                 if (!SCM_UNBNDP (res))
1931                         if (scm_is_pair (res)) {
1932                                 $$ = $3;
1933                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1934                         }
1935                         else
1936                                 $$ = scm_cons (res, $3);
1937                 else {
1938                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1939                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
1940                 }
1941         }
1942         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup STRING
1943         {
1944                 SCM res = try_string_variants ($2, $4);
1945                 if (!SCM_UNBNDP (res))
1946                         if (scm_is_pair (res)) {
1947                                 $$ = $3;
1948                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1949                         }
1950                         else
1951                                 $$ = scm_cons (res, $3);
1952                 else {
1953                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1954                         MYBACKUP (STRING, $4, @4);
1955                 }
1956         }
1957         | function_arglist_backup REPARSE pitch_or_music
1958         {
1959                 if (scm_is_true (scm_call_1 ($2, $3)))
1960                         $$ = scm_cons ($3, $1);
1961                 else
1962                         $$ = check_scheme_arg (parser, @3,
1963                                                make_music_from_simple
1964                                                (parser, @3, $3),
1965                                                $1, $2);
1966         }
1967         | function_arglist_backup REPARSE bare_number_common
1968         {
1969                 $$ = check_scheme_arg (parser, @3,
1970                                        $3, $1, $2);
1971         }
1972         | function_arglist_backup REPARSE duration_length
1973         {
1974                 $$ = check_scheme_arg (parser, @3,
1975                                        $3, $1, $2);
1976         }
1977         | function_arglist_backup REPARSE symbol_list_arg
1978         {
1979                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1980         }
1981         ;
1982
1983 function_arglist:
1984         function_arglist_nonbackup
1985         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_nonbackup DEFAULT
1986         {
1987                 $$ = scm_cons (loc_on_music (@4, $1), $3);
1988         }
1989         ;
1990
1991 function_arglist_skip_nonbackup:
1992         function_arglist_nonbackup
1993         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_nonbackup
1994         {
1995                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1996         }
1997         ;
1998
1999 function_arglist_common:
2000         EXPECT_NO_MORE_ARGS {
2001                 $$ = SCM_EOL;
2002         }
2003         | EXPECT_SCM function_arglist_optional embedded_scm_arg
2004         {
2005                 if (scm_is_true (scm_call_1 ($1, $3)))
2006                         $$ = scm_cons ($3, $2);
2007                 else
2008                         $$ = check_scheme_arg (parser, @3,
2009                                                make_music_from_simple
2010                                                (parser, @3, $3),
2011                                                $2, $1);
2012         }
2013         | EXPECT_SCM function_arglist_optional bare_number_common
2014         {
2015                 $$ = check_scheme_arg (parser, @3,
2016                                        $3, $2, $1);
2017         }
2018         | EXPECT_SCM function_arglist_optional post_event_nofinger
2019         {
2020                 $$ = check_scheme_arg (parser, @3,
2021                                        $3, $2, $1);
2022         }
2023         | EXPECT_SCM function_arglist_optional '-' NUMBER_IDENTIFIER
2024         {
2025                 SCM n = scm_difference ($4, SCM_UNDEFINED);
2026                 $$ = check_scheme_arg (parser, @4, n, $2, $1);
2027         }
2028         | function_arglist_common_reparse REPARSE SCM_ARG
2029         {
2030                 $$ = check_scheme_arg (parser, @3,
2031                                        $3, $1, $2);
2032         }
2033         | function_arglist_common_reparse REPARSE lyric_element_music
2034         {
2035                 $$ = check_scheme_arg (parser, @3,
2036                                        $3, $1, $2);
2037         }
2038         | function_arglist_common_reparse REPARSE pitch_or_music
2039         {
2040                 if (scm_is_true (scm_call_1 ($2, $3)))
2041                         $$ = scm_cons ($3, $1);
2042                 else
2043                         $$ = check_scheme_arg (parser, @3,
2044                                                make_music_from_simple
2045                                                (parser, @3, $3),
2046                                                $1, $2);
2047         }
2048         | function_arglist_common_reparse REPARSE bare_number_common
2049         {
2050                 $$ = check_scheme_arg (parser, @3,
2051                                        $3, $1, $2);
2052         }
2053         | function_arglist_common_reparse REPARSE duration_length
2054         {
2055                 $$ = check_scheme_arg (parser, @3,
2056                                        $3, $1, $2);
2057         }
2058         | function_arglist_common_reparse REPARSE symbol_list_arg
2059         {
2060                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
2061         }
2062         ;
2063
2064 function_arglist_common_reparse:
2065         EXPECT_SCM function_arglist_optional SCM_IDENTIFIER
2066         {
2067                 $$ = $2;
2068                 SCM res = try_string_variants ($1, $3);
2069                 if (!SCM_UNBNDP (res))
2070                         if (scm_is_pair (res))
2071                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
2072                         else
2073                                 MYREPARSE (@3, $1, SCM_ARG, res);
2074                 else if (scm_is_true
2075                          (scm_call_1
2076                           ($1, make_music_from_simple (parser, @3, $3))))
2077                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
2078                 else
2079                         // This is going to flag a syntax error, we
2080                         // know the predicate to be false.
2081                         MYREPARSE (@3, $1, SCM_ARG, $3);
2082         }
2083         | EXPECT_SCM function_arglist_optional pitch
2084         {
2085                 $$ = $2;
2086                 if (scm_is_true
2087                     (scm_call_1
2088                      ($1, make_music_from_simple
2089                       (parser, @3, $3))))
2090                         MYREPARSE (@3, $1, PITCH_IDENTIFIER, $3);
2091                 else
2092                         MYREPARSE (@3, $1, SCM_ARG, $3);
2093         }
2094         | EXPECT_SCM function_arglist_optional steno_tonic_pitch
2095         {
2096                 $$ = $2;
2097                 if (scm_is_true
2098                     (scm_call_1
2099                      ($1, make_music_from_simple
2100                       (parser, @3, $3))))
2101                         MYREPARSE (@3, $1, TONICNAME_PITCH, $3);
2102                 else
2103                         MYREPARSE (@3, $1, SCM_ARG, $3);
2104         }
2105         | EXPECT_SCM function_arglist_optional STRING
2106         {
2107                 $$ = $2;
2108                 SCM res = try_string_variants ($1, $3);
2109                 if (!SCM_UNBNDP (res))
2110                         if (scm_is_pair (res))
2111                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
2112                         else
2113                                 MYREPARSE (@3, $1, SCM_ARG, res);
2114                 else if (scm_is_true
2115                          (scm_call_1
2116                           ($1, make_music_from_simple (parser, @3, $3))))
2117                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
2118                 else
2119                         // This is going to flag a syntax error, we
2120                         // know the predicate to be false.
2121                         MYREPARSE (@3, $1, SCM_ARG, $3);
2122         }
2123         | EXPECT_SCM function_arglist_optional full_markup
2124         {
2125                 $$ = $2;
2126                 if (scm_is_true (scm_call_1 ($1, $3)))
2127                         MYREPARSE (@3, $1, SCM_ARG, $3);
2128                 else if (scm_is_true
2129                          (scm_call_1
2130                           ($1, make_music_from_simple (parser, @3, $3))))
2131                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
2132                 else
2133                         // This is going to flag a syntax error, we
2134                         // know the predicate to be false.
2135                         MYREPARSE (@3, $1, SCM_ARG, $3);
2136         }
2137         | EXPECT_SCM function_arglist_optional UNSIGNED
2138         {
2139                 $$ = $2;
2140                 if (scm_is_true (scm_call_1 ($1, $3)))
2141                         MYREPARSE (@3, $1, REAL, $3);
2142                 else {
2143                         SCM d = make_duration ($3);
2144                         if (SCM_UNBNDP (d) || scm_is_false (scm_call_1 ($1, d)))
2145                                 MYREPARSE (@3, $1, REAL, $3);
2146                         else
2147                                 MYREPARSE (@3, $1, DURATION_IDENTIFIER, d);
2148                 }
2149         }
2150         | EXPECT_SCM function_arglist_optional DURATION_IDENTIFIER
2151         {
2152                 $$ = $2;
2153                 MYREPARSE (@3, $1, DURATION_IDENTIFIER, $3);
2154         }
2155         | EXPECT_SCM function_arglist_optional '-' UNSIGNED
2156         {
2157                 $$ = $2;
2158                 SCM n = scm_difference ($4, SCM_UNDEFINED);
2159                 if (scm_is_true (scm_call_1 ($1, n)))
2160                         MYREPARSE (@4, $1, REAL, n);
2161                 else {
2162                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @4);
2163                         t->set_property ("digit", $4);
2164                         SCM m = t->unprotect ();
2165                         if (scm_is_true (scm_call_1 ($1, m)))
2166                                 MYREPARSE (@4, $1, SCM_ARG, m);
2167                         else
2168                                 MYREPARSE (@4, $1, SCM_ARG, $4);
2169                 }
2170         }
2171         | EXPECT_SCM function_arglist_optional '-' REAL
2172         {
2173                 $$ = $2;
2174                 SCM n = scm_difference ($4, SCM_UNDEFINED);
2175                 MYREPARSE (@4, $1, REAL, n);
2176         }
2177         ;
2178
2179 function_arglist_optional:
2180         function_arglist_backup
2181         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_backup DEFAULT
2182         {
2183                 $$ = scm_cons (loc_on_music (@4, $1), $3);
2184         }
2185         | function_arglist_skip_backup BACKUP
2186         ;
2187
2188 function_arglist_skip_backup:
2189         function_arglist_backup
2190         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_backup
2191         {
2192                 $$ = scm_cons (loc_on_music (@3, $1), $3);
2193         }
2194         ;
2195
2196 music_function_call:
2197         MUSIC_FUNCTION function_arglist {
2198                 $$ = MAKE_SYNTAX ("music-function", @$,
2199                                          $1, $2);
2200         }
2201         ;
2202
2203
2204 optional_id:
2205         /**/ { $$ = SCM_EOL; }
2206         | '=' simple_string {
2207                 $$ = $2;
2208         }
2209         ;
2210
2211 // We must not have lookahead tokens parsed in lyric mode.  In order
2212 // to save confusion, we take almost the same set as permitted with
2213 // \lyricmode and/or \lyrics.  However, music identifiers are also
2214 // allowed, and they obviously do not require switching into lyrics
2215 // mode for parsing.
2216
2217 lyric_mode_music:
2218         {
2219                 parser->lexer_->push_lyric_state ();
2220         } grouped_music_list
2221         {
2222                 parser->lexer_->pop_state ();
2223                 $$ = $2;
2224         }
2225         | MUSIC_IDENTIFIER
2226         ;
2227
2228 mode_changed_music:
2229         mode_changing_head grouped_music_list {
2230                 if ($1 == ly_symbol2scm ("chords"))
2231                 {
2232                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
2233                 }
2234                 else
2235                 {
2236                   $$ = $2;
2237                 }
2238                 parser->lexer_->pop_state ();
2239         }
2240         | mode_changing_head_with_context optional_context_mod grouped_music_list {
2241                 Context_mod *ctxmod = Context_mod::unsmob ($2);
2242                 SCM mods = SCM_EOL;
2243                 if (ctxmod)
2244                         mods = ctxmod->get_mods ();
2245                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, mods, SCM_BOOL_T, $3);
2246                 if ($1 == ly_symbol2scm ("ChordNames"))
2247                 {
2248                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
2249                 }
2250                 parser->lexer_->pop_state ();
2251         }
2252         ;
2253
2254 mode_changing_head:
2255         NOTEMODE {
2256                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
2257                 parser->lexer_->push_note_state (nn);
2258
2259                 $$ = ly_symbol2scm ("notes");
2260         }
2261         | DRUMMODE
2262                 {
2263                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
2264                 parser->lexer_->push_note_state (nn);
2265
2266                 $$ = ly_symbol2scm ("drums");
2267         }
2268         | FIGUREMODE {
2269                 parser->lexer_->push_figuredbass_state ();
2270
2271                 $$ = ly_symbol2scm ("figures");
2272         }
2273         | CHORDMODE {
2274                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
2275                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
2276                 nn = parser->lexer_->lookup_identifier ("pitchnames");
2277                 parser->lexer_->push_chord_state (nn);
2278                 $$ = ly_symbol2scm ("chords");
2279
2280         }
2281         | LYRICMODE
2282                 { parser->lexer_->push_lyric_state ();
2283                 $$ = ly_symbol2scm ("lyrics");
2284         }
2285         ;
2286
2287 mode_changing_head_with_context:
2288         DRUMS {
2289                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
2290                 parser->lexer_->push_note_state (nn);
2291
2292                 $$ = ly_symbol2scm ("DrumStaff");
2293         }
2294         | FIGURES {
2295                 parser->lexer_->push_figuredbass_state ();
2296
2297                 $$ = ly_symbol2scm ("FiguredBass");
2298         }
2299         | CHORDS {
2300                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
2301                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
2302                 nn = parser->lexer_->lookup_identifier ("pitchnames");
2303                 parser->lexer_->push_chord_state (nn);
2304                 $$ = ly_symbol2scm ("ChordNames");
2305         }
2306         | LYRICS
2307                 { parser->lexer_->push_lyric_state ();
2308                 $$ = ly_symbol2scm ("Lyrics");
2309         }
2310         ;
2311
2312 context_change:
2313         CHANGE symbol '=' simple_string  {
2314                 $$ = MAKE_SYNTAX ("context-change", @$, $2, $4);
2315         }
2316         ;
2317
2318
2319 property_path:
2320         symbol_list_rev  {
2321                 $$ = scm_reverse_x ($1, SCM_EOL);
2322         }
2323         | symbol_list_rev property_path {
2324                 $$ = scm_reverse_x ($1, $2);
2325         }
2326         ;
2327
2328 property_operation:
2329         symbol '=' scalar {
2330                 $$ = scm_list_3 (ly_symbol2scm ("assign"), $1, $3);
2331         }
2332         | UNSET symbol {
2333                 $$ = scm_list_2 (ly_symbol2scm ("unset"), $2);
2334         }
2335         | OVERRIDE property_path '=' scalar {
2336                 if (scm_ilength ($2) < 2) {
2337                         parser->parser_error (@2, _("bad grob property path"));
2338                         $$ = SCM_UNDEFINED;
2339                 } else {
2340                         $$ = scm_cons (ly_symbol2scm ("push"),
2341                                        scm_cons2 (scm_car ($2),
2342                                                   $4,
2343                                                   scm_cdr ($2)));
2344                 }
2345         }
2346         | REVERT revert_arg {
2347                 $$ = scm_cons (ly_symbol2scm ("pop"), $2);
2348         }
2349         ;
2350
2351 // This is all quite awkward for the sake of substantial backward
2352 // compatibility while at the same time allowing a more "natural" form
2353 // of specification not separating grob specification from grob
2354 // property path.  The purpose of this definition of revert_arg is to
2355 // allow the symbol list which specifies grob and property to revert
2356 // to be optionally be split into two parts after the grob (which in
2357 // this case is just the first element of the list).  symbol_list_part
2358 // is only one path component, but it can be parsed without lookahead,
2359 // so we can follow it with a synthetic BACKUP token when needed.  If
2360 // the first symbol_list_part already contains multiple elements (only
2361 // possible if a Scheme expression provides them), we just parse for
2362 // additional elements introduced by '.', which is what the
2363 // SYMBOL_LIST backup in connection with the immediately following
2364 // rule using symbol_list_arg does.
2365 //
2366 // As long as we don't have our coffers filled with both grob and at
2367 // least one grob property specification, the rest of the required
2368 // symbol list chain may be provided either with or without a leading
2369 // dot.  This is for both allowing the traditional
2370 // \revert Accidental #'color
2371 // as well as well as the "naive" form
2372 // \revert Accidental.color
2373
2374 revert_arg:
2375         revert_arg_backup BACKUP symbol_list_arg
2376         {
2377                 $$ = $3;
2378         }
2379         ;
2380
2381 revert_arg_backup:
2382         revert_arg_part
2383         {
2384                 if (scm_is_null ($1)
2385                     || scm_is_null (scm_cdr ($1)))
2386                         MYBACKUP (SCM_ARG, $1, @1);
2387                 else
2388                         MYBACKUP (SYMBOL_LIST, scm_reverse_x ($1, SCM_EOL), @1);
2389         }
2390         ;
2391
2392 // revert_arg_part delivers results in reverse
2393 revert_arg_part:
2394         symbol_list_part
2395         | revert_arg_backup BACKUP SCM_ARG '.' symbol_list_part
2396         {
2397                 $$ = scm_append_x (scm_list_2 ($5, $3));
2398         }
2399         | revert_arg_backup BACKUP SCM_ARG symbol_list_part
2400         {
2401                 $$ = scm_append_x (scm_list_2 ($4, $3));
2402         }
2403         ;
2404
2405 context_def_mod:
2406         CONSISTS { $$ = ly_symbol2scm ("consists"); }
2407         | REMOVE { $$ = ly_symbol2scm ("remove"); }
2408
2409         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
2410         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
2411         | DENIES { $$ = ly_symbol2scm ("denies"); }
2412
2413         | ALIAS { $$ = ly_symbol2scm ("alias"); }
2414         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
2415         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
2416         | NAME { $$ = ly_symbol2scm ("context-name"); }
2417         ;
2418
2419 context_mod:
2420         property_operation { $$ = $1; }
2421         | context_def_mod STRING {
2422                 $$ = scm_list_2 ($1, $2);
2423         }
2424         | context_def_mod embedded_scm
2425         {
2426                 if (!scm_is_string ($2)
2427                     && ly_symbol2scm ("consists") != $1
2428                     && ly_symbol2scm ("remove") != $1)
2429                 {
2430                         $$ = SCM_EOL;
2431                         parser->parser_error (@1, _ ("only \\consists and \\remove take non-string argument."));
2432                 }
2433                 else
2434                 {
2435                         $$ = scm_list_2 ($1, $2);
2436                 }
2437         }
2438         ;
2439
2440 // If defined, at least two members.
2441 grob_prop_spec:
2442         symbol_list_rev
2443         {
2444                 SCM l = scm_reverse_x ($1, SCM_EOL);
2445                 if (scm_is_pair (l)
2446                     && to_boolean
2447                     (scm_object_property (scm_car (l),
2448                                           ly_symbol2scm ("is-grob?"))))
2449                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2450                 if (scm_is_null (l) || scm_is_null (scm_cdr (l))) {
2451                         parser->parser_error (@1, _ ("bad grob property path"));
2452                         l = SCM_UNDEFINED;
2453                 }
2454                 $$ = l;
2455         }
2456         ;
2457
2458 // If defined, at least three members
2459 grob_prop_path:
2460         grob_prop_spec
2461         {
2462                 if (!SCM_UNBNDP ($1) && scm_is_null (scm_cddr ($1)))
2463                 {
2464                         parser->parser_error (@1, _ ("bad grob property path"));
2465                         $$ = SCM_UNDEFINED;
2466                 }
2467         }
2468         | grob_prop_spec property_path
2469         {
2470                 if (!SCM_UNBNDP ($1)) {
2471                         $$ = scm_append_x (scm_list_2 ($1, $2));
2472                         if (scm_is_null (scm_cddr ($$))) {
2473                                 parser->parser_error (@$, _ ("bad grob property path"));
2474                                 $$ = SCM_UNDEFINED;
2475                         }
2476                 }
2477
2478         }
2479         ;
2480
2481 // Exactly two elements or undefined
2482 context_prop_spec:
2483         symbol_list_rev
2484         {
2485                 SCM l = scm_reverse_x ($1, SCM_EOL);
2486                 switch (scm_ilength (l)) {
2487                 case 1:
2488                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2489                 case 2:
2490                         break;
2491                 default:
2492                         parser->parser_error (@1, _ ("bad context property path"));
2493                         l = SCM_UNDEFINED;
2494                 }
2495                 $$ = l;
2496         }
2497         ;
2498
2499 simple_music_property_def:
2500         OVERRIDE grob_prop_path '=' scalar {
2501                 if (SCM_UNBNDP ($2))
2502                         $$ = SCM_UNDEFINED;
2503                 else {
2504                         $$ = scm_list_5 (scm_car ($2),
2505                                          ly_symbol2scm ("OverrideProperty"),
2506                                          scm_cadr ($2),
2507                                          $4,
2508                                          scm_cddr ($2));
2509                 }
2510         }
2511         | REVERT simple_revert_context revert_arg {
2512                 $$ = scm_list_4 ($2,
2513                                  ly_symbol2scm ("RevertProperty"),
2514                                  scm_car ($3),
2515                                  scm_cdr ($3));
2516         }
2517         | SET context_prop_spec '=' scalar {
2518                 if (SCM_UNBNDP ($2))
2519                         $$ = SCM_UNDEFINED;
2520                 else
2521                         $$ = scm_list_4 (scm_car ($2),
2522                                          ly_symbol2scm ("PropertySet"),
2523                                          scm_cadr ($2),
2524                                          $4);
2525         }
2526         | UNSET context_prop_spec {
2527                 if (SCM_UNBNDP ($2))
2528                         $$ = SCM_UNDEFINED;
2529                 else
2530                         $$ = scm_list_3 (scm_car ($2),
2531                                          ly_symbol2scm ("PropertyUnset"),
2532                                          scm_cadr ($2));
2533         }
2534         ;
2535
2536
2537 // This is all quite awkward for the sake of substantial backward
2538 // compatibility while at the same time allowing a more "natural" form
2539 // of specification not separating grob specification from grob
2540 // property path.  The purpose of this definition of
2541 // simple_revert_context is to allow the symbol list which specifies
2542 // grob and property to revert to be optionally be split into two
2543 // parts after the grob (which may be preceded by a context
2544 // specification, a case which we distinguish by checking whether the
2545 // first symbol is a valid grob symbol instead).
2546 //
2547 // See revert_arg above for the main work horse of this arrangement.
2548 // simple_revert_context just caters for the context and delegates the
2549 // rest of the job to revert_arg.
2550
2551 simple_revert_context:
2552         symbol_list_part
2553         {
2554                 $1 = scm_reverse_x ($1, SCM_EOL);
2555                 if (scm_is_null ($1)
2556                     || to_boolean
2557                     (scm_object_property (scm_car ($1),
2558                                           ly_symbol2scm ("is-grob?")))) {
2559                         $$ = ly_symbol2scm ("Bottom");
2560                         parser->lexer_->push_extra_token (@1, SCM_IDENTIFIER, $1);
2561                 } else {
2562                         $$ = scm_car ($1);
2563                         parser->lexer_->push_extra_token (@1, SCM_IDENTIFIER,
2564                                                           scm_cdr ($1));
2565                 }
2566         }
2567         ;
2568
2569 music_property_def:
2570         simple_music_property_def {
2571                 if (SCM_UNBNDP ($1))
2572                         $$ = MAKE_SYNTAX ("void-music", @1);
2573                 else
2574                         $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons2 (parser->self_scm (), @$.smobbed_copy (), $1));
2575         }
2576         ;
2577
2578 string:
2579         STRING {
2580                 $$ = $1;
2581         }
2582         | full_markup
2583         ;
2584
2585 simple_string: STRING {
2586                 $$ = $1;
2587         }
2588         | embedded_scm_bare
2589         {
2590                 if (scm_is_string ($1)) {
2591                         $$ = $1;
2592                 } else {
2593                         parser->parser_error (@1, (_ ("simple string expected")));
2594                         $$ = scm_string (SCM_EOL);
2595                 }
2596         }
2597         ;
2598
2599 symbol:
2600         STRING {
2601                 $$ = scm_string_to_symbol ($1);
2602         }
2603         | embedded_scm_bare
2604         {
2605                 // This is a bit of overkill but makes the same
2606                 // routine responsible for all symbol interpretations.
2607                 $$ = try_string_variants (ly_lily_module_constant ("symbol?"),
2608                                           $1);
2609                 if (SCM_UNBNDP ($$))
2610                 {
2611                         parser->parser_error (@1, (_ ("symbol expected")));
2612                         // Generate a unique symbol in case it is used
2613                         // for an assignment or similar
2614                         $$ = scm_make_symbol (ly_string2scm ("undefined"));
2615                 }
2616         }
2617         ;
2618
2619 scalar:
2620         embedded_scm_arg
2621         | pitch_or_music
2622         | SCM_IDENTIFIER
2623         | bare_number
2624         // The following is a rather defensive variant of admitting
2625         // negative numbers: the grammar would permit number_factor or
2626         // even number_expression.  However, function arguments allow
2627         // only this simple kind of negative number, so to have things
2628         // like \tweak and \override behave reasonably similar, it
2629         // makes sense to rule out things like -- which are rather an
2630         // accent in function argument contexts.
2631         | '-' bare_number
2632         {
2633                 $$ = scm_difference ($2, SCM_UNDEFINED);
2634         }
2635         | string
2636         ;
2637
2638 event_chord:
2639         simple_element post_events {
2640                 // Let the rhythmic music iterator sort this mess out.
2641                 if (scm_is_pair ($2)) {
2642                         Music::unsmob ($$)->set_property ("articulations",
2643                                                          scm_reverse_x ($2, SCM_EOL));
2644                 }
2645         } %prec ':'
2646         | CHORD_REPETITION optional_notemode_duration post_events {
2647                 Input i;
2648                 i.set_location (@1, @3);
2649                 $$ = MAKE_SYNTAX ("repetition-chord", i,
2650                                   $2, scm_reverse_x ($3, SCM_EOL));
2651         } %prec ':'
2652         | MULTI_MEASURE_REST optional_notemode_duration post_events {
2653                 Input i;
2654                 i.set_location (@1, @3);
2655                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
2656                                   scm_reverse_x ($3, SCM_EOL));
2657         } %prec ':'
2658         | tempo_event
2659         | note_chord_element
2660         ;
2661
2662
2663 note_chord_element:
2664         chord_body optional_notemode_duration post_events
2665         {
2666                 Music *m = Music::unsmob ($1);
2667                 SCM dur = Duration::unsmob ($2)->smobbed_copy ();
2668                 SCM es = m->get_property ("elements");
2669                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
2670
2671                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
2672                   Music::unsmob (scm_car (s))->set_property ("duration", dur);
2673                 es = ly_append2 (es, postevs);
2674
2675                 m-> set_property ("elements", es);
2676                 m->set_spot (@$);
2677                 $$ = m->self_scm ();
2678         } %prec ':'
2679         ;
2680
2681 chord_body:
2682         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
2683         {
2684                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
2685         }
2686         | FIGURE_OPEN figure_list FIGURE_CLOSE
2687         {
2688                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
2689         }
2690         ;
2691
2692 chord_body_elements:
2693         /* empty */             { $$ = SCM_EOL; }
2694         | chord_body_elements chord_body_element {
2695                 if (!SCM_UNBNDP ($2))
2696                         $$ = scm_cons ($2, $1);
2697         }
2698         ;
2699
2700 chord_body_element:
2701         pitch_or_tonic_pitch exclamations questions octave_check post_events
2702         {
2703                 bool q = to_boolean ($3);
2704                 bool ex = to_boolean ($2);
2705                 SCM check = $4;
2706                 SCM post = $5;
2707
2708                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2709                 n->set_property ("pitch", $1);
2710                 if (q)
2711                         n->set_property ("cautionary", SCM_BOOL_T);
2712                 if (ex || q)
2713                         n->set_property ("force-accidental", SCM_BOOL_T);
2714
2715                 if (scm_is_pair (post)) {
2716                         SCM arts = scm_reverse_x (post, SCM_EOL);
2717                         n->set_property ("articulations", arts);
2718                 }
2719                 if (scm_is_number (check))
2720                 {
2721                         int q = scm_to_int (check);
2722                         n->set_property ("absolute-octave", scm_from_int (q-1));
2723                 }
2724
2725                 $$ = n->unprotect ();
2726         }
2727         | DRUM_PITCH post_events {
2728                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2729                 n->set_property ("drum-type", $1);
2730
2731                 if (scm_is_pair ($2)) {
2732                         SCM arts = scm_reverse_x ($2, SCM_EOL);
2733                         n->set_property ("articulations", arts);
2734                 }
2735                 $$ = n->unprotect ();
2736         }
2737         | music_function_chord_body
2738         {
2739                 Music *m = Music::unsmob ($1);
2740
2741                 while (m && m->is_mus_type ("music-wrapper-music")) {
2742                         $$ = m->get_property ("element");
2743                         m = Music::unsmob ($$);
2744                 }
2745
2746                 if (!(m && m->is_mus_type ("rhythmic-event"))) {
2747                         parser->parser_error (@$, _ ("not a rhythmic event"));
2748                         $$ = SCM_UNDEFINED;
2749                 }
2750         }
2751         ;
2752
2753 music_function_chord_body:
2754         music_function_call
2755         | MUSIC_IDENTIFIER
2756         | embedded_scm
2757         ;
2758
2759 event_function_event:
2760         EVENT_FUNCTION function_arglist {
2761                 $$ = MAKE_SYNTAX ("music-function", @$,
2762                                          $1, $2);
2763         }
2764         ;
2765
2766 post_events:
2767         /* empty */ {
2768                 $$ = SCM_EOL;
2769         }
2770         | post_events post_event {
2771                 $$ = $1;
2772                 if (Music *m = Music::unsmob ($2))
2773                 {
2774                         if (m->is_mus_type ("post-event-wrapper"))
2775                         {
2776                                 for (SCM p = m->get_property ("elements");
2777                                      scm_is_pair (p);
2778                                      p = scm_cdr (p))
2779                                 {
2780                                         $$ = scm_cons (scm_car (p), $$);
2781                                 }
2782                         } else {
2783                                 m->set_spot (@2);
2784                                 $$ = scm_cons ($2, $$);
2785                         }
2786                 }
2787         }
2788         ;
2789
2790 post_event_nofinger:
2791         direction_less_event {
2792                 $$ = $1;
2793         }
2794         | script_dir music_function_call {
2795                 $$ = $2;
2796                 if (!Music::unsmob ($2)->is_mus_type ("post-event")) {
2797                         parser->parser_error (@2, _ ("post-event expected"));
2798                         $$ = SCM_UNSPECIFIED;
2799                 } else if (!SCM_UNBNDP ($1))
2800                 {
2801                         Music::unsmob ($$)->set_property ("direction", $1);
2802                 }
2803         }
2804         | HYPHEN {
2805                 if (!parser->lexer_->is_lyric_state ())
2806                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2807                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
2808         }
2809         | EXTENDER {
2810                 if (!parser->lexer_->is_lyric_state ())
2811                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2812                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
2813         }
2814         | script_dir direction_reqd_event {
2815                 if (!SCM_UNBNDP ($1))
2816                 {
2817                         Music *m = Music::unsmob ($2);
2818                         m->set_property ("direction", $1);
2819                 }
2820                 $$ = $2;
2821         }
2822         | script_dir direction_less_event {
2823                 if (!SCM_UNBNDP ($1))
2824                 {
2825                         Music *m = Music::unsmob ($2);
2826                         m->set_property ("direction", $1);
2827                 }
2828                 $$ = $2;
2829         }
2830         | '^' fingering
2831         {
2832                 $$ = $2;
2833                 Music::unsmob ($$)->set_property ("direction", scm_from_int (UP));
2834         }
2835         | '_' fingering
2836         {
2837                 $$ = $2;
2838                 Music::unsmob ($$)->set_property ("direction", scm_from_int (DOWN));
2839         }
2840         ;
2841
2842 post_event:
2843         post_event_nofinger
2844         | '-' fingering {
2845                 $$ = $2;
2846         }
2847         ;
2848
2849 string_number_event:
2850         E_UNSIGNED {
2851                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
2852                 s->set_property ("string-number", $1);
2853                 $$ = s->unprotect ();
2854         }
2855         ;
2856
2857 direction_less_event:
2858         string_number_event
2859         | EVENT_IDENTIFIER      {
2860                 $$ = $1;
2861         }
2862         | tremolo_type  {
2863                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
2864                a->set_property ("tremolo-type", $1);
2865                $$ = a->unprotect ();
2866         }
2867         | event_function_event
2868         ;
2869
2870 direction_reqd_event:
2871         gen_text_def {
2872                 $$ = $1;
2873         }
2874         | script_abbreviation {
2875                 SCM s = parser->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
2876                 if (scm_is_string (s)) {
2877                         Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
2878                         a->set_property ("articulation-type", s);
2879                         $$ = a->unprotect ();
2880                 } else {
2881                         Music *original = Music::unsmob (s);
2882                         if (original && original->is_mus_type ("post-event")) {
2883                                 Music *a = original->clone ();
2884                                 a->set_spot (parser->lexer_->override_input (@$));
2885                                 $$ = a->unprotect ();
2886                         } else {
2887                                 parser->parser_error (@1, _ ("expecting string or post-event as script definition"));
2888                                 $$ = MY_MAKE_MUSIC ("PostEvents", @$)->unprotect ();
2889                         }
2890                 }
2891         }
2892         ;
2893
2894 octave_check:
2895         /**/ { $$ = SCM_EOL; }
2896         | '=' quotes { $$ = $2; }
2897         ;
2898
2899 quotes:
2900         /* empty */
2901         {
2902                 $$ = SCM_INUM0;
2903         }
2904         | sub_quotes
2905         | sup_quotes
2906         ;
2907
2908 sup_quotes:
2909         '\'' {
2910                 $$ = scm_from_int (1);
2911         }
2912         | sup_quotes '\'' {
2913                 $$ = scm_oneplus ($1);
2914         }
2915         ;
2916
2917 sub_quotes:
2918         ',' {
2919                 $$ = scm_from_int (-1);
2920         }
2921         | sub_quotes ',' {
2922                 $$ = scm_oneminus ($1);
2923         }
2924         ;
2925
2926 steno_pitch:
2927         NOTENAME_PITCH quotes {
2928                 if (!scm_is_eq (SCM_INUM0, $2))
2929                 {
2930                         Pitch p = *Pitch::unsmob ($1);
2931                         p = p.transposed (Pitch (scm_to_int ($2), 0));
2932                         $$ = p.smobbed_copy ();
2933                 }
2934         }
2935         ;
2936
2937 /*
2938 ugh. duplication
2939 */
2940
2941 steno_tonic_pitch:
2942         TONICNAME_PITCH quotes {
2943                 if (!scm_is_eq (SCM_INUM0, $2))
2944                 {
2945                         Pitch p = *Pitch::unsmob ($1);
2946                         p = p.transposed (Pitch (scm_to_int ($2), 0));
2947                         $$ = p.smobbed_copy ();
2948                 }
2949         }
2950         ;
2951
2952 pitch:
2953         steno_pitch
2954         | PITCH_IDENTIFIER quotes {
2955                 if (!scm_is_eq (SCM_INUM0, $2))
2956                 {
2957                         Pitch p = *Pitch::unsmob ($1);
2958                         p = p.transposed (Pitch (scm_to_int ($2), 0));
2959                         $$ = p.smobbed_copy ();
2960                 }
2961         }
2962         ;
2963
2964 pitch_or_tonic_pitch:
2965         pitch
2966         | steno_tonic_pitch
2967         ;
2968
2969 gen_text_def:
2970         full_markup {
2971                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2972                 t->set_property ("text", $1);
2973                 $$ = t->unprotect ();
2974         }
2975         | STRING {
2976                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2977                 t->set_property ("text",
2978                         make_simple_markup ($1));
2979                 $$ = t->unprotect ();
2980         }
2981         | embedded_scm
2982         {
2983                 Music *m = Music::unsmob ($1);
2984                 if (m && m->is_mus_type ("post-event"))
2985                         $$ = $1;
2986                 else if (Text_interface::is_markup ($1)) {
2987                         Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2988                         t->set_property ("text", $1);
2989                         $$ = t->unprotect ();
2990                 } else
2991                         parser->parser_error (@1, _ ("not an articulation"));
2992         }
2993         ;
2994
2995 fingering:
2996         UNSIGNED {
2997                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
2998                 t->set_property ("digit", $1);
2999                 $$ = t->unprotect ();
3000         }
3001         ;
3002
3003 script_abbreviation:
3004         '^'             {
3005                 $$ = scm_from_locale_string ("Hat");
3006         }
3007         | '+'           {
3008                 $$ = scm_from_locale_string ("Plus");
3009         }
3010         | '-'           {
3011                 $$ = scm_from_locale_string ("Dash");
3012         }
3013         | '!'           {
3014                 $$ = scm_from_locale_string ("Bang");
3015         }
3016         | ANGLE_CLOSE   {
3017                 $$ = scm_from_locale_string ("Larger");
3018         }
3019         | '.'           {
3020                 $$ = scm_from_locale_string ("Dot");
3021         }
3022         | '_' {
3023                 $$ = scm_from_locale_string ("Underscore");
3024         }
3025         ;
3026
3027 script_dir:
3028         '_'     { $$ = scm_from_int (DOWN); }
3029         | '^'   { $$ = scm_from_int (UP); }
3030         | '-'   { $$ = SCM_UNDEFINED; }
3031         ;
3032
3033 duration_length:
3034         multiplied_duration {
3035                 $$ = $1;
3036         }
3037         ;
3038
3039 maybe_notemode_duration:
3040         {
3041                 $$ = SCM_UNDEFINED;
3042         } %prec ':'
3043         | multiplied_duration   {
3044                 $$ = $1;
3045                 parser->default_duration_ = *Duration::unsmob ($$);
3046         }
3047 ;
3048
3049
3050 optional_notemode_duration:
3051         maybe_notemode_duration
3052         {
3053                 if (SCM_UNBNDP ($$))
3054                         $$ = parser->default_duration_.smobbed_copy ();
3055         }
3056         ;
3057
3058 steno_duration:
3059         UNSIGNED dots           {
3060                 $$ = make_duration ($1, scm_to_int ($2));
3061                 if (SCM_UNBNDP ($$))
3062                 {
3063                         parser->parser_error (@1, _ ("not a duration"));
3064                         $$ = Duration ().smobbed_copy ();
3065                 }
3066         }
3067         | DURATION_IDENTIFIER dots      {
3068                 Duration *d = Duration::unsmob ($1);
3069                 Duration k (d->duration_log (),
3070                             d->dot_count () + scm_to_int ($2));
3071                 k = k.compressed (d->factor ());
3072                 scm_remember_upto_here_1 ($1);
3073                 $$ = k.smobbed_copy ();
3074         }
3075         ;
3076
3077 multiplied_duration:
3078         steno_duration {
3079                 $$ = $1;
3080         }
3081         | multiplied_duration '*' UNSIGNED {
3082                 $$ = Duration::unsmob ($$)->compressed (scm_to_int ($3)).smobbed_copy ();
3083         }
3084         | multiplied_duration '*' FRACTION {
3085                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
3086
3087                 $$ = Duration::unsmob ($$)->compressed (m).smobbed_copy ();
3088         }
3089         ;
3090
3091 dots:
3092         /* empty */     {
3093                 $$ = SCM_INUM0;
3094         }
3095         | dots '.' {
3096                 $$ = scm_oneplus ($1);
3097         }
3098         ;
3099
3100 tremolo_type:
3101         ':'     {
3102                 $$ = scm_from_int (parser->default_tremolo_type_);
3103         }
3104         | ':' UNSIGNED {
3105                 if (SCM_UNBNDP (make_duration ($2))) {
3106                         parser->parser_error (@2, _ ("not a duration"));
3107                         $$ = scm_from_int (parser->default_tremolo_type_);
3108                 } else {
3109                         $$ = $2;
3110                         parser->default_tremolo_type_ = scm_to_int ($2);
3111                 }
3112         }
3113         ;
3114
3115 bass_number:
3116         UNSIGNED { $$ = $1; }
3117         | STRING { $$ = $1; }
3118         | full_markup { $$ = $1; }
3119         | embedded_scm_bare
3120         {
3121                 // as an integer, it needs to be non-negative, and otherwise
3122                 // it needs to be suitable as a markup.
3123                 if (scm_is_integer ($1)
3124                     ? scm_is_true (scm_negative_p ($1))
3125                     : !Text_interface::is_markup ($1))
3126                 {
3127                         parser->parser_error (@1, _ ("bass number expected"));
3128                         $$ = SCM_INUM0;
3129                 }
3130         }
3131         ;
3132
3133 figured_bass_alteration:
3134         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
3135         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
3136         | '!'   { $$ = scm_from_int (0); }
3137         ;
3138
3139 bass_figure:
3140         FIGURE_SPACE {
3141                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
3142                 $$ = bfr->unprotect ();
3143         }
3144         | bass_number  {
3145                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
3146                 $$ = bfr->self_scm ();
3147
3148                 if (scm_is_number ($1))
3149                         bfr->set_property ("figure", $1);
3150                 else if (Text_interface::is_markup ($1))
3151                         bfr->set_property ("text", $1);
3152
3153                 bfr->unprotect ();
3154         }
3155         | bass_figure ']' {
3156                 $$ = $1;
3157                 Music::unsmob ($1)->set_property ("bracket-stop", SCM_BOOL_T);
3158         }
3159         | bass_figure figured_bass_alteration {
3160                 Music *m = Music::unsmob ($1);
3161                 if (scm_to_double ($2)) {
3162                         SCM salter = m->get_property ("alteration");
3163                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
3164                         m->set_property ("alteration",
3165                                          scm_sum (alter, $2));
3166                 } else {
3167                         m->set_property ("alteration", scm_from_int (0));
3168                 }
3169         }
3170         | bass_figure figured_bass_modification  {
3171                 Music *m = Music::unsmob ($1);
3172                 m->set_property ($2, SCM_BOOL_T);
3173         }
3174         ;
3175
3176
3177 figured_bass_modification:
3178         E_PLUS          {
3179                 $$ = ly_symbol2scm ("augmented");
3180         }
3181         | E_EXCLAMATION {
3182                 $$ = ly_symbol2scm ("no-continuation");
3183         }
3184         | '/'           {
3185                 $$ = ly_symbol2scm ("diminished");
3186         }
3187         | E_BACKSLASH {
3188                 $$ = ly_symbol2scm ("augmented-slash");
3189         }
3190         ;
3191
3192 br_bass_figure:
3193         bass_figure {
3194                 $$ = $1;
3195         }
3196         | '[' bass_figure {
3197                 $$ = $2;
3198                 Music::unsmob ($$)->set_property ("bracket-start", SCM_BOOL_T);
3199         }
3200         ;
3201
3202 figure_list:
3203         /**/            {
3204                 $$ = SCM_EOL;
3205         }
3206         | figure_list br_bass_figure {
3207                 $$ = scm_cons ($2, $1);
3208         }
3209         ;
3210
3211 optional_rest:
3212         /**/   { $$ = SCM_BOOL_F; }
3213         | REST { $$ = SCM_BOOL_T; }
3214         ;
3215
3216 pitch_or_music:
3217         pitch exclamations questions octave_check maybe_notemode_duration optional_rest post_events {
3218                 if (!parser->lexer_->is_note_state ())
3219                         parser->parser_error (@1, _ ("have to be in Note mode for notes"));
3220                 if (!SCM_UNBNDP ($2)
3221                     || !SCM_UNBNDP ($3)
3222                     || scm_is_number ($4)
3223                     || !SCM_UNBNDP ($5)
3224                     || scm_is_true ($6)
3225                     || scm_is_pair ($7))
3226                 {
3227                         Music *n = 0;
3228                         if (scm_is_true ($6))
3229                                 n = MY_MAKE_MUSIC ("RestEvent", @$);
3230                         else
3231                                 n = MY_MAKE_MUSIC ("NoteEvent", @$);
3232
3233                         n->set_property ("pitch", $1);
3234                         if (SCM_UNBNDP ($5))
3235                                 n->set_property ("duration",
3236                                                  parser->default_duration_.smobbed_copy ());
3237                         else
3238                                 n->set_property ("duration", $5);
3239
3240                         if (scm_is_number ($4))
3241                         {
3242                                 int q = scm_to_int ($4);
3243                                 n->set_property ("absolute-octave", scm_from_int (q-1));
3244                         }
3245
3246                         if (to_boolean ($3))
3247                                 n->set_property ("cautionary", SCM_BOOL_T);
3248                         if (to_boolean ($2) || to_boolean ($3))
3249                                 n->set_property ("force-accidental", SCM_BOOL_T);
3250                         if (scm_is_pair ($7))
3251                                 n->set_property ("articulations",
3252                                                  scm_reverse_x ($7, SCM_EOL));
3253                         $$ = n->unprotect ();
3254                 }
3255         } %prec ':'
3256         | new_chord post_events {
3257                 if (!parser->lexer_->is_chord_state ())
3258                         parser->parser_error (@1, _ ("have to be in Chord mode for chords"));
3259                 if (scm_is_pair ($2)) {
3260                         if (Pitch::is_smob ($1))
3261                                 $1 = make_chord_elements (@1,
3262                                                           $1,
3263                                                           parser->default_duration_.smobbed_copy (),
3264                                                           SCM_EOL);
3265
3266                         SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
3267
3268                         $$ = MAKE_SYNTAX ("event-chord", @1, elts);
3269                 } else if (!Pitch::is_smob ($1))
3270                         $$ = MAKE_SYNTAX ("event-chord", @1, $1);
3271                 // A mere pitch drops through.
3272         } %prec ':'
3273         ;
3274
3275 simple_element:
3276         DRUM_PITCH optional_notemode_duration {
3277                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
3278                 n->set_property ("duration", $2);
3279                 n->set_property ("drum-type", $1);
3280
3281                 $$ = n->unprotect ();
3282         }
3283         | RESTNAME optional_notemode_duration           {
3284                 Music *ev = 0;
3285                 if (ly_scm2string ($1) == "s") {
3286                         /* Space */
3287                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
3288                   }
3289                 else {
3290                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
3291
3292                     }
3293                 ev->set_property ("duration", $2);
3294                 $$ = ev->unprotect ();
3295         }
3296         ;
3297
3298 lyric_element:
3299         full_markup {
3300                 if (!parser->lexer_->is_lyric_state ())
3301                         parser->parser_error (@1, _ ("markup outside of text script or \\lyricmode"));
3302                 $$ = $1;
3303         }
3304         | STRING {
3305                 if (!parser->lexer_->is_lyric_state ())
3306                         parser->parser_error (@1, _ ("unrecognized string, not in text script or \\lyricmode"));
3307                 $$ = $1;
3308         }
3309         | LYRIC_ELEMENT
3310         ;
3311
3312 lyric_element_music:
3313         lyric_element optional_notemode_duration post_events {
3314                 $$ = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
3315                 if (scm_is_pair ($3))
3316                         Music::unsmob ($$)->set_property
3317                                 ("articulations", scm_reverse_x ($3, SCM_EOL));
3318         } %prec ':'
3319         ;
3320
3321 // Can return a single pitch rather than a list.
3322 new_chord:
3323         steno_tonic_pitch maybe_notemode_duration   {
3324                 if (SCM_UNBNDP ($2))
3325                         $$ = $1;
3326                 else
3327                         $$ = make_chord_elements (@$, $1, $2, SCM_EOL);
3328         }
3329         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
3330                 SCM its = scm_reverse_x ($4, SCM_EOL);
3331                 $$ = make_chord_elements (@$, $1, $2, scm_cons ($3, its));
3332         } %prec ':'
3333         ;
3334
3335 chord_items:
3336         /**/ {
3337                 $$ = SCM_EOL;
3338         }
3339         | chord_items chord_item {
3340                 $$ = scm_cons ($2, $$);
3341         }
3342         ;
3343
3344 chord_separator:
3345         CHORD_COLON {
3346                 $$ = ly_symbol2scm ("chord-colon");
3347         }
3348         | CHORD_CARET {
3349                 $$ = ly_symbol2scm ("chord-caret");
3350         }
3351         | CHORD_SLASH steno_tonic_pitch {
3352                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
3353         }
3354         | CHORD_BASS steno_tonic_pitch {
3355                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
3356         }
3357         ;
3358
3359 chord_item:
3360         chord_separator {
3361                 $$ = $1;
3362         }
3363         | step_numbers {
3364                 $$ = scm_reverse_x ($1, SCM_EOL);
3365         }
3366         | CHORD_MODIFIER  {
3367                 $$ = $1;
3368         }
3369         ;
3370
3371 step_numbers:
3372         step_number { $$ = scm_cons ($1, SCM_EOL); }
3373         | step_numbers '.' step_number {
3374                 $$ = scm_cons ($3, $$);
3375         }
3376         ;
3377
3378 step_number:
3379         UNSIGNED {
3380                 $$ = make_chord_step ($1, 0);
3381         }
3382         | UNSIGNED '+' {
3383                 $$ = make_chord_step ($1, SHARP_ALTERATION);
3384         }
3385         | UNSIGNED CHORD_MINUS {
3386                 $$ = make_chord_step ($1, FLAT_ALTERATION);
3387         }
3388         ;
3389
3390 tempo_range:
3391         unsigned_number {
3392                 $$ = $1;
3393         } %prec ':'
3394         | unsigned_number '-' unsigned_number {
3395                 $$ = scm_cons ($1, $3);
3396         }
3397         ;
3398
3399 /*
3400         UTILITIES
3401
3402 TODO: should deprecate in favor of Scheme?
3403
3404  */
3405 number_expression:
3406         number_expression '+' number_term {
3407                 $$ = scm_sum ($1, $3);
3408         }
3409         | number_expression '-' number_term {
3410                 $$ = scm_difference ($1, $3);
3411         }
3412         | number_term
3413         ;
3414
3415 number_term:
3416         number_factor {
3417                 $$ = $1;
3418         }
3419         | number_factor '*' number_factor {
3420                 $$ = scm_product ($1, $3);
3421         }
3422         | number_factor '/' number_factor {
3423                 $$ = scm_divide ($1, $3);
3424         }
3425         ;
3426
3427 number_factor:
3428         '-'  number_factor { /* %prec UNARY_MINUS */
3429                 $$ = scm_difference ($2, SCM_UNDEFINED);
3430         }
3431         | bare_number
3432         ;
3433
3434 bare_number_common:
3435         REAL
3436         | NUMBER_IDENTIFIER
3437         | REAL NUMBER_IDENTIFIER
3438         {
3439                 $$ = scm_product ($1, $2);
3440         }
3441         ;
3442
3443 bare_number:
3444         bare_number_common
3445         | UNSIGNED
3446         | UNSIGNED NUMBER_IDENTIFIER    {
3447                 $$ = scm_product ($1, $2);
3448         }
3449         ;
3450
3451 unsigned_number:
3452         UNSIGNED
3453         | NUMBER_IDENTIFIER
3454         {
3455                 if (!scm_is_integer ($1)
3456                     || scm_is_true (scm_negative_p ($1)))
3457                 {
3458                         parser->parser_error (@1, _("not an unsigned integer"));
3459                         $$ = SCM_INUM0;
3460                 }
3461         }
3462         | embedded_scm
3463         {
3464                 if (!scm_is_integer ($1)
3465                     || scm_is_true (scm_negative_p ($1)))
3466                 {
3467                         parser->parser_error (@1, _("not an unsigned integer"));
3468                         $$ = SCM_INUM0;
3469                 }
3470         }
3471         ;
3472
3473 exclamations:
3474                 { $$ = SCM_UNDEFINED; }
3475         | exclamations '!'
3476         {
3477                 if (SCM_UNBNDP ($1))
3478                         $$ = SCM_BOOL_T;
3479                 else
3480                         $$ = scm_not ($1);
3481         }
3482         ;
3483
3484 questions:
3485 // This precedence rule is rather weird.  It triggers when '!' is
3486 // encountered after a pitch, and is used for deciding whether to save
3487 // this instead for a figure modification.  This should not actually
3488 // occur in practice as pitches and figures are generated in different
3489 // modes.  Using a greedy (%right) precedence makes sure that we don't
3490 // get stuck in a wrong interpretation.
3491         { $$ = SCM_UNDEFINED; } %prec ':'
3492         | questions '?'
3493         {
3494                 if (SCM_UNBNDP ($1))
3495                         $$ = SCM_BOOL_T;
3496                 else
3497                         $$ = scm_not ($1);
3498         }
3499         ;
3500
3501 full_markup_list:
3502         MARKUPLIST
3503                 { parser->lexer_->push_markup_state (); }
3504         markup_list {
3505                 $$ = $3;
3506                 parser->lexer_->pop_state ();
3507         }
3508         ;
3509
3510 full_markup:
3511         MARKUP
3512                 { parser->lexer_->push_markup_state (); }
3513         markup_top {
3514                 $$ = $3;
3515                 parser->lexer_->pop_state ();
3516         }
3517         ;
3518
3519 markup_top:
3520         markup_list {
3521                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
3522         }
3523         | markup_head_1_list simple_markup
3524         {
3525                 $$ = scm_car (MAKE_SYNTAX ("composed-markup-list",
3526                                            @2, $1, scm_list_1 ($2)));
3527         }
3528         | simple_markup {
3529                 $$ = $1;
3530         }
3531         ;
3532
3533 markup_scm:
3534         embedded_scm_bare
3535         {
3536                 if (Text_interface::is_markup ($1))
3537                         MYBACKUP (MARKUP_IDENTIFIER, $1, @1);
3538                 else if (Text_interface::is_markup_list ($1))
3539                         MYBACKUP (MARKUPLIST_IDENTIFIER, $1, @1);
3540                 else {
3541                         parser->parser_error (@1, _ ("not a markup"));
3542                         MYBACKUP (MARKUP_IDENTIFIER, scm_string (SCM_EOL), @1);
3543                 }
3544         } BACKUP
3545         ;
3546
3547
3548 markup_list:
3549         markup_composed_list {
3550                 $$ = $1;
3551         }
3552         | markup_uncomposed_list
3553         ;
3554
3555 markup_uncomposed_list:
3556         markup_braced_list {
3557                 $$ = $1;
3558         }
3559         | markup_command_list {
3560                 $$ = scm_list_1 ($1);
3561         }
3562         | markup_scm MARKUPLIST_IDENTIFIER
3563         {
3564                 $$ = $2;
3565         }
3566         | SCORELINES {
3567                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
3568                 parser->lexer_->push_note_state (nn);
3569         } '{' score_body '}' {
3570                 Score *sc = Score::unsmob ($4);
3571                 sc->origin ()->set_spot (@$);
3572                 if (sc->defs_.empty ()) {
3573                         Output_def *od = get_layout (parser);
3574                         sc->add_output_def (od);
3575                         od->unprotect ();
3576                 }
3577                 $$ = scm_list_1 (scm_list_2 (ly_lily_module_constant ("score-lines-markup-list"), $4));
3578                 parser->lexer_->pop_state ();
3579         }
3580         ;
3581
3582 markup_composed_list:
3583         markup_head_1_list markup_uncomposed_list {
3584                 $$ = MAKE_SYNTAX ("composed-markup-list",
3585                                   @2, $1, $2);
3586         }
3587         ;
3588
3589 markup_braced_list:
3590         '{' markup_braced_list_body '}' {
3591                 $$ = scm_reverse_x ($2, SCM_EOL);
3592         }
3593         ;
3594
3595 markup_braced_list_body:
3596         /* empty */     {  $$ = SCM_EOL; }
3597         | markup_braced_list_body markup {
3598                 $$ = scm_cons ($2, $1);
3599         }
3600         | markup_braced_list_body markup_list {
3601                 $$ = scm_reverse_x ($2, $1);
3602         }
3603         ;
3604
3605 markup_command_list:
3606         MARKUP_LIST_FUNCTION markup_command_list_arguments {
3607           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
3608         }
3609         ;
3610
3611 markup_command_basic_arguments:
3612         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
3613           $$ = scm_cons ($3, $2);
3614         }
3615         | EXPECT_SCM markup_command_list_arguments embedded_scm {
3616           $$ = check_scheme_arg (parser, @3, $3, $2, $1);
3617         }
3618         | EXPECT_NO_MORE_ARGS {
3619           $$ = SCM_EOL;
3620         }
3621         ;
3622
3623 markup_command_list_arguments:
3624         markup_command_basic_arguments { $$ = $1; }
3625         | EXPECT_MARKUP markup_command_list_arguments markup {
3626           $$ = scm_cons ($3, $2);
3627         }
3628         ;
3629
3630 markup_head_1_item:
3631         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
3632           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
3633         }
3634         ;
3635
3636 markup_head_1_list:
3637         markup_head_1_item      {
3638                 $$ = scm_list_1 ($1);
3639         }
3640         | markup_head_1_list markup_head_1_item {
3641                 $$ = scm_cons ($2, $1);
3642         }
3643         ;
3644
3645 simple_markup:
3646         STRING {
3647                 $$ = make_simple_markup ($1);
3648         }
3649         | SCORE {
3650                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
3651                 parser->lexer_->push_note_state (nn);
3652         } '{' score_body '}' {
3653                 Score *sc = Score::unsmob ($4);
3654                 sc->origin ()->set_spot (@$);
3655                 if (sc->defs_.empty ()) {
3656                         Output_def *od = get_layout (parser);
3657                         sc->add_output_def (od);
3658                         od->unprotect ();
3659                 }
3660                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), $4);
3661                 parser->lexer_->pop_state ();
3662         }
3663         | MARKUP_FUNCTION markup_command_basic_arguments {
3664                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
3665         }
3666         | markup_scm MARKUP_IDENTIFIER
3667         {
3668                 $$ = $2;
3669         }
3670         ;
3671
3672 markup:
3673         markup_head_1_list simple_markup
3674         {
3675                 $$ = scm_car (MAKE_SYNTAX ("composed-markup-list",
3676                                            @2, $1, scm_list_1 ($2)));
3677         }
3678         | simple_markup {
3679                 $$ = $1;
3680         }
3681         ;
3682
3683 %%
3684
3685 void
3686 Lily_parser::set_yydebug (bool x)
3687 {
3688         yydebug = x;
3689 }
3690
3691 SCM
3692 Lily_parser::do_yyparse ()
3693 {
3694         SCM retval = SCM_UNDEFINED;
3695         yyparse (this, &retval);
3696         return retval;
3697 }
3698
3699
3700
3701
3702
3703 /*
3704
3705 It is a little strange to have this function in this file, but
3706 otherwise, we have to import music classes into the lexer.
3707
3708 */
3709 int
3710 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
3711 {
3712         if (Book::is_smob (sid)) {
3713                 Book *book =  Book::unsmob (sid)->clone ();
3714                 *destination = book->self_scm ();
3715                 book->unprotect ();
3716
3717                 return BOOK_IDENTIFIER;
3718         } else if (scm_is_number (sid)) {
3719                 *destination = sid;
3720                 return NUMBER_IDENTIFIER;
3721         } else if (Context_def::is_smob (sid))
3722         {
3723                 *destination = Context_def::unsmob (sid)->clone ()->unprotect ();
3724                 return SCM_IDENTIFIER;
3725         } else if (Context_mod::is_smob (sid)) {
3726                 *destination = Context_mod::unsmob (sid)->smobbed_copy ();
3727                 return CONTEXT_MOD_IDENTIFIER;
3728         } else if (Music *mus = Music::unsmob (sid)) {
3729                 mus = mus->clone ();
3730                 *destination = mus->self_scm ();
3731                 bool is_event = mus->is_mus_type ("post-event");
3732                 mus->unprotect ();
3733                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
3734         } else if (Pitch::is_smob (sid)) {
3735                 *destination = Pitch::unsmob (sid)->smobbed_copy ();
3736                 return PITCH_IDENTIFIER;
3737         } else if (Duration::is_smob (sid)) {
3738                 *destination = Duration::unsmob (sid)->smobbed_copy ();
3739                 return DURATION_IDENTIFIER;
3740         } else if (Output_def::is_smob (sid)) {
3741                 *destination = Output_def::unsmob (sid)->clone ()->unprotect ();
3742                 return SCM_IDENTIFIER;
3743         } else if (Score::is_smob (sid)) {
3744                 *destination = Score::unsmob (sid)->clone ()->unprotect ();
3745                 return SCM_IDENTIFIER;
3746         }
3747
3748         return -1;
3749 }
3750
3751 SCM
3752 get_next_unique_context_id ()
3753 {
3754         return scm_from_locale_string ("$uniqueContextId");
3755 }
3756
3757
3758 SCM
3759 get_next_unique_lyrics_context_id ()
3760 {
3761         static int new_context_count;
3762         char s[128];
3763         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
3764         return scm_from_locale_string (s);
3765 }
3766
3767 // check_scheme_arg checks one argument with a given predicate for use
3768 // in an argument list and throws a syntax error if it is unusable.
3769 // The argument is prepended to the argument list in any case.  After
3770 // throwing a syntax error, the argument list is terminated with #f as
3771 // its last cdr in order to mark it as uncallable while not losing
3772 // track of its total length.
3773 //
3774 // There are a few special considerations: if optional argument disp
3775 // is given (otherwise it defaults to SCM_UNDEFINED), it will be used
3776 // instead of arg in a prospective error message.  This is useful if
3777 // arg is not the actual argument but rather a transformation of it.
3778 //
3779 // If arg itself is SCM_UNDEFINED, the predicate is considered false
3780 // and an error message using disp is produced unconditionally.
3781
3782 SCM check_scheme_arg (Lily_parser *parser, Input loc,
3783                       SCM arg, SCM args, SCM pred, SCM disp)
3784 {
3785         if (SCM_UNBNDP (arg))
3786                 args = scm_cons (disp, args);
3787         else {
3788                 args = scm_cons (arg, args);
3789                 if (scm_is_true (scm_call_1 (pred, arg)))
3790                         return args;
3791         }
3792         scm_set_cdr_x (scm_last_pair (args), SCM_EOL);
3793         MAKE_SYNTAX ("argument-error", loc, scm_length (args), pred,
3794                      SCM_UNBNDP (disp) ? arg : disp);
3795         scm_set_cdr_x (scm_last_pair (args), SCM_BOOL_F);
3796         return args;
3797 }
3798
3799 SCM loc_on_music (Input loc, SCM arg)
3800 {
3801         if (Music *m = Music::unsmob (arg))
3802         {
3803                 m = m->clone ();
3804                 m->set_spot (loc);
3805                 return m->unprotect ();
3806         }
3807         return arg;
3808 }
3809
3810 SCM
3811 try_string_variants (SCM pred, SCM str)
3812 {
3813         // a matching predicate is always ok
3814         if (scm_is_true (scm_call_1 (pred, str)))
3815                 return str;
3816         // a symbol may be interpreted as a list of symbols if it helps
3817         if (scm_is_symbol (str)) {
3818                 str = scm_list_1 (str);
3819                 if (scm_is_true (scm_call_1 (pred, str)))
3820                         return str;
3821                 return SCM_UNDEFINED;
3822         }
3823
3824         // If this cannot be a string representation of a symbol list,
3825         // we are through.
3826
3827         if (!is_regular_identifier (str, true))
3828                 return SCM_UNDEFINED;
3829
3830         str = scm_string_split (str, SCM_MAKE_CHAR ('.'));
3831         for (SCM p = str; scm_is_pair (p); p = scm_cdr (p))
3832                 scm_set_car_x (p, scm_string_to_symbol (scm_car (p)));
3833
3834         // Let's attempt the symbol list interpretation first.
3835
3836         if (scm_is_true (scm_call_1 (pred, str)))
3837                 return str;
3838
3839         // If there is just one symbol in the list, we might interpret
3840         // it as a single symbol
3841
3842         if (scm_is_null (scm_cdr (str)))
3843         {
3844                 str = scm_car (str);
3845                 if (scm_is_true (scm_call_1 (pred, str)))
3846                         return str;
3847         }
3848
3849         return SCM_UNDEFINED;
3850 }
3851
3852 bool
3853 is_regular_identifier (SCM id, bool multiple)
3854 {
3855   if (!scm_is_string (id))
3856           return false;
3857
3858   string str = ly_scm2string (id);
3859
3860   bool middle = false;
3861
3862   for (string::iterator it=str.begin(); it != str.end (); it++)
3863   {
3864           int c = *it & 0xff;
3865           if ((c >= 'a' && c <= 'z')
3866               || (c >= 'A' && c <= 'Z')
3867               || c > 0x7f)
3868                   middle = true;
3869           else if (middle && (c == '-' || c == '_' || (multiple && c == '.')))
3870                   middle = false;
3871           else
3872                   return false;
3873   }
3874   return middle;
3875 }
3876
3877 SCM
3878 make_music_from_simple (Lily_parser *parser, Input loc, SCM simple)
3879 {
3880         if (Music::is_smob (simple))
3881                 return simple;
3882         if (parser->lexer_->is_note_state ()) {
3883                 if (scm_is_symbol (simple)) {
3884                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
3885                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
3886                         n->set_property ("drum-type", simple);
3887                         return n->unprotect ();
3888                 }
3889                 if (Pitch::is_smob (simple)) {
3890                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
3891                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
3892                         n->set_property ("pitch", simple);
3893                         return n->unprotect ();
3894                 }
3895                 return simple;
3896         } else if (parser->lexer_->is_lyric_state ()) {
3897                 if (Text_interface::is_markup (simple))
3898                         return MAKE_SYNTAX ("lyric-event", loc, simple,
3899                                             parser->default_duration_.smobbed_copy ());
3900         } else if (parser->lexer_->is_chord_state ()) {
3901                 if (Pitch::is_smob (simple))
3902                         return MAKE_SYNTAX
3903                                 ("event-chord",
3904                                  loc,
3905                                  make_chord_elements (loc, simple,
3906                                                       parser->default_duration_.smobbed_copy (),
3907                                                       SCM_EOL));
3908         }
3909         return simple;
3910 }
3911
3912 Music *
3913 make_music_with_input (SCM name, Input where)
3914 {
3915        Music *m = make_music_by_name (name);
3916        m->set_spot (where);
3917        return m;
3918 }
3919
3920 SCM
3921 make_simple_markup (SCM a)
3922 {
3923         return a;
3924 }
3925
3926 SCM
3927 make_duration (SCM d, int dots)
3928 {
3929         int t = scm_to_int (d);
3930         if (t > 0 && (t & (t-1)) == 0)
3931                 return Duration (intlog2 (t), dots).smobbed_copy ();
3932         else
3933                 return SCM_UNDEFINED;
3934 }
3935
3936 SCM
3937 make_chord_step (SCM step_scm, Rational alter)
3938 {
3939         int step = scm_to_int (step_scm);
3940
3941         if (step == 7)
3942                 alter += FLAT_ALTERATION;
3943
3944         while (step < 0)
3945                 step += 7;
3946         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
3947         return m.smobbed_copy ();
3948 }
3949
3950
3951 SCM
3952 make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list)
3953 {
3954         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
3955         SCM res = scm_call_3 (chord_ctor, pitch, dur, modification_list);
3956         for (SCM s = res; scm_is_pair (s); s = scm_cdr (s))
3957         {
3958                 Music::unsmob (scm_car (s))->set_spot (loc);
3959         }
3960         return res;
3961 }
3962
3963 int
3964 yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser)
3965 {
3966         Lily_lexer *lex = parser->lexer_;
3967
3968         lex->lexval_ = s;
3969         lex->lexloc_ = loc;
3970         int tok = lex->pop_extra_token ();
3971         if (tok >= 0)
3972                 return tok;
3973         lex->prepare_for_next_token ();
3974         return lex->yylex ();
3975 }