lily/lexer.ll

   1 %{ // -*-Fundamental-*-
   2 /*
   3   lexer.l -- implement the Flex lexer
   4
   5   source file of the LilyPond music typesetter
   6
   7   (c) 1996--2000 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   8            Jan Nieuwenhuizen <janneke@gnu.org>
   9 */
  10
  11
  12 /*
  13   backup rules
  14
  15   after making a change to the lexer rules, run
  16       flex -b <this lexer file>
  17   and make sure that
  18       lex.backup
  19   contains no backup states, but only the reminder
  20       Compressed tables always back up.
  21   (don-t forget to rm lex.yy.cc :-)
  22  */
  23
  24
  25 #include <stdio.h>
  26 #include <ctype.h>
  27
  28 #include "score.hh"
  29 #include "lily-guile.hh"
  30 #include "string.hh"
  31 #include "string-convert.hh"
  32 #include "my-lily-lexer.hh"
  33 #include "array.hh"
  34 #include "interval.hh"
  35 #include "lily-guile.hh"
  36 #include "parser.hh"
  37 #include "debug.hh"
  38 #include "main.hh"
  39 #include "musical-request.hh"
  40 #include "version.hh"
  41 #include "lilypond-input-version.hh"
  42 #include "translator-def.hh"
  43 #include "music-output-def.hh"
  44
  45 /*
  46 RH 7 fix (?)
  47 */
  48 #define isatty HORRIBLEKLUDGE
  49
  50 void strip_trailing_white (String&);
  51 void strip_leading_white (String&);
  52
  53
  54 bool
  55 valid_version_b (String s);
  56
  57
  58
  59 #define start_quote()   \
  60         yy_push_state (quote);\
  61         yylval.string = new String
  62
  63 #define yylval (*(YYSTYPE*)lexval_l)
  64
  65 #define YY_USER_ACTION  add_lexed_char (YYLeng ());
  66 /*
  67
  68 LYRICS          ({AA}|{TEX})[^0-9 \t\n\f]*
  69
  70 */
  71
  72 %}
  73
  74 %option c++
  75 %option noyywrap
  76 %option nodefault
  77 %option debug
  78 %option yyclass="My_lily_lexer"
  79 %option stack
  80 %option never-interactive
  81 %option warn
  82
  83 %x version
  84 %x chords
  85 %x incl
  86 %x lyrics
  87 %x notes
  88 %x quote
  89 %x longcomment
  90
  91
  92 A               [a-zA-Z]
  93 AA              {A}|_
  94 N               [0-9]
  95 AN              {AA}|{N}
  96 PUNCT           [?!:']
  97 ACCENT          \\[`'"^]
  98 NATIONAL  [\001-\006\021-\027\031\036\200-\377]
  99 TEX             {AA}|-|{PUNCT}|{ACCENT}|{NATIONAL}
 100 WORD            {A}{AN}*
 101 ALPHAWORD       {A}+
 102 DIGIT           {N}
 103 UNSIGNED        {N}+
 104 INT             -?{UNSIGNED}
 105 REAL            ({INT}\.{N}*)|(-?\.{N}+)
 106 KEYWORD         \\{WORD}
 107 WHITE           [ \n\t\f\r]
 108 HORIZONTALWHITE         [ \t]
 109 BLACK           [^ \n\t\f\r]
 110 RESTNAME        [rs]
 111 NOTECOMMAND     \\{A}+
 112 LYRICS          ({AA}|{TEX})[^0-9 \t\n\f]*
 113 ESCAPED         [nt\\'"]
 114 EXTENDER        __
 115 HYPHEN          --
 116 %%
 117
 118
 119 <*>\r           {
 120         // windows-suck-suck-suck
 121 }
 122
 123 <INITIAL,chords,incl,lyrics,notes>{
 124   "%{"  {
 125         yy_push_state (longcomment);
 126   }
 127   %[^{\n].*\n   {
 128   }
 129   %[^{\n]       { // backup rule
 130   }
 131   %\n   {
 132   }
 133   %[^{\n].*     {
 134   }
 135   {WHITE}+      {
 136
 137   }
 138 }
 139
 140 <INITIAL,chords,lyrics,notes>\\version{WHITE}*  {
 141         yy_push_state (version);
 142 }
 143 <version>\"[^"]*\";?   { /* got the include file name */
 144         String s (YYText ()+1);
 145         s = s.left_str (s.index_last_i ('"'));
 146         DEBUG_OUT << "#version `" << s << "'\n";
 147         yy_pop_state ();
 148         if (!valid_version_b (s))
 149                 return INVALID;
 150 }
 151 <version>.      {
 152         LexerError ("No quoted string found after \\version");
 153         yy_pop_state ();
 154 }
 155 <longcomment>{
 156         [^\%]*          {
 157         }
 158         \%*[^}%]*               {
 159
 160         }
 161         "%"+"}"         {
 162                 yy_pop_state ();
 163         }
 164         <<EOF>>         {
 165                 LexerError (_ ("EOF found inside a comment").ch_C ());
 166                 if (! close_input ())
 167                   yyterminate (); // can't move this, since it actually rets a YY_NULL
 168         }
 169 }
 170
 171
 172 <INITIAL,chords,lyrics,notes>\\maininput           {
 173         if (!main_input_b_)
 174         {
 175                 start_main_input ();
 176                 main_input_b_ = true;
 177         }
 178         else
 179                 error (_ ("\\maininput disallowed outside init files"));
 180 }
 181
 182 <INITIAL,chords,lyrics,notes>\\include           {
 183         yy_push_state (incl);
 184 }
 185 <incl>\"[^"]*\";?   { /* got the include file name */
 186         String s (YYText ()+1);
 187         s = s.left_str (s.index_last_i ('"'));
 188         DEBUG_OUT << "#include `" << s << "'\n";
 189         new_input (s,source_global_l);
 190         yy_pop_state ();
 191 }
 192 <incl>\\{BLACK}*;?{WHITE} { /* got the include identifier */
 193         String s = YYText () + 1;
 194         strip_trailing_white (s);
 195         if (s.length_i () && (s[s.length_i () - 1] == ';'))
 196           s = s.left_str (s.length_i () - 1);
 197         DEBUG_OUT << "#include `\\" << s << "'\n";
 198         SCM sid = lookup_identifier (s);
 199         if (gh_string_p (sid)) {
 200                 new_input (ly_scm2string (sid), source_global_l);
 201                 yy_pop_state ();
 202         } else {
 203             String msg (_f ("wrong or undefined identifier: `%s'", s ));
 204             LexerError (msg.ch_C ());
 205           }
 206 }
 207 <incl>\"[^"]*   { // backup rule
 208         cerr << _ ("Missing end quote") << endl;
 209         exit (1);
 210 }
 211 <chords,notes>{RESTNAME}        {
 212         const char *s = YYText ();
 213         yylval.scm = ly_str02scm (s);
 214         return RESTNAME;
 215 }
 216 <chords,notes>R         {
 217         return MEASURES;
 218 }
 219 <INITIAL,chords,lyrics,notes>\\\${BLACK}*{WHITE}        {
 220         String s=YYText () + 2;
 221         s=s.left_str (s.length_i () - 1);
 222         return scan_escaped_word (s);
 223 }
 224 <INITIAL,chords,lyrics,notes>\${BLACK}*{WHITE}          {
 225         String s=YYText () + 1;
 226         s=s.left_str (s.length_i () - 1);
 227         return scan_bare_word (s);
 228 }
 229 <INITIAL,chords,lyrics,notes>\\\${BLACK}*               { // backup rule
 230         cerr << _ ("white expected") << endl;
 231         exit (1);
 232 }
 233 <INITIAL,chords,lyrics,notes>\${BLACK}*         { // backup rule
 234         cerr << _ ("white expected") << endl;
 235         exit (1);
 236 }
 237
 238 <INITIAL,chords,lyrics,notes>#  { //embedded scm
 239         //char const* s = YYText () + 1;
 240         char const* s = here_ch_C ();
 241         int n = 0;
 242         if (main_input_b_ && safe_global_b) {
 243                 error (_ ("Can't evaluate Scheme in safe mode"));
 244                 yylval.scm =  SCM_EOL;
 245                 return SCM_T;
 246         }
 247         yylval.scm = ly_parse_scm (s, &n);
 248
 249         for (int i=0; i < n; i++)
 250         {
 251                 yyinput ();
 252         }
 253         char_count_stack_.top () += n;
 254
 255         return SCM_T;
 256 }
 257 <notes>{
 258         {ALPHAWORD}     {
 259                 return scan_bare_word (YYText ());
 260         }
 261
 262         {NOTECOMMAND}   {
 263                 return scan_escaped_word (YYText () + 1);
 264         }
 265
 266         {DIGIT}         {
 267                 yylval.i = String_convert::dec2_i (String (YYText ()));
 268                 return DIGIT;
 269         }
 270         {UNSIGNED}              {
 271                 yylval.i = String_convert::dec2_i (String (YYText ()));
 272                 return UNSIGNED;
 273         }
 274
 275         \" {
 276                 start_quote ();
 277         }
 278 }
 279
 280 \"              {
 281         start_quote ();
 282 }
 283 <quote>{
 284         \\{ESCAPED}     {
 285                 *yylval.string += to_str (escaped_char(YYText()[1]));
 286         }
 287         [^\\"]+ {
 288                 *yylval.string += YYText ();
 289         }
 290         \"      {
 291                 DEBUG_OUT << "quoted string: `" << *yylval.string << "'\n";
 292                 yy_pop_state ();
 293
 294                 /* yylval is union. Must remember STRING before setting SCM*/
 295                 String *sp = yylval.string;
 296                 yylval.scm = ly_str02scm  (sp->ch_C ());
 297                 delete sp;
 298                 return STRING;
 299         }
 300         .       {
 301                 *yylval.string += YYText ();
 302         }
 303 }
 304
 305 <lyrics>{
 306         \" {
 307                 start_quote ();
 308         }
 309         {UNSIGNED}              {
 310                 yylval.i = String_convert::dec2_i (String (YYText ()));
 311                 return UNSIGNED;
 312         }
 313         {NOTECOMMAND}   {
 314                 return scan_escaped_word (YYText () + 1);
 315         }
 316         {LYRICS} {
 317                 /* ugr. This sux. */
 318                 String s (YYText ());
 319                 if (s == "__")
 320                         return yylval.i = EXTENDER;
 321                 if (s == "--")
 322                         return yylval.i = HYPHEN;
 323                 int i = 0;
 324                 while ((i=s.index_i ("_")) != -1) // change word binding "_" to " "
 325                         *(s.ch_l () + i) = ' ';
 326                 if ((i=s.index_i ("\\,")) != -1)   // change "\," to TeX's "\c "
 327                         {
 328                         *(s.ch_l () + i + 1) = 'c';
 329                         s = s.left_str (i+2) + " " + s.right_str (s.length_i ()-i-2);
 330                         }
 331
 332                 char c = s[s.length_i () - 1];
 333                 if (c == '{' ||  c == '}') // brace open is for not confusing dumb tools.
 334                         here_input ().warning (
 335                                 _("Brace found at end of lyric. Did you forget a space?"));
 336                 yylval.scm = ly_str02scm (s.ch_C ());
 337
 338                 DEBUG_OUT << "lyric : `" << s << "'\n";
 339                 return STRING;
 340         }
 341         . {
 342                 return YYText ()[0];
 343         }
 344 }
 345 <chords>{
 346         {ALPHAWORD}     {
 347                 return scan_bare_word (YYText ());
 348         }
 349         {NOTECOMMAND}   {
 350                 return scan_escaped_word (YYText () + 1);
 351         }
 352         {UNSIGNED}              {
 353                 yylval.i = String_convert::dec2_i (String (YYText ()));
 354                 return UNSIGNED;
 355         }
 356         \" {
 357                 start_quote ();
 358         }
 359         -  {
 360                 return CHORD_MINUS;
 361         }
 362         :  {
 363                 return CHORD_COLON;
 364         }
 365         \/\+ {
 366                 return CHORD_BASS;
 367         }
 368         \^  {
 369                 return CHORD_CARET;
 370         }
 371         . {
 372                 return YYText ()[0];
 373         }
 374 }
 375
 376 <<EOF>> {
 377         DEBUG_OUT << "<<eof>>";
 378
 379         if (! close_input ()) {
 380           yyterminate (); // can't move this, since it actually rets a YY_NULL
 381         }
 382 }
 383
 384
 385 {WORD}  {
 386         return scan_bare_word (YYText ());
 387 }
 388 {KEYWORD}       {
 389         return scan_escaped_word (YYText () + 1);
 390 }
 391 {REAL}          {
 392         Real r;
 393         int cnv=sscanf (YYText (), "%lf", &r);
 394         assert (cnv == 1);
 395         DEBUG_OUT  << "REAL" << r<<'\n';
 396         yylval.real = r;
 397         return REAL;
 398 }
 399
 400 {UNSIGNED}      {
 401         yylval.i = String_convert::dec2_i (String (YYText ()));
 402         return UNSIGNED;
 403 }
 404
 405 [{}]    {
 406         DEBUG_OUT << "parens\n";
 407         return YYText ()[0];
 408 }
 409 [*:=]           {
 410         char c = YYText ()[0];
 411         DEBUG_OUT << "misc char" <<c<<"\n";
 412         return c;
 413 }
 414
 415 <INITIAL,notes>.        {
 416         return YYText ()[0];
 417 }
 418
 419 <INITIAL,lyrics,notes>\\. {
 420     char c= YYText ()[1];
 421
 422     switch (c) {
 423     case '>':
 424         return E_BIGGER;
 425     case '<':
 426         return E_SMALLER;
 427     case '!':
 428         return E_EXCLAMATION;
 429     case '(':
 430         return E_OPEN;
 431     case ')':
 432         return E_CLOSE;
 433     default:
 434         return E_CHAR;
 435     }
 436 }
 437
 438 <*>.            {
 439         String msg = _f ("invalid character: `%c'", YYText ()[0]);
 440         LexerError (msg.ch_C ());
 441         return YYText ()[0];
 442 }
 443
 444 %%
 445
 446 void
 447 My_lily_lexer::push_note_state ()
 448 {
 449         yy_push_state (notes);
 450 }
 451
 452 void
 453 My_lily_lexer::push_chord_state ()
 454 {
 455         yy_push_state (chords);
 456 }
 457
 458 void
 459 My_lily_lexer::push_lyric_state ()
 460 {
 461         yy_push_state (lyrics);
 462 }
 463
 464 void
 465 My_lily_lexer::pop_state ()
 466 {
 467         yy_pop_state ();
 468 }
 469
 470 int
 471 My_lily_lexer::scan_escaped_word (String str)
 472 {
 473         // use more SCM for this.
 474
 475         SCM sym = ly_symbol2scm (str.ch_C());
 476
 477         int l = lookup_keyword (str);
 478         if (l != -1) {
 479                 return l;
 480         }
 481         SCM sid = lookup_identifier (str);
 482         if (gh_string_p (sid)) {
 483                 yylval.scm = sid;
 484                 return STRING_IDENTIFIER;
 485         } else if (gh_number_p (sid)) {
 486                 yylval.scm = sid;
 487                 return NUMBER_IDENTIFIER;
 488         } else if (unsmob_translator_def (sid)) {
 489                 yylval.scm = sid;
 490                 return TRANSLATOR_IDENTIFIER;
 491         } else if (unsmob_score (sid)) {
 492                 yylval.scm =sid;
 493                 return SCORE_IDENTIFIER;
 494         } else if (Music * mus =unsmob_music (sid)) {
 495                 yylval.scm = sid;
 496
 497                 return dynamic_cast<Request*> (mus) ? REQUEST_IDENTIFIER : MUSIC_IDENTIFIER;
 498         } else if (unsmob_duration (sid)) {
 499                 yylval.scm = sid;
 500                 return DURATION_IDENTIFIER;
 501         } else if (unsmob_music_output_def (sid)) {
 502                 yylval.scm = sid;
 503                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
 504         }
 505
 506         if (sid != SCM_UNDEFINED) {
 507                 yylval.scm = sid;
 508                 return SCM_IDENTIFIER;
 509         }
 510
 511         if ((YYSTATE != notes) && (YYSTATE != chords)) {
 512                 SCM pitch = scm_hashq_get_handle (pitchname_tab_, sym);
 513
 514                 if (gh_pair_p (pitch))
 515                 {
 516                         yylval.scm = gh_cdr (pitch);
 517                         return NOTENAME_PITCH;
 518                 }
 519         }
 520         String msg (_f ("unknown escaped string: `\\%s'", str));
 521         LexerError (msg.ch_C ());
 522
 523         yylval.scm = ly_str02scm(str.ch_C());
 524
 525         return STRING;
 526 }
 527
 528 int
 529 My_lily_lexer::scan_bare_word (String str)
 530 {
 531         SCM sym = ly_symbol2scm (str.ch_C ());
 532         if ((YYSTATE == notes) || (YYSTATE == chords)) {
 533                 SCM pitch = scm_hashq_get_handle (pitchname_tab_, sym);
 534                 if (gh_pair_p (pitch)) {
 535                     yylval.scm = gh_cdr (pitch);
 536                     return (YYSTATE == notes) ? NOTENAME_PITCH : TONICNAME_PITCH;
 537                 } else if ((pitch = scm_hashq_get_handle (chordmodifier_tab_, sym))!= SCM_BOOL_F)
 538                 {
 539                     yylval.scm = gh_cdr (pitch);
 540                     return CHORDMODIFIER_PITCH;
 541                 }
 542         }
 543
 544         yylval.scm = ly_str02scm (str.ch_C());
 545         return STRING;
 546 }
 547
 548 bool
 549 My_lily_lexer::note_state_b () const
 550 {
 551         return YY_START == notes;
 552 }
 553
 554 bool
 555 My_lily_lexer::chord_state_b () const
 556 {
 557         return YY_START == chords;
 558 }
 559
 560 bool
 561 My_lily_lexer::lyric_state_b () const
 562 {
 563         return YY_START == lyrics;
 564 }
 565
 566 /*
 567  urg, belong to String(_convert)
 568  and should be generalised
 569  */
 570 void
 571 strip_leading_white (String&s)
 572 {
 573         int i=0;
 574         for (;  i < s.length_i (); i++)
 575                 if (!isspace (s[i]))
 576                         break;
 577
 578         s = s.nomid_str (0, i);
 579 }
 580
 581 void
 582 strip_trailing_white (String&s)
 583 {
 584         int i=s.length_i ();
 585         while (i--)
 586                 if (!isspace (s[i]))
 587                         break;
 588
 589         s = s.left_str (i+1);
 590 }
 591
 592
 593
 594
 595 bool
 596 valid_version_b (String s)
 597 {
 598   Lilypond_version current ( MAJOR_VERSION "." MINOR_VERSION "." PATCH_LEVEL );
 599   Lilypond_version ver (s);
 600   if (!((ver >= oldest_version) && (ver <= current)))
 601         {
 602                 non_fatal_error (_f ("incorrect lilypond version: %s (%s, %s)", ver.str (), oldest_version.str (), current.str ()));
 603                 non_fatal_error (_("Consider converting the input with the convert-ly script"));
 604                 return false;
 605     }
 606   return true;
 607 }
 608