Lib/CMake/build.cmake

   1 ###| CMAKE Kiibohd Controller Source Configurator |###
   2 #
   3 # Written by Jacob Alexander in 2011-2015 for the Kiibohd Controller
   4 #
   5 # Released into the Public Domain
   6 #
   7 ###
   8
   9
  10 ###
  11 # Disable -Wl,-search_paths_first for OSX (not supported by avr-gcc or arm-none-eabi-gcc)
  12 #
  13
  14 if ( APPLE )
  15         string ( REPLACE "-Wl,-search_paths_first" "" CMAKE_C_LINK_FLAGS ${CMAKE_C_LINK_FLAGS} )
  16         string ( REPLACE "-Wl,-search_paths_first" "" CMAKE_CXX_LINK_FLAGS ${CMAKE_CXX_LINK_FLAGS} )
  17 endif ()
  18
  19
  20
  21 ###
  22 # Build Targets
  23 #
  24
  25 #| Create the .ELF file
  26 set( TARGET_ELF ${TARGET}.elf )
  27 add_executable( ${TARGET_ELF} ${SRCS} generatedKeymap.h )
  28
  29
  30 #| .ELF Properties
  31 set_target_properties( ${TARGET_ELF} PROPERTIES
  32         LINK_FLAGS ${LINKER_FLAGS}
  33         SUFFIX ""                               # XXX Force Windows to keep the .exe off
  34 )
  35
  36 #| llvm-clang does not have an objcopy equivalent
  37 if ( "${COMPILER}" MATCHES "clang" )
  38         if ( "${COMPILER_FAMILY}" MATCHES "arm" )
  39                 set ( OBJ_COPY arm-none-eabi-objcopy )
  40         elseif ( "${COMPILER_FAMILY}" MATCHES "arm" )
  41                 set ( OBJ_COPY avr-objcopy )
  42         endif ()
  43 else ()
  44         set ( OBJ_COPY ${CMAKE_OBJCOPY} )
  45 endif ()
  46
  47
  48 #| Convert the .ELF into a .bin to load onto the McHCK
  49 #| Then sign using dfu-suffix (requries dfu-util)
  50 if ( DEFINED DFU )
  51         # dfu-suffix is required to sign the dfu binary
  52         find_package ( DFUSuffix )
  53
  54         set( TARGET_BIN ${TARGET}.dfu.bin )
  55         if ( DFU_SUFFIX_FOUND )
  56                 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  57                         COMMAND ${OBJ_COPY} ${BIN_FLAGS} ${TARGET_ELF} ${TARGET_BIN}
  58                         COMMAND ${DFU_SUFFIX_EXECUTABLE} --add ${TARGET_BIN} --vid ${BOOT_VENDOR_ID} --pid ${BOOT_PRODUCT_ID} 1> /dev/null
  59                         COMMENT "Create and sign dfu bin file:  ${TARGET_BIN}"
  60                 )
  61         else ()
  62                 message ( WARNING "DFU Binary has not been signed, requires dfu-suffix..." )
  63                 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  64                         COMMAND ${OBJ_COPY} ${BIN_FLAGS} ${TARGET_ELF} ${TARGET_BIN}
  65                         COMMENT "Creating dfu binary file:      ${TARGET_BIN}"
  66                 )
  67         endif ()
  68 endif ()
  69
  70
  71 #| Convert the .ELF into a .HEX to load onto the Teensy
  72 if ( DEFINED TEENSY )
  73         set( TARGET_HEX ${TARGET}.teensy.hex )
  74         add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  75                 COMMAND ${OBJ_COPY} ${HEX_FLAGS} ${TARGET_ELF} ${TARGET_HEX}
  76                 COMMENT "Creating iHex file to load:    ${TARGET_HEX}"
  77         )
  78 endif()
  79
  80
  81 #| Generate the Extended .LSS
  82 set( TARGET_LSS ${TARGET}.lss )
  83 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  84         COMMAND ${CMAKE_OBJDUMP} ${LSS_FLAGS} ${TARGET_ELF} > ${TARGET_LSS}
  85         COMMENT "Creating Extended Listing:     ${TARGET_LSS}"
  86 )
  87
  88
  89 #| Generate the Symbol Table .SYM
  90 set( TARGET_SYM ${TARGET}.sym )
  91 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  92         COMMAND ${CMAKE_NM} -n ${TARGET_ELF} > ${TARGET_SYM}
  93         COMMENT "Creating Symbol Table:         ${TARGET_SYM}"
  94 )
  95
  96
  97 #| Compiler Selection Record
  98 add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
  99         COMMAND ${CMAKE_SOURCE_DIR}/Lib/CMake/writer compiler ${COMPILER_FAMILY}
 100 )
 101
 102
 103
 104 ###
 105 # Size Information
 106 #
 107
 108 #| After Changes Size Information
 109 add_custom_target( SizeAfter ALL
 110         COMMAND ${CMAKE_SOURCE_DIR}/Lib/CMake/sizeCalculator ${CMAKE_SIZE} ram   ${TARGET_ELF} ${SIZE_RAM}   " SRAM"
 111         COMMAND ${CMAKE_SOURCE_DIR}/Lib/CMake/sizeCalculator ${CMAKE_SIZE} flash ${TARGET_ELF} ${SIZE_FLASH} "Flash"
 112         DEPENDS ${TARGET_ELF}
 113         COMMENT "Chip usage for ${CHIP}"
 114 )
 115
 116
 117
 118 ###
 119 # Setup Loader Script and Program
 120 #
 121
 122 #| First check for DFU based controllers
 123 if( DEFINED DFU )
 124         configure_file( LoadFile/load.dfu load NEWLINE_STYLE UNIX )
 125
 126 #| Next check for Teensy based
 127 elseif ( DEFINED TEENSY )
 128         # Provides the user with the correct teensy-loader-cli command for the built .HEX file
 129         # Windows
 130         if( CMAKE_SYSTEM_NAME MATCHES "Windows" )
 131                 configure_file( LoadFile/winload.teensy load NEWLINE_STYLE UNIX )
 132         # Default
 133         else()
 134                 configure_file( LoadFile/load.teensy load NEWLINE_STYLE UNIX )
 135         endif()
 136 endif()
 137
 138
 139
 140 ###
 141 # Compiler Command Generation
 142 #
 143
 144 #| Generate list of compiler commands for clang-tidy usage
 145 set( CMAKE_EXPORT_COMPILE_COMMANDS ON )
 146
 147 #| Make sure symlink exists (for convenience)
 148 if ( UNIX )
 149         # Make sure symlink is created immediately
 150         execute_process ( COMMAND ln -sfn ${CMAKE_BINARY_DIR}/compile_commands.json ${CMAKE_SOURCE_DIR}/. )
 151
 152         # Also update before each build
 153         add_custom_command( TARGET ${TARGET_ELF} POST_BUILD
 154                 COMMAND ln -sfn ${CMAKE_BINARY_DIR}/compile_commands.json ${CMAKE_SOURCE_DIR}/.
 155         )
 156 endif ()
 157