stepmake/aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4
   5 ### mostly interal macros
   6
   7 # Get full path of executable ($1)
   8 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
   9     ## which doesn't work in ash, if /usr/bin/which isn't installed
  10     ## type -p doesn't work in ash
  11     ## command -v doesn't work in zsh
  12     ## command -v "$1" 2>&1
  13     ## this test should work in ash, bash, pdksh (ksh), zsh
  14     type -p $1 2>/dev/null | tail -n 1 | awk '{print $NF}'
  15 ])
  16
  17
  18 # Get version string from executable ($1)
  19 AC_DEFUN(STEPMAKE_GET_VERSION, [
  20     ## "$1" --version 2>&1 | grep -v '^$' | head -n 1 | awk '{print $NF}'
  21     ##
  22     ## ARG.
  23     ## Workaround for broken Debian gcc version string:
  24     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  25     ##
  26     ## -V: Workaround for python
  27
  28     changequote(<<, >>)#dnl
  29
  30     ## Assume and hunt for dotted version multiplet.
  31     ## use eval trickery, because we cannot use multi-level $() instead of ``
  32     ## for compatibility reasons.
  33
  34     ## grab the first version number in  --version output.
  35     eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 |
  36                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  37                 head -n 1 |
  38                 tr ' ' '\n' |
  39                 sed 's/\([0-9][0-9]*\.[0-9][0-9.]*\).*/\1/g' |
  40                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  41                 head -n 1\`\"
  42
  43     if test -z "$_ver"; then
  44         ## If empty, try date [fontforge]
  45         eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '[0-9]\{6,8\}' \
  46             | head -n 1 \
  47             | sed -e 's/^[^.0-9]*//' -e 's/[^.0-9]*$//'\`\"
  48     fi
  49     echo "$_ver"
  50     changequote([, ])#dnl
  51 ])
  52
  53 # Calculate simplistic numeric version from version string ($1)
  54 # As yet, we have no need for something more elaborate.
  55 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  56     echo "$1" | awk -F. '
  57     {
  58       if ([$]3) {three = [$]3}
  59       else {three = 0}
  60     }
  61     {printf "%.0f\n", [$]1*1000000 + [$]2*1000 + three}'
  62 ])
  63
  64
  65 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  66 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  67     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  68 ])
  69
  70 # Check if tested program ($2) was found ($1).
  71 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  72 # We could abort here if a 'REQUIRED' program is not found
  73 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  74     STEPMAKE_CHECK_SEARCH_RESULT($1)
  75     if test $? -ne 0; then
  76         STEPMAKE_ADD_ENTRY($3, $2)
  77         if test "$3" = "REQUIRED"; then
  78             command="echo ERROR: $2 not found"
  79             # abort configure process here?
  80         else
  81             command="- echo $2 not found"
  82         fi
  83         eval "$1"='$command'
  84         false
  85     else
  86         true
  87     fi
  88 ])
  89
  90
  91 # Return if tested proram ($1) was found (true) or not (false).
  92 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  93     r="`eval echo '$'"$1"`"
  94     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  95         true
  96     else
  97         ##STEPMAKE_WARN(cannot find $2. $3)
  98         false
  99     fi
 100 ])
 101
 102
 103 # Check version of program ($1)
 104 # If version ($4: optional argument, supply if version cannot be
 105 # parsed using --version or -V ) is smaller than requested ($3), add
 106 # entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
 107 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
 108     r="`eval echo '$'"$1"`"
 109     AC_MSG_CHECKING([$r version])
 110     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 111     if test -n "$4"; then
 112         ver="$4"
 113     else
 114         ver=`STEPMAKE_GET_VERSION($exe)`
 115     fi
 116     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 117     req=`STEPMAKE_NUMERIC_VERSION($3)`
 118     AC_MSG_RESULT([$ver])
 119     if test "$num" -lt "$req"; then
 120         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
 121     fi
 122     vervar="`echo $1 | tr '[a-z]' '[A-Z]'`_VERSION"
 123     eval `echo $vervar=$num`
 124 ##    AC_SUBST(`eval echo $vervar`)
 125 ])
 126
 127 # Check version of program ($1)
 128 # If version is greater than or equals unsupported ($3),
 129 # add entry to unsupported list ($2, 'UNSUPPORTED')
 130 AC_DEFUN(STEPMAKE_CHECK_VERSION_UNSUPPORTED, [
 131     r="`eval echo '$'"$1"`"
 132     AC_MSG_CHECKING([$r version])
 133     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 134     ver=`STEPMAKE_GET_VERSION($exe)`
 135     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 136     sup=`STEPMAKE_NUMERIC_VERSION($3)`
 137     AC_MSG_RESULT([$ver])
 138     if test "$num" -ge "$sup"; then
 139         STEPMAKE_ADD_ENTRY($2, ["$r < $3 (installed: $ver)"])
 140     fi
 141 ])
 142
 143 ### Macros to build configure.in
 144
 145
 146 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 147     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 148     if test "$BIBTEX2HTML" = "bib2html"; then
 149         BIBTEX2HTML_FLAGS='$< $(@)'
 150     else
 151         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 152     fi
 153     AC_SUBST(BIBTEX2HTML)
 154     AC_SUBST(BIBTEX2HTML_FLAGS)
 155 ])
 156
 157
 158 AC_DEFUN(STEPMAKE_BISON, [
 159     # ugh, automake: we want (and check for) bison
 160     AC_PROG_YACC
 161
 162     STEPMAKE_PROGS(BISON, bison, $1)
 163
 164     # urg.  should test functionality rather than version.
 165     if test "$BISON" = "bison" -a -n "$2"; then
 166         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 167     fi
 168 ])
 169
 170 AC_DEFUN(STEPMAKE_COMPILE_BEFORE, [
 171     # -O is necessary to get inlining
 172     CFLAGS=${CFLAGS-""}
 173     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 174     LDFLAGS=${LDFLAGS-""}
 175     optimise_b=yes
 176     profile_b=no
 177     debug_b=yes
 178     pipe_b=yes
 179
 180     AC_ARG_ENABLE(debugging,
 181     [AS_HELP_STRING([--enable-debugging],
 182                     [compile with debugging info.  Default: on])],
 183     [debug_b=$enableval])
 184
 185     AC_ARG_ENABLE(optimising,
 186     [AS_HELP_STRING([--enable-optimising],
 187                     [compile with optimising.  Default: on])],
 188     [optimise_b=$enableval])
 189
 190     AC_ARG_ENABLE(profiling,
 191     [AS_HELP_STRING([--enable-profiling],
 192                     [compile with gprof support.  Default: off])],
 193     [profile_b=$enableval])
 194
 195     AC_ARG_ENABLE(pipe,
 196     [AS_HELP_STRING([--enable-pipe],
 197                     [compile with -pipe.  Default: on])],
 198     [pipe_b=$enableval])
 199
 200     if test "$optimise_b" = yes; then
 201         AC_DEFINE(NDEBUG)
 202         DEFINES="$DEFINES -DNDEBUG"
 203         OPTIMIZE=" -O2 -finline-functions"
 204     fi
 205
 206     if test $profile_b = yes; then
 207         EXTRA_LIBS="-pg"
 208         OPTIMIZE="$OPTIMIZE -pg"
 209     fi
 210
 211     if test $debug_b = yes; then
 212         OPTIMIZE="$OPTIMIZE -g"
 213     fi
 214 ])
 215
 216 AC_DEFUN(STEPMAKE_COMPILE, [
 217
 218     AC_REQUIRE([STEPMAKE_COMPILE_BEFORE])
 219     AC_REQUIRE([AC_PROG_CC])
 220
 221     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 222     LD='$(CC)'
 223     AC_SUBST(LD)
 224
 225     # If -pipe requested, test if it works and add to CFLAGS.
 226     if test "$pipe_b" = yes; then
 227         save_cflags="$CFLAGS"
 228         CFLAGS=" -pipe $CFLAGS";
 229         AC_CACHE_CHECK([whether compiler understands -pipe],
 230             [stepmake_cv_cflags_pipe],
 231             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[/* -pipe test */]])],
 232                 [stepmake_cv_cflags_pipe=yes],
 233                 [stepmake_cv_cflags_pipe=no]))
 234         CFLAGS=$save_cflags
 235         if test $stepmake_cv_cflags_pipe = yes; then
 236             OPTIMIZE="$OPTIMIZE -pipe"
 237         fi
 238     fi
 239
 240     CFLAGS="$CFLAGS $OPTIMIZE"
 241     CPPFLAGS=${CPPFLAGS-""}
 242
 243     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 244     save_cflags="$CFLAGS"
 245     case "$host" in
 246         alpha*-*-*)
 247             dnl should do compile test?
 248             AC_MSG_RESULT(-mieee)
 249             CFLAGS=" -mieee $CFLAGS"
 250             ;;
 251         *)
 252             AC_MSG_RESULT([none])
 253             ;;
 254     esac
 255
 256     AC_SUBST(cross_compiling)
 257     AC_SUBST(CFLAGS)
 258     AC_SUBST(CPPFLAGS)
 259     AC_SUBST(LDFLAGS)
 260     AC_SUBST(DEFINES)
 261     AC_SUBST(EXTRA_LIBS)
 262 ])
 263
 264 AC_DEFUN(STEPMAKE_CXX, [
 265     AC_PROG_CXX
 266     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 267
 268     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 269     LD='$(CXX)'
 270
 271     AC_SUBST(CXX)
 272     AC_SUBST(CXXFLAGS)
 273     AC_SUBST(LD)
 274 ])
 275
 276
 277 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 278     AC_CACHE_CHECK([whether explicit instantiation is needed],
 279         stepmake_cv_need_explicit_instantiation,
 280         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 281     template <class T> struct foo { static int baz; };
 282     template <class T> int foo<T>::baz = 1;
 283     ]], [[ return foo<int>::baz; ]])],[stepmake_cv_need_explicit_instantiation=no],[stepmake_cv_need_explicit_instantiation=yes]))
 284     if test x"$stepmake_cv_need_explicit_instantiation"x = x"yes"x; then
 285         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 286     fi
 287 ])
 288
 289
 290 AC_DEFUN(STEPMAKE_DATADIR, [
 291     if test "$datadir" = "\${prefix}/share"; then
 292             datadir='${prefix}/share'
 293     fi
 294     presome=${prefix}
 295     if test "$prefix" = "NONE"; then
 296         presome=${ac_default_prefix}
 297     fi
 298
 299     build_package_datadir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/share/$package
 300
 301     DATADIR=`echo ${datadir} | sed "s!\\\${datarootdir}!${prefix}/share!"`
 302     DATADIR=`echo ${DATADIR} | sed "s!\\\${prefix}!$presome!"`
 303     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 304
 305     AC_SUBST(datadir)
 306     AC_SUBST(datarootdir)
 307     AC_SUBST(build_package_datadir)
 308     AC_DEFINE_UNQUOTED(DATADIR, ["${DATADIR}"])
 309     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, ["${BUILD_PACKAGE_DATADIR}"])
 310 ])
 311
 312 ## ugh: cut & paste programming from datadir.
 313 AC_DEFUN(STEPMAKE_LIBDIR, [
 314
 315     if test "$libdir" = "\${exec_prefix}/lib"; then
 316         libdir='${exec_prefix}/lib'
 317     fi
 318     presome=$exec_prefix
 319     build_package_libdir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/lib/$package
 320
 321     LIBDIR=`echo ${libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 322     BUILD_PACKAGE_LIBDIR=`echo ${build_package_libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 323
 324     AC_SUBST(libdir)
 325     AC_SUBST(build_package_libdir)
 326     AC_DEFINE_UNQUOTED(LIBDIR, ["${LIBDIR}"])
 327     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_LIBDIR, ["${BUILD_PACKAGE_LIBDIR}"])
 328 ])
 329
 330
 331 AC_DEFUN(STEPMAKE_PREFIX_EXPAND_FIXUP, [
 332     # undo expanding of explicit --infodir=/usr/share
 333     # to ease install-time override with prefix=...
 334     strip=`echo $includedir | eval sed s@^$prefix@@`
 335     if test "$includedir" = "`eval echo $prefix$strip`"; then
 336             includedir='${prefix}'$strip''
 337     fi
 338     strip=`echo $libdir | eval sed s@^$exec_prefix@@`
 339     if test "$libdir" = "`eval echo $exec_prefix$strip`"; then
 340             libdir='${exec_prefix}'$strip''
 341     fi
 342     strip=`echo $infodir | eval sed s@^$datarootdir@@`
 343     if test "$infodir" = "`eval echo $datarootdir$strip`"; then
 344             infodir='${datarootdir}'$strip''
 345     fi
 346     strip=`echo $mandir | eval sed s@^$datarootdir@@`
 347     if test "$mandir" = "`eval echo $datarootdir$strip`"; then
 348             mandir='${datarootdir}'$strip''
 349     fi
 350 ])
 351
 352
 353 AC_DEFUN(STEPMAKE_END, [
 354     STEPMAKE_PREFIX_EXPAND_FIXUP
 355
 356     AC_SUBST(OPTIONAL)
 357     AC_SUBST(REQUIRED)
 358
 359     AC_CONFIG_FILES([$CONFIGFILE.make:config.make.in])
 360     AC_OUTPUT
 361
 362     if test -n "$OPTIONAL"; then
 363         echo
 364         echo "WARNING: Please consider installing optional programs: $OPTIONAL"
 365     fi
 366
 367     if test -n "$REQUIRED"; then
 368         echo
 369         echo "ERROR: Please install required programs: $REQUIRED"
 370     fi
 371
 372     if test -n "$UNSUPPORTED"; then
 373         echo
 374         echo "ERROR: Please use older version of programs: $UNSUPPORTED"
 375     fi
 376
 377     if test -n "$OPTIONAL$REQUIRED$UNSUPPORTED"; then
 378         echo
 379         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 380         if test -f config.cache ; then
 381             echo "Remove config.cache before rerunning ./configure"
 382         fi
 383     fi
 384
 385     if test -n "$REQUIRED$UNSUPPORTED"; then
 386         rm -f $srcdir/GNUmakefile
 387         exit 1
 388     fi
 389
 390     # regular in-place build
 391     # test for srcdir_build = yes ?
 392     if test "$srcdir_build" = "yes"; then
 393         rm -f $srcdir/GNUmakefile
 394         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 395         chmod 444 $srcdir/GNUmakefile
 396     else
 397         if test -f $srcdir/GNUmakefile; then
 398             cat <<EOF
 399 Source directory already configured.  Please clean the source directory
 400
 401      make -C $srcdir distclean
 402
 403 and rerun configure.
 404 EOF
 405             exit 2
 406         fi
 407
 408         for d in 2 3 4 ; do
 409             for mf in `cd $srcdir ; find . -maxdepth $d -mindepth $d -name GNUmakefile`; do
 410                 mkdir -p $(dirname $mf)
 411                 cat <<EOF | $PYTHON -  > $mf
 412 print 'depth=' + ('../' * ( $d-1 ) )
 413 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 414 print 'include \$(configure-srcdir)/$mf'
 415 print 'MODULE_INCLUDES += \$(src-dir)/\$(outbase)'
 416 EOF
 417             done
 418             for mf in `cd $srcdir ; find . -maxdepth $d -mindepth $d -name '*.make' | grep -v config.make `; do
 419                 mkdir -p $(dirname $mf)
 420                 cat <<EOF | $PYTHON -  > $mf
 421 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 422 print 'include \$(configure-srcdir)/$mf'
 423 EOF
 424             done
 425         done
 426
 427
 428         cat <<EOF > GNUmakefile
 429 depth = .
 430 include config\$(if \$(conf),-\$(conf),).make
 431 include \$(configure-srcdir)/GNUmakefile.in
 432 EOF
 433         AC_SUBST(VPATH)
 434     fi
 435 ])
 436
 437
 438 AC_DEFUN(STEPMAKE_FLEX, [
 439     # ugh, automake: we want (and check for) flex
 440     # AC_PROG_LEX
 441     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 442
 443     # AC_PROG_LEX()
 444     # ugh, ugh
 445     ac_cv_prog_lex_root=lex.yy
 446     STEPMAKE_PROGS(FLEX, flex, $1)
 447 ])
 448
 449
 450 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 451     AC_CHECK_HEADERS([FlexLexer.h],[true],[false])
 452     if test $? -ne 0; then
 453         warn='FlexLexer.h (flex package)'
 454         STEPMAKE_ADD_ENTRY($1, $warn)
 455     fi
 456     # check for yyFlexLexer.yy_current_buffer,
 457     # in 2.5.4 <= flex < 2.5.29
 458     AC_CACHE_CHECK([for yyFlexLexer.yy_current_buffer],
 459         [stepmake_cv_flexlexer_yy_current_buffer],
 460         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 461 using namespace std;
 462 #include <FlexLexer.h>
 463 class yy_flex_lexer: public yyFlexLexer
 464 {
 465   public:
 466     yy_flex_lexer ()
 467     {
 468       yy_current_buffer = 0;
 469     }
 470 };
 471 ]])],
 472             [stepmake_cv_flexlexer_yy_current_buffer=yes],
 473             [stepmake_cv_flexlexer_yy_current_buffer=no]))
 474     if test $stepmake_cv_flexlexer_yy_current_buffer = yes; then
 475         AC_DEFINE(HAVE_FLEXLEXER_YY_CURRENT_BUFFER, 1, [Define to 1 if yyFlexLexer has yy_current_buffer.])
 476     fi
 477 ])
 478
 479
 480
 481 AC_DEFUN(STEPMAKE_FLEXLEXER_LOCATION, [
 482         AC_MSG_CHECKING([FlexLexer.h location])
 483
 484         # ugh.
 485         cat <<EOF > conftest.cc
 486 using namespace std;
 487 #include <FlexLexer.h>
 488 EOF
 489         FLEXLEXER_FILE=`eval $ac_cpp conftest.cc | \
 490           sed 's!# 1 "\(.*FlexLexer.h\)"!@FLEXLEXER@\1@@!g' | grep '@@' | \
 491           sed 's!.*@FLEXLEXER@\(.*\)@@.*$!\1!g' ` 1> /dev/null 2> /dev/null
 492         rm conftest.cc
 493         AC_SUBST(FLEXLEXER_FILE)
 494         AC_MSG_RESULT($FLEXLEXER_FILE)
 495 ])
 496
 497 AC_DEFUN(STEPMAKE_GCC_OR_CLANG, [
 498     STEPMAKE_HAS_CLANG()
 499     if test "$HAS_CLANG" = "no"; then
 500         if test "$GCC" = "yes"; then
 501             STEPMAKE_CHECK_VERSION(CC, $1, $2)
 502         else
 503             warn="$CC (Please install *GNU* cc)"
 504             STEPMAKE_ADD_ENTRY($1, $warn)
 505         fi
 506     fi
 507     # no else, we're fine with any clang
 508 ])
 509
 510 AC_DEFUN(STEPMAKE_GETTEXT, [
 511     presome=${prefix}
 512     if test "$prefix" = "NONE"; then
 513             presome=${ac_default_prefix}
 514     fi
 515     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 516
 517     AC_SUBST(localedir)
 518     AC_DEFINE_UNQUOTED(LOCALEDIR, ["${LOCALEDIR}"])
 519     AC_CHECK_LIB(intl, gettext)
 520     AC_CHECK_FUNCS(gettext)
 521 ])
 522
 523
 524 AC_DEFUN(STEPMAKE_GUILE, [
 525     STEPMAKE_PATH_PROG(GUILE, guile, $1)
 526 ])
 527
 528
 529 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 530 #
 531 #   This macro runs the guile-config script, installed with Guile,
 532 #   to find out where Guile's header files and libraries are
 533 #   installed.  It sets two variables, marked for substitution, as
 534 #   by AC_SUBST.
 535 #
 536 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 537 #             code that uses Guile header files.  This is almost
 538 #             always just a -I flag.
 539 #
 540 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 541 #             program against Guile.  This includes -lguile for
 542 #             the Guile library itself, any libraries that Guile
 543 #             itself requires (like -lqthreads), and so on.  It may
 544 #             also include a -L flag to tell the compiler where to
 545 #             find the libraries.
 546
 547 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 548     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 549     if test -x $exe; then
 550         AC_MSG_CHECKING([guile compile flags])
 551         GUILE_CFLAGS="`$guile_config compile`"
 552         AC_MSG_RESULT($GUILE_CFLAGS)
 553         AC_MSG_CHECKING([guile link flags])
 554         GUILE_LDFLAGS="`$guile_config link`"
 555         AC_MSG_RESULT($GUILE_LDFLAGS)
 556     fi
 557     AC_SUBST(GUILE_CFLAGS)
 558     AC_SUBST(GUILE_LDFLAGS)
 559 ])
 560
 561
 562 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 563     ## First, let's just see if we can find Guile at all.
 564     test -n "$target_alias" && target_guile_config=$target_alias-guile-config
 565     test -n "$host_alias" && host_guile_config=$host_alias-guile-config
 566     AC_MSG_CHECKING([for guile-config])
 567     for guile_config in $GUILE_CONFIG $target_guile_config $host_guile_config $build_guile_config guile-config; do
 568         AC_MSG_RESULT([$guile_config])
 569         if ! $guile_config --version > /dev/null 2>&1 ; then
 570             AC_MSG_WARN([cannot execute $guile_config])
 571             AC_MSG_CHECKING([if we are cross compiling])
 572             GUILE_CONFIG='echo no guile-config'
 573         else
 574             GUILE_CONFIG=$guile_config
 575             break
 576         fi
 577     done
 578     STEPMAKE_OPTIONAL_REQUIRED(GUILE_CONFIG, $guile_config, $1)
 579     if test $? -ne 0; then
 580         STEPMAKE_ADD_ENTRY($1, 'guile-config (guile-devel, guile-dev or libguile-dev package)')
 581     fi
 582
 583     STEPMAKE_CHECK_SEARCH_RESULT(GUILE_CONFIG)
 584     # urg.  should test functionality rather than version.
 585     if test $? -eq 0 -a -n "$2"; then
 586         STEPMAKE_CHECK_VERSION(GUILE_CONFIG, $1, $2)
 587     fi
 588
 589     AC_SUBST(GUILE_CONFIG)
 590
 591     guile_version="$ver"
 592     changequote(<<, >>)#dnl
 593     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 594     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 595     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 596     changequote([, ])#dnl
 597     STEPMAKE_GUILE_FLAGS
 598     save_CPPFLAGS="$CPPFLAGS"
 599     save_LIBS="$LIBS"
 600     CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 601     LIBS="$GUILE_LDFLAGS $LIBS"
 602     AC_CHECK_HEADERS([libguile.h])
 603     AC_CHECK_LIB(guile, scm_boot_guile)
 604     AC_CHECK_FUNCS(scm_boot_guile,,libguile_b=no)
 605     if test "$libguile_b" = "no"; then
 606             warn='libguile (libguile-dev, guile-devel or guile-dev
 607    package).'
 608             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 609     fi
 610     CPPFLAGS="$save_CPPFLAGS"
 611     LIBS="$save_LIBS"
 612     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 613     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 614     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 615 ])
 616
 617
 618 AC_DEFUN(STEPMAKE_DLOPEN, [
 619     AC_CHECK_LIB(dl, dlopen)
 620     AC_CHECK_FUNCS(dlopen)
 621 ])
 622
 623 AC_DEFUN(STEPMAKE_HAS_CLANG, [
 624     AC_EGREP_CPP(yes,
 625       [#ifdef __clang__
 626        yes
 627        #endif
 628       ], HAS_CLANG=yes, HAS_CLANG=no)
 629 ])
 630
 631 AC_DEFUN(STEPMAKE_GXX_OR_CLANG, [
 632     STEPMAKE_HAS_CLANG()
 633     if test "$HAS_CLANG" = "no"; then
 634         if test "$GXX" = "yes"; then
 635             STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 636         else
 637             warn="$CXX (Please install *GNU* c++)"
 638             STEPMAKE_ADD_ENTRY($1, $warn)
 639         fi
 640     fi
 641     # no else, we're fine with any clang
 642 ])
 643
 644
 645 AC_DEFUN(STEPMAKE_INIT, [
 646
 647     . $srcdir/VERSION
 648     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 649     MICRO_VERSION=$PATCH_LEVEL
 650     TOPLEVEL_VERSION=$FULL_VERSION
 651     if test x$MY_PATCH_LEVEL != x; then
 652         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 653     fi
 654     VERSION=$FULL_VERSION
 655     export MAJOR_VERSION MINOR_VERSION PATCH_LEVEL
 656     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 657     changequote(<<, >>)#dnl
 658     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 659     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 660     changequote([, ])#dnl
 661
 662     # No versioning on directory names of sub-packages
 663     # urg, urg
 664     stepmake=${datadir}/stepmake
 665     presome=${prefix}
 666     if test "$prefix" = "NONE"; then
 667             presome=${ac_default_prefix}
 668     fi
 669     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 670
 671     # urg, how is this supposed to work?
 672     if test "$program_prefix" = "NONE"; then
 673           program_prefix=
 674     fi
 675     if test "$program_suffix" = "NONE"; then
 676           program_suffix=
 677     fi
 678
 679     AC_MSG_CHECKING(Package)
 680     if test "$PACKAGE" = "STEPMAKE"; then
 681         AC_MSG_RESULT(Stepmake package!)
 682
 683         AC_MSG_CHECKING(builddir)
 684
 685         ugh_ugh_autoconf250_builddir="`pwd`"
 686
 687         if test "$srcdir" = "."; then
 688             srcdir_build=yes
 689         else
 690             srcdir_build=no
 691             package_builddir="`dirname $ugh_ugh_autoconf250_builddir`"
 692             package_srcdir="`dirname  $srcdir`"
 693         fi
 694         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 695
 696         (cd stepmake 2>/dev/null || mkdir stepmake)
 697         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 698         stepmake=stepmake
 699     else
 700         AC_MSG_RESULT($PACKAGE)
 701
 702         AC_MSG_CHECKING(builddir)
 703         ugh_ugh_autoconf250_builddir="`pwd`"
 704
 705         here_dir=$(cd . && pwd)
 706         full_src_dir=$(cd $srcdir && pwd)
 707
 708         if test "$full_src_dir" = "$here_dir"; then
 709             srcdir_build=yes
 710         else
 711             srcdir_build=no
 712         fi
 713         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 714
 715         AC_MSG_CHECKING(for stepmake)
 716         # Check for installed stepmake
 717         if test -d $stepmake; then
 718             AC_MSG_RESULT($stepmake)
 719         else
 720             stepmake="`cd $srcdir/stepmake; pwd`"
 721             AC_MSG_RESULT([$srcdir/stepmake  ($datadir/stepmake not found)])
 722         fi
 723     fi
 724
 725     AC_SUBST(ugh_ugh_autoconf250_builddir)
 726
 727     # Use absolute directory for non-srcdir builds, so that build
 728     # dir can be moved.
 729     if test "$srcdir_build" = "no" ;  then
 730         srcdir="`cd $srcdir; pwd`"
 731     fi
 732
 733     AC_SUBST(srcdir)
 734     AC_SUBST(stepmake)
 735     AC_SUBST(package)
 736     AC_SUBST(PACKAGE)
 737     AC_SUBST(PACKAGE_NAME)
 738     AC_SUBST(VERSION)
 739     AC_SUBST(MAJOR_VERSION)
 740     AC_SUBST(MINOR_VERSION)
 741     AC_SUBST(MICRO_VERSION)
 742
 743     # stepmake nonstandard names
 744     AC_SUBST(PATCH_LEVEL)
 745     AC_SUBST(TOPLEVEL_VERSION)
 746
 747     # We don't need the upper case variant,
 748     # so stick to macros are uppercase convention.
 749     # AC_DEFINE_UNQUOTED(package, ["${package}"])
 750     # AC_DEFINE_UNQUOTED(PACKAGE, ["${PACKAGE}"])
 751     AC_DEFINE_UNQUOTED(PACKAGE, ["${package}"])
 752     AC_DEFINE_UNQUOTED(PACKAGE_NAME, ["${PACKAGE_NAME}"])
 753     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, ["${FULL_VERSION}"])
 754
 755     if test -z "$package_depth"; then
 756         package_depth="."
 757     else
 758         package_depth="../$package_depth"
 759     fi
 760     export package_depth
 761     AC_SUBST(package_depth)
 762
 763     AUTOGENERATE="This file was automatically generated by configure"
 764     AC_SUBST(AUTOGENERATE)
 765
 766     CONFIGSUFFIX=
 767     AC_ARG_ENABLE(config,
 768     [AS_HELP_STRING([--enable-config=CONF],
 769                     [put settings in config-CONF.make and config-CONF.h;
 770                     do `make conf=CONF' to get output in ./out-CONF])],
 771     [CONFIGURATION=$enableval])
 772
 773     ##'`#
 774
 775     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 776     CONFIGFILE=config$CONFIGSUFFIX
 777     AC_SUBST(CONFIGSUFFIX)
 778
 779     AC_CANONICAL_HOST
 780     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 781     STEPMAKE_PROGS(FIND, find, REQUIRED)
 782
 783     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 784
 785     if test "$(echo 2)" != "2" ||
 786         test "x`uname`" = "xHP-UX"; then
 787         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 788         AC_PATH_PROG(BASH, bash, $KSH)
 789         STEPMAKE_WARN(avoiding buggy /bin/sh)
 790         AC_PATH_PROG(SHELL, bash, $KSH)
 791     else
 792         SHELL=/bin/sh
 793         AC_PATH_PROG(BASH, bash, $SHELL)
 794     fi
 795     AC_SUBST(SHELL)
 796
 797     STEPMAKE_PYTHON(REQUIRED, 1.5)
 798
 799     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 800         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 801         if test "$?" = 1; then
 802             warn='make (Please install *GNU* make)'
 803             # STEPMAKE_WARN($warn)
 804             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 805         fi
 806     fi
 807
 808     ROOTSEP=':'
 809     DIRSEP='/'
 810     PATHSEP=':'
 811     LN=ln
 812     LN_S='ln -s'
 813     ZIP="zip -r -9"
 814
 815     AC_SUBST(program_prefix)
 816     AC_SUBST(program_suffix)
 817     AC_SUBST(ZIP)
 818     AC_SUBST(LN)
 819     AC_SUBST(LN_S)
 820     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
 821     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
 822     AC_SUBST(DIRSEP)
 823     AC_SUBST(PATHSEP)
 824     AC_SUBST(ROOTSEP)
 825
 826     STEPMAKE_DATADIR
 827     STEPMAKE_LIBDIR
 828 ])
 829
 830
 831 AC_DEFUN(STEPMAKE_LIB, [
 832     STEPMAKE_PROGS(AR, ar, $1)
 833     AC_PROG_RANLIB
 834     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 835 ])
 836
 837
 838 AC_DEFUN(STEPMAKE_LIBTOOL, [
 839     # libtool.info ...
 840     # **Never** try to set library version numbers so that they correspond
 841     # to the release number of your package.  This is an abuse that only
 842     # fosters misunderstanding of the purpose of library versions.
 843
 844     REVISION=$PATCH_LEVEL
 845     # CURRENT=$MINOR_VERSION
 846     CURRENT=`expr $MINOR_VERSION + 1`
 847     # AGE=`expr $MAJOR_VERSION + 1`
 848     AGE=$MAJOR_VERSION
 849     AC_SUBST(CURRENT)
 850     AC_SUBST(REVISION)
 851     AC_SUBST(AGE)
 852 ])
 853
 854
 855 AC_DEFUN(STEPMAKE_LOCALE, [
 856     lang=English
 857     ALL_LINGUAS="en nl"
 858
 859     # with/enable ??
 860     AC_ARG_WITH(localedir,
 861     [AS_HELP_STRING([--with-localedir=DIR],
 862                     [location of locales.  Default: PREFIX/share/locale])],
 863     localedir=$with_localedir,
 864     localedir='${prefix}/share/locale')
 865
 866     AC_ARG_WITH(lang,
 867     [AS_HELP_STRING([--with-lang=LANG],
 868                     [use LANG as language to emit messages])],
 869     language=$with_lang,
 870     language=English)
 871
 872     AC_MSG_CHECKING(language)
 873     case "$language" in
 874       En* | en* | Am* | am* | US* | us*)
 875             lang=English;;
 876       NL | nl | Du* | du* | Ned* | ned*)
 877             lang=Dutch;;
 878       "")
 879             lang=English;;
 880       *)
 881             lang=unknown;;
 882     esac
 883     AC_MSG_RESULT($lang)
 884
 885     if test "$lang" = "unknown" ; then
 886         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 887     fi
 888
 889 ])
 890
 891
 892 AC_DEFUN(STEPMAKE_MAKEINFO, [
 893     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 894 ])
 895
 896
 897 AC_DEFUN(STEPMAKE_MAN, [
 898     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 899     AC_SUBST(GROFF)
 900     STEPMAKE_PROGS(TROFF, troff, $1)
 901     AC_SUBST(TROFF)
 902     STEPMAKE_PROGS(TBL, tbl, $1)
 903     AC_SUBST(TBL)
 904 ])
 905
 906
 907 AC_DEFUN(STEPMAKE_MSGFMT, [
 908     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
 909 ])
 910
 911
 912 # Check for program ($2), set full path result to ($1).
 913 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 914 AC_DEFUN(STEPMAKE_PATH_PROG, [
 915     AC_CHECK_PROGS($1, $2, no)
 916     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 917     if test $? -eq 0; then
 918         AC_PATH_PROG($1, $2)
 919         if test -n "$4"; then
 920             STEPMAKE_CHECK_VERSION($1, $3, $4)
 921         fi
 922     fi
 923 ])
 924
 925
 926 # Check for program in set of names ($2), set result to ($1) .
 927 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 928 # If exists, and a minimal version ($4) is required
 929 AC_DEFUN(STEPMAKE_PROGS, [
 930     AC_CHECK_PROGS($1, $2, no)
 931     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 932     if test $? -eq 0 -a -n "$4"; then
 933         STEPMAKE_CHECK_VERSION($1, $3, $4)
 934     fi
 935 ])
 936
 937
 938 AC_DEFUN(STEPMAKE_PERL, [
 939     STEPMAKE_PATH_PROG(PERL, perl, $1)
 940 ])
 941
 942
 943 AC_DEFUN(STEPMAKE_PYTHON, [
 944     unset pv
 945     AC_MSG_CHECKING([for python])
 946     for python in $PYTHON python python2 python2.4 python2.3 python2.2 python2.1 python2.0; do
 947         AC_MSG_RESULT([$python])
 948         if ! $python -V > /dev/null 2>&1 ; then
 949             #AC_MSG_WARN([cannot execute $python])
 950             PYTHON='echo no python'
 951         else
 952             unset pv
 953             STEPMAKE_CHECK_VERSION(python, pv, $2)
 954             if test -z "$pv"; then
 955                 PYTHON=$python
 956                 break
 957             fi
 958         fi
 959     done
 960     if test -n "$pv"; then
 961         STEPMAKE_ADD_ENTRY($1, $pv)
 962     fi
 963     # clear cached value since arg 2 might point us to a new binary
 964     unset ac_cv_path_PYTHON
 965
 966     AC_PATH_PROG(PYTHON, $PYTHON)
 967     AC_SUBST(PYTHON)
 968 ])
 969
 970 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
 971     AC_ARG_WITH(python-include,
 972         [AS_HELP_STRING([--with-python-include=DIR],
 973                         [location of the python include dir])],[
 974         if test "$withval" = "yes" -o "$withval" = "no"; then
 975             AC_MSG_WARN(Usage: --with-python-include=includedir)
 976         else
 977             PYTHON_CFLAGS="-I${withval}"
 978         fi
 979     ])
 980
 981     AC_ARG_WITH(python-lib,
 982         [AS_HELP_STRING([--with-python-lib=NAME],
 983                         [name of the python lib])],[
 984         if test "$withval" = "yes" -o "$withval" = "no"; then
 985             AC_MSG_WARN(Usage: --with-python-lib=name)
 986         else
 987             LDFLAGS="$LDFLAGS -l${withval}"
 988         fi
 989     ])
 990
 991     AC_CHECK_PROGS(PYTHON_CONFIG, python-config, no)
 992
 993     if test -z "$PYTHON_CFLAGS" -a "$PYTHON_CONFIG" != "no"; then
 994         # Clean out junk: http://bugs.python.org/issue3290
 995         # Python headers may need some -f* flags, leave them in.
 996         # We want the sed commands to look like 's/-[WDOm][[:alnum:][:punct:]][[:alnum:][:punct:]]*//g' and 's/-arch [^[:space:]]*//g', but automake eats brackets.
 997         PYTHON_CFLAGS=`$PYTHON_CONFIG --cflags | sed -e 's/-[[WDOm]][[[:alnum:][:punct:]]][[[:alnum:][:punct:]]]*//g' | sed -e 's/-arch @<:@^@<:@:space:@:>@@:>@*//g'`
 998         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 999     fi
1000
1001     if test -z "$PYTHON_CFLAGS" -a "$cross_compiling" = "no"; then
1002         changequote(<<, >>)#dnl
1003         # alternatively, for python >= 2.0
1004         # 'import sys, distutils.sysconfig; sys.stdout.write (distutils.sysconfig.get_python_inc ())'
1005         PYTHON_INCLUDE=`$PYTHON -c 'import sys; sys.stdout.write ("%s/include/python%s" % (sys.prefix, sys.version[:3]))'`
1006         PYTHON_CFLAGS="-I$PYTHON_INCLUDE"
1007         changequote([, ])#dnl
1008     fi
1009
1010     if test -z "$PYTHON_HEADER"; then
1011         CPPFLAGS="$PYTHON_CFLAGS $CPPFLAGS"
1012         AC_CHECK_HEADERS([Python.h],[PYTHON_HEADER=yes])
1013     fi
1014
1015     if test -z "$PYTHON_HEADER"; then
1016         warn="Python.h (python-devel, python-dev or libpython-dev package)"
1017         STEPMAKE_ADD_ENTRY($1, $warn)
1018     fi
1019 ])
1020
1021
1022
1023 AC_DEFUN(STEPMAKE_STL_DATA_METHOD, [
1024     AC_CACHE_CHECK([for stl.data () method],
1025         [stepmake_cv_stl_data_method],
1026         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1027 #include <vector>
1028 using namespace std;
1029 vector <int> v;
1030 void *p = v.data ();
1031 ]])],
1032             [stepmake_cv_stl_data_method=yes],
1033             [stepmake_cv_stl_data_method=no]))
1034     if test $stepmake_cv_stl_data_method = yes; then
1035         AC_DEFINE(HAVE_STL_DATA_METHOD, 1, [define if stl classes have data () method])
1036     fi
1037 ])
1038
1039
1040 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
1041     # ugh
1042     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, OPTIONAL)
1043 ])
1044
1045 AC_DEFUN(STEPMAKE_TEXMF, [
1046     STEPMAKE_PROGS(METAFONT, mf-nowin mf mfw mfont, $1)
1047     STEPMAKE_PROGS(METAPOST, mpost, $1)
1048
1049     AC_MSG_CHECKING(for working metafont mode)
1050     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
1051     for MFMODE in $modelist; do
1052         $METAFONT -progname=mf "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
1053         if test -f mfput.tfm; then
1054             break;
1055         fi
1056     done
1057     AC_MSG_RESULT($MFMODE)
1058
1059     rm -f mfput.*
1060
1061     AC_SUBST(MFMODE)
1062 ])
1063
1064
1065 AC_DEFUN(STEPMAKE_WARN, [
1066     AC_MSG_WARN($1)
1067     warn_b=yes
1068 ])
1069
1070
1071 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1072 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1073 dnl also defines GSTUFF_PKG_ERRORS on error
1074 AC_DEFUN(PKG_CHECK_MODULES, [
1075   succeeded=no
1076
1077   if test -z "$PKG_CONFIG"; then
1078     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1079   fi
1080
1081   if test "$PKG_CONFIG" = "no" ; then
1082      echo "*** The pkg-config script could not be found. Make sure it is"
1083      echo "*** in your path, or set the PKG_CONFIG environment variable"
1084      echo "*** to the full path to pkg-config."
1085      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1086   else
1087      PKG_CONFIG_MIN_VERSION=0.9.0
1088      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1089         AC_MSG_CHECKING(for $2)
1090
1091         if $PKG_CONFIG --exists "$2" ; then
1092             AC_MSG_RESULT(yes)
1093             succeeded=yes
1094
1095             AC_MSG_CHECKING($1_CFLAGS)
1096             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1097             AC_MSG_RESULT($$1_CFLAGS)
1098
1099             AC_MSG_CHECKING($1_LIBS)
1100             $1_LIBS=`$PKG_CONFIG --libs "$2"`
1101             AC_MSG_RESULT($$1_LIBS)
1102         else
1103             $1_CFLAGS=""
1104             $1_LIBS=""
1105             ## If we have a custom action on failure, don't print errors, but
1106             ## do set a variable so people can do so.
1107             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1108             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1109         fi
1110
1111         AC_SUBST($1_CFLAGS)
1112         AC_SUBST($1_LIBS)
1113      fi
1114   fi
1115
1116   if test $succeeded = yes; then
1117      ifelse([$3], , :, [$3])
1118   else
1119      ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
1120   fi
1121 ])
1122
1123 AC_DEFUN(STEPMAKE_FREETYPE2, [
1124     PKG_CHECK_MODULES(FREETYPE2, $1 >= $3, have_freetype2=yes, true)
1125     if test "$have_freetype2" = yes; then
1126         AC_DEFINE(HAVE_FREETYPE2)
1127         save_CPPFLAGS="$CPPFLAGS"
1128         save_LIBS="$LIBS"
1129         CPPFLAGS="$FREETYPE2_CFLAGS $CPPFLAGS"
1130         LIBS="$FREETYPE2_LIBS $LIBS"
1131         AC_SUBST(FREETYPE2_CFLAGS)
1132         AC_SUBST(FREETYPE2_LIBS)
1133         CPPFLAGS="$save_CPPFLAGS"
1134         LIBS="$save_LIBS"
1135     else
1136         # UGR
1137         #r="lib$1-dev or $1-devel"
1138         r="libfreetype6-dev or freetype?-devel"
1139         ver="`pkg-config --modversion $1`"
1140         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1141     fi
1142 ])
1143
1144 AC_DEFUN(STEPMAKE_PANGO, [
1145     PKG_CHECK_MODULES(PANGO, $1 >= $3, have_pango16=yes, true)
1146     if test "$have_pango16" = yes ; then
1147         AC_DEFINE(HAVE_PANGO16)
1148         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1149         save_CPPFLAGS="$CPPFLAGS"
1150         save_LIBS="$LIBS"
1151         CPPFLAGS="$PANGO_CFLAGS $CPPFLAGS"
1152         LIBS="$PANGO_LIBS $LIBS"
1153         AC_CHECK_HEADERS([pango/pangofc-fontmap.h])
1154         AC_CHECK_FUNCS([pango_fc_font_map_add_decoder_find_func])
1155         AC_SUBST(PANGO_CFLAGS)
1156         AC_SUBST(PANGO_LIBS)
1157         CPPFLAGS="$save_CPPFLAGS"
1158         LIBS="$save_LIBS"
1159     else
1160         # UGR
1161         #r="lib$1-dev or $1-devel"
1162         r="libpango1.0-dev or pango1.0-devel"
1163         ver="`pkg-config --modversion $1`"
1164         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1165     fi
1166 ])
1167
1168 AC_DEFUN(STEPMAKE_PANGO_FT2, [
1169     PKG_CHECK_MODULES(PANGO_FT2, $1 >= $3, have_pangoft2=yes, true)
1170     if test "$have_pangoft2" = yes ; then
1171         AC_DEFINE(HAVE_PANGO16)
1172         AC_DEFINE(HAVE_PANGO_FT2)
1173         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1174         save_CPPFLAGS="$CPPFLAGS"
1175         save_LIBS="$LIBS"
1176         CPPFLAGS="$CPPFLAGS $PANGO_FT2_CFLAGS"
1177         LIBS="$PANGO_FT2_LIBS $LIBS"
1178         AC_CHECK_HEADERS([pango/pangoft2.h])
1179         AC_CHECK_FUNCS([pango_ft2_font_map_create_context])
1180         AC_SUBST(PANGO_FT2_CFLAGS)
1181         AC_SUBST(PANGO_FT2_LIBS)
1182         CPPFLAGS="$save_CPPFLAGS"
1183         LIBS="$save_LIBS"
1184     else
1185         # UGR
1186         #r="lib$1-dev or $1-devel"e
1187         r="libpango1.0-dev or pango?-devel"
1188         ver="`pkg-config --modversion $1`"
1189         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1190     fi
1191 ])
1192
1193 AC_DEFUN(STEPMAKE_FONTCONFIG, [
1194     PKG_CHECK_MODULES(FONTCONFIG, $1 >= $3, have_fontconfig=yes, true)
1195     if test "$have_fontconfig" = yes ; then
1196         AC_DEFINE(HAVE_FONTCONFIG)
1197         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1198         save_CPPFLAGS="$CPPFLAGS"
1199         save_LIBS="$LIBS"
1200         CPPFLAGS="$FONTCONFIG_CFLAGS $CPPFLAGS"
1201         LIBS="$FONTCONFIG_LIBS $LIBS"
1202         AC_SUBST(FONTCONFIG_CFLAGS)
1203         AC_SUBST(FONTCONFIG_LIBS)
1204         CPPFLAGS="$save_CPPFLAGS"
1205         LIBS="$save_LIBS"
1206     else
1207         r="lib$1-dev or $1-devel"
1208         ver="`pkg-config --modversion $1`"
1209         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1210     fi
1211 ])
1212
1213 AC_DEFUN(STEPMAKE_WINDOWS, [
1214     AC_CYGWIN
1215     AC_MINGW32
1216
1217     if test "$CYGWIN" = "yes"; then
1218         LN_S='cp -r' # Cygwin symbolic links do not work for native apps.
1219         program_suffix=.exe
1220         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1221     elif test "$MINGW32" = "yes"; then
1222         LN='cp -r'
1223         LN_S='cp -r'
1224         program_suffix=.exe
1225         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1226         PATHSEP=';'
1227     fi
1228
1229     AC_SUBST(LN)
1230     AC_SUBST(LN_S)
1231     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
1232     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
1233     AC_SUBST(DIRSEP)
1234     AC_SUBST(PATHSEP)
1235     AC_SUBST(program_suffix)
1236
1237     AC_MSG_CHECKING([for some flavor of Windows])
1238     if test "$CYGWIN$MINGW32" = "nono"; then
1239         PLATFORM_WINDOWS=no
1240     else
1241         PLATFORM_WINDOWS=yes
1242     fi
1243     AC_MSG_RESULT([$PLATFORM_WINDOWS])
1244     AC_SUBST(PLATFORM_WINDOWS)
1245     STEPMAKE_PROGS(WINDRES, $target-windres windres, x)
1246     AC_SUBST(WINDRES)
1247 ])