Lib/mk20dx256vlh7.ld

   1 /* Teensyduino Core Library
   2  * http://www.pjrc.com/teensy/
   3  * Copyright (c) 2013 PJRC.COM, LLC.
   4  * Modifications by Jacob Alexander 2014 for use with McHCK and Kiibohd-dfu
   5  *
   6  * Permission is hereby granted, free of charge, to any person obtaining
   7  * a copy of this software and associated documentation files (the
   8  * "Software"), to deal in the Software without restriction, including
   9  * without limitation the rights to use, copy, modify, merge, publish,
  10  * distribute, sublicense, and/or sell copies of the Software, and to
  11  * permit persons to whom the Software is furnished to do so, subject to
  12  * the following conditions:
  13  *
  14  * 1. The above copyright notice and this permission notice shall be
  15  * included in all copies or substantial portions of the Software.
  16  *
  17  * 2. If the Software is incorporated into a build system that allows
  18  * selection among a list of target devices, then similar target
  19  * devices manufactured by PJRC.COM must be included in the list of
  20  * target devices and selectable in the same manner.
  21  *
  22  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  23  * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  24  * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  25  * NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS
  26  * BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN
  27  * ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  28  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  29  * SOFTWARE.
  30  */
  31
  32 /* XXX Not tested yet -HaaTa */
  33
  34 MEMORY
  35 {
  36         FLASH (rx) : ORIGIN = 8K, LENGTH = 256K-8K
  37         RAM  (rwx) : ORIGIN = 0x20000000 - 64K / 2, LENGTH = 64K
  38 }
  39
  40 /* Section Definitions */
  41 SECTIONS
  42 {
  43         .text :
  44         {
  45                 . = 0;
  46                 KEEP(* (.vectors))
  47                 *(.startup*)
  48                 *(.text*)
  49                 *(.rodata*)
  50                 . = ALIGN(4);
  51                 KEEP(*(.init))
  52         } > FLASH
  53
  54         .ARM.exidx :
  55         {
  56                 __exidx_start = .;
  57                 *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  58                 __exidx_end = .;
  59         } > FLASH
  60         _etext = .;
  61
  62         .usbdescriptortable (NOLOAD) : {
  63                 . = ALIGN(512);
  64                 *(.usbdescriptortable*)
  65         } > RAM
  66
  67         .dmabuffers (NOLOAD) : {
  68                 . = ALIGN(4);
  69                 *(.dmabuffers*)
  70         } > RAM
  71
  72         .usbbuffers (NOLOAD) : {
  73                 . = ALIGN(4);
  74                 *(.usbbuffers*)
  75         } > RAM
  76
  77         .data : AT (_etext) {
  78                 . = ALIGN(4);
  79                 _sdata = .;
  80                 *(.data*)
  81                 . = ALIGN(4);
  82                 _edata = .;
  83         } > RAM
  84
  85         .noinit (NOLOAD) : {
  86                 *(.noinit*)
  87         } > RAM
  88
  89         .bss : {
  90                 . = ALIGN(4);
  91                 _sbss = .;
  92                 *(.bss*)
  93                 *(COMMON)
  94                 . = ALIGN(4);
  95                 _ebss = .;
  96                 __bss_end = .;
  97         } > RAM
  98
  99         _estack = ORIGIN(RAM) + LENGTH(RAM);
 100 }
 101