.zsh/zshrc/30_aliases

   1 # -*- mode: sh -*-
   2 # zshrc/30_aliases
   3 #
   4 # Defines command shortcuts
   5 #
   6 # Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
   7 # Released under the terms of the Artistic Licence 2.0
   8 #
   9 # Source repository: git://git.madduck.net/etc/zsh.git
  10 #
  11
  12 function trace() { eval "set -x; $@" }
  13
  14 alias mv='nocorrect mv'
  15 alias cp='nocorrect cp'
  16 alias ln='nocorrect ln'
  17 alias mkdir='nocorrect mkdir'
  18 alias rm='nocorrect rm'
  19
  20 alias find='noglob find'
  21 alias w3m='noglob w3m -no-mouse'
  22 alias links='noglob links'
  23 alias wb='noglob www-browser'
  24 alias wget='noglob wget'
  25 alias curl='noglob curl'
  26 alias apt-cache='noglob apt-cache'
  27 alias locate='noglob locate'
  28
  29 local _USER_AGENT="Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.8.1.14) Gecko/20080404 Iceweasel/2.0.0.14 (Debian-2.0.0.14-2)"
  30 alias swget="noglob wget --user-agent='$USER_AGENT'"
  31
  32 typeset -a _ls_opts; _ls_opts=(-bC --color=auto)
  33 command ls --group-directories-first >/dev/null 2>&1 \
  34   && _ls_opts+=--group-directories-first
  35 # I prefer POSIX collation for ls
  36 alias ls="LC_COLLATE=POSIX ls $_ls_opts"
  37
  38 alias l='ls --time-style=+%Y%m%d.%H%M -gG'
  39 alias ll='ls -l'
  40 alias la='ls -a'
  41 alias lla='ls -la'
  42 alias lt='ls -lt'
  43 alias lrt='ls -lrt'
  44 alias lat='ls -lat'
  45 alias lart='ls -lart'
  46 # List only directories and symbolic links that point to directories
  47 alias lsd='ll -d *(-/DN)'
  48
  49 alias lscontext=ls
  50 cd () { __CHPWD_RUN_FIRST=lscontext && builtin cd "$@" && unset __CHPWD_RUN_FIRST }
  51 #_cd_l() { ll }
  52 #chpwd_functions+=_cd_l
  53
  54 # #183394
  55 alias w='w|cat'
  56
  57 alias -g ND='*(/om[1])' # newest directory
  58 alias -g NF='*(.om[1])' # newest file
  59
  60 alias egrep='egrep --color=auto -d skip'
  61 alias fgrep='fgrep --color=auto -d skip'
  62 alias grep='grep --color=auto -d skip'
  63
  64 alias mmv='noglob zmv -W'
  65 alias zcp='zmv -C'
  66 alias zln='zmv -L'
  67 alias zgmv='zmv -p git-mv'
  68
  69 alias cal='cal -3'
  70 alias ftp=lftp
  71
  72 alias mbug='bts show --mbox'
  73 alias bug='BROWSER=www-browser bts show'
  74
  75 edalias() {
  76   [[ -z "$1" ]] && { echo "Usage: edalias <alias_to_edit>" ; return 1 } || vared aliases'[$1]' ;
  77 }
  78 compdef _aliases edalias
  79
  80 edfunc() {
  81   [[ -z "$1" ]] && { echo "Usage: edfunc <function_to_edit>" ; return 1 } || zed -f "$1" ;
  82 }
  83 compdef _functions edfunc
  84
  85 doc() { cd /usr/share/doc/$1 }
  86 compdef '_files -W /usr/share/doc -/' doc
  87
  88 alias giti='git init && git add . && git commit -minitial\ checkin && git tag orig'
  89 gbs() {
  90   local branch; branch="$(git symbolic-ref -q HEAD)"; branch="${branch##*/}"
  91   git config branch.${branch}.remote ${1:-origin}
  92   git config branch.${branch}.merge refs/heads/${branch}
  93   git config branch.${branch}.rebase true
  94 }
  95
  96 if whence mtail >/dev/null; then
  97   alias t=mtail
  98 elif whence tailf >/dev/null; then
  99   alias t=tailf
 100 else
 101   alias t='tail -f'
 102 fi
 103 compdef _files t
 104
 105 function ltail() { t ~log/$1 }
 106 compdef '_files -W ~log' ltail
 107
 108 function lless() { sensible-pager ~log/$1 }
 109 compdef '_files -W ~log' lless
 110
 111 alias tsl='ltail syslog'
 112 alias lsl='lless syslog'
 113 alias tml='ltail mail.log'
 114 alias lml='lless mail.log'
 115 alias tal='ltail auth.log'
 116 alias lal='lless auth.log'
 117 alias tdl='ltail daemon.log'
 118 alias ldl='lless daemon.log'
 119 alias tkl='ltail kern.log'
 120 alias lkl='lless kern.log'
 121
 122 function lgrep() {
 123   local pattern="$1"; shift
 124   eval egrep "'$pattern'" "~log/${(j: ~log/:)@}"
 125 }
 126
 127 alias px='ps afux'
 128 alias mps='ps -ao user,pcpu,start,command'
 129
 130 function of() { lsof -np "$1" }
 131 compdef _pids of
 132
 133 function psgrep() { ps aux | grep "[${1[1]}]${1[2,-1]}" }
 134
 135 alias rw-='chmod 600'
 136 alias rwx='chmod 700'
 137 alias r--='chmod 644'
 138 alias r-x='chmod 755'
 139 alias r-s='chmod 2755'
 140 alias rws='chmod 2775'
 141
 142 alias bofh='fortune bofh-excuses'
 143
 144 autoload -U baseconv
 145 alias b2d='baseconv 2 10'
 146 alias d2b='baseconv 10 2'
 147 alias d2h='baseconv 10 16'
 148 alias h2d='baseconv 16 10'
 149 alias d2o='baseconv 10 8'
 150 alias d2o='baseconv 10 8'
 151 alias h2b='baseconv 16 2'
 152 alias b2h='baseconv 2 16'
 153
 154 alias sendmail=/usr/sbin/sendmail
 155
 156 _d() { dict $* }
 157 d() { _d $* | sensible-pager }
 158 the() { d -d moby-thesaurus $* }
 159 typeset -A _LANGUAGES
 160 _LANGUAGES[en]=eng
 161 _LANGUAGES[de]=deu
 162 _LANGUAGES[es]=spa
 163 _LANGUAGES[fr]=fra
 164 _LANGUAGES[it]=ita
 165 _LANGUAGES[tn]=lat
 166 for l0 in ${(k)_LANGUAGES}; do
 167   for l1 in ${(k)_LANGUAGES}; do
 168     eval "function _${l0}-${l1}() { _d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 169     eval "function ${l0}-${l1}() { d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 170   done
 171 done
 172 unset '_LANGUAGES[en]'
 173 for l in ${(k)_LANGUAGES}; do
 174   eval "function ${l}() { (_${l}-en \$*; _en-${l} \$*) | more }"
 175 done
 176 unset _LANGUAGES
 177
 178 alias dpkg-buildpackage="dpkg-buildpackage -k$DEBKEYID -rfakeroot"
 179
 180 bugsub() { echo X-debbugs-autosubscribe: don | sendmail -f $DEBEMAIL ${1:?No bug number}-subscribe@bugs.debian.org }
 181 bugunsub() { sendmail -f $DEBEMAIL ${1:?No bug number}-unsubscribe@bugs.debian.org </dev/null }
 182 ptssub() { echo subscribe ${1:?E: no package name given.} | sendmail -f ${2:-$DEBEMAIL} pts@qa.debian.org }
 183 ptsunsub() { echo unsubscribe ${1:?E: no package name given.} | sendmail -f ${2:-$DEBEMAIL} pts@qa.debian.org }
 184 qasub() { echo subscribe ${1:?E: no package name given.} ${2:-unspecifed} | sendmail -f $DEBEMAIL ddpo@qa.debian.org }
 185 qaunsub() { echo unsubscribe ${1:?E: no package name given.} ${2:-unspecifed} | sendmail -f $DEBEMAIL ddpo@qa.debian.org }
 186
 187 uc() { unicode --max=0 --colour=off "$@" | sensible-pager }
 188
 189 alias ipr='ip r'
 190 alias ipa='ip a'
 191 alias ipl='ip l'
 192
 193 alias btd='btdownloadheadless'
 194
 195 function asc () { autossh -t "$@" 'screen -qxp= || screen -qdRR' }
 196 compdef asc=ssh
 197
 198 alias mdtest='swaks -s localhost -t'
 199
 200 if whence devtodo >/dev/null; then
 201   _devtodo_on_chpwd() {
 202     local out; out="$(devtodo)"
 203     [[ -n $out ]] && print "todo:\n$out"
 204   }
 205   [[ -z ${(M)chpwd_functions:#_devtodo_on_chpwd} ]] && chpwd_functions+=_devtodo_on_chpwd
 206 fi
 207
 208 # vim:ft=zsh